CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 2.6.4)
   8
   9
  10 set(LYX_PROJECT lyx)
  11
  12 set(LYX_CMAKE_DIR "development/cmake")
  13 set(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/${LYX_CMAKE_DIR}/modules")
  14
  15 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README ABSOLUTE)
  16 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  17
  18 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  19
  20 message(STATUS)
  21 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  22         message(STATUS "Building in-source")
  23         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  24 else()
  25         message(STATUS "Building out-of-source")
  26         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  27 endif()
  28
  29
  30 if(COMMAND cmake_policy)
  31         cmake_policy(SET CMP0003 OLD)
  32         cmake_policy(SET CMP0005 OLD)
  33 endif()
  34
  35 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  36
  37 # Supress regeneration
  38 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  39
  40 if(NOT help AND NOT HELP)
  41         # 'project' triggers the searching for a compiler
  42         project(${LYX_PROJECT})
  43 endif()
  44
  45 include(LyXMacros)
  46
  47 # Usage LYX_OPTION
  48 # 1. parameter: option name without prefix 'LYX_'
  49 # 2. parameter: description
  50 # 3. parameter: default value, ON or OFF
  51 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
  52
  53
  54 LYX_OPTION_INIT()
  55
  56 # Options for all compilers/systems
  57 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
  58 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
  59 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
  60 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
  61 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
  62 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
  63 LYX_OPTION(DEVEL_VERSION    "Build developer version" OFF ALL)
  64 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" OFF ALL)
  65 LYX_OPTION(DEBUG            "Enforce debug build"  OFF ALL)
  66 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
  67 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
  68 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
  69 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
  70 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
  71 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
  72 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
  73 LYX_OPTION(EXTERNAL_LIBINTL "Use external libintl" ON ALL)
  74
  75 # GCC specific
  76 LYX_OPTION(PROFILE              "Build profile version" OFF GCC)
  77 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" OFF GCC)
  78 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
  79 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
  80 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++pedantic debug mode" OFF GCC)
  81 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" OFF GCC)
  82 LYX_OPTION(CONCEPT_CHECKS       "Enable concept-checks" OFF GCC)
  83
  84 # MSVC specific
  85 LYX_OPTION(CONSOLE               "Show console on Windows" ON MSVC)
  86 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
  87 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
  88 LYX_OPTION(CONFIGURE_CHECKS      "Also run configure checks for MSVC" OFF MSVC)
  89 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
  90
  91 # APPLE specific
  92 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
  93 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
  94
  95 if(help OR HELP)
  96         message(STATUS)
  97         message(STATUS "Available options: (dis/enable with -D=0/1)")
  98         message(STATUS)
  99         LYX_OPTION_LIST_ALL(help)
 100         message(STATUS)
 101 else()
 102
 103
 104 # Check option dependencies
 105
 106 if(LYX_CPACK)
 107         set(LYX_INSTALL ON)
 108 endif()
 109
 110 if(LYX_INSTALL)
 111         set(LYX_NLS ON)
 112         if (WIN32)
 113                 set(LYX_HUNSPELL ON)
 114         endif()
 115         set(LYX_CONSOLE OFF)
 116         set(LYX_PACKAGE_SUFFIX ON)
 117         set(LYX_RELEASE ON)
 118         set(LYX_PROFILE OFF)
 119 endif()
 120
 121
 122 if(LYX_MERGE_FILES)
 123         set(LYX_PCH OFF)
 124 else()
 125         set(LYX_MERGE_REBUILD OFF)
 126 endif()
 127
 128 if(LYX_DEPENDENCIES_DOWNLOAD)
 129         message(STATUS)
 130         set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 131         message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 132         set(deps_files lyx20-deps-msvc2010-x86.zip)
 133         foreach(it ${deps_files})
 134                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 135                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 136                 if(NOT already_downloaded)
 137                         message(STATUS "Downloading ${it} ...")
 138                         file(DOWNLOAD ftp://ftp.devel.lyx.org/pub/contrib/windows/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS)
 139                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 140                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 141                 endif()
 142         endforeach()
 143         set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/deps20)
 144 endif()
 145
 146
 147
 148 message(STATUS)
 149
 150 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 151 set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 152
 153
 154
 155 if(UNIX OR MINGW)
 156         execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION)
 157         message(STATUS "Using GCC version ${GCC_VERSION}")
 158         if(NOT GCC_VERSION VERSION_LESS 4.4)
 159                 set(LYX_USE_TR1 1)
 160                 # GCC <= 4.5 does not support regex: there are linker errors
 161                 # http://gcc.gnu.org/onlinedocs/libstdc++/manual/status.html#status.iso.tr1
 162                 set(LYX_USE_TR1_REGEX 0)
 163         endif()
 164 else()
 165         if(MSVC10)
 166                 set(LYX_USE_TR1 1)
 167                 #set(LYX_USE_TR1_REGEX 1) #TODO should we use it in ECMAScript mode?
 168         endif()
 169 endif()
 170
 171
 172 set(VERSION_INFO "CMake Build")
 173
 174 # Try to get some informations from configure.ac
 175
 176 include(LyXPaths)
 177 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 178
 179 if(WIN32)
 180         set(USE_WINDOWS_PACKAGING 1)
 181 elseif(APPLE)
 182         set(USE_MACOSX_PACKAGING 1)
 183 else()
 184         set(USE_POSIX_PACKAGING 1)
 185 endif()
 186
 187 macro(setstripped _varname _value)
 188         string(STRIP ${_value} _v)
 189         if(USE_POSIX_PACKAGING)
 190                 string(TOLOWER ${_v} ${_varname})
 191         else()
 192                 set(${_varname} ${_v})
 193         endif()
 194 endmacro(setstripped)
 195
 196 foreach(_c_l ${_config_lines} )
 197         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 198                 setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 199                 setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 200                 setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 201                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\).*$")
 202                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 203                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 204                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 205                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 206                         set(LYX_INSTALL_SUFFIX "${CMAKE_MATCH_1}.${CMAKE_MATCH_2}")
 207                 endif()
 208         endif()
 209         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 210                 set(LYX_DATE "${CMAKE_MATCH_1}")
 211         endif()
 212 endforeach(_c_l)
 213
 214
 215 if(LYX_DMG)
 216     set(bundle_dir ${TOP_BINARY_DIR}/bin)
 217         set(LYX_CPACK 1)
 218         set(LYX_BUNDLE MACOSX_BUNDLE)
 219         set(LYX_INSTALL_PREFIX LyX2.1 CACHE STRING "LyX bundle install prefix" FORCE)
 220         set(LYX_DATA_SUBDIR LyX.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 221         message(STATUS)
 222         message(STATUS "Bundle creation is enabled.")
 223         message(STATUS "It is experimental, to increase turn around speed use:")
 224         message(STATUS "    cmake -DLYX_MERGE_FILES=1 -DLYX_NO_OPTIMIZE=1 -DLYX_INSTALL=1 -DLYX_DMG=1 ../trunk")
 225         message(STATUS "or use the shell script 'developent/cmake/dmg'")
 226         message(STATUS)
 227 endif()
 228
 229
 230 if(LYX_INSTALL_PREFIX)
 231         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 232         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 233 endif()
 234 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 235
 236 if(LYX_PACKAGE_SUFFIX)
 237         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 238 else()
 239         set(PACKAGE ${PACKAGE_BASE})
 240 endif()
 241
 242 if(LYX_PROGRAM_SUFFIX)
 243         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 244 else()
 245         set(PROGRAM_SUFFIX "")
 246 endif()
 247
 248
 249 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 250         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 251         if (UNIX)
 252                 # don't use the default "/usr/local"
 253                 # but respect the user-choice on the command-line
 254                 if(LYX_INSTALL_SUFFIX)
 255                         set(CMAKE_INSTALL_PREFIX "/usr/local/lyx${LYX_INSTALL_SUFFIX}" CACHE PATH "LyX default install prefix" FORCE)
 256                 else()
 257                         set(CMAKE_INSTALL_PREFIX "/usr/local/${LYX_PROJECT}" CACHE PATH "LyX default install prefix" FORCE)
 258                 endif()
 259         endif()
 260         if(WIN32)
 261                 set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 262         endif()
 263 endif()
 264
 265 if(NOT LYX_DATA_SUBDIR)
 266         if (WIN32)
 267                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 268         else()
 269                 set(LYX_DATA_SUBDIR "" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 270         endif()
 271 endif()
 272
 273 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 274 set(LYX_LOCALEDIR "locale")
 275 set(LYX_ABS_INSTALLED_LOCALEDIR "${LYX_ABS_INSTALLED_DATADIR}/${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}")
 276 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 277
 278
 279
 280 if(NOT GROUP_CODE)
 281         #set(GROUP_CODE "The Golden Code")
 282         set(GROUP_CODE flat)
 283 endif()
 284
 285 # lyx's source files
 286 set(LYX_CPP_FILES *.cpp)
 287 set(LYX_HPP_FILES *.h)
 288 set(LYX_MOC_FILES moc_*.cpp)
 289
 290 include(ProjectSourceGroup)
 291
 292
 293 if(LYX_PROFILE)
 294         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 295         set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -pg" CACHE TYPE STRING FORCE)
 296 endif()
 297
 298
 299 if(LYX_NO_OPTIMIZE)
 300         set(CMAKE_BUILD_TYPE None)
 301         set(LYX_DEBUG OFF)
 302         set(LYX_RELEASE OFF)
 303 elseif(LYX_RELEASE)
 304         set(CMAKE_BUILD_TYPE Release)
 305         set(LYX_DEBUG OFF)
 306 else()
 307         set(CMAKE_BUILD_TYPE Debug)
 308 endif()
 309
 310
 311 # When shared libs are supported enable this option
 312 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 313 if(LYX_SHARED_LIBRARIES)
 314         set(library_type SHARED)
 315 else()
 316         set(library_type STATIC)
 317 endif()
 318
 319 if(NOT MSVC)
 320         if(NOT LYX_QUIET)
 321                 set(CMAKE_VERBOSE_MAKEFILE ON)
 322         endif()
 323         set(LYX_CXX_FLAGS "-Wall -Wunused-parameter")
 324         if(LYX_STDLIB_DEBUG)
 325                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 326         endif()
 327         if(LYX_CONCEPT_CHECKS)
 328                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCPP_CONCEPT_CHECKS")
 329         endif()
 330         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 331         set(CMAKE_CXX_FLAGS_DEBUG "${LYX_CXX_FLAGS} -fno-strict-aliasing -O0 -g -D_DEBUG" CACHE TYPE STRING FORCE)
 332         if(MINGW)
 333                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 334         else()
 335                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 336         endif()
 337         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg" CACHE TYPE STRING FORCE)
 338 endif()
 339
 340
 341 find_package(Qt4 REQUIRED)
 342
 343
 344 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 345
 346 if(LYX_ASPELL)
 347         find_package(ASPELL)
 348         include_directories(${ASPELL_INCLUDE_DIR})
 349 endif()
 350
 351 if(LYX_ENCHANT)
 352         find_package(Enchant REQUIRED)
 353         include_directories(${ENCHANT_INCLUDE_DIR})
 354 endif()
 355
 356 if(LYX_HUNSPELL)
 357         find_package(Hunspell REQUIRED)
 358         include_directories(${HUNSPELL_INCLUDE_DIR})
 359 endif()
 360
 361 if(LYX_NLS)
 362         FIND_PROGRAM(LYX_PYTHON_EXECUTABLE python HINTS ${GNUWIN32_DIR}/python)
 363         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 364                 message(FATAL_ERROR "Python 2.6 needed!")
 365         endif()
 366         find_package(LyXGettext REQUIRED)
 367         include_directories(${TOP_SRC_DIR}/po)
 368         add_subdirectory(po "${TOP_BINARY_DIR}/po")
 369 endif()
 370
 371 if(LYX_NLS)
 372         if(LYX_EXTERNAL_LIBINTL)
 373                 find_package(Libintl REQUIRED)
 374                 if(DEFINED LIBINTL_LIBRARIES)
 375                         # find getext when configuring
 376                         list(APPEND CMAKE_REQUIRED_LIBRARIES ${LIBINTL_LIBRARIES})
 377                         # on mac use iconv also form ports
 378                         get_filename_component(ICONV_RELATIVE_TO_LIBINTL ${LIBINTL_LIBRARIES} PATH)
 379                 endif()
 380         else()
 381                 add_subdirectory(intl "${TOP_BINARY_DIR}/intl")
 382         endif()
 383 endif()
 384
 385 find_package(ICONV REQUIRED)
 386 find_package(ZLIB REQUIRED)
 387
 388 if(LYX_EXTERNAL_BOOST)
 389         message(STATUS "Searching for boost")
 390         find_package(Boost COMPONENTS signals regex) #TODO could REQUIRED be used
 391         if(Boost_FOUND)
 392                 message(STATUS "Boost found")
 393                 message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 394                 set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 395         else()
 396                 message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 397         endif()
 398 else()
 399         if(LYX_USE_TR1_REGEX)
 400                 set(Lyx_Boost_Libraries boost_signals)
 401         else()
 402                 set(Lyx_Boost_Libraries boost_signals boost_regex)
 403         endif()
 404         add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 405         include_directories(${TOP_SRC_DIR}/boost)
 406         add_subdirectory(boost "${TOP_BINARY_DIR}/boost")
 407 endif()
 408
 409
 410
 411
 412 if(WIN32)
 413         if(NOT LYX_CONSOLE)
 414                 set(WIN32_CONSOLE WIN32)
 415                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARY})
 416         endif()
 417         if(MSVC)
 418                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 419                 # disable checked iterators for msvc release builds to get maximum speed
 420                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 421         else()
 422                 add_definitions(-DWINVER=0x0500)
 423         endif()
 424 endif()
 425
 426 message(STATUS "")
 427 foreach(_v PACKAGE PACKAGE_VERSION
 428         PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 429         LYX_ABS_TOP_SRCDIR
 430         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 431         if(NOT DEFINED ${_v})
 432                 message(FATAL_ERROR "${_v} not defined")
 433         endif()
 434         string(SUBSTRING "${_v}                            " 0 28 _v1)
 435         message(STATUS "----- ${_v1}: ${${_v}}")
 436 endforeach(_v)
 437 message(STATUS "")
 438
 439
 440 if(LYX_PCH)
 441         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 442         # Not sure if it works for all non-msvc compilers
 443         include(PCHSupport_26)
 444         configure_file(${TOP_SRC_DIR}/${LYX_CMAKE_DIR}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
 445         configure_file(${TOP_SRC_DIR}/${LYX_CMAKE_DIR}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 446         add_definitions(-DLYX_ENABLE_PCH)
 447
 448         if(MSVC)
 449                 macro(lyx_add_msvc_pch name_)
 450                         set_source_files_properties(${${name_}_sources} PROPERTIES
 451                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 452                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
 453                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 454                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
 455                                 ${TOP_BINARY_DIR}/pcheaders.h)
 456                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 457                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 458                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 459                 endmacro(lyx_add_msvc_pch)
 460                 macro(lyx_add_gcc_pch name_)
 461                 endmacro()
 462         else()
 463                 macro(lyx_add_msvc_pch name_)
 464                 endmacro()
 465                 macro(lyx_add_gcc_pch name_)
 466                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT4)
 467                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
 468                 endmacro()
 469         endif()
 470 else()
 471         macro(lyx_add_msvc_pch)
 472         endmacro(lyx_add_msvc_pch)
 473         macro(lyx_add_gcc_pch name_)
 474         endmacro()
 475 endif()
 476
 477 if(MSVC)
 478         if(LYX_VLD)
 479                 set(LYX_LEAK_DETECTION 1 CACHE TYPE STRING FORCE)
 480                 set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 481                 set(LYX_VLD_PATH ${CMAKE_CURRENT_SOURCE_DIR}/../Win32/vld)
 482                 include(${LYX_VLD_PATH}/tools/cmake/vld.cmake)
 483         endif()
 484
 485         if(LYX_WALL)
 486                 # Use the highest warning level
 487                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 488
 489                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 490                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 491                 else()
 492                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 493                 endif()
 494
 495                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 496                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 497                 else()
 498                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 499                 endif()
 500
 501                 # add here warnings which should produce an error /weXXXX
 502                 set(MSVC_W_ERROR   "/we4101 /we4189")
 503                 # add here warnings which should be disabled /wdXXXX
 504                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 505
 506                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 507                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 508                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 509
 510         else()
 511                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 512
 513                 # add here warnings which should produce an error /weXXXX
 514                 set(MSVC_W_ERROR   "/we4101 /we4189")
 515                 # add here warnings which should be disabled /wdXXXX
 516                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 517
 518                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 519                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 520                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 521
 522         endif()
 523         set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 524         set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 525         set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 526
 527         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 528         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 529         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 530         message(STATUS "")
 531 endif()
 532
 533
 534 if(LYX_DEBUG_GLIBC)
 535         set(_GLIBCXX_DEBUG 1)
 536 endif()
 537
 538 if(LYX_DEBUG_GLIBC_PEDANTIC)
 539         set(_GLIBCXX_DEBUG_PEDANTIC 1)
 540 endif()
 541
 542 # compiler tests, config.h generation
 543 if(MSVC AND NOT LYX_CONFIGURE_CHECKS)
 544         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.msvc ${TOP_BINARY_DIR}/configCompiler.h)
 545 else()
 546         include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
 547         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
 548 endif()
 549
 550 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
 551
 552
 553 add_subdirectory(src "${TOP_BINARY_DIR}/src")
 554 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
 555 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
 556
 557
 558 if(LYX_INSTALL)
 559         FIND_PROGRAM(LYX_PERL_EXECUTABLE perl)
 560         if(${LYX_PERL_EXECUTABLE} MATCHES "-NOTFOUND")
 561                 message(FATAL_ERROR "Perl required!")
 562         endif()
 563         add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
 564         add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
 565         include(../Install)
 566 endif()
 567
 568
 569 message(STATUS)
 570 message(STATUS "Build options, switch LYX_* variables by -DLYX_*=1 or 0:")
 571 message(STATUS)
 572 LYX_OPTION_LIST_ALL(used)
 573
 574
 575 if(LYX_NLS)
 576         message(STATUS)
 577         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
 578         message(STATUS)
 579         message(STATUS "  * intl")
 580         message(STATUS "     - header : ${LIBINTL_HEADER}")
 581         message(STATUS "     - library: ${LIBINTL_LIBRARIES}")
 582         message(STATUS "  * iconv")
 583         message(STATUS "     - header : ${ICONV_HEADER}")
 584         message(STATUS "     - library: ${ICONV_LIBRARY}")
 585         message(STATUS "  * zlib")
 586         message(STATUS "     - header : ${ZLIB_HEADER}")
 587         message(STATUS "     - library: ${ZLIB_LIBRARY}")
 588         message(STATUS)
 589 endif()
 590
 591
 592 # CPack packaging
 593 #
 594 # http://cmake.org/cmake/help/cmake-2-8-docs.html#module:CPack
 595
 596 set(CPACK_PACKAGE_VERSION_MAJOR "${LYX_MAJOR_VERSION}")
 597 set(CPACK_PACKAGE_VERSION_MINOR "${LYX_MINOR_VERSION}")
 598 FILE(STRINGS "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}/LyX_summary.txt" CPACK_PACKAGE_DESCRIPTION_SUMMARY)
 599
 600 set(CPACK_SOURCE_GENERATOR TGZ ZIP TBZ2)
 601 set(CPACK_SOURCE_INSTALLED_DIRECTORIES "${TOP_SRC_DIR};/") # http://www.mail-archive.com/cmake@cmake.org/msg33720.html
 602
 603 set(CPACK_PACKAGE_INSTALL_DIRECTORY "CMake ${LYX_INSTALL_SUFFIX}")
 604
 605 set(CPACK_SOURCE_GENERATOR TGZ ZIP TBZ2)
 606 set(CPACK_SOURCE_INSTALLED_DIRECTORIES "${TOP_SRC_DIR};/") # http://www.mail-archive.com/cmake@cmake.org/msg33720.html
 607 #
 608 # needed by rpm
 609 set(CPACK_SET_DESTDIR "ON")
 610 FILE(READ "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}/LyX_license.txt" CPACK_RPM_PACKAGE_LICENSE)
 611 set(CPACK_RPM_PACKAGE_GROUP "Applications/Publishing")
 612 set(CPACK_RPM_PACKAGE_VENDOR "The LyX team")
 613 #
 614 # the next ones are needed by deb
 615 set(CPACK_PACKAGE_CONTACT "${PACKAGE_BUGREPORT}")
 616 set(CPACK_SOURCE_PACKAGE_FILE_NAME "${LYX_PROJECT}-${LYX_INSTALL_SUFFIX}")
 617
 618 # This is experimental, valid on _my_ system (Kornel)
 619 set(CPACK_DEBIAN_PACKAGE_DEPENDS "libqtgui4 (>= 4.4.3-0)")
 620 if(ASPELL_FOUND)
 621         set(CPACK_DEBIAN_PACKAGE_DEPENDS "libaspell15 (>= 0.60.6-1),${CPACK_DEBIAN_PACKAGE_DEPENDS}")
 622 endif()
 623 if(ENCHANT_FOUND)
 624         set(CPACK_DEBIAN_PACKAGE_DEPENDS "libenchant1c2a (>= 1.6.0-0),${CPACK_DEBIAN_PACKAGE_DEPENDS}")
 625 endif()
 626 if(LYX_EXTERNAL_BOOST)
 627         if(Boost_FOUND)
 628                 set(CPACK_DEBIAN_PACKAGE_DEPENDS "libboost-regex1.40.0 (>= 1.40.0-4),libboost-signals1.40.0 (>= 1.40.0-4),${CPACK_DEBIAN_PACKAGE_DEPENDS}")
 629         endif()
 630 endif()
 631 #
 632 # for the next ones, cpack insists on data with values in some file
 633 set(CPACK_PACKAGE_DESCRIPTION_FILE "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}/LyX_description.txt")
 634 set(CPACK_RESOURCE_FILE_LICENSE "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}/LyX_license.txt")
 635
 636 # Find the revision number and use it as the release in rpm-package-build.
 637 # This way we may omit the otherwise needed "--force" parameter when
 638 # installing from that rpm package.
 639 FIND_PROGRAM(LYX_SVNVERSION svnversion)
 640 #message(STATUS "svnversion = ${LYX_SVNVERSION}")
 641 if(NOT ${LYX_SVNVERSION} MATCHES "-NOTFOUND")
 642         EXECUTE_PROCESS(COMMAND ${LYX_SVNVERSION} WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE CPACK_RPM_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 643         # We use this value also to set the package-patch-value
 644         if(CPACK_RPM_PACKAGE_RELEASE MATCHES "^\([0-9]+\)")
 645                 set(CPACK_PACKAGE_VERSION_PATCH ${CMAKE_MATCH_1})
 646         endif()
 647 endif()
 648
 649 # we do not have a readme or welcome data,
 650 # so we do not provide infofiles for
 651 # CPACK_RESOURCE_FILE_README and CPACK_RESOURCE_FILE_WELCOME
 652
 653 if(WIN32)
 654         set(CPACK_GENERATOR NSIS ZIP)
 655         set(CPACK_BINARY_ZIP 1)
 656 endif()
 657
 658
 659 set(CPACK_STRIP_FILES 1)
 660
 661 # sources
 662 set(CPACK_SOURCE_INSTALLED_DIRECTORIES "${TOP_SRC_DIR};/") # http://www.mail-archive.com/cmake@cmake.org/msg33720.html
 663 set(CPACK_SOURCE_GENERATOR TGZ ZIP TBZ2)
 664
 665
 666 if(LYX_DMG)
 667         set(CPACK_PACKAGE_NAME LyX)
 668         set(CPACK_GENERATOR DragNDrop)
 669
 670         # We start from bin/lyx.app, all is build into the final bundle folder
 671         # On Mac the paths to required shared libraries are hardcoded in the
 672         # binary/library. This is fixed by the macro 'fixup_bundle'
 673         # Hardcoded pathes to libraries are resolved automatically
 674
 675
 676         set(app          ${bundle_dir}/LyX.app)
 677         set(contents_dir LyX.app/Contents/)
 678         install(DIRECTORY "${QT_PLUGINS_DIR}/imageformats" DESTINATION ${bundle_dir}/${contents_dir}/plugins COMPONENT Runtime)
 679
 680         message(STATUS "Qt Plugins: ${QT_PLUGINS_DIR}/imageformats DESTINATION ${bundle_dir}/${contents_dir}/plugins")
 681
 682         install(CODE
 683                 "file(GLOB qt_plugins \"${bundle_dir}/${contents_dir}/plugins/imageformats/*${CMAKE_SHARED_LIBRARY_SUFFIX}\")
 684                 include(BundleUtilities)
 685                 fixup_bundle(\"${app}\" \"\${qt_plugins}\" \"${dir}\") "
 686                 COMPONENT RUNTIME)
 687
 688         file(WRITE ${CMAKE_BINARY_DIR}/qt.conf "")
 689         install(FILES ${CMAKE_BINARY_DIR}/qt.conf DESTINATION ${contents_dir}/Resources COMPONENT Runtime)
 690
 691 endif()
 692
 693
 694 if(LYX_CPACK)
 695         include(CPack)
 696 endif()
 697
 698 #Now it is possible to create some packages
 699 # cd <BuildDir>
 700 # make package
 701 #############################################################################################
 702 # So, e.g. for variables
 703 #    CMAKE_PROJECT_NAME                     : lyx
 704 #    CPACK_PACKAGE_VERSION_MAJOR            : 2
 705 #    CPACK_PACKAGE_VERSION_MINOR            : 0
 706 #    CPACK_PACKAGE_VERSION_PATCH            : 1
 707 #    CMAKE_SYSTEM_NAME                      : Linux
 708 #    CPACK_BINARY_DEB:BOOL                  : ON
 709 #
 710 # the package name builds as "lyx-2.0.1-Linux.deb"
 711 #
 712 ############################## rpm ################################### deb ##################
 713 # create    # cpack -G RPM --config CPackConfig.cmake   # cpack -G DEB --config CPackConfig.cmake
 714 # creates =># lyx-2.0.1-Linux.rpm                       # lyx-2.0.1-Linux.deb
 715 # list      # rpm -qlp lyx-2.0.1-Linux.rpm              # dpkg-deb -c lyx-2.0.1-Linux.deb
 716 # install   # rpm -U lyx-2.0.1-Linux.rpm                # dpkg -i lyx-2.0.1-Linux.deb
 717 #
 718 message(STATUS)
 719
 720 endif() #help
 721