CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 2.6.4)
   8
   9 set(LYX_PROJECT LyX)
  10
  11 enable_testing()
  12
  13 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README ABSOLUTE)
  14 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  15
  16 set(LYX_CMAKE_DIR "development/cmake")
  17 set(TOP_CMAKE_PATH "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}")
  18 set(TOP_MODULE_PATH "${TOP_CMAKE_PATH}/modules")
  19 set(TOP_SCRIPT_PATH "${TOP_CMAKE_PATH}/scripts")
  20
  21 set(CMAKE_MODULE_PATH "${TOP_MODULE_PATH}")
  22
  23 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  24
  25 message(STATUS)
  26 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  27         message(STATUS "Building in-source")
  28         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  29 else()
  30         message(STATUS "Building out-of-source")
  31         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  32 endif()
  33
  34 # This directory should be used if some test uses lyx-executable
  35 set(LYX_TESTS_USERDIR "${TOP_BINARY_DIR}/Testing/.lyx")
  36 file(MAKE_DIRECTORY "${LYX_TESTS_USERDIR}")
  37
  38 if(COMMAND cmake_policy)
  39         cmake_policy(SET CMP0003 OLD)
  40         cmake_policy(SET CMP0005 OLD)
  41         # Installing MACOSX_BUNDLE targets requires a BUNDLE DESTINATION
  42         cmake_policy(SET CMP0006 NEW)
  43         if(POLICY CMP0020)
  44                 cmake_policy(SET CMP0020 OLD)
  45         endif()
  46         if(POLICY CMP0028)
  47                 cmake_policy(SET CMP0028 OLD)
  48         endif()
  49         if(POLICY CMP0043)
  50                 # COMPILE_DEFINITIONS are not used yet. Enable new behavior.
  51                 cmake_policy(SET CMP0043 NEW)
  52         endif()
  53 endif()
  54
  55 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  56
  57 # Supress regeneration
  58 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  59
  60 if(LYX_XMINGW)
  61     set(CMAKE_SYSTEM_NAME Windows)
  62     set(TOOLNAME ${LYX_XMINGW})
  63     set(TOOLCHAIN "${TOOLNAME}-")
  64     set(CMAKE_C_COMPILER   "${TOOLCHAIN}gcc"     CACHE PATH "Mingw C compiler" FORCE)
  65     set(CMAKE_CXX_COMPILER "${TOOLCHAIN}g++"     CACHE PATH "Mingw C++ compiler" FORCE)
  66     set(CMAKE_RC_COMPILER  "${TOOLCHAIN}windres" CACHE PATH "Mingw rc compiler" FORCE)
  67
  68     set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM BOTH)
  69     set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY)
  70     set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY)
  71 endif()
  72
  73 if(NOT help AND NOT HELP)
  74   # 'project' triggers the searching for a compiler
  75   project(${LYX_PROJECT})
  76   if (CMAKE_COMPILER_IS_GNUCXX)
  77     if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS "4.0")
  78       message(STATUS "Gnu CXX compiler version = ${CMAKE_CXX_COMPILER_VERSION}")
  79       message(STATUS "is too old, should be >= 4.0")
  80       message(FATAL_ERROR "Exiting")
  81     endif()
  82   endif()
  83 endif()
  84
  85 if(UNIX)
  86         set(ARCH_TRIPLET )
  87         FIND_PROGRAM(DPKG_ARCHITECTURE_EXECUTABLE dpkg-architecture)
  88         if(DPKG_ARCHITECTURE_EXECUTABLE)
  89                 EXECUTE_PROCESS(COMMAND ${DPKG_ARCHITECTURE_EXECUTABLE} -qDEB_HOST_MULTIARCH
  90                                 OUTPUT_VARIABLE ARCH_TRIPLET
  91                                 ERROR_VARIABLE ERROR_ARCH_TRIPLET
  92                                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  93         endif()
  94 endif()
  95 if(ARCH_TRIPLET)
  96         set(SYSTEM_LIB_DIRS /usr/lib /usr/lib/${ARCH_TRIPLET} /usr/local/lib)
  97 else()
  98         set(SYSTEM_LIB_DIRS /usr/lib /usr/local/lib)
  99 endif()
 100
 101 include(LyXMacros)
 102
 103 # Usage LYX_OPTION
 104 # 1. parameter: option name without prefix 'LYX_'
 105 # 2. parameter: description
 106 # 3. parameter: default value, ON or OFF
 107 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
 108
 109 # Usage LYX_COMBO
 110 # 1. parameter: name without prefix 'LYX_'
 111 # 2. parameter: description
 112 # 3. parameter: default value
 113 # 4-n parameter: possible other string values
 114
 115 LYX_OPTION_INIT()
 116
 117 # Options for all compilers/systems
 118 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
 119 LYX_OPTION(LOCALVERSIONING  "Add version info to created package name (only used if LYX_CPACK option set)" OFF ALL)
 120 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
 121 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
 122 LYX_OPTION(REQUIRE_SPELLCHECK "Abort if no spellchecker available" OFF ALL)
 123 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
 124 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
 125 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
 126 LYX_OPTION(DEVEL_VERSION    "Build developer version" OFF ALL)
 127 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" OFF ALL)
 128 LYX_OPTION(DEBUG            "Enforce debug build"  OFF ALL)
 129 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
 130 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
 131 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
 132 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
 133 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
 134 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
 135 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
 136 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
 137 LYX_OPTION(ENABLE_URLTESTS  "Enable for URL tests" OFF ALL)
 138 LYX_OPTION(ENABLE_EXPORT_TESTS "Enable for export tests" OFF ALL)
 139 LYX_OPTION(ASAN             "Use address sanitizer" OFF ALL)
 140 LYX_COMBO(USE_QT            "Use Qt version as frontend" QT4 QT5)
 141
 142 # GCC specific
 143 LYX_OPTION(PROFILE              "Build profile version" OFF GCC)
 144 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" OFF GCC)
 145 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
 146 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
 147 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++ pedantic debug mode" OFF GCC)
 148 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" OFF GCC)
 149 LYX_OPTION(PROFILE              "Build with options for gprof" OFF GCC)
 150 LYX_OPTION(ENABLE_CXX11         "Build with options for c++11-mode" OFF GCC)
 151
 152 # MSVC specific
 153 LYX_OPTION(CONSOLE               "Show console on Windows, enforce with =FORCE" ON MSVC)
 154 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
 155 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
 156 LYX_OPTION(CONFIGURE_CHECKS      "Also run configure checks for MSVC" OFF MSVC)
 157 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
 158
 159 # APPLE specific
 160 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
 161 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
 162
 163
 164 if(help OR HELP)
 165         message(STATUS)
 166         message(STATUS "Available options: (dis/enable with -DLYX_*=OFF/ON)")
 167         message(STATUS)
 168         LYX_OPTION_LIST_ALL(help)
 169         message(STATUS)
 170         RETURN()
 171 endif()
 172
 173 # Check option dependencies
 174
 175 if(LYX_DMG)
 176         set(LYX_BUNDLE ON)
 177         set(LYX_CPACK ON)
 178 endif()
 179
 180 if(LYX_CPACK)
 181         set(LYX_INSTALL ON)
 182 endif()
 183
 184 if(LYX_INSTALL)
 185         set(LYX_NLS ON)
 186         if(WIN32 AND NOT MINGW)
 187                 set(LYX_HUNSPELL ON)
 188         endif()
 189         if(LYX_CONSOLE MATCHES "FORCE")
 190                 set(LYX_CONSOLE ON)
 191         else()
 192                 set(LYX_CONSOLE OFF)
 193         endif()
 194         set(LYX_PACKAGE_SUFFIX ON)
 195         if(NOT LYX_DEBUG)
 196                 set(LYX_RELEASE ON)
 197         endif()
 198         set(LYX_PROFILE OFF)
 199 endif()
 200
 201
 202 if(LYX_MERGE_FILES)
 203         set(LYX_PCH OFF)
 204 else()
 205         set(LYX_MERGE_REBUILD OFF)
 206 endif()
 207
 208
 209 if(LYX_DEPENDENCIES_DOWNLOAD)
 210         message(STATUS)
 211         set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 212         message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 213         set(deps_files lyx20-deps-msvc2010-x86.zip)
 214         set(deps_server http://downloads.sourceforge.net/project/lyx/Win_installers/Dependencies)
 215         foreach(it ${deps_files})
 216                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 217                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 218                 if(NOT already_downloaded)
 219                         message(STATUS "Downloading ${it} ...")
 220                         file(DOWNLOAD ${deps_server}/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS STATUS status LOG log)
 221                         list(GET status 0 status_code)
 222                         list(GET status 1 status_string)
 223                         if(NOT status_code EQUAL 0)
 224                                 file(REMOVE ${LYX_DEPENDENCIES_DIR}/${it})
 225                                 message(FATAL_ERROR "error: downloading '${it}' failed. status_code: ${status_code}, status_string: ${status_string}. \nLog: ${log} ")
 226                         endif()
 227                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 228                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 229                 endif()
 230         endforeach()
 231         set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/deps20)
 232     if(MSVC12)
 233         # handle error in msvc12 when linking against msvc10 libs
 234         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /vd2")
 235     endif()
 236 endif()
 237
 238
 239
 240 message(STATUS)
 241
 242 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 243 if(WIN32)
 244         set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 245 else()
 246         set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 247 endif()
 248
 249
 250 set(LYX_GCC11_MODE)
 251 if(UNIX OR MINGW)
 252         execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION OUTPUT_STRIP_TRAILING_WHITESPACE)
 253         message(STATUS "Using GCC version ${GCC_VERSION}")
 254         if(GCC_VERSION VERSION_LESS 4.9)
 255                 # <regex> in gcc is unusable in versions less than 4.9.0
 256                 # see https://gcc.gnu.org/bugzilla/show_bug.cgi?id=53631
 257                 set(LYX_USE_STD_REGEX 0)
 258         endif()
 259         if (LYX_ENABLE_CXX11)
 260                 find_package(CXX11Compiler)
 261                 if(NOT CXX11COMPILER_FOUND)
 262                         message(FATAL_ERROR "A C++11 compatible compiler is required.")
 263                 endif()
 264                 set(LYX_GCC11_MODE "${CXX11_FLAG}")
 265         endif()
 266 else()
 267         set(LYX_USE_STD_REGEX 0)
 268 #       if(MSVC10)
 269 #               set(LYX_USE_STD_REGEX 1) #TODO should we use it in ECMAScript mode?
 270 #       endif()
 271 endif()
 272
 273
 274 set(VERSION_INFO "CMake Build")
 275
 276 # Try to get some informations from configure.ac
 277
 278 include(LyXPaths)
 279 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 280
 281 if(WIN32)
 282         set(USE_WINDOWS_PACKAGING ON)
 283 elseif(APPLE)
 284         set(USE_MACOSX_PACKAGING ON)
 285 else()
 286         set(USE_POSIX_PACKAGING ON)
 287 endif()
 288
 289 macro(setstripped _varname)
 290         if(${ARGC} GREATER 1)
 291                 string(STRIP "${ARGV1}" _v)
 292                 if(USE_POSIX_PACKAGING)
 293                         string(TOLOWER ${_v} ${_varname})
 294                 else()
 295                         set(${_varname} ${_v})
 296                 endif()
 297         else()
 298                 set(${_varname})
 299         endif()
 300 endmacro(setstripped)
 301
 302 foreach(_c_l ${_config_lines} )
 303         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 304                 setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 305                 setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 306                 setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 307                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\)\(\\.\([0-9]+\)\)?.*$")
 308                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 309                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 310                         set(LYX_PATCH_VERSION ${CMAKE_MATCH_4})
 311                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 312                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 313                         set(LYX_INSTALL_SUFFIX "${CMAKE_MATCH_1}.${CMAKE_MATCH_2}")
 314                 endif()
 315         endif()
 316         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 317                 set(LYX_DATE "${CMAKE_MATCH_1}")
 318         endif()
 319 endforeach(_c_l)
 320
 321 FIND_PROGRAM(LYX_GITVERSION git)
 322 #message(STATUS "gitversion = ${LYX_GITVERSION}")
 323 set(LYX_REVISION_VERSION ${LYX_PATCH_VERSION})
 324 if(LYX_GITVERSION)
 325   if (LYX_LOCALVERSIONING)
 326     # Find the revision number and for later use
 327     EXECUTE_PROCESS(COMMAND ${LYX_GITVERSION} describe --match 2.0.0 HEAD
 328       WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE LYX_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 329     if (LYX_PACKAGE_RELEASE MATCHES "^2\\.0\\.0\\-\([0-9]+\)\\-.*$")
 330       # We will add offset of 40000 to get appropriate value to
 331       # previous svn.
 332       # We use this value than also to set the package-patch-value
 333       MATH(EXPR tmp_REVISION_VERSION "(${CMAKE_MATCH_1}+40000)")
 334       set(LYX_REVISION_VERSION "${LYX_PATCH_VERSION}-${tmp_REVISION_VERSION}git")
 335       set(ENABLE_DIST ON)
 336     endif()
 337   endif()
 338 endif()
 339
 340 # Set the programs (lyx, tex2lyx, etc.) suffix
 341 # When building an OS X bundle, we will append
 342 # the suffix only to the bundle, not to the programs
 343 set(PROGRAM_SUFFIX "")
 344 if(LYX_PROGRAM_SUFFIX AND NOT (APPLE AND LYX_BUNDLE))
 345         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 346 endif()
 347 set(_lyx "${PACKAGE_BASE}${PROGRAM_SUFFIX}")
 348 set(_tex2lyx tex2lyx${PROGRAM_SUFFIX})
 349
 350 add_custom_target(lyx_version ALL
 351   COMMAND ${CMAKE_COMMAND} -DTOP_SRC_DIR=${TOP_SRC_DIR} -DTOP_CMAKE_PATH=${TOP_CMAKE_PATH} -DTOP_BINARY_DIR=${TOP_BINARY_DIR} -DLYX_DATE=${LYX_DATE} -P ${TOP_SCRIPT_PATH}/LyXGetVersion.cmake
 352   )
 353 set_target_properties(lyx_version PROPERTIES FOLDER "applications")
 354
 355 # Default paths for installed utilities (tex2lyx, lyxclient, etc.)
 356 set(LYX_UTILITIES_INSTALL_PATH bin)
 357
 358 if(LYX_BUNDLE)
 359         set(LYX_CPACK ON)
 360
 361         message(STATUS)
 362         message(STATUS "Bundle creation is enabled (experimental):")
 363         message(STATUS "    make")
 364         message(STATUS "    make install/strip")
 365         message(STATUS "    make package")
 366         if(APPLE)
 367                 set(MACOSX_BUNDLE TRUE)
 368                 # This sets the bundle + executable names
 369                 set(_lyx "${PACKAGE_BASE}${LYX_INSTALL_SUFFIX}")
 370                 # This sets the Info.plist executable name
 371                 set(osx_bundle_program_name ${_lyx})
 372                 # Bundle name
 373                 set(LYX_BUNDLE_NAME ${_lyx})
 374
 375                 # This will contain the list of files that need to be included
 376                 # in the bundle and their location within the bundle
 377                 set(OSX_BUNDLE_FILES "${TOP_SRC_DIR}/development/MacOSX/LyX.sdef;${TOP_SRC_DIR}/development/MacOSX/LyXapp.icns;${CMAKE_BINARY_DIR}/lyxrc.dist")
 378                 set(OSX_BUNDLE_DIRS "Resources;Resources;Resources")
 379
 380                 # Process Info.plist and lyxrc.dist
 381                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/Info.plist.in" "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 382                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/lyxrc.dist.in" "${CMAKE_CURRENT_BINARY_DIR}/lyxrc.dist")
 383
 384                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 385                 set(LYX_DATA_SUBDIR ${LYX_BUNDLE_NAME}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 386
 387                 # Variables used by CPack
 388                 set(CPACK_BUNDLE_NAME ${LYX_BUNDLE_NAME})
 389                 set(CPACK_BUNDLE_PLIST "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 390                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${LYX_BUNDLE_NAME}.app)
 391
 392                 # Set the install paths
 393                 set(LYX_UTILITIES_INSTALL_PATH ${LYX_BUNDLE_NAME}.app/Contents/MacOS)
 394                 if(NOT LYX_INSTALL_PREFIX)
 395                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 396                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 397                 endif()
 398                 # Change the owner so that the install can work
 399                 install(CODE "set(BU_CHMOD_BUNDLE_ITEMS 1)" COMPONENT Runtime)
 400         elseif(UNIX)
 401                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 402                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 403                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 404         elseif(WIN32)
 405                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 406         endif()
 407 endif()
 408
 409 if(LYX_INSTALL_PREFIX)
 410         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 411         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 412 endif()
 413 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 414
 415 string(REGEX REPLACE "/lyx${LYX_INSTALL_SUFFIX}$" "/share" SYSTEM_DATADIR ${CMAKE_INSTALL_PREFIX})
 416
 417 if(LYX_PACKAGE_SUFFIX)
 418         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 419 else()
 420         set(PACKAGE ${PACKAGE_BASE})
 421 endif()
 422
 423 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 424         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 425         if (UNIX)
 426                 # don't use the default "/usr/local"
 427                 # but respect the user-choice on the command-line
 428                 if(LYX_INSTALL_SUFFIX)
 429                         set(CMAKE_INSTALL_PREFIX "/usr/local/lyx${LYX_INSTALL_SUFFIX}" CACHE PATH "LyX default install prefix" FORCE)
 430                 else()
 431                         set(CMAKE_INSTALL_PREFIX "/usr/local/${LYX_PROJECT}" CACHE PATH "LyX default install prefix" FORCE)
 432                 endif()
 433         endif()
 434         if(WIN32)
 435                 set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 436         endif()
 437 endif()
 438 if(IS_ABSOLUTE)
 439         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 440 else()
 441         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 442 endif()
 443
 444
 445
 446 if(NOT LYX_DATA_SUBDIR)
 447         if (WIN32)
 448                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 449         else()
 450                 set(LYX_DATA_SUBDIR "" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 451         endif()
 452 endif()
 453
 454 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 455 set(LYX_LOCALEDIR "locale")
 456 set(LYX_ABS_INSTALLED_LOCALEDIR "${LYX_ABS_INSTALLED_DATADIR}/${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}")
 457 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 458
 459 if(LYX_BUNDLE AND APPLE)
 460         set(LYX_MAN_DIR "${LYX_DATA_SUBDIR}" CACHE STRING "Install location for man pages.")
 461 else()
 462         set(LYX_MAN_DIR "/usr/local/man/man1" CACHE STRING "Install location for man pages.")
 463 endif()
 464 mark_as_advanced(LYX_MAN_DIR)
 465
 466 if(LYX_INSTALL AND WIN32)
 467         message(STATUS "Configuring NSIS files")
 468         configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 469         configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 470         configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 471         message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 472 endif()
 473
 474 if(NOT GROUP_CODE)
 475         #set(GROUP_CODE "The Golden Code")
 476         set(GROUP_CODE flat)
 477 endif()
 478
 479 # lyx's source files
 480 set(LYX_CPP_FILES [a-zA-Z]*.cpp)
 481 set(LYX_HPP_FILES [a-zA-Z]*.h)
 482 set(LYX_MOC_FILES moc_*.cpp)
 483
 484 include(ProjectSourceGroup)
 485
 486
 487 if(LYX_PROFILE AND NOT MSVC)
 488         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 489         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg")
 490         set(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS}  -pg")
 491 else()
 492         set(LYX_PROFILE OFF)
 493 endif()
 494
 495
 496 if(LYX_NO_OPTIMIZE)
 497         set(CMAKE_BUILD_TYPE None)
 498         set(LYX_DEBUG OFF)
 499         set(LYX_RELEASE OFF)
 500         set(LYX_PROFILE OFF)
 501 elseif(LYX_RELEASE)
 502         set(CMAKE_BUILD_TYPE Release)
 503         set(LYX_DEBUG OFF)
 504         set(LYX_PROFILE OFF)
 505 elseif(LYX_PROFILE)
 506         set(CMAKE_BUILD_TYPE Profile)
 507         set(LYX_DEBUG OFF)
 508 else()
 509         set(CMAKE_BUILD_TYPE Debug)
 510         set(LYX_DEBUG ON)
 511 endif()
 512
 513
 514 # When shared libs are supported enable this option
 515 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 516 if(LYX_SHARED_LIBRARIES)
 517         set(library_type SHARED)
 518 else()
 519         set(library_type STATIC)
 520 endif()
 521
 522 if(NOT MSVC)
 523         if(NOT LYX_QUIET)
 524                 set(CMAKE_VERBOSE_MAKEFILE ON)
 525         endif()
 526     set(LYX_CXX_FLAGS "-Wall -Wunused-parameter ${LYX_GCC11_MODE}")
 527         if(LYX_STDLIB_DEBUG)
 528                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 529         endif()
 530         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 531         set(CMAKE_CXX_FLAGS_DEBUG "${LYX_CXX_FLAGS} -fno-strict-aliasing -O0 -g3 -D_DEBUG" CACHE TYPE STRING FORCE)
 532         if(MINGW)
 533                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 534         else()
 535                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 536         endif()
 537 endif()
 538
 539 set(LYX_CXX_FLAGS_EXTRA "" CACHE STRING "Desired semicolon separated list of extra cxx compile flags, like '-Werror'")
 540 mark_as_advanced(LYX_CXX_FLAGS_EXTRA)
 541 if(LYX_CXX_FLAGS_EXTRA)
 542         foreach(_flag ${LYX_CXX_FLAGS_EXTRA})
 543                 add_definitions(${_flag})
 544         endforeach()
 545 endif()
 546
 547 if(LYX_XMINGW)
 548         list(APPEND CMAKE_FIND_ROOT_PATH ${GNUWIN32_DIR})
 549 endif()
 550
 551 if(LYX_USE_QT MATCHES "QT5")
 552         find_package(Qt5Core REQUIRED)
 553         if (Qt5Core_FOUND)
 554                 find_package(Qt5Widgets REQUIRED)
 555                 if(APPLE)
 556                         find_package(Qt5MacExtras REQUIRED)
 557                 endif()
 558                 find_package(Qt5X11Extras QUIET)
 559                 find_package(Qt5WinExtras QUIET)
 560                 set(QTVERSION ${Qt5Core_VERSION})
 561                 macro (qt_use_modules)
 562                         qt5_use_modules(${ARGN})
 563                 endmacro()
 564                 macro (qt_add_resources)
 565                         qt5_add_resources(${ARGN})
 566                 endmacro()
 567                 macro (qt_wrap_uifiles)
 568                         qt5_wrap_ui(${ARGN})
 569                 endmacro()
 570                 message(STATUS "Found Qt-Version ${QTVERSION}")
 571         endif()
 572 elseif(LYX_USE_QT MATCHES "QT4")
 573         if(LYX_XMINGW)
 574                 set(QT_MINGW_DIR ${LYX_QT4} CACHE PATH "Qt for Mingw" FORCE)
 575                 list(APPEND CMAKE_FIND_ROOT_PATH ${QT_MINGW_DIR} ${GNUWIN32_DIR})
 576         endif()
 577         find_package(Qt4 "4.5.0" REQUIRED)
 578         macro (qt_use_modules)
 579         endmacro()
 580         macro (qt_add_resources)
 581                 qt4_add_resources(${ARGN})
 582         endmacro()
 583         macro (qt_wrap_uifiles)
 584                 qt4_wrap_ui(${ARGN})
 585         endmacro()
 586 else()
 587   message(FATAL_ERROR "Unhandled value for LYX_USE_QT (${LYX_USE_QT})")
 588 endif()
 589
 590 find_package(Magic)
 591 if(Magic_FOUND)
 592         set(HAVE_MAGIC_H 1)
 593 endif()
 594
 595 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 596
 597 set(Spelling_FOUND OFF)
 598 set(Include_used_spellchecker)   # String will be inserted into config.h
 599
 600 foreach(_spell "ASPELL" "Enchant" "Hunspell")
 601   string(TOUPPER ${_spell} _upspell)
 602   find_package(${_spell})
 603   if (${_upspell}_FOUND)
 604     include_directories(${${_upspell}_INCLUDE_DIR})
 605     set(Spelling_FOUND ON)
 606     message(STATUS "Building with USE_${_upspell}")
 607     set(Include_used_spellchecker "${Include_used_spellchecker}#define USE_${_upspell} 1\n")
 608   else()
 609     if(LYX_${_upspell})
 610       message(FATAL_ERROR "Required ${_spell} devel package not found")
 611     else()
 612       message(STATUS "${_upspell} not found, building without ${_spell} support")
 613     endif()
 614   endif()
 615 endforeach()
 616
 617 find_package(PythonInterp 2.7 QUIET)
 618 if(PYTHONINTERP_FOUND)
 619   if(PYTHON_VERSION_STRING VERSION_GREATER 2.8)
 620     unset(PYTHONINTERP_FOUND)
 621   endif()
 622 endif()
 623
 624 if (NOT PYTHONINTERP_FOUND)
 625   unset(PYTHON_EXECUTABLE CACHE)
 626   unset(PYTHON_VERSION_MAJOR)
 627   unset(PYTHON_VERSION_MINOR)
 628   unset(PYTHON_VERSION_STRING)
 629   find_package(PythonInterp 3.3 REQUIRED)
 630 endif()
 631
 632 set(LYX_PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 633
 634 if(LYX_NLS)
 635         find_package(LyXGettext)
 636         if(LYX_PYTHON_EXECUTABLE AND GETTEXT_FOUND)
 637                 add_subdirectory(po "${TOP_BINARY_DIR}/po")
 638         else()
 639                 # Install only supplied .gmo-files
 640                 file(GLOB _gmofiles RELATIVE "${TOP_SRC_DIR}/po" "${TOP_SRC_DIR}/po/*.gmo")
 641                 message(STATUS "Installing provided .gmo-files only")
 642                 foreach( _gmo ${_gmofiles})
 643                         string(REGEX REPLACE "\\.gmo$" "" _lang ${_gmo})
 644                         install(FILES "${TOP_SRC_DIR}/po/${_gmo}" DESTINATION ${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}/${_lang}/LC_MESSAGES RENAME ${PACKAGE}.mo)
 645                 endforeach()
 646         endif()
 647 endif()
 648
 649
 650 find_package(ICONV REQUIRED)
 651 find_package(ZLIB REQUIRED)
 652
 653 if(LYX_EXTERNAL_BOOST)
 654         message(STATUS "Searching for boost")
 655         if(LYX_USE_STD_REGEX)
 656                 find_package(Boost COMPONENTS signals)
 657         else()
 658                 find_package(Boost COMPONENTS signals regex)
 659         endif()
 660         if(Boost_FOUND)
 661                 message(STATUS "Boost found")
 662                 message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 663                 set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 664                 if (LYX_STDLIB_DEBUG)
 665                         # Comment from  Jean-Marc Lasgouttes:
 666                         # In general, system boost libraries are incompatible with
 667                         # the use of stdlib-debug in libstdc++. See ticket #9736 for
 668                         # details.
 669                         message(WARNING "Compiling LyX with stdlib-debug and system boost libraries may lead to crashes. Consider using '-DLYX_STDLIB_DEBUG=OFF' or using '-DLYX_EXTERNAL_BOOST=OFF'")
 670                 endif()
 671         else()
 672                 message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 673         endif()
 674 else()
 675         if(LYX_USE_STD_REGEX)
 676                 set(Lyx_Boost_Libraries boost_signals)
 677         else()
 678                 set(Lyx_Boost_Libraries boost_signals boost_regex)
 679         endif()
 680         add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 681         add_definitions(-DBOOST_SIGNALS_NO_DEPRECATION_WARNING=1)
 682         include_directories(${TOP_SRC_DIR}/boost)
 683         add_subdirectory(boost "${TOP_BINARY_DIR}/boost")
 684 endif()
 685
 686
 687
 688
 689 if(WIN32)
 690         if(NOT LYX_CONSOLE)
 691                 set(WIN32_CONSOLE WIN32)
 692                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARY})
 693         endif()
 694         if(MSVC)
 695                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 696                 # disable checked iterators for msvc release builds to get maximum speed
 697                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 698         else()
 699                 add_definitions(-DWINVER=0x0500)
 700         endif()
 701 endif()
 702
 703 # Compute qt4-version from ${QTVERSION}
 704
 705 message(STATUS "")
 706 foreach(_v PACKAGE PACKAGE_VERSION
 707         PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 708         LYX_ABS_TOP_SRCDIR
 709         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 710         if(NOT DEFINED ${_v})
 711                 message(FATAL_ERROR "${_v} not defined")
 712         endif()
 713         string(SUBSTRING "${_v}                            " 0 28 _v1)
 714         message(STATUS "----- ${_v1}: ${${_v}}")
 715 endforeach(_v)
 716 message(STATUS "")
 717
 718
 719 if(LYX_PCH)
 720         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 721         # Not sure if it works for all non-msvc compilers
 722         include(PCHSupport_26)
 723         configure_file(${TOP_CMAKE_PATH}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
 724         configure_file(${TOP_CMAKE_PATH}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 725         add_definitions(-DLYX_ENABLE_PCH)
 726
 727         if(MSVC)
 728                 macro(lyx_add_msvc_pch name_)
 729                         set_source_files_properties(${${name_}_sources} PROPERTIES
 730                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 731                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
 732                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 733                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
 734                                 ${TOP_BINARY_DIR}/pcheaders.h)
 735                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 736                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 737                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 738                 endmacro(lyx_add_msvc_pch)
 739                 macro(lyx_add_gcc_pch name_)
 740                 endmacro()
 741         else()
 742                 macro(lyx_add_msvc_pch name_)
 743                 endmacro()
 744                 macro(lyx_add_gcc_pch name_)
 745                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT)
 746                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
 747                 endmacro()
 748         endif()
 749 else()
 750         macro(lyx_add_msvc_pch)
 751         endmacro(lyx_add_msvc_pch)
 752         macro(lyx_add_gcc_pch name_)
 753         endmacro()
 754 endif()
 755
 756
 757 if(MSVC)
 758
 759         if(LYX_VLD)
 760                 set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/development/Win32/vld)
 761                 add_subdirectory(${vld_path}/cmake)
 762                 include(${vld_path}/cmake/vld.cmake) # forced include
 763                 set(vld_dll vld)
 764         endif()
 765
 766         if(LYX_WALL)
 767                 # Use the highest warning level
 768                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 769
 770                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 771                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 772                 else()
 773                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 774                 endif()
 775
 776                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 777                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 778                 else()
 779                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 780                 endif()
 781
 782                 # add here warnings which should produce an error /weXXXX
 783                 set(MSVC_W_ERROR   "/we4101 /we4189")
 784                 # add here warnings which should be disabled /wdXXXX
 785                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 786
 787                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 788                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 789                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 790
 791         else()
 792                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 793
 794                 # add here warnings which should produce an error /weXXXX
 795                 set(MSVC_W_ERROR   "/we4101 /we4189")
 796                 # add here warnings which should be disabled /wdXXXX
 797                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 798
 799                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 800                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 801                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 802
 803         endif()
 804
 805         if (NOT Qt5Core_FOUND)
 806                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 807                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 808                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 809         endif()
 810
 811         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 812         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 813         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 814         message(STATUS "")
 815 endif()
 816
 817
 818 if(LYX_DEBUG_GLIBC)
 819         set(_GLIBCXX_DEBUG ON)
 820 endif()
 821
 822 if(LYX_DEBUG_GLIBC_PEDANTIC)
 823         set(_GLIBCXX_DEBUG_PEDANTIC ON)
 824 endif()
 825
 826 # Xcode compiler
 827 if (CMAKE_GENERATOR MATCHES Xcode)
 828         if (XCODE_VERSION VERSION_LESS "5.0")
 829                 # Automatically select the Xcode compiler if not set
 830                 if (NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 831                         # XCode >= 3.1 has gcc 4.2 (up to actual Xcode)
 832                         if (XCODE_VERSION VERSION_GREATER "3.1")
 833                                 SET(CMAKE_XCODE_ATTRIBUTE_GCC_VERSION "com.apple.compilers.llvmgcc42")
 834                         ENDIF(XCODE_VERSION VERSION_GREATER "3.1")
 835                 ENDIF(NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 836                 # Print the selected compiler version
 837         MESSAGE(STATUS "---- Using XCode compiler CMAKE_XCODE_ATTRIBUTE_GCC_VERSION=${CMAKE_XCODE_ATTRIBUTE_GCC_VERSION}")
 838         ENDIF(XCODE_VERSION VERSION_LESS "5.0")
 839 ENDIF(CMAKE_GENERATOR MATCHES Xcode)
 840
 841 if (WIN32 AND Qt5Core_FOUND)
 842         set(Z_PREFIX 1)
 843 endif()
 844
 845 # compiler tests, config.h generation
 846 if(MSVC AND NOT LYX_CONFIGURE_CHECKS)
 847         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.msvc ${TOP_BINARY_DIR}/configCompiler.h)
 848 else()
 849         include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
 850         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
 851 endif()
 852
 853 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
 854
 855 if(QTVERSION MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+).*")
 856         MATH(EXPR QT4_VERSION "(${CMAKE_MATCH_1}<<16)|(${CMAKE_MATCH_2}<<8)|${CMAKE_MATCH_3}")
 857 endif()
 858
 859
 860 set (cmd ${CMAKE_CTEST_COMMAND})
 861 if (MSVC)
 862         set (cmd ${cmd} -C ${CMAKE_CFG_INTDIR})
 863 else ()
 864         set (cmd ${cmd} -C ${CMAKE_BUILD_TYPE})
 865 endif ()
 866 add_custom_target (lyx_run_tests COMMAND ${cmd})
 867 set_target_properties(lyx_run_tests PROPERTIES FOLDER "tests")
 868
 869 if(LYX_ASAN)
 870     set(LYX_CXX_FLAGS "-fsanitize=address -fno-omit-frame-pointer -g")
 871     message(STATUS)
 872     message(STATUS "Address sanitizer enabled. Usage:")
 873     message(STATUS "    wget https://llvm.org/svn/llvm-project/compiler-rt/trunk/lib/asan/scripts/asan_symbolize.py")
 874     message(STATUS "    chmod  +x ./asan_symbolize.py")
 875     message(STATUS "    ./bin/lyx2.2 2>&1 | ./asan_symbolize.py  | c++filt ")
 876     message(STATUS)
 877 endif()
 878
 879 if(LYX_INSTALL)
 880         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 881                 message(STATUS "Python required to create doc!")
 882         else()
 883                 if(UNIX)
 884                         add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
 885                 endif()
 886                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
 887         endif()
 888         include(../Install)
 889 endif()
 890
 891 add_subdirectory(src "${TOP_BINARY_DIR}/src")
 892 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
 893 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
 894 add_subdirectory(lib/examples "${TOP_BINARY_DIR}/lib/examples")
 895 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
 896 add_subdirectory(development/autotests "${TOP_BINARY_DIR}/autotests")
 897 if(LYX_ENABLE_URLTESTS)
 898         add_subdirectory(development/checkurls "${TOP_BINARY_DIR}/checkurls")
 899 endif()
 900
 901 message(STATUS)
 902 message(STATUS "Build params, switch LYX_* options by -DLYX_*=ON or OFF, LYX_* combos by -DLYX_*=value:")
 903 message(STATUS)
 904
 905 LYX_OPTION_LIST_ALL(used)
 906
 907
 908 if(LYX_NLS)
 909         message(STATUS)
 910         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
 911         message(STATUS)
 912         message(STATUS "  * iconv")
 913         message(STATUS "     - header : ${ICONV_HEADER}")
 914         message(STATUS "     - library: ${ICONV_LIBRARY}")
 915         message(STATUS "  * zlib")
 916         message(STATUS "     - header : ${ZLIB_HEADER}")
 917         message(STATUS "     - library: ${ZLIB_LIBRARY}")
 918         message(STATUS)
 919 endif()
 920
 921 # Apple has builtin native spell checker,
 922 # no need to warn for missing Aspell, Hunspell or Enchant
 923 if(NOT Spelling_FOUND AND NOT APPLE)
 924   if(LYX_REQUIRE_SPELLCHECK)
 925     set(_mode "FATAL_ERROR")
 926   else()
 927     set(_mode "STATUS")
 928   endif()
 929   message(${_mode} "No spellcheck libraries found. LyX will be unable use spellchecking")
 930 endif()
 931
 932 include("${TOP_CMAKE_PATH}/LyxPackaging.cmake")
 933
 934 if(ENABLE_DIST)
 935   # Use git to create the source package
 936   # git archive --format=tgz --output=/home/kornel/x.tar.gz master
 937   if(UNIX)
 938     set(DIST_FORMAT tgz)
 939   else()
 940     set(DIST_FORMAT zip)
 941   endif()
 942   set(DIST_NAME ${CMAKE_PROJECT_NAME}-${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}-${CMAKE_SYSTEM_NAME}.${DIST_FORMAT})
 943
 944   add_custom_command(
 945     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME}
 946     COMMAND  ${LYX_GITVERSION} archive --format=${DIST_FORMAT} --output=${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME} master
 947     WORKING_DIRECTORY ${TOP_SRC_DIR})
 948   add_custom_target(git-archive DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME})
 949 endif()
 950
 951 # Last directory to be included so that the fixup code (OS X)
 952 # can be run last
 953 add_subdirectory(development/cmake/post_install)
 954
 955 message(STATUS)