CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 2.6.4)
   8
   9 set(LYX_PROJECT LyX)
  10
  11 enable_testing()
  12
  13 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README REALPATH) # Resolve symlinks
  14 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  15 message(STATUS "TOP_SRC_DIR = ${TOP_SRC_DIR}")
  16
  17 set(LYX_CMAKE_DIR "development/cmake")
  18 set(TOP_CMAKE_PATH "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}")
  19 set(TOP_MODULE_PATH "${TOP_CMAKE_PATH}/modules")
  20 set(TOP_SCRIPT_PATH "${TOP_CMAKE_PATH}/scripts")
  21
  22 set(CMAKE_MODULE_PATH "${TOP_MODULE_PATH}")
  23
  24 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  25
  26 message(STATUS)
  27 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  28         message(STATUS "Building in-source")
  29         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  30 else()
  31         message(STATUS "Building out-of-source")
  32         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  33 endif()
  34
  35 # This directory should be used if some test uses lyx-executable
  36 set(LYX_TESTS_USERDIR "${TOP_BINARY_DIR}/Testing/.lyx")
  37 file(MAKE_DIRECTORY "${LYX_TESTS_USERDIR}")
  38
  39 if(COMMAND cmake_policy)
  40         cmake_policy(SET CMP0003 OLD)
  41         cmake_policy(SET CMP0005 OLD)
  42         # Installing MACOSX_BUNDLE targets requires a BUNDLE DESTINATION
  43         cmake_policy(SET CMP0006 NEW)
  44         if(POLICY CMP0020)
  45                 cmake_policy(SET CMP0020 OLD)
  46         endif()
  47         if(POLICY CMP0028)
  48                 cmake_policy(SET CMP0028 OLD)
  49         endif()
  50         if(POLICY CMP0043)
  51                 # COMPILE_DEFINITIONS are not used yet. Enable new behavior.
  52                 cmake_policy(SET CMP0043 NEW)
  53         endif()
  54 endif()
  55
  56 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  57
  58 # Supress regeneration
  59 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  60
  61 if(LYX_XMINGW)
  62     set(CMAKE_SYSTEM_NAME Windows)
  63     set(TOOLNAME ${LYX_XMINGW})
  64     set(TOOLCHAIN "${TOOLNAME}-")
  65     set(CMAKE_C_COMPILER   "${TOOLCHAIN}gcc"     CACHE PATH "Mingw C compiler" FORCE)
  66     set(CMAKE_CXX_COMPILER "${TOOLCHAIN}g++"     CACHE PATH "Mingw C++ compiler" FORCE)
  67     set(CMAKE_RC_COMPILER  "${TOOLCHAIN}windres" CACHE PATH "Mingw rc compiler" FORCE)
  68
  69     set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM BOTH)
  70     set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY)
  71     set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY)
  72 endif()
  73
  74 if(NOT help AND NOT HELP)
  75   # 'project' triggers the searching for a compiler
  76   project(${LYX_PROJECT})
  77   if (CMAKE_COMPILER_IS_GNUCXX)
  78     if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS "4.0")
  79       message(STATUS "Gnu CXX compiler version = ${CMAKE_CXX_COMPILER_VERSION}")
  80       message(STATUS "is too old, should be >= 4.0")
  81       message(FATAL_ERROR "Exiting")
  82     endif()
  83   endif()
  84 endif()
  85
  86 if(UNIX)
  87         set(ARCH_TRIPLET )
  88         FIND_PROGRAM(DPKG_ARCHITECTURE_EXECUTABLE dpkg-architecture)
  89         if(DPKG_ARCHITECTURE_EXECUTABLE)
  90                 EXECUTE_PROCESS(COMMAND ${DPKG_ARCHITECTURE_EXECUTABLE} -qDEB_HOST_MULTIARCH
  91                                 OUTPUT_VARIABLE ARCH_TRIPLET
  92                                 ERROR_VARIABLE ERROR_ARCH_TRIPLET
  93                                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  94         endif()
  95 endif()
  96 if(ARCH_TRIPLET)
  97         set(SYSTEM_LIB_DIRS /usr/lib /usr/lib/${ARCH_TRIPLET} /usr/local/lib)
  98 else()
  99         set(SYSTEM_LIB_DIRS /usr/lib /usr/local/lib)
 100 endif()
 101
 102 include(LyXMacros)
 103
 104 # Usage LYX_OPTION
 105 # 1. parameter: option name without prefix 'LYX_'
 106 # 2. parameter: description
 107 # 3. parameter: default value, ON or OFF
 108 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
 109
 110 # Usage LYX_COMBO
 111 # 1. parameter: name without prefix 'LYX_'
 112 # 2. parameter: description
 113 # 3. parameter: default value
 114 # 4-n parameter: possible other string values
 115
 116 LYX_OPTION_INIT()
 117
 118 # Options for all compilers/systems
 119 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
 120 LYX_OPTION(LOCALVERSIONING  "Add version info to created package name (only used if LYX_CPACK option set)" OFF ALL)
 121 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
 122 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
 123 LYX_OPTION(REQUIRE_SPELLCHECK "Abort if no spellchecker available" OFF ALL)
 124 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
 125 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
 126 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
 127 LYX_OPTION(DEVEL_VERSION    "Build developer version" OFF ALL)
 128 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" OFF ALL)
 129 LYX_OPTION(DEBUG            "Enforce debug build"  OFF ALL)
 130 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
 131 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
 132 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
 133 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
 134 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
 135 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
 136 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
 137 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
 138 LYX_OPTION(ENABLE_URLTESTS  "Enable for URL tests" OFF ALL)
 139 LYX_OPTION(ENABLE_EXPORT_TESTS "Enable for export tests" OFF ALL)
 140 LYX_OPTION(ASAN             "Use address sanitizer" OFF ALL)
 141 LYX_COMBO(USE_QT            "Use Qt version as frontend" QT4 QT5)
 142 LYX_OPTION(3RDPARTY_BUILD   "Build 3rdparty libs" OFF ALL)
 143
 144 # GCC specific
 145 LYX_OPTION(PROFILE              "Build profile version" OFF GCC)
 146 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" OFF GCC)
 147 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
 148 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
 149 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++ pedantic debug mode" OFF GCC)
 150 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" OFF GCC)
 151 LYX_OPTION(PROFILE              "Build with options for gprof" OFF GCC)
 152 LYX_OPTION(ENABLE_CXX11         "Build with options for c++11-mode" OFF GCC)
 153
 154 # MSVC specific
 155 LYX_OPTION(CONSOLE               "Show console on Windows, enforce with =FORCE" ON MSVC)
 156 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
 157 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
 158 LYX_OPTION(CONFIGURE_CHECKS      "Also run configure checks for MSVC" OFF MSVC)
 159 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
 160
 161 # APPLE specific
 162 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
 163 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
 164
 165
 166 if(help OR HELP)
 167         message(STATUS)
 168         message(STATUS "Available options: (dis/enable with -DLYX_*=OFF/ON)")
 169         message(STATUS)
 170         LYX_OPTION_LIST_ALL(help)
 171         message(STATUS)
 172         RETURN()
 173 endif()
 174
 175 # Check option dependencies
 176
 177 if(LYX_DMG)
 178         set(LYX_BUNDLE ON)
 179         set(LYX_CPACK ON)
 180 endif()
 181
 182 if(LYX_CPACK)
 183         set(LYX_INSTALL ON)
 184 endif()
 185
 186 if(LYX_INSTALL)
 187         set(LYX_NLS ON)
 188         if(WIN32 AND NOT MINGW)
 189                 set(LYX_HUNSPELL ON)
 190         endif()
 191         if(LYX_CONSOLE MATCHES "FORCE")
 192                 set(LYX_CONSOLE ON)
 193         else()
 194                 set(LYX_CONSOLE OFF)
 195         endif()
 196         set(LYX_PACKAGE_SUFFIX ON)
 197         if(NOT LYX_DEBUG)
 198                 set(LYX_RELEASE ON)
 199         endif()
 200         set(LYX_PROFILE OFF)
 201 endif()
 202
 203
 204 if(LYX_MERGE_FILES)
 205         set(LYX_PCH OFF)
 206 else()
 207         set(LYX_MERGE_REBUILD OFF)
 208 endif()
 209
 210
 211 if(LYX_DEPENDENCIES_DOWNLOAD)
 212         message(STATUS)
 213     if(MSVC12)
 214         set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2013-deps)
 215         set(deps_files lyx-windows-deps-msvc2013.zip)
 216         set(deps_server http://ftp.lyx.de/LyX-Windows-Deps)
 217         set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2013)
 218     else()
 219         set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 220             set(deps_files lyx20-deps-msvc2010-x86.zip)
 221             set(deps_server http://downloads.sourceforge.net/project/lyx/Win_installers/Dependencies)
 222         set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/deps20)
 223     endif()
 224     message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 225         foreach(it ${deps_files})
 226                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 227                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 228                 if(NOT already_downloaded)
 229                         message(STATUS "Downloading ${it} ...")
 230                         file(DOWNLOAD ${deps_server}/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS STATUS status LOG log)
 231                         list(GET status 0 status_code)
 232                         list(GET status 1 status_string)
 233                         if(NOT status_code EQUAL 0)
 234                                 file(REMOVE ${LYX_DEPENDENCIES_DIR}/${it})
 235                                 message(FATAL_ERROR "error: downloading '${it}' failed. status_code: ${status_code}, status_string: ${status_string}. \nLog: ${log} ")
 236                         endif()
 237                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 238                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 239                 endif()
 240         endforeach()
 241 endif()
 242
 243
 244
 245 message(STATUS)
 246
 247 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 248 if(WIN32)
 249         set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 250 else()
 251         set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 252 endif()
 253
 254
 255 set(LYX_GCC11_MODE)
 256 if(UNIX OR MINGW)
 257         execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION OUTPUT_STRIP_TRAILING_WHITESPACE)
 258         message(STATUS "Using GCC version ${GCC_VERSION}")
 259         if(GCC_VERSION VERSION_LESS 4.9)
 260                 # <regex> in gcc is unusable in versions less than 4.9.0
 261                 # see https://gcc.gnu.org/bugzilla/show_bug.cgi?id=53631
 262                 set(LYX_USE_STD_REGEX 0)
 263         else()
 264                 if (LYX_ENABLE_CXX11)
 265                         set(LYX_USE_STD_REGEX 1)
 266                 endif()
 267         endif()
 268         if (LYX_ENABLE_CXX11)
 269                 find_package(CXX11Compiler)
 270                 if(NOT CXX11COMPILER_FOUND)
 271                         message(FATAL_ERROR "A C++11 compatible compiler is required.")
 272                 endif()
 273                 set(LYX_GCC11_MODE "${CXX11_FLAG}")
 274         endif()
 275 else()
 276         set(LYX_USE_STD_REGEX 0)
 277 #       if(MSVC10)
 278 #               set(LYX_USE_STD_REGEX 1) #TODO should we use it in ECMAScript mode?
 279 #       endif()
 280 endif()
 281
 282
 283 set(VERSION_INFO "CMake Build")
 284
 285 # Try to get some informations from configure.ac
 286
 287 include(LyXPaths)
 288 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 289
 290 if(WIN32)
 291         set(USE_WINDOWS_PACKAGING ON)
 292 elseif(APPLE)
 293         set(USE_MACOSX_PACKAGING ON)
 294 else()
 295         set(USE_POSIX_PACKAGING ON)
 296 endif()
 297
 298 macro(setstripped _varname)
 299         if(${ARGC} GREATER 1)
 300                 string(STRIP "${ARGV1}" _v)
 301                 if(USE_POSIX_PACKAGING)
 302                         string(TOLOWER ${_v} ${_varname})
 303                 else()
 304                         set(${_varname} ${_v})
 305                 endif()
 306         else()
 307                 set(${_varname})
 308         endif()
 309 endmacro(setstripped)
 310
 311 foreach(_c_l ${_config_lines} )
 312         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 313                 setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 314                 setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 315                 setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 316                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\)\(\\.\([0-9]+\)\)?.*$")
 317                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 318                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 319                         set(LYX_PATCH_VERSION ${CMAKE_MATCH_4})
 320                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 321                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 322                         set(LYX_INSTALL_SUFFIX "${CMAKE_MATCH_1}.${CMAKE_MATCH_2}")
 323                 endif()
 324         endif()
 325         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 326                 set(LYX_DATE "${CMAKE_MATCH_1}")
 327         endif()
 328 endforeach(_c_l)
 329
 330 FIND_PROGRAM(LYX_GITVERSION git)
 331 #message(STATUS "gitversion = ${LYX_GITVERSION}")
 332 set(LYX_REVISION_VERSION ${LYX_PATCH_VERSION})
 333 if(LYX_GITVERSION)
 334   if (LYX_LOCALVERSIONING)
 335     # Find the revision number and for later use
 336     EXECUTE_PROCESS(COMMAND ${LYX_GITVERSION} describe --match 2.0.0 HEAD
 337       WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE LYX_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 338     if (LYX_PACKAGE_RELEASE MATCHES "^2\\.0\\.0\\-\([0-9]+\)\\-.*$")
 339       # We will add offset of 40000 to get appropriate value to
 340       # previous svn.
 341       # We use this value than also to set the package-patch-value
 342       MATH(EXPR tmp_REVISION_VERSION "(${CMAKE_MATCH_1}+40000)")
 343       set(LYX_REVISION_VERSION "${LYX_PATCH_VERSION}-${tmp_REVISION_VERSION}git")
 344       set(ENABLE_DIST ON)
 345     endif()
 346   endif()
 347 endif()
 348
 349 # Set the programs (lyx, tex2lyx, etc.) suffix
 350 # When building an OS X bundle, we will append
 351 # the suffix only to the bundle, not to the programs
 352 set(PROGRAM_SUFFIX "")
 353 if(LYX_PROGRAM_SUFFIX AND NOT (APPLE AND LYX_BUNDLE))
 354         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 355 endif()
 356 set(_lyx "${PACKAGE_BASE}${PROGRAM_SUFFIX}")
 357 set(_tex2lyx tex2lyx${PROGRAM_SUFFIX})
 358
 359 add_custom_target(lyx_version ALL
 360   COMMAND ${CMAKE_COMMAND} -DTOP_SRC_DIR=${TOP_SRC_DIR} -DTOP_CMAKE_PATH=${TOP_CMAKE_PATH} -DTOP_BINARY_DIR=${TOP_BINARY_DIR} -DLYX_DATE=${LYX_DATE} -P ${TOP_SCRIPT_PATH}/LyXGetVersion.cmake
 361   )
 362 set_target_properties(lyx_version PROPERTIES FOLDER "applications")
 363
 364 # Default paths for installed utilities (tex2lyx, lyxclient, etc.)
 365 set(LYX_UTILITIES_INSTALL_PATH bin)
 366
 367 if(LYX_BUNDLE)
 368         set(LYX_CPACK ON)
 369
 370         message(STATUS)
 371         message(STATUS "Bundle creation is enabled (experimental):")
 372         message(STATUS "    make")
 373         message(STATUS "    make install/strip")
 374         message(STATUS "    make package")
 375         if(APPLE)
 376                 set(MACOSX_BUNDLE TRUE)
 377                 # This sets the bundle + executable names
 378                 set(_lyx "${PACKAGE_BASE}${LYX_INSTALL_SUFFIX}")
 379                 # This sets the Info.plist executable name
 380                 set(osx_bundle_program_name ${_lyx})
 381                 # Bundle name
 382                 set(LYX_BUNDLE_NAME ${_lyx})
 383
 384                 # This will contain the list of files that need to be included
 385                 # in the bundle and their location within the bundle
 386                 set(OSX_BUNDLE_FILES "${TOP_SRC_DIR}/development/MacOSX/LyX.sdef;${TOP_SRC_DIR}/development/MacOSX/LyXapp.icns;${CMAKE_BINARY_DIR}/lyxrc.dist")
 387                 set(OSX_BUNDLE_DIRS "Resources;Resources;Resources")
 388
 389                 # Process Info.plist and lyxrc.dist
 390                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/Info.plist.in" "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 391                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/lyxrc.dist.in" "${CMAKE_CURRENT_BINARY_DIR}/lyxrc.dist")
 392
 393                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 394                 set(LYX_DATA_SUBDIR ${LYX_BUNDLE_NAME}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 395
 396                 # Variables used by CPack
 397                 set(CPACK_BUNDLE_NAME ${LYX_BUNDLE_NAME})
 398                 set(CPACK_BUNDLE_PLIST "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 399                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${LYX_BUNDLE_NAME}.app)
 400
 401                 # Set the install paths
 402                 set(LYX_UTILITIES_INSTALL_PATH ${LYX_BUNDLE_NAME}.app/Contents/MacOS)
 403                 if(NOT LYX_INSTALL_PREFIX)
 404                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 405                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 406                 endif()
 407                 # Change the owner so that the install can work
 408                 install(CODE "set(BU_CHMOD_BUNDLE_ITEMS 1)" COMPONENT Runtime)
 409         elseif(UNIX)
 410                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 411                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 412                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 413         elseif(WIN32)
 414                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 415         endif()
 416 endif()
 417
 418 if(LYX_INSTALL_PREFIX)
 419         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 420         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 421 endif()
 422 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 423
 424 string(REGEX REPLACE "/lyx${LYX_INSTALL_SUFFIX}$" "/share" SYSTEM_DATADIR ${CMAKE_INSTALL_PREFIX})
 425
 426 if(LYX_PACKAGE_SUFFIX)
 427         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 428 else()
 429         set(PACKAGE ${PACKAGE_BASE})
 430 endif()
 431
 432 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 433         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 434         if (UNIX)
 435                 # don't use the default "/usr/local"
 436                 # but respect the user-choice on the command-line
 437                 if(LYX_INSTALL_SUFFIX)
 438                         set(CMAKE_INSTALL_PREFIX "/usr/local/lyx${LYX_INSTALL_SUFFIX}" CACHE PATH "LyX default install prefix" FORCE)
 439                 else()
 440                         set(CMAKE_INSTALL_PREFIX "/usr/local/${LYX_PROJECT}" CACHE PATH "LyX default install prefix" FORCE)
 441                 endif()
 442         endif()
 443         if(WIN32)
 444                 set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 445         endif()
 446 endif()
 447 if(IS_ABSOLUTE)
 448         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 449 else()
 450         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 451 endif()
 452
 453
 454
 455 if(NOT LYX_DATA_SUBDIR)
 456         if (WIN32)
 457                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 458         else()
 459                 set(LYX_DATA_SUBDIR "" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 460         endif()
 461 endif()
 462
 463 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 464 set(LYX_LOCALEDIR "locale")
 465 set(LYX_ABS_INSTALLED_LOCALEDIR "${LYX_ABS_INSTALLED_DATADIR}/${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}")
 466 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 467
 468 if(LYX_BUNDLE AND APPLE)
 469         set(LYX_MAN_DIR "${LYX_DATA_SUBDIR}" CACHE STRING "Install location for man pages.")
 470 else()
 471         set(LYX_MAN_DIR "/usr/local/man/man1" CACHE STRING "Install location for man pages.")
 472 endif()
 473 mark_as_advanced(LYX_MAN_DIR)
 474
 475 if(LYX_INSTALL AND WIN32)
 476         message(STATUS "Configuring NSIS files")
 477         configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 478         configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 479         configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 480         message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 481 endif()
 482
 483 if(NOT GROUP_CODE)
 484         #set(GROUP_CODE "The Golden Code")
 485         set(GROUP_CODE flat)
 486 endif()
 487
 488 # lyx's source files
 489 set(LYX_CPP_FILES [a-zA-Z]*.cpp)
 490 set(LYX_HPP_FILES [a-zA-Z]*.h)
 491 set(LYX_MOC_FILES moc_*.cpp)
 492
 493 include(ProjectSourceGroup)
 494
 495
 496 if(LYX_PROFILE AND NOT MSVC)
 497         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 498         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg")
 499         set(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS}  -pg")
 500 else()
 501         set(LYX_PROFILE OFF)
 502 endif()
 503
 504
 505 if(LYX_NO_OPTIMIZE)
 506         set(CMAKE_BUILD_TYPE None)
 507         set(LYX_DEBUG OFF)
 508         set(LYX_RELEASE OFF)
 509         set(LYX_PROFILE OFF)
 510 elseif(LYX_RELEASE)
 511         set(CMAKE_BUILD_TYPE Release)
 512         set(LYX_DEBUG OFF)
 513         set(LYX_PROFILE OFF)
 514 elseif(LYX_PROFILE)
 515         set(CMAKE_BUILD_TYPE Profile)
 516         set(LYX_DEBUG OFF)
 517 else()
 518         set(CMAKE_BUILD_TYPE Debug)
 519         set(LYX_DEBUG ON)
 520 endif()
 521
 522
 523 # When shared libs are supported enable this option
 524 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 525 if(LYX_SHARED_LIBRARIES)
 526         set(library_type SHARED)
 527 else()
 528         set(library_type STATIC)
 529 endif()
 530
 531 if(NOT MSVC)
 532         if(NOT LYX_QUIET)
 533                 set(CMAKE_VERBOSE_MAKEFILE ON)
 534         endif()
 535     set(LYX_CXX_FLAGS "-Wall -Wunused-parameter ${LYX_GCC11_MODE}")
 536         if(LYX_STDLIB_DEBUG)
 537                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 538         endif()
 539         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 540         set(CMAKE_CXX_FLAGS_DEBUG "${LYX_CXX_FLAGS} -fno-strict-aliasing -O0 -g3 -D_DEBUG" CACHE TYPE STRING FORCE)
 541         if(MINGW)
 542                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 543         else()
 544                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 545         endif()
 546 endif()
 547
 548 set(LYX_CXX_FLAGS_EXTRA "" CACHE STRING "Desired semicolon separated list of extra cxx compile flags, like '-Werror'")
 549 mark_as_advanced(LYX_CXX_FLAGS_EXTRA)
 550 if(LYX_CXX_FLAGS_EXTRA)
 551         foreach(_flag ${LYX_CXX_FLAGS_EXTRA})
 552                 add_definitions(${_flag})
 553         endforeach()
 554 endif()
 555
 556 if(LYX_XMINGW)
 557         list(APPEND CMAKE_FIND_ROOT_PATH ${GNUWIN32_DIR})
 558 endif()
 559
 560 if(LYX_USE_QT MATCHES "QT5")
 561         find_package(Qt5Core REQUIRED)
 562         if (Qt5Core_FOUND)
 563                 find_package(Qt5Widgets REQUIRED)
 564                 if(APPLE)
 565                         find_package(Qt5MacExtras REQUIRED)
 566                 endif()
 567                 find_package(Qt5X11Extras QUIET)
 568                 find_package(Qt5WinExtras QUIET)
 569                 set(QTVERSION ${Qt5Core_VERSION})
 570                 macro (qt_use_modules)
 571                         qt5_use_modules(${ARGN})
 572                 endmacro()
 573                 macro (qt_add_resources)
 574                         qt5_add_resources(${ARGN})
 575                 endmacro()
 576                 macro (qt_wrap_uifiles)
 577                         qt5_wrap_ui(${ARGN})
 578                 endmacro()
 579                 message(STATUS "Found Qt-Version ${QTVERSION}")
 580                 if(WIN32)
 581                         set(LYX_QTMAIN_LIBRARY ${Qt5Core_QTMAIN_LIBRARIES})
 582                 endif()
 583         endif()
 584 elseif(LYX_USE_QT MATCHES "QT4")
 585         if(LYX_XMINGW)
 586                 set(QT_MINGW_DIR ${LYX_QT4} CACHE PATH "Qt for Mingw" FORCE)
 587                 list(APPEND CMAKE_FIND_ROOT_PATH ${QT_MINGW_DIR} ${GNUWIN32_DIR})
 588         endif()
 589         find_package(Qt4 "4.5.0" REQUIRED)
 590         macro (qt_use_modules)
 591         endmacro()
 592         macro (qt_add_resources)
 593                 qt4_add_resources(${ARGN})
 594         endmacro()
 595         macro (qt_wrap_uifiles)
 596                 qt4_wrap_ui(${ARGN})
 597         endmacro()
 598         if(WIN32)
 599                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARIES})
 600         endif()
 601 else()
 602   message(FATAL_ERROR "Unhandled value for LYX_USE_QT (${LYX_USE_QT})")
 603 endif()
 604
 605 find_package(Magic)
 606 if(Magic_FOUND)
 607         set(HAVE_MAGIC_H 1)
 608 endif()
 609
 610 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 611
 612 set(Spelling_FOUND OFF)
 613 set(Include_used_spellchecker)   # String will be inserted into config.h
 614
 615 if(LYX_3RDPARTY_BUILD)
 616     add_subdirectory(src/3rdparty/hunspell)
 617     add_definitions(-DHUNSPELL_STATIC)
 618     set(HUNSPELL_FOUND ON)
 619     message(STATUS "  * Hunspell:")
 620     message(STATUS "     - include: ${HUNSPELL_INCLUDE_DIR}")
 621     message(STATUS "     - library: ${HUNSPELL_LIBRARY}")
 622 endif()
 623
 624 foreach(_spell "ASPELL" "Enchant" "Hunspell")
 625   string(TOUPPER ${_spell} _upspell)
 626   if (NOT ${_upspell}_FOUND)
 627     find_package(${_spell})
 628   endif()
 629   if (${_upspell}_FOUND)
 630     include_directories(${${_upspell}_INCLUDE_DIR})
 631     set(Spelling_FOUND ON)
 632     message(STATUS "Building with USE_${_upspell}")
 633     set(Include_used_spellchecker "${Include_used_spellchecker}#define USE_${_upspell} 1\n")
 634   else()
 635     if(LYX_${_upspell})
 636       message(FATAL_ERROR "Required ${_spell} devel package not found")
 637     else()
 638       message(STATUS "${_upspell} not found, building without ${_spell} support")
 639     endif()
 640   endif()
 641 endforeach()
 642
 643
 644 find_package(PythonInterp 2.7 QUIET)
 645 if(PYTHONINTERP_FOUND)
 646   if(PYTHON_VERSION_STRING VERSION_GREATER 2.8)
 647     unset(PYTHONINTERP_FOUND)
 648   endif()
 649 endif()
 650
 651 if (NOT PYTHONINTERP_FOUND)
 652   unset(PYTHON_EXECUTABLE CACHE)
 653   unset(PYTHON_VERSION_MAJOR)
 654   unset(PYTHON_VERSION_MINOR)
 655   unset(PYTHON_VERSION_STRING)
 656   find_package(PythonInterp 3.3 REQUIRED)
 657 endif()
 658
 659 set(LYX_PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 660
 661 if(LYX_NLS)
 662         find_package(LyXGettext)
 663         if(LYX_PYTHON_EXECUTABLE AND GETTEXT_FOUND)
 664                 add_subdirectory(po "${TOP_BINARY_DIR}/po")
 665         else()
 666                 # Install only supplied .gmo-files
 667                 file(GLOB _gmofiles RELATIVE "${TOP_SRC_DIR}/po" "${TOP_SRC_DIR}/po/*.gmo")
 668                 message(STATUS "Installing provided .gmo-files only")
 669                 foreach( _gmo ${_gmofiles})
 670                         string(REGEX REPLACE "\\.gmo$" "" _lang ${_gmo})
 671                         install(FILES "${TOP_SRC_DIR}/po/${_gmo}" DESTINATION ${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}/${_lang}/LC_MESSAGES RENAME ${PACKAGE}.mo)
 672                 endforeach()
 673         endif()
 674 endif()
 675
 676 if(UNIX)
 677     find_package(ICONV REQUIRED)
 678     find_package(ZLIB REQUIRED)
 679 endif()
 680
 681 if(LYX_3RDPARTY_BUILD)
 682     add_subdirectory(src/3rdparty/libiconv)
 683     set(HAVE_ICONV_CONST 1)
 684     add_subdirectory(src/3rdparty/zlib)
 685 endif()
 686
 687
 688 if(LYX_EXTERNAL_BOOST)
 689         message(STATUS "Searching for boost")
 690         if(LYX_USE_STD_REGEX)
 691                 find_package(Boost COMPONENTS signals)
 692         else()
 693                 find_package(Boost COMPONENTS signals regex)
 694         endif()
 695         if(Boost_FOUND)
 696                 message(STATUS "Boost found")
 697                 message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 698                 set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 699                 if (LYX_STDLIB_DEBUG)
 700                         # Comment from  Jean-Marc Lasgouttes:
 701                         # In general, system boost libraries are incompatible with
 702                         # the use of stdlib-debug in libstdc++. See ticket #9736 for
 703                         # details.
 704                         message(WARNING "Compiling LyX with stdlib-debug and system boost libraries may lead to crashes. Consider using '-DLYX_STDLIB_DEBUG=OFF' or using '-DLYX_EXTERNAL_BOOST=OFF'")
 705                 endif()
 706         else()
 707                 message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 708         endif()
 709 else()
 710         if(LYX_USE_STD_REGEX)
 711                 set(Lyx_Boost_Libraries boost_signals)
 712         else()
 713                 set(Lyx_Boost_Libraries boost_signals boost_regex)
 714         endif()
 715         add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 716         add_definitions(-DBOOST_SIGNALS_NO_DEPRECATION_WARNING=1)
 717         include_directories(${TOP_SRC_DIR}/boost)
 718         add_subdirectory(boost "${TOP_BINARY_DIR}/boost")
 719 endif()
 720
 721
 722
 723
 724 if(WIN32)
 725         if(LYX_CONSOLE)
 726                 set(LYX_QTMAIN_LIBRARY)
 727         else()
 728                 set(WIN32_CONSOLE WIN32)
 729         endif()
 730         if(MSVC)
 731                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 732                 # disable checked iterators for msvc release builds to get maximum speed
 733                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 734         else()
 735                 add_definitions(-DWINVER=0x0500)
 736         endif()
 737 endif()
 738
 739 # Compute qt4-version from ${QTVERSION}
 740
 741 message(STATUS "")
 742 foreach(_v PACKAGE PACKAGE_VERSION
 743         PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 744         LYX_ABS_TOP_SRCDIR
 745         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 746         if(NOT DEFINED ${_v})
 747                 message(FATAL_ERROR "${_v} not defined")
 748         endif()
 749         string(SUBSTRING "${_v}                            " 0 28 _v1)
 750         message(STATUS "----- ${_v1}: ${${_v}}")
 751 endforeach(_v)
 752 message(STATUS "")
 753
 754
 755 if(LYX_PCH)
 756         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 757         # Not sure if it works for all non-msvc compilers
 758         include(PCHSupport_26)
 759         configure_file(${TOP_CMAKE_PATH}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
 760         configure_file(${TOP_CMAKE_PATH}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 761         add_definitions(-DLYX_ENABLE_PCH)
 762
 763         if(MSVC)
 764                 macro(lyx_add_msvc_pch name_)
 765                         set_source_files_properties(${${name_}_sources} PROPERTIES
 766                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 767                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
 768                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 769                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
 770                                 ${TOP_BINARY_DIR}/pcheaders.h)
 771                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 772                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 773                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 774                 endmacro(lyx_add_msvc_pch)
 775                 macro(lyx_add_gcc_pch name_)
 776                 endmacro()
 777         else()
 778                 macro(lyx_add_msvc_pch name_)
 779                 endmacro()
 780                 macro(lyx_add_gcc_pch name_)
 781                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT)
 782                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
 783                 endmacro()
 784         endif()
 785 else()
 786         macro(lyx_add_msvc_pch)
 787         endmacro(lyx_add_msvc_pch)
 788         macro(lyx_add_gcc_pch name_)
 789         endmacro()
 790 endif()
 791
 792
 793 if(MSVC)
 794
 795         if(LYX_VLD)
 796                 set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/development/Win32/vld)
 797                 add_subdirectory(${vld_path}/cmake)
 798                 include(${vld_path}/cmake/vld.cmake) # forced include
 799                 set(vld_dll vld)
 800         endif()
 801
 802         if(LYX_WALL)
 803                 # Use the highest warning level
 804                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 805
 806                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 807                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 808                 else()
 809                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 810                 endif()
 811
 812                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 813                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 814                 else()
 815                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 816                 endif()
 817
 818                 # add here warnings which should produce an error /weXXXX
 819                 set(MSVC_W_ERROR   "/we4101 /we4189")
 820                 # add here warnings which should be disabled /wdXXXX
 821                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 822
 823                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 824                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 825                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 826
 827         else()
 828                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 829
 830                 # add here warnings which should produce an error /weXXXX
 831                 set(MSVC_W_ERROR   "/we4101 /we4189")
 832                 # add here warnings which should be disabled /wdXXXX
 833                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 834
 835                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 836                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 837                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 838
 839         endif()
 840
 841         if (NOT Qt5Core_FOUND)
 842                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 843                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 844                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 845         endif()
 846
 847         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 848         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 849         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 850         message(STATUS "")
 851 endif()
 852
 853
 854 if(LYX_DEBUG_GLIBC)
 855         set(_GLIBCXX_DEBUG ON)
 856 endif()
 857
 858 if(LYX_DEBUG_GLIBC_PEDANTIC)
 859         set(_GLIBCXX_DEBUG_PEDANTIC ON)
 860 endif()
 861
 862 # Xcode compiler
 863 if (CMAKE_GENERATOR MATCHES Xcode)
 864         if (XCODE_VERSION VERSION_LESS "5.0")
 865                 # Automatically select the Xcode compiler if not set
 866                 if (NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 867                         # XCode >= 3.1 has gcc 4.2 (up to actual Xcode)
 868                         if (XCODE_VERSION VERSION_GREATER "3.1")
 869                                 SET(CMAKE_XCODE_ATTRIBUTE_GCC_VERSION "com.apple.compilers.llvmgcc42")
 870                         ENDIF(XCODE_VERSION VERSION_GREATER "3.1")
 871                 ENDIF(NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 872                 # Print the selected compiler version
 873         MESSAGE(STATUS "---- Using XCode compiler CMAKE_XCODE_ATTRIBUTE_GCC_VERSION=${CMAKE_XCODE_ATTRIBUTE_GCC_VERSION}")
 874         ENDIF(XCODE_VERSION VERSION_LESS "5.0")
 875 ENDIF(CMAKE_GENERATOR MATCHES Xcode)
 876
 877 if (WIN32 AND Qt5Core_FOUND)
 878         set(Z_PREFIX 1)
 879 endif()
 880
 881 # compiler tests, config.h generation
 882 if(MSVC AND NOT LYX_CONFIGURE_CHECKS)
 883         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.msvc ${TOP_BINARY_DIR}/configCompiler.h)
 884 else()
 885         include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
 886         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
 887 endif()
 888
 889 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
 890
 891 if(QTVERSION MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+).*")
 892         MATH(EXPR QT4_VERSION "(${CMAKE_MATCH_1}<<16)|(${CMAKE_MATCH_2}<<8)|${CMAKE_MATCH_3}")
 893 endif()
 894
 895 if (NOT HAVE_REGEX)
 896         set(LYX_USE_STD_REGEX 0)
 897 endif()
 898
 899
 900 set (cmd ${CMAKE_CTEST_COMMAND})
 901 if (MSVC)
 902         set (cmd ${cmd} -C ${CMAKE_CFG_INTDIR})
 903 else ()
 904         set (cmd ${cmd} -C ${CMAKE_BUILD_TYPE})
 905 endif ()
 906 add_custom_target (lyx_run_tests COMMAND ${cmd})
 907 set_target_properties(lyx_run_tests PROPERTIES FOLDER "tests")
 908
 909 if(LYX_ASAN)
 910     set(LYX_CXX_FLAGS "-fsanitize=address -fno-omit-frame-pointer -g")
 911     message(STATUS)
 912     message(STATUS "Address sanitizer enabled. Usage:")
 913     message(STATUS "    wget https://llvm.org/svn/llvm-project/compiler-rt/trunk/lib/asan/scripts/asan_symbolize.py")
 914     message(STATUS "    chmod  +x ./asan_symbolize.py")
 915     message(STATUS "    ./bin/lyx2.2 2>&1 | ./asan_symbolize.py  | c++filt ")
 916     message(STATUS)
 917 endif()
 918
 919 if(LYX_INSTALL)
 920         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 921                 message(STATUS "Python required to create doc!")
 922         else()
 923                 if(UNIX)
 924                         add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
 925                 endif()
 926                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
 927         endif()
 928         include(../Install)
 929 endif()
 930
 931 add_subdirectory(src "${TOP_BINARY_DIR}/src")
 932 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
 933 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
 934 add_subdirectory(lib/examples "${TOP_BINARY_DIR}/lib/examples")
 935 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
 936 add_subdirectory(development/autotests "${TOP_BINARY_DIR}/autotests")
 937 if(LYX_ENABLE_URLTESTS)
 938         add_subdirectory(development/checkurls "${TOP_BINARY_DIR}/checkurls")
 939 endif()
 940
 941 message(STATUS)
 942 message(STATUS "Build params, switch LYX_* options by -DLYX_*=ON or OFF, LYX_* combos by -DLYX_*=value:")
 943 message(STATUS)
 944
 945 LYX_OPTION_LIST_ALL(used)
 946
 947
 948 if(LYX_NLS)
 949         message(STATUS)
 950         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
 951         message(STATUS)
 952         message(STATUS "  * iconv")
 953         message(STATUS "     - include: ${ICONV_INCLUDE_DIR}")
 954         message(STATUS "     - library: ${ICONV_LIBRARY}")
 955         message(STATUS "  * zlib")
 956         message(STATUS "     - include: ${ZLIB_INCLUDE_DIR}")
 957         message(STATUS "     - library: ${ZLIB_LIBRARY}")
 958         message(STATUS)
 959 endif()
 960
 961 # Apple has builtin native spell checker,
 962 # no need to warn for missing Aspell, Hunspell or Enchant
 963 if(NOT Spelling_FOUND AND NOT APPLE)
 964   if(LYX_REQUIRE_SPELLCHECK)
 965     set(_mode "FATAL_ERROR")
 966   else()
 967     set(_mode "STATUS")
 968   endif()
 969   message(${_mode} "No spellcheck libraries found. LyX will be unable use spellchecking")
 970 endif()
 971
 972 include("${TOP_CMAKE_PATH}/LyxPackaging.cmake")
 973
 974 if(ENABLE_DIST)
 975   # Use git to create the source package
 976   # git archive --format=tgz --output=/home/kornel/x.tar.gz master
 977   if(UNIX)
 978     set(DIST_FORMAT tgz)
 979   else()
 980     set(DIST_FORMAT zip)
 981   endif()
 982   set(DIST_NAME ${CMAKE_PROJECT_NAME}-${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}-${CMAKE_SYSTEM_NAME}.${DIST_FORMAT})
 983
 984   add_custom_command(
 985     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME}
 986     COMMAND  ${LYX_GITVERSION} archive --format=${DIST_FORMAT} --output=${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME} master
 987     WORKING_DIRECTORY ${TOP_SRC_DIR})
 988   add_custom_target(git-archive DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME})
 989 endif()
 990
 991 # Last directory to be included so that the fixup code (OS X)
 992 # can be run last
 993 add_subdirectory(development/cmake/post_install)
 994
 995 message(STATUS)