CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 2.6.4)
   8
   9 set(LYX_PROJECT LyX)
  10
  11 enable_testing()
  12
  13 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README ABSOLUTE)
  14 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  15
  16 set(LYX_CMAKE_DIR "development/cmake")
  17 set(TOP_CMAKE_PATH "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}")
  18 set(TOP_MODULE_PATH "${TOP_CMAKE_PATH}/modules")
  19 set(TOP_SCRIPT_PATH "${TOP_CMAKE_PATH}/scripts")
  20
  21 set(CMAKE_MODULE_PATH "${TOP_MODULE_PATH}")
  22
  23 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  24
  25 message(STATUS)
  26 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  27         message(STATUS "Building in-source")
  28         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  29 else()
  30         message(STATUS "Building out-of-source")
  31         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  32 endif()
  33
  34 # This directory should be used if some test uses lyx-executable
  35 set(LYX_TESTS_USERDIR "${TOP_BINARY_DIR}/Testing/.lyx")
  36 file(MAKE_DIRECTORY "${LYX_TESTS_USERDIR}")
  37
  38 if(COMMAND cmake_policy)
  39         cmake_policy(SET CMP0003 OLD)
  40         cmake_policy(SET CMP0005 OLD)
  41         # Installing MACOSX_BUNDLE targets requires a BUNDLE DESTINATION
  42         cmake_policy(SET CMP0006 NEW)
  43         if(POLICY CMP0028)
  44                 cmake_policy(SET CMP0028 OLD)
  45         endif()
  46         if(POLICY CMP0043)
  47                 # COMPILE_DEFINITIONS are not used yet. Enable new behavior.
  48                 cmake_policy(SET CMP0043 NEW)
  49         endif()
  50         cmake_policy(SET CMP0020 OLD)
  51 endif()
  52
  53 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  54
  55 # Supress regeneration
  56 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  57
  58 if(LYX_XMINGW)
  59     set(CMAKE_SYSTEM_NAME Windows)
  60     set(TOOLNAME ${LYX_XMINGW})
  61     set(TOOLCHAIN "${TOOLNAME}-")
  62     set(CMAKE_C_COMPILER   "${TOOLCHAIN}gcc"     CACHE PATH "Mingw C compiler" FORCE)
  63     set(CMAKE_CXX_COMPILER "${TOOLCHAIN}g++"     CACHE PATH "Mingw C++ compiler" FORCE)
  64     set(CMAKE_RC_COMPILER  "${TOOLCHAIN}windres" CACHE PATH "Mingw rc compiler" FORCE)
  65
  66     set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM BOTH)
  67     set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY)
  68     set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY)
  69 endif()
  70
  71 if(NOT help AND NOT HELP)
  72   # 'project' triggers the searching for a compiler
  73   project(${LYX_PROJECT})
  74   if (CMAKE_COMPILER_IS_GNUCXX)
  75     if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS "4.0")
  76       message(STATUS "Gnu CXX compiler version = ${CMAKE_CXX_COMPILER_VERSION}")
  77       message(STATUS "is too old, should be >= 4.0")
  78       message(FATAL_ERROR "Exiting")
  79     endif()
  80   endif()
  81 endif()
  82
  83 if(UNIX)
  84         set(ARCH_TRIPLET )
  85         FIND_PROGRAM(DPKG_ARCHITECTURE_EXECUTABLE dpkg-architecture)
  86         if(DPKG_ARCHITECTURE_EXECUTABLE)
  87                 EXECUTE_PROCESS(COMMAND ${DPKG_ARCHITECTURE_EXECUTABLE} -qDEB_HOST_MULTIARCH
  88                                 OUTPUT_VARIABLE ARCH_TRIPLET
  89                                 ERROR_VARIABLE ERROR_ARCH_TRIPLET
  90                                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  91         endif()
  92 endif()
  93 if(ARCH_TRIPLET)
  94         set(SYSTEM_LIB_DIRS /usr/lib /usr/lib/${ARCH_TRIPLET} /usr/local/lib)
  95 else()
  96         set(SYSTEM_LIB_DIRS /usr/lib /usr/local/lib)
  97 endif()
  98
  99 include(LyXMacros)
 100
 101 # Usage LYX_OPTION
 102 # 1. parameter: option name without prefix 'LYX_'
 103 # 2. parameter: description
 104 # 3. parameter: default value, ON or OFF
 105 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
 106
 107 # Usage LYX_COMBO
 108 # 1. parameter: name without prefix 'LYX_'
 109 # 2. parameter: description
 110 # 3. parameter: default value
 111 # 4-n parameter: possible other string values
 112
 113 LYX_OPTION_INIT()
 114
 115 # Options for all compilers/systems
 116 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
 117 LYX_OPTION(LOCALVERSIONING  "Add version info to created package name (only used if LYX_CPACK option set)" OFF ALL)
 118 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
 119 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
 120 LYX_OPTION(REQUIRE_SPELLCHECK "Abort if no spellchecker available" OFF ALL)
 121 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
 122 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
 123 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
 124 LYX_OPTION(DEVEL_VERSION    "Build developer version" OFF ALL)
 125 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" OFF ALL)
 126 LYX_OPTION(DEBUG            "Enforce debug build"  OFF ALL)
 127 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
 128 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
 129 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
 130 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
 131 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
 132 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
 133 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
 134 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
 135 LYX_OPTION(ENABLE_URLTESTS  "Enable for URL tests" OFF ALL)
 136 LYX_OPTION(ENABLE_EXPORT_TESTS "Enable for export tests" OFF ALL)
 137 LYX_OPTION(ASAN             "Use address sanitizer" OFF ALL)
 138 LYX_COMBO(USE_QT            "Use Qt version as frontend" QT4 QT5)
 139
 140 # GCC specific
 141 LYX_OPTION(PROFILE              "Build profile version" OFF GCC)
 142 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" OFF GCC)
 143 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
 144 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
 145 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++ pedantic debug mode" OFF GCC)
 146 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" OFF GCC)
 147 LYX_OPTION(PROFILE              "Build with options for gprof" OFF GCC)
 148 LYX_OPTION(ENABLE_CXX11         "Build with options for c++11-mode" OFF GCC)
 149
 150 # MSVC specific
 151 LYX_OPTION(CONSOLE               "Show console on Windows, enforce with =FORCE" ON MSVC)
 152 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
 153 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
 154 LYX_OPTION(CONFIGURE_CHECKS      "Also run configure checks for MSVC" OFF MSVC)
 155 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
 156
 157 # APPLE specific
 158 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
 159 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
 160
 161
 162 if(help OR HELP)
 163         message(STATUS)
 164         message(STATUS "Available options: (dis/enable with -DLYX_*=OFF/ON)")
 165         message(STATUS)
 166         LYX_OPTION_LIST_ALL(help)
 167         message(STATUS)
 168         RETURN()
 169 endif()
 170
 171 # Check option dependencies
 172
 173 if(LYX_DMG)
 174         set(LYX_BUNDLE ON)
 175         set(LYX_CPACK ON)
 176 endif()
 177
 178 if(LYX_CPACK)
 179         set(LYX_INSTALL ON)
 180 endif()
 181
 182 if(LYX_INSTALL)
 183         set(LYX_NLS ON)
 184         if(WIN32 AND NOT MINGW)
 185                 set(LYX_HUNSPELL ON)
 186         endif()
 187         if(LYX_CONSOLE MATCHES "FORCE")
 188                 set(LYX_CONSOLE ON)
 189         else()
 190                 set(LYX_CONSOLE OFF)
 191         endif()
 192         set(LYX_PACKAGE_SUFFIX ON)
 193         if(NOT LYX_DEBUG)
 194                 set(LYX_RELEASE ON)
 195         endif()
 196         set(LYX_PROFILE OFF)
 197 endif()
 198
 199
 200 if(LYX_MERGE_FILES)
 201         set(LYX_PCH OFF)
 202 else()
 203         set(LYX_MERGE_REBUILD OFF)
 204 endif()
 205
 206
 207 if(LYX_DEPENDENCIES_DOWNLOAD)
 208         message(STATUS)
 209         set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 210         message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 211         set(deps_files lyx20-deps-msvc2010-x86.zip)
 212         set(deps_server http://downloads.sourceforge.net/project/lyx/Win_installers/Dependencies)
 213         foreach(it ${deps_files})
 214                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 215                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 216                 if(NOT already_downloaded)
 217                         message(STATUS "Downloading ${it} ...")
 218                         file(DOWNLOAD ${deps_server}/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS STATUS status LOG log)
 219                         list(GET status 0 status_code)
 220                         list(GET status 1 status_string)
 221                         if(NOT status_code EQUAL 0)
 222                                 file(REMOVE ${LYX_DEPENDENCIES_DIR}/${it})
 223                                 message(FATAL_ERROR "error: downloading '${it}' failed. status_code: ${status_code}, status_string: ${status_string}. \nLog: ${log} ")
 224                         endif()
 225                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 226                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 227                 endif()
 228         endforeach()
 229         set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/deps20)
 230     if(MSVC12)
 231         # handle error in msvc12 when linking against msvc10 libs
 232         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /vd2")
 233     endif()
 234 endif()
 235
 236
 237
 238 message(STATUS)
 239
 240 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 241 if(WIN32)
 242         set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 243 else()
 244         set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 245 endif()
 246
 247
 248 set(LYX_GCC11_MODE)
 249 if(UNIX OR MINGW)
 250         execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION OUTPUT_STRIP_TRAILING_WHITESPACE)
 251         message(STATUS "Using GCC version ${GCC_VERSION}")
 252         if(GCC_VERSION VERSION_LESS 4.9)
 253                 # <regex> in gcc is unusable in versions less than 4.9.0
 254                 # see https://gcc.gnu.org/bugzilla/show_bug.cgi?id=53631
 255                 set(LYX_USE_STD_REGEX 0)
 256         endif()
 257         if (LYX_ENABLE_CXX11)
 258                 find_package(CXX11Compiler)
 259                 if(NOT CXX11COMPILER_FOUND)
 260                         message(FATAL_ERROR "A C++11 compatible compiler is required.")
 261                 endif()
 262                 set(LYX_GCC11_MODE "${CXX11_FLAG}")
 263         endif()
 264 else()
 265         set(LYX_USE_STD_REGEX 0)
 266 #       if(MSVC10)
 267 #               set(LYX_USE_STD_REGEX 1) #TODO should we use it in ECMAScript mode?
 268 #       endif()
 269 endif()
 270
 271
 272 set(VERSION_INFO "CMake Build")
 273
 274 # Try to get some informations from configure.ac
 275
 276 include(LyXPaths)
 277 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 278
 279 if(WIN32)
 280         set(USE_WINDOWS_PACKAGING ON)
 281 elseif(APPLE)
 282         set(USE_MACOSX_PACKAGING ON)
 283 else()
 284         set(USE_POSIX_PACKAGING ON)
 285 endif()
 286
 287 macro(setstripped _varname)
 288         if(${ARGC} GREATER 1)
 289                 string(STRIP "${ARGV1}" _v)
 290                 if(USE_POSIX_PACKAGING)
 291                         string(TOLOWER ${_v} ${_varname})
 292                 else()
 293                         set(${_varname} ${_v})
 294                 endif()
 295         else()
 296                 set(${_varname})
 297         endif()
 298 endmacro(setstripped)
 299
 300 foreach(_c_l ${_config_lines} )
 301         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 302                 setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 303                 setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 304                 setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 305                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\)\(\\.\([0-9]+\)\)?.*$")
 306                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 307                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 308                         set(LYX_PATCH_VERSION ${CMAKE_MATCH_4})
 309                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 310                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 311                         set(LYX_INSTALL_SUFFIX "${CMAKE_MATCH_1}.${CMAKE_MATCH_2}")
 312                 endif()
 313         endif()
 314         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 315                 set(LYX_DATE "${CMAKE_MATCH_1}")
 316         endif()
 317 endforeach(_c_l)
 318
 319 FIND_PROGRAM(LYX_GITVERSION git)
 320 #message(STATUS "gitversion = ${LYX_GITVERSION}")
 321 set(LYX_REVISION_VERSION ${LYX_PATCH_VERSION})
 322 if(LYX_GITVERSION)
 323   if (LYX_LOCALVERSIONING)
 324     # Find the revision number and for later use
 325     EXECUTE_PROCESS(COMMAND ${LYX_GITVERSION} describe --match 2.0.0 HEAD
 326       WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE LYX_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 327     if (LYX_PACKAGE_RELEASE MATCHES "^2\\.0\\.0\\-\([0-9]+\)\\-.*$")
 328       # We will add offset of 40000 to get appropriate value to
 329       # previous svn.
 330       # We use this value than also to set the package-patch-value
 331       MATH(EXPR tmp_REVISION_VERSION "(${CMAKE_MATCH_1}+40000)")
 332       set(LYX_REVISION_VERSION "${LYX_PATCH_VERSION}-${tmp_REVISION_VERSION}git")
 333       set(ENABLE_DIST ON)
 334     endif()
 335   endif()
 336 endif()
 337
 338 # Set the programs (lyx, tex2lyx, etc.) suffix
 339 # When building an OS X bundle, we will append
 340 # the suffix only to the bundle, not to the programs
 341 set(PROGRAM_SUFFIX "")
 342 if(LYX_PROGRAM_SUFFIX AND NOT (APPLE AND LYX_BUNDLE))
 343         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 344 endif()
 345 set(_lyx "${PACKAGE_BASE}${PROGRAM_SUFFIX}")
 346 set(_tex2lyx tex2lyx${PROGRAM_SUFFIX})
 347
 348 add_custom_target(lyx_version ALL
 349   COMMAND ${CMAKE_COMMAND} -DTOP_SRC_DIR=${TOP_SRC_DIR} -DTOP_CMAKE_PATH=${TOP_CMAKE_PATH} -DTOP_BINARY_DIR=${TOP_BINARY_DIR} -DLYX_DATE=${LYX_DATE} -P ${TOP_SCRIPT_PATH}/LyXGetVersion.cmake
 350   )
 351 set_target_properties(lyx_version PROPERTIES FOLDER "applications")
 352
 353 # Default paths for installed utilities (tex2lyx, lyxclient, etc.)
 354 set(LYX_UTILITIES_INSTALL_PATH bin)
 355
 356 if(LYX_BUNDLE)
 357         set(LYX_CPACK ON)
 358
 359         message(STATUS)
 360         message(STATUS "Bundle creation is enabled (experimental):")
 361         message(STATUS "    make")
 362         message(STATUS "    make install/strip")
 363         message(STATUS "    make package")
 364         if(APPLE)
 365                 set(MACOSX_BUNDLE TRUE)
 366                 # This sets the bundle + executable names
 367                 set(_lyx "${PACKAGE_BASE}${LYX_INSTALL_SUFFIX}")
 368                 # This sets the Info.plist executable name
 369                 set(osx_bundle_program_name ${_lyx})
 370                 # Bundle name
 371                 set(LYX_BUNDLE_NAME ${_lyx})
 372
 373                 # This will contain the list of files that need to be included
 374                 # in the bundle and their location within the bundle
 375                 set(OSX_BUNDLE_FILES "${TOP_SRC_DIR}/development/MacOSX/LyX.sdef;${TOP_SRC_DIR}/development/MacOSX/LyXapp.icns;${CMAKE_BINARY_DIR}/lyxrc.dist")
 376                 set(OSX_BUNDLE_DIRS "Resources;Resources;Resources")
 377
 378                 # Process Info.plist and lyxrc.dist
 379                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/Info.plist.in" "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 380                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/lyxrc.dist.in" "${CMAKE_CURRENT_BINARY_DIR}/lyxrc.dist")
 381
 382                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 383                 set(LYX_DATA_SUBDIR ${LYX_BUNDLE_NAME}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 384
 385                 # Variables used by CPack
 386                 set(CPACK_BUNDLE_NAME ${LYX_BUNDLE_NAME})
 387                 set(CPACK_BUNDLE_PLIST "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 388                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${LYX_BUNDLE_NAME}.app)
 389
 390                 # Set the install paths
 391                 set(LYX_UTILITIES_INSTALL_PATH ${LYX_BUNDLE_NAME}.app/Contents/MacOS)
 392                 if(NOT LYX_INSTALL_PREFIX)
 393                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 394                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 395                 endif()
 396                 # Change the owner so that the install can work
 397                 install(CODE "set(BU_CHMOD_BUNDLE_ITEMS 1)" COMPONENT Runtime)
 398         elseif(UNIX)
 399                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 400                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 401                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 402         elseif(WIN32)
 403                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 404         endif()
 405 endif()
 406
 407 if(LYX_INSTALL_PREFIX)
 408         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 409         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 410 endif()
 411 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 412
 413 string(REGEX REPLACE "/lyx${LYX_INSTALL_SUFFIX}$" "/share" SYSTEM_DATADIR ${CMAKE_INSTALL_PREFIX})
 414
 415 if(LYX_PACKAGE_SUFFIX)
 416         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 417 else()
 418         set(PACKAGE ${PACKAGE_BASE})
 419 endif()
 420
 421 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 422         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 423         if (UNIX)
 424                 # don't use the default "/usr/local"
 425                 # but respect the user-choice on the command-line
 426                 if(LYX_INSTALL_SUFFIX)
 427                         set(CMAKE_INSTALL_PREFIX "/usr/local/lyx${LYX_INSTALL_SUFFIX}" CACHE PATH "LyX default install prefix" FORCE)
 428                 else()
 429                         set(CMAKE_INSTALL_PREFIX "/usr/local/${LYX_PROJECT}" CACHE PATH "LyX default install prefix" FORCE)
 430                 endif()
 431         endif()
 432         if(WIN32)
 433                 set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 434         endif()
 435 endif()
 436 if(IS_ABSOLUTE)
 437         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 438 else()
 439         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 440 endif()
 441
 442
 443
 444 if(NOT LYX_DATA_SUBDIR)
 445         if (WIN32)
 446                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 447         else()
 448                 set(LYX_DATA_SUBDIR "" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 449         endif()
 450 endif()
 451
 452 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 453 set(LYX_LOCALEDIR "locale")
 454 set(LYX_ABS_INSTALLED_LOCALEDIR "${LYX_ABS_INSTALLED_DATADIR}/${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}")
 455 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 456
 457 if(LYX_BUNDLE AND APPLE)
 458         set(LYX_MAN_DIR "${LYX_DATA_SUBDIR}" CACHE STRING "Install location for man pages.")
 459 else()
 460         set(LYX_MAN_DIR "/usr/local/man/man1" CACHE STRING "Install location for man pages.")
 461 endif()
 462 mark_as_advanced(LYX_MAN_DIR)
 463
 464 if(LYX_INSTALL AND WIN32)
 465         message(STATUS "Configuring NSIS files")
 466         configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 467         configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 468         configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 469         message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 470 endif()
 471
 472 if(NOT GROUP_CODE)
 473         #set(GROUP_CODE "The Golden Code")
 474         set(GROUP_CODE flat)
 475 endif()
 476
 477 # lyx's source files
 478 set(LYX_CPP_FILES [a-zA-Z]*.cpp)
 479 set(LYX_HPP_FILES [a-zA-Z]*.h)
 480 set(LYX_MOC_FILES moc_*.cpp)
 481
 482 include(ProjectSourceGroup)
 483
 484
 485 if(LYX_PROFILE AND NOT MSVC)
 486         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 487         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg")
 488         set(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS}  -pg")
 489 else()
 490         set(LYX_PROFILE OFF)
 491 endif()
 492
 493
 494 if(LYX_NO_OPTIMIZE)
 495         set(CMAKE_BUILD_TYPE None)
 496         set(LYX_DEBUG OFF)
 497         set(LYX_RELEASE OFF)
 498         set(LYX_PROFILE OFF)
 499 elseif(LYX_RELEASE)
 500         set(CMAKE_BUILD_TYPE Release)
 501         set(LYX_DEBUG OFF)
 502         set(LYX_PROFILE OFF)
 503 elseif(LYX_PROFILE)
 504         set(CMAKE_BUILD_TYPE Profile)
 505         set(LYX_DEBUG OFF)
 506 else()
 507         set(CMAKE_BUILD_TYPE Debug)
 508         set(LYX_DEBUG ON)
 509 endif()
 510
 511
 512 # When shared libs are supported enable this option
 513 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 514 if(LYX_SHARED_LIBRARIES)
 515         set(library_type SHARED)
 516 else()
 517         set(library_type STATIC)
 518 endif()
 519
 520 if(NOT MSVC)
 521         if(NOT LYX_QUIET)
 522                 set(CMAKE_VERBOSE_MAKEFILE ON)
 523         endif()
 524     set(LYX_CXX_FLAGS "-Wall -Wunused-parameter ${LYX_GCC11_MODE}")
 525         if(LYX_STDLIB_DEBUG)
 526                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 527         endif()
 528         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 529         set(CMAKE_CXX_FLAGS_DEBUG "${LYX_CXX_FLAGS} -fno-strict-aliasing -O0 -g3 -D_DEBUG" CACHE TYPE STRING FORCE)
 530         if(MINGW)
 531                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 532         else()
 533                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 534         endif()
 535 endif()
 536
 537 set(LYX_CXX_FLAGS_EXTRA "" CACHE STRING "Desired semicolon separated list of extra cxx compile flags, like '-Werror'")
 538 mark_as_advanced(LYX_CXX_FLAGS_EXTRA)
 539 if(LYX_CXX_FLAGS_EXTRA)
 540         foreach(_flag ${LYX_CXX_FLAGS_EXTRA})
 541                 add_definitions(${_flag})
 542         endforeach()
 543 endif()
 544
 545 if(LYX_XMINGW)
 546         list(APPEND CMAKE_FIND_ROOT_PATH ${GNUWIN32_DIR})
 547 endif()
 548
 549 if(LYX_USE_QT MATCHES "QT5")
 550         find_package(Qt5Core REQUIRED)
 551         if (Qt5Core_FOUND)
 552                 find_package(Qt5Widgets REQUIRED)
 553                 if(APPLE)
 554                         find_package(Qt5MacExtras REQUIRED)
 555                 endif()
 556                 find_package(Qt5X11Extras QUIET)
 557                 find_package(Qt5WinExtras QUIET)
 558                 set(QTVERSION ${Qt5Core_VERSION})
 559                 macro (qt_use_modules)
 560                         qt5_use_modules(${ARGN})
 561                 endmacro()
 562                 macro (qt_add_resources)
 563                         qt5_add_resources(${ARGN})
 564                 endmacro()
 565                 macro (qt_wrap_uifiles)
 566                         qt5_wrap_ui(${ARGN})
 567                 endmacro()
 568                 message(STATUS "Found Qt-Version ${QTVERSION}")
 569         endif()
 570 elseif(LYX_USE_QT MATCHES "QT4")
 571         if(LYX_XMINGW)
 572                 set(QT_MINGW_DIR ${LYX_QT4} CACHE PATH "Qt for Mingw" FORCE)
 573                 list(APPEND CMAKE_FIND_ROOT_PATH ${QT_MINGW_DIR} ${GNUWIN32_DIR})
 574         endif()
 575         find_package(Qt4 "4.5.0" REQUIRED)
 576         macro (qt_use_modules)
 577         endmacro()
 578         macro (qt_add_resources)
 579                 qt4_add_resources(${ARGN})
 580         endmacro()
 581         macro (qt_wrap_uifiles)
 582                 qt4_wrap_ui(${ARGN})
 583         endmacro()
 584 else()
 585   message(FATAL_ERROR "Unhandled value for LYX_USE_QT (${LYX_USE_QT})")
 586 endif()
 587
 588 find_package(Magic)
 589 if(Magic_FOUND)
 590         set(HAVE_MAGIC_H 1)
 591 endif()
 592
 593 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 594
 595 set(Spelling_FOUND OFF)
 596 set(Include_used_spellchecker)   # String will be inserted into config.h
 597
 598 foreach(_spell "ASPELL" "Enchant" "Hunspell")
 599   string(TOUPPER ${_spell} _upspell)
 600   find_package(${_spell})
 601   if (${_upspell}_FOUND)
 602     include_directories(${${_upspell}_INCLUDE_DIR})
 603     set(Spelling_FOUND ON)
 604     message(STATUS "Building with USE_${_upspell}")
 605     set(Include_used_spellchecker "${Include_used_spellchecker}#define USE_${_upspell} 1\n")
 606   else()
 607     if(LYX_${_upspell})
 608       message(FATAL_ERROR "Required ${_spell} devel package not found")
 609     else()
 610       message(STATUS "${_upspell} not found, building without ${_spell} support")
 611     endif()
 612   endif()
 613 endforeach()
 614
 615 find_package(PythonInterp 2.7 QUIET)
 616 if(PYTHONINTERP_FOUND)
 617   if(PYTHON_VERSION_STRING VERSION_GREATER 2.8)
 618     unset(PYTHONINTERP_FOUND)
 619   endif()
 620 endif()
 621
 622 if (NOT PYTHONINTERP_FOUND)
 623   unset(PYTHON_EXECUTABLE CACHE)
 624   unset(PYTHON_VERSION_MAJOR)
 625   unset(PYTHON_VERSION_MINOR)
 626   unset(PYTHON_VERSION_STRING)
 627   find_package(PythonInterp 3.3 REQUIRED)
 628 endif()
 629
 630 set(LYX_PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 631
 632 if(LYX_NLS)
 633         find_package(LyXGettext)
 634         if(LYX_PYTHON_EXECUTABLE AND GETTEXT_FOUND)
 635                 add_subdirectory(po "${TOP_BINARY_DIR}/po")
 636         else()
 637                 # Install only supplied .gmo-files
 638                 file(GLOB _gmofiles RELATIVE "${TOP_SRC_DIR}/po" "${TOP_SRC_DIR}/po/*.gmo")
 639                 message(STATUS "Installing provided .gmo-files only")
 640                 foreach( _gmo ${_gmofiles})
 641                         string(REGEX REPLACE "\\.gmo$" "" _lang ${_gmo})
 642                         install(FILES "${TOP_SRC_DIR}/po/${_gmo}" DESTINATION ${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}/${_lang}/LC_MESSAGES RENAME ${PACKAGE}.mo)
 643                 endforeach()
 644         endif()
 645 endif()
 646
 647
 648 find_package(ICONV REQUIRED)
 649 find_package(ZLIB REQUIRED)
 650
 651 if(LYX_EXTERNAL_BOOST)
 652         message(STATUS "Searching for boost")
 653         if(LYX_USE_STD_REGEX)
 654                 find_package(Boost COMPONENTS signals)
 655         else()
 656                 find_package(Boost COMPONENTS signals regex)
 657         endif()
 658         if(Boost_FOUND)
 659                 message(STATUS "Boost found")
 660                 message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 661                 set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 662                 if (LYX_STDLIB_DEBUG)
 663                         # Comment from  Jean-Marc Lasgouttes:
 664                         # In general, system boost libraries are incompatible with
 665                         # the use of stdlib-debug in libstdc++. See ticket #9736 for
 666                         # details.
 667                         message(WARNING "Compiling LyX with stdlib-debug and system boost libraries may lead to crashes. Consider using '-DLYX_STDLIB_DEBUG=OFF' or using '-DLYX_EXTERNAL_BOOST=OFF'")
 668                 endif()
 669         else()
 670                 message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 671         endif()
 672 else()
 673         if(LYX_USE_STD_REGEX)
 674                 set(Lyx_Boost_Libraries boost_signals)
 675         else()
 676                 set(Lyx_Boost_Libraries boost_signals boost_regex)
 677         endif()
 678         add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 679         add_definitions(-DBOOST_SIGNALS_NO_DEPRECATION_WARNING=1)
 680         include_directories(${TOP_SRC_DIR}/boost)
 681         add_subdirectory(boost "${TOP_BINARY_DIR}/boost")
 682 endif()
 683
 684
 685
 686
 687 if(WIN32)
 688         if(NOT LYX_CONSOLE)
 689                 set(WIN32_CONSOLE WIN32)
 690                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARY})
 691         endif()
 692         if(MSVC)
 693                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 694                 # disable checked iterators for msvc release builds to get maximum speed
 695                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 696         else()
 697                 add_definitions(-DWINVER=0x0500)
 698         endif()
 699 endif()
 700
 701 # Compute qt4-version from ${QTVERSION}
 702
 703 message(STATUS "")
 704 foreach(_v PACKAGE PACKAGE_VERSION
 705         PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 706         LYX_ABS_TOP_SRCDIR
 707         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 708         if(NOT DEFINED ${_v})
 709                 message(FATAL_ERROR "${_v} not defined")
 710         endif()
 711         string(SUBSTRING "${_v}                            " 0 28 _v1)
 712         message(STATUS "----- ${_v1}: ${${_v}}")
 713 endforeach(_v)
 714 message(STATUS "")
 715
 716
 717 if(LYX_PCH)
 718         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 719         # Not sure if it works for all non-msvc compilers
 720         include(PCHSupport_26)
 721         configure_file(${TOP_CMAKE_PATH}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
 722         configure_file(${TOP_CMAKE_PATH}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 723         add_definitions(-DLYX_ENABLE_PCH)
 724
 725         if(MSVC)
 726                 macro(lyx_add_msvc_pch name_)
 727                         set_source_files_properties(${${name_}_sources} PROPERTIES
 728                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 729                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
 730                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 731                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
 732                                 ${TOP_BINARY_DIR}/pcheaders.h)
 733                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 734                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 735                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 736                 endmacro(lyx_add_msvc_pch)
 737                 macro(lyx_add_gcc_pch name_)
 738                 endmacro()
 739         else()
 740                 macro(lyx_add_msvc_pch name_)
 741                 endmacro()
 742                 macro(lyx_add_gcc_pch name_)
 743                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT)
 744                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
 745                 endmacro()
 746         endif()
 747 else()
 748         macro(lyx_add_msvc_pch)
 749         endmacro(lyx_add_msvc_pch)
 750         macro(lyx_add_gcc_pch name_)
 751         endmacro()
 752 endif()
 753
 754
 755 if(MSVC)
 756
 757         if(LYX_VLD)
 758                 set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/development/Win32/vld)
 759                 add_subdirectory(${vld_path}/cmake)
 760                 include(${vld_path}/cmake/vld.cmake) # forced include
 761                 set(vld_dll vld)
 762         endif()
 763
 764         if(LYX_WALL)
 765                 # Use the highest warning level
 766                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 767
 768                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 769                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 770                 else()
 771                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 772                 endif()
 773
 774                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 775                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 776                 else()
 777                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 778                 endif()
 779
 780                 # add here warnings which should produce an error /weXXXX
 781                 set(MSVC_W_ERROR   "/we4101 /we4189")
 782                 # add here warnings which should be disabled /wdXXXX
 783                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 784
 785                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 786                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 787                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 788
 789         else()
 790                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 791
 792                 # add here warnings which should produce an error /weXXXX
 793                 set(MSVC_W_ERROR   "/we4101 /we4189")
 794                 # add here warnings which should be disabled /wdXXXX
 795                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 796
 797                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 798                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 799                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 800
 801         endif()
 802
 803         if (NOT Qt5Core_FOUND)
 804                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 805                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 806                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 807         endif()
 808
 809         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 810         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 811         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 812         message(STATUS "")
 813 endif()
 814
 815
 816 if(LYX_DEBUG_GLIBC)
 817         set(_GLIBCXX_DEBUG ON)
 818 endif()
 819
 820 if(LYX_DEBUG_GLIBC_PEDANTIC)
 821         set(_GLIBCXX_DEBUG_PEDANTIC ON)
 822 endif()
 823
 824 # Xcode compiler
 825 if (CMAKE_GENERATOR MATCHES Xcode)
 826         if (XCODE_VERSION VERSION_LESS "5.0")
 827                 # Automatically select the Xcode compiler if not set
 828                 if (NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 829                         # XCode >= 3.1 has gcc 4.2 (up to actual Xcode)
 830                         if (XCODE_VERSION VERSION_GREATER "3.1")
 831                                 SET(CMAKE_XCODE_ATTRIBUTE_GCC_VERSION "com.apple.compilers.llvmgcc42")
 832                         ENDIF(XCODE_VERSION VERSION_GREATER "3.1")
 833                 ENDIF(NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 834                 # Print the selected compiler version
 835         MESSAGE(STATUS "---- Using XCode compiler CMAKE_XCODE_ATTRIBUTE_GCC_VERSION=${CMAKE_XCODE_ATTRIBUTE_GCC_VERSION}")
 836         ENDIF(XCODE_VERSION VERSION_LESS "5.0")
 837 ENDIF(CMAKE_GENERATOR MATCHES Xcode)
 838
 839 if (WIN32 AND Qt5Core_FOUND)
 840         set(Z_PREFIX 1)
 841 endif()
 842
 843 # compiler tests, config.h generation
 844 if(MSVC AND NOT LYX_CONFIGURE_CHECKS)
 845         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.msvc ${TOP_BINARY_DIR}/configCompiler.h)
 846 else()
 847         include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
 848         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
 849 endif()
 850
 851 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
 852
 853 if(QTVERSION MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+).*")
 854         MATH(EXPR QT4_VERSION "(${CMAKE_MATCH_1}<<16)|(${CMAKE_MATCH_2}<<8)|${CMAKE_MATCH_3}")
 855 endif()
 856
 857
 858 set (cmd ${CMAKE_CTEST_COMMAND})
 859 if (MSVC)
 860         set (cmd ${cmd} -C ${CMAKE_CFG_INTDIR})
 861 else ()
 862         set (cmd ${cmd} -C ${CMAKE_BUILD_TYPE})
 863 endif ()
 864 add_custom_target (lyx_run_tests COMMAND ${cmd})
 865 set_target_properties(lyx_run_tests PROPERTIES FOLDER "tests")
 866
 867 if(LYX_ASAN)
 868     set(LYX_CXX_FLAGS "-fsanitize=address -fno-omit-frame-pointer -g")
 869     message(STATUS)
 870     message(STATUS "Address sanitizer enabled. Usage:")
 871     message(STATUS "    wget https://llvm.org/svn/llvm-project/compiler-rt/trunk/lib/asan/scripts/asan_symbolize.py")
 872     message(STATUS "    chmod  +x ./asan_symbolize.py")
 873     message(STATUS "    ./bin/lyx2.2 2>&1 | ./asan_symbolize.py  | c++filt ")
 874     message(STATUS)
 875 endif()
 876
 877 if(LYX_INSTALL)
 878         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 879                 message(STATUS "Python required to create doc!")
 880         else()
 881                 if(UNIX)
 882                         add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
 883                 endif()
 884                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
 885         endif()
 886         include(../Install)
 887 endif()
 888
 889 add_subdirectory(src "${TOP_BINARY_DIR}/src")
 890 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
 891 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
 892 add_subdirectory(lib/examples "${TOP_BINARY_DIR}/lib/examples")
 893 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
 894 add_subdirectory(development/autotests "${TOP_BINARY_DIR}/autotests")
 895 if(LYX_ENABLE_URLTESTS)
 896         add_subdirectory(development/checkurls "${TOP_BINARY_DIR}/checkurls")
 897 endif()
 898
 899 message(STATUS)
 900 message(STATUS "Build params, switch LYX_* options by -DLYX_*=ON or OFF, LYX_* combos by -DLYX_*=value:")
 901 message(STATUS)
 902
 903 LYX_OPTION_LIST_ALL(used)
 904
 905
 906 if(LYX_NLS)
 907         message(STATUS)
 908         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
 909         message(STATUS)
 910         message(STATUS "  * iconv")
 911         message(STATUS "     - header : ${ICONV_HEADER}")
 912         message(STATUS "     - library: ${ICONV_LIBRARY}")
 913         message(STATUS "  * zlib")
 914         message(STATUS "     - header : ${ZLIB_HEADER}")
 915         message(STATUS "     - library: ${ZLIB_LIBRARY}")
 916         message(STATUS)
 917 endif()
 918
 919 # Apple has builtin native spell checker,
 920 # no need to warn for missing Aspell, Hunspell or Enchant
 921 if(NOT Spelling_FOUND AND NOT APPLE)
 922   if(LYX_REQUIRE_SPELLCHECK)
 923     set(_mode "FATAL_ERROR")
 924   else()
 925     set(_mode "STATUS")
 926   endif()
 927   message(${_mode} "No spellcheck libraries found. LyX will be unable use spellchecking")
 928 endif()
 929
 930 include("${TOP_CMAKE_PATH}/LyxPackaging.cmake")
 931
 932 if(ENABLE_DIST)
 933   # Use git to create the source package
 934   # git archive --format=tgz --output=/home/kornel/x.tar.gz master
 935   if(UNIX)
 936     set(DIST_FORMAT tgz)
 937   else()
 938     set(DIST_FORMAT zip)
 939   endif()
 940   set(DIST_NAME ${CMAKE_PROJECT_NAME}-${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}-${CMAKE_SYSTEM_NAME}.${DIST_FORMAT})
 941
 942   add_custom_command(
 943     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME}
 944     COMMAND  ${LYX_GITVERSION} archive --format=${DIST_FORMAT} --output=${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME} master
 945     WORKING_DIRECTORY ${TOP_SRC_DIR})
 946   add_custom_target(git-archive DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME})
 947 endif()
 948
 949 # Last directory to be included so that the fixup code (OS X)
 950 # can be run last
 951 add_subdirectory(development/cmake/post_install)
 952
 953 message(STATUS)