CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 2.6.4)
   8
   9 set(LYX_PROJECT LyX)
  10
  11 enable_testing()
  12
  13 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README ABSOLUTE)
  14 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  15
  16 set(LYX_CMAKE_DIR "development/cmake")
  17 set(TOP_CMAKE_PATH "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}")
  18 set(TOP_MODULE_PATH "${TOP_CMAKE_PATH}/modules")
  19 set(TOP_SCRIPT_PATH "${TOP_CMAKE_PATH}/scripts")
  20
  21 set(CMAKE_MODULE_PATH "${TOP_MODULE_PATH}")
  22
  23 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  24
  25 message(STATUS)
  26 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  27         message(STATUS "Building in-source")
  28         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  29 else()
  30         message(STATUS "Building out-of-source")
  31         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  32 endif()
  33
  34 # This directory should be used if some test uses lyx-executable
  35 set(LYX_TESTS_USERDIR "${TOP_BINARY_DIR}/Testing/.lyx")
  36 file(MAKE_DIRECTORY "${LYX_TESTS_USERDIR}")
  37
  38 if(COMMAND cmake_policy)
  39         cmake_policy(SET CMP0003 OLD)
  40         cmake_policy(SET CMP0005 OLD)
  41         # Installing MACOSX_BUNDLE targets requires a BUNDLE DESTINATION
  42         cmake_policy(SET CMP0006 NEW)
  43         if(POLICY CMP0020)
  44                 cmake_policy(SET CMP0020 OLD)
  45         endif()
  46         if(POLICY CMP0028)
  47                 cmake_policy(SET CMP0028 OLD)
  48         endif()
  49         if(POLICY CMP0043)
  50                 # COMPILE_DEFINITIONS are not used yet. Enable new behavior.
  51                 cmake_policy(SET CMP0043 NEW)
  52         endif()
  53 endif()
  54
  55 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  56
  57 # Supress regeneration
  58 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  59
  60 if(LYX_XMINGW)
  61     set(CMAKE_SYSTEM_NAME Windows)
  62     set(TOOLNAME ${LYX_XMINGW})
  63     set(TOOLCHAIN "${TOOLNAME}-")
  64     set(CMAKE_C_COMPILER   "${TOOLCHAIN}gcc"     CACHE PATH "Mingw C compiler" FORCE)
  65     set(CMAKE_CXX_COMPILER "${TOOLCHAIN}g++"     CACHE PATH "Mingw C++ compiler" FORCE)
  66     set(CMAKE_RC_COMPILER  "${TOOLCHAIN}windres" CACHE PATH "Mingw rc compiler" FORCE)
  67
  68     set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM BOTH)
  69     set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY)
  70     set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY)
  71 endif()
  72
  73 if(NOT help AND NOT HELP)
  74   # 'project' triggers the searching for a compiler
  75   project(${LYX_PROJECT})
  76   if (CMAKE_COMPILER_IS_GNUCXX)
  77     if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS "4.0")
  78       message(STATUS "Gnu CXX compiler version = ${CMAKE_CXX_COMPILER_VERSION}")
  79       message(STATUS "is too old, should be >= 4.0")
  80       message(FATAL_ERROR "Exiting")
  81     endif()
  82   endif()
  83 endif()
  84
  85 if(UNIX)
  86         set(ARCH_TRIPLET )
  87         FIND_PROGRAM(DPKG_ARCHITECTURE_EXECUTABLE dpkg-architecture)
  88         if(DPKG_ARCHITECTURE_EXECUTABLE)
  89                 EXECUTE_PROCESS(COMMAND ${DPKG_ARCHITECTURE_EXECUTABLE} -qDEB_HOST_MULTIARCH
  90                                 OUTPUT_VARIABLE ARCH_TRIPLET
  91                                 ERROR_VARIABLE ERROR_ARCH_TRIPLET
  92                                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  93         endif()
  94 endif()
  95 if(ARCH_TRIPLET)
  96         set(SYSTEM_LIB_DIRS /usr/lib /usr/lib/${ARCH_TRIPLET} /usr/local/lib)
  97 else()
  98         set(SYSTEM_LIB_DIRS /usr/lib /usr/local/lib)
  99 endif()
 100
 101 include(LyXMacros)
 102
 103 # Usage LYX_OPTION
 104 # 1. parameter: option name without prefix 'LYX_'
 105 # 2. parameter: description
 106 # 3. parameter: default value, ON or OFF
 107 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
 108
 109 # Usage LYX_COMBO
 110 # 1. parameter: name without prefix 'LYX_'
 111 # 2. parameter: description
 112 # 3. parameter: default value
 113 # 4-n parameter: possible other string values
 114
 115 LYX_OPTION_INIT()
 116
 117 # Options for all compilers/systems
 118 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
 119 LYX_OPTION(LOCALVERSIONING  "Add version info to created package name (only used if LYX_CPACK option set)" OFF ALL)
 120 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
 121 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
 122 LYX_OPTION(REQUIRE_SPELLCHECK "Abort if no spellchecker available" OFF ALL)
 123 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
 124 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
 125 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
 126 LYX_OPTION(DEVEL_VERSION    "Build developer version" OFF ALL)
 127 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" OFF ALL)
 128 LYX_OPTION(DEBUG            "Enforce debug build"  OFF ALL)
 129 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
 130 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
 131 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
 132 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
 133 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
 134 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
 135 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
 136 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
 137 LYX_OPTION(ENABLE_URLTESTS  "Enable for URL tests" OFF ALL)
 138 LYX_OPTION(ENABLE_EXPORT_TESTS "Enable for export tests" OFF ALL)
 139 LYX_OPTION(ASAN             "Use address sanitizer" OFF ALL)
 140 LYX_COMBO(USE_QT            "Use Qt version as frontend" QT4 QT5)
 141
 142 # GCC specific
 143 LYX_OPTION(PROFILE              "Build profile version" OFF GCC)
 144 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" OFF GCC)
 145 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
 146 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
 147 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++ pedantic debug mode" OFF GCC)
 148 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" OFF GCC)
 149 LYX_OPTION(PROFILE              "Build with options for gprof" OFF GCC)
 150 LYX_OPTION(ENABLE_CXX11         "Build with options for c++11-mode" OFF GCC)
 151
 152 # MSVC specific
 153 LYX_OPTION(CONSOLE               "Show console on Windows, enforce with =FORCE" ON MSVC)
 154 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
 155 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
 156 LYX_OPTION(CONFIGURE_CHECKS      "Also run configure checks for MSVC" OFF MSVC)
 157 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
 158
 159 # APPLE specific
 160 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
 161 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
 162
 163
 164 if(help OR HELP)
 165         message(STATUS)
 166         message(STATUS "Available options: (dis/enable with -DLYX_*=OFF/ON)")
 167         message(STATUS)
 168         LYX_OPTION_LIST_ALL(help)
 169         message(STATUS)
 170         RETURN()
 171 endif()
 172
 173 # Check option dependencies
 174
 175 if(LYX_DMG)
 176         set(LYX_BUNDLE ON)
 177         set(LYX_CPACK ON)
 178 endif()
 179
 180 if(LYX_CPACK)
 181         set(LYX_INSTALL ON)
 182 endif()
 183
 184 if(LYX_INSTALL)
 185         set(LYX_NLS ON)
 186         if(WIN32 AND NOT MINGW)
 187                 set(LYX_HUNSPELL ON)
 188         endif()
 189         if(LYX_CONSOLE MATCHES "FORCE")
 190                 set(LYX_CONSOLE ON)
 191         else()
 192                 set(LYX_CONSOLE OFF)
 193         endif()
 194         set(LYX_PACKAGE_SUFFIX ON)
 195         if(NOT LYX_DEBUG)
 196                 set(LYX_RELEASE ON)
 197         endif()
 198         set(LYX_PROFILE OFF)
 199 endif()
 200
 201
 202 if(LYX_MERGE_FILES)
 203         set(LYX_PCH OFF)
 204 else()
 205         set(LYX_MERGE_REBUILD OFF)
 206 endif()
 207
 208
 209 if(LYX_DEPENDENCIES_DOWNLOAD)
 210         message(STATUS)
 211     if(MSVC12)
 212         set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2013-deps)
 213         set(deps_files lyx-windows-deps-msvc2013.zip)
 214         set(deps_server http://ftp.lyx.de/LyX-Windows-Deps)
 215         set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2013)
 216     else()
 217         set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 218             set(deps_files lyx20-deps-msvc2010-x86.zip)
 219             set(deps_server http://downloads.sourceforge.net/project/lyx/Win_installers/Dependencies)
 220         set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/deps20)
 221     endif()
 222     message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 223         foreach(it ${deps_files})
 224                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 225                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 226                 if(NOT already_downloaded)
 227                         message(STATUS "Downloading ${it} ...")
 228                         file(DOWNLOAD ${deps_server}/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS STATUS status LOG log)
 229                         list(GET status 0 status_code)
 230                         list(GET status 1 status_string)
 231                         if(NOT status_code EQUAL 0)
 232                                 file(REMOVE ${LYX_DEPENDENCIES_DIR}/${it})
 233                                 message(FATAL_ERROR "error: downloading '${it}' failed. status_code: ${status_code}, status_string: ${status_string}. \nLog: ${log} ")
 234                         endif()
 235                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 236                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 237                 endif()
 238         endforeach()
 239 endif()
 240
 241
 242
 243 message(STATUS)
 244
 245 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 246 if(WIN32)
 247         set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 248 else()
 249         set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 250 endif()
 251
 252
 253 set(LYX_GCC11_MODE)
 254 if(UNIX OR MINGW)
 255         execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION OUTPUT_STRIP_TRAILING_WHITESPACE)
 256         message(STATUS "Using GCC version ${GCC_VERSION}")
 257         if(GCC_VERSION VERSION_LESS 4.9)
 258                 # <regex> in gcc is unusable in versions less than 4.9.0
 259                 # see https://gcc.gnu.org/bugzilla/show_bug.cgi?id=53631
 260                 set(LYX_USE_STD_REGEX 0)
 261         else()
 262                 if (LYX_ENABLE_CXX11)
 263                         set(LYX_USE_STD_REGEX 1)
 264                 endif()
 265         endif()
 266         if (LYX_ENABLE_CXX11)
 267                 find_package(CXX11Compiler)
 268                 if(NOT CXX11COMPILER_FOUND)
 269                         message(FATAL_ERROR "A C++11 compatible compiler is required.")
 270                 endif()
 271                 set(LYX_GCC11_MODE "${CXX11_FLAG}")
 272         endif()
 273 else()
 274         set(LYX_USE_STD_REGEX 0)
 275 #       if(MSVC10)
 276 #               set(LYX_USE_STD_REGEX 1) #TODO should we use it in ECMAScript mode?
 277 #       endif()
 278 endif()
 279
 280
 281 set(VERSION_INFO "CMake Build")
 282
 283 # Try to get some informations from configure.ac
 284
 285 include(LyXPaths)
 286 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 287
 288 if(WIN32)
 289         set(USE_WINDOWS_PACKAGING ON)
 290 elseif(APPLE)
 291         set(USE_MACOSX_PACKAGING ON)
 292 else()
 293         set(USE_POSIX_PACKAGING ON)
 294 endif()
 295
 296 macro(setstripped _varname)
 297         if(${ARGC} GREATER 1)
 298                 string(STRIP "${ARGV1}" _v)
 299                 if(USE_POSIX_PACKAGING)
 300                         string(TOLOWER ${_v} ${_varname})
 301                 else()
 302                         set(${_varname} ${_v})
 303                 endif()
 304         else()
 305                 set(${_varname})
 306         endif()
 307 endmacro(setstripped)
 308
 309 foreach(_c_l ${_config_lines} )
 310         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 311                 setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 312                 setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 313                 setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 314                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\)\(\\.\([0-9]+\)\)?.*$")
 315                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 316                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 317                         set(LYX_PATCH_VERSION ${CMAKE_MATCH_4})
 318                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 319                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 320                         set(LYX_INSTALL_SUFFIX "${CMAKE_MATCH_1}.${CMAKE_MATCH_2}")
 321                 endif()
 322         endif()
 323         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 324                 set(LYX_DATE "${CMAKE_MATCH_1}")
 325         endif()
 326 endforeach(_c_l)
 327
 328 FIND_PROGRAM(LYX_GITVERSION git)
 329 #message(STATUS "gitversion = ${LYX_GITVERSION}")
 330 set(LYX_REVISION_VERSION ${LYX_PATCH_VERSION})
 331 if(LYX_GITVERSION)
 332   if (LYX_LOCALVERSIONING)
 333     # Find the revision number and for later use
 334     EXECUTE_PROCESS(COMMAND ${LYX_GITVERSION} describe --match 2.0.0 HEAD
 335       WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE LYX_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 336     if (LYX_PACKAGE_RELEASE MATCHES "^2\\.0\\.0\\-\([0-9]+\)\\-.*$")
 337       # We will add offset of 40000 to get appropriate value to
 338       # previous svn.
 339       # We use this value than also to set the package-patch-value
 340       MATH(EXPR tmp_REVISION_VERSION "(${CMAKE_MATCH_1}+40000)")
 341       set(LYX_REVISION_VERSION "${LYX_PATCH_VERSION}-${tmp_REVISION_VERSION}git")
 342       set(ENABLE_DIST ON)
 343     endif()
 344   endif()
 345 endif()
 346
 347 # Set the programs (lyx, tex2lyx, etc.) suffix
 348 # When building an OS X bundle, we will append
 349 # the suffix only to the bundle, not to the programs
 350 set(PROGRAM_SUFFIX "")
 351 if(LYX_PROGRAM_SUFFIX AND NOT (APPLE AND LYX_BUNDLE))
 352         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 353 endif()
 354 set(_lyx "${PACKAGE_BASE}${PROGRAM_SUFFIX}")
 355 set(_tex2lyx tex2lyx${PROGRAM_SUFFIX})
 356
 357 add_custom_target(lyx_version ALL
 358   COMMAND ${CMAKE_COMMAND} -DTOP_SRC_DIR=${TOP_SRC_DIR} -DTOP_CMAKE_PATH=${TOP_CMAKE_PATH} -DTOP_BINARY_DIR=${TOP_BINARY_DIR} -DLYX_DATE=${LYX_DATE} -P ${TOP_SCRIPT_PATH}/LyXGetVersion.cmake
 359   )
 360 set_target_properties(lyx_version PROPERTIES FOLDER "applications")
 361
 362 # Default paths for installed utilities (tex2lyx, lyxclient, etc.)
 363 set(LYX_UTILITIES_INSTALL_PATH bin)
 364
 365 if(LYX_BUNDLE)
 366         set(LYX_CPACK ON)
 367
 368         message(STATUS)
 369         message(STATUS "Bundle creation is enabled (experimental):")
 370         message(STATUS "    make")
 371         message(STATUS "    make install/strip")
 372         message(STATUS "    make package")
 373         if(APPLE)
 374                 set(MACOSX_BUNDLE TRUE)
 375                 # This sets the bundle + executable names
 376                 set(_lyx "${PACKAGE_BASE}${LYX_INSTALL_SUFFIX}")
 377                 # This sets the Info.plist executable name
 378                 set(osx_bundle_program_name ${_lyx})
 379                 # Bundle name
 380                 set(LYX_BUNDLE_NAME ${_lyx})
 381
 382                 # This will contain the list of files that need to be included
 383                 # in the bundle and their location within the bundle
 384                 set(OSX_BUNDLE_FILES "${TOP_SRC_DIR}/development/MacOSX/LyX.sdef;${TOP_SRC_DIR}/development/MacOSX/LyXapp.icns;${CMAKE_BINARY_DIR}/lyxrc.dist")
 385                 set(OSX_BUNDLE_DIRS "Resources;Resources;Resources")
 386
 387                 # Process Info.plist and lyxrc.dist
 388                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/Info.plist.in" "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 389                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/lyxrc.dist.in" "${CMAKE_CURRENT_BINARY_DIR}/lyxrc.dist")
 390
 391                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 392                 set(LYX_DATA_SUBDIR ${LYX_BUNDLE_NAME}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 393
 394                 # Variables used by CPack
 395                 set(CPACK_BUNDLE_NAME ${LYX_BUNDLE_NAME})
 396                 set(CPACK_BUNDLE_PLIST "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 397                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${LYX_BUNDLE_NAME}.app)
 398
 399                 # Set the install paths
 400                 set(LYX_UTILITIES_INSTALL_PATH ${LYX_BUNDLE_NAME}.app/Contents/MacOS)
 401                 if(NOT LYX_INSTALL_PREFIX)
 402                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 403                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 404                 endif()
 405                 # Change the owner so that the install can work
 406                 install(CODE "set(BU_CHMOD_BUNDLE_ITEMS 1)" COMPONENT Runtime)
 407         elseif(UNIX)
 408                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 409                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 410                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 411         elseif(WIN32)
 412                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 413         endif()
 414 endif()
 415
 416 if(LYX_INSTALL_PREFIX)
 417         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 418         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 419 endif()
 420 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 421
 422 string(REGEX REPLACE "/lyx${LYX_INSTALL_SUFFIX}$" "/share" SYSTEM_DATADIR ${CMAKE_INSTALL_PREFIX})
 423
 424 if(LYX_PACKAGE_SUFFIX)
 425         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 426 else()
 427         set(PACKAGE ${PACKAGE_BASE})
 428 endif()
 429
 430 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 431         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 432         if (UNIX)
 433                 # don't use the default "/usr/local"
 434                 # but respect the user-choice on the command-line
 435                 if(LYX_INSTALL_SUFFIX)
 436                         set(CMAKE_INSTALL_PREFIX "/usr/local/lyx${LYX_INSTALL_SUFFIX}" CACHE PATH "LyX default install prefix" FORCE)
 437                 else()
 438                         set(CMAKE_INSTALL_PREFIX "/usr/local/${LYX_PROJECT}" CACHE PATH "LyX default install prefix" FORCE)
 439                 endif()
 440         endif()
 441         if(WIN32)
 442                 set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 443         endif()
 444 endif()
 445 if(IS_ABSOLUTE)
 446         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 447 else()
 448         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 449 endif()
 450
 451
 452
 453 if(NOT LYX_DATA_SUBDIR)
 454         if (WIN32)
 455                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 456         else()
 457                 set(LYX_DATA_SUBDIR "" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 458         endif()
 459 endif()
 460
 461 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 462 set(LYX_LOCALEDIR "locale")
 463 set(LYX_ABS_INSTALLED_LOCALEDIR "${LYX_ABS_INSTALLED_DATADIR}/${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}")
 464 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 465
 466 if(LYX_BUNDLE AND APPLE)
 467         set(LYX_MAN_DIR "${LYX_DATA_SUBDIR}" CACHE STRING "Install location for man pages.")
 468 else()
 469         set(LYX_MAN_DIR "/usr/local/man/man1" CACHE STRING "Install location for man pages.")
 470 endif()
 471 mark_as_advanced(LYX_MAN_DIR)
 472
 473 if(LYX_INSTALL AND WIN32)
 474         message(STATUS "Configuring NSIS files")
 475         configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 476         configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 477         configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 478         message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 479 endif()
 480
 481 if(NOT GROUP_CODE)
 482         #set(GROUP_CODE "The Golden Code")
 483         set(GROUP_CODE flat)
 484 endif()
 485
 486 # lyx's source files
 487 set(LYX_CPP_FILES [a-zA-Z]*.cpp)
 488 set(LYX_HPP_FILES [a-zA-Z]*.h)
 489 set(LYX_MOC_FILES moc_*.cpp)
 490
 491 include(ProjectSourceGroup)
 492
 493
 494 if(LYX_PROFILE AND NOT MSVC)
 495         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 496         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg")
 497         set(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS}  -pg")
 498 else()
 499         set(LYX_PROFILE OFF)
 500 endif()
 501
 502
 503 if(LYX_NO_OPTIMIZE)
 504         set(CMAKE_BUILD_TYPE None)
 505         set(LYX_DEBUG OFF)
 506         set(LYX_RELEASE OFF)
 507         set(LYX_PROFILE OFF)
 508 elseif(LYX_RELEASE)
 509         set(CMAKE_BUILD_TYPE Release)
 510         set(LYX_DEBUG OFF)
 511         set(LYX_PROFILE OFF)
 512 elseif(LYX_PROFILE)
 513         set(CMAKE_BUILD_TYPE Profile)
 514         set(LYX_DEBUG OFF)
 515 else()
 516         set(CMAKE_BUILD_TYPE Debug)
 517         set(LYX_DEBUG ON)
 518 endif()
 519
 520
 521 # When shared libs are supported enable this option
 522 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 523 if(LYX_SHARED_LIBRARIES)
 524         set(library_type SHARED)
 525 else()
 526         set(library_type STATIC)
 527 endif()
 528
 529 if(NOT MSVC)
 530         if(NOT LYX_QUIET)
 531                 set(CMAKE_VERBOSE_MAKEFILE ON)
 532         endif()
 533     set(LYX_CXX_FLAGS "-Wall -Wunused-parameter ${LYX_GCC11_MODE}")
 534         if(LYX_STDLIB_DEBUG)
 535                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 536         endif()
 537         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 538         set(CMAKE_CXX_FLAGS_DEBUG "${LYX_CXX_FLAGS} -fno-strict-aliasing -O0 -g3 -D_DEBUG" CACHE TYPE STRING FORCE)
 539         if(MINGW)
 540                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 541         else()
 542                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 543         endif()
 544 endif()
 545
 546 set(LYX_CXX_FLAGS_EXTRA "" CACHE STRING "Desired semicolon separated list of extra cxx compile flags, like '-Werror'")
 547 mark_as_advanced(LYX_CXX_FLAGS_EXTRA)
 548 if(LYX_CXX_FLAGS_EXTRA)
 549         foreach(_flag ${LYX_CXX_FLAGS_EXTRA})
 550                 add_definitions(${_flag})
 551         endforeach()
 552 endif()
 553
 554 if(LYX_XMINGW)
 555         list(APPEND CMAKE_FIND_ROOT_PATH ${GNUWIN32_DIR})
 556 endif()
 557
 558 if(LYX_USE_QT MATCHES "QT5")
 559         find_package(Qt5Core REQUIRED)
 560         if (Qt5Core_FOUND)
 561                 find_package(Qt5Widgets REQUIRED)
 562                 if(APPLE)
 563                         find_package(Qt5MacExtras REQUIRED)
 564                 endif()
 565                 find_package(Qt5X11Extras QUIET)
 566                 find_package(Qt5WinExtras QUIET)
 567                 set(QTVERSION ${Qt5Core_VERSION})
 568                 macro (qt_use_modules)
 569                         qt5_use_modules(${ARGN})
 570                 endmacro()
 571                 macro (qt_add_resources)
 572                         qt5_add_resources(${ARGN})
 573                 endmacro()
 574                 macro (qt_wrap_uifiles)
 575                         qt5_wrap_ui(${ARGN})
 576                 endmacro()
 577                 message(STATUS "Found Qt-Version ${QTVERSION}")
 578                 if(WIN32)
 579                         set(LYX_QTMAIN_LIBRARY ${Qt5Core_QTMAIN_LIBRARIES})
 580                 endif()
 581         endif()
 582 elseif(LYX_USE_QT MATCHES "QT4")
 583         if(LYX_XMINGW)
 584                 set(QT_MINGW_DIR ${LYX_QT4} CACHE PATH "Qt for Mingw" FORCE)
 585                 list(APPEND CMAKE_FIND_ROOT_PATH ${QT_MINGW_DIR} ${GNUWIN32_DIR})
 586         endif()
 587         find_package(Qt4 "4.5.0" REQUIRED)
 588         macro (qt_use_modules)
 589         endmacro()
 590         macro (qt_add_resources)
 591                 qt4_add_resources(${ARGN})
 592         endmacro()
 593         macro (qt_wrap_uifiles)
 594                 qt4_wrap_ui(${ARGN})
 595         endmacro()
 596         if(WIN32)
 597                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARIES})
 598         endif()
 599 else()
 600   message(FATAL_ERROR "Unhandled value for LYX_USE_QT (${LYX_USE_QT})")
 601 endif()
 602
 603 find_package(Magic)
 604 if(Magic_FOUND)
 605         set(HAVE_MAGIC_H 1)
 606 endif()
 607
 608 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 609
 610 set(Spelling_FOUND OFF)
 611 set(Include_used_spellchecker)   # String will be inserted into config.h
 612
 613 foreach(_spell "ASPELL" "Enchant" "Hunspell")
 614   string(TOUPPER ${_spell} _upspell)
 615   find_package(${_spell})
 616   if (${_upspell}_FOUND)
 617     include_directories(${${_upspell}_INCLUDE_DIR})
 618     set(Spelling_FOUND ON)
 619     message(STATUS "Building with USE_${_upspell}")
 620     set(Include_used_spellchecker "${Include_used_spellchecker}#define USE_${_upspell} 1\n")
 621   else()
 622     if(LYX_${_upspell})
 623       message(FATAL_ERROR "Required ${_spell} devel package not found")
 624     else()
 625       message(STATUS "${_upspell} not found, building without ${_spell} support")
 626     endif()
 627   endif()
 628 endforeach()
 629
 630 find_package(PythonInterp 2.7 QUIET)
 631 if(PYTHONINTERP_FOUND)
 632   if(PYTHON_VERSION_STRING VERSION_GREATER 2.8)
 633     unset(PYTHONINTERP_FOUND)
 634   endif()
 635 endif()
 636
 637 if (NOT PYTHONINTERP_FOUND)
 638   unset(PYTHON_EXECUTABLE CACHE)
 639   unset(PYTHON_VERSION_MAJOR)
 640   unset(PYTHON_VERSION_MINOR)
 641   unset(PYTHON_VERSION_STRING)
 642   find_package(PythonInterp 3.3 REQUIRED)
 643 endif()
 644
 645 set(LYX_PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 646
 647 if(LYX_NLS)
 648         find_package(LyXGettext)
 649         if(LYX_PYTHON_EXECUTABLE AND GETTEXT_FOUND)
 650                 add_subdirectory(po "${TOP_BINARY_DIR}/po")
 651         else()
 652                 # Install only supplied .gmo-files
 653                 file(GLOB _gmofiles RELATIVE "${TOP_SRC_DIR}/po" "${TOP_SRC_DIR}/po/*.gmo")
 654                 message(STATUS "Installing provided .gmo-files only")
 655                 foreach( _gmo ${_gmofiles})
 656                         string(REGEX REPLACE "\\.gmo$" "" _lang ${_gmo})
 657                         install(FILES "${TOP_SRC_DIR}/po/${_gmo}" DESTINATION ${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}/${_lang}/LC_MESSAGES RENAME ${PACKAGE}.mo)
 658                 endforeach()
 659         endif()
 660 endif()
 661
 662
 663 find_package(ICONV REQUIRED)
 664 find_package(ZLIB REQUIRED)
 665
 666 if(LYX_EXTERNAL_BOOST)
 667         message(STATUS "Searching for boost")
 668         if(LYX_USE_STD_REGEX)
 669                 find_package(Boost COMPONENTS signals)
 670         else()
 671                 find_package(Boost COMPONENTS signals regex)
 672         endif()
 673         if(Boost_FOUND)
 674                 message(STATUS "Boost found")
 675                 message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 676                 set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 677                 if (LYX_STDLIB_DEBUG)
 678                         # Comment from  Jean-Marc Lasgouttes:
 679                         # In general, system boost libraries are incompatible with
 680                         # the use of stdlib-debug in libstdc++. See ticket #9736 for
 681                         # details.
 682                         message(WARNING "Compiling LyX with stdlib-debug and system boost libraries may lead to crashes. Consider using '-DLYX_STDLIB_DEBUG=OFF' or using '-DLYX_EXTERNAL_BOOST=OFF'")
 683                 endif()
 684         else()
 685                 message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 686         endif()
 687 else()
 688         if(LYX_USE_STD_REGEX)
 689                 set(Lyx_Boost_Libraries boost_signals)
 690         else()
 691                 set(Lyx_Boost_Libraries boost_signals boost_regex)
 692         endif()
 693         add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 694         add_definitions(-DBOOST_SIGNALS_NO_DEPRECATION_WARNING=1)
 695         include_directories(${TOP_SRC_DIR}/boost)
 696         add_subdirectory(boost "${TOP_BINARY_DIR}/boost")
 697 endif()
 698
 699
 700
 701
 702 if(WIN32)
 703         if(LYX_CONSOLE)
 704                 set(LYX_QTMAIN_LIBRARY)
 705         else()
 706                 set(WIN32_CONSOLE WIN32)
 707         endif()
 708         if(MSVC)
 709                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 710                 # disable checked iterators for msvc release builds to get maximum speed
 711                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 712         else()
 713                 add_definitions(-DWINVER=0x0500)
 714         endif()
 715 endif()
 716
 717 # Compute qt4-version from ${QTVERSION}
 718
 719 message(STATUS "")
 720 foreach(_v PACKAGE PACKAGE_VERSION
 721         PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 722         LYX_ABS_TOP_SRCDIR
 723         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 724         if(NOT DEFINED ${_v})
 725                 message(FATAL_ERROR "${_v} not defined")
 726         endif()
 727         string(SUBSTRING "${_v}                            " 0 28 _v1)
 728         message(STATUS "----- ${_v1}: ${${_v}}")
 729 endforeach(_v)
 730 message(STATUS "")
 731
 732
 733 if(LYX_PCH)
 734         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 735         # Not sure if it works for all non-msvc compilers
 736         include(PCHSupport_26)
 737         configure_file(${TOP_CMAKE_PATH}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
 738         configure_file(${TOP_CMAKE_PATH}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 739         add_definitions(-DLYX_ENABLE_PCH)
 740
 741         if(MSVC)
 742                 macro(lyx_add_msvc_pch name_)
 743                         set_source_files_properties(${${name_}_sources} PROPERTIES
 744                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 745                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
 746                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 747                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
 748                                 ${TOP_BINARY_DIR}/pcheaders.h)
 749                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 750                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 751                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 752                 endmacro(lyx_add_msvc_pch)
 753                 macro(lyx_add_gcc_pch name_)
 754                 endmacro()
 755         else()
 756                 macro(lyx_add_msvc_pch name_)
 757                 endmacro()
 758                 macro(lyx_add_gcc_pch name_)
 759                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT)
 760                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
 761                 endmacro()
 762         endif()
 763 else()
 764         macro(lyx_add_msvc_pch)
 765         endmacro(lyx_add_msvc_pch)
 766         macro(lyx_add_gcc_pch name_)
 767         endmacro()
 768 endif()
 769
 770
 771 if(MSVC)
 772
 773         if(LYX_VLD)
 774                 set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/development/Win32/vld)
 775                 add_subdirectory(${vld_path}/cmake)
 776                 include(${vld_path}/cmake/vld.cmake) # forced include
 777                 set(vld_dll vld)
 778         endif()
 779
 780         if(LYX_WALL)
 781                 # Use the highest warning level
 782                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 783
 784                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 785                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 786                 else()
 787                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 788                 endif()
 789
 790                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 791                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 792                 else()
 793                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 794                 endif()
 795
 796                 # add here warnings which should produce an error /weXXXX
 797                 set(MSVC_W_ERROR   "/we4101 /we4189")
 798                 # add here warnings which should be disabled /wdXXXX
 799                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 800
 801                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 802                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 803                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 804
 805         else()
 806                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 807
 808                 # add here warnings which should produce an error /weXXXX
 809                 set(MSVC_W_ERROR   "/we4101 /we4189")
 810                 # add here warnings which should be disabled /wdXXXX
 811                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 812
 813                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 814                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 815                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 816
 817         endif()
 818
 819         if (NOT Qt5Core_FOUND)
 820                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 821                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 822                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 823         endif()
 824
 825         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 826         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 827         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 828         message(STATUS "")
 829 endif()
 830
 831
 832 if(LYX_DEBUG_GLIBC)
 833         set(_GLIBCXX_DEBUG ON)
 834 endif()
 835
 836 if(LYX_DEBUG_GLIBC_PEDANTIC)
 837         set(_GLIBCXX_DEBUG_PEDANTIC ON)
 838 endif()
 839
 840 # Xcode compiler
 841 if (CMAKE_GENERATOR MATCHES Xcode)
 842         if (XCODE_VERSION VERSION_LESS "5.0")
 843                 # Automatically select the Xcode compiler if not set
 844                 if (NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 845                         # XCode >= 3.1 has gcc 4.2 (up to actual Xcode)
 846                         if (XCODE_VERSION VERSION_GREATER "3.1")
 847                                 SET(CMAKE_XCODE_ATTRIBUTE_GCC_VERSION "com.apple.compilers.llvmgcc42")
 848                         ENDIF(XCODE_VERSION VERSION_GREATER "3.1")
 849                 ENDIF(NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 850                 # Print the selected compiler version
 851         MESSAGE(STATUS "---- Using XCode compiler CMAKE_XCODE_ATTRIBUTE_GCC_VERSION=${CMAKE_XCODE_ATTRIBUTE_GCC_VERSION}")
 852         ENDIF(XCODE_VERSION VERSION_LESS "5.0")
 853 ENDIF(CMAKE_GENERATOR MATCHES Xcode)
 854
 855 if (WIN32 AND Qt5Core_FOUND)
 856         set(Z_PREFIX 1)
 857 endif()
 858
 859 # compiler tests, config.h generation
 860 if(MSVC AND NOT LYX_CONFIGURE_CHECKS)
 861         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.msvc ${TOP_BINARY_DIR}/configCompiler.h)
 862 else()
 863         include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
 864         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
 865 endif()
 866
 867 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
 868
 869 if(QTVERSION MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+).*")
 870         MATH(EXPR QT4_VERSION "(${CMAKE_MATCH_1}<<16)|(${CMAKE_MATCH_2}<<8)|${CMAKE_MATCH_3}")
 871 endif()
 872
 873 if (NOT HAVE_REGEX)
 874         set(LYX_USE_STD_REGEX 0)
 875 endif()
 876
 877
 878 set (cmd ${CMAKE_CTEST_COMMAND})
 879 if (MSVC)
 880         set (cmd ${cmd} -C ${CMAKE_CFG_INTDIR})
 881 else ()
 882         set (cmd ${cmd} -C ${CMAKE_BUILD_TYPE})
 883 endif ()
 884 add_custom_target (lyx_run_tests COMMAND ${cmd})
 885 set_target_properties(lyx_run_tests PROPERTIES FOLDER "tests")
 886
 887 if(LYX_ASAN)
 888     set(LYX_CXX_FLAGS "-fsanitize=address -fno-omit-frame-pointer -g")
 889     message(STATUS)
 890     message(STATUS "Address sanitizer enabled. Usage:")
 891     message(STATUS "    wget https://llvm.org/svn/llvm-project/compiler-rt/trunk/lib/asan/scripts/asan_symbolize.py")
 892     message(STATUS "    chmod  +x ./asan_symbolize.py")
 893     message(STATUS "    ./bin/lyx2.2 2>&1 | ./asan_symbolize.py  | c++filt ")
 894     message(STATUS)
 895 endif()
 896
 897 if(LYX_INSTALL)
 898         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 899                 message(STATUS "Python required to create doc!")
 900         else()
 901                 if(UNIX)
 902                         add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
 903                 endif()
 904                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
 905         endif()
 906         include(../Install)
 907 endif()
 908
 909 add_subdirectory(src "${TOP_BINARY_DIR}/src")
 910 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
 911 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
 912 add_subdirectory(lib/examples "${TOP_BINARY_DIR}/lib/examples")
 913 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
 914 add_subdirectory(development/autotests "${TOP_BINARY_DIR}/autotests")
 915 if(LYX_ENABLE_URLTESTS)
 916         add_subdirectory(development/checkurls "${TOP_BINARY_DIR}/checkurls")
 917 endif()
 918
 919 message(STATUS)
 920 message(STATUS "Build params, switch LYX_* options by -DLYX_*=ON or OFF, LYX_* combos by -DLYX_*=value:")
 921 message(STATUS)
 922
 923 LYX_OPTION_LIST_ALL(used)
 924
 925
 926 if(LYX_NLS)
 927         message(STATUS)
 928         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
 929         message(STATUS)
 930         message(STATUS "  * iconv")
 931         message(STATUS "     - header : ${ICONV_HEADER}")
 932         message(STATUS "     - library: ${ICONV_LIBRARY}")
 933         message(STATUS "  * zlib")
 934         message(STATUS "     - header : ${ZLIB_HEADER}")
 935         message(STATUS "     - library: ${ZLIB_LIBRARY}")
 936         message(STATUS)
 937 endif()
 938
 939 # Apple has builtin native spell checker,
 940 # no need to warn for missing Aspell, Hunspell or Enchant
 941 if(NOT Spelling_FOUND AND NOT APPLE)
 942   if(LYX_REQUIRE_SPELLCHECK)
 943     set(_mode "FATAL_ERROR")
 944   else()
 945     set(_mode "STATUS")
 946   endif()
 947   message(${_mode} "No spellcheck libraries found. LyX will be unable use spellchecking")
 948 endif()
 949
 950 include("${TOP_CMAKE_PATH}/LyxPackaging.cmake")
 951
 952 if(ENABLE_DIST)
 953   # Use git to create the source package
 954   # git archive --format=tgz --output=/home/kornel/x.tar.gz master
 955   if(UNIX)
 956     set(DIST_FORMAT tgz)
 957   else()
 958     set(DIST_FORMAT zip)
 959   endif()
 960   set(DIST_NAME ${CMAKE_PROJECT_NAME}-${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}-${CMAKE_SYSTEM_NAME}.${DIST_FORMAT})
 961
 962   add_custom_command(
 963     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME}
 964     COMMAND  ${LYX_GITVERSION} archive --format=${DIST_FORMAT} --output=${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME} master
 965     WORKING_DIRECTORY ${TOP_SRC_DIR})
 966   add_custom_target(git-archive DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME})
 967 endif()
 968
 969 # Last directory to be included so that the fixup code (OS X)
 970 # can be run last
 971 add_subdirectory(development/cmake/post_install)
 972
 973 message(STATUS)