CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 2.6.4)
   8
   9 set(LYX_PROJECT LyX)
  10
  11 enable_testing()
  12
  13 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README REALPATH) # Resolve symlinks
  14 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  15 message(STATUS "TOP_SRC_DIR = ${TOP_SRC_DIR}")
  16
  17 set(LYX_CMAKE_DIR "development/cmake")
  18 set(TOP_CMAKE_PATH "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}")
  19 set(TOP_MODULE_PATH "${TOP_CMAKE_PATH}/modules")
  20 set(TOP_SCRIPT_PATH "${TOP_CMAKE_PATH}/scripts")
  21
  22 set(CMAKE_MODULE_PATH "${TOP_MODULE_PATH}")
  23
  24 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  25
  26 message(STATUS)
  27 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  28         message(STATUS "Building in-source")
  29         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  30 else()
  31         message(STATUS "Building out-of-source")
  32         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  33 endif()
  34
  35 # This directory should be used if some test uses lyx-executable
  36 set(LYX_TESTS_USERDIR "${TOP_BINARY_DIR}/Testing/.lyx")
  37 file(MAKE_DIRECTORY "${LYX_TESTS_USERDIR}")
  38
  39 if(COMMAND cmake_policy)
  40         cmake_policy(SET CMP0003 OLD)
  41         cmake_policy(SET CMP0005 OLD)
  42         # Installing MACOSX_BUNDLE targets requires a BUNDLE DESTINATION
  43         cmake_policy(SET CMP0006 NEW)
  44         if(POLICY CMP0020)
  45                 cmake_policy(SET CMP0020 OLD)
  46         endif()
  47         if(POLICY CMP0028)
  48                 cmake_policy(SET CMP0028 OLD)
  49         endif()
  50         if(POLICY CMP0043)
  51                 # COMPILE_DEFINITIONS are not used yet. Enable new behavior.
  52                 cmake_policy(SET CMP0043 NEW)
  53         endif()
  54 endif()
  55
  56 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  57
  58 # Supress regeneration
  59 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  60
  61 if(LYX_XMINGW)
  62     set(CMAKE_SYSTEM_NAME Windows)
  63     set(TOOLNAME ${LYX_XMINGW})
  64     set(TOOLCHAIN "${TOOLNAME}-")
  65     set(CMAKE_C_COMPILER   "${TOOLCHAIN}gcc"     CACHE PATH "Mingw C compiler" FORCE)
  66     set(CMAKE_CXX_COMPILER "${TOOLCHAIN}g++"     CACHE PATH "Mingw C++ compiler" FORCE)
  67     set(CMAKE_RC_COMPILER  "${TOOLCHAIN}windres" CACHE PATH "Mingw rc compiler" FORCE)
  68
  69     set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM BOTH)
  70     set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY)
  71     set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY)
  72 endif()
  73
  74 if(NOT help AND NOT HELP)
  75   # 'project' triggers the searching for a compiler
  76   project(${LYX_PROJECT})
  77   if (CMAKE_COMPILER_IS_GNUCXX)
  78     if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS "4.0")
  79       message(STATUS "Gnu CXX compiler version = ${CMAKE_CXX_COMPILER_VERSION}")
  80       message(STATUS "is too old, should be >= 4.0")
  81       message(FATAL_ERROR "Exiting")
  82     endif()
  83   endif()
  84 endif()
  85
  86 if(UNIX)
  87         set(ARCH_TRIPLET )
  88         FIND_PROGRAM(DPKG_ARCHITECTURE_EXECUTABLE dpkg-architecture)
  89         if(DPKG_ARCHITECTURE_EXECUTABLE)
  90                 EXECUTE_PROCESS(COMMAND ${DPKG_ARCHITECTURE_EXECUTABLE} -qDEB_HOST_MULTIARCH
  91                                 OUTPUT_VARIABLE ARCH_TRIPLET
  92                                 ERROR_VARIABLE ERROR_ARCH_TRIPLET
  93                                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  94         endif()
  95 endif()
  96 if(ARCH_TRIPLET)
  97         set(SYSTEM_LIB_DIRS /usr/lib /usr/lib/${ARCH_TRIPLET} /usr/local/lib)
  98 else()
  99         set(SYSTEM_LIB_DIRS /usr/lib /usr/local/lib)
 100 endif()
 101
 102 include(LyXMacros)
 103 include(LyXDestinations)
 104
 105 # Usage LYX_OPTION
 106 # 1. parameter: option name without prefix 'LYX_'
 107 # 2. parameter: description
 108 # 3. parameter: default value, ON or OFF
 109 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
 110
 111 # Usage LYX_COMBO
 112 # 1. parameter: name without prefix 'LYX_'
 113 # 2. parameter: description
 114 # 3. parameter: default value
 115 # 4-n parameter: possible other string values
 116
 117 LYX_OPTION_INIT()
 118
 119 # Options for all compilers/systems
 120 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
 121 LYX_OPTION(LOCALVERSIONING  "Add version info to created package name (only used if LYX_CPACK option set)" OFF ALL)
 122 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
 123 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
 124 LYX_OPTION(REQUIRE_SPELLCHECK "Abort if no spellchecker available" OFF ALL)
 125 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
 126 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
 127 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
 128 LYX_OPTION(DEVEL_VERSION    "Build developer version" OFF ALL)
 129 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" OFF ALL)
 130 LYX_OPTION(DEBUG            "Enforce debug build"  OFF ALL)
 131 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
 132 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
 133 LYX_STRING(SUFFIX_VALUE     "Use this string as suffix" "")
 134 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
 135 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
 136 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
 137 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
 138 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
 139 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
 140 LYX_OPTION(ENABLE_URLTESTS  "Enable for URL tests" OFF ALL)
 141 LYX_OPTION(ENABLE_EXPORT_TESTS "Enable for export tests" OFF ALL)
 142 LYX_OPTION(ENABLE_KEYTESTS  "Enable for keytests" OFF ALL)
 143 LYX_OPTION(ASAN             "Use address sanitizer" OFF ALL)
 144 LYX_COMBO(USE_QT            "Use Qt version as frontend" QT4 QT5)
 145 #LYX_OPTION(3RDPARTY_BUILD   "Build 3rdparty libs" OFF ALL)
 146 LYX_OPTION(EXTERNAL_Z       "Build 3rdparty lib zlib" ON ALL)
 147 LYX_OPTION(EXTERNAL_ICONV   "Build 3rdparty lib iconvlib" ON ALL)
 148 LYX_OPTION(EXTERNAL_HUNSPELL "Build 3rdparty lib hunspelllib" ON ALL)
 149
 150 # GCC specific
 151 LYX_OPTION(PROFILE              "Build profile version" OFF GCC)
 152 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" OFF GCC)
 153 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
 154 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
 155 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++ pedantic debug mode" OFF GCC)
 156 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" OFF GCC)
 157 LYX_OPTION(PROFILE              "Build with options for gprof" OFF GCC)
 158
 159 # MSVC specific
 160 LYX_OPTION(CONSOLE               "Show console on Windows, enforce with =FORCE" ON MSVC)
 161 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
 162 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
 163 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
 164
 165 # APPLE specific
 166 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
 167 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
 168
 169
 170 if(help OR HELP)
 171         message(STATUS)
 172         message(STATUS "Available options: (dis/enable with -DLYX_*=OFF/ON)")
 173         message(STATUS)
 174         LYX_OPTION_LIST_ALL(help)
 175         message(STATUS)
 176         RETURN()
 177 endif()
 178
 179 # Check option dependencies
 180
 181 if(LYX_DMG)
 182         set(LYX_BUNDLE ON)
 183         set(LYX_CPACK ON)
 184 endif()
 185
 186 if(LYX_CPACK)
 187         set(LYX_INSTALL ON)
 188 endif()
 189
 190 if(LYX_INSTALL)
 191         set(LYX_NLS ON)
 192         if(WIN32 AND NOT MINGW)
 193                 set(LYX_HUNSPELL ON)
 194         endif()
 195         if(LYX_CONSOLE MATCHES "FORCE")
 196                 set(LYX_CONSOLE ON)
 197         else()
 198                 set(LYX_CONSOLE OFF)
 199         endif()
 200         set(LYX_PACKAGE_SUFFIX ON)
 201         if(NOT LYX_DEBUG)
 202                 set(LYX_RELEASE ON)
 203         endif()
 204         set(LYX_PROFILE OFF)
 205 endif()
 206
 207
 208 if(LYX_MERGE_FILES)
 209         set(LYX_PCH OFF)
 210 else()
 211         set(LYX_MERGE_REBUILD OFF)
 212 endif()
 213
 214 if(LYX_DEPENDENCIES_DOWNLOAD)
 215         message(STATUS)
 216         if(MSVC14)
 217                 set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2015-deps)
 218                 set(deps_files lyx-windows-deps-msvc2015.zip)
 219                 set(deps_server http://ftp.lyx.de/LyX-Windows-Deps)
 220                 set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2015)
 221         elseif(MSVC10)
 222                 set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 223                 set(deps_files lyx-windows-deps-msvc2010.zip)
 224                 set(deps_server http://ftp.lyx.de/LyX-Windows-Deps)
 225                 set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2010)
 226         else()
 227                 message(FATAL_ERROR "error: no dependency package known for the selected MSVC version.")
 228         endif()
 229     message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 230         foreach(it ${deps_files})
 231                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 232                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 233                 if(NOT already_downloaded)
 234                         message(STATUS "Downloading ${it} ...")
 235                         file(DOWNLOAD ${deps_server}/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS STATUS status LOG log)
 236                         list(GET status 0 status_code)
 237                         list(GET status 1 status_string)
 238                         if(NOT status_code EQUAL 0)
 239                                 file(REMOVE ${LYX_DEPENDENCIES_DIR}/${it})
 240                                 message(FATAL_ERROR "error: downloading '${it}' failed. status_code: ${status_code}, status_string: ${status_string}. \nLog: ${log} ")
 241                         endif()
 242                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 243                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 244                 endif()
 245         endforeach()
 246 endif()
 247
 248
 249
 250 message(STATUS)
 251
 252 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 253 if(WIN32)
 254         set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 255 else()
 256         set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 257 endif()
 258
 259
 260 # Set to some meaningful default
 261 find_package(CXX11Compiler)
 262 if(NOT CXX11COMPILER_FOUND)
 263         message(FATAL_ERROR "A C++11 compatible compiler is required.")
 264 endif()
 265 set(LYX_GCC11_MODE)
 266 if(UNIX OR MINGW)
 267         if (CMAKE_CXX_COMPILER_ID MATCHES "^[cC]lang$")
 268           # ignore the GCC_VERSION for clang
 269           # and use the resulting CXX11_STD_REGEX found in FindCXX11Compiler.cmake
 270           message(STATUS "Using clang")
 271           if(CXX11_STD_REGEX)
 272             set(LYX_USE_STD_REGEX 1)
 273           else()
 274             set(LYX_USE_STD_REGEX 0)
 275           endif()
 276         else()
 277           execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION OUTPUT_STRIP_TRAILING_WHITESPACE)
 278           message(STATUS "Using GCC version ${GCC_VERSION}")
 279           if(GCC_VERSION VERSION_LESS 4.9)
 280                   if(GCC_VERSION VERSION_LESS 4.6)
 281                           message(FATAL_ERROR "gcc >= 4.6 is required.")
 282                   endif()
 283                   # <regex> in gcc is unusable in versions less than 4.9.0
 284                   # see https://gcc.gnu.org/bugzilla/show_bug.cgi?id=53631
 285                   set(LYX_USE_STD_REGEX 0)
 286           else()
 287                   set(LYX_USE_STD_REGEX 1)
 288           endif()
 289         endif()
 290         set(LYX_GCC11_MODE "${CXX11_FLAG}")
 291 else()
 292         set(LYX_USE_STD_REGEX 0)
 293 #       if(MSVC10)
 294 #               set(LYX_USE_STD_REGEX 1) #TODO should we use it in ECMAScript mode?
 295 #       endif()
 296 endif()
 297
 298
 299 set(VERSION_INFO "CMake Build")
 300
 301 # Try to get some informations from configure.ac
 302
 303 include(LyXPaths)
 304 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 305
 306 if(WIN32)
 307         set(CMAKE_PREFIX_PATH Specify-path-to-Qt CACHE PATH "Used Qt version")
 308         if(MSVC)
 309                 set(LYX_3RDPARTY_BUILD ON CACHE BOOL "Build 3rdparty libraries" FORCE)
 310         endif()
 311         set(USE_WINDOWS_PACKAGING ON)
 312 elseif(APPLE)
 313         set(USE_MACOSX_PACKAGING ON)
 314 else()
 315         set(USE_POSIX_PACKAGING ON)
 316 endif()
 317
 318 if(LYX_3RDPARTY_BUILD)
 319   # LYX_3RDPARTY_BUILD is not cached anymore, but for compatibility reasons
 320   # this enables the build of all 3rd_party libs
 321   set(LYX_EXTERNAL_Z        OFF CACHE BOOL "Build 3rdparty lib zlib"    FORCE)
 322   set(LYX_EXTERNAL_ICONV    OFF CACHE BOOL "Build 3rdparty iconvlib"    FORCE)
 323   set(LYX_EXTERNAL_HUNSPELL OFF CACHE BOOL "Build 3rdparty hunspelllib" FORCE)
 324 endif()
 325
 326 macro(setstripped _varname)
 327         if(${ARGC} GREATER 1)
 328                 string(STRIP "${ARGV1}" _v)
 329                 if(USE_POSIX_PACKAGING)
 330                         string(TOLOWER ${_v} ${_varname})
 331                 else()
 332                         set(${_varname} ${_v})
 333                 endif()
 334         else()
 335                 set(${_varname})
 336         endif()
 337 endmacro(setstripped)
 338
 339 foreach(_c_l ${_config_lines} )
 340         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 341                 setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 342                 setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 343                 setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 344                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\)\(\\.\([0-9]+\)\)?.*$")
 345                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 346                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 347                         set(LYX_PATCH_VERSION ${CMAKE_MATCH_4})
 348                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 349                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 350                         if ("${LYX_SUFFIX_VALUE}" MATCHES "")
 351                           set(LYX_INSTALL_SUFFIX "${LYX_MAJOR_VERSION}.${LYX_MINOR_VERSION}")
 352                         else()
 353                           set(LYX_INSTALL_SUFFIX "${LYX_SUFFIX_VALUE}")
 354                         endif()
 355                 endif()
 356         endif()
 357         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 358                 set(LYX_DATE "${CMAKE_MATCH_1}")
 359         endif()
 360 endforeach(_c_l)
 361
 362 FIND_PROGRAM(LYX_GITVERSION git)
 363 #message(STATUS "gitversion = ${LYX_GITVERSION}")
 364 set(LYX_REVISION_VERSION ${LYX_PATCH_VERSION})
 365 if(LYX_GITVERSION)
 366   if (LYX_LOCALVERSIONING)
 367     # Find the revision number and for later use
 368     EXECUTE_PROCESS(COMMAND ${LYX_GITVERSION} describe --match 2.0.0 HEAD
 369       WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE LYX_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 370     if (LYX_PACKAGE_RELEASE MATCHES "^2\\.0\\.0\\-\([0-9]+\)\\-.*$")
 371       # We will add offset of 40000 to get appropriate value to
 372       # previous svn.
 373       # We use this value than also to set the package-patch-value
 374       MATH(EXPR tmp_REVISION_VERSION "(${CMAKE_MATCH_1}+40000)")
 375       set(LYX_REVISION_VERSION "${LYX_PATCH_VERSION}-${tmp_REVISION_VERSION}git")
 376       set(ENABLE_DIST ON)
 377     endif()
 378   endif()
 379 endif()
 380
 381 # Set the programs (lyx, tex2lyx, etc.) suffix
 382 # When building an OS X bundle, we will append
 383 # the suffix only to the bundle, not to the programs
 384 set(PROGRAM_SUFFIX "")
 385 if(LYX_PROGRAM_SUFFIX AND NOT (APPLE AND LYX_BUNDLE))
 386         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 387 endif()
 388 set(_lyx "${PACKAGE_BASE}${PROGRAM_SUFFIX}")
 389 set(_tex2lyx tex2lyx${PROGRAM_SUFFIX})
 390
 391 add_custom_target(lyx_version ALL
 392   COMMAND ${CMAKE_COMMAND} -DTOP_SRC_DIR=${TOP_SRC_DIR} -DTOP_CMAKE_PATH=${TOP_CMAKE_PATH} -DTOP_BINARY_DIR=${TOP_BINARY_DIR} -DLYX_DATE=${LYX_DATE} -P ${TOP_SCRIPT_PATH}/LyXGetVersion.cmake
 393   )
 394 set_target_properties(lyx_version PROPERTIES FOLDER "applications")
 395
 396 # Default paths for installed utilities (tex2lyx, lyxclient, etc.)
 397 set(LYX_UTILITIES_INSTALL_PATH bin)
 398
 399 if(LYX_BUNDLE)
 400         set(LYX_CPACK ON)
 401
 402         message(STATUS)
 403         message(STATUS "Bundle creation is enabled (experimental):")
 404         message(STATUS "    make")
 405         message(STATUS "    make install/strip")
 406         message(STATUS "    make package")
 407         if(APPLE)
 408                 set(MACOSX_BUNDLE TRUE)
 409                 # This sets the bundle + executable names
 410                 set(_lyx "${PACKAGE_BASE}${LYX_INSTALL_SUFFIX}")
 411                 # This sets the Info.plist executable name
 412                 set(osx_bundle_program_name ${_lyx})
 413                 # Bundle name
 414                 set(LYX_BUNDLE_NAME ${_lyx})
 415
 416                 # This will contain the list of files that need to be included
 417                 # in the bundle and their location within the bundle
 418                 set(OSX_BUNDLE_FILES "${TOP_SRC_DIR}/development/MacOSX/LyX.sdef;${TOP_SRC_DIR}/development/MacOSX/LyXapp.icns;${CMAKE_BINARY_DIR}/lyxrc.dist")
 419                 set(OSX_BUNDLE_DIRS "Resources;Resources;Resources")
 420
 421                 # Process Info.plist and lyxrc.dist
 422                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/Info.plist.in" "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 423                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/lyxrc.dist.in" "${CMAKE_CURRENT_BINARY_DIR}/lyxrc.dist")
 424
 425                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 426                 set(LYX_DATA_SUBDIR ${LYX_BUNDLE_NAME}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 427
 428                 # Variables used by CPack
 429                 set(CPACK_BUNDLE_NAME ${LYX_BUNDLE_NAME})
 430                 set(CPACK_BUNDLE_PLIST "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 431                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${LYX_BUNDLE_NAME}.app)
 432
 433                 # Set the install paths
 434                 set(LYX_UTILITIES_INSTALL_PATH ${LYX_BUNDLE_NAME}.app/Contents/MacOS)
 435                 if(NOT LYX_INSTALL_PREFIX)
 436                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 437                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 438                 endif()
 439                 # Change the owner so that the install can work
 440                 install(CODE "set(BU_CHMOD_BUNDLE_ITEMS 1)" COMPONENT Runtime)
 441         elseif(UNIX)
 442                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 443                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 444                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 445         elseif(WIN32)
 446                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 447         endif()
 448 endif()
 449
 450 if(LYX_INSTALL_PREFIX)
 451         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 452         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 453 endif()
 454 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 455
 456 if(UNIX)
 457   set(SYSTEM_DATADIR "${CMAKE_INSTALL_PREFIX}/share")
 458 elseif(CMAKE_INSTALL_PREFIX MATCHES "/lyx${LYX_INSTALL_SUFFIX}$")
 459   string(REGEX REPLACE "/lyx${LYX_INSTALL_SUFFIX}$" "/share" SYSTEM_DATADIR ${CMAKE_INSTALL_PREFIX})
 460 else()
 461   set(SYSTEM_DATADIR "${CMAKE_INSTALL_PREFIX}")
 462 endif()
 463
 464 # The define below allows lyx-executable to find its default configuration files
 465 # see routines
 466 #    Package::messages_file()
 467 #    get_default_user_support_dir()
 468 #    relative_system_support_dir()
 469 # in src/support/Package.cpp
 470 #
 471 if(LYX_PROGRAM_SUFFIX)
 472         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 473 else()
 474         set(PACKAGE ${PACKAGE_BASE})
 475 endif()
 476
 477 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 478         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 479         if (UNIX)
 480                 # use the default "/usr/local"
 481                 # but respect the user-choice on the command-line
 482                 set(CMAKE_INSTALL_PREFIX "/usr/local" CACHE PATH "LyX default install prefix" FORCE)
 483         endif()
 484 endif()
 485 if(WIN32)
 486         set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 487 endif()
 488 if(IS_ABSOLUTE)
 489         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 490 else()
 491         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 492 endif()
 493
 494
 495
 496 if(NOT LYX_DATA_SUBDIR)
 497         if (WIN32)
 498                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 499         else()
 500                 set(LYX_DATA_SUBDIR "share/${_lyx}/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 501         endif()
 502 endif()
 503
 504 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 505 get_locale_destination(LYX_LOCALEDIR)
 506 set(LYX_ABS_INSTALLED_LOCALEDIR "${CMAKE_INSTALL_PREFIX}/${LYX_LOCALEDIR}")
 507 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 508
 509 if(LYX_BUNDLE AND APPLE)
 510         set(LYX_MAN_DIR "${LYX_DATA_SUBDIR}" CACHE STRING "Install location for man pages.")
 511 else()
 512         if(WIN32)
 513                 set(LYX_MAN_DIR "${CMAKE_BINARY_DIR}/usr/local/man" CACHE STRING "Install location for man pages.")
 514         elseif(UNIX)
 515                 set(LYX_MAN_DIR "${CMAKE_INSTALL_PREFIX}/share/man" CACHE STRING "Install location for man pages.")
 516         else()
 517                 set(LYX_MAN_DIR "${CMAKE_INSTALL_PREFIX}/man" CACHE STRING "Install location for man pages.")
 518         endif()
 519 endif()
 520 mark_as_advanced(LYX_MAN_DIR)
 521
 522 if(LYX_INSTALL AND WIN32)
 523         message(STATUS "Configuring NSIS files")
 524         configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 525         configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 526         configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 527         message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 528 endif()
 529
 530 if(NOT GROUP_CODE)
 531         #set(GROUP_CODE "The Golden Code")
 532         set(GROUP_CODE flat)
 533 endif()
 534
 535 # lyx's source files
 536 set(LYX_CPP_FILES [a-zA-Z]*.cpp)
 537 set(LYX_HPP_FILES [a-zA-Z]*.h)
 538 set(LYX_MOC_FILES moc_*.cpp)
 539
 540 include(ProjectSourceGroup)
 541
 542
 543 if(LYX_PROFILE AND NOT MSVC)
 544         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 545         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg")
 546         set(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS}  -pg")
 547 else()
 548         set(LYX_PROFILE OFF)
 549 endif()
 550
 551
 552 if(LYX_NO_OPTIMIZE)
 553         set(CMAKE_BUILD_TYPE None)
 554         set(LYX_DEBUG OFF)
 555         set(LYX_RELEASE OFF)
 556         set(LYX_PROFILE OFF)
 557 elseif(LYX_RELEASE)
 558         set(CMAKE_BUILD_TYPE Release)
 559         set(LYX_DEBUG OFF)
 560         set(LYX_PROFILE OFF)
 561 elseif(LYX_PROFILE)
 562         set(CMAKE_BUILD_TYPE Profile)
 563         set(LYX_DEBUG OFF)
 564 else()
 565         set(CMAKE_BUILD_TYPE Debug)
 566         set(LYX_DEBUG ON)
 567 endif()
 568
 569
 570 # When shared libs are supported enable this option
 571 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 572 if(LYX_SHARED_LIBRARIES)
 573         set(library_type SHARED)
 574 else()
 575         set(library_type STATIC)
 576 endif()
 577
 578 if(NOT MSVC)
 579         if(NOT LYX_QUIET)
 580                 set(CMAKE_VERBOSE_MAKEFILE ON)
 581         endif()
 582         set(LYX_CXX_FLAGS "-Wall -Wunused-parameter ${LYX_GCC11_MODE}")
 583         if(LYX_CXX_FLAGS MATCHES "\\+\\+(14|11|98)")
 584           # Thanks to Brad King <brad.king@kitware.com>
 585           # for the pointer to https://cmake.org/cmake/help/v3.6/variable/CMAKE_CXX_STANDARD.html
 586           # This allows us to use QT5.7 with recent g++ (version >= 4.9) compilers
 587           # and still use our own c++ extension tests
 588           set(CMAKE_CXX_STANDARD ${CMAKE_MATCH_1})
 589           message(STATUS "CMAKE_CXX_STANDARD set to ${CMAKE_CXX_STANDARD}")
 590         endif()
 591         if(LYX_STDLIB_DEBUG)
 592                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 593         endif()
 594         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 595         set(CMAKE_CXX_FLAGS_DEBUG "${LYX_CXX_FLAGS} -fno-strict-aliasing -O0 -g3 -D_DEBUG" CACHE TYPE STRING FORCE)
 596         if(MINGW)
 597                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 598         else()
 599                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 600         endif()
 601 endif()
 602
 603 set(LYX_CXX_FLAGS_EXTRA "" CACHE STRING "Desired semicolon separated list of extra cxx compile flags, like '-Werror'")
 604 mark_as_advanced(LYX_CXX_FLAGS_EXTRA)
 605 if(LYX_CXX_FLAGS_EXTRA)
 606         foreach(_flag ${LYX_CXX_FLAGS_EXTRA})
 607                 add_definitions(${_flag})
 608         endforeach()
 609 endif()
 610
 611 if(LYX_XMINGW)
 612         list(APPEND CMAKE_FIND_ROOT_PATH ${GNUWIN32_DIR})
 613 endif()
 614
 615 if(LYX_USE_QT MATCHES "QT5")
 616         # set QPA_XCB if QT uses X11
 617         find_package(Qt5Core REQUIRED)
 618         if (Qt5Core_FOUND)
 619                 find_package(Qt5Widgets REQUIRED)
 620                 if(APPLE)
 621                         find_package(Qt5MacExtras REQUIRED)
 622                 endif()
 623                 find_package(Qt5X11Extras QUIET)
 624                 find_package(Qt5WinExtras QUIET)
 625                 set(QTVERSION ${Qt5Core_VERSION})
 626                 macro (qt_use_modules)
 627                         qt5_use_modules(${ARGN})
 628                 endmacro()
 629                 macro (qt_add_resources)
 630                         qt5_add_resources(${ARGN})
 631                 endmacro()
 632                 macro (qt_wrap_uifiles)
 633                         qt5_wrap_ui(${ARGN})
 634                 endmacro()
 635                 message(STATUS "Found Qt-Version ${QTVERSION}")
 636                 if(WIN32)
 637                         set(LYX_QTMAIN_LIBRARY ${Qt5Core_QTMAIN_LIBRARIES})
 638                 endif()
 639         endif()
 640 elseif(LYX_USE_QT MATCHES "QT4")
 641         if(LYX_XMINGW)
 642                 set(QT_MINGW_DIR ${LYX_QT4} CACHE PATH "Qt for Mingw" FORCE)
 643                 list(APPEND CMAKE_FIND_ROOT_PATH ${QT_MINGW_DIR} ${GNUWIN32_DIR})
 644         endif()
 645         find_package(Qt4 "4.5.0" REQUIRED)
 646         macro (qt_use_modules)
 647         endmacro()
 648         macro (qt_add_resources)
 649                 qt4_add_resources(${ARGN})
 650         endmacro()
 651         macro (qt_wrap_uifiles)
 652                 qt4_wrap_ui(${ARGN})
 653         endmacro()
 654         set(LYX_QTMAIN_LIBRARY ${QT_QTSVG_LIBRARY})
 655         if(WIN32)
 656                 list(APPEND LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARIES})
 657         endif()
 658 else()
 659   message(FATAL_ERROR "Unhandled value for LYX_USE_QT (${LYX_USE_QT})")
 660 endif()
 661
 662 find_package(Magic)
 663 if(Magic_FOUND)
 664         set(HAVE_MAGIC_H 1)
 665 endif()
 666
 667 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 668
 669 set(Spelling_FOUND OFF)
 670 set(Include_used_spellchecker)   # String will be inserted into config.h
 671
 672 if(NOT LYX_EXTERNAL_HUNSPELL)
 673     add_subdirectory(3rdparty/hunspell)
 674     add_definitions(-DHUNSPELL_STATIC)
 675     set(HUNSPELL_FOUND ON)
 676     message(STATUS "  * Hunspell:")
 677     message(STATUS "     - include: ${HUNSPELL_INCLUDE_DIR}")
 678     message(STATUS "     - library: ${HUNSPELL_LIBRARY}")
 679 endif()
 680
 681 foreach(_spell "ASPELL" "Enchant" "Hunspell")
 682   string(TOUPPER ${_spell} _upspell)
 683   if (NOT ${_upspell}_FOUND)
 684     find_package(${_spell})
 685   endif()
 686   if (${_upspell}_FOUND)
 687     include_directories(${${_upspell}_INCLUDE_DIR})
 688     set(Spelling_FOUND ON)
 689     message(STATUS "Building with USE_${_upspell}")
 690     set(Include_used_spellchecker "${Include_used_spellchecker}#define USE_${_upspell} 1\n")
 691   else()
 692     if(LYX_${_upspell})
 693       message(FATAL_ERROR "Required ${_spell} devel package not found")
 694     else()
 695       message(STATUS "${_upspell} not found, building without ${_spell} support")
 696     endif()
 697   endif()
 698 endforeach()
 699
 700 if(GNUWIN32_DIR)
 701         list(APPEND CMAKE_PROGRAM_PATH "${GNUWIN32_DIR}/Python" )
 702 endif()
 703
 704 find_package(PythonInterp 2.7 QUIET)
 705 if(PYTHONINTERP_FOUND)
 706         if(PYTHON_VERSION_STRING VERSION_GREATER 2.8)
 707         unset(PYTHONINTERP_FOUND)
 708         endif()
 709 endif()
 710
 711 if(NOT PYTHONINTERP_FOUND)
 712   unset(PYTHON_EXECUTABLE CACHE)
 713   unset(PYTHON_VERSION_MAJOR)
 714   unset(PYTHON_VERSION_MINOR)
 715   unset(PYTHON_VERSION_STRING)
 716   find_package(PythonInterp 3.3 REQUIRED)
 717 endif()
 718
 719 set(LYX_PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 720
 721 if(LYX_NLS)
 722         find_package(LyXGettext)
 723         if(LYX_PYTHON_EXECUTABLE AND GETTEXT_FOUND)
 724                 add_subdirectory(po "${TOP_BINARY_DIR}/po")
 725         else()
 726                 # Install only supplied .gmo-files
 727                 file(GLOB _gmofiles RELATIVE "${TOP_SRC_DIR}/po" "${TOP_SRC_DIR}/po/*.gmo")
 728                 message(STATUS "Installing provided .gmo-files only")
 729                 foreach( _gmo ${_gmofiles})
 730                         string(REGEX REPLACE "\\.gmo$" "" _lang ${_gmo})
 731                         install(FILES "${TOP_SRC_DIR}/po/${_gmo}" DESTINATION ${LYX_LOCALEDIR}/${_lang}/LC_MESSAGES RENAME ${PACKAGE}.mo)
 732                 endforeach()
 733         endif()
 734 endif()
 735
 736 if(LYX_EXTERNAL_ICONV)
 737   find_package(ICONV REQUIRED)
 738 else()
 739   add_subdirectory(3rdparty/libiconv)
 740   set(HAVE_ICONV_CONST 1)
 741 endif()
 742
 743 if(LYX_EXTERNAL_Z)
 744   find_package(ZLIB REQUIRED)
 745 else()
 746   add_subdirectory(3rdparty/zlib)
 747 endif()
 748
 749 if(LYX_EXTERNAL_BOOST)
 750         message(STATUS "Searching for boost")
 751         if(NOT LYX_USE_STD_REGEX)
 752                 find_package(Boost COMPONENTS regex)
 753         endif()
 754         if(Boost_FOUND)
 755                 message(STATUS "Boost found")
 756                 message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 757                 set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 758                 if (LYX_STDLIB_DEBUG)
 759                         # Comment from  Jean-Marc Lasgouttes:
 760                         # In general, system boost libraries are incompatible with
 761                         # the use of stdlib-debug in libstdc++. See ticket #9736 for
 762                         # details.
 763                         message(WARNING "Compiling LyX with stdlib-debug and system boost libraries may lead to crashes. Consider using '-DLYX_STDLIB_DEBUG=OFF' or using '-DLYX_EXTERNAL_BOOST=OFF'")
 764                 endif()
 765         else()
 766                 message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 767         endif()
 768 else()
 769         if(NOT LYX_USE_STD_REGEX)
 770                 set(Lyx_Boost_Libraries boost_regex)
 771         endif()
 772         add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 773         include_directories(${TOP_SRC_DIR}/3rdparty/boost)
 774         add_subdirectory(3rdparty/boost "${TOP_BINARY_DIR}/3rdparty/boost")
 775 endif()
 776
 777
 778
 779
 780 if(WIN32)
 781         if(LYX_CONSOLE)
 782                 set(LYX_QTMAIN_LIBRARY)
 783         else()
 784                 set(WIN32_CONSOLE WIN32)
 785         endif()
 786         if(MSVC)
 787                 # -DPSAPI_VERSION=1 is needed to run on vista (bug 10186)
 788                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX -DPSAPI_VERSION=1)
 789                 # disable checked iterators for msvc release builds to get maximum speed
 790                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 791         else()
 792                 # -DPSAPI_VERSION=1 is not needed for mingw, since the mingw psapi.h
 793                 # does not use it and always declares the vista compatible API.
 794                 # If this ever changes then -DPSAPI_VERSION might be needed here as well.
 795                 add_definitions(-DWINVER=0x0500)
 796         endif()
 797 endif()
 798
 799 # Compute qt4-version from ${QTVERSION}
 800
 801 message(STATUS "")
 802 foreach(_v PACKAGE PACKAGE_VERSION
 803         PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 804         LYX_ABS_TOP_SRCDIR
 805         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 806         if(NOT DEFINED ${_v})
 807                 message(FATAL_ERROR "${_v} not defined")
 808         endif()
 809         string(SUBSTRING "${_v}                            " 0 28 _v1)
 810         message(STATUS "----- ${_v1}: ${${_v}}")
 811 endforeach(_v)
 812 message(STATUS "")
 813
 814
 815 if(LYX_PCH)
 816         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 817         # Not sure if it works for all non-msvc compilers
 818         include(PCHSupport_26)
 819         configure_file(${TOP_CMAKE_PATH}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
 820         configure_file(${TOP_CMAKE_PATH}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 821         add_definitions(-DLYX_ENABLE_PCH)
 822
 823         if(MSVC)
 824                 macro(lyx_add_msvc_pch name_)
 825                         set_source_files_properties(${${name_}_sources} PROPERTIES
 826                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 827                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
 828                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 829                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
 830                                 ${TOP_BINARY_DIR}/pcheaders.h)
 831                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 832                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 833                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 834                 endmacro(lyx_add_msvc_pch)
 835                 macro(lyx_add_gcc_pch name_)
 836                 endmacro()
 837         else()
 838                 macro(lyx_add_msvc_pch name_)
 839                 endmacro()
 840                 macro(lyx_add_gcc_pch name_)
 841                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT)
 842                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
 843                 endmacro()
 844         endif()
 845 else()
 846         macro(lyx_add_msvc_pch)
 847         endmacro(lyx_add_msvc_pch)
 848         macro(lyx_add_gcc_pch name_)
 849         endmacro()
 850 endif()
 851
 852
 853 if(MSVC)
 854
 855         if(LYX_VLD)
 856                 set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/development/Win32/vld)
 857                 add_subdirectory(${vld_path}/cmake)
 858                 include(${vld_path}/cmake/vld.cmake) # forced include
 859                 set(vld_dll vld)
 860         endif()
 861
 862         if(LYX_WALL)
 863                 # Use the highest warning level
 864                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 865
 866                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 867                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 868                 else()
 869                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 870                 endif()
 871
 872                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 873                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 874                 else()
 875                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 876                 endif()
 877
 878                 # add here warnings which should produce an error /weXXXX
 879                 set(MSVC_W_ERROR   "/we4101 /we4189")
 880                 # add here warnings which should be disabled /wdXXXX
 881                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 882
 883                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 884                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 885                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 886
 887         else()
 888                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 889
 890                 # add here warnings which should produce an error /weXXXX
 891                 set(MSVC_W_ERROR   "/we4101 /we4189")
 892                 # add here warnings which should be disabled /wdXXXX
 893                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 894
 895                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 896                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 897                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 898
 899         endif()
 900
 901         if (NOT Qt5Core_FOUND)
 902                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 903                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 904                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 905         endif()
 906
 907         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 908         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 909         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 910         message(STATUS "")
 911 endif()
 912
 913
 914 if(LYX_DEBUG_GLIBC)
 915         set(_GLIBCXX_DEBUG ON)
 916 endif()
 917
 918 if(LYX_DEBUG_GLIBC_PEDANTIC)
 919         set(_GLIBCXX_DEBUG_PEDANTIC ON)
 920 endif()
 921
 922 # Xcode compiler
 923 if (CMAKE_GENERATOR MATCHES Xcode)
 924         if (XCODE_VERSION VERSION_LESS "5.0")
 925                 # Automatically select the Xcode compiler if not set
 926                 if (NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 927                         # XCode >= 3.1 has gcc 4.2 (up to actual Xcode)
 928                         if (XCODE_VERSION VERSION_GREATER "3.1")
 929                                 SET(CMAKE_XCODE_ATTRIBUTE_GCC_VERSION "com.apple.compilers.llvmgcc42")
 930                         ENDIF(XCODE_VERSION VERSION_GREATER "3.1")
 931                 ENDIF(NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 932                 # Print the selected compiler version
 933         MESSAGE(STATUS "---- Using XCode compiler CMAKE_XCODE_ATTRIBUTE_GCC_VERSION=${CMAKE_XCODE_ATTRIBUTE_GCC_VERSION}")
 934         ENDIF(XCODE_VERSION VERSION_LESS "5.0")
 935 ENDIF(CMAKE_GENERATOR MATCHES Xcode)
 936
 937 if (WIN32 AND Qt5Core_FOUND)
 938         set(Z_PREFIX 1)
 939 endif()
 940
 941 # compiler tests, config.h generation LYX_CONFIGURE_CHECKS
 942 include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
 943 configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
 944
 945 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
 946
 947 if(QTVERSION MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+).*")
 948         MATH(EXPR QT4_VERSION "(${CMAKE_MATCH_1}<<16)|(${CMAKE_MATCH_2}<<8)|${CMAKE_MATCH_3}")
 949 endif()
 950
 951 if (NOT HAVE_REGEX)
 952         set(LYX_USE_STD_REGEX 0)
 953 endif()
 954
 955
 956 set (cmd ${CMAKE_CTEST_COMMAND})
 957 if (MSVC)
 958         set (cmd ${cmd} -C ${CMAKE_CFG_INTDIR})
 959 else ()
 960         set (cmd ${cmd} -C ${CMAKE_BUILD_TYPE})
 961 endif ()
 962 add_custom_target (lyx_run_tests COMMAND ${cmd})
 963 set_target_properties(lyx_run_tests PROPERTIES FOLDER "tests")
 964
 965 if(LYX_ASAN)
 966     set(LYX_CXX_FLAGS "-fsanitize=address -fno-omit-frame-pointer -g")
 967     message(STATUS)
 968     message(STATUS "Address sanitizer enabled. Usage:")
 969     message(STATUS "    wget https://llvm.org/svn/llvm-project/compiler-rt/trunk/lib/asan/scripts/asan_symbolize.py")
 970     message(STATUS "    chmod  +x ./asan_symbolize.py")
 971     message(STATUS "    ./bin/lyx2.2 2>&1 | ./asan_symbolize.py  | c++filt ")
 972     message(STATUS)
 973 endif()
 974
 975 if(LYX_INSTALL)
 976         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 977                 message(STATUS "Python required to create doc!")
 978         else()
 979                 if(UNIX)
 980                         add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
 981                 endif()
 982                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
 983         endif()
 984         include(../Install)
 985 endif()
 986
 987 add_subdirectory(src "${TOP_BINARY_DIR}/src")
 988 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
 989 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
 990 add_subdirectory(lib/examples "${TOP_BINARY_DIR}/lib/examples")
 991 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
 992 add_subdirectory(development/autotests "${TOP_BINARY_DIR}/autotests")
 993 if(LYX_ENABLE_URLTESTS)
 994         add_subdirectory(development/checkurls "${TOP_BINARY_DIR}/checkurls")
 995 endif()
 996
 997 message(STATUS)
 998 message(STATUS "Build params, switch LYX_* options by -DLYX_*=ON or OFF, LYX_* combos by -DLYX_*=value:")
 999 message(STATUS)
1000
1001 LYX_OPTION_LIST_ALL(used)
1002
1003
1004 if(LYX_NLS)
1005         message(STATUS)
1006         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
1007         message(STATUS)
1008         message(STATUS "  * iconv")
1009         message(STATUS "     - include: ${ICONV_INCLUDE_DIR}")
1010         message(STATUS "     - library: ${ICONV_LIBRARY}")
1011         message(STATUS "  * zlib")
1012         message(STATUS "     - include: ${ZLIB_INCLUDE_DIR}")
1013         message(STATUS "     - library: ${ZLIB_LIBRARY}")
1014         message(STATUS)
1015 endif()
1016
1017 # Apple has builtin native spell checker,
1018 # no need to warn for missing Aspell, Hunspell or Enchant
1019 if(NOT Spelling_FOUND AND NOT APPLE)
1020   if(LYX_REQUIRE_SPELLCHECK)
1021     set(_mode "FATAL_ERROR")
1022   else()
1023     set(_mode "STATUS")
1024   endif()
1025   message(${_mode} "No spellcheck libraries found. LyX will be unable use spellchecking")
1026 endif()
1027
1028 include("${TOP_CMAKE_PATH}/LyxPackaging.cmake")
1029
1030 if(ENABLE_DIST)
1031   # Use git to create the source package
1032   # git archive --format=tgz --output=/home/kornel/x.tar.gz master
1033   if(UNIX)
1034     set(DIST_FORMAT tgz)
1035   else()
1036     set(DIST_FORMAT zip)
1037   endif()
1038   set(DIST_NAME ${CMAKE_PROJECT_NAME}-${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}-${CMAKE_SYSTEM_NAME}.${DIST_FORMAT})
1039
1040   add_custom_command(
1041     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME}
1042     COMMAND  ${LYX_GITVERSION} archive --format=${DIST_FORMAT} --output=${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME} master
1043     WORKING_DIRECTORY ${TOP_SRC_DIR})
1044   add_custom_target(git-archive DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME})
1045 endif()
1046
1047 # Last directory to be included so that the fixup code (OS X)
1048 # can be run last
1049 add_subdirectory(development/cmake/post_install)
1050
1051 message(STATUS)