CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 3.1.0)
   8
   9 set(LYX_PROJECT LyX)
  10
  11 # Instruct cmake to not use gnu extensions,
  12 # this prevents the mix of '-std=c++*' and '-std=gnu++*' flags
  13 set(CMAKE_CXX_EXTENSIONS OFF)
  14
  15 enable_testing()
  16
  17 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README REALPATH) # Resolve symlinks
  18 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  19 message(STATUS "TOP_SRC_DIR = ${TOP_SRC_DIR}")
  20
  21 set(LYX_CMAKE_DIR "development/cmake")
  22 set(TOP_CMAKE_PATH "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}")
  23 set(TOP_MODULE_PATH "${TOP_CMAKE_PATH}/modules")
  24 set(TOP_SCRIPT_PATH "${TOP_CMAKE_PATH}/scripts")
  25
  26 set(CMAKE_MODULE_PATH "${TOP_MODULE_PATH}")
  27
  28 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  29
  30 message(STATUS)
  31 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  32         message(STATUS "Building in-source")
  33         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  34 else()
  35         message(STATUS "Building out-of-source")
  36         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  37 endif()
  38
  39 # This directory should be used if some test uses lyx-executable
  40 set(LYX_TESTS_USERDIR "${TOP_BINARY_DIR}/Testing/.lyx")
  41 file(MAKE_DIRECTORY "${LYX_TESTS_USERDIR}")
  42
  43 if(COMMAND cmake_policy)
  44         # Installing MACOSX_BUNDLE targets requires a BUNDLE DESTINATION
  45         cmake_policy(SET CMP0006 NEW)
  46         if(POLICY CMP0043)
  47                 # COMPILE_DEFINITIONS are not used yet. Enable new behavior.
  48                 cmake_policy(SET CMP0043 NEW)
  49         endif()
  50         cmake_policy(SET CMP0020 NEW)
  51         if(POLICY CMP0075)
  52                 cmake_policy(SET CMP0075 OLD)
  53         endif()
  54 endif()
  55
  56 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  57
  58 # Supress regeneration
  59 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  60
  61 if(LYX_XMINGW)
  62     set(CMAKE_SYSTEM_NAME Windows)
  63     set(TOOLNAME ${LYX_XMINGW})
  64     set(TOOLCHAIN "${TOOLNAME}-")
  65     set(CMAKE_C_COMPILER   "${TOOLCHAIN}gcc"     CACHE PATH "Mingw C compiler" FORCE)
  66     set(CMAKE_CXX_COMPILER "${TOOLCHAIN}g++"     CACHE PATH "Mingw C++ compiler" FORCE)
  67     set(CMAKE_RC_COMPILER  "${TOOLCHAIN}windres" CACHE PATH "Mingw rc compiler" FORCE)
  68
  69     set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM BOTH)
  70     set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY)
  71     set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY)
  72 endif()
  73
  74 if(NOT help AND NOT HELP)
  75   # 'project' triggers the searching for a compiler
  76   project(${LYX_PROJECT})
  77   if (CMAKE_COMPILER_IS_GNUCXX)
  78     if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS "4.0")
  79       message(STATUS "Gnu CXX compiler version = ${CMAKE_CXX_COMPILER_VERSION}")
  80       message(STATUS "is too old, should be >= 4.0")
  81       message(FATAL_ERROR "Exiting")
  82     endif()
  83   endif()
  84 endif()
  85
  86 if(UNIX)
  87         set(ARCH_TRIPLET )
  88         FIND_PROGRAM(DPKG_ARCHITECTURE_EXECUTABLE dpkg-architecture)
  89         if(DPKG_ARCHITECTURE_EXECUTABLE)
  90                 EXECUTE_PROCESS(COMMAND ${DPKG_ARCHITECTURE_EXECUTABLE} -qDEB_HOST_MULTIARCH
  91                                 OUTPUT_VARIABLE ARCH_TRIPLET
  92                                 ERROR_VARIABLE ERROR_ARCH_TRIPLET
  93                                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  94         endif()
  95 endif()
  96 if(ARCH_TRIPLET)
  97         set(SYSTEM_LIB_DIRS /usr/lib /usr/lib/${ARCH_TRIPLET} /usr/local/lib)
  98 else()
  99         set(SYSTEM_LIB_DIRS /usr/lib /usr/local/lib)
 100 endif()
 101
 102 include(LyXMacros)
 103 include(LyXDestinations)
 104
 105 # Usage LYX_OPTION
 106 # 1. parameter: option name without prefix 'LYX_'
 107 # 2. parameter: description
 108 # 3. parameter: default value, ON or OFF
 109 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
 110
 111 # Usage LYX_COMBO
 112 # 1. parameter: name without prefix 'LYX_'
 113 # 2. parameter: description
 114 # 3. parameter: default value
 115 # 4-n parameter: possible other string values
 116
 117 LYX_OPTION_INIT()
 118
 119 # Options for all compilers/systems
 120 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
 121 LYX_OPTION(LOCALVERSIONING  "Add version info to created package name (only used if LYX_CPACK option set)" OFF ALL)
 122 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
 123 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
 124 LYX_OPTION(REQUIRE_SPELLCHECK "Abort if no spellchecker available" OFF ALL)
 125 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
 126 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
 127 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
 128 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" OFF ALL)
 129 LYX_OPTION(DEBUG            "Enforce debug build"  OFF ALL)
 130 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
 131 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
 132 LYX_STRING(SUFFIX_VALUE     "Use this string as suffix" "")
 133 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
 134 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
 135 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
 136 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
 137 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
 138 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
 139 LYX_OPTION(ENABLE_URLTESTS  "Enable for URL tests" OFF ALL)
 140 LYX_OPTION(ENABLE_EXPORT_TESTS "Enable for export tests" OFF ALL)
 141 LYX_OPTION(ENABLE_KEYTESTS  "Enable for keytests" OFF ALL)
 142 LYX_OPTION(ASAN             "Use address sanitizer" OFF ALL)
 143 LYX_COMBO(USE_FILEDIALOG    "Use native or QT file dialog" QT NATIVE)
 144 LYX_COMBO(USE_QT            "Use Qt version as frontend" AUTO QT4 QT5)
 145 LYX_COMBO(USE_IPO           "Interprocedural optimization" OFF AUTO ON)
 146 #LYX_OPTION(3RDPARTY_BUILD   "Build 3rdparty libs" OFF ALL)
 147 LYX_OPTION(DISABLE_CALLSTACK_PRINTING "do not print a callstack when crashing" OFF ALL)
 148 LYX_OPTION(EXTERNAL_Z       "OFF := Build 3rdparty lib zlib" ON ALL)
 149 LYX_OPTION(EXTERNAL_ICONV   "OFF := Build 3rdparty lib iconvlib" ON ALL)
 150 LYX_OPTION(EXTERNAL_HUNSPELL "OFF := Build 3rdparty lib hunspelllib" ON ALL)
 151 LYX_COMBO(EXTERNAL_MYTHES   "OFF := Build 3rdparty lib mytheslib" AUTO OFF ON)
 152
 153 # GCC specific
 154 LYX_OPTION(PROFILE              "Build with options for gprof" OFF GCC)
 155 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" OFF GCC)
 156 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
 157 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
 158 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++ pedantic debug mode" OFF GCC)
 159 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" OFF GCC)
 160
 161 # MSVC specific
 162 LYX_OPTION(CONSOLE               "Show console on Windows" ON MSVC)
 163 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
 164 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
 165 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
 166
 167 # APPLE specific
 168 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
 169 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
 170
 171
 172 if(help OR HELP)
 173         message(STATUS)
 174         message(STATUS "Available options: (dis/enable with -DLYX_*=OFF/ON)")
 175         message(STATUS)
 176         LYX_OPTION_LIST_ALL(help)
 177         message(STATUS)
 178         RETURN()
 179 endif()
 180
 181 # Check option dependencies
 182
 183 if(LYX_DMG)
 184         set(LYX_BUNDLE ON)
 185         set(LYX_CPACK ON)
 186 endif()
 187
 188 if(LYX_CPACK)
 189         set(LYX_INSTALL ON)
 190 endif()
 191
 192 if(LYX_INSTALL)
 193         set(LYX_NLS ON)
 194         if(WIN32 AND NOT MINGW)
 195                 set(LYX_HUNSPELL ON)
 196         endif()
 197         set(LYX_PACKAGE_SUFFIX ON)
 198         if(NOT LYX_DEBUG)
 199                 set(LYX_RELEASE ON)
 200         endif()
 201         set(LYX_PROFILE OFF)
 202 endif()
 203
 204
 205 if(LYX_MERGE_FILES)
 206         set(LYX_PCH OFF)
 207 else()
 208         set(LYX_MERGE_REBUILD OFF)
 209 endif()
 210
 211 if(LYX_DEPENDENCIES_DOWNLOAD)
 212         message(STATUS)
 213         if(MSVC14)
 214                 set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2015-deps)
 215                 set(deps_files lyx-windows-deps-msvc2015.zip)
 216                 set(deps_server http://ftp.lyx.de/LyX-Windows-Deps)
 217                 set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2015)
 218         elseif(MSVC10)
 219                 set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 220                 set(deps_files lyx-windows-deps-msvc2010.zip)
 221                 set(deps_server http://ftp.lyx.de/LyX-Windows-Deps)
 222                 set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2010)
 223         else()
 224                 message(FATAL_ERROR "error: no dependency package known for the selected MSVC version.")
 225         endif()
 226     message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 227         foreach(it ${deps_files})
 228                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 229                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 230                 if(NOT already_downloaded)
 231                         message(STATUS "Downloading ${it} ...")
 232                         file(DOWNLOAD ${deps_server}/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS STATUS status LOG log)
 233                         list(GET status 0 status_code)
 234                         list(GET status 1 status_string)
 235                         if(NOT status_code EQUAL 0)
 236                                 file(REMOVE ${LYX_DEPENDENCIES_DIR}/${it})
 237                                 message(FATAL_ERROR "error: downloading '${it}' failed. status_code: ${status_code}, status_string: ${status_string}. \nLog: ${log} ")
 238                         endif()
 239                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 240                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 241                 endif()
 242         endforeach()
 243 endif()
 244
 245 message(STATUS)
 246
 247 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 248 if(WIN32)
 249         set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 250 else()
 251         set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 252 endif()
 253
 254 set(LYX_IPO_SUPPORTED OFF)
 255 if (POLICY CMP0069)
 256   cmake_policy(SET CMP0069 NEW)
 257   if(LYX_USE_IPO MATCHES "AUTO")
 258     # Enable LTO if supported and not debugging
 259     if (NOT LYX_DEBUG)
 260       include(CheckIPOSupported)
 261       check_ipo_supported(RESULT LYX_IPO_SUPPORTED)
 262     endif()
 263   else()
 264     set(LYX_IPO_SUPPORTED ${LYX_USE_IPO})
 265   endif()
 266 endif()
 267 if (LYX_IPO_SUPPORTED)
 268   set(LYX_USE_IPO "ON" CACHE STRING "Use interprocedural optimization" FORCE)
 269 else()
 270   set(LYX_USE_IPO "OFF" CACHE STRING "Use interprocedural optimization" FORCE)
 271 endif()
 272
 273 # Set to some meaningful default
 274 find_package(CXX11Compiler)
 275 if(NOT CXX11COMPILER_FOUND)
 276         message(FATAL_ERROR "A C++11 compatible compiler is required.")
 277 endif()
 278 set(LYX_GCC11_MODE)
 279 if(UNIX OR MINGW)
 280         if (CMAKE_CXX_COMPILER_ID MATCHES "^([cC]lang|AppleClang)$")
 281           # ignore the GCC_VERSION for clang
 282           # and use the resulting CXX11_STD_REGEX found in FindCXX11Compiler.cmake
 283           message(STATUS "Using clang")
 284           if(CXX11_STD_REGEX)
 285             set(LYX_USE_STD_REGEX 1)
 286           else()
 287             set(LYX_USE_STD_REGEX 0)
 288           endif()
 289         else()
 290           execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpfullversion OUTPUT_VARIABLE GCC_VERSION ERROR_VARIABLE _error RESULT_VARIABLE _err OUTPUT_STRIP_TRAILING_WHITESPACE)
 291           #message(STATUS "dumpfullversion: error = ${_error}, result = ${_err}")
 292           if (_err)
 293             # previous check failed, try again with _old_ parameter
 294             execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION ERROR_VARIABLE _error RESULT_VARIABLE _err OUTPUT_STRIP_TRAILING_WHITESPACE)
 295             #message(STATUS "dumpversion: error = ${_error}, result = ${_err}")
 296           endif()
 297           message(STATUS "Using GCC version ${GCC_VERSION}")
 298           if(GCC_VERSION VERSION_LESS 4.6)
 299                 message(FATAL_ERROR "gcc >= 4.6 is required.")
 300           elseif(GCC_VERSION VERSION_LESS 4.9)
 301                 # <regex> in gcc is unusable in versions less than 4.9.0
 302                 # see https://gcc.gnu.org/bugzilla/show_bug.cgi?id=53631
 303                 set(LYX_USE_STD_REGEX 0)
 304           else()
 305                 set(LYX_USE_STD_REGEX 1)
 306           endif()
 307         endif()
 308         set(LYX_GCC11_MODE "${CXX11_FLAG}")
 309 else()
 310         if(MSVC_VERSION LESS 1900)
 311                 # Drop support for msvc versions prior to 1900 (Visual Studio 2015)
 312                 message(FATAL_ERROR "Visual Studio >= 2015 is required.")
 313                 set(LYX_USE_STD_REGEX 0)
 314         else()
 315                 set(LYX_USE_STD_REGEX 1)
 316         endif()
 317 endif()
 318
 319
 320 set(VERSION_INFO "CMake Build")
 321
 322 # Try to get some informations from configure.ac
 323
 324 include(LyXPaths)
 325 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 326
 327 if(WIN32)
 328         set(CMAKE_PREFIX_PATH Specify-path-to-Qt CACHE PATH "Used Qt version")
 329         if(MSVC)
 330                 set(LYX_3RDPARTY_BUILD ON CACHE BOOL "Build 3rdparty libraries" FORCE)
 331         endif()
 332         set(USE_WINDOWS_PACKAGING ON)
 333 elseif(APPLE)
 334         set(USE_MACOSX_PACKAGING ON)
 335 else()
 336         set(USE_POSIX_PACKAGING ON)
 337 endif()
 338
 339 if(LYX_3RDPARTY_BUILD)
 340   # LYX_3RDPARTY_BUILD is not cached anymore, but for compatibility reasons
 341   # this enables the build of all 3rd_party libs
 342   set(LYX_EXTERNAL_Z        OFF CACHE BOOL "Build 3rdparty lib zlib"    FORCE)
 343   set(LYX_EXTERNAL_ICONV    OFF CACHE BOOL "Build 3rdparty iconvlib"    FORCE)
 344   set(LYX_EXTERNAL_HUNSPELL OFF CACHE BOOL "Build 3rdparty hunspelllib" FORCE)
 345   set(LYX_EXTERNAL_MYTHES   OFF CACHE STRING "Build 3rdparty mytheslib" FORCE)
 346 endif()
 347
 348 macro(setstripped _varname)
 349         if(${ARGC} GREATER 1)
 350                 string(STRIP "${ARGV1}" _v)
 351                 if (_v MATCHES "^\\[\(.+\)\\]$")
 352                   set(_v ${CMAKE_MATCH_1})
 353                 endif()
 354                 if(USE_POSIX_PACKAGING)
 355                         string(TOLOWER ${_v} ${_varname})
 356                 else()
 357                         set(${_varname} ${_v})
 358                 endif()
 359         else()
 360                 set(${_varname})
 361         endif()
 362 endmacro(setstripped)
 363
 364 foreach(_c_l ${_config_lines} )
 365         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 366                 # Not using CMAKE_MATCH_ directly is needed, because
 367                 # its value is now changed inside macro setstripped
 368                 set(_PB ${CMAKE_MATCH_1})
 369                 set(_PV ${CMAKE_MATCH_2})
 370                 set(_PBU ${CMAKE_MATCH_3})
 371                 setstripped(PACKAGE_BASE ${_PB})
 372                 setstripped(PACKAGE_VERSION ${_PV})
 373                 setstripped(PACKAGE_BUGREPORT ${_PBU})
 374                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\)\(\\.\([0-9]+\)\(\\.\([0-9]+\)\)?\)?.*$")
 375                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 376                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 377                         set(LYX_RELEASE_LEVEL ${CMAKE_MATCH_4})
 378                         set(LYX_RELEASE_PATCH ${CMAKE_MATCH_6})
 379                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 380                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 381                         if (NOT LYX_RELEASE_LEVEL)
 382                                 set(LYX_RELEASE_LEVEL 0)
 383                         endif()
 384                         if (NOT LYX_RELEASE_PATCH)
 385                                 set(LYX_RELEASE_PATCH 0)
 386                         endif()
 387                         if ("${LYX_SUFFIX_VALUE}" MATCHES "")
 388                           set(LYX_INSTALL_SUFFIX "${LYX_MAJOR_VERSION}.${LYX_MINOR_VERSION}")
 389                         else()
 390                           set(LYX_INSTALL_SUFFIX "${LYX_SUFFIX_VALUE}")
 391                         endif()
 392                 endif()
 393         endif()
 394         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 395                 set(LYX_DATE "${CMAKE_MATCH_1}")
 396         endif()
 397 endforeach(_c_l)
 398
 399 FIND_PROGRAM(LYX_GITVERSION git)
 400 #message(STATUS "gitversion = ${LYX_GITVERSION}")
 401 set(LYX_REVISION_VERSION ${LYX_RELEASE_LEVEL})
 402 set(LYX_PACKAGE_RELEASE "1")
 403 if(LYX_GITVERSION)
 404   if (LYX_LOCALVERSIONING)
 405     # Find the revision number for later use
 406     EXECUTE_PROCESS(COMMAND ${LYX_GITVERSION} describe --match 2.0.0 HEAD
 407       WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE tmp_LYX_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 408     if (tmp_LYX_PACKAGE_RELEASE MATCHES "^2\\.0\\.0\\-\([0-9]+\)\\-\(.*\)$")
 409       set(LYX_PACKAGE_RELEASE ${CMAKE_MATCH_2})
 410       # We will add offset of 40000 to get appropriate value to
 411       # previous svn.
 412       # We use this value than also to set the package-patch-value
 413       MATH(EXPR tmp_REVISION_VERSION "(${CMAKE_MATCH_1}+40000)")
 414       set(LYX_REVISION_VERSION "${LYX_RELEASE_LEVEL}-${tmp_REVISION_VERSION}git")
 415       set(ENABLE_DIST ON)
 416     endif()
 417   endif()
 418 else()
 419   if (LYX_RELEASE_PATCH GREATER 0)
 420     set(LYX_REVISION_VERSION "${LYX_RELEASE_LEVEL}.${LYX_RELEASE_PATCH}")
 421   endif()
 422 endif()
 423
 424 # Set the programs (lyx, tex2lyx, etc.) suffix
 425 # When building an OS X bundle, we will append
 426 # the suffix only to the bundle, not to the programs
 427 set(PROGRAM_SUFFIX "")
 428 if(LYX_PROGRAM_SUFFIX AND NOT (APPLE AND LYX_BUNDLE))
 429         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 430 endif()
 431 set(_lyx "${PACKAGE_BASE}${PROGRAM_SUFFIX}")
 432 set(_tex2lyx tex2lyx${PROGRAM_SUFFIX})
 433 set(_convert lyxconvert${PROGRAM_SUFFIX})
 434
 435 add_custom_target(lyx_version ALL
 436   COMMAND ${CMAKE_COMMAND} -DTOP_SRC_DIR=${TOP_SRC_DIR} -DTOP_CMAKE_PATH=${TOP_CMAKE_PATH} -DTOP_BINARY_DIR=${TOP_BINARY_DIR} -DLYX_DATE=${LYX_DATE} -P ${TOP_SCRIPT_PATH}/LyXGetVersion.cmake
 437   )
 438 set_target_properties(lyx_version PROPERTIES FOLDER "applications")
 439
 440 # Default paths for installed utilities (tex2lyx, lyxclient, etc.)
 441 set(LYX_UTILITIES_INSTALL_PATH bin)
 442
 443 if(LYX_BUNDLE)
 444         set(LYX_CPACK ON)
 445
 446         message(STATUS)
 447         message(STATUS "Bundle creation is enabled (experimental):")
 448         message(STATUS "    make")
 449         message(STATUS "    make install/strip")
 450         message(STATUS "    make package")
 451         if(APPLE)
 452                 set(MACOSX_BUNDLE TRUE)
 453                 # This sets the bundle + executable names
 454                 set(_lyx "${PACKAGE_BASE}${LYX_INSTALL_SUFFIX}")
 455                 # This sets the Info.plist executable name
 456                 set(osx_bundle_program_name ${_lyx})
 457                 # Bundle name
 458                 set(LYX_BUNDLE_NAME ${_lyx})
 459
 460                 # This will contain the list of files that need to be included
 461                 # in the bundle and their location within the bundle
 462                 set(OSX_BUNDLE_FILES "${TOP_SRC_DIR}/development/MacOSX/LyX.sdef;${TOP_SRC_DIR}/development/MacOSX/LyXapp.icns;${CMAKE_BINARY_DIR}/lyxrc.dist")
 463                 set(OSX_BUNDLE_DIRS "Resources;Resources;Resources")
 464
 465                 # Process Info.plist and lyxrc.dist
 466                 # See development/cmake/Install.cmake
 467                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/Info.plist.in" "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 468
 469                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 470                 set(LYX_DATA_SUBDIR ${LYX_BUNDLE_NAME}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 471
 472                 # Variables used by CPack
 473                 set(CPACK_BUNDLE_NAME ${LYX_BUNDLE_NAME})
 474                 set(CPACK_BUNDLE_PLIST "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 475                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${LYX_BUNDLE_NAME}.app)
 476
 477                 # Set the install paths
 478                 set(LYX_UTILITIES_INSTALL_PATH ${LYX_BUNDLE_NAME}.app/Contents/MacOS)
 479                 if(NOT LYX_INSTALL_PREFIX)
 480                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 481                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 482                 endif()
 483                 # Change the owner so that the install can work
 484                 install(CODE "set(BU_CHMOD_BUNDLE_ITEMS 1)" COMPONENT Runtime)
 485         elseif(UNIX)
 486                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 487                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 488                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 489         elseif(WIN32)
 490                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 491         endif()
 492 endif()
 493
 494 if(LYX_INSTALL_PREFIX)
 495         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 496         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 497 endif()
 498 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 499
 500 if(UNIX)
 501   set(SYSTEM_DATADIR "${CMAKE_INSTALL_PREFIX}/share")
 502 elseif(CMAKE_INSTALL_PREFIX MATCHES "/lyx${LYX_INSTALL_SUFFIX}$")
 503   string(REGEX REPLACE "/lyx${LYX_INSTALL_SUFFIX}$" "/share" SYSTEM_DATADIR ${CMAKE_INSTALL_PREFIX})
 504 else()
 505   set(SYSTEM_DATADIR "${CMAKE_INSTALL_PREFIX}")
 506 endif()
 507
 508 if(NOT CMAKE_COMPILER_IS_GNUCXX)
 509   # Not a GCC compiler, programs do not have a suffix
 510   set(suffixing ${LYX_PACKAGE_SUFFIX})
 511 elseif(WIN32 AND MINGW)
 512   # We want to use a suffix for the package in this case,
 513   # even if not for the program
 514   set(suffixing ${LYX_PACKAGE_SUFFIX})
 515 else()
 516   message(STATUS "CMAKE_COMPILER_IS_GNUCXX = ${CMAKE_COMPILER_IS_GNUCXX}")
 517   set(suffixing ${LYX_PROGRAM_SUFFIX})
 518 endif()
 519
 520 # The define PACKAGE below allows lyx-executable to find its default configuration files
 521 # see routines
 522 #    Package::messages_file()
 523 #    get_default_user_support_dir()
 524 #    relative_system_support_dir()
 525 # in src/support/Package.cpp
 526 if(suffixing)
 527         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 528 else()
 529         set(PACKAGE ${PACKAGE_BASE})
 530 endif()
 531
 532 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 533         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 534         if (UNIX)
 535                 # use the default "/usr/local"
 536                 # but respect the user-choice on the command-line
 537                 set(CMAKE_INSTALL_PREFIX "/usr/local" CACHE PATH "LyX default install prefix" FORCE)
 538         endif()
 539 endif()
 540 if(WIN32)
 541         set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 542 endif()
 543 if(IS_ABSOLUTE)
 544         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 545 else()
 546         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 547 endif()
 548
 549
 550
 551 if(NOT LYX_DATA_SUBDIR)
 552         if (WIN32)
 553                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 554         else()
 555                 set(LYX_DATA_SUBDIR "share/${_lyx}/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 556         endif()
 557 endif()
 558
 559 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 560 get_locale_destination(LYX_LOCALEDIR)
 561 set(LYX_ABS_INSTALLED_LOCALEDIR "${CMAKE_INSTALL_PREFIX}/${LYX_LOCALEDIR}")
 562 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 563
 564 if(LYX_BUNDLE AND APPLE)
 565         set(LYX_MAN_DIR "${LYX_DATA_SUBDIR}" CACHE STRING "Install location for man pages.")
 566 else()
 567         if(WIN32)
 568                 set(LYX_MAN_DIR "${CMAKE_BINARY_DIR}/usr/local/man" CACHE STRING "Install location for man pages.")
 569         elseif(UNIX)
 570                 set(LYX_MAN_DIR "${CMAKE_INSTALL_PREFIX}/share/man" CACHE STRING "Install location for man pages.")
 571         else()
 572                 set(LYX_MAN_DIR "${CMAKE_INSTALL_PREFIX}/man" CACHE STRING "Install location for man pages.")
 573         endif()
 574 endif()
 575 mark_as_advanced(LYX_MAN_DIR)
 576
 577 # The Win installer cannot be built by CMake because one needs to install plugins for NSIS
 578 # see the Readme.txt of the installer
 579 #if(LYX_INSTALL AND WIN32)
 580 #       message(STATUS "Configuring NSIS files")
 581 #       configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 582 #       configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 583 #       configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 584 #       message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 585 #endif()
 586
 587 if(NOT GROUP_CODE)
 588         #set(GROUP_CODE "The Golden Code")
 589         set(GROUP_CODE flat)
 590 endif()
 591
 592 # lyx's source files
 593 set(LYX_CPP_FILES [a-zA-Z]*.cpp)
 594 set(LYX_HPP_FILES [a-zA-Z]*.h)
 595 set(LYX_MOC_FILES moc_*.cpp)
 596
 597 include(ProjectSourceGroup)
 598
 599
 600 if(LYX_PROFILE AND NOT MSVC)
 601         set(CMAKE_BUILD_TYPE Profile CACHE STRING "Profile build type" FORCE)
 602         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg")
 603         set(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS}  -pg")
 604 else()
 605         set(LYX_PROFILE OFF)
 606 endif()
 607
 608
 609 if(LYX_NO_OPTIMIZE)
 610         set(CMAKE_BUILD_TYPE None)
 611         set(LYX_DEBUG OFF)
 612         set(LYX_RELEASE OFF)
 613         set(LYX_PROFILE OFF)
 614 elseif(LYX_RELEASE)
 615         set(CMAKE_BUILD_TYPE Release)
 616         set(LYX_DEBUG OFF)
 617         set(LYX_PROFILE OFF)
 618 elseif(LYX_PROFILE)
 619         set(CMAKE_BUILD_TYPE Profile)
 620         set(LYX_DEBUG OFF)
 621 else()
 622         set(CMAKE_BUILD_TYPE Debug)
 623         set(LYX_DEBUG ON)
 624 endif()
 625
 626
 627 # When shared libs are supported enable this option
 628 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 629 if(LYX_SHARED_LIBRARIES)
 630         set(library_type SHARED)
 631 else()
 632         set(library_type STATIC)
 633 endif()
 634
 635 if(NOT MSVC)
 636         if(NOT LYX_QUIET)
 637                 set(CMAKE_VERBOSE_MAKEFILE ON)
 638         endif()
 639         set(LYX_CXX_FLAGS "-Wall -Wunused-parameter ${LYX_GCC11_MODE}")
 640         if(LYX_CXX_FLAGS MATCHES "\\+\\+(14|11|98)")
 641           # Thanks to Brad King <brad.king@kitware.com>
 642           # for the pointer to https://cmake.org/cmake/help/v3.6/variable/CMAKE_CXX_STANDARD.html
 643           # This allows us to use QT5.7 with recent g++ (version >= 4.9) compilers
 644           # and still use our own c++ extension tests
 645           set(CMAKE_CXX_STANDARD ${CMAKE_MATCH_1})
 646           message(STATUS "CMAKE_CXX_STANDARD set to ${CMAKE_CXX_STANDARD}")
 647         endif()
 648         if(LYX_STDLIB_DEBUG)
 649                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 650         endif()
 651         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE STRING "Set CXX flags" FORCE)
 652         set(CMAKE_CXX_FLAGS_DEBUG "-O0 -g3 -D_DEBUG" CACHE STRING "Set debug flags" FORCE)
 653         if(MINGW)
 654                 set(CMAKE_CXX_FLAGS_RELEASE "-O2 -DNDEBUG" CACHE STRING "Set release flags for Mingw" FORCE)
 655         else()
 656                 set(CMAKE_CXX_FLAGS_RELEASE "-O3 -DNDEBUG" CACHE STRING "Set release flags" FORCE)
 657         endif()
 658 endif()
 659
 660 set(LYX_CXX_FLAGS_EXTRA "" CACHE STRING "Desired semicolon separated list of extra cxx compile flags, like '-Werror'")
 661 mark_as_advanced(LYX_CXX_FLAGS_EXTRA)
 662 if(LYX_CXX_FLAGS_EXTRA)
 663         foreach(_flag ${LYX_CXX_FLAGS_EXTRA})
 664                 add_definitions(${_flag})
 665         endforeach()
 666 endif()
 667
 668 if(LYX_XMINGW)
 669         list(APPEND CMAKE_FIND_ROOT_PATH ${GNUWIN32_DIR})
 670 endif()
 671
 672 set(min_qt5_version "5.6")
 673 if(LYX_USE_QT MATCHES "AUTO")
 674         # try qt5 first
 675         find_package(Qt5Core CONFIG QUIET)
 676         if(Qt5Core_FOUND)
 677                 set(LYX_USE_QT "QT5" CACHE STRING "Valid qt version" FORCE)
 678                 message(STATUS "Qt5Core_VERSION = ${Qt5Core_VERSION}")
 679                 if(Qt5Core_VERSION VERSION_LESS ${min_qt5_version})
 680                         find_package(Qt4 "4.5.0" QUIET)
 681                         if(QT4_FOUND)
 682                                 set(LYX_USE_QT "QT4" CACHE STRING "Valid qt version" FORCE)
 683                         endif()
 684                 endif()
 685         else()
 686                 set(LYX_USE_QT "QT4" CACHE STRING "Valid qt version" FORCE)
 687         endif()
 688 endif()
 689 if(LYX_USE_QT MATCHES "QT5")
 690         # set QPA_XCB if QT uses X11
 691         find_package(Qt5Core CONFIG REQUIRED)
 692         if (Qt5Core_FOUND)
 693                 find_package(Qt5Widgets CONFIG REQUIRED)
 694                 if(APPLE)
 695                         find_package(Qt5MacExtras CONFIG REQUIRED)
 696                 endif()
 697                 find_package(Qt5X11Extras CONFIG QUIET)
 698                 find_package(Qt5WinExtras CONFIG QUIET)
 699                 set(QTVERSION ${Qt5Core_VERSION})
 700                 if (QTVERSION VERSION_LESS ${min_qt5_version})
 701                         message(STATUS "QTVERSION = \"${QTVERSION}\"")
 702                         message(STATUS "This version is not recommended, try either option -DLYX_USE_QT=QT4 or")
 703                         message(STATUS "install QT-Version >= \"${min_qt5_version}\"")
 704                         # see thread in lyx-devel list
 705                         # From: Jean-Pierre Chrétien <jeanpierre.chretien@free.fr>
 706                         # Date 11.03.2017
 707                         # Subject: cmake compilation error
 708                         #message(FATAL_ERROR "Wrong Qt-Version")
 709                 endif()
 710                 macro (qt_use_modules lyxtarget)
 711                         foreach (_tg ${ARGN})
 712                                 find_package(Qt5${_tg} CONFIG REQUIRED)
 713                                 target_link_libraries(${lyxtarget} Qt5::${_tg})
 714                         endforeach()
 715                 endmacro()
 716                 macro (qt_add_resources)
 717                         qt5_add_resources(${ARGN})
 718                 endmacro()
 719                 macro (qt_wrap_uifiles)
 720                         qt5_wrap_ui(${ARGN})
 721                 endmacro()
 722                 message(STATUS "Found Qt-Version ${QTVERSION}")
 723                 if(WIN32)
 724                         set(LYX_QTMAIN_LIBRARY ${Qt5Core_QTMAIN_LIBRARIES})
 725                 endif()
 726         endif()
 727 elseif(LYX_USE_QT MATCHES "QT4")
 728         if(LYX_XMINGW)
 729                 set(QT_MINGW_DIR ${LYX_QT4} CACHE PATH "Qt for Mingw" FORCE)
 730                 list(APPEND CMAKE_FIND_ROOT_PATH ${QT_MINGW_DIR} ${GNUWIN32_DIR})
 731         endif()
 732         find_package(Qt4 "4.5.0" REQUIRED)
 733         macro (qt_use_modules)
 734         endmacro()
 735         macro (qt_add_resources)
 736                 qt4_add_resources(${ARGN})
 737         endmacro()
 738         macro (qt_wrap_uifiles)
 739                 qt4_wrap_ui(${ARGN})
 740         endmacro()
 741         set(LYX_QTMAIN_LIBRARY ${QT_QTSVG_LIBRARY})
 742         if(WIN32)
 743                 list(APPEND LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARIES})
 744         endif()
 745 else()
 746   message(FATAL_ERROR "Unhandled value for LYX_USE_QT (${LYX_USE_QT})")
 747 endif()
 748
 749 find_package(Magic)
 750 if(Magic_FOUND)
 751   set(HAVE_MAGIC_H 1)
 752   include_directories(${Magic_INCLUDE_DIR})
 753 endif()
 754
 755 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 756
 757 set(Spelling_FOUND OFF)
 758 set(Include_used_spellchecker)   # String will be inserted into config.h
 759
 760 if (LYX_EXTERNAL_MYTHES MATCHES "AUTO")
 761   # try system library first
 762   find_package(MyThesLIB)
 763   if (MYTHESLIB_FOUND)
 764     set(LYX_EXTERNAL_MYTHES ON CACHE STRING "OFF:= Build 3rdparty mytheslib" FORCE)
 765   else()
 766     set(LYX_EXTERNAL_MYTHES OFF CACHE STRING "OFF:= Build 3rdparty mytheslib" FORCE)
 767   endif()
 768 endif()
 769 if (LYX_EXTERNAL_MYTHES MATCHES "ON")
 770   find_package(MyThesLIB REQUIRED)
 771 else()
 772   add_subdirectory(3rdparty/mythes)
 773 endif()
 774 set(MYTHES_DIR ${MYTHESLIB_INCLUDE_DIR})
 775
 776 if(NOT LYX_EXTERNAL_HUNSPELL)
 777     add_subdirectory(3rdparty/hunspell)
 778     add_definitions(-DHUNSPELL_STATIC)
 779     set(HUNSPELL_FOUND ON)
 780     message(STATUS "  * Hunspell:")
 781     message(STATUS "     - include: ${HUNSPELL_INCLUDE_DIR}")
 782     message(STATUS "     - library: ${HUNSPELL_LIBRARY}")
 783 endif()
 784
 785 foreach(_spell "ASPELL" "ENCHANT" "HUNSPELL")
 786   string(TOUPPER ${_spell} _upspell)
 787   if (NOT ${_upspell}_FOUND)
 788     find_package(${_spell})
 789   endif()
 790   if (${_upspell}_FOUND)
 791     include_directories(${${_upspell}_INCLUDE_DIR})
 792     set(Spelling_FOUND ON)
 793     message(STATUS "Building with USE_${_upspell}")
 794     set(Include_used_spellchecker "${Include_used_spellchecker}#define USE_${_upspell} 1\n")
 795   else()
 796     if(LYX_${_upspell})
 797       message(FATAL_ERROR "Required ${_spell} devel package not found")
 798     else()
 799       message(STATUS "${_upspell} not found, building without ${_spell} support")
 800     endif()
 801   endif()
 802 endforeach()
 803
 804 if(GNUWIN32_DIR)
 805         list(APPEND CMAKE_PROGRAM_PATH "${GNUWIN32_DIR}/Python" )
 806 endif()
 807
 808 # Search for python default version first
 809 unset(PYTHON_EXECUTABLE CACHE)
 810 unset(LYX_PYTHON_EXECUTABLE CACHE)
 811 unset(PYTHON_VERSION_MAJOR)
 812 unset(PYTHON_VERSION_MINOR)
 813 unset(PYTHON_VERSION_STRING)
 814 if (CMAKE_VERSION VERSION_LESS "3.13")
 815   find_package(PythonInterp 3.5 QUIET)
 816   if(NOT PYTHONINTERP_FOUND)
 817     find_package(PythonInterp 2.0 REQUIRED)
 818     if(NOT PYTHON_VERSION_STRING VERSION_LESS 2.8)
 819       message(FATAL_ERROR "Python interpreter found, but is not suitable")
 820     endif()
 821   endif()
 822   set(LYX_PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 823 else()
 824   find_package(Python3 3.5 QUIET)
 825   if(NOT Python3_Interpreter_FOUND)
 826     unset(PYTHON_EXECUTABLE CACHE)
 827     find_package(Python2 2.0 REQUIRED)
 828     if(NOT Python2_VERSION VERSION_LESS 2.8)
 829       message(FATAL_ERROR "Python interpreter found, but is not suitable")
 830     endif()
 831     set(LYX_PYTHON_EXECUTABLE ${Python2_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 832   else()
 833     set(LYX_PYTHON_EXECUTABLE ${Python3_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 834   endif()
 835 endif()
 836
 837 if(LYX_NLS)
 838         find_package(LyXGettext)
 839         if(LYX_PYTHON_EXECUTABLE AND GETTEXT_FOUND)
 840                 add_subdirectory(po "${TOP_BINARY_DIR}/po")
 841         else()
 842                 # Install only supplied .gmo-files
 843                 file(GLOB _gmofiles RELATIVE "${TOP_SRC_DIR}/po" "${TOP_SRC_DIR}/po/*.gmo")
 844                 message(STATUS "Installing provided .gmo-files only")
 845                 foreach( _gmo ${_gmofiles})
 846                         string(REGEX REPLACE "\\.gmo$" "" _lang ${_gmo})
 847                         install(FILES "${TOP_SRC_DIR}/po/${_gmo}" DESTINATION ${LYX_LOCALEDIR}/${_lang}/LC_MESSAGES RENAME ${PACKAGE}.mo)
 848                 endforeach()
 849         endif()
 850 endif()
 851
 852 if(LYX_EXTERNAL_ICONV)
 853   find_package(ICONV REQUIRED)
 854 else()
 855   add_subdirectory(3rdparty/libiconv)
 856   set(HAVE_ICONV_CONST 1)
 857 endif()
 858
 859 if(LYX_EXTERNAL_Z)
 860   find_package(ZLIB REQUIRED)
 861 else()
 862   add_subdirectory(3rdparty/zlib)
 863 endif()
 864
 865 if(LYX_USE_STD_REGEX)
 866   # Set only include path.
 867   # Use internal boost, which is known to exist
 868   # we don't need any libraries
 869   set(Lyx_Boost_Libraries)
 870   add_definitions(-DBOOST_USER_CONFIG=<config.h>)
 871   include_directories(${TOP_SRC_DIR}/3rdparty/boost)
 872 else()
 873   # Using boost-regex
 874   if(LYX_EXTERNAL_BOOST)
 875     message(STATUS "Searching for external boost")
 876     find_package(Boost COMPONENTS regex)
 877     if(Boost_FOUND)
 878       message(STATUS "Boost found")
 879       message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 880       set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 881       if (LYX_STDLIB_DEBUG)
 882         # Comment from  Jean-Marc Lasgouttes:
 883         # In general, system boost libraries are incompatible with
 884         # the use of stdlib-debug in libstdc++. See ticket #9736 for
 885         # details.
 886         message(WARNING "Compiling LyX with stdlib-debug and system boost libraries may lead to crashes. Consider using '-DLYX_STDLIB_DEBUG=OFF' or using '-DLYX_EXTERNAL_BOOST=OFF'")
 887       endif()
 888     else()
 889       message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 890     endif()
 891   else()
 892     # Using included boost
 893     set(Lyx_Boost_Libraries boost_regex)
 894     add_definitions(-DBOOST_USER_CONFIG=<config.h>)
 895     include_directories(${TOP_SRC_DIR}/3rdparty/boost)
 896     add_subdirectory(3rdparty/boost "${TOP_BINARY_DIR}/3rdparty/boost")
 897   endif()
 898 endif()
 899
 900 if(WIN32)
 901         if(LYX_CONSOLE)
 902                 set(LYX_QTMAIN_LIBRARY)
 903         else()
 904                 set(WIN32_CONSOLE WIN32)
 905         endif()
 906         if(MSVC)
 907                 # -DPSAPI_VERSION=1 is needed to run on vista (bug 10186)
 908                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX -DPSAPI_VERSION=1)
 909                 # disable checked iterators for msvc release builds to get maximum speed
 910                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 911         else()
 912                 # -DPSAPI_VERSION=1 is not needed for mingw, since the mingw psapi.h
 913                 # does not use it and always declares the vista compatible API.
 914                 # If this ever changes then -DPSAPI_VERSION might be needed here as well.
 915                 add_definitions(-DWINVER=0x0500)
 916         endif()
 917 endif()
 918
 919 # Compute qt-version from ${QTVERSION}
 920
 921 message(STATUS "")
 922 foreach(_v PACKAGE PACKAGE_VERSION
 923         PROGRAM_SUFFIX LYX_DIR_VER LYX_USERDIR_VER
 924         LYX_ABS_TOP_SRCDIR
 925         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 926         if(NOT DEFINED ${_v})
 927                 message(FATAL_ERROR "${_v} not defined")
 928         endif()
 929         string(SUBSTRING "${_v}                            " 0 28 _v1)
 930         message(STATUS "----- ${_v1}: ${${_v}}")
 931 endforeach(_v)
 932 message(STATUS "")
 933
 934
 935 if(LYX_PCH)
 936         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 937         # Not sure if it works for all non-msvc compilers
 938         include(PCHSupport_26)
 939         configure_file(${TOP_CMAKE_PATH}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
 940         configure_file(${TOP_CMAKE_PATH}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 941         add_definitions(-DLYX_ENABLE_PCH)
 942
 943         if(MSVC)
 944                 macro(lyx_add_msvc_pch name_)
 945                         set_source_files_properties(${${name_}_sources} PROPERTIES
 946                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 947                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
 948                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 949                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
 950                                 ${TOP_BINARY_DIR}/pcheaders.h)
 951                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 952                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 953                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 954                 endmacro(lyx_add_msvc_pch)
 955                 macro(lyx_add_gcc_pch name_)
 956                 endmacro()
 957         else()
 958                 macro(lyx_add_msvc_pch name_)
 959                 endmacro()
 960                 macro(lyx_add_gcc_pch name_)
 961                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT)
 962                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
 963                 endmacro()
 964         endif()
 965 else()
 966         macro(lyx_add_msvc_pch)
 967         endmacro(lyx_add_msvc_pch)
 968         macro(lyx_add_gcc_pch name_)
 969         endmacro()
 970 endif()
 971
 972
 973 if(MSVC)
 974
 975         if(LYX_VLD)
 976                 set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/development/Win32/vld)
 977                 add_subdirectory(${vld_path}/cmake)
 978                 include(${vld_path}/cmake/vld.cmake) # forced include
 979                 set(vld_dll vld)
 980         endif()
 981
 982         if(LYX_WALL)
 983                 # Use the highest warning level
 984                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE STRING "Warning level" FORCE)
 985
 986                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 987                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 988                 else()
 989                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 990                 endif()
 991
 992                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 993                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 994                 else()
 995                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 996                 endif()
 997
 998                 # add here warnings which should produce an error /weXXXX
 999                 set(MSVC_W_ERROR   "/we4101 /we4189")
1000                 # add here warnings which should be disabled /wdXXXX
1001                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
1002
1003                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1004                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1005                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1006
1007         else()
1008                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE STRING "Warning level" FORCE)
1009
1010                 # add here warnings which should produce an error /weXXXX
1011                 set(MSVC_W_ERROR   "/we4101 /we4189")
1012                 # add here warnings which should be disabled /wdXXXX
1013                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
1014
1015                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1016                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1017                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1018
1019         endif()
1020
1021         if (NOT Qt5Core_FOUND)
1022                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
1023                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
1024                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
1025         endif()
1026
1027         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
1028         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
1029         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
1030         message(STATUS "")
1031 endif()
1032
1033
1034 if(LYX_DEBUG_GLIBC)
1035         set(_GLIBCXX_DEBUG ON)
1036 endif()
1037
1038 if(LYX_DEBUG_GLIBC_PEDANTIC)
1039         set(_GLIBCXX_DEBUG_PEDANTIC ON)
1040 endif()
1041
1042 # Xcode compiler
1043 if (CMAKE_GENERATOR MATCHES Xcode)
1044         if (XCODE_VERSION VERSION_LESS "5.0")
1045                 # Automatically select the Xcode compiler if not set
1046                 if (NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
1047                         # XCode >= 3.1 has gcc 4.2 (up to actual Xcode)
1048                         if (XCODE_VERSION VERSION_GREATER "3.1")
1049                                 SET(CMAKE_XCODE_ATTRIBUTE_GCC_VERSION "com.apple.compilers.llvmgcc42")
1050                         ENDIF(XCODE_VERSION VERSION_GREATER "3.1")
1051                 ENDIF(NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
1052                 # Print the selected compiler version
1053         MESSAGE(STATUS "---- Using XCode compiler CMAKE_XCODE_ATTRIBUTE_GCC_VERSION=${CMAKE_XCODE_ATTRIBUTE_GCC_VERSION}")
1054         ENDIF(XCODE_VERSION VERSION_LESS "5.0")
1055 ENDIF(CMAKE_GENERATOR MATCHES Xcode)
1056
1057 if (WIN32 AND Qt5Core_FOUND)
1058         set(Z_PREFIX 1)
1059 endif()
1060
1061 # compiler tests, config.h generation LYX_CONFIGURE_CHECKS
1062 include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
1063 configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
1064
1065 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
1066
1067 if(QTVERSION MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+).*")
1068         MATH(EXPR QT4_VERSION "(${CMAKE_MATCH_1}<<16)|(${CMAKE_MATCH_2}<<8)|${CMAKE_MATCH_3}")
1069 endif()
1070
1071 if (NOT HAVE_REGEX)
1072         set(LYX_USE_STD_REGEX 0)
1073 endif()
1074
1075
1076 set (cmd ${CMAKE_CTEST_COMMAND})
1077 if (MSVC)
1078         set (cmd ${cmd} -C ${CMAKE_CFG_INTDIR})
1079 else ()
1080         set (cmd ${cmd} -C ${CMAKE_BUILD_TYPE})
1081 endif ()
1082 add_custom_target (lyx_run_tests COMMAND ${cmd})
1083 set_target_properties(lyx_run_tests PROPERTIES FOLDER "tests")
1084
1085 if(LYX_ASAN)
1086     set(LYX_CXX_FLAGS "-fsanitize=address -fno-omit-frame-pointer -g")
1087     message(STATUS)
1088     message(STATUS "Address sanitizer enabled. Usage:")
1089     message(STATUS "    wget https://llvm.org/svn/llvm-project/compiler-rt/trunk/lib/asan/scripts/asan_symbolize.py")
1090     message(STATUS "    chmod  +x ./asan_symbolize.py")
1091     message(STATUS "    ./bin/lyx2.2 2>&1 | ./asan_symbolize.py  | c++filt ")
1092     message(STATUS)
1093 endif()
1094
1095 if(LYX_INSTALL)
1096         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
1097                 message(STATUS "Python required to create doc!")
1098         else()
1099                 if(UNIX)
1100                         add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
1101                 endif()
1102                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
1103         endif()
1104 endif()
1105 include(../Install)
1106
1107 # By running the URL tests first, time can be saved when running the ctests in
1108 # parallel since the URL tests take a long time to run (e.g. 10 minutes).
1109 if(LYX_ENABLE_URLTESTS)
1110         add_subdirectory(development/checkurls "${TOP_BINARY_DIR}/checkurls")
1111 endif()
1112 add_subdirectory(src "${TOP_BINARY_DIR}/src")
1113 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
1114 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
1115 add_subdirectory(lib/examples "${TOP_BINARY_DIR}/lib/examples")
1116 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
1117 add_subdirectory(development/autotests "${TOP_BINARY_DIR}/autotests")
1118 add_subdirectory(development/batchtests "${TOP_BINARY_DIR}/batchtests")
1119
1120 message(STATUS)
1121 message(STATUS "Build params, switch LYX_* options by -DLYX_*=ON or OFF, LYX_* combos by -DLYX_*=value:")
1122 message(STATUS)
1123
1124 LYX_OPTION_LIST_ALL(used)
1125
1126
1127 if(LYX_NLS)
1128         message(STATUS)
1129         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
1130         message(STATUS)
1131         message(STATUS "  * iconv")
1132         message(STATUS "     - include: ${ICONV_INCLUDE_DIR}")
1133         message(STATUS "     - library: ${ICONV_LIBRARY}")
1134         message(STATUS "  * zlib")
1135         message(STATUS "     - include: ${ZLIB_INCLUDE_DIR}")
1136         message(STATUS "     - library: ${ZLIB_LIBRARY}")
1137         message(STATUS)
1138 endif()
1139
1140 # Apple has builtin native spell checker,
1141 # no need to warn for missing Aspell, Hunspell or Enchant
1142 if(NOT Spelling_FOUND AND NOT APPLE)
1143   if(LYX_REQUIRE_SPELLCHECK)
1144     set(_mode "FATAL_ERROR")
1145   else()
1146     set(_mode "STATUS")
1147   endif()
1148   message(${_mode} "No spellcheck libraries found. LyX will be unable use spellchecking")
1149 endif()
1150
1151 include("${TOP_CMAKE_PATH}/LyxPackaging.cmake")
1152
1153 if(ENABLE_DIST)
1154   # Use git to create the source package
1155   # git archive --format=tgz --output=/home/kornel/x.tar.gz master
1156   if(UNIX)
1157     set(DIST_FORMAT tgz)
1158   else()
1159     set(DIST_FORMAT zip)
1160   endif()
1161   set(DIST_NAME ${CMAKE_PROJECT_NAME}-${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}-${CMAKE_SYSTEM_NAME}.${DIST_FORMAT})
1162
1163   add_custom_command(
1164     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME}
1165     COMMAND  ${LYX_GITVERSION} archive --format=${DIST_FORMAT} --output=${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME} master
1166     WORKING_DIRECTORY ${TOP_SRC_DIR})
1167   add_custom_target(git-archive DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME})
1168 endif()
1169
1170 # Last directory to be included so that the fixup code (OS X)
1171 # can be run last
1172 add_subdirectory(development/cmake/post_install)
1173
1174 message(STATUS)