CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 2.6.4)
   8
   9 set(LYX_PROJECT LyX)
  10
  11 enable_testing()
  12
  13 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README ABSOLUTE)
  14 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  15
  16 set(LYX_CMAKE_DIR "development/cmake")
  17 set(TOP_CMAKE_PATH "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}")
  18 set(TOP_MODULE_PATH "${TOP_CMAKE_PATH}/modules")
  19 set(TOP_SCRIPT_PATH "${TOP_CMAKE_PATH}/scripts")
  20
  21 set(CMAKE_MODULE_PATH "${TOP_MODULE_PATH}")
  22
  23 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  24
  25 message(STATUS)
  26 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  27         message(STATUS "Building in-source")
  28         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  29 else()
  30         message(STATUS "Building out-of-source")
  31         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  32 endif()
  33
  34 # This directory should be used if some test uses lyx-executable
  35 set(LYX_TESTS_USERDIR "${TOP_BINARY_DIR}/Testing/.lyx")
  36 file(MAKE_DIRECTORY "${LYX_TESTS_USERDIR}")
  37
  38 if(COMMAND cmake_policy)
  39         cmake_policy(SET CMP0003 OLD)
  40         cmake_policy(SET CMP0005 OLD)
  41         # Installing MACOSX_BUNDLE targets requires a BUNDLE DESTINATION
  42         cmake_policy(SET CMP0006 NEW)
  43 endif()
  44
  45 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  46
  47 # Supress regeneration
  48 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  49
  50 if(LYX_XMINGW)
  51     set(CMAKE_SYSTEM_NAME Windows)
  52     set(TOOLNAME ${LYX_XMINGW})
  53     set(TOOLCHAIN "${TOOLNAME}-")
  54     set(CMAKE_C_COMPILER   "${TOOLCHAIN}gcc"     CACHE PATH "Mingw C compiler" FORCE)
  55     set(CMAKE_CXX_COMPILER "${TOOLCHAIN}g++"     CACHE PATH "Mingw C++ compiler" FORCE)
  56     set(CMAKE_RC_COMPILER  "${TOOLCHAIN}windres" CACHE PATH "Mingw rc compiler" FORCE)
  57
  58     set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM BOTH)
  59     set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY)
  60     set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY)
  61 endif()
  62
  63 if(NOT help AND NOT HELP)
  64         # 'project' triggers the searching for a compiler
  65         project(${LYX_PROJECT})
  66 endif()
  67
  68 if(UNIX)
  69         set(ARCH_TRIPLET )
  70         FIND_PROGRAM(DPKG_ARCHITECTURE_EXECUTABLE dpkg-architecture)
  71         if(DPKG_ARCHITECTURE_EXECUTABLE)
  72                 EXECUTE_PROCESS(COMMAND ${DPKG_ARCHITECTURE_EXECUTABLE} -qDEB_HOST_MULTIARCH
  73                                 OUTPUT_VARIABLE ARCH_TRIPLET
  74                                 ERROR_VARIABLE ERROR_ARCH_TRIPLET
  75                                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  76         endif()
  77 endif()
  78 if(ARCH_TRIPLET)
  79         set(SYSTEM_LIB_DIRS /usr/lib /usr/lib/${ARCH_TRIPLET} /usr/local/lib)
  80 else()
  81         set(SYSTEM_LIB_DIRS /usr/lib /usr/local/lib)
  82 endif()
  83
  84 include(LyXMacros)
  85
  86 # Usage LYX_OPTION
  87 # 1. parameter: option name without prefix 'LYX_'
  88 # 2. parameter: description
  89 # 3. parameter: default value, ON or OFF
  90 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
  91
  92 # Usage LYX_COMBO
  93 # 1. parameter: name without prefix 'LYX_'
  94 # 2. parameter: description
  95 # 3. parameter: default value
  96 # 4-n parameter: possible other string values
  97
  98 LYX_OPTION_INIT()
  99
 100 # Options for all compilers/systems
 101 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
 102 LYX_OPTION(LOCALVERSIONING  "Add version info to created package name (only used if LYX_CPACK option set)" OFF ALL)
 103 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
 104 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
 105 LYX_OPTION(REQUIRE_SPELLCHECK "Abort if no spellchecker available" OFF ALL)
 106 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
 107 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
 108 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
 109 LYX_OPTION(DEVEL_VERSION    "Build developer version" OFF ALL)
 110 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" OFF ALL)
 111 LYX_OPTION(DEBUG            "Enforce debug build"  OFF ALL)
 112 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
 113 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
 114 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
 115 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
 116 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
 117 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
 118 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
 119 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
 120 LYX_OPTION(ENABLE_URLTESTS  "Enable for URL tests" OFF ALL)
 121
 122 # GCC specific
 123 LYX_OPTION(PROFILE              "Build profile version" OFF GCC)
 124 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" OFF GCC)
 125 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
 126 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
 127 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++ pedantic debug mode" OFF GCC)
 128 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" OFF GCC)
 129 LYX_OPTION(CONCEPT_CHECKS       "Enable concept-checks" OFF GCC)
 130 LYX_OPTION(PROFILE              "Build with options for gprof" OFF GCC)
 131 LYX_OPTION(ENABLE_CXX11         "Build with options for c++11-mode" OFF GCC)
 132
 133 # MSVC specific
 134 LYX_OPTION(CONSOLE               "Show console on Windows, enforce with =FORCE" ON MSVC)
 135 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
 136 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
 137 LYX_OPTION(CONFIGURE_CHECKS      "Also run configure checks for MSVC" OFF MSVC)
 138 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
 139
 140 # APPLE specific
 141 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
 142 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
 143 LYX_COMBO(USE_QT                 "Use Qt version as frontend (QT4 QT5)" QT4 QT5)
 144
 145
 146 if(help OR HELP)
 147         message(STATUS)
 148         message(STATUS "Available options: (dis/enable with -DLYX_*=OFF/ON)")
 149         message(STATUS)
 150         LYX_OPTION_LIST_ALL(help)
 151         message(STATUS)
 152         RETURN()
 153 endif()
 154
 155 # Check option dependencies
 156
 157 if(LYX_DMG)
 158         set(LYX_BUNDLE ON)
 159         set(LYX_CPACK ON)
 160 endif()
 161
 162 if(LYX_CPACK)
 163         set(LYX_INSTALL ON)
 164 endif()
 165
 166 if(LYX_INSTALL)
 167         set(LYX_NLS ON)
 168         if(WIN32 AND NOT MINGW)
 169                 set(LYX_HUNSPELL ON)
 170         endif()
 171         if(LYX_CONSOLE MATCHES "FORCE")
 172                 set(LYX_CONSOLE ON)
 173         else()
 174                 set(LYX_CONSOLE OFF)
 175         endif()
 176         set(LYX_PACKAGE_SUFFIX ON)
 177         if(NOT LYX_DEBUG)
 178                 set(LYX_RELEASE ON)
 179         endif()
 180         set(LYX_PROFILE OFF)
 181 endif()
 182
 183
 184 if(LYX_MERGE_FILES)
 185         set(LYX_PCH OFF)
 186 else()
 187         set(LYX_MERGE_REBUILD OFF)
 188 endif()
 189
 190
 191 if(LYX_DEPENDENCIES_DOWNLOAD)
 192         message(STATUS)
 193         set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 194         message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 195         set(deps_files lyx20-deps-msvc2010-x86.zip)
 196         set(deps_server http://downloads.sourceforge.net/project/lyx/Win_installers/Dependencies)
 197         foreach(it ${deps_files})
 198                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 199                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 200                 if(NOT already_downloaded)
 201                         message(STATUS "Downloading ${it} ...")
 202                         file(DOWNLOAD ${deps_server}/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS STATUS status LOG log)
 203                         list(GET status 0 status_code)
 204                         list(GET status 1 status_string)
 205                         if(NOT status_code EQUAL 0)
 206                                 file(REMOVE ${LYX_DEPENDENCIES_DIR}/${it})
 207                                 message(FATAL_ERROR "error: downloading '${it}' failed. status_code: ${status_code}, status_string: ${status_string}. \nLog: ${log} ")
 208                         endif()
 209                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 210                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 211                 endif()
 212         endforeach()
 213         set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/deps20)
 214     if(MSVC12)
 215         # handle error in msvc12 when linking against msvc10 libs
 216         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /vd2")
 217     endif()
 218 endif()
 219
 220
 221
 222 message(STATUS)
 223
 224 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 225 if(WIN32)
 226         set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 227 else()
 228         set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 229 endif()
 230
 231
 232 set(LYX_GCC11_MODE)
 233 if(UNIX OR MINGW)
 234         execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION)
 235         message(STATUS "Using GCC version ${GCC_VERSION}")
 236         if(NOT GCC_VERSION VERSION_LESS 4.4)
 237                 set(LYX_USE_TR1 1)
 238                 # GCC <= 4.5 does not support regex: there are linker errors
 239                 # http://gcc.gnu.org/onlinedocs/libstdc++/manual/status.html#status.iso.tr1
 240                 set(LYX_USE_TR1_REGEX 0)
 241         endif()
 242         if (LYX_ENABLE_CXX11)
 243                 find_package(CXX11Compiler)
 244                 if(NOT CXX11COMPILER_FOUND)
 245                         message(FATAL_ERROR "A C++11 compatible compiler is required.")
 246                 endif()
 247                 set(LYX_GCC11_MODE "${CXX11_FLAG}")
 248         endif()
 249 else()
 250         if(MSVC10)
 251                 set(LYX_USE_TR1 1)
 252                 #set(LYX_USE_TR1_REGEX 1) #TODO should we use it in ECMAScript mode?
 253         endif()
 254 endif()
 255
 256
 257 set(VERSION_INFO "CMake Build")
 258
 259 # Try to get some informations from configure.ac
 260
 261 include(LyXPaths)
 262 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 263
 264 if(WIN32)
 265         set(USE_WINDOWS_PACKAGING ON)
 266 elseif(APPLE)
 267         set(USE_MACOSX_PACKAGING ON)
 268 else()
 269         set(USE_POSIX_PACKAGING ON)
 270 endif()
 271
 272 macro(setstripped _varname)
 273         if(${ARGC} GREATER 1)
 274                 string(STRIP "${ARGV1}" _v)
 275                 if(USE_POSIX_PACKAGING)
 276                         string(TOLOWER ${_v} ${_varname})
 277                 else()
 278                         set(${_varname} ${_v})
 279                 endif()
 280         else()
 281                 set(${_varname})
 282         endif()
 283 endmacro(setstripped)
 284
 285 foreach(_c_l ${_config_lines} )
 286         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 287                 setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 288                 setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 289                 setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 290                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\)\(\\.\([0-9]+\)\)?.*$")
 291                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 292                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 293                         set(LYX_PATCH_VERSION ${CMAKE_MATCH_4})
 294                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 295                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 296                         set(LYX_INSTALL_SUFFIX "${CMAKE_MATCH_1}.${CMAKE_MATCH_2}")
 297                 endif()
 298         endif()
 299         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 300                 set(LYX_DATE "${CMAKE_MATCH_1}")
 301         endif()
 302 endforeach(_c_l)
 303
 304 if (LYX_LOCALVERSIONING)
 305         # Find the revision number and for later use
 306         FIND_PROGRAM(LYX_GITVERSION git)
 307         #message(STATUS "gitversion = ${LYX_GITVERSION}")
 308         if(LYX_GITVERSION)
 309                 EXECUTE_PROCESS(COMMAND ${LYX_GITVERSION} describe --match 2.0.0 HEAD
 310                 WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE LYX_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 311                 if (LYX_PACKAGE_RELEASE MATCHES "^2\\.0\\.0\\-\([0-9]+\)\\-.*$")
 312                   # We will add offset of 40000 to get appropriate value to
 313                   # previous svn.
 314                   # We use this value than also to set the package-patch-value
 315                   MATH(EXPR tmp_REVISION_VERSION "(${CMAKE_MATCH_1}+40000)")
 316                   set(LYX_REVISION_VERSION "${LYX_PATCH_VERSION}-${tmp_REVISION_VERSION}git")
 317                   set(ENABLE_DIST ON)
 318                 endif()
 319         else()
 320                 set(LYX_REVISION_VERSION git) #TODO use date
 321         endif()
 322 else()
 323         set(LYX_REVISION_VERSION ${LYX_PATCH_VERSION})
 324 endif()
 325
 326 # Set the programs (lyx, tex2lyx, etc.) suffix
 327 # When building an OS X bundle, we will append
 328 # the suffix only to the bundle, not to the programs
 329 set(PROGRAM_SUFFIX "")
 330 if(LYX_PROGRAM_SUFFIX AND NOT (APPLE AND LYX_BUNDLE))
 331         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 332 endif()
 333 set(_lyx "${PACKAGE_BASE}${PROGRAM_SUFFIX}")
 334 set(_tex2lyx tex2lyx${PROGRAM_SUFFIX})
 335
 336 add_custom_target(lyx_version ALL
 337   COMMAND ${CMAKE_COMMAND} -DTOP_SRC_DIR=${TOP_SRC_DIR} -DTOP_CMAKE_PATH=${TOP_CMAKE_PATH} -DTOP_BINARY_DIR=${TOP_BINARY_DIR} -DLYX_DATE=${LYX_DATE} -P ${TOP_SCRIPT_PATH}/LyXGetVersion.cmake
 338   )
 339 set_target_properties(lyx_version PROPERTIES FOLDER "applications")
 340
 341 # Default paths for installed utilities (tex2lyx, lyxclient, etc.)
 342 set(LYX_UTILITIES_INSTALL_PATH bin)
 343
 344 if(LYX_BUNDLE)
 345         set(LYX_CPACK ON)
 346
 347         message(STATUS)
 348         message(STATUS "Bundle creation is enabled (experimental):")
 349         message(STATUS "    make")
 350         message(STATUS "    make install/strip")
 351         message(STATUS "    make package")
 352         if(APPLE)
 353                 set(MACOSX_BUNDLE TRUE)
 354                 # This sets the bundle + executable names
 355                 set(_lyx "${PACKAGE_BASE}${LYX_INSTALL_SUFFIX}")
 356                 # This sets the Info.plist executable name
 357                 set(osx_bundle_program_name ${_lyx})
 358                 # Bundle name
 359                 set(LYX_BUNDLE_NAME ${_lyx})
 360
 361                 # This will contain the list of files that need to be included
 362                 # in the bundle and their location within the bundle
 363                 set(OSX_BUNDLE_FILES "${TOP_SRC_DIR}/development/MacOSX/LyX.sdef;${TOP_SRC_DIR}/development/MacOSX/LyXapp.icns;${CMAKE_BINARY_DIR}/lyxrc.dist")
 364                 set(OSX_BUNDLE_DIRS "Resources;Resources;Resources")
 365
 366                 # Process Info.plist and lyxrc.dist
 367                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/Info.plist.in" "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 368                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/lyxrc.dist.in" "${CMAKE_CURRENT_BINARY_DIR}/lyxrc.dist")
 369
 370                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 371                 set(LYX_DATA_SUBDIR ${LYX_BUNDLE_NAME}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 372
 373                 # Variables used by CPack
 374                 set(CPACK_BUNDLE_NAME ${LYX_BUNDLE_NAME})
 375                 set(CPACK_BUNDLE_PLIST "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 376                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${LYX_BUNDLE_NAME}.app)
 377
 378                 # Set the install paths
 379                 set(LYX_UTILITIES_INSTALL_PATH ${LYX_BUNDLE_NAME}.app/Contents/MacOS)
 380                 if(NOT LYX_INSTALL_PREFIX)
 381                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 382                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 383                 endif()
 384                 # Change the owner so that the install can work
 385                 install(CODE "set(BU_CHMOD_BUNDLE_ITEMS 1)" COMPONENT Runtime)
 386         elseif(UNIX)
 387                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 388                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 389                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 390         elseif(WIN32)
 391                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 392         endif()
 393 endif()
 394
 395 if(LYX_INSTALL_PREFIX)
 396         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 397         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 398 endif()
 399 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 400
 401 string(REGEX REPLACE "/lyx${LYX_INSTALL_SUFFIX}$" "/share" SYSTEM_DATADIR ${CMAKE_INSTALL_PREFIX})
 402
 403 if(LYX_PACKAGE_SUFFIX)
 404         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 405 else()
 406         set(PACKAGE ${PACKAGE_BASE})
 407 endif()
 408
 409 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 410         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 411         if (UNIX)
 412                 # don't use the default "/usr/local"
 413                 # but respect the user-choice on the command-line
 414                 if(LYX_INSTALL_SUFFIX)
 415                         set(CMAKE_INSTALL_PREFIX "/usr/local/lyx${LYX_INSTALL_SUFFIX}" CACHE PATH "LyX default install prefix" FORCE)
 416                 else()
 417                         set(CMAKE_INSTALL_PREFIX "/usr/local/${LYX_PROJECT}" CACHE PATH "LyX default install prefix" FORCE)
 418                 endif()
 419         endif()
 420         if(WIN32)
 421                 set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 422         endif()
 423 endif()
 424 if(IS_ABSOLUTE)
 425         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 426 else()
 427         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 428 endif()
 429
 430
 431
 432 if(NOT LYX_DATA_SUBDIR)
 433         if (WIN32)
 434                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 435         else()
 436                 set(LYX_DATA_SUBDIR "" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 437         endif()
 438 endif()
 439
 440 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 441 set(LYX_LOCALEDIR "locale")
 442 set(LYX_ABS_INSTALLED_LOCALEDIR "${LYX_ABS_INSTALLED_DATADIR}/${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}")
 443 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 444
 445 if(LYX_BUNDLE AND APPLE)
 446         set(LYX_MAN_DIR "${LYX_DATA_SUBDIR}" CACHE STRING "Install location for man pages.")
 447 else()
 448         set(LYX_MAN_DIR "/usr/local/man/man1" CACHE STRING "Install location for man pages.")
 449 endif()
 450 mark_as_advanced(LYX_MAN_DIR)
 451
 452 if(LYX_INSTALL AND WIN32)
 453         message(STATUS "Configuring NSIS files")
 454         configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 455         configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 456         configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 457         message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 458 endif()
 459
 460 if(NOT GROUP_CODE)
 461         #set(GROUP_CODE "The Golden Code")
 462         set(GROUP_CODE flat)
 463 endif()
 464
 465 # lyx's source files
 466 set(LYX_CPP_FILES *.cpp)
 467 set(LYX_HPP_FILES *.h)
 468 set(LYX_MOC_FILES moc_*.cpp)
 469
 470 include(ProjectSourceGroup)
 471
 472
 473 if(LYX_PROFILE AND NOT MSVC)
 474         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 475         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg")
 476         set(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS}  -pg")
 477 else()
 478         set(LYX_PROFILE OFF)
 479 endif()
 480
 481
 482 if(LYX_NO_OPTIMIZE)
 483         set(CMAKE_BUILD_TYPE None)
 484         set(LYX_DEBUG OFF)
 485         set(LYX_RELEASE OFF)
 486         set(LYX_PROFILE OFF)
 487 elseif(LYX_RELEASE)
 488         set(CMAKE_BUILD_TYPE Release)
 489         set(LYX_DEBUG OFF)
 490         set(LYX_PROFILE OFF)
 491 elseif(LYX_PROFILE)
 492         set(CMAKE_BUILD_TYPE Profile)
 493         set(LYX_DEBUG OFF)
 494 else()
 495         set(CMAKE_BUILD_TYPE Debug)
 496         set(LYX_DEBUG ON)
 497 endif()
 498
 499
 500 # When shared libs are supported enable this option
 501 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 502 if(LYX_SHARED_LIBRARIES)
 503         set(library_type SHARED)
 504 else()
 505         set(library_type STATIC)
 506 endif()
 507
 508 if(NOT MSVC)
 509         if(NOT LYX_QUIET)
 510                 set(CMAKE_VERBOSE_MAKEFILE ON)
 511         endif()
 512         set(LYX_CXX_FLAGS "-Wall -Wunused-parameter ${LYX_GCC11_MODE}")
 513         if(LYX_STDLIB_DEBUG)
 514                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 515         endif()
 516         if(LYX_CONCEPT_CHECKS)
 517                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCPP_CONCEPT_CHECKS")
 518         endif()
 519         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 520         set(CMAKE_CXX_FLAGS_DEBUG "${LYX_CXX_FLAGS} -fno-strict-aliasing -O0 -g3 -D_DEBUG" CACHE TYPE STRING FORCE)
 521         if(MINGW)
 522                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 523         else()
 524                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 525         endif()
 526 endif()
 527
 528 set(LYX_CXX_FLAGS_EXTRA "" CACHE STRING "Desired semicolon separated list of extra cxx compile flags, like '-Werror'")
 529 mark_as_advanced(LYX_CXX_FLAGS_EXTRA)
 530 if(LYX_CXX_FLAGS_EXTRA)
 531         foreach(_flag ${LYX_CXX_FLAGS_EXTRA})
 532                 add_definitions(${_flag})
 533         endforeach()
 534 endif()
 535
 536 if(LYX_XMINGW)
 537     set(QT_MINGW_DIR ${LYX_QT4} CACHE PATH "Qt for Mingw" FORCE)
 538     list(APPEND CMAKE_FIND_ROOT_PATH ${QT_MINGW_DIR} ${GNUWIN32_DIR})
 539 else()
 540     find_package(Qt5Core QUIET)
 541 endif()
 542 if (Qt5Core_FOUND)
 543         find_package(Qt5Widgets REQUIRED)
 544         find_package(Qt5X11Extras)
 545         set(QTVERSION ${Qt5Core_VERSION})
 546         macro (qt_use_modules)
 547                 qt5_use_modules(${ARGN})
 548         endmacro()
 549         macro (qt_add_resources)
 550                 qt5_add_resources(${ARGN})
 551         endmacro()
 552         macro (qt_wrap_uifiles)
 553                 qt5_wrap_ui(${ARGN})
 554         endmacro()
 555 else()
 556         find_package(Qt4 "4.5.0" REQUIRED)
 557         macro (qt_use_modules)
 558         endmacro()
 559         macro (qt_add_resources)
 560                 qt4_add_resources(${ARGN})
 561         endmacro()
 562         macro (qt_wrap_uifiles)
 563                 qt4_wrap_ui(${ARGN})
 564         endmacro()
 565 endif()
 566
 567 find_package(Magic)
 568 if(Magic_FOUND)
 569         set(HAVE_MAGIC_H 1)
 570 endif()
 571
 572 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 573
 574 set(Spelling_FOUND OFF)
 575 set(Include_used_spellchecker)   # String will be inserted into config.h
 576
 577 foreach(_spell "ASPELL" "Enchant" "Hunspell")
 578   string(TOUPPER ${_spell} _upspell)
 579   find_package(${_spell})
 580   if (${_upspell}_FOUND)
 581     include_directories(${${_upspell}_INCLUDE_DIR})
 582     set(Spelling_FOUND ON)
 583     message(STATUS "Building with USE_${_upspell}")
 584     set(Include_used_spellchecker "${Include_used_spellchecker}#define USE_${_upspell} 1\n")
 585   else()
 586     if(LYX_${_upspell})
 587       message(FATAL_ERROR "Required ${_spell} devel package not found")
 588     else()
 589       message(STATUS "${_upspell} not found, building without ${_spell} support")
 590     endif()
 591   endif()
 592 endforeach()
 593
 594 if(LYX_NLS)
 595         FIND_PROGRAM(LYX_PYTHON_EXECUTABLE python2 python HINTS ${GNUWIN32_DIR}/python)
 596         find_package(LyXGettext)
 597         if(LYX_PYTHON_EXECUTABLE AND GETTEXT_FOUND)
 598                 add_subdirectory(po "${TOP_BINARY_DIR}/po")
 599         else()
 600                 # Install only supplied .gmo-files
 601                 file(GLOB _gmofiles RELATIVE "${TOP_SRC_DIR}/po" "${TOP_SRC_DIR}/po/*.gmo")
 602                 message(STATUS "Installing provided .gmo-files only")
 603                 foreach( _gmo ${_gmofiles})
 604                         string(REGEX REPLACE "\\.gmo$" "" _lang ${_gmo})
 605                         install(FILES "${TOP_SRC_DIR}/po/${_gmo}" DESTINATION ${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}/${_lang}/LC_MESSAGES RENAME ${PACKAGE}.mo)
 606                 endforeach()
 607         endif()
 608 endif()
 609
 610
 611 find_package(ICONV REQUIRED)
 612 find_package(ZLIB REQUIRED)
 613
 614 if(LYX_EXTERNAL_BOOST)
 615         message(STATUS "Searching for boost")
 616         find_package(Boost COMPONENTS signals regex) #TODO could REQUIRED be used
 617         if(Boost_FOUND)
 618                 message(STATUS "Boost found")
 619                 message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 620                 set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 621         else()
 622                 message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 623         endif()
 624 else()
 625         if(LYX_USE_TR1_REGEX)
 626                 set(Lyx_Boost_Libraries boost_signals)
 627         else()
 628                 set(Lyx_Boost_Libraries boost_signals boost_regex)
 629         endif()
 630         add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 631         add_definitions(-DBOOST_SIGNALS_NO_DEPRECATION_WARNING=1)
 632         include_directories(${TOP_SRC_DIR}/boost)
 633         add_subdirectory(boost "${TOP_BINARY_DIR}/boost")
 634 endif()
 635
 636
 637
 638
 639 if(WIN32)
 640         if(NOT LYX_CONSOLE)
 641                 set(WIN32_CONSOLE WIN32)
 642                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARY})
 643         endif()
 644         if(MSVC)
 645                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 646                 # disable checked iterators for msvc release builds to get maximum speed
 647                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 648         else()
 649                 add_definitions(-DWINVER=0x0500)
 650         endif()
 651 endif()
 652
 653 # Compute qt4-version from ${QTVERSION}
 654
 655 message(STATUS "")
 656 foreach(_v PACKAGE PACKAGE_VERSION
 657         PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 658         LYX_ABS_TOP_SRCDIR
 659         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 660         if(NOT DEFINED ${_v})
 661                 message(FATAL_ERROR "${_v} not defined")
 662         endif()
 663         string(SUBSTRING "${_v}                            " 0 28 _v1)
 664         message(STATUS "----- ${_v1}: ${${_v}}")
 665 endforeach(_v)
 666 message(STATUS "")
 667
 668
 669 if(LYX_PCH)
 670         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 671         # Not sure if it works for all non-msvc compilers
 672         include(PCHSupport_26)
 673         configure_file(${TOP_CMAKE_PATH}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
 674         configure_file(${TOP_CMAKE_PATH}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 675         add_definitions(-DLYX_ENABLE_PCH)
 676
 677         if(MSVC)
 678                 macro(lyx_add_msvc_pch name_)
 679                         set_source_files_properties(${${name_}_sources} PROPERTIES
 680                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 681                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
 682                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 683                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
 684                                 ${TOP_BINARY_DIR}/pcheaders.h)
 685                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 686                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 687                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 688                 endmacro(lyx_add_msvc_pch)
 689                 macro(lyx_add_gcc_pch name_)
 690                 endmacro()
 691         else()
 692                 macro(lyx_add_msvc_pch name_)
 693                 endmacro()
 694                 macro(lyx_add_gcc_pch name_)
 695                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT4)
 696                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
 697                 endmacro()
 698         endif()
 699 else()
 700         macro(lyx_add_msvc_pch)
 701         endmacro(lyx_add_msvc_pch)
 702         macro(lyx_add_gcc_pch name_)
 703         endmacro()
 704 endif()
 705
 706
 707 if(MSVC)
 708
 709         if(LYX_VLD)
 710                 set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/development/Win32/vld)
 711                 add_subdirectory(${vld_path}/cmake)
 712                 include(${vld_path}/cmake/vld.cmake) # forced include
 713                 set(vld_dll vld)
 714         endif()
 715
 716         if(LYX_WALL)
 717                 # Use the highest warning level
 718                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 719
 720                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 721                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 722                 else()
 723                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 724                 endif()
 725
 726                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 727                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 728                 else()
 729                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 730                 endif()
 731
 732                 # add here warnings which should produce an error /weXXXX
 733                 set(MSVC_W_ERROR   "/we4101 /we4189")
 734                 # add here warnings which should be disabled /wdXXXX
 735                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 736
 737                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 738                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 739                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 740
 741         else()
 742                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 743
 744                 # add here warnings which should produce an error /weXXXX
 745                 set(MSVC_W_ERROR   "/we4101 /we4189")
 746                 # add here warnings which should be disabled /wdXXXX
 747                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 748
 749                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 750                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 751                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 752
 753         endif()
 754
 755         if (NOT Qt5Core_FOUND)
 756                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 757                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 758                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 759         endif()
 760
 761         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 762         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 763         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 764         message(STATUS "")
 765 endif()
 766
 767
 768 if(LYX_DEBUG_GLIBC)
 769         set(_GLIBCXX_DEBUG ON)
 770 endif()
 771
 772 if(LYX_DEBUG_GLIBC_PEDANTIC)
 773         set(_GLIBCXX_DEBUG_PEDANTIC ON)
 774 endif()
 775
 776 # Xcode compiler
 777 if (CMAKE_GENERATOR MATCHES Xcode)
 778         if (XCODE_VERSION VERSION_LESS "5.0")
 779                 # Automatically select the Xcode compiler if not set
 780                 if (NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 781                         # XCode >= 3.1 has gcc 4.2 (up to actual Xcode)
 782                         if (XCODE_VERSION VERSION_GREATER "3.1")
 783                                 SET(CMAKE_XCODE_ATTRIBUTE_GCC_VERSION "com.apple.compilers.llvmgcc42")
 784                         ENDIF(XCODE_VERSION VERSION_GREATER "3.1")
 785                 ENDIF(NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 786                 # Print the selected compiler version
 787         MESSAGE(STATUS "---- Using XCode compiler CMAKE_XCODE_ATTRIBUTE_GCC_VERSION=${CMAKE_XCODE_ATTRIBUTE_GCC_VERSION}")
 788         ENDIF(XCODE_VERSION VERSION_LESS "5.0")
 789 ENDIF(CMAKE_GENERATOR MATCHES Xcode)
 790
 791 if (WIN32 AND Qt5Core_FOUND)
 792         set(Z_PREFIX 1)
 793 endif()
 794
 795 # compiler tests, config.h generation
 796 if(MSVC AND NOT LYX_CONFIGURE_CHECKS)
 797         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.msvc ${TOP_BINARY_DIR}/configCompiler.h)
 798 else()
 799         include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
 800         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
 801 endif()
 802
 803 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
 804
 805 if(QTVERSION MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+).*")
 806         MATH(EXPR QT4_VERSION "(${CMAKE_MATCH_1}<<16)|(${CMAKE_MATCH_2}<<8)|${CMAKE_MATCH_3}")
 807 endif()
 808
 809
 810 set (cmd ${CMAKE_CTEST_COMMAND})
 811 if (MSVC)
 812         set (cmd ${cmd} -C ${CMAKE_CFG_INTDIR})
 813 else ()
 814         set (cmd ${cmd} -C ${CMAKE_BUILD_TYPE})
 815 endif ()
 816 add_custom_target (lyx_run_tests COMMAND ${cmd})
 817 set_target_properties(lyx_run_tests PROPERTIES FOLDER "tests")
 818
 819
 820 if(LYX_INSTALL)
 821         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 822                 message(STATUS "Python required to create doc!")
 823         else()
 824                 if(UNIX)
 825                         add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
 826                 endif()
 827                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
 828         endif()
 829         include(../Install)
 830 endif()
 831
 832 add_subdirectory(src "${TOP_BINARY_DIR}/src")
 833 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
 834 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
 835 add_subdirectory(lib/examples "${TOP_BINARY_DIR}/lib/examples")
 836 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
 837 add_subdirectory(development/autotests "${TOP_BINARY_DIR}/autotests")
 838 if(LYX_ENABLE_URLTESTS)
 839         add_subdirectory(development/checkurls "${TOP_BINARY_DIR}/checkurls")
 840 endif()
 841
 842 message(STATUS)
 843 message(STATUS "Build params, switch LYX_* options by -DLYX_*=ON or OFF, LYX_* combos by -DLYX_*=value:")
 844 message(STATUS)
 845
 846 LYX_OPTION_LIST_ALL(used)
 847
 848
 849 if(LYX_NLS)
 850         message(STATUS)
 851         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
 852         message(STATUS)
 853         message(STATUS "  * iconv")
 854         message(STATUS "     - header : ${ICONV_HEADER}")
 855         message(STATUS "     - library: ${ICONV_LIBRARY}")
 856         message(STATUS "  * zlib")
 857         message(STATUS "     - header : ${ZLIB_HEADER}")
 858         message(STATUS "     - library: ${ZLIB_LIBRARY}")
 859         message(STATUS)
 860 endif()
 861
 862 if(NOT Spelling_FOUND)
 863   if(LYX_REQUIRE_SPELLCHECK)
 864     set(_mode "FATAL_ERROR")
 865   else()
 866     set(_mode "STATUS")
 867   endif()
 868   message(${_mode} "No spellcheck libraries found. Lyx will be unable use spellchecking")
 869 endif()
 870
 871 include("${TOP_CMAKE_PATH}/LyxPackaging.cmake")
 872
 873 if(ENABLE_DIST)
 874   # Use git to create the source package
 875   # git archive --format=tgz --output=/home/kornel/x.tar.gz master
 876   if(UNIX)
 877     set(DIST_FORMAT tgz)
 878   else()
 879     set(DIST_FORMAT zip)
 880   endif()
 881   set(DIST_NAME ${CMAKE_PROJECT_NAME}-${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}-${CMAKE_SYSTEM_NAME}.${DIST_FORMAT})
 882
 883   add_custom_command(
 884     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME}
 885     COMMAND  ${LYX_GITVERSION} archive --format=${DIST_FORMAT} --output=${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME} master
 886     WORKING_DIRECTORY ${TOP_SRC_DIR})
 887   add_custom_target(git-archive DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME})
 888 endif()
 889
 890 # Last directory to be included so that the fixup code (OS X)
 891 # can be run last
 892 add_subdirectory(development/cmake/post_install)
 893
 894 message(STATUS)