CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 3.1.0)
   8
   9 set(LYX_PROJECT LyX)
  10
  11 # Instruct cmake to not use gnu extensions,
  12 # this prevents the mix of '-std=c++*' and '-std=gnu++*' flags
  13 set(CMAKE_CXX_EXTENSIONS OFF)
  14
  15 enable_testing()
  16
  17 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README REALPATH) # Resolve symlinks
  18 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  19 message(STATUS "TOP_SRC_DIR = ${TOP_SRC_DIR}")
  20
  21 set(LYX_CMAKE_DIR "development/cmake")
  22 set(TOP_CMAKE_PATH "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}")
  23 set(TOP_MODULE_PATH "${TOP_CMAKE_PATH}/modules")
  24 set(TOP_SCRIPT_PATH "${TOP_CMAKE_PATH}/scripts")
  25
  26 set(CMAKE_MODULE_PATH "${TOP_MODULE_PATH}")
  27
  28 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  29
  30 message(STATUS)
  31 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  32         message(STATUS "Building in-source")
  33         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  34 else()
  35         message(STATUS "Building out-of-source")
  36         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  37 endif()
  38
  39 # This directory should be used if some test uses lyx-executable
  40 set(LYX_TESTS_USERDIR "${TOP_BINARY_DIR}/Testing/.lyx")
  41 file(MAKE_DIRECTORY "${LYX_TESTS_USERDIR}")
  42
  43 if(COMMAND cmake_policy)
  44         # Installing MACOSX_BUNDLE targets requires a BUNDLE DESTINATION
  45         cmake_policy(SET CMP0006 NEW)
  46         if(POLICY CMP0043)
  47                 # COMPILE_DEFINITIONS are not used yet. Enable new behavior.
  48                 cmake_policy(SET CMP0043 NEW)
  49         endif()
  50         cmake_policy(SET CMP0020 NEW)
  51         if(POLICY CMP0075)
  52                 cmake_policy(SET CMP0075 NEW)
  53         endif()
  54 endif()
  55
  56 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  57
  58 # Supress regeneration
  59 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  60
  61 if(LYX_XMINGW)
  62     set(CMAKE_SYSTEM_NAME Windows)
  63     set(TOOLNAME ${LYX_XMINGW})
  64     set(TOOLCHAIN "${TOOLNAME}-")
  65     set(CMAKE_C_COMPILER   "${TOOLCHAIN}gcc"     CACHE PATH "Mingw C compiler" FORCE)
  66     set(CMAKE_CXX_COMPILER "${TOOLCHAIN}g++"     CACHE PATH "Mingw C++ compiler" FORCE)
  67     set(CMAKE_RC_COMPILER  "${TOOLCHAIN}windres" CACHE PATH "Mingw rc compiler" FORCE)
  68
  69     set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM BOTH)
  70     set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY)
  71     set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY)
  72 endif()
  73
  74 if(NOT help AND NOT HELP)
  75   # 'project' triggers the searching for a compiler
  76   project(${LYX_PROJECT})
  77   if (CMAKE_COMPILER_IS_GNUCXX)
  78     if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS "4.0")
  79       message(STATUS "Gnu CXX compiler version = ${CMAKE_CXX_COMPILER_VERSION}")
  80       message(STATUS "is too old, should be >= 4.0")
  81       message(FATAL_ERROR "Exiting")
  82     endif()
  83   endif()
  84 endif()
  85
  86 if(UNIX)
  87         set(ARCH_TRIPLET )
  88         FIND_PROGRAM(DPKG_ARCHITECTURE_EXECUTABLE dpkg-architecture)
  89         if(DPKG_ARCHITECTURE_EXECUTABLE)
  90                 EXECUTE_PROCESS(COMMAND ${DPKG_ARCHITECTURE_EXECUTABLE} -qDEB_HOST_MULTIARCH
  91                                 OUTPUT_VARIABLE ARCH_TRIPLET
  92                                 ERROR_VARIABLE ERROR_ARCH_TRIPLET
  93                                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  94         endif()
  95 endif()
  96 if(ARCH_TRIPLET)
  97         set(SYSTEM_LIB_DIRS /usr/lib /usr/lib/${ARCH_TRIPLET} /usr/local/lib)
  98 else()
  99         set(SYSTEM_LIB_DIRS /usr/lib /usr/local/lib)
 100 endif()
 101
 102 include(LyXMacros)
 103 include(LyXDestinations)
 104
 105 # Usage LYX_OPTION
 106 # 1. parameter: option name without prefix 'LYX_'
 107 # 2. parameter: description
 108 # 3. parameter: default value, ON or OFF
 109 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
 110
 111 # Usage LYX_COMBO
 112 # 1. parameter: name without prefix 'LYX_'
 113 # 2. parameter: description
 114 # 3. parameter: default value
 115 # 4-n parameter: possible other string values
 116
 117 LYX_OPTION_INIT()
 118
 119 # Options for all compilers/systems
 120 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
 121 LYX_OPTION(LOCALVERSIONING  "Add version info to created package name (only used if LYX_CPACK option set)" OFF ALL)
 122 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
 123 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
 124 LYX_OPTION(REQUIRE_SPELLCHECK "Abort if no spellchecker available" OFF ALL)
 125 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
 126 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
 127 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
 128 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" OFF ALL)
 129 LYX_OPTION(DEBUG            "Enforce debug build"  OFF ALL)
 130 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
 131 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
 132 LYX_STRING(SUFFIX_VALUE     "Use this string as suffix" "")
 133 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
 134 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
 135 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
 136 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
 137 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
 138 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
 139 LYX_OPTION(ENABLE_URLTESTS  "Enable for URL tests" OFF ALL)
 140 LYX_OPTION(ENABLE_EXPORT_TESTS "Enable for export tests" OFF ALL)
 141 LYX_OPTION(ENABLE_KEYTESTS  "Enable for keytests" OFF ALL)
 142 if (NOT CMAKE_VERSION VERSION_LESS "3.17")
 143   LYX_OPTION(ENABLE_VALGRIND_TESTS  "Enable for tests involving valgrind" OFF ALL)
 144 else()
 145   if (LYX_ENABLE_VALGRIND_TESTS)
 146     unset(LYX_ENABLE_VALGRIND_TESTS CACHE)
 147   endif()
 148 endif()
 149 LYX_OPTION(ASAN             "Use address sanitizer" OFF ALL)
 150 #LYX_COMBO(USE_FILEDIALOG    "Use native or QT file dialog" QT NATIVE)
 151 LYX_COMBO(USE_QT            "Use Qt version as frontend" AUTO QT4 QT5)
 152 LYX_COMBO(USE_IPO           "Interprocedural optimization" OFF AUTO ON)
 153 #LYX_OPTION(3RDPARTY_BUILD   "Build 3rdparty libs" OFF ALL)
 154 LYX_OPTION(DISABLE_CALLSTACK_PRINTING "do not print a callstack when crashing" OFF ALL)
 155 LYX_OPTION(EXTERNAL_Z       "OFF := Build 3rdparty lib zlib" ON ALL)
 156 LYX_OPTION(EXTERNAL_DTL     "OFF := Build 3rdparty commands dt2dv and dv2dt" ON ALL)
 157 LYX_OPTION(EXTERNAL_ICONV   "OFF := Build 3rdparty lib iconvlib" ON ALL)
 158 LYX_OPTION(EXTERNAL_HUNSPELL "OFF := Build 3rdparty lib hunspelllib" ON ALL)
 159 LYX_COMBO(EXTERNAL_MYTHES   "OFF := Build 3rdparty lib mytheslib" AUTO OFF ON)
 160
 161 # GCC specific
 162 LYX_OPTION(PROFILE              "Build with options for gprof" OFF GCC)
 163 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" OFF GCC)
 164 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
 165 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
 166 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++ pedantic debug mode" OFF GCC)
 167 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" OFF GCC)
 168
 169 # MSVC specific
 170 LYX_OPTION(CONSOLE               "Show console on Windows" ON MSVC)
 171 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
 172 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
 173 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
 174
 175 # APPLE specific
 176 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
 177 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
 178
 179
 180 if(help OR HELP)
 181         message(STATUS)
 182         message(STATUS "Available options: (dis/enable with -DLYX_*=OFF/ON)")
 183         message(STATUS)
 184         LYX_OPTION_LIST_ALL(help)
 185         message(STATUS)
 186         RETURN()
 187 endif()
 188
 189 # Check option dependencies
 190 if (LYX_ENABLE_VALGRIND_TESTS)
 191         find_program(VALGRIND_EXECUTABLE "valgrind")
 192         if (NOT VALGRIND_EXECUTABLE)
 193                 message(FATAL_ERROR "Cannot use valgrind tests, executable valgrind is missing. Please disable LYX_ENABLE_VALGRIND_TESTS")
 194         endif()
 195 endif()
 196 if (LYX_DEBUG_GLIBC OR LYX_DEBUG_GLIBC_PEDANTIC OR LYX_STDLIB_DEBUG)
 197   if (LYX_EXTERNAL_BOOST)
 198     message(FATAL_ERROR "Using external boost not compatible with debug mode for stdlib")
 199   endif()
 200 endif()
 201
 202 if(LYX_DMG)
 203         set(LYX_BUNDLE ON)
 204         set(LYX_CPACK ON)
 205 endif()
 206
 207 if(LYX_CPACK)
 208         set(LYX_INSTALL ON)
 209 endif()
 210
 211 if(LYX_INSTALL)
 212         set(LYX_NLS ON)
 213         if(WIN32 AND NOT MINGW)
 214                 set(LYX_HUNSPELL ON)
 215         endif()
 216         set(LYX_PACKAGE_SUFFIX ON)
 217         if(NOT LYX_DEBUG)
 218                 set(LYX_RELEASE ON)
 219         endif()
 220         set(LYX_PROFILE OFF)
 221 endif()
 222
 223
 224 if(LYX_MERGE_FILES)
 225         set(LYX_PCH OFF)
 226 else()
 227         set(LYX_MERGE_REBUILD OFF)
 228 endif()
 229
 230 if(LYX_DEPENDENCIES_DOWNLOAD)
 231         message(STATUS)
 232         if(MSVC14)
 233                 set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2015-deps)
 234                 set(deps_files lyx-windows-deps-msvc2015.zip)
 235                 set(deps_server http://ftp.lyx.de/LyX-Windows-Deps)
 236                 set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2015)
 237         elseif(MSVC10)
 238                 set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 239                 set(deps_files lyx-windows-deps-msvc2010.zip)
 240                 set(deps_server http://ftp.lyx.de/LyX-Windows-Deps)
 241                 set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2010)
 242         else()
 243                 message(FATAL_ERROR "error: no dependency package known for the selected MSVC version.")
 244         endif()
 245     message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 246         foreach(it ${deps_files})
 247                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 248                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 249                 if(NOT already_downloaded)
 250                         message(STATUS "Downloading ${it} ...")
 251                         file(DOWNLOAD ${deps_server}/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS STATUS status LOG log)
 252                         list(GET status 0 status_code)
 253                         list(GET status 1 status_string)
 254                         if(NOT status_code EQUAL 0)
 255                                 file(REMOVE ${LYX_DEPENDENCIES_DIR}/${it})
 256                                 message(FATAL_ERROR "error: downloading '${it}' failed. status_code: ${status_code}, status_string: ${status_string}. \nLog: ${log} ")
 257                         endif()
 258                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 259                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 260                 endif()
 261         endforeach()
 262 endif()
 263
 264 message(STATUS)
 265
 266 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 267 if(WIN32)
 268         set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 269 else()
 270         set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 271 endif()
 272
 273 set(LYX_IPO_SUPPORTED OFF)
 274 if (POLICY CMP0069)
 275   cmake_policy(SET CMP0069 NEW)
 276   if(LYX_USE_IPO MATCHES "AUTO")
 277     # Enable LTO if supported and not debugging
 278     if (NOT LYX_DEBUG)
 279       include(CheckIPOSupported)
 280       check_ipo_supported(RESULT LYX_IPO_SUPPORTED)
 281     endif()
 282   else()
 283     set(LYX_IPO_SUPPORTED ${LYX_USE_IPO})
 284   endif()
 285 endif()
 286 if (LYX_IPO_SUPPORTED)
 287   set(LYX_USE_IPO "ON" CACHE STRING "Use interprocedural optimization" FORCE)
 288 else()
 289   set(LYX_USE_IPO "OFF" CACHE STRING "Use interprocedural optimization" FORCE)
 290 endif()
 291
 292 # Set to some meaningful default
 293 find_package(CXX11Compiler)
 294 if(NOT CXX11COMPILER_FOUND)
 295         message(FATAL_ERROR "A C++11 compatible compiler is required.")
 296 endif()
 297 unset(LYX_GCC11_MODE)
 298 if(UNIX OR MINGW)
 299         if (CMAKE_CXX_COMPILER_ID MATCHES "^([cC]lang|AppleClang)$")
 300           # ignore the GCC_VERSION for clang
 301           # and use the resulting CXX11_STD_REGEX found in FindCXX11Compiler.cmake
 302           message(STATUS "Using clang")
 303           if(CXX11_STD_REGEX)
 304             set(LYX_USE_STD_REGEX 1)
 305           else()
 306             set(LYX_USE_STD_REGEX 0)
 307           endif()
 308         else()
 309           execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpfullversion OUTPUT_VARIABLE GCC_VERSION ERROR_VARIABLE _error RESULT_VARIABLE _err OUTPUT_STRIP_TRAILING_WHITESPACE)
 310           #message(STATUS "dumpfullversion: error = ${_error}, result = ${_err}")
 311           if (_err)
 312             # previous check failed, try again with _old_ parameter
 313             execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION ERROR_VARIABLE _error RESULT_VARIABLE _err OUTPUT_STRIP_TRAILING_WHITESPACE)
 314             #message(STATUS "dumpversion: error = ${_error}, result = ${_err}")
 315           endif()
 316           message(STATUS "Using GCC version ${GCC_VERSION}")
 317           if(GCC_VERSION VERSION_LESS 4.6)
 318                 message(FATAL_ERROR "gcc >= 4.6 is required.")
 319           elseif(GCC_VERSION VERSION_LESS 4.9)
 320                 # <regex> in gcc is unusable in versions less than 4.9.0
 321                 # see https://gcc.gnu.org/bugzilla/show_bug.cgi?id=53631
 322                 set(LYX_USE_STD_REGEX 0)
 323           else()
 324                 set(LYX_USE_STD_REGEX 1)
 325           endif()
 326         endif()
 327         set(LYX_GCC11_MODE "${CXX11_FLAG}")
 328 else()
 329         if(MSVC_VERSION LESS 1900)
 330                 # Drop support for msvc versions prior to 1900 (Visual Studio 2015)
 331                 message(FATAL_ERROR "Visual Studio >= 2015 is required.")
 332                 set(LYX_USE_STD_REGEX 0)
 333         else()
 334                 set(LYX_USE_STD_REGEX 1)
 335         endif()
 336 endif()
 337
 338
 339 # Try to get some informations from configure.ac
 340
 341 include(LyXPaths)
 342 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 343
 344 if(WIN32)
 345         set(CMAKE_PREFIX_PATH Specify-path-to-Qt CACHE PATH "Used Qt version")
 346         if(MSVC)
 347                 set(LYX_3RDPARTY_BUILD ON CACHE BOOL "Build 3rdparty libraries" FORCE)
 348         endif()
 349         set(USE_WINDOWS_PACKAGING ON)
 350 elseif(APPLE)
 351         set(USE_MACOSX_PACKAGING ON)
 352 else()
 353         set(USE_POSIX_PACKAGING ON)
 354 endif()
 355
 356 if(LYX_3RDPARTY_BUILD)
 357   # LYX_3RDPARTY_BUILD is not cached anymore, but for compatibility reasons
 358   # this enables the build of all 3rd_party libs
 359   set(LYX_EXTERNAL_Z        OFF CACHE BOOL "Build 3rdparty lib zlib"    FORCE)
 360   set(LYX_EXTERNAL_ICONV    OFF CACHE BOOL "Build 3rdparty iconvlib"    FORCE)
 361   set(LYX_EXTERNAL_HUNSPELL OFF CACHE BOOL "Build 3rdparty hunspelllib" FORCE)
 362   set(LYX_EXTERNAL_MYTHES   OFF CACHE STRING "Build 3rdparty mytheslib" FORCE)
 363 endif()
 364
 365 macro(setstripped _varname)
 366         if(${ARGC} GREATER 1)
 367                 string(STRIP "${ARGV1}" _v)
 368                 if (_v MATCHES "^\\[\(.+\)\\]$")
 369                   set(_v ${CMAKE_MATCH_1})
 370                 endif()
 371                 if(USE_POSIX_PACKAGING)
 372                         string(TOLOWER ${_v} ${_varname})
 373                 else()
 374                         set(${_varname} ${_v})
 375                 endif()
 376         else()
 377                 set(${_varname})
 378         endif()
 379 endmacro(setstripped)
 380
 381 foreach(_c_l ${_config_lines} )
 382         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 383                 # Not using CMAKE_MATCH_ directly is needed, because
 384                 # its value is now changed inside macro setstripped
 385                 set(_PB ${CMAKE_MATCH_1})
 386                 set(_PV ${CMAKE_MATCH_2})
 387                 set(_PBU ${CMAKE_MATCH_3})
 388                 setstripped(PACKAGE_BASE ${_PB})
 389                 setstripped(PACKAGE_VERSION ${_PV})
 390                 setstripped(PACKAGE_BUGREPORT ${_PBU})
 391                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\)\(\\.\([0-9]+\)\(\\.\([0-9]+\)\)?\)?.*$")
 392                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 393                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 394                         set(LYX_RELEASE_LEVEL ${CMAKE_MATCH_4})
 395                         set(LYX_RELEASE_PATCH ${CMAKE_MATCH_6})
 396                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 397                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 398                         if (NOT LYX_RELEASE_LEVEL)
 399                                 set(LYX_RELEASE_LEVEL 0)
 400                         endif()
 401                         if (NOT LYX_RELEASE_PATCH)
 402                                 set(LYX_RELEASE_PATCH 0)
 403                         endif()
 404                         set(LYX_VERSION "${LYX_MAJOR_VERSION}.${LYX_MINOR_VERSION}")
 405                         if ("${LYX_SUFFIX_VALUE}" MATCHES "")
 406                           set(LYX_INSTALL_SUFFIX "${LYX_MAJOR_VERSION}.${LYX_MINOR_VERSION}")
 407                         else()
 408                           set(LYX_INSTALL_SUFFIX "${LYX_SUFFIX_VALUE}")
 409                         endif()
 410                 endif()
 411         endif()
 412         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 413                 set(LYX_DATE "${CMAKE_MATCH_1}")
 414         endif()
 415 endforeach(_c_l)
 416 unset(_config_lines)
 417
 418 FIND_PROGRAM(LYX_GITVERSION git)
 419 #message(STATUS "gitversion = ${LYX_GITVERSION}")
 420 set(LYX_REVISION_VERSION ${LYX_RELEASE_LEVEL})
 421 set(LYX_PACKAGE_RELEASE "UNDEFINED")
 422 if(LYX_GITVERSION)
 423   if (LYX_LOCALVERSIONING)
 424     # Find the revision number for later use
 425     EXECUTE_PROCESS(COMMAND ${LYX_GITVERSION} describe --match 2.0.0 HEAD
 426       WORKING_DIRECTORY "${TOP_SRC_DIR}"
 427       RESULT_VARIABLE tmp_GIT_RESULT
 428       OUTPUT_VARIABLE tmp_LYX_PACKAGE_RELEASE
 429       ERROR_VARIABLE tmp_GIT_ERROR
 430       OUTPUT_STRIP_TRAILING_WHITESPACE)
 431     if (tmp_GIT_RESULT EQUAL 0)
 432       if (tmp_LYX_PACKAGE_RELEASE MATCHES "^2\\.0\\.0\\-\([0-9]+\)\\-\(.*\)$")
 433         set(LYX_PACKAGE_RELEASE ${CMAKE_MATCH_2})
 434         # We will add offset of 40000 to get appropriate value to
 435         # previous svn.
 436         # We use this value than also to set the package-patch-value
 437         MATH(EXPR tmp_REVISION_VERSION "(${CMAKE_MATCH_1}+40000)")
 438         set(LYX_REVISION_VERSION "${LYX_RELEASE_LEVEL}-${tmp_REVISION_VERSION}git")
 439         set(ENABLE_DIST ON)
 440       endif()
 441     endif()
 442   endif()
 443 endif()
 444 if (LYX_PACKAGE_RELEASE MATCHES "UNDEFINED")
 445   set(LYX_PACKAGE_RELEASE  "1")
 446   if (LYX_RELEASE_PATCH GREATER 0)
 447     set(LYX_REVISION_VERSION "${LYX_RELEASE_LEVEL}.${LYX_RELEASE_PATCH}")
 448   endif()
 449 endif()
 450
 451 # Set the programs (lyx, tex2lyx, etc.) suffix
 452 # When building an OS X bundle, we will append
 453 # the suffix only to the bundle, not to the programs
 454 set(PROGRAM_SUFFIX "")
 455 if(LYX_PROGRAM_SUFFIX AND NOT (APPLE AND LYX_BUNDLE))
 456         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 457 endif()
 458 set(_lyx "${PACKAGE_BASE}${PROGRAM_SUFFIX}")
 459 set(_tex2lyx tex2lyx${PROGRAM_SUFFIX})
 460 set(_convert lyxconvert${PROGRAM_SUFFIX})
 461
 462 add_custom_target(lyx_version ALL
 463   COMMAND ${CMAKE_COMMAND} -DTOP_SRC_DIR=${TOP_SRC_DIR} -DTOP_CMAKE_PATH=${TOP_CMAKE_PATH} -DTOP_BINARY_DIR=${TOP_BINARY_DIR} -DLYX_DATE=${LYX_DATE} -P ${TOP_SCRIPT_PATH}/LyXGetVersion.cmake
 464   )
 465 set_target_properties(lyx_version PROPERTIES FOLDER "applications")
 466
 467 # Default paths for installed utilities (tex2lyx, lyxclient, etc.)
 468 set(LYX_UTILITIES_INSTALL_PATH bin)
 469
 470 if(LYX_BUNDLE)
 471         set(LYX_CPACK ON)
 472
 473         message(STATUS)
 474         message(STATUS "Bundle creation is enabled (experimental):")
 475         message(STATUS "    make")
 476         message(STATUS "    make install/strip")
 477         message(STATUS "    make package")
 478         if(APPLE)
 479                 set(MACOSX_BUNDLE TRUE)
 480                 # This sets the bundle + executable names
 481                 set(_lyx "${PACKAGE_BASE}${LYX_INSTALL_SUFFIX}")
 482                 # This sets the Info.plist executable name
 483                 set(osx_bundle_program_name ${_lyx})
 484                 # Bundle name
 485                 set(LYX_BUNDLE_NAME ${_lyx})
 486
 487                 # This will contain the list of files that need to be included
 488                 # in the bundle and their location within the bundle
 489                 set(OSX_BUNDLE_FILES "${TOP_SRC_DIR}/development/MacOSX/LyX.sdef;${TOP_SRC_DIR}/development/MacOSX/LyXapp.icns;${CMAKE_BINARY_DIR}/lyxrc.dist")
 490                 set(OSX_BUNDLE_DIRS "Resources;Resources;Resources")
 491
 492                 # Process Info.plist and lyxrc.dist
 493                 # See development/cmake/Install.cmake
 494                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/Info.plist.in" "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 495
 496                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 497                 set(LYX_DATA_SUBDIR ${LYX_BUNDLE_NAME}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 498
 499                 # Variables used by CPack
 500                 set(CPACK_BUNDLE_NAME ${LYX_BUNDLE_NAME})
 501                 set(CPACK_BUNDLE_PLIST "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 502                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${LYX_BUNDLE_NAME}.app)
 503
 504                 # Set the install paths
 505                 set(LYX_UTILITIES_INSTALL_PATH ${LYX_BUNDLE_NAME}.app/Contents/MacOS)
 506                 if(NOT LYX_INSTALL_PREFIX)
 507                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 508                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 509                 endif()
 510                 # Change the owner so that the install can work
 511                 install(CODE "set(BU_CHMOD_BUNDLE_ITEMS 1)" COMPONENT Runtime)
 512         elseif(UNIX)
 513                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 514                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 515                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 516         elseif(WIN32)
 517                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 518         endif()
 519 endif()
 520
 521 if(LYX_INSTALL_PREFIX)
 522         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 523         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 524 endif()
 525 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 526
 527 if(UNIX)
 528   set(SYSTEM_DATADIR "${CMAKE_INSTALL_PREFIX}/share")
 529 elseif(CMAKE_INSTALL_PREFIX MATCHES "/lyx${LYX_INSTALL_SUFFIX}$")
 530   string(REGEX REPLACE "/lyx${LYX_INSTALL_SUFFIX}$" "/share" SYSTEM_DATADIR ${CMAKE_INSTALL_PREFIX})
 531 else()
 532   set(SYSTEM_DATADIR "${CMAKE_INSTALL_PREFIX}")
 533 endif()
 534
 535 if(NOT CMAKE_COMPILER_IS_GNUCXX)
 536   # Not a GCC compiler, programs do not have a suffix
 537   set(suffixing ${LYX_PACKAGE_SUFFIX})
 538 elseif(WIN32 AND MINGW)
 539   # We want to use a suffix for the package in this case,
 540   # even if not for the program
 541   set(suffixing ${LYX_PACKAGE_SUFFIX})
 542 else()
 543   message(STATUS "CMAKE_COMPILER_IS_GNUCXX = ${CMAKE_COMPILER_IS_GNUCXX}")
 544   set(suffixing ${LYX_PROGRAM_SUFFIX})
 545 endif()
 546
 547 # The define PACKAGE below allows lyx-executable to find its default configuration files
 548 # see routines
 549 #    Package::messages_file()
 550 #    get_default_user_support_dir()
 551 #    relative_system_support_dir()
 552 # in src/support/Package.cpp
 553 if(suffixing)
 554         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 555 else()
 556         set(PACKAGE ${PACKAGE_BASE})
 557 endif()
 558
 559 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 560         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 561         if (UNIX)
 562                 # use the default "/usr/local"
 563                 # but respect the user-choice on the command-line
 564                 set(CMAKE_INSTALL_PREFIX "/usr/local" CACHE PATH "LyX default install prefix" FORCE)
 565         endif()
 566 endif()
 567 if(WIN32)
 568         set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 569 endif()
 570 if(IS_ABSOLUTE)
 571         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 572 else()
 573         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 574 endif()
 575
 576
 577
 578 if(NOT LYX_DATA_SUBDIR)
 579         if (WIN32)
 580                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 581         else()
 582                 set(LYX_DATA_SUBDIR "share/${_lyx}/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 583         endif()
 584 endif()
 585
 586 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}/${LYX_DATA_SUBDIR}")
 587 get_locale_destination(LYX_LOCALEDIR)
 588 set(LYX_ABS_INSTALLED_LOCALEDIR "${CMAKE_INSTALL_PREFIX}/${LYX_LOCALEDIR}")
 589 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 590
 591 if(LYX_BUNDLE AND APPLE)
 592         set(LYX_MAN_DIR_tmp "${LYX_DATA_SUBDIR}")
 593 else()
 594         if(WIN32)
 595                 set(LYX_MAN_DIR_tmp "${CMAKE_BINARY_DIR}/usr/local/man/")
 596         elseif(UNIX)
 597                 set(LYX_MAN_DIR_tmp "${CMAKE_INSTALL_PREFIX}/share/man/")
 598         else()
 599                 set(LYX_MAN_DIR_tmp "${CMAKE_INSTALL_PREFIX}/man/")
 600         endif()
 601 endif()
 602 if (NOT LYX_MAN_DIR_tmp EQUAL "${LYX_MAN_DIR}")
 603         unset(LYX_MAN_DIR CACHE)
 604         set(LYX_MAN_DIR "${LYX_MAN_DIR_tmp}" CACHE STRING "Install location for man pages.")
 605 endif()
 606 unset(LYX_MAN_DIR_tmp)
 607 mark_as_advanced(LYX_MAN_DIR)
 608
 609 # The Win installer cannot be built by CMake because one needs to install plugins for NSIS
 610 # see the Readme.txt of the installer
 611 #if(LYX_INSTALL AND WIN32)
 612 #       message(STATUS "Configuring NSIS files")
 613 #       configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 614 #       configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 615 #       configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 616 #       message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 617 #endif()
 618
 619 if(NOT GROUP_CODE)
 620         #set(GROUP_CODE "The Golden Code")
 621         set(GROUP_CODE flat)
 622 endif()
 623
 624 # lyx's source files
 625 set(LYX_CPP_FILES [a-zA-Z]*.cpp)
 626 set(LYX_HPP_FILES [a-zA-Z]*.h)
 627 set(LYX_MOC_FILES moc_*.cpp)
 628
 629 include(ProjectSourceGroup)
 630
 631
 632 if(LYX_PROFILE AND NOT MSVC)
 633         set(CMAKE_BUILD_TYPE Profile CACHE STRING "Profile build type" FORCE)
 634         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg")
 635         set(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS}  -pg")
 636 else()
 637         set(LYX_PROFILE OFF)
 638 endif()
 639
 640
 641 if(LYX_NO_OPTIMIZE)
 642         set(CMAKE_BUILD_TYPE None)
 643         set(LYX_DEBUG OFF)
 644         set(LYX_RELEASE OFF)
 645         set(LYX_PROFILE OFF)
 646 elseif(LYX_RELEASE)
 647         set(CMAKE_BUILD_TYPE Release)
 648         set(LYX_DEBUG OFF)
 649         set(LYX_PROFILE OFF)
 650 elseif(LYX_PROFILE)
 651         set(CMAKE_BUILD_TYPE Profile)
 652         set(LYX_DEBUG OFF)
 653 else()
 654         set(CMAKE_BUILD_TYPE Debug)
 655         set(LYX_DEBUG ON)
 656 endif()
 657
 658
 659 # When shared libs are supported enable this option
 660 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 661 if(LYX_SHARED_LIBRARIES)
 662         set(library_type SHARED)
 663 else()
 664         set(library_type STATIC)
 665 endif()
 666
 667 if(MSVC)
 668   if (CXX11_FLAG MATCHES "\\+\\+([0-9]+)")
 669     set(CMAKE_CXX_STANDARD ${CMAKE_MATCH_1})
 670     message(STATUS "CMAKE_CXX_STANDARD set to ${CMAKE_CXX_STANDARD}")
 671   endif()
 672 else()
 673         if(NOT LYX_QUIET)
 674                 set(CMAKE_VERBOSE_MAKEFILE ON)
 675         endif()
 676         set(LYX_CXX_FLAGS "-Wall -Wunused-parameter ${LYX_GCC11_MODE}")
 677         if(LYX_CXX_FLAGS MATCHES "\\+\\+(14|11|98)")
 678           # Thanks to Brad King <brad.king@kitware.com>
 679           # for the pointer to https://cmake.org/cmake/help/v3.6/variable/CMAKE_CXX_STANDARD.html
 680           # This allows us to use QT5.7 with recent g++ (version >= 4.9) compilers
 681           # and still use our own c++ extension tests
 682           set(CMAKE_CXX_STANDARD ${CMAKE_MATCH_1})
 683           message(STATUS "CMAKE_CXX_STANDARD set to ${CMAKE_CXX_STANDARD}")
 684         endif()
 685         if(LYX_STDLIB_DEBUG)
 686           set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 687         else()
 688           if(LYX_DEBUG_GLIBC)
 689             set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG")
 690           endif()
 691           if(LYX_DEBUG_GLIBC_PEDANTIC)
 692             set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG_PEDANTIC")
 693           endif()
 694         endif()
 695         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE STRING "Set CXX flags" FORCE)
 696         set(CMAKE_CXX_FLAGS_DEBUG "-O0 -g3 -D_DEBUG" CACHE STRING "Set debug flags" FORCE)
 697         if(MINGW)
 698                 set(CMAKE_CXX_FLAGS_RELEASE "-O2 -DNDEBUG" CACHE STRING "Set release flags for Mingw" FORCE)
 699         else()
 700                 set(CMAKE_CXX_FLAGS_RELEASE "-O3 -DNDEBUG" CACHE STRING "Set release flags" FORCE)
 701         endif()
 702 endif()
 703
 704 set(LYX_CXX_FLAGS_EXTRA "" CACHE STRING "Desired semicolon separated list of extra cxx compile flags, like '-Werror'")
 705 mark_as_advanced(LYX_CXX_FLAGS_EXTRA)
 706 if(LYX_CXX_FLAGS_EXTRA)
 707         foreach(_flag ${LYX_CXX_FLAGS_EXTRA})
 708                 add_definitions(${_flag})
 709         endforeach()
 710 endif()
 711
 712 if(LYX_XMINGW)
 713         list(APPEND CMAKE_FIND_ROOT_PATH ${GNUWIN32_DIR})
 714 endif()
 715
 716 set(min_qt5_version "5.6")
 717 if(LYX_USE_QT MATCHES "AUTO")
 718         # try qt5 first
 719         find_package(Qt5Core CONFIG QUIET)
 720         if(Qt5Core_FOUND)
 721                 set(LYX_USE_QT "QT5" CACHE STRING "Valid qt version" FORCE)
 722                 message(STATUS "Qt5Core_VERSION = ${Qt5Core_VERSION}")
 723                 if(Qt5Core_VERSION VERSION_LESS ${min_qt5_version})
 724                         find_package(Qt4 "4.5.0" QUIET)
 725                         if(QT4_FOUND)
 726                                 set(LYX_USE_QT "QT4" CACHE STRING "Valid qt version" FORCE)
 727                         endif()
 728                 endif()
 729         else()
 730                 set(LYX_USE_QT "QT4" CACHE STRING "Valid qt version" FORCE)
 731         endif()
 732 endif()
 733 if(LYX_USE_QT MATCHES "QT5")
 734         # set QPA_XCB if QT uses X11
 735         find_package(Qt5Core CONFIG REQUIRED)
 736         if (Qt5Core_FOUND)
 737                 find_package(Qt5Widgets CONFIG REQUIRED)
 738                 if(APPLE)
 739                         find_package(Qt5MacExtras CONFIG REQUIRED)
 740                 endif()
 741                 find_package(Qt5X11Extras CONFIG QUIET)
 742                 find_package(Qt5WinExtras CONFIG QUIET)
 743                 set(QTVERSION ${Qt5Core_VERSION})
 744                 if (QTVERSION VERSION_LESS ${min_qt5_version})
 745                         message(STATUS "QTVERSION = \"${QTVERSION}\"")
 746                         message(STATUS "This version is not recommended, try either option -DLYX_USE_QT=QT4 or")
 747                         message(STATUS "install QT-Version >= \"${min_qt5_version}\"")
 748                         # see thread in lyx-devel list
 749                         # From: Jean-Pierre Chrétien <jeanpierre.chretien@free.fr>
 750                         # Date 11.03.2017
 751                         # Subject: cmake compilation error
 752                         #message(FATAL_ERROR "Wrong Qt-Version")
 753                 endif()
 754                 macro (qt_use_modules lyxtarget)
 755                         foreach (_tg ${ARGN})
 756                                 find_package(Qt5${_tg} CONFIG REQUIRED)
 757                                 target_link_libraries(${lyxtarget} Qt5::${_tg})
 758                         endforeach()
 759                 endmacro()
 760                 macro (qt_add_resources)
 761                         qt5_add_resources(${ARGN})
 762                 endmacro()
 763                 macro (qt_wrap_uifiles)
 764                         qt5_wrap_ui(${ARGN})
 765                 endmacro()
 766                 message(STATUS "Found Qt-Version ${QTVERSION}")
 767                 if(WIN32)
 768                         set(LYX_QTMAIN_LIBRARY ${Qt5Core_QTMAIN_LIBRARIES})
 769                 endif()
 770         endif()
 771 elseif(LYX_USE_QT MATCHES "QT4")
 772         if(LYX_XMINGW)
 773                 set(QT_MINGW_DIR ${LYX_QT4} CACHE PATH "Qt for Mingw" FORCE)
 774                 list(APPEND CMAKE_FIND_ROOT_PATH ${QT_MINGW_DIR} ${GNUWIN32_DIR})
 775         endif()
 776         find_package(Qt4 "4.5.0" REQUIRED)
 777         macro (qt_use_modules)
 778         endmacro()
 779         macro (qt_add_resources)
 780                 qt4_add_resources(${ARGN})
 781         endmacro()
 782         macro (qt_wrap_uifiles)
 783                 qt4_wrap_ui(${ARGN})
 784         endmacro()
 785         set(LYX_QTMAIN_LIBRARY ${QT_QTSVG_LIBRARY})
 786         if(WIN32)
 787                 list(APPEND LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARIES})
 788         endif()
 789 else()
 790   message(FATAL_ERROR "Unhandled value for LYX_USE_QT (${LYX_USE_QT})")
 791 endif()
 792
 793 find_package(Magic)
 794 if(Magic_FOUND)
 795   set(HAVE_MAGIC_H 1)
 796   include_directories(${Magic_INCLUDE_DIR})
 797 endif()
 798
 799 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 800
 801 set(Spelling_FOUND OFF)
 802 set(Include_used_spellchecker)   # String will be inserted into config.h
 803
 804 if (LYX_EXTERNAL_MYTHES MATCHES "AUTO")
 805   # try system library first
 806   find_package(MyThesLIB)
 807   if (MYTHESLIB_FOUND)
 808     set(LYX_EXTERNAL_MYTHES ON CACHE STRING "OFF:= Build 3rdparty mytheslib" FORCE)
 809   else()
 810     set(LYX_EXTERNAL_MYTHES OFF CACHE STRING "OFF:= Build 3rdparty mytheslib" FORCE)
 811   endif()
 812 endif()
 813 if (LYX_EXTERNAL_MYTHES MATCHES "ON")
 814   find_package(MyThesLIB REQUIRED)
 815 else()
 816   add_subdirectory(3rdparty/mythes)
 817 endif()
 818 set(MYTHES_DIR ${MYTHESLIB_INCLUDE_DIR})
 819
 820 if(NOT LYX_EXTERNAL_HUNSPELL)
 821     add_subdirectory(3rdparty/hunspell)
 822     add_definitions(-DHUNSPELL_STATIC)
 823     set(HUNSPELL_FOUND ON)
 824     message(STATUS "  * Hunspell:")
 825     message(STATUS "     - include: ${HUNSPELL_INCLUDE_DIR}")
 826     message(STATUS "     - library: ${HUNSPELL_LIBRARY}")
 827 endif()
 828
 829 foreach(_spell "ASPELL" "ENCHANT" "HUNSPELL")
 830   string(TOUPPER ${_spell} _upspell)
 831   if (NOT ${_upspell}_FOUND)
 832     find_package(${_spell})
 833   endif()
 834   if (${_upspell}_FOUND)
 835     include_directories(${${_upspell}_INCLUDE_DIR})
 836     set(Spelling_FOUND ON)
 837     message(STATUS "Building with USE_${_upspell}")
 838     set(Include_used_spellchecker "${Include_used_spellchecker}#define USE_${_upspell} 1\n")
 839   else()
 840     if(LYX_${_upspell})
 841       message(FATAL_ERROR "Required ${_spell} devel package not found")
 842     else()
 843       message(STATUS "${_upspell} not found, building without ${_spell} support")
 844     endif()
 845   endif()
 846 endforeach()
 847
 848 if(GNUWIN32_DIR)
 849         list(APPEND CMAKE_PROGRAM_PATH "${GNUWIN32_DIR}/Python" )
 850 endif()
 851
 852 # Search for python default version first
 853 unset(PYTHON_EXECUTABLE CACHE)
 854 unset(LYX_PYTHON_EXECUTABLE CACHE)
 855 unset(PYTHON_VERSION_MAJOR)
 856 unset(PYTHON_VERSION_MINOR)
 857 unset(PYTHON_VERSION_STRING)
 858 if (CMAKE_VERSION VERSION_LESS "3.13")
 859   find_package(PythonInterp 3.5 QUIET)
 860   if(NOT PYTHONINTERP_FOUND)
 861     find_package(PythonInterp 2.0 REQUIRED)
 862     if(NOT PYTHON_VERSION_STRING VERSION_LESS 2.8)
 863       message(FATAL_ERROR "Python interpreter found, but is not suitable")
 864     endif()
 865   endif()
 866   set(LYX_PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 867 else()
 868   find_package(Python3 3.5 QUIET)
 869   if(NOT Python3_Interpreter_FOUND)
 870     unset(PYTHON_EXECUTABLE CACHE)
 871     find_package(Python2 2.0 REQUIRED)
 872     if(NOT Python2_VERSION VERSION_LESS 2.8)
 873       message(FATAL_ERROR "Python interpreter found, but is not suitable")
 874     endif()
 875     set(LYX_PYTHON_EXECUTABLE ${Python2_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 876   else()
 877     set(LYX_PYTHON_EXECUTABLE ${Python3_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 878   endif()
 879 endif()
 880
 881 if(LYX_NLS)
 882         find_package(LyXGettext)
 883         if(LYX_PYTHON_EXECUTABLE AND GETTEXT_FOUND)
 884                 add_subdirectory(po "${TOP_BINARY_DIR}/po")
 885         else()
 886                 # Install only supplied .gmo-files
 887                 file(GLOB _gmofiles RELATIVE "${TOP_SRC_DIR}/po" "${TOP_SRC_DIR}/po/*.gmo")
 888                 message(STATUS "Installing provided .gmo-files only")
 889                 foreach( _gmo ${_gmofiles})
 890                         string(REGEX REPLACE "\\.gmo$" "" _lang ${_gmo})
 891                         install(FILES "${TOP_SRC_DIR}/po/${_gmo}" DESTINATION ${LYX_LOCALEDIR}/${_lang}/LC_MESSAGES RENAME ${PACKAGE}.mo)
 892                 endforeach()
 893         endif()
 894 endif()
 895
 896 if(LYX_EXTERNAL_ICONV)
 897   find_package(ICONV REQUIRED)
 898 else()
 899   add_subdirectory(3rdparty/libiconv)
 900   set(HAVE_ICONV_CONST 1)
 901 endif()
 902
 903 if(LYX_EXTERNAL_Z)
 904   find_package(ZLIB REQUIRED)
 905 else()
 906   add_subdirectory(3rdparty/zlib)
 907 endif()
 908
 909 if(NOT LYX_EXTERNAL_DTL)
 910   add_subdirectory(3rdparty/dtl)
 911 endif()
 912
 913 if(LYX_USE_STD_REGEX)
 914   # Set only include path.
 915   # Use internal boost, which is known to exist
 916   # we don't need any libraries
 917   set(Lyx_Boost_Libraries)
 918   add_definitions(-DBOOST_USER_CONFIG=<config.h>)
 919   include_directories(${TOP_SRC_DIR}/3rdparty/boost)
 920 else()
 921   # Using boost-regex
 922   if(LYX_EXTERNAL_BOOST)
 923     message(STATUS "Searching for external boost")
 924     find_package(Boost COMPONENTS regex)
 925     if(Boost_FOUND)
 926       message(STATUS "Boost found")
 927       message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 928       set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 929       if (LYX_STDLIB_DEBUG)
 930         # Comment from  Jean-Marc Lasgouttes:
 931         # In general, system boost libraries are incompatible with
 932         # the use of stdlib-debug in libstdc++. See ticket #9736 for
 933         # details.
 934         message(WARNING "Compiling LyX with stdlib-debug and system boost libraries may lead to crashes. Consider using '-DLYX_STDLIB_DEBUG=OFF' or using '-DLYX_EXTERNAL_BOOST=OFF'")
 935       endif()
 936     else()
 937       message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 938     endif()
 939   else()
 940     # Using included boost
 941     set(Lyx_Boost_Libraries boost_regex)
 942     add_definitions(-DBOOST_USER_CONFIG=<config.h>)
 943     include_directories(${TOP_SRC_DIR}/3rdparty/boost)
 944     add_subdirectory(3rdparty/boost "${TOP_BINARY_DIR}/3rdparty/boost")
 945   endif()
 946 endif()
 947
 948 if(WIN32)
 949         if(LYX_CONSOLE)
 950                 set(LYX_QTMAIN_LIBRARY)
 951         else()
 952                 set(WIN32_CONSOLE WIN32)
 953         endif()
 954         if(MSVC)
 955                 # -DPSAPI_VERSION=1 is needed to run on vista (bug 10186)
 956                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX -DPSAPI_VERSION=1)
 957                 # disable checked iterators for msvc release builds to get maximum speed
 958                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 959         else()
 960                 # -DPSAPI_VERSION=1 is not needed for mingw, since the mingw psapi.h
 961                 # does not use it and always declares the vista compatible API.
 962                 # If this ever changes then -DPSAPI_VERSION might be needed here as well.
 963                 add_definitions(-DWINVER=0x0500)
 964         endif()
 965 endif()
 966
 967 # Compute qt-version from ${QTVERSION}
 968
 969 message(STATUS "")
 970 foreach(_v PACKAGE PACKAGE_VERSION
 971         PROGRAM_SUFFIX LYX_VERSION LYX_DIR_VER LYX_USERDIR_VER
 972         LYX_ABS_TOP_SRCDIR
 973         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 974         if(NOT DEFINED ${_v})
 975                 message(FATAL_ERROR "${_v} not defined")
 976         endif()
 977         string(SUBSTRING "${_v}                            " 0 28 _v1)
 978         message(STATUS "----- ${_v1}: ${${_v}}")
 979 endforeach(_v)
 980 message(STATUS "")
 981
 982
 983 if(LYX_PCH)
 984         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 985         # Not sure if it works for all non-msvc compilers
 986         include(PCHSupport_26)
 987         configure_file(${TOP_CMAKE_PATH}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
 988         configure_file(${TOP_CMAKE_PATH}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 989         add_definitions(-DLYX_ENABLE_PCH)
 990
 991         if(MSVC)
 992                 macro(lyx_add_msvc_pch name_)
 993                         set_source_files_properties(${${name_}_sources} PROPERTIES
 994                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 995                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
 996                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 997                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
 998                                 ${TOP_BINARY_DIR}/pcheaders.h)
 999                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
1000                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
1001                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
1002                 endmacro(lyx_add_msvc_pch)
1003                 macro(lyx_add_gcc_pch name_)
1004                 endmacro()
1005         else()
1006                 macro(lyx_add_msvc_pch name_)
1007                 endmacro()
1008                 macro(lyx_add_gcc_pch name_)
1009                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT)
1010                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
1011                 endmacro()
1012         endif()
1013 else()
1014         macro(lyx_add_msvc_pch)
1015         endmacro(lyx_add_msvc_pch)
1016         macro(lyx_add_gcc_pch name_)
1017         endmacro()
1018 endif()
1019
1020
1021 if(MSVC)
1022
1023         if(LYX_VLD)
1024                 set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/development/Win32/vld)
1025                 add_subdirectory(${vld_path}/cmake)
1026                 include(${vld_path}/cmake/vld.cmake) # forced include
1027                 set(vld_dll vld)
1028         endif()
1029
1030         if(LYX_WALL)
1031                 # Use the highest warning level
1032                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE STRING "Warning level" FORCE)
1033
1034                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
1035                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
1036                 else()
1037                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
1038                 endif()
1039
1040                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
1041                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
1042                 else()
1043                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
1044                 endif()
1045
1046                 # add here warnings which should produce an error /weXXXX
1047                 set(MSVC_W_ERROR   "/we4101 /we4189")
1048                 # add here warnings which should be disabled /wdXXXX
1049                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
1050
1051                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1052                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1053                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1054
1055         else()
1056                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE STRING "Warning level" FORCE)
1057
1058                 # add here warnings which should produce an error /weXXXX
1059                 set(MSVC_W_ERROR   "/we4101 /we4189")
1060                 # add here warnings which should be disabled /wdXXXX
1061                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
1062
1063                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1064                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1065                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1066
1067         endif()
1068
1069         if (NOT Qt5Core_FOUND)
1070                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
1071                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
1072                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
1073         endif()
1074
1075         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
1076         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
1077         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
1078         message(STATUS "")
1079 endif()
1080
1081
1082 # Xcode compiler
1083 if (CMAKE_GENERATOR MATCHES Xcode)
1084         if (XCODE_VERSION VERSION_LESS "5.0")
1085                 # Automatically select the Xcode compiler if not set
1086                 if (NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
1087                         # XCode >= 3.1 has gcc 4.2 (up to actual Xcode)
1088                         if (XCODE_VERSION VERSION_GREATER "3.1")
1089                                 SET(CMAKE_XCODE_ATTRIBUTE_GCC_VERSION "com.apple.compilers.llvmgcc42")
1090                         ENDIF(XCODE_VERSION VERSION_GREATER "3.1")
1091                 ENDIF(NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
1092                 # Print the selected compiler version
1093         MESSAGE(STATUS "---- Using XCode compiler CMAKE_XCODE_ATTRIBUTE_GCC_VERSION=${CMAKE_XCODE_ATTRIBUTE_GCC_VERSION}")
1094         ENDIF(XCODE_VERSION VERSION_LESS "5.0")
1095 ENDIF(CMAKE_GENERATOR MATCHES Xcode)
1096
1097 if (WIN32 AND Qt5Core_FOUND)
1098         set(Z_PREFIX 1)
1099 endif()
1100
1101 # compiler tests, config.h generation LYX_CONFIGURE_CHECKS
1102 include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
1103 configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
1104
1105 unset(opts)
1106 foreach(_option ${LYX_OPTIONS})
1107   if(${_option}_show_message)
1108     string(SUBSTRING "${_option}                            " 0 31 _var)
1109     get_property(_prop CACHE ${_option} PROPERTY STRINGS)
1110     list(FIND LYX_OPTION_STRINGS ${_option} _index)
1111     if (${_index} GREATER -1)
1112       set(_isset ${${_option}})
1113     elseif(${_option})
1114       set(_isset ON)
1115     else()
1116       set(_isset OFF)
1117     endif()
1118     string(SUBSTRING "${_isset}           " 0 10 _val)
1119     set(opts "${opts} ${_option}(${${_option}})")
1120   endif()
1121 endforeach()
1122 set(tmp_vi "CMake Build")
1123 list(APPEND tmp_vi "  Host name:               ${CMAKE_HOST_SYSTEM_NAME}")
1124 list(APPEND tmp_vi "  Host processor:          ${CMAKE_HOST_SYSTEM_PROCESSOR}")
1125 list(APPEND tmp_vi "  Build flags:             ${opts}")
1126 list(APPEND tmp_vi "  C++ Compiler:            ${CMAKE_CXX_COMPILER_ID} (${CMAKE_CXX_COMPILER_VERSION})")
1127 list(APPEND tmp_vi "  C++ Compiler flags:      ${CMAKE_CXX_FLAGS}")
1128 if (LYX_DEBUG)
1129 list(APPEND tmp_vi "  C++ Compiler user flags: ${CMAKE_CXX_FLAGS_DEBUG}")
1130 else()
1131 list(APPEND tmp_vi "  C++ Compiler user flags: ${CMAKE_CXX_FLAGS_RELEASE}")
1132 endif()
1133 list(APPEND tmp_vi "  Qt version:              ${QTVERSION}")
1134 list(APPEND tmp_vi "  LyX binary dir:          ${CMAKE_INSTALL_PREFIX}/${LYX_UTILITIES_INSTALL_PATH}")
1135 get_data_destination(dest_data)
1136 list(APPEND tmp_vi "  LyX files dir:           ${CMAKE_INSTALL_PREFIX}/${dest_data}")
1137 string(REPLACE ";" "\\n" VERSION_INFO "${tmp_vi}")
1138
1139 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
1140 unset(opts)
1141 unset(tmp_vi)
1142
1143 if(QTVERSION MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+).*")
1144         MATH(EXPR QT4_VERSION "(${CMAKE_MATCH_1}<<16)|(${CMAKE_MATCH_2}<<8)|${CMAKE_MATCH_3}")
1145 endif()
1146
1147 if (NOT HAVE_REGEX)
1148         set(LYX_USE_STD_REGEX 0)
1149 endif()
1150
1151
1152 set (cmd ${CMAKE_CTEST_COMMAND})
1153 if (MSVC)
1154         set (cmd ${cmd} -C ${CMAKE_CFG_INTDIR})
1155 else ()
1156         set (cmd ${cmd} -C ${CMAKE_BUILD_TYPE})
1157 endif ()
1158 add_custom_target (lyx_run_tests COMMAND ${cmd})
1159 set_target_properties(lyx_run_tests PROPERTIES FOLDER "tests")
1160
1161 if(LYX_ASAN)
1162     set(LYX_CXX_FLAGS "-fsanitize=address -fno-omit-frame-pointer -g")
1163     message(STATUS)
1164     message(STATUS "Address sanitizer enabled. Usage:")
1165     message(STATUS "    wget https://llvm.org/svn/llvm-project/compiler-rt/trunk/lib/asan/scripts/asan_symbolize.py")
1166     message(STATUS "    chmod  +x ./asan_symbolize.py")
1167     message(STATUS "    ./bin/lyx2.2 2>&1 | ./asan_symbolize.py  | c++filt ")
1168     message(STATUS)
1169 endif()
1170
1171 if(LYX_INSTALL)
1172         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
1173                 message(STATUS "Python required to create doc!")
1174         else()
1175                 if(UNIX)
1176                         add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
1177                 endif()
1178                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
1179         endif()
1180 endif()
1181 include(../Install)
1182
1183 # By running the URL tests first, time can be saved when running the ctests in
1184 # parallel since the URL tests take a long time to run (e.g. 10 minutes).
1185 if(LYX_ENABLE_URLTESTS)
1186         add_subdirectory(development/checkurls "${TOP_BINARY_DIR}/checkurls")
1187 endif()
1188 add_subdirectory(src "${TOP_BINARY_DIR}/src")
1189 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
1190 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
1191 add_subdirectory(lib/examples "${TOP_BINARY_DIR}/lib/examples")
1192 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
1193 add_subdirectory(development/autotests "${TOP_BINARY_DIR}/autotests")
1194 add_subdirectory(development/batchtests "${TOP_BINARY_DIR}/batchtests")
1195
1196 message(STATUS)
1197 message(STATUS "Build params, switch LYX_* options by -DLYX_*=ON or OFF, LYX_* combos by -DLYX_*=value:")
1198 message(STATUS)
1199
1200 LYX_OPTION_LIST_ALL(used)
1201
1202
1203 if(LYX_NLS)
1204         message(STATUS)
1205         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
1206         message(STATUS)
1207         message(STATUS "  * iconv")
1208         message(STATUS "     - include: ${ICONV_INCLUDE_DIR}")
1209         message(STATUS "     - library: ${ICONV_LIBRARY}")
1210         message(STATUS "  * zlib")
1211         message(STATUS "     - include: ${ZLIB_INCLUDE_DIR}")
1212         message(STATUS "     - library: ${ZLIB_LIBRARY}")
1213         message(STATUS)
1214 endif()
1215
1216 # Apple has builtin native spell checker,
1217 # no need to warn for missing Aspell, Hunspell or Enchant
1218 if(NOT Spelling_FOUND AND NOT APPLE)
1219   if(LYX_REQUIRE_SPELLCHECK)
1220     set(_mode "FATAL_ERROR")
1221   else()
1222     set(_mode "STATUS")
1223   endif()
1224   message(${_mode} "No spellcheck libraries found. LyX will be unable use spellchecking")
1225 endif()
1226
1227 include("${TOP_CMAKE_PATH}/LyxPackaging.cmake")
1228
1229 if(ENABLE_DIST)
1230   # Use git to create the source package
1231   # git archive --format=tgz --output=/home/kornel/x.tar.gz master
1232   if(UNIX)
1233     set(DIST_FORMAT tgz)
1234   else()
1235     set(DIST_FORMAT zip)
1236   endif()
1237   set(DIST_NAME ${CMAKE_PROJECT_NAME}-${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}-${CMAKE_SYSTEM_NAME}.${DIST_FORMAT})
1238
1239   add_custom_command(
1240     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME}
1241     COMMAND  ${LYX_GITVERSION} archive --format=${DIST_FORMAT} --output=${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME} master
1242     WORKING_DIRECTORY ${TOP_SRC_DIR})
1243   add_custom_target(git-archive DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME})
1244 endif()
1245
1246 # Last directory to be included so that the fixup code (OS X)
1247 # can be run last
1248 add_subdirectory(development/cmake/post_install)
1249
1250 message(STATUS)