CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 2.6.4)
   8
   9 set(LYX_PROJECT LyX)
  10
  11 enable_testing()
  12
  13 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README REALPATH) # Resolve symlinks
  14 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  15 message(STATUS "TOP_SRC_DIR = ${TOP_SRC_DIR}")
  16
  17 set(LYX_CMAKE_DIR "development/cmake")
  18 set(TOP_CMAKE_PATH "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}")
  19 set(TOP_MODULE_PATH "${TOP_CMAKE_PATH}/modules")
  20 set(TOP_SCRIPT_PATH "${TOP_CMAKE_PATH}/scripts")
  21
  22 set(CMAKE_MODULE_PATH "${TOP_MODULE_PATH}")
  23
  24 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  25
  26 message(STATUS)
  27 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  28         message(STATUS "Building in-source")
  29         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  30 else()
  31         message(STATUS "Building out-of-source")
  32         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  33 endif()
  34
  35 # This directory should be used if some test uses lyx-executable
  36 set(LYX_TESTS_USERDIR "${TOP_BINARY_DIR}/Testing/.lyx")
  37 file(MAKE_DIRECTORY "${LYX_TESTS_USERDIR}")
  38
  39 if(COMMAND cmake_policy)
  40         cmake_policy(SET CMP0003 OLD)
  41         cmake_policy(SET CMP0005 OLD)
  42         # Installing MACOSX_BUNDLE targets requires a BUNDLE DESTINATION
  43         cmake_policy(SET CMP0006 NEW)
  44         if(POLICY CMP0020)
  45                 cmake_policy(SET CMP0020 OLD)
  46         endif()
  47         if(POLICY CMP0028)
  48                 cmake_policy(SET CMP0028 OLD)
  49         endif()
  50         if(POLICY CMP0043)
  51                 # COMPILE_DEFINITIONS are not used yet. Enable new behavior.
  52                 cmake_policy(SET CMP0043 NEW)
  53         endif()
  54 endif()
  55
  56 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  57
  58 # Supress regeneration
  59 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  60
  61 if(LYX_XMINGW)
  62     set(CMAKE_SYSTEM_NAME Windows)
  63     set(TOOLNAME ${LYX_XMINGW})
  64     set(TOOLCHAIN "${TOOLNAME}-")
  65     set(CMAKE_C_COMPILER   "${TOOLCHAIN}gcc"     CACHE PATH "Mingw C compiler" FORCE)
  66     set(CMAKE_CXX_COMPILER "${TOOLCHAIN}g++"     CACHE PATH "Mingw C++ compiler" FORCE)
  67     set(CMAKE_RC_COMPILER  "${TOOLCHAIN}windres" CACHE PATH "Mingw rc compiler" FORCE)
  68
  69     set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM BOTH)
  70     set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY)
  71     set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY)
  72 endif()
  73
  74 if(NOT help AND NOT HELP)
  75   # 'project' triggers the searching for a compiler
  76   project(${LYX_PROJECT})
  77   if (CMAKE_COMPILER_IS_GNUCXX)
  78     if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS "4.0")
  79       message(STATUS "Gnu CXX compiler version = ${CMAKE_CXX_COMPILER_VERSION}")
  80       message(STATUS "is too old, should be >= 4.0")
  81       message(FATAL_ERROR "Exiting")
  82     endif()
  83   endif()
  84 endif()
  85
  86 if(UNIX)
  87         set(ARCH_TRIPLET )
  88         FIND_PROGRAM(DPKG_ARCHITECTURE_EXECUTABLE dpkg-architecture)
  89         if(DPKG_ARCHITECTURE_EXECUTABLE)
  90                 EXECUTE_PROCESS(COMMAND ${DPKG_ARCHITECTURE_EXECUTABLE} -qDEB_HOST_MULTIARCH
  91                                 OUTPUT_VARIABLE ARCH_TRIPLET
  92                                 ERROR_VARIABLE ERROR_ARCH_TRIPLET
  93                                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  94         endif()
  95 endif()
  96 if(ARCH_TRIPLET)
  97         set(SYSTEM_LIB_DIRS /usr/lib /usr/lib/${ARCH_TRIPLET} /usr/local/lib)
  98 else()
  99         set(SYSTEM_LIB_DIRS /usr/lib /usr/local/lib)
 100 endif()
 101
 102 include(LyXMacros)
 103 include(LyXDestinations)
 104
 105 # Usage LYX_OPTION
 106 # 1. parameter: option name without prefix 'LYX_'
 107 # 2. parameter: description
 108 # 3. parameter: default value, ON or OFF
 109 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
 110
 111 # Usage LYX_COMBO
 112 # 1. parameter: name without prefix 'LYX_'
 113 # 2. parameter: description
 114 # 3. parameter: default value
 115 # 4-n parameter: possible other string values
 116
 117 LYX_OPTION_INIT()
 118
 119 # Options for all compilers/systems
 120 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
 121 LYX_OPTION(LOCALVERSIONING  "Add version info to created package name (only used if LYX_CPACK option set)" OFF ALL)
 122 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
 123 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
 124 LYX_OPTION(REQUIRE_SPELLCHECK "Abort if no spellchecker available" OFF ALL)
 125 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
 126 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
 127 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
 128 LYX_OPTION(DEVEL_VERSION    "Build developer version" OFF ALL)
 129 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" OFF ALL)
 130 LYX_OPTION(DEBUG            "Enforce debug build"  OFF ALL)
 131 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
 132 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
 133 LYX_STRING(SUFFIX_VALUE     "Use this string as suffix" "")
 134 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
 135 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
 136 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
 137 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
 138 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
 139 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
 140 LYX_OPTION(ENABLE_URLTESTS  "Enable for URL tests" OFF ALL)
 141 LYX_OPTION(ENABLE_EXPORT_TESTS "Enable for export tests" OFF ALL)
 142 LYX_OPTION(ASAN             "Use address sanitizer" OFF ALL)
 143 LYX_COMBO(USE_QT            "Use Qt version as frontend" QT4 QT5)
 144 LYX_OPTION(3RDPARTY_BUILD   "Build 3rdparty libs" OFF ALL)
 145 LYX_COMBO(ENABLE_CXX11          "Build with options for c++11-mode" AUTO ON OFF)
 146
 147 # GCC specific
 148 LYX_OPTION(PROFILE              "Build profile version" OFF GCC)
 149 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" OFF GCC)
 150 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
 151 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
 152 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++ pedantic debug mode" OFF GCC)
 153 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" OFF GCC)
 154 LYX_OPTION(PROFILE              "Build with options for gprof" OFF GCC)
 155
 156 # MSVC specific
 157 LYX_OPTION(CONSOLE               "Show console on Windows, enforce with =FORCE" ON MSVC)
 158 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
 159 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
 160 LYX_OPTION(CONFIGURE_CHECKS      "Also run configure checks for MSVC" OFF MSVC)
 161 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
 162
 163 # APPLE specific
 164 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
 165 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
 166
 167
 168 if(help OR HELP)
 169         message(STATUS)
 170         message(STATUS "Available options: (dis/enable with -DLYX_*=OFF/ON)")
 171         message(STATUS)
 172         LYX_OPTION_LIST_ALL(help)
 173         message(STATUS)
 174         RETURN()
 175 endif()
 176
 177 # Check option dependencies
 178
 179 if(LYX_DMG)
 180         set(LYX_BUNDLE ON)
 181         set(LYX_CPACK ON)
 182 endif()
 183
 184 if(LYX_CPACK)
 185         set(LYX_INSTALL ON)
 186 endif()
 187
 188 if(LYX_INSTALL)
 189         set(LYX_NLS ON)
 190         if(WIN32 AND NOT MINGW)
 191                 set(LYX_HUNSPELL ON)
 192         endif()
 193         if(LYX_CONSOLE MATCHES "FORCE")
 194                 set(LYX_CONSOLE ON)
 195         else()
 196                 set(LYX_CONSOLE OFF)
 197         endif()
 198         set(LYX_PACKAGE_SUFFIX ON)
 199         if(NOT LYX_DEBUG)
 200                 set(LYX_RELEASE ON)
 201         endif()
 202         set(LYX_PROFILE OFF)
 203 endif()
 204
 205
 206 if(LYX_MERGE_FILES)
 207         set(LYX_PCH OFF)
 208 else()
 209         set(LYX_MERGE_REBUILD OFF)
 210 endif()
 211
 212
 213 if(LYX_DEPENDENCIES_DOWNLOAD)
 214         message(STATUS)
 215     if(MSVC12)
 216         set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2013-deps)
 217         set(deps_files lyx-windows-deps-msvc2013.zip)
 218         set(deps_server http://ftp.lyx.de/LyX-Windows-Deps)
 219         set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2013)
 220     else()
 221         set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 222             set(deps_files lyx20-deps-msvc2010-x86.zip)
 223             set(deps_server http://downloads.sourceforge.net/project/lyx/Win_installers/Dependencies)
 224         set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/deps20)
 225     endif()
 226     message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 227         foreach(it ${deps_files})
 228                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 229                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 230                 if(NOT already_downloaded)
 231                         message(STATUS "Downloading ${it} ...")
 232                         file(DOWNLOAD ${deps_server}/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS STATUS status LOG log)
 233                         list(GET status 0 status_code)
 234                         list(GET status 1 status_string)
 235                         if(NOT status_code EQUAL 0)
 236                                 file(REMOVE ${LYX_DEPENDENCIES_DIR}/${it})
 237                                 message(FATAL_ERROR "error: downloading '${it}' failed. status_code: ${status_code}, status_string: ${status_string}. \nLog: ${log} ")
 238                         endif()
 239                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 240                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 241                 endif()
 242         endforeach()
 243 endif()
 244
 245
 246
 247 message(STATUS)
 248
 249 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 250 if(WIN32)
 251         set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 252 else()
 253         set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 254 endif()
 255
 256
 257 if(LYX_ENABLE_CXX11 MATCHES "AUTO")
 258   # Set to some meaningful default
 259   find_package(CXX11Compiler)
 260   if(NOT CXX11COMPILER_FOUND)
 261     set(LYX_ENABLE_CXX11 OFF CACHE TYPE STRING FORCE)
 262   else()
 263     if(CMAKE_CXX_COMPILER_ID MATCHES "GNU")
 264       execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION OUTPUT_STRIP_TRAILING_WHITESPACE)
 265         set(LYX_ENABLE_CXX11 ON CACHE TYPE STRING FORCE)
 266     else()
 267       # Not a gnu compiler
 268       if(CMAKE_CXX_COMPILER_ID MATCHES "^[cC]lang$")
 269         set(LYX_ENABLE_CXX11 ON CACHE TYPE STRING FORCE)
 270       else()
 271         set(LYX_ENABLE_CXX11 OFF CACHE TYPE STRING FORCE)
 272       endif()
 273     endif()
 274   endif()
 275 endif()
 276 set(LYX_GCC11_MODE)
 277 if(UNIX OR MINGW)
 278         execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION OUTPUT_STRIP_TRAILING_WHITESPACE)
 279         message(STATUS "Using GCC version ${GCC_VERSION}")
 280         if(GCC_VERSION VERSION_LESS 4.9)
 281                 if(GCC_VERSION VERSION_LESS 4.3)
 282                         message(FATAL_ERROR "gcc >= 4.3 is required.")
 283                 endif()
 284                 # <regex> in gcc is unusable in versions less than 4.9.0
 285                 # see https://gcc.gnu.org/bugzilla/show_bug.cgi?id=53631
 286                 set(LYX_USE_STD_REGEX 0)
 287         else()
 288                 if (LYX_ENABLE_CXX11)
 289                         set(LYX_USE_STD_REGEX 1)
 290                 endif()
 291         endif()
 292         if (LYX_ENABLE_CXX11)
 293                 find_package(CXX11Compiler)
 294                 if(NOT CXX11COMPILER_FOUND)
 295                         message(FATAL_ERROR "A C++11 compatible compiler is required.")
 296                 endif()
 297                 set(LYX_GCC11_MODE "${CXX11_FLAG}")
 298         endif()
 299 else()
 300         set(LYX_USE_STD_REGEX 0)
 301 #       if(MSVC10)
 302 #               set(LYX_USE_STD_REGEX 1) #TODO should we use it in ECMAScript mode?
 303 #       endif()
 304 endif()
 305
 306
 307 set(VERSION_INFO "CMake Build")
 308
 309 # Try to get some informations from configure.ac
 310
 311 include(LyXPaths)
 312 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 313
 314 if(WIN32)
 315         set(CMAKE_PREFIX_PATH Specify-path-to-Qt CACHE PATH "Used Qt version")
 316         if(MSVC)
 317                 set(LYX_3RDPARTY_BUILD ON CACHE BOOL "Build 3rdparty libraries" FORCE)
 318         endif()
 319         set(USE_WINDOWS_PACKAGING ON)
 320 elseif(APPLE)
 321         set(USE_MACOSX_PACKAGING ON)
 322 else()
 323         set(USE_POSIX_PACKAGING ON)
 324 endif()
 325
 326 macro(setstripped _varname)
 327         if(${ARGC} GREATER 1)
 328                 string(STRIP "${ARGV1}" _v)
 329                 if(USE_POSIX_PACKAGING)
 330                         string(TOLOWER ${_v} ${_varname})
 331                 else()
 332                         set(${_varname} ${_v})
 333                 endif()
 334         else()
 335                 set(${_varname})
 336         endif()
 337 endmacro(setstripped)
 338
 339 foreach(_c_l ${_config_lines} )
 340         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 341                 setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 342                 setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 343                 setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 344                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\)\(\\.\([0-9]+\)\)?.*$")
 345                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 346                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 347                         set(LYX_PATCH_VERSION ${CMAKE_MATCH_4})
 348                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 349                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 350                         if ("${LYX_SUFFIX_VALUE}" MATCHES "")
 351                           set(LYX_INSTALL_SUFFIX "${LYX_MAJOR_VERSION}.${LYX_MINOR_VERSION}")
 352                         else()
 353                           set(LYX_INSTALL_SUFFIX "${LYX_SUFFIX_VALUE}")
 354                         endif()
 355                 endif()
 356         endif()
 357         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 358                 set(LYX_DATE "${CMAKE_MATCH_1}")
 359         endif()
 360 endforeach(_c_l)
 361
 362 FIND_PROGRAM(LYX_GITVERSION git)
 363 #message(STATUS "gitversion = ${LYX_GITVERSION}")
 364 set(LYX_REVISION_VERSION ${LYX_PATCH_VERSION})
 365 if(LYX_GITVERSION)
 366   if (LYX_LOCALVERSIONING)
 367     # Find the revision number and for later use
 368     EXECUTE_PROCESS(COMMAND ${LYX_GITVERSION} describe --match 2.0.0 HEAD
 369       WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE LYX_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 370     if (LYX_PACKAGE_RELEASE MATCHES "^2\\.0\\.0\\-\([0-9]+\)\\-.*$")
 371       # We will add offset of 40000 to get appropriate value to
 372       # previous svn.
 373       # We use this value than also to set the package-patch-value
 374       MATH(EXPR tmp_REVISION_VERSION "(${CMAKE_MATCH_1}+40000)")
 375       set(LYX_REVISION_VERSION "${LYX_PATCH_VERSION}-${tmp_REVISION_VERSION}git")
 376       set(ENABLE_DIST ON)
 377     endif()
 378   endif()
 379 endif()
 380
 381 # Set the programs (lyx, tex2lyx, etc.) suffix
 382 # When building an OS X bundle, we will append
 383 # the suffix only to the bundle, not to the programs
 384 set(PROGRAM_SUFFIX "")
 385 if(LYX_PROGRAM_SUFFIX AND NOT (APPLE AND LYX_BUNDLE))
 386         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 387 endif()
 388 set(_lyx "${PACKAGE_BASE}${PROGRAM_SUFFIX}")
 389 set(_tex2lyx tex2lyx${PROGRAM_SUFFIX})
 390
 391 add_custom_target(lyx_version ALL
 392   COMMAND ${CMAKE_COMMAND} -DTOP_SRC_DIR=${TOP_SRC_DIR} -DTOP_CMAKE_PATH=${TOP_CMAKE_PATH} -DTOP_BINARY_DIR=${TOP_BINARY_DIR} -DLYX_DATE=${LYX_DATE} -P ${TOP_SCRIPT_PATH}/LyXGetVersion.cmake
 393   )
 394 set_target_properties(lyx_version PROPERTIES FOLDER "applications")
 395
 396 # Default paths for installed utilities (tex2lyx, lyxclient, etc.)
 397 set(LYX_UTILITIES_INSTALL_PATH bin)
 398
 399 if(LYX_BUNDLE)
 400         set(LYX_CPACK ON)
 401
 402         message(STATUS)
 403         message(STATUS "Bundle creation is enabled (experimental):")
 404         message(STATUS "    make")
 405         message(STATUS "    make install/strip")
 406         message(STATUS "    make package")
 407         if(APPLE)
 408                 set(MACOSX_BUNDLE TRUE)
 409                 # This sets the bundle + executable names
 410                 set(_lyx "${PACKAGE_BASE}${LYX_INSTALL_SUFFIX}")
 411                 # This sets the Info.plist executable name
 412                 set(osx_bundle_program_name ${_lyx})
 413                 # Bundle name
 414                 set(LYX_BUNDLE_NAME ${_lyx})
 415
 416                 # This will contain the list of files that need to be included
 417                 # in the bundle and their location within the bundle
 418                 set(OSX_BUNDLE_FILES "${TOP_SRC_DIR}/development/MacOSX/LyX.sdef;${TOP_SRC_DIR}/development/MacOSX/LyXapp.icns;${CMAKE_BINARY_DIR}/lyxrc.dist")
 419                 set(OSX_BUNDLE_DIRS "Resources;Resources;Resources")
 420
 421                 # Process Info.plist and lyxrc.dist
 422                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/Info.plist.in" "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 423                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/lyxrc.dist.in" "${CMAKE_CURRENT_BINARY_DIR}/lyxrc.dist")
 424
 425                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 426                 set(LYX_DATA_SUBDIR ${LYX_BUNDLE_NAME}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 427
 428                 # Variables used by CPack
 429                 set(CPACK_BUNDLE_NAME ${LYX_BUNDLE_NAME})
 430                 set(CPACK_BUNDLE_PLIST "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 431                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${LYX_BUNDLE_NAME}.app)
 432
 433                 # Set the install paths
 434                 set(LYX_UTILITIES_INSTALL_PATH ${LYX_BUNDLE_NAME}.app/Contents/MacOS)
 435                 if(NOT LYX_INSTALL_PREFIX)
 436                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 437                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 438                 endif()
 439                 # Change the owner so that the install can work
 440                 install(CODE "set(BU_CHMOD_BUNDLE_ITEMS 1)" COMPONENT Runtime)
 441         elseif(UNIX)
 442                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 443                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 444                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 445         elseif(WIN32)
 446                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 447         endif()
 448 endif()
 449
 450 if(LYX_INSTALL_PREFIX)
 451         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 452         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 453 endif()
 454 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 455
 456 string(REGEX REPLACE "/lyx${LYX_INSTALL_SUFFIX}$" "/share" SYSTEM_DATADIR ${CMAKE_INSTALL_PREFIX})
 457
 458 if(LYX_PACKAGE_SUFFIX)
 459         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 460 else()
 461         set(PACKAGE ${PACKAGE_BASE})
 462 endif()
 463
 464 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 465         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 466         if (UNIX)
 467                 # use the default "/usr/local"
 468                 # but respect the user-choice on the command-line
 469                 set(CMAKE_INSTALL_PREFIX "/usr/local" CACHE PATH "LyX default install prefix" FORCE)
 470         endif()
 471 endif()
 472 if(WIN32)
 473         set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 474 endif()
 475 if(IS_ABSOLUTE)
 476         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 477 else()
 478         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 479 endif()
 480
 481
 482
 483 if(NOT LYX_DATA_SUBDIR)
 484         if (WIN32)
 485                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 486         else()
 487                 set(LYX_DATA_SUBDIR "share/${_lyx}/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 488         endif()
 489 endif()
 490
 491 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 492 get_locale_destination(LYX_LOCALEDIR)
 493 set(LYX_ABS_INSTALLED_LOCALEDIR "${CMAKE_INSTALL_PREFIX}/${LYX_LOCALEDIR}")
 494 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 495
 496 if(LYX_BUNDLE AND APPLE)
 497         set(LYX_MAN_DIR "${LYX_DATA_SUBDIR}" CACHE STRING "Install location for man pages.")
 498 else()
 499         if(WIN32)
 500                 set(LYX_MAN_DIR "${CMAKE_BINARY_DIR}/usr/local/man/man1" CACHE STRING "Install location for man pages.")
 501         else()
 502                 set(LYX_MAN_DIR "${CMAKE_INSTALL_PREFIX}/man/man1" CACHE STRING "Install location for man pages.")
 503         endif()
 504 endif()
 505 mark_as_advanced(LYX_MAN_DIR)
 506
 507 if(LYX_INSTALL AND WIN32)
 508         message(STATUS "Configuring NSIS files")
 509         configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 510         configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 511         configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 512         message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 513 endif()
 514
 515 if(NOT GROUP_CODE)
 516         #set(GROUP_CODE "The Golden Code")
 517         set(GROUP_CODE flat)
 518 endif()
 519
 520 # lyx's source files
 521 set(LYX_CPP_FILES [a-zA-Z]*.cpp)
 522 set(LYX_HPP_FILES [a-zA-Z]*.h)
 523 set(LYX_MOC_FILES moc_*.cpp)
 524
 525 include(ProjectSourceGroup)
 526
 527
 528 if(LYX_PROFILE AND NOT MSVC)
 529         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 530         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg")
 531         set(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS}  -pg")
 532 else()
 533         set(LYX_PROFILE OFF)
 534 endif()
 535
 536
 537 if(LYX_NO_OPTIMIZE)
 538         set(CMAKE_BUILD_TYPE None)
 539         set(LYX_DEBUG OFF)
 540         set(LYX_RELEASE OFF)
 541         set(LYX_PROFILE OFF)
 542 elseif(LYX_RELEASE)
 543         set(CMAKE_BUILD_TYPE Release)
 544         set(LYX_DEBUG OFF)
 545         set(LYX_PROFILE OFF)
 546 elseif(LYX_PROFILE)
 547         set(CMAKE_BUILD_TYPE Profile)
 548         set(LYX_DEBUG OFF)
 549 else()
 550         set(CMAKE_BUILD_TYPE Debug)
 551         set(LYX_DEBUG ON)
 552 endif()
 553
 554
 555 # When shared libs are supported enable this option
 556 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 557 if(LYX_SHARED_LIBRARIES)
 558         set(library_type SHARED)
 559 else()
 560         set(library_type STATIC)
 561 endif()
 562
 563 if(NOT MSVC)
 564         if(NOT LYX_QUIET)
 565                 set(CMAKE_VERBOSE_MAKEFILE ON)
 566         endif()
 567     set(LYX_CXX_FLAGS "-Wall -Wunused-parameter ${LYX_GCC11_MODE}")
 568         if(LYX_STDLIB_DEBUG)
 569                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 570         endif()
 571         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 572         set(CMAKE_CXX_FLAGS_DEBUG "${LYX_CXX_FLAGS} -fno-strict-aliasing -O0 -g3 -D_DEBUG" CACHE TYPE STRING FORCE)
 573         if(MINGW)
 574                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 575         else()
 576                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 577         endif()
 578 endif()
 579
 580 set(LYX_CXX_FLAGS_EXTRA "" CACHE STRING "Desired semicolon separated list of extra cxx compile flags, like '-Werror'")
 581 mark_as_advanced(LYX_CXX_FLAGS_EXTRA)
 582 if(LYX_CXX_FLAGS_EXTRA)
 583         foreach(_flag ${LYX_CXX_FLAGS_EXTRA})
 584                 add_definitions(${_flag})
 585         endforeach()
 586 endif()
 587
 588 if(LYX_XMINGW)
 589         list(APPEND CMAKE_FIND_ROOT_PATH ${GNUWIN32_DIR})
 590 endif()
 591
 592 set(QPA_XCB)
 593 if(LYX_USE_QT MATCHES "QT5")
 594         # set QPA_XCB if QT uses X11
 595         find_package(Qt5Core REQUIRED)
 596         if (Qt5Core_FOUND)
 597                 find_package(Qt5Widgets REQUIRED)
 598                 if(APPLE)
 599                         find_package(Qt5MacExtras REQUIRED)
 600                 endif()
 601                 find_package(Qt5X11Extras QUIET)
 602                 if(Qt5X11Extras_FOUND)
 603                   set(QPA_XCB 1)
 604                 endif()
 605                 find_package(Qt5WinExtras QUIET)
 606                 set(QTVERSION ${Qt5Core_VERSION})
 607                 macro (qt_use_modules)
 608                         qt5_use_modules(${ARGN})
 609                 endmacro()
 610                 macro (qt_add_resources)
 611                         qt5_add_resources(${ARGN})
 612                 endmacro()
 613                 macro (qt_wrap_uifiles)
 614                         qt5_wrap_ui(${ARGN})
 615                 endmacro()
 616                 message(STATUS "Found Qt-Version ${QTVERSION}")
 617                 if(WIN32)
 618                         set(LYX_QTMAIN_LIBRARY ${Qt5Core_QTMAIN_LIBRARIES})
 619                 endif()
 620         endif()
 621 elseif(LYX_USE_QT MATCHES "QT4")
 622         if(LYX_XMINGW)
 623                 set(QT_MINGW_DIR ${LYX_QT4} CACHE PATH "Qt for Mingw" FORCE)
 624                 list(APPEND CMAKE_FIND_ROOT_PATH ${QT_MINGW_DIR} ${GNUWIN32_DIR})
 625         endif()
 626         find_package(Qt4 "4.5.0" REQUIRED)
 627         macro (qt_use_modules)
 628         endmacro()
 629         macro (qt_add_resources)
 630                 qt4_add_resources(${ARGN})
 631         endmacro()
 632         macro (qt_wrap_uifiles)
 633                 qt4_wrap_ui(${ARGN})
 634         endmacro()
 635         if(WIN32)
 636                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARIES})
 637         endif()
 638 else()
 639   message(FATAL_ERROR "Unhandled value for LYX_USE_QT (${LYX_USE_QT})")
 640 endif()
 641
 642 find_package(Magic)
 643 if(Magic_FOUND)
 644         set(HAVE_MAGIC_H 1)
 645 endif()
 646
 647 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 648
 649 set(Spelling_FOUND OFF)
 650 set(Include_used_spellchecker)   # String will be inserted into config.h
 651
 652 if(LYX_3RDPARTY_BUILD)
 653     add_subdirectory(3rdparty/hunspell)
 654     add_definitions(-DHUNSPELL_STATIC)
 655     set(HUNSPELL_FOUND ON)
 656     message(STATUS "  * Hunspell:")
 657     message(STATUS "     - include: ${HUNSPELL_INCLUDE_DIR}")
 658     message(STATUS "     - library: ${HUNSPELL_LIBRARY}")
 659 endif()
 660
 661 foreach(_spell "ASPELL" "Enchant" "Hunspell")
 662   string(TOUPPER ${_spell} _upspell)
 663   if (NOT ${_upspell}_FOUND)
 664     find_package(${_spell})
 665   endif()
 666   if (${_upspell}_FOUND)
 667     include_directories(${${_upspell}_INCLUDE_DIR})
 668     set(Spelling_FOUND ON)
 669     message(STATUS "Building with USE_${_upspell}")
 670     set(Include_used_spellchecker "${Include_used_spellchecker}#define USE_${_upspell} 1\n")
 671   else()
 672     if(LYX_${_upspell})
 673       message(FATAL_ERROR "Required ${_spell} devel package not found")
 674     else()
 675       message(STATUS "${_upspell} not found, building without ${_spell} support")
 676     endif()
 677   endif()
 678 endforeach()
 679
 680 if(GNUWIN32_DIR)
 681         list(APPEND CMAKE_PROGRAM_PATH "${GNUWIN32_DIR}/Python" )
 682 endif()
 683
 684 find_package(PythonInterp 2.7 QUIET)
 685 if(PYTHONINTERP_FOUND)
 686         if(PYTHON_VERSION_STRING VERSION_GREATER 2.8)
 687         unset(PYTHONINTERP_FOUND)
 688         endif()
 689 endif()
 690
 691 if(NOT PYTHONINTERP_FOUND)
 692   unset(PYTHON_EXECUTABLE CACHE)
 693   unset(PYTHON_VERSION_MAJOR)
 694   unset(PYTHON_VERSION_MINOR)
 695   unset(PYTHON_VERSION_STRING)
 696   find_package(PythonInterp 3.3 REQUIRED)
 697 endif()
 698
 699 set(LYX_PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 700
 701 if(LYX_NLS)
 702         find_package(LyXGettext)
 703         if(LYX_PYTHON_EXECUTABLE AND GETTEXT_FOUND)
 704                 add_subdirectory(po "${TOP_BINARY_DIR}/po")
 705         else()
 706                 # Install only supplied .gmo-files
 707                 file(GLOB _gmofiles RELATIVE "${TOP_SRC_DIR}/po" "${TOP_SRC_DIR}/po/*.gmo")
 708                 message(STATUS "Installing provided .gmo-files only")
 709                 foreach( _gmo ${_gmofiles})
 710                         string(REGEX REPLACE "\\.gmo$" "" _lang ${_gmo})
 711                         install(FILES "${TOP_SRC_DIR}/po/${_gmo}" DESTINATION ${LYX_LOCALEDIR}/${_lang}/LC_MESSAGES RENAME ${PACKAGE}.mo)
 712                 endforeach()
 713         endif()
 714 endif()
 715
 716 if(UNIX)
 717     find_package(ICONV REQUIRED)
 718     find_package(ZLIB REQUIRED)
 719 else()
 720     if(LYX_3RDPARTY_BUILD)
 721         add_subdirectory(3rdparty/libiconv)
 722         set(HAVE_ICONV_CONST 1)
 723         add_subdirectory(3rdparty/zlib)
 724     endif()
 725 endif()
 726
 727 if(LYX_EXTERNAL_BOOST)
 728         message(STATUS "Searching for boost")
 729         if(LYX_USE_STD_REGEX)
 730                 find_package(Boost COMPONENTS signals)
 731         else()
 732                 find_package(Boost COMPONENTS signals regex)
 733         endif()
 734         if(Boost_FOUND)
 735                 message(STATUS "Boost found")
 736                 message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 737                 set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 738                 if (LYX_STDLIB_DEBUG)
 739                         # Comment from  Jean-Marc Lasgouttes:
 740                         # In general, system boost libraries are incompatible with
 741                         # the use of stdlib-debug in libstdc++. See ticket #9736 for
 742                         # details.
 743                         message(WARNING "Compiling LyX with stdlib-debug and system boost libraries may lead to crashes. Consider using '-DLYX_STDLIB_DEBUG=OFF' or using '-DLYX_EXTERNAL_BOOST=OFF'")
 744                 endif()
 745         else()
 746                 message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 747         endif()
 748 else()
 749         if(LYX_USE_STD_REGEX)
 750                 set(Lyx_Boost_Libraries boost_signals)
 751         else()
 752                 set(Lyx_Boost_Libraries boost_signals boost_regex)
 753         endif()
 754         add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 755         add_definitions(-DBOOST_SIGNALS_NO_DEPRECATION_WARNING=1)
 756         include_directories(${TOP_SRC_DIR}/3rdparty/boost)
 757         add_subdirectory(3rdparty/boost "${TOP_BINARY_DIR}/3rdparty/boost")
 758 endif()
 759
 760
 761
 762
 763 if(WIN32)
 764         if(LYX_CONSOLE)
 765                 set(LYX_QTMAIN_LIBRARY)
 766         else()
 767                 set(WIN32_CONSOLE WIN32)
 768         endif()
 769         if(MSVC)
 770                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 771                 # disable checked iterators for msvc release builds to get maximum speed
 772                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 773         else()
 774                 add_definitions(-DWINVER=0x0500)
 775         endif()
 776 endif()
 777
 778 # Compute qt4-version from ${QTVERSION}
 779
 780 message(STATUS "")
 781 foreach(_v PACKAGE PACKAGE_VERSION
 782         PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 783         LYX_ABS_TOP_SRCDIR
 784         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 785         if(NOT DEFINED ${_v})
 786                 message(FATAL_ERROR "${_v} not defined")
 787         endif()
 788         string(SUBSTRING "${_v}                            " 0 28 _v1)
 789         message(STATUS "----- ${_v1}: ${${_v}}")
 790 endforeach(_v)
 791 message(STATUS "")
 792
 793
 794 if(LYX_PCH)
 795         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 796         # Not sure if it works for all non-msvc compilers
 797         include(PCHSupport_26)
 798         configure_file(${TOP_CMAKE_PATH}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
 799         configure_file(${TOP_CMAKE_PATH}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 800         add_definitions(-DLYX_ENABLE_PCH)
 801
 802         if(MSVC)
 803                 macro(lyx_add_msvc_pch name_)
 804                         set_source_files_properties(${${name_}_sources} PROPERTIES
 805                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 806                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
 807                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 808                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
 809                                 ${TOP_BINARY_DIR}/pcheaders.h)
 810                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 811                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 812                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 813                 endmacro(lyx_add_msvc_pch)
 814                 macro(lyx_add_gcc_pch name_)
 815                 endmacro()
 816         else()
 817                 macro(lyx_add_msvc_pch name_)
 818                 endmacro()
 819                 macro(lyx_add_gcc_pch name_)
 820                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT)
 821                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
 822                 endmacro()
 823         endif()
 824 else()
 825         macro(lyx_add_msvc_pch)
 826         endmacro(lyx_add_msvc_pch)
 827         macro(lyx_add_gcc_pch name_)
 828         endmacro()
 829 endif()
 830
 831
 832 if(MSVC)
 833
 834         if(LYX_VLD)
 835                 set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/development/Win32/vld)
 836                 add_subdirectory(${vld_path}/cmake)
 837                 include(${vld_path}/cmake/vld.cmake) # forced include
 838                 set(vld_dll vld)
 839         endif()
 840
 841         if(LYX_WALL)
 842                 # Use the highest warning level
 843                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 844
 845                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 846                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 847                 else()
 848                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 849                 endif()
 850
 851                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 852                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 853                 else()
 854                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 855                 endif()
 856
 857                 # add here warnings which should produce an error /weXXXX
 858                 set(MSVC_W_ERROR   "/we4101 /we4189")
 859                 # add here warnings which should be disabled /wdXXXX
 860                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 861
 862                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 863                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 864                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 865
 866         else()
 867                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 868
 869                 # add here warnings which should produce an error /weXXXX
 870                 set(MSVC_W_ERROR   "/we4101 /we4189")
 871                 # add here warnings which should be disabled /wdXXXX
 872                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 873
 874                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 875                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 876                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 877
 878         endif()
 879
 880         if (NOT Qt5Core_FOUND)
 881                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 882                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 883                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 884         endif()
 885
 886         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 887         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 888         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 889         message(STATUS "")
 890 endif()
 891
 892
 893 if(LYX_DEBUG_GLIBC)
 894         set(_GLIBCXX_DEBUG ON)
 895 endif()
 896
 897 if(LYX_DEBUG_GLIBC_PEDANTIC)
 898         set(_GLIBCXX_DEBUG_PEDANTIC ON)
 899 endif()
 900
 901 # Xcode compiler
 902 if (CMAKE_GENERATOR MATCHES Xcode)
 903         if (XCODE_VERSION VERSION_LESS "5.0")
 904                 # Automatically select the Xcode compiler if not set
 905                 if (NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 906                         # XCode >= 3.1 has gcc 4.2 (up to actual Xcode)
 907                         if (XCODE_VERSION VERSION_GREATER "3.1")
 908                                 SET(CMAKE_XCODE_ATTRIBUTE_GCC_VERSION "com.apple.compilers.llvmgcc42")
 909                         ENDIF(XCODE_VERSION VERSION_GREATER "3.1")
 910                 ENDIF(NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 911                 # Print the selected compiler version
 912         MESSAGE(STATUS "---- Using XCode compiler CMAKE_XCODE_ATTRIBUTE_GCC_VERSION=${CMAKE_XCODE_ATTRIBUTE_GCC_VERSION}")
 913         ENDIF(XCODE_VERSION VERSION_LESS "5.0")
 914 ENDIF(CMAKE_GENERATOR MATCHES Xcode)
 915
 916 if (WIN32 AND Qt5Core_FOUND)
 917         set(Z_PREFIX 1)
 918 endif()
 919
 920 # compiler tests, config.h generation
 921 if(MSVC AND NOT LYX_CONFIGURE_CHECKS)
 922         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.msvc ${TOP_BINARY_DIR}/configCompiler.h)
 923 else()
 924         include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
 925         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
 926 endif()
 927
 928 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
 929
 930 if(QTVERSION MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+).*")
 931         MATH(EXPR QT4_VERSION "(${CMAKE_MATCH_1}<<16)|(${CMAKE_MATCH_2}<<8)|${CMAKE_MATCH_3}")
 932 endif()
 933
 934 if (NOT HAVE_REGEX)
 935         set(LYX_USE_STD_REGEX 0)
 936 endif()
 937
 938
 939 set (cmd ${CMAKE_CTEST_COMMAND})
 940 if (MSVC)
 941         set (cmd ${cmd} -C ${CMAKE_CFG_INTDIR})
 942 else ()
 943         set (cmd ${cmd} -C ${CMAKE_BUILD_TYPE})
 944 endif ()
 945 add_custom_target (lyx_run_tests COMMAND ${cmd})
 946 set_target_properties(lyx_run_tests PROPERTIES FOLDER "tests")
 947
 948 if(LYX_ASAN)
 949     set(LYX_CXX_FLAGS "-fsanitize=address -fno-omit-frame-pointer -g")
 950     message(STATUS)
 951     message(STATUS "Address sanitizer enabled. Usage:")
 952     message(STATUS "    wget https://llvm.org/svn/llvm-project/compiler-rt/trunk/lib/asan/scripts/asan_symbolize.py")
 953     message(STATUS "    chmod  +x ./asan_symbolize.py")
 954     message(STATUS "    ./bin/lyx2.2 2>&1 | ./asan_symbolize.py  | c++filt ")
 955     message(STATUS)
 956 endif()
 957
 958 if(LYX_INSTALL)
 959         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 960                 message(STATUS "Python required to create doc!")
 961         else()
 962                 if(UNIX)
 963                         add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
 964                 endif()
 965                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
 966         endif()
 967         include(../Install)
 968 endif()
 969
 970 add_subdirectory(src "${TOP_BINARY_DIR}/src")
 971 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
 972 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
 973 add_subdirectory(lib/examples "${TOP_BINARY_DIR}/lib/examples")
 974 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
 975 add_subdirectory(development/autotests "${TOP_BINARY_DIR}/autotests")
 976 if(LYX_ENABLE_URLTESTS)
 977         add_subdirectory(development/checkurls "${TOP_BINARY_DIR}/checkurls")
 978 endif()
 979
 980 message(STATUS)
 981 message(STATUS "Build params, switch LYX_* options by -DLYX_*=ON or OFF, LYX_* combos by -DLYX_*=value:")
 982 message(STATUS)
 983
 984 LYX_OPTION_LIST_ALL(used)
 985
 986
 987 if(LYX_NLS)
 988         message(STATUS)
 989         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
 990         message(STATUS)
 991         message(STATUS "  * iconv")
 992         message(STATUS "     - include: ${ICONV_INCLUDE_DIR}")
 993         message(STATUS "     - library: ${ICONV_LIBRARY}")
 994         message(STATUS "  * zlib")
 995         message(STATUS "     - include: ${ZLIB_INCLUDE_DIR}")
 996         message(STATUS "     - library: ${ZLIB_LIBRARY}")
 997         message(STATUS)
 998 endif()
 999
1000 # Apple has builtin native spell checker,
1001 # no need to warn for missing Aspell, Hunspell or Enchant
1002 if(NOT Spelling_FOUND AND NOT APPLE)
1003   if(LYX_REQUIRE_SPELLCHECK)
1004     set(_mode "FATAL_ERROR")
1005   else()
1006     set(_mode "STATUS")
1007   endif()
1008   message(${_mode} "No spellcheck libraries found. LyX will be unable use spellchecking")
1009 endif()
1010
1011 include("${TOP_CMAKE_PATH}/LyxPackaging.cmake")
1012
1013 if(ENABLE_DIST)
1014   # Use git to create the source package
1015   # git archive --format=tgz --output=/home/kornel/x.tar.gz master
1016   if(UNIX)
1017     set(DIST_FORMAT tgz)
1018   else()
1019     set(DIST_FORMAT zip)
1020   endif()
1021   set(DIST_NAME ${CMAKE_PROJECT_NAME}-${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}-${CMAKE_SYSTEM_NAME}.${DIST_FORMAT})
1022
1023   add_custom_command(
1024     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME}
1025     COMMAND  ${LYX_GITVERSION} archive --format=${DIST_FORMAT} --output=${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME} master
1026     WORKING_DIRECTORY ${TOP_SRC_DIR})
1027   add_custom_target(git-archive DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME})
1028 endif()
1029
1030 # Last directory to be included so that the fixup code (OS X)
1031 # can be run last
1032 add_subdirectory(development/cmake/post_install)
1033
1034 message(STATUS)