CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 2.6.4)
   8
   9 set(LYX_PROJECT LyX)
  10
  11 enable_testing()
  12
  13 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README ABSOLUTE)
  14 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  15
  16 set(LYX_CMAKE_DIR "development/cmake")
  17 set(TOP_CMAKE_PATH "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}")
  18 set(TOP_MODULE_PATH "${TOP_CMAKE_PATH}/modules")
  19 set(TOP_SCRIPT_PATH "${TOP_CMAKE_PATH}/scripts")
  20
  21 set(CMAKE_MODULE_PATH "${TOP_MODULE_PATH}")
  22
  23 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  24
  25 message(STATUS)
  26 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  27         message(STATUS "Building in-source")
  28         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  29 else()
  30         message(STATUS "Building out-of-source")
  31         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  32 endif()
  33
  34 # This directory should be used if some test uses lyx-executable
  35 set(LYX_TESTS_USERDIR "${TOP_BINARY_DIR}/Testing/.lyx")
  36 file(MAKE_DIRECTORY "${LYX_TESTS_USERDIR}")
  37
  38 if(COMMAND cmake_policy)
  39         cmake_policy(SET CMP0003 OLD)
  40         cmake_policy(SET CMP0005 OLD)
  41         # Installing MACOSX_BUNDLE targets requires a BUNDLE DESTINATION
  42         cmake_policy(SET CMP0006 NEW)
  43         if(POLICY CMP0028)
  44                 cmake_policy(SET CMP0028 OLD)
  45         endif()
  46         if(POLICY CMP0043)
  47                 # COMPILE_DEFINITIONS are not used yet. Enable new behavior.
  48                 cmake_policy(SET CMP0043 NEW)
  49         endif()
  50 endif()
  51
  52 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  53
  54 # Supress regeneration
  55 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  56
  57 if(LYX_XMINGW)
  58     set(CMAKE_SYSTEM_NAME Windows)
  59     set(TOOLNAME ${LYX_XMINGW})
  60     set(TOOLCHAIN "${TOOLNAME}-")
  61     set(CMAKE_C_COMPILER   "${TOOLCHAIN}gcc"     CACHE PATH "Mingw C compiler" FORCE)
  62     set(CMAKE_CXX_COMPILER "${TOOLCHAIN}g++"     CACHE PATH "Mingw C++ compiler" FORCE)
  63     set(CMAKE_RC_COMPILER  "${TOOLCHAIN}windres" CACHE PATH "Mingw rc compiler" FORCE)
  64
  65     set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM BOTH)
  66     set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY)
  67     set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY)
  68 endif()
  69
  70 if(NOT help AND NOT HELP)
  71         # 'project' triggers the searching for a compiler
  72         project(${LYX_PROJECT})
  73 endif()
  74
  75 if(UNIX)
  76         set(ARCH_TRIPLET )
  77         FIND_PROGRAM(DPKG_ARCHITECTURE_EXECUTABLE dpkg-architecture)
  78         if(DPKG_ARCHITECTURE_EXECUTABLE)
  79                 EXECUTE_PROCESS(COMMAND ${DPKG_ARCHITECTURE_EXECUTABLE} -qDEB_HOST_MULTIARCH
  80                                 OUTPUT_VARIABLE ARCH_TRIPLET
  81                                 ERROR_VARIABLE ERROR_ARCH_TRIPLET
  82                                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  83         endif()
  84 endif()
  85 if(ARCH_TRIPLET)
  86         set(SYSTEM_LIB_DIRS /usr/lib /usr/lib/${ARCH_TRIPLET} /usr/local/lib)
  87 else()
  88         set(SYSTEM_LIB_DIRS /usr/lib /usr/local/lib)
  89 endif()
  90
  91 include(LyXMacros)
  92
  93 # Usage LYX_OPTION
  94 # 1. parameter: option name without prefix 'LYX_'
  95 # 2. parameter: description
  96 # 3. parameter: default value, ON or OFF
  97 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
  98
  99 # Usage LYX_COMBO
 100 # 1. parameter: name without prefix 'LYX_'
 101 # 2. parameter: description
 102 # 3. parameter: default value
 103 # 4-n parameter: possible other string values
 104
 105 LYX_OPTION_INIT()
 106
 107 # Options for all compilers/systems
 108 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
 109 LYX_OPTION(LOCALVERSIONING  "Add version info to created package name (only used if LYX_CPACK option set)" OFF ALL)
 110 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
 111 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
 112 LYX_OPTION(REQUIRE_SPELLCHECK "Abort if no spellchecker available" OFF ALL)
 113 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
 114 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
 115 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
 116 LYX_OPTION(DEVEL_VERSION    "Build developer version" OFF ALL)
 117 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" OFF ALL)
 118 LYX_OPTION(DEBUG            "Enforce debug build"  OFF ALL)
 119 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
 120 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
 121 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
 122 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
 123 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
 124 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
 125 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
 126 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
 127 LYX_OPTION(ENABLE_URLTESTS  "Enable for URL tests" OFF ALL)
 128 LYX_OPTION(ENABLE_EXPORT_TESTS "Enable for export tests" OFF ALL)
 129 LYX_OPTION(ASAN             "Use address sanitizer" OFF ALL)
 130
 131 # GCC specific
 132 LYX_OPTION(PROFILE              "Build profile version" OFF GCC)
 133 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" OFF GCC)
 134 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
 135 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
 136 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++ pedantic debug mode" OFF GCC)
 137 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" OFF GCC)
 138 LYX_OPTION(CONCEPT_CHECKS       "Enable concept-checks" OFF GCC)
 139 LYX_OPTION(PROFILE              "Build with options for gprof" OFF GCC)
 140 LYX_OPTION(ENABLE_CXX11         "Build with options for c++11-mode" OFF GCC)
 141
 142 # MSVC specific
 143 LYX_OPTION(CONSOLE               "Show console on Windows, enforce with =FORCE" ON MSVC)
 144 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
 145 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
 146 LYX_OPTION(CONFIGURE_CHECKS      "Also run configure checks for MSVC" OFF MSVC)
 147 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
 148
 149 # APPLE specific
 150 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
 151 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
 152 if(LYX_XMINGW)
 153   LYX_COMBO(USE_QT               "Use Qt version as frontend for MINGW" QT4)
 154 else()
 155   LYX_COMBO(USE_QT               "Use Qt version as frontend" QT4 QT5)
 156 endif()
 157
 158
 159 if(help OR HELP)
 160         message(STATUS)
 161         message(STATUS "Available options: (dis/enable with -DLYX_*=OFF/ON)")
 162         message(STATUS)
 163         LYX_OPTION_LIST_ALL(help)
 164         message(STATUS)
 165         RETURN()
 166 endif()
 167
 168 # Check option dependencies
 169
 170 if(LYX_DMG)
 171         set(LYX_BUNDLE ON)
 172         set(LYX_CPACK ON)
 173 endif()
 174
 175 if(LYX_CPACK)
 176         set(LYX_INSTALL ON)
 177 endif()
 178
 179 if(LYX_INSTALL)
 180         set(LYX_NLS ON)
 181         if(WIN32 AND NOT MINGW)
 182                 set(LYX_HUNSPELL ON)
 183         endif()
 184         if(LYX_CONSOLE MATCHES "FORCE")
 185                 set(LYX_CONSOLE ON)
 186         else()
 187                 set(LYX_CONSOLE OFF)
 188         endif()
 189         set(LYX_PACKAGE_SUFFIX ON)
 190         if(NOT LYX_DEBUG)
 191                 set(LYX_RELEASE ON)
 192         endif()
 193         set(LYX_PROFILE OFF)
 194 endif()
 195
 196
 197 if(LYX_MERGE_FILES)
 198         set(LYX_PCH OFF)
 199 else()
 200         set(LYX_MERGE_REBUILD OFF)
 201 endif()
 202
 203
 204 if(LYX_DEPENDENCIES_DOWNLOAD)
 205         message(STATUS)
 206         set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 207         message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 208         set(deps_files lyx20-deps-msvc2010-x86.zip)
 209         set(deps_server http://downloads.sourceforge.net/project/lyx/Win_installers/Dependencies)
 210         foreach(it ${deps_files})
 211                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 212                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 213                 if(NOT already_downloaded)
 214                         message(STATUS "Downloading ${it} ...")
 215                         file(DOWNLOAD ${deps_server}/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS STATUS status LOG log)
 216                         list(GET status 0 status_code)
 217                         list(GET status 1 status_string)
 218                         if(NOT status_code EQUAL 0)
 219                                 file(REMOVE ${LYX_DEPENDENCIES_DIR}/${it})
 220                                 message(FATAL_ERROR "error: downloading '${it}' failed. status_code: ${status_code}, status_string: ${status_string}. \nLog: ${log} ")
 221                         endif()
 222                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 223                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 224                 endif()
 225         endforeach()
 226         set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/deps20)
 227     if(MSVC12)
 228         # handle error in msvc12 when linking against msvc10 libs
 229         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /vd2")
 230     endif()
 231 endif()
 232
 233
 234
 235 message(STATUS)
 236
 237 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 238 if(WIN32)
 239         set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 240 else()
 241         set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 242 endif()
 243
 244
 245 set(LYX_GCC11_MODE)
 246 if(UNIX OR MINGW)
 247         execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION)
 248         message(STATUS "Using GCC version ${GCC_VERSION}")
 249         if(NOT GCC_VERSION VERSION_LESS 4.4)
 250                 set(LYX_USE_TR1 1)
 251                 # GCC <= 4.5 does not support regex: there are linker errors
 252                 # http://gcc.gnu.org/onlinedocs/libstdc++/manual/status.html#status.iso.tr1
 253                 set(LYX_USE_TR1_REGEX 0)
 254         endif()
 255         if (LYX_ENABLE_CXX11)
 256                 find_package(CXX11Compiler)
 257                 if(NOT CXX11COMPILER_FOUND)
 258                         message(FATAL_ERROR "A C++11 compatible compiler is required.")
 259                 endif()
 260                 set(LYX_GCC11_MODE "${CXX11_FLAG}")
 261         endif()
 262         set(STD_STRING_USES_COW 1)
 263 else()
 264         if(MSVC10)
 265                 set(LYX_USE_TR1 1)
 266                 #set(LYX_USE_TR1_REGEX 1) #TODO should we use it in ECMAScript mode?
 267         else()
 268                 set(STD_STRING_USES_COW 1)
 269         endif()
 270 endif()
 271
 272
 273 set(VERSION_INFO "CMake Build")
 274
 275 # Try to get some informations from configure.ac
 276
 277 include(LyXPaths)
 278 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 279
 280 if(WIN32)
 281         set(USE_WINDOWS_PACKAGING ON)
 282 elseif(APPLE)
 283         set(USE_MACOSX_PACKAGING ON)
 284 else()
 285         set(USE_POSIX_PACKAGING ON)
 286 endif()
 287
 288 macro(setstripped _varname)
 289         if(${ARGC} GREATER 1)
 290                 string(STRIP "${ARGV1}" _v)
 291                 if(USE_POSIX_PACKAGING)
 292                         string(TOLOWER ${_v} ${_varname})
 293                 else()
 294                         set(${_varname} ${_v})
 295                 endif()
 296         else()
 297                 set(${_varname})
 298         endif()
 299 endmacro(setstripped)
 300
 301 foreach(_c_l ${_config_lines} )
 302         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 303                 setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 304                 setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 305                 setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 306                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\)\(\\.\([0-9]+\)\)?.*$")
 307                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 308                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 309                         set(LYX_PATCH_VERSION ${CMAKE_MATCH_4})
 310                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 311                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 312                         set(LYX_INSTALL_SUFFIX "${CMAKE_MATCH_1}.${CMAKE_MATCH_2}")
 313                 endif()
 314         endif()
 315         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 316                 set(LYX_DATE "${CMAKE_MATCH_1}")
 317         endif()
 318 endforeach(_c_l)
 319
 320 FIND_PROGRAM(LYX_GITVERSION git)
 321 #message(STATUS "gitversion = ${LYX_GITVERSION}")
 322 set(LYX_REVISION_VERSION ${LYX_PATCH_VERSION})
 323 if(LYX_GITVERSION)
 324   if (LYX_LOCALVERSIONING)
 325     # Find the revision number and for later use
 326     EXECUTE_PROCESS(COMMAND ${LYX_GITVERSION} describe --match 2.0.0 HEAD
 327       WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE LYX_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 328     if (LYX_PACKAGE_RELEASE MATCHES "^2\\.0\\.0\\-\([0-9]+\)\\-.*$")
 329       # We will add offset of 40000 to get appropriate value to
 330       # previous svn.
 331       # We use this value than also to set the package-patch-value
 332       MATH(EXPR tmp_REVISION_VERSION "(${CMAKE_MATCH_1}+40000)")
 333       set(LYX_REVISION_VERSION "${LYX_PATCH_VERSION}-${tmp_REVISION_VERSION}git")
 334       set(ENABLE_DIST ON)
 335     endif()
 336   endif()
 337 endif()
 338
 339 # Set the programs (lyx, tex2lyx, etc.) suffix
 340 # When building an OS X bundle, we will append
 341 # the suffix only to the bundle, not to the programs
 342 set(PROGRAM_SUFFIX "")
 343 if(LYX_PROGRAM_SUFFIX AND NOT (APPLE AND LYX_BUNDLE))
 344         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 345 endif()
 346 set(_lyx "${PACKAGE_BASE}${PROGRAM_SUFFIX}")
 347 set(_tex2lyx tex2lyx${PROGRAM_SUFFIX})
 348
 349 add_custom_target(lyx_version ALL
 350   COMMAND ${CMAKE_COMMAND} -DTOP_SRC_DIR=${TOP_SRC_DIR} -DTOP_CMAKE_PATH=${TOP_CMAKE_PATH} -DTOP_BINARY_DIR=${TOP_BINARY_DIR} -DLYX_DATE=${LYX_DATE} -P ${TOP_SCRIPT_PATH}/LyXGetVersion.cmake
 351   )
 352 set_target_properties(lyx_version PROPERTIES FOLDER "applications")
 353
 354 # Default paths for installed utilities (tex2lyx, lyxclient, etc.)
 355 set(LYX_UTILITIES_INSTALL_PATH bin)
 356
 357 if(LYX_BUNDLE)
 358         set(LYX_CPACK ON)
 359
 360         message(STATUS)
 361         message(STATUS "Bundle creation is enabled (experimental):")
 362         message(STATUS "    make")
 363         message(STATUS "    make install/strip")
 364         message(STATUS "    make package")
 365         if(APPLE)
 366                 set(MACOSX_BUNDLE TRUE)
 367                 # This sets the bundle + executable names
 368                 set(_lyx "${PACKAGE_BASE}${LYX_INSTALL_SUFFIX}")
 369                 # This sets the Info.plist executable name
 370                 set(osx_bundle_program_name ${_lyx})
 371                 # Bundle name
 372                 set(LYX_BUNDLE_NAME ${_lyx})
 373
 374                 # This will contain the list of files that need to be included
 375                 # in the bundle and their location within the bundle
 376                 set(OSX_BUNDLE_FILES "${TOP_SRC_DIR}/development/MacOSX/LyX.sdef;${TOP_SRC_DIR}/development/MacOSX/LyXapp.icns;${CMAKE_BINARY_DIR}/lyxrc.dist")
 377                 set(OSX_BUNDLE_DIRS "Resources;Resources;Resources")
 378
 379                 # Process Info.plist and lyxrc.dist
 380                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/Info.plist.in" "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 381                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/lyxrc.dist.in" "${CMAKE_CURRENT_BINARY_DIR}/lyxrc.dist")
 382
 383                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 384                 set(LYX_DATA_SUBDIR ${LYX_BUNDLE_NAME}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 385
 386                 # Variables used by CPack
 387                 set(CPACK_BUNDLE_NAME ${LYX_BUNDLE_NAME})
 388                 set(CPACK_BUNDLE_PLIST "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 389                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${LYX_BUNDLE_NAME}.app)
 390
 391                 # Set the install paths
 392                 set(LYX_UTILITIES_INSTALL_PATH ${LYX_BUNDLE_NAME}.app/Contents/MacOS)
 393                 if(NOT LYX_INSTALL_PREFIX)
 394                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 395                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 396                 endif()
 397                 # Change the owner so that the install can work
 398                 install(CODE "set(BU_CHMOD_BUNDLE_ITEMS 1)" COMPONENT Runtime)
 399         elseif(UNIX)
 400                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 401                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 402                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 403         elseif(WIN32)
 404                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 405         endif()
 406 endif()
 407
 408 if(LYX_INSTALL_PREFIX)
 409         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 410         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 411 endif()
 412 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 413
 414 string(REGEX REPLACE "/lyx${LYX_INSTALL_SUFFIX}$" "/share" SYSTEM_DATADIR ${CMAKE_INSTALL_PREFIX})
 415
 416 if(LYX_PACKAGE_SUFFIX)
 417         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 418 else()
 419         set(PACKAGE ${PACKAGE_BASE})
 420 endif()
 421
 422 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 423         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 424         if (UNIX)
 425                 # don't use the default "/usr/local"
 426                 # but respect the user-choice on the command-line
 427                 if(LYX_INSTALL_SUFFIX)
 428                         set(CMAKE_INSTALL_PREFIX "/usr/local/lyx${LYX_INSTALL_SUFFIX}" CACHE PATH "LyX default install prefix" FORCE)
 429                 else()
 430                         set(CMAKE_INSTALL_PREFIX "/usr/local/${LYX_PROJECT}" CACHE PATH "LyX default install prefix" FORCE)
 431                 endif()
 432         endif()
 433         if(WIN32)
 434                 set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 435         endif()
 436 endif()
 437 if(IS_ABSOLUTE)
 438         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 439 else()
 440         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 441 endif()
 442
 443
 444
 445 if(NOT LYX_DATA_SUBDIR)
 446         if (WIN32)
 447                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 448         else()
 449                 set(LYX_DATA_SUBDIR "" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 450         endif()
 451 endif()
 452
 453 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 454 set(LYX_LOCALEDIR "locale")
 455 set(LYX_ABS_INSTALLED_LOCALEDIR "${LYX_ABS_INSTALLED_DATADIR}/${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}")
 456 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 457
 458 if(LYX_BUNDLE AND APPLE)
 459         set(LYX_MAN_DIR "${LYX_DATA_SUBDIR}" CACHE STRING "Install location for man pages.")
 460 else()
 461         set(LYX_MAN_DIR "/usr/local/man/man1" CACHE STRING "Install location for man pages.")
 462 endif()
 463 mark_as_advanced(LYX_MAN_DIR)
 464
 465 if(LYX_INSTALL AND WIN32)
 466         message(STATUS "Configuring NSIS files")
 467         configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 468         configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 469         configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 470         message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 471 endif()
 472
 473 if(NOT GROUP_CODE)
 474         #set(GROUP_CODE "The Golden Code")
 475         set(GROUP_CODE flat)
 476 endif()
 477
 478 # lyx's source files
 479 set(LYX_CPP_FILES [a-zA-Z]*.cpp)
 480 set(LYX_HPP_FILES [a-zA-Z]*.h)
 481 set(LYX_MOC_FILES moc_*.cpp)
 482
 483 include(ProjectSourceGroup)
 484
 485
 486 if(LYX_PROFILE AND NOT MSVC)
 487         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 488         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg")
 489         set(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS}  -pg")
 490 else()
 491         set(LYX_PROFILE OFF)
 492 endif()
 493
 494
 495 if(LYX_NO_OPTIMIZE)
 496         set(CMAKE_BUILD_TYPE None)
 497         set(LYX_DEBUG OFF)
 498         set(LYX_RELEASE OFF)
 499         set(LYX_PROFILE OFF)
 500 elseif(LYX_RELEASE)
 501         set(CMAKE_BUILD_TYPE Release)
 502         set(LYX_DEBUG OFF)
 503         set(LYX_PROFILE OFF)
 504 elseif(LYX_PROFILE)
 505         set(CMAKE_BUILD_TYPE Profile)
 506         set(LYX_DEBUG OFF)
 507 else()
 508         set(CMAKE_BUILD_TYPE Debug)
 509         set(LYX_DEBUG ON)
 510 endif()
 511
 512
 513 # When shared libs are supported enable this option
 514 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 515 if(LYX_SHARED_LIBRARIES)
 516         set(library_type SHARED)
 517 else()
 518         set(library_type STATIC)
 519 endif()
 520
 521 if(NOT MSVC)
 522         if(NOT LYX_QUIET)
 523                 set(CMAKE_VERBOSE_MAKEFILE ON)
 524         endif()
 525     set(LYX_CXX_FLAGS "-Wall -Wunused-parameter ${LYX_GCC11_MODE}")
 526         if(LYX_STDLIB_DEBUG)
 527                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 528         endif()
 529         if(LYX_CONCEPT_CHECKS)
 530                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCPP_CONCEPT_CHECKS")
 531         endif()
 532         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 533         set(CMAKE_CXX_FLAGS_DEBUG "${LYX_CXX_FLAGS} -fno-strict-aliasing -O0 -g3 -D_DEBUG" CACHE TYPE STRING FORCE)
 534         if(MINGW)
 535                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 536         else()
 537                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 538         endif()
 539 endif()
 540
 541 set(LYX_CXX_FLAGS_EXTRA "" CACHE STRING "Desired semicolon separated list of extra cxx compile flags, like '-Werror'")
 542 mark_as_advanced(LYX_CXX_FLAGS_EXTRA)
 543 if(LYX_CXX_FLAGS_EXTRA)
 544         foreach(_flag ${LYX_CXX_FLAGS_EXTRA})
 545                 add_definitions(${_flag})
 546         endforeach()
 547 endif()
 548
 549 if(LYX_XMINGW)
 550     set(QT_MINGW_DIR ${LYX_QT4} CACHE PATH "Qt for Mingw" FORCE)
 551     list(APPEND CMAKE_FIND_ROOT_PATH ${QT_MINGW_DIR} ${GNUWIN32_DIR})
 552 endif()
 553 if(LYX_USE_QT MATCHES "QT5")
 554         find_package(Qt5Core REQUIRED)
 555         if (Qt5Core_FOUND)
 556                 find_package(Qt5Widgets REQUIRED)
 557                 if(APPLE)
 558                         find_package(Qt5MacExtras REQUIRED)
 559                 endif()
 560                 find_package(Qt5X11Extras QUIET)
 561                 set(QTVERSION ${Qt5Core_VERSION})
 562                 macro (qt_use_modules)
 563                         qt5_use_modules(${ARGN})
 564                 endmacro()
 565                 macro (qt_add_resources)
 566                         qt5_add_resources(${ARGN})
 567                 endmacro()
 568                 macro (qt_wrap_uifiles)
 569                         qt5_wrap_ui(${ARGN})
 570                 endmacro()
 571                 message(STATUS "Found Qt-Version ${QTVERSION}")
 572         endif()
 573 elseif(LYX_USE_QT MATCHES "QT4")
 574         find_package(Qt4 "4.5.0" REQUIRED)
 575         macro (qt_use_modules)
 576         endmacro()
 577         macro (qt_add_resources)
 578                 qt4_add_resources(${ARGN})
 579         endmacro()
 580         macro (qt_wrap_uifiles)
 581                 qt4_wrap_ui(${ARGN})
 582         endmacro()
 583 else()
 584   message(FATAL_ERROR "Unhandled value for LYX_USE_QT (${LYX_USE_QT})")
 585 endif()
 586
 587 find_package(Magic)
 588 if(Magic_FOUND)
 589         set(HAVE_MAGIC_H 1)
 590 endif()
 591
 592 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 593
 594 set(Spelling_FOUND OFF)
 595 set(Include_used_spellchecker)   # String will be inserted into config.h
 596
 597 foreach(_spell "ASPELL" "Enchant" "Hunspell")
 598   string(TOUPPER ${_spell} _upspell)
 599   find_package(${_spell})
 600   if (${_upspell}_FOUND)
 601     include_directories(${${_upspell}_INCLUDE_DIR})
 602     set(Spelling_FOUND ON)
 603     message(STATUS "Building with USE_${_upspell}")
 604     set(Include_used_spellchecker "${Include_used_spellchecker}#define USE_${_upspell} 1\n")
 605   else()
 606     if(LYX_${_upspell})
 607       message(FATAL_ERROR "Required ${_spell} devel package not found")
 608     else()
 609       message(STATUS "${_upspell} not found, building without ${_spell} support")
 610     endif()
 611   endif()
 612 endforeach()
 613
 614 if(LYX_NLS)
 615         FIND_PROGRAM(LYX_PYTHON_EXECUTABLE python2 python HINTS ${GNUWIN32_DIR}/python)
 616         find_package(LyXGettext)
 617         if(LYX_PYTHON_EXECUTABLE AND GETTEXT_FOUND)
 618                 add_subdirectory(po "${TOP_BINARY_DIR}/po")
 619         else()
 620                 # Install only supplied .gmo-files
 621                 file(GLOB _gmofiles RELATIVE "${TOP_SRC_DIR}/po" "${TOP_SRC_DIR}/po/*.gmo")
 622                 message(STATUS "Installing provided .gmo-files only")
 623                 foreach( _gmo ${_gmofiles})
 624                         string(REGEX REPLACE "\\.gmo$" "" _lang ${_gmo})
 625                         install(FILES "${TOP_SRC_DIR}/po/${_gmo}" DESTINATION ${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}/${_lang}/LC_MESSAGES RENAME ${PACKAGE}.mo)
 626                 endforeach()
 627         endif()
 628 endif()
 629
 630
 631 find_package(ICONV REQUIRED)
 632 find_package(ZLIB REQUIRED)
 633
 634 if(LYX_EXTERNAL_BOOST)
 635         message(STATUS "Searching for boost")
 636         find_package(Boost COMPONENTS signals regex) #TODO could REQUIRED be used
 637         if(Boost_FOUND)
 638                 message(STATUS "Boost found")
 639                 message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 640                 set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 641         else()
 642                 message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 643         endif()
 644 else()
 645         if(LYX_USE_TR1_REGEX)
 646                 set(Lyx_Boost_Libraries boost_signals)
 647         else()
 648                 set(Lyx_Boost_Libraries boost_signals boost_regex)
 649         endif()
 650         add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 651         add_definitions(-DBOOST_SIGNALS_NO_DEPRECATION_WARNING=1)
 652         include_directories(${TOP_SRC_DIR}/boost)
 653         add_subdirectory(boost "${TOP_BINARY_DIR}/boost")
 654 endif()
 655
 656
 657
 658
 659 if(WIN32)
 660         if(NOT LYX_CONSOLE)
 661                 set(WIN32_CONSOLE WIN32)
 662                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARY})
 663         endif()
 664         if(MSVC)
 665                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 666                 # disable checked iterators for msvc release builds to get maximum speed
 667                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 668         else()
 669                 add_definitions(-DWINVER=0x0500)
 670         endif()
 671 endif()
 672
 673 # Compute qt4-version from ${QTVERSION}
 674
 675 message(STATUS "")
 676 foreach(_v PACKAGE PACKAGE_VERSION
 677         PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 678         LYX_ABS_TOP_SRCDIR
 679         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 680         if(NOT DEFINED ${_v})
 681                 message(FATAL_ERROR "${_v} not defined")
 682         endif()
 683         string(SUBSTRING "${_v}                            " 0 28 _v1)
 684         message(STATUS "----- ${_v1}: ${${_v}}")
 685 endforeach(_v)
 686 message(STATUS "")
 687
 688
 689 if(LYX_PCH)
 690         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 691         # Not sure if it works for all non-msvc compilers
 692         include(PCHSupport_26)
 693         configure_file(${TOP_CMAKE_PATH}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
 694         configure_file(${TOP_CMAKE_PATH}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 695         add_definitions(-DLYX_ENABLE_PCH)
 696
 697         if(MSVC)
 698                 macro(lyx_add_msvc_pch name_)
 699                         set_source_files_properties(${${name_}_sources} PROPERTIES
 700                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 701                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
 702                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 703                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
 704                                 ${TOP_BINARY_DIR}/pcheaders.h)
 705                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 706                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 707                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 708                 endmacro(lyx_add_msvc_pch)
 709                 macro(lyx_add_gcc_pch name_)
 710                 endmacro()
 711         else()
 712                 macro(lyx_add_msvc_pch name_)
 713                 endmacro()
 714                 macro(lyx_add_gcc_pch name_)
 715                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT)
 716                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
 717                 endmacro()
 718         endif()
 719 else()
 720         macro(lyx_add_msvc_pch)
 721         endmacro(lyx_add_msvc_pch)
 722         macro(lyx_add_gcc_pch name_)
 723         endmacro()
 724 endif()
 725
 726
 727 if(MSVC)
 728
 729         if(LYX_VLD)
 730                 set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/development/Win32/vld)
 731                 add_subdirectory(${vld_path}/cmake)
 732                 include(${vld_path}/cmake/vld.cmake) # forced include
 733                 set(vld_dll vld)
 734         endif()
 735
 736         if(LYX_WALL)
 737                 # Use the highest warning level
 738                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 739
 740                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 741                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 742                 else()
 743                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 744                 endif()
 745
 746                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 747                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 748                 else()
 749                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 750                 endif()
 751
 752                 # add here warnings which should produce an error /weXXXX
 753                 set(MSVC_W_ERROR   "/we4101 /we4189")
 754                 # add here warnings which should be disabled /wdXXXX
 755                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 756
 757                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 758                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 759                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 760
 761         else()
 762                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 763
 764                 # add here warnings which should produce an error /weXXXX
 765                 set(MSVC_W_ERROR   "/we4101 /we4189")
 766                 # add here warnings which should be disabled /wdXXXX
 767                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 768
 769                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 770                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 771                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 772
 773         endif()
 774
 775         if (NOT Qt5Core_FOUND)
 776                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 777                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 778                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 779         endif()
 780
 781         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 782         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 783         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 784         message(STATUS "")
 785 endif()
 786
 787
 788 if(LYX_DEBUG_GLIBC)
 789         set(_GLIBCXX_DEBUG ON)
 790 endif()
 791
 792 if(LYX_DEBUG_GLIBC_PEDANTIC)
 793         set(_GLIBCXX_DEBUG_PEDANTIC ON)
 794 endif()
 795
 796 # Xcode compiler
 797 if (CMAKE_GENERATOR MATCHES Xcode)
 798         if (XCODE_VERSION VERSION_LESS "5.0")
 799                 # Automatically select the Xcode compiler if not set
 800                 if (NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 801                         # XCode >= 3.1 has gcc 4.2 (up to actual Xcode)
 802                         if (XCODE_VERSION VERSION_GREATER "3.1")
 803                                 SET(CMAKE_XCODE_ATTRIBUTE_GCC_VERSION "com.apple.compilers.llvmgcc42")
 804                         ENDIF(XCODE_VERSION VERSION_GREATER "3.1")
 805                 ENDIF(NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 806                 # Print the selected compiler version
 807         MESSAGE(STATUS "---- Using XCode compiler CMAKE_XCODE_ATTRIBUTE_GCC_VERSION=${CMAKE_XCODE_ATTRIBUTE_GCC_VERSION}")
 808         ENDIF(XCODE_VERSION VERSION_LESS "5.0")
 809 ENDIF(CMAKE_GENERATOR MATCHES Xcode)
 810
 811 if (WIN32 AND Qt5Core_FOUND)
 812         set(Z_PREFIX 1)
 813 endif()
 814
 815 # compiler tests, config.h generation
 816 if(MSVC AND NOT LYX_CONFIGURE_CHECKS)
 817         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.msvc ${TOP_BINARY_DIR}/configCompiler.h)
 818 else()
 819         include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
 820         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
 821 endif()
 822
 823 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
 824
 825 if(QTVERSION MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+).*")
 826         MATH(EXPR QT4_VERSION "(${CMAKE_MATCH_1}<<16)|(${CMAKE_MATCH_2}<<8)|${CMAKE_MATCH_3}")
 827 endif()
 828
 829
 830 set (cmd ${CMAKE_CTEST_COMMAND})
 831 if (MSVC)
 832         set (cmd ${cmd} -C ${CMAKE_CFG_INTDIR})
 833 else ()
 834         set (cmd ${cmd} -C ${CMAKE_BUILD_TYPE})
 835 endif ()
 836 add_custom_target (lyx_run_tests COMMAND ${cmd})
 837 set_target_properties(lyx_run_tests PROPERTIES FOLDER "tests")
 838
 839 if(LYX_ASAN)
 840     set(LYX_CXX_FLAGS "-fsanitize=address -fno-omit-frame-pointer -g")
 841     message(STATUS)
 842     message(STATUS "Address sanitizer enabled. Usage:")
 843     message(STATUS "    wget https://llvm.org/svn/llvm-project/compiler-rt/trunk/lib/asan/scripts/asan_symbolize.py")
 844     message(STATUS "    chmod  +x ./asan_symbolize.py")
 845     message(STATUS "    ./bin/lyx2.2 2>&1 | ./asan_symbolize.py  | c++filt ")
 846     message(STATUS)
 847 endif()
 848
 849 if(LYX_INSTALL)
 850         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 851                 message(STATUS "Python required to create doc!")
 852         else()
 853                 if(UNIX)
 854                         add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
 855                 endif()
 856                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
 857         endif()
 858         include(../Install)
 859 endif()
 860
 861 add_subdirectory(src "${TOP_BINARY_DIR}/src")
 862 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
 863 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
 864 add_subdirectory(lib/examples "${TOP_BINARY_DIR}/lib/examples")
 865 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
 866 add_subdirectory(development/autotests "${TOP_BINARY_DIR}/autotests")
 867 if(LYX_ENABLE_URLTESTS)
 868         add_subdirectory(development/checkurls "${TOP_BINARY_DIR}/checkurls")
 869 endif()
 870
 871 message(STATUS)
 872 message(STATUS "Build params, switch LYX_* options by -DLYX_*=ON or OFF, LYX_* combos by -DLYX_*=value:")
 873 message(STATUS)
 874
 875 LYX_OPTION_LIST_ALL(used)
 876
 877
 878 if(LYX_NLS)
 879         message(STATUS)
 880         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
 881         message(STATUS)
 882         message(STATUS "  * iconv")
 883         message(STATUS "     - header : ${ICONV_HEADER}")
 884         message(STATUS "     - library: ${ICONV_LIBRARY}")
 885         message(STATUS "  * zlib")
 886         message(STATUS "     - header : ${ZLIB_HEADER}")
 887         message(STATUS "     - library: ${ZLIB_LIBRARY}")
 888         message(STATUS)
 889 endif()
 890
 891 # Apple has builtin native spell checker,
 892 # no need to warn for missing Aspell, Hunspell or Enchant
 893 if(NOT Spelling_FOUND AND NOT APPLE)
 894   if(LYX_REQUIRE_SPELLCHECK)
 895     set(_mode "FATAL_ERROR")
 896   else()
 897     set(_mode "STATUS")
 898   endif()
 899   message(${_mode} "No spellcheck libraries found. LyX will be unable use spellchecking")
 900 endif()
 901
 902 include("${TOP_CMAKE_PATH}/LyxPackaging.cmake")
 903
 904 if(ENABLE_DIST)
 905   # Use git to create the source package
 906   # git archive --format=tgz --output=/home/kornel/x.tar.gz master
 907   if(UNIX)
 908     set(DIST_FORMAT tgz)
 909   else()
 910     set(DIST_FORMAT zip)
 911   endif()
 912   set(DIST_NAME ${CMAKE_PROJECT_NAME}-${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}-${CMAKE_SYSTEM_NAME}.${DIST_FORMAT})
 913
 914   add_custom_command(
 915     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME}
 916     COMMAND  ${LYX_GITVERSION} archive --format=${DIST_FORMAT} --output=${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME} master
 917     WORKING_DIRECTORY ${TOP_SRC_DIR})
 918   add_custom_target(git-archive DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME})
 919 endif()
 920
 921 # Last directory to be included so that the fixup code (OS X)
 922 # can be run last
 923 add_subdirectory(development/cmake/post_install)
 924
 925 message(STATUS)