CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 3.1.0)
   8
   9 set(LYX_PROJECT LyX)
  10
  11 # Instruct cmake to not use gnu extensions,
  12 # this prevents the mix of '-std=c++*' and '-std=gnu++*' flags
  13 set(CMAKE_CXX_EXTENSIONS OFF)
  14
  15 enable_testing()
  16
  17 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README REALPATH) # Resolve symlinks
  18 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  19 message(STATUS "TOP_SRC_DIR = ${TOP_SRC_DIR}")
  20
  21 set(LYX_CMAKE_DIR "development/cmake")
  22 set(TOP_CMAKE_PATH "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}")
  23 set(TOP_MODULE_PATH "${TOP_CMAKE_PATH}/modules")
  24 set(TOP_SCRIPT_PATH "${TOP_CMAKE_PATH}/scripts")
  25
  26 set(CMAKE_MODULE_PATH "${TOP_MODULE_PATH}")
  27
  28 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  29
  30 message(STATUS)
  31 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  32         message(STATUS "Building in-source")
  33         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  34 else()
  35         message(STATUS "Building out-of-source")
  36         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  37 endif()
  38
  39 # This directory should be used if some test uses lyx-executable
  40 set(LYX_TESTS_USERDIR "${TOP_BINARY_DIR}/Testing/.lyx")
  41 file(MAKE_DIRECTORY "${LYX_TESTS_USERDIR}")
  42
  43 if(COMMAND cmake_policy)
  44         # Installing MACOSX_BUNDLE targets requires a BUNDLE DESTINATION
  45         cmake_policy(SET CMP0006 NEW)
  46         if(POLICY CMP0043)
  47                 # COMPILE_DEFINITIONS are not used yet. Enable new behavior.
  48                 cmake_policy(SET CMP0043 NEW)
  49         endif()
  50         cmake_policy(SET CMP0020 NEW)
  51         if(POLICY CMP0075)
  52                 cmake_policy(SET CMP0075 NEW)
  53         endif()
  54 endif()
  55
  56 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  57
  58 # Supress regeneration
  59 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  60
  61 if(LYX_XMINGW)
  62     set(CMAKE_SYSTEM_NAME Windows)
  63     set(TOOLNAME ${LYX_XMINGW})
  64     set(TOOLCHAIN "${TOOLNAME}-")
  65     set(CMAKE_C_COMPILER   "${TOOLCHAIN}gcc"     CACHE PATH "Mingw C compiler" FORCE)
  66     set(CMAKE_CXX_COMPILER "${TOOLCHAIN}g++"     CACHE PATH "Mingw C++ compiler" FORCE)
  67     set(CMAKE_RC_COMPILER  "${TOOLCHAIN}windres" CACHE PATH "Mingw rc compiler" FORCE)
  68
  69     set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM BOTH)
  70     set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY)
  71     set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY)
  72 endif()
  73
  74 if(NOT help AND NOT HELP)
  75   # 'project' triggers the searching for a compiler
  76   project(${LYX_PROJECT})
  77   if (CMAKE_COMPILER_IS_GNUCXX)
  78     if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS "4.0")
  79       message(STATUS "Gnu CXX compiler version = ${CMAKE_CXX_COMPILER_VERSION}")
  80       message(STATUS "is too old, should be >= 4.0")
  81       message(FATAL_ERROR "Exiting")
  82     endif()
  83   endif()
  84 endif()
  85
  86 if(UNIX)
  87         set(ARCH_TRIPLET )
  88         FIND_PROGRAM(DPKG_ARCHITECTURE_EXECUTABLE dpkg-architecture)
  89         if(DPKG_ARCHITECTURE_EXECUTABLE)
  90                 EXECUTE_PROCESS(COMMAND ${DPKG_ARCHITECTURE_EXECUTABLE} -qDEB_HOST_MULTIARCH
  91                                 OUTPUT_VARIABLE ARCH_TRIPLET
  92                                 ERROR_VARIABLE ERROR_ARCH_TRIPLET
  93                                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  94         endif()
  95 endif()
  96 if(ARCH_TRIPLET)
  97         set(SYSTEM_LIB_DIRS /usr/lib /usr/lib/${ARCH_TRIPLET} /usr/local/lib)
  98 else()
  99         set(SYSTEM_LIB_DIRS /usr/lib /usr/local/lib)
 100 endif()
 101
 102 include(LyXMacros)
 103 include(LyXDestinations)
 104
 105 # Usage LYX_OPTION
 106 # 1. parameter: option name without prefix 'LYX_'
 107 # 2. parameter: description
 108 # 3. parameter: default value, ON or OFF
 109 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
 110
 111 # Usage LYX_COMBO
 112 # 1. parameter: name without prefix 'LYX_'
 113 # 2. parameter: description
 114 # 3. parameter: default value
 115 # 4-n parameter: possible other string values
 116
 117 LYX_OPTION_INIT()
 118
 119 # Options for all compilers/systems
 120 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
 121 LYX_OPTION(LOCALVERSIONING  "Add version info to created package name (only used if LYX_CPACK option set)" OFF ALL)
 122 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
 123 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
 124 LYX_OPTION(REQUIRE_SPELLCHECK "Abort if no spellchecker available" OFF ALL)
 125 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
 126 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
 127 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
 128 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" OFF ALL)
 129 LYX_OPTION(DEBUG            "Enforce debug build"  OFF ALL)
 130 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
 131 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
 132 LYX_STRING(SUFFIX_VALUE     "Use this string as suffix" "")
 133 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
 134 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
 135 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
 136 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
 137 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
 138 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
 139 LYX_OPTION(ENABLE_URLTESTS  "Enable for URL tests" OFF ALL)
 140 LYX_OPTION(ENABLE_EXPORT_TESTS "Enable for export tests" OFF ALL)
 141 LYX_OPTION(ENABLE_KEYTESTS  "Enable for keytests" OFF ALL)
 142 LYX_OPTION(ASAN             "Use address sanitizer" OFF ALL)
 143 #LYX_COMBO(USE_FILEDIALOG    "Use native or QT file dialog" QT NATIVE)
 144 LYX_COMBO(USE_QT            "Use Qt version as frontend" AUTO QT4 QT5)
 145 LYX_COMBO(USE_IPO           "Interprocedural optimization" OFF AUTO ON)
 146 #LYX_OPTION(3RDPARTY_BUILD   "Build 3rdparty libs" OFF ALL)
 147 LYX_OPTION(DISABLE_CALLSTACK_PRINTING "do not print a callstack when crashing" OFF ALL)
 148 LYX_OPTION(EXTERNAL_Z       "OFF := Build 3rdparty lib zlib" ON ALL)
 149 LYX_OPTION(EXTERNAL_ICONV   "OFF := Build 3rdparty lib iconvlib" ON ALL)
 150 LYX_OPTION(EXTERNAL_HUNSPELL "OFF := Build 3rdparty lib hunspelllib" ON ALL)
 151 LYX_COMBO(EXTERNAL_MYTHES   "OFF := Build 3rdparty lib mytheslib" AUTO OFF ON)
 152
 153 # GCC specific
 154 LYX_OPTION(PROFILE              "Build with options for gprof" OFF GCC)
 155 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" OFF GCC)
 156 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
 157 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
 158 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++ pedantic debug mode" OFF GCC)
 159 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" OFF GCC)
 160
 161 # MSVC specific
 162 LYX_OPTION(CONSOLE               "Show console on Windows" ON MSVC)
 163 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
 164 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
 165 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
 166
 167 # APPLE specific
 168 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
 169 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
 170
 171
 172 if(help OR HELP)
 173         message(STATUS)
 174         message(STATUS "Available options: (dis/enable with -DLYX_*=OFF/ON)")
 175         message(STATUS)
 176         LYX_OPTION_LIST_ALL(help)
 177         message(STATUS)
 178         RETURN()
 179 endif()
 180
 181 # Check option dependencies
 182
 183 if(LYX_DMG)
 184         set(LYX_BUNDLE ON)
 185         set(LYX_CPACK ON)
 186 endif()
 187
 188 if(LYX_CPACK)
 189         set(LYX_INSTALL ON)
 190 endif()
 191
 192 if(LYX_INSTALL)
 193         set(LYX_NLS ON)
 194         if(WIN32 AND NOT MINGW)
 195                 set(LYX_HUNSPELL ON)
 196         endif()
 197         set(LYX_PACKAGE_SUFFIX ON)
 198         if(NOT LYX_DEBUG)
 199                 set(LYX_RELEASE ON)
 200         endif()
 201         set(LYX_PROFILE OFF)
 202 endif()
 203
 204
 205 if(LYX_MERGE_FILES)
 206         set(LYX_PCH OFF)
 207 else()
 208         set(LYX_MERGE_REBUILD OFF)
 209 endif()
 210
 211 if(LYX_DEPENDENCIES_DOWNLOAD)
 212         message(STATUS)
 213         if(MSVC14)
 214                 set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2015-deps)
 215                 set(deps_files lyx-windows-deps-msvc2015.zip)
 216                 set(deps_server http://ftp.lyx.de/LyX-Windows-Deps)
 217                 set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2015)
 218         elseif(MSVC10)
 219                 set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 220                 set(deps_files lyx-windows-deps-msvc2010.zip)
 221                 set(deps_server http://ftp.lyx.de/LyX-Windows-Deps)
 222                 set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2010)
 223         else()
 224                 message(FATAL_ERROR "error: no dependency package known for the selected MSVC version.")
 225         endif()
 226     message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 227         foreach(it ${deps_files})
 228                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 229                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 230                 if(NOT already_downloaded)
 231                         message(STATUS "Downloading ${it} ...")
 232                         file(DOWNLOAD ${deps_server}/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS STATUS status LOG log)
 233                         list(GET status 0 status_code)
 234                         list(GET status 1 status_string)
 235                         if(NOT status_code EQUAL 0)
 236                                 file(REMOVE ${LYX_DEPENDENCIES_DIR}/${it})
 237                                 message(FATAL_ERROR "error: downloading '${it}' failed. status_code: ${status_code}, status_string: ${status_string}. \nLog: ${log} ")
 238                         endif()
 239                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 240                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 241                 endif()
 242         endforeach()
 243 endif()
 244
 245 message(STATUS)
 246
 247 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 248 if(WIN32)
 249         set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 250 else()
 251         set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 252 endif()
 253
 254 set(LYX_IPO_SUPPORTED OFF)
 255 if (POLICY CMP0069)
 256   cmake_policy(SET CMP0069 NEW)
 257   if(LYX_USE_IPO MATCHES "AUTO")
 258     # Enable LTO if supported and not debugging
 259     if (NOT LYX_DEBUG)
 260       include(CheckIPOSupported)
 261       check_ipo_supported(RESULT LYX_IPO_SUPPORTED)
 262     endif()
 263   else()
 264     set(LYX_IPO_SUPPORTED ${LYX_USE_IPO})
 265   endif()
 266 endif()
 267 if (LYX_IPO_SUPPORTED)
 268   set(LYX_USE_IPO "ON" CACHE STRING "Use interprocedural optimization" FORCE)
 269 else()
 270   set(LYX_USE_IPO "OFF" CACHE STRING "Use interprocedural optimization" FORCE)
 271 endif()
 272
 273 # Set to some meaningful default
 274 find_package(CXX11Compiler)
 275 if(NOT CXX11COMPILER_FOUND)
 276         message(FATAL_ERROR "A C++11 compatible compiler is required.")
 277 endif()
 278 unset(LYX_GCC11_MODE)
 279 if(UNIX OR MINGW)
 280         if (CMAKE_CXX_COMPILER_ID MATCHES "^([cC]lang|AppleClang)$")
 281           # ignore the GCC_VERSION for clang
 282           # and use the resulting CXX11_STD_REGEX found in FindCXX11Compiler.cmake
 283           message(STATUS "Using clang")
 284           if(CXX11_STD_REGEX)
 285             set(LYX_USE_STD_REGEX 1)
 286           else()
 287             set(LYX_USE_STD_REGEX 0)
 288           endif()
 289         else()
 290           execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpfullversion OUTPUT_VARIABLE GCC_VERSION ERROR_VARIABLE _error RESULT_VARIABLE _err OUTPUT_STRIP_TRAILING_WHITESPACE)
 291           #message(STATUS "dumpfullversion: error = ${_error}, result = ${_err}")
 292           if (_err)
 293             # previous check failed, try again with _old_ parameter
 294             execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION ERROR_VARIABLE _error RESULT_VARIABLE _err OUTPUT_STRIP_TRAILING_WHITESPACE)
 295             #message(STATUS "dumpversion: error = ${_error}, result = ${_err}")
 296           endif()
 297           message(STATUS "Using GCC version ${GCC_VERSION}")
 298           if(GCC_VERSION VERSION_LESS 4.6)
 299                 message(FATAL_ERROR "gcc >= 4.6 is required.")
 300           elseif(GCC_VERSION VERSION_LESS 4.9)
 301                 # <regex> in gcc is unusable in versions less than 4.9.0
 302                 # see https://gcc.gnu.org/bugzilla/show_bug.cgi?id=53631
 303                 set(LYX_USE_STD_REGEX 0)
 304           else()
 305                 set(LYX_USE_STD_REGEX 1)
 306           endif()
 307         endif()
 308         set(LYX_GCC11_MODE "${CXX11_FLAG}")
 309 else()
 310         if(MSVC_VERSION LESS 1900)
 311                 # Drop support for msvc versions prior to 1900 (Visual Studio 2015)
 312                 message(FATAL_ERROR "Visual Studio >= 2015 is required.")
 313                 set(LYX_USE_STD_REGEX 0)
 314         else()
 315                 set(LYX_USE_STD_REGEX 1)
 316         endif()
 317 endif()
 318
 319
 320 # Try to get some informations from configure.ac
 321
 322 include(LyXPaths)
 323 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 324
 325 if(WIN32)
 326         set(CMAKE_PREFIX_PATH Specify-path-to-Qt CACHE PATH "Used Qt version")
 327         if(MSVC)
 328                 set(LYX_3RDPARTY_BUILD ON CACHE BOOL "Build 3rdparty libraries" FORCE)
 329         endif()
 330         set(USE_WINDOWS_PACKAGING ON)
 331 elseif(APPLE)
 332         set(USE_MACOSX_PACKAGING ON)
 333 else()
 334         set(USE_POSIX_PACKAGING ON)
 335 endif()
 336
 337 if(LYX_3RDPARTY_BUILD)
 338   # LYX_3RDPARTY_BUILD is not cached anymore, but for compatibility reasons
 339   # this enables the build of all 3rd_party libs
 340   set(LYX_EXTERNAL_Z        OFF CACHE BOOL "Build 3rdparty lib zlib"    FORCE)
 341   set(LYX_EXTERNAL_ICONV    OFF CACHE BOOL "Build 3rdparty iconvlib"    FORCE)
 342   set(LYX_EXTERNAL_HUNSPELL OFF CACHE BOOL "Build 3rdparty hunspelllib" FORCE)
 343   set(LYX_EXTERNAL_MYTHES   OFF CACHE STRING "Build 3rdparty mytheslib" FORCE)
 344 endif()
 345
 346 macro(setstripped _varname)
 347         if(${ARGC} GREATER 1)
 348                 string(STRIP "${ARGV1}" _v)
 349                 if (_v MATCHES "^\\[\(.+\)\\]$")
 350                   set(_v ${CMAKE_MATCH_1})
 351                 endif()
 352                 if(USE_POSIX_PACKAGING)
 353                         string(TOLOWER ${_v} ${_varname})
 354                 else()
 355                         set(${_varname} ${_v})
 356                 endif()
 357         else()
 358                 set(${_varname})
 359         endif()
 360 endmacro(setstripped)
 361
 362 foreach(_c_l ${_config_lines} )
 363         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 364                 # Not using CMAKE_MATCH_ directly is needed, because
 365                 # its value is now changed inside macro setstripped
 366                 set(_PB ${CMAKE_MATCH_1})
 367                 set(_PV ${CMAKE_MATCH_2})
 368                 set(_PBU ${CMAKE_MATCH_3})
 369                 setstripped(PACKAGE_BASE ${_PB})
 370                 setstripped(PACKAGE_VERSION ${_PV})
 371                 setstripped(PACKAGE_BUGREPORT ${_PBU})
 372                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\)\(\\.\([0-9]+\)\(\\.\([0-9]+\)\)?\)?.*$")
 373                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 374                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 375                         set(LYX_RELEASE_LEVEL ${CMAKE_MATCH_4})
 376                         set(LYX_RELEASE_PATCH ${CMAKE_MATCH_6})
 377                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 378                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 379                         if (NOT LYX_RELEASE_LEVEL)
 380                                 set(LYX_RELEASE_LEVEL 0)
 381                         endif()
 382                         if (NOT LYX_RELEASE_PATCH)
 383                                 set(LYX_RELEASE_PATCH 0)
 384                         endif()
 385                         if ("${LYX_SUFFIX_VALUE}" MATCHES "")
 386                           set(LYX_INSTALL_SUFFIX "${LYX_MAJOR_VERSION}.${LYX_MINOR_VERSION}")
 387                         else()
 388                           set(LYX_INSTALL_SUFFIX "${LYX_SUFFIX_VALUE}")
 389                         endif()
 390                 endif()
 391         endif()
 392         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 393                 set(LYX_DATE "${CMAKE_MATCH_1}")
 394         endif()
 395 endforeach(_c_l)
 396 unset(_config_lines)
 397
 398 FIND_PROGRAM(LYX_GITVERSION git)
 399 #message(STATUS "gitversion = ${LYX_GITVERSION}")
 400 set(LYX_REVISION_VERSION ${LYX_RELEASE_LEVEL})
 401 set(LYX_PACKAGE_RELEASE "UNDEFINED")
 402 if(LYX_GITVERSION)
 403   if (LYX_LOCALVERSIONING)
 404     # Find the revision number for later use
 405     EXECUTE_PROCESS(COMMAND ${LYX_GITVERSION} describe --match 2.0.0 HEAD
 406       WORKING_DIRECTORY "${TOP_SRC_DIR}"
 407       RESULT_VARIABLE tmp_GIT_RESULT
 408       OUTPUT_VARIABLE tmp_LYX_PACKAGE_RELEASE
 409       ERROR_VARIABLE tmp_GIT_ERROR
 410       OUTPUT_STRIP_TRAILING_WHITESPACE)
 411     if (tmp_GIT_RESULT EQUAL 0)
 412       if (tmp_LYX_PACKAGE_RELEASE MATCHES "^2\\.0\\.0\\-\([0-9]+\)\\-\(.*\)$")
 413         set(LYX_PACKAGE_RELEASE ${CMAKE_MATCH_2})
 414         # We will add offset of 40000 to get appropriate value to
 415         # previous svn.
 416         # We use this value than also to set the package-patch-value
 417         MATH(EXPR tmp_REVISION_VERSION "(${CMAKE_MATCH_1}+40000)")
 418         set(LYX_REVISION_VERSION "${LYX_RELEASE_LEVEL}-${tmp_REVISION_VERSION}git")
 419         set(ENABLE_DIST ON)
 420       endif()
 421     endif()
 422   endif()
 423 endif()
 424 if (LYX_PACKAGE_RELEASE MATCHES "UNDEFINED")
 425   set(LYX_PACKAGE_RELEASE  "1")
 426   if (LYX_RELEASE_PATCH GREATER 0)
 427     set(LYX_REVISION_VERSION "${LYX_RELEASE_LEVEL}.${LYX_RELEASE_PATCH}")
 428   endif()
 429 endif()
 430
 431 # Set the programs (lyx, tex2lyx, etc.) suffix
 432 # When building an OS X bundle, we will append
 433 # the suffix only to the bundle, not to the programs
 434 set(PROGRAM_SUFFIX "")
 435 if(LYX_PROGRAM_SUFFIX AND NOT (APPLE AND LYX_BUNDLE))
 436         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 437 endif()
 438 set(_lyx "${PACKAGE_BASE}${PROGRAM_SUFFIX}")
 439 set(_tex2lyx tex2lyx${PROGRAM_SUFFIX})
 440 set(_convert lyxconvert${PROGRAM_SUFFIX})
 441
 442 add_custom_target(lyx_version ALL
 443   COMMAND ${CMAKE_COMMAND} -DTOP_SRC_DIR=${TOP_SRC_DIR} -DTOP_CMAKE_PATH=${TOP_CMAKE_PATH} -DTOP_BINARY_DIR=${TOP_BINARY_DIR} -DLYX_DATE=${LYX_DATE} -P ${TOP_SCRIPT_PATH}/LyXGetVersion.cmake
 444   )
 445 set_target_properties(lyx_version PROPERTIES FOLDER "applications")
 446
 447 # Default paths for installed utilities (tex2lyx, lyxclient, etc.)
 448 set(LYX_UTILITIES_INSTALL_PATH bin)
 449
 450 if(LYX_BUNDLE)
 451         set(LYX_CPACK ON)
 452
 453         message(STATUS)
 454         message(STATUS "Bundle creation is enabled (experimental):")
 455         message(STATUS "    make")
 456         message(STATUS "    make install/strip")
 457         message(STATUS "    make package")
 458         if(APPLE)
 459                 set(MACOSX_BUNDLE TRUE)
 460                 # This sets the bundle + executable names
 461                 set(_lyx "${PACKAGE_BASE}${LYX_INSTALL_SUFFIX}")
 462                 # This sets the Info.plist executable name
 463                 set(osx_bundle_program_name ${_lyx})
 464                 # Bundle name
 465                 set(LYX_BUNDLE_NAME ${_lyx})
 466
 467                 # This will contain the list of files that need to be included
 468                 # in the bundle and their location within the bundle
 469                 set(OSX_BUNDLE_FILES "${TOP_SRC_DIR}/development/MacOSX/LyX.sdef;${TOP_SRC_DIR}/development/MacOSX/LyXapp.icns;${CMAKE_BINARY_DIR}/lyxrc.dist")
 470                 set(OSX_BUNDLE_DIRS "Resources;Resources;Resources")
 471
 472                 # Process Info.plist and lyxrc.dist
 473                 # See development/cmake/Install.cmake
 474                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/Info.plist.in" "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 475
 476                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 477                 set(LYX_DATA_SUBDIR ${LYX_BUNDLE_NAME}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 478
 479                 # Variables used by CPack
 480                 set(CPACK_BUNDLE_NAME ${LYX_BUNDLE_NAME})
 481                 set(CPACK_BUNDLE_PLIST "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 482                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${LYX_BUNDLE_NAME}.app)
 483
 484                 # Set the install paths
 485                 set(LYX_UTILITIES_INSTALL_PATH ${LYX_BUNDLE_NAME}.app/Contents/MacOS)
 486                 if(NOT LYX_INSTALL_PREFIX)
 487                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 488                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 489                 endif()
 490                 # Change the owner so that the install can work
 491                 install(CODE "set(BU_CHMOD_BUNDLE_ITEMS 1)" COMPONENT Runtime)
 492         elseif(UNIX)
 493                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 494                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 495                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 496         elseif(WIN32)
 497                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 498         endif()
 499 endif()
 500
 501 if(LYX_INSTALL_PREFIX)
 502         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 503         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 504 endif()
 505 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 506
 507 if(UNIX)
 508   set(SYSTEM_DATADIR "${CMAKE_INSTALL_PREFIX}/share")
 509 elseif(CMAKE_INSTALL_PREFIX MATCHES "/lyx${LYX_INSTALL_SUFFIX}$")
 510   string(REGEX REPLACE "/lyx${LYX_INSTALL_SUFFIX}$" "/share" SYSTEM_DATADIR ${CMAKE_INSTALL_PREFIX})
 511 else()
 512   set(SYSTEM_DATADIR "${CMAKE_INSTALL_PREFIX}")
 513 endif()
 514
 515 if(NOT CMAKE_COMPILER_IS_GNUCXX)
 516   # Not a GCC compiler, programs do not have a suffix
 517   set(suffixing ${LYX_PACKAGE_SUFFIX})
 518 elseif(WIN32 AND MINGW)
 519   # We want to use a suffix for the package in this case,
 520   # even if not for the program
 521   set(suffixing ${LYX_PACKAGE_SUFFIX})
 522 else()
 523   message(STATUS "CMAKE_COMPILER_IS_GNUCXX = ${CMAKE_COMPILER_IS_GNUCXX}")
 524   set(suffixing ${LYX_PROGRAM_SUFFIX})
 525 endif()
 526
 527 # The define PACKAGE below allows lyx-executable to find its default configuration files
 528 # see routines
 529 #    Package::messages_file()
 530 #    get_default_user_support_dir()
 531 #    relative_system_support_dir()
 532 # in src/support/Package.cpp
 533 if(suffixing)
 534         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 535 else()
 536         set(PACKAGE ${PACKAGE_BASE})
 537 endif()
 538
 539 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 540         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 541         if (UNIX)
 542                 # use the default "/usr/local"
 543                 # but respect the user-choice on the command-line
 544                 set(CMAKE_INSTALL_PREFIX "/usr/local" CACHE PATH "LyX default install prefix" FORCE)
 545         endif()
 546 endif()
 547 if(WIN32)
 548         set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 549 endif()
 550 if(IS_ABSOLUTE)
 551         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 552 else()
 553         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 554 endif()
 555
 556
 557
 558 if(NOT LYX_DATA_SUBDIR)
 559         if (WIN32)
 560                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 561         else()
 562                 set(LYX_DATA_SUBDIR "share/${_lyx}/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 563         endif()
 564 endif()
 565
 566 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 567 get_locale_destination(LYX_LOCALEDIR)
 568 set(LYX_ABS_INSTALLED_LOCALEDIR "${CMAKE_INSTALL_PREFIX}/${LYX_LOCALEDIR}")
 569 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 570
 571 if(LYX_BUNDLE AND APPLE)
 572         set(LYX_MAN_DIR "${LYX_DATA_SUBDIR}" CACHE STRING "Install location for man pages.")
 573 else()
 574         if(WIN32)
 575                 set(LYX_MAN_DIR "${CMAKE_BINARY_DIR}/usr/local/man" CACHE STRING "Install location for man pages.")
 576         elseif(UNIX)
 577                 set(LYX_MAN_DIR "${CMAKE_INSTALL_PREFIX}/share/man" CACHE STRING "Install location for man pages.")
 578         else()
 579                 set(LYX_MAN_DIR "${CMAKE_INSTALL_PREFIX}/man" CACHE STRING "Install location for man pages.")
 580         endif()
 581 endif()
 582 mark_as_advanced(LYX_MAN_DIR)
 583
 584 # The Win installer cannot be built by CMake because one needs to install plugins for NSIS
 585 # see the Readme.txt of the installer
 586 #if(LYX_INSTALL AND WIN32)
 587 #       message(STATUS "Configuring NSIS files")
 588 #       configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 589 #       configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 590 #       configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 591 #       message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 592 #endif()
 593
 594 if(NOT GROUP_CODE)
 595         #set(GROUP_CODE "The Golden Code")
 596         set(GROUP_CODE flat)
 597 endif()
 598
 599 # lyx's source files
 600 set(LYX_CPP_FILES [a-zA-Z]*.cpp)
 601 set(LYX_HPP_FILES [a-zA-Z]*.h)
 602 set(LYX_MOC_FILES moc_*.cpp)
 603
 604 include(ProjectSourceGroup)
 605
 606
 607 if(LYX_PROFILE AND NOT MSVC)
 608         set(CMAKE_BUILD_TYPE Profile CACHE STRING "Profile build type" FORCE)
 609         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg")
 610         set(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS}  -pg")
 611 else()
 612         set(LYX_PROFILE OFF)
 613 endif()
 614
 615
 616 if(LYX_NO_OPTIMIZE)
 617         set(CMAKE_BUILD_TYPE None)
 618         set(LYX_DEBUG OFF)
 619         set(LYX_RELEASE OFF)
 620         set(LYX_PROFILE OFF)
 621 elseif(LYX_RELEASE)
 622         set(CMAKE_BUILD_TYPE Release)
 623         set(LYX_DEBUG OFF)
 624         set(LYX_PROFILE OFF)
 625 elseif(LYX_PROFILE)
 626         set(CMAKE_BUILD_TYPE Profile)
 627         set(LYX_DEBUG OFF)
 628 else()
 629         set(CMAKE_BUILD_TYPE Debug)
 630         set(LYX_DEBUG ON)
 631 endif()
 632
 633
 634 # When shared libs are supported enable this option
 635 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 636 if(LYX_SHARED_LIBRARIES)
 637         set(library_type SHARED)
 638 else()
 639         set(library_type STATIC)
 640 endif()
 641
 642 if(NOT MSVC)
 643         if(NOT LYX_QUIET)
 644                 set(CMAKE_VERBOSE_MAKEFILE ON)
 645         endif()
 646         set(LYX_CXX_FLAGS "-Wall -Wunused-parameter ${LYX_GCC11_MODE}")
 647         if(LYX_CXX_FLAGS MATCHES "\\+\\+(14|11|98)")
 648           # Thanks to Brad King <brad.king@kitware.com>
 649           # for the pointer to https://cmake.org/cmake/help/v3.6/variable/CMAKE_CXX_STANDARD.html
 650           # This allows us to use QT5.7 with recent g++ (version >= 4.9) compilers
 651           # and still use our own c++ extension tests
 652           set(CMAKE_CXX_STANDARD ${CMAKE_MATCH_1})
 653           message(STATUS "CMAKE_CXX_STANDARD set to ${CMAKE_CXX_STANDARD}")
 654         endif()
 655         if(LYX_STDLIB_DEBUG)
 656                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 657         endif()
 658         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE STRING "Set CXX flags" FORCE)
 659         set(CMAKE_CXX_FLAGS_DEBUG "-O0 -g3 -D_DEBUG" CACHE STRING "Set debug flags" FORCE)
 660         if(MINGW)
 661                 set(CMAKE_CXX_FLAGS_RELEASE "-O2 -DNDEBUG" CACHE STRING "Set release flags for Mingw" FORCE)
 662         else()
 663                 set(CMAKE_CXX_FLAGS_RELEASE "-O3 -DNDEBUG" CACHE STRING "Set release flags" FORCE)
 664         endif()
 665 endif()
 666
 667 set(LYX_CXX_FLAGS_EXTRA "" CACHE STRING "Desired semicolon separated list of extra cxx compile flags, like '-Werror'")
 668 mark_as_advanced(LYX_CXX_FLAGS_EXTRA)
 669 if(LYX_CXX_FLAGS_EXTRA)
 670         foreach(_flag ${LYX_CXX_FLAGS_EXTRA})
 671                 add_definitions(${_flag})
 672         endforeach()
 673 endif()
 674
 675 if(LYX_XMINGW)
 676         list(APPEND CMAKE_FIND_ROOT_PATH ${GNUWIN32_DIR})
 677 endif()
 678
 679 set(min_qt5_version "5.6")
 680 if(LYX_USE_QT MATCHES "AUTO")
 681         # try qt5 first
 682         find_package(Qt5Core CONFIG QUIET)
 683         if(Qt5Core_FOUND)
 684                 set(LYX_USE_QT "QT5" CACHE STRING "Valid qt version" FORCE)
 685                 message(STATUS "Qt5Core_VERSION = ${Qt5Core_VERSION}")
 686                 if(Qt5Core_VERSION VERSION_LESS ${min_qt5_version})
 687                         find_package(Qt4 "4.5.0" QUIET)
 688                         if(QT4_FOUND)
 689                                 set(LYX_USE_QT "QT4" CACHE STRING "Valid qt version" FORCE)
 690                         endif()
 691                 endif()
 692         else()
 693                 set(LYX_USE_QT "QT4" CACHE STRING "Valid qt version" FORCE)
 694         endif()
 695 endif()
 696 if(LYX_USE_QT MATCHES "QT5")
 697         # set QPA_XCB if QT uses X11
 698         find_package(Qt5Core CONFIG REQUIRED)
 699         if (Qt5Core_FOUND)
 700                 find_package(Qt5Widgets CONFIG REQUIRED)
 701                 if(APPLE)
 702                         find_package(Qt5MacExtras CONFIG REQUIRED)
 703                 endif()
 704                 find_package(Qt5X11Extras CONFIG QUIET)
 705                 find_package(Qt5WinExtras CONFIG QUIET)
 706                 set(QTVERSION ${Qt5Core_VERSION})
 707                 if (QTVERSION VERSION_LESS ${min_qt5_version})
 708                         message(STATUS "QTVERSION = \"${QTVERSION}\"")
 709                         message(STATUS "This version is not recommended, try either option -DLYX_USE_QT=QT4 or")
 710                         message(STATUS "install QT-Version >= \"${min_qt5_version}\"")
 711                         # see thread in lyx-devel list
 712                         # From: Jean-Pierre Chrétien <jeanpierre.chretien@free.fr>
 713                         # Date 11.03.2017
 714                         # Subject: cmake compilation error
 715                         #message(FATAL_ERROR "Wrong Qt-Version")
 716                 endif()
 717                 macro (qt_use_modules lyxtarget)
 718                         foreach (_tg ${ARGN})
 719                                 find_package(Qt5${_tg} CONFIG REQUIRED)
 720                                 target_link_libraries(${lyxtarget} Qt5::${_tg})
 721                         endforeach()
 722                 endmacro()
 723                 macro (qt_add_resources)
 724                         qt5_add_resources(${ARGN})
 725                 endmacro()
 726                 macro (qt_wrap_uifiles)
 727                         qt5_wrap_ui(${ARGN})
 728                 endmacro()
 729                 message(STATUS "Found Qt-Version ${QTVERSION}")
 730                 if(WIN32)
 731                         set(LYX_QTMAIN_LIBRARY ${Qt5Core_QTMAIN_LIBRARIES})
 732                 endif()
 733         endif()
 734 elseif(LYX_USE_QT MATCHES "QT4")
 735         if(LYX_XMINGW)
 736                 set(QT_MINGW_DIR ${LYX_QT4} CACHE PATH "Qt for Mingw" FORCE)
 737                 list(APPEND CMAKE_FIND_ROOT_PATH ${QT_MINGW_DIR} ${GNUWIN32_DIR})
 738         endif()
 739         find_package(Qt4 "4.5.0" REQUIRED)
 740         macro (qt_use_modules)
 741         endmacro()
 742         macro (qt_add_resources)
 743                 qt4_add_resources(${ARGN})
 744         endmacro()
 745         macro (qt_wrap_uifiles)
 746                 qt4_wrap_ui(${ARGN})
 747         endmacro()
 748         set(LYX_QTMAIN_LIBRARY ${QT_QTSVG_LIBRARY})
 749         if(WIN32)
 750                 list(APPEND LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARIES})
 751         endif()
 752 else()
 753   message(FATAL_ERROR "Unhandled value for LYX_USE_QT (${LYX_USE_QT})")
 754 endif()
 755
 756 find_package(Magic)
 757 if(Magic_FOUND)
 758   set(HAVE_MAGIC_H 1)
 759   include_directories(${Magic_INCLUDE_DIR})
 760 endif()
 761
 762 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 763
 764 set(Spelling_FOUND OFF)
 765 set(Include_used_spellchecker)   # String will be inserted into config.h
 766
 767 if (LYX_EXTERNAL_MYTHES MATCHES "AUTO")
 768   # try system library first
 769   find_package(MyThesLIB)
 770   if (MYTHESLIB_FOUND)
 771     set(LYX_EXTERNAL_MYTHES ON CACHE STRING "OFF:= Build 3rdparty mytheslib" FORCE)
 772   else()
 773     set(LYX_EXTERNAL_MYTHES OFF CACHE STRING "OFF:= Build 3rdparty mytheslib" FORCE)
 774   endif()
 775 endif()
 776 if (LYX_EXTERNAL_MYTHES MATCHES "ON")
 777   find_package(MyThesLIB REQUIRED)
 778 else()
 779   add_subdirectory(3rdparty/mythes)
 780 endif()
 781 set(MYTHES_DIR ${MYTHESLIB_INCLUDE_DIR})
 782
 783 if(NOT LYX_EXTERNAL_HUNSPELL)
 784     add_subdirectory(3rdparty/hunspell)
 785     add_definitions(-DHUNSPELL_STATIC)
 786     set(HUNSPELL_FOUND ON)
 787     message(STATUS "  * Hunspell:")
 788     message(STATUS "     - include: ${HUNSPELL_INCLUDE_DIR}")
 789     message(STATUS "     - library: ${HUNSPELL_LIBRARY}")
 790 endif()
 791
 792 foreach(_spell "ASPELL" "ENCHANT" "HUNSPELL")
 793   string(TOUPPER ${_spell} _upspell)
 794   if (NOT ${_upspell}_FOUND)
 795     find_package(${_spell})
 796   endif()
 797   if (${_upspell}_FOUND)
 798     include_directories(${${_upspell}_INCLUDE_DIR})
 799     set(Spelling_FOUND ON)
 800     message(STATUS "Building with USE_${_upspell}")
 801     set(Include_used_spellchecker "${Include_used_spellchecker}#define USE_${_upspell} 1\n")
 802   else()
 803     if(LYX_${_upspell})
 804       message(FATAL_ERROR "Required ${_spell} devel package not found")
 805     else()
 806       message(STATUS "${_upspell} not found, building without ${_spell} support")
 807     endif()
 808   endif()
 809 endforeach()
 810
 811 if(GNUWIN32_DIR)
 812         list(APPEND CMAKE_PROGRAM_PATH "${GNUWIN32_DIR}/Python" )
 813 endif()
 814
 815 # Search for python default version first
 816 unset(PYTHON_EXECUTABLE CACHE)
 817 unset(LYX_PYTHON_EXECUTABLE CACHE)
 818 unset(PYTHON_VERSION_MAJOR)
 819 unset(PYTHON_VERSION_MINOR)
 820 unset(PYTHON_VERSION_STRING)
 821 if (CMAKE_VERSION VERSION_LESS "3.13")
 822   find_package(PythonInterp 3.5 QUIET)
 823   if(NOT PYTHONINTERP_FOUND)
 824     find_package(PythonInterp 2.0 REQUIRED)
 825     if(NOT PYTHON_VERSION_STRING VERSION_LESS 2.8)
 826       message(FATAL_ERROR "Python interpreter found, but is not suitable")
 827     endif()
 828   endif()
 829   set(LYX_PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 830 else()
 831   find_package(Python3 3.5 QUIET)
 832   if(NOT Python3_Interpreter_FOUND)
 833     unset(PYTHON_EXECUTABLE CACHE)
 834     find_package(Python2 2.0 REQUIRED)
 835     if(NOT Python2_VERSION VERSION_LESS 2.8)
 836       message(FATAL_ERROR "Python interpreter found, but is not suitable")
 837     endif()
 838     set(LYX_PYTHON_EXECUTABLE ${Python2_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 839   else()
 840     set(LYX_PYTHON_EXECUTABLE ${Python3_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 841   endif()
 842 endif()
 843
 844 if(LYX_NLS)
 845         find_package(LyXGettext)
 846         if(LYX_PYTHON_EXECUTABLE AND GETTEXT_FOUND)
 847                 add_subdirectory(po "${TOP_BINARY_DIR}/po")
 848         else()
 849                 # Install only supplied .gmo-files
 850                 file(GLOB _gmofiles RELATIVE "${TOP_SRC_DIR}/po" "${TOP_SRC_DIR}/po/*.gmo")
 851                 message(STATUS "Installing provided .gmo-files only")
 852                 foreach( _gmo ${_gmofiles})
 853                         string(REGEX REPLACE "\\.gmo$" "" _lang ${_gmo})
 854                         install(FILES "${TOP_SRC_DIR}/po/${_gmo}" DESTINATION ${LYX_LOCALEDIR}/${_lang}/LC_MESSAGES RENAME ${PACKAGE}.mo)
 855                 endforeach()
 856         endif()
 857 endif()
 858
 859 if(LYX_EXTERNAL_ICONV)
 860   find_package(ICONV REQUIRED)
 861 else()
 862   add_subdirectory(3rdparty/libiconv)
 863   set(HAVE_ICONV_CONST 1)
 864 endif()
 865
 866 if(LYX_EXTERNAL_Z)
 867   find_package(ZLIB REQUIRED)
 868 else()
 869   add_subdirectory(3rdparty/zlib)
 870 endif()
 871
 872 if(LYX_USE_STD_REGEX)
 873   # Set only include path.
 874   # Use internal boost, which is known to exist
 875   # we don't need any libraries
 876   set(Lyx_Boost_Libraries)
 877   add_definitions(-DBOOST_USER_CONFIG=<config.h>)
 878   include_directories(${TOP_SRC_DIR}/3rdparty/boost)
 879 else()
 880   # Using boost-regex
 881   if(LYX_EXTERNAL_BOOST)
 882     message(STATUS "Searching for external boost")
 883     find_package(Boost COMPONENTS regex)
 884     if(Boost_FOUND)
 885       message(STATUS "Boost found")
 886       message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 887       set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 888       if (LYX_STDLIB_DEBUG)
 889         # Comment from  Jean-Marc Lasgouttes:
 890         # In general, system boost libraries are incompatible with
 891         # the use of stdlib-debug in libstdc++. See ticket #9736 for
 892         # details.
 893         message(WARNING "Compiling LyX with stdlib-debug and system boost libraries may lead to crashes. Consider using '-DLYX_STDLIB_DEBUG=OFF' or using '-DLYX_EXTERNAL_BOOST=OFF'")
 894       endif()
 895     else()
 896       message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 897     endif()
 898   else()
 899     # Using included boost
 900     set(Lyx_Boost_Libraries boost_regex)
 901     add_definitions(-DBOOST_USER_CONFIG=<config.h>)
 902     include_directories(${TOP_SRC_DIR}/3rdparty/boost)
 903     add_subdirectory(3rdparty/boost "${TOP_BINARY_DIR}/3rdparty/boost")
 904   endif()
 905 endif()
 906
 907 if(WIN32)
 908         if(LYX_CONSOLE)
 909                 set(LYX_QTMAIN_LIBRARY)
 910         else()
 911                 set(WIN32_CONSOLE WIN32)
 912         endif()
 913         if(MSVC)
 914                 # -DPSAPI_VERSION=1 is needed to run on vista (bug 10186)
 915                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX -DPSAPI_VERSION=1)
 916                 # disable checked iterators for msvc release builds to get maximum speed
 917                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 918         else()
 919                 # -DPSAPI_VERSION=1 is not needed for mingw, since the mingw psapi.h
 920                 # does not use it and always declares the vista compatible API.
 921                 # If this ever changes then -DPSAPI_VERSION might be needed here as well.
 922                 add_definitions(-DWINVER=0x0500)
 923         endif()
 924 endif()
 925
 926 # Compute qt-version from ${QTVERSION}
 927
 928 message(STATUS "")
 929 foreach(_v PACKAGE PACKAGE_VERSION
 930         PROGRAM_SUFFIX LYX_DIR_VER LYX_USERDIR_VER
 931         LYX_ABS_TOP_SRCDIR
 932         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 933         if(NOT DEFINED ${_v})
 934                 message(FATAL_ERROR "${_v} not defined")
 935         endif()
 936         string(SUBSTRING "${_v}                            " 0 28 _v1)
 937         message(STATUS "----- ${_v1}: ${${_v}}")
 938 endforeach(_v)
 939 message(STATUS "")
 940
 941
 942 if(LYX_PCH)
 943         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 944         # Not sure if it works for all non-msvc compilers
 945         include(PCHSupport_26)
 946         configure_file(${TOP_CMAKE_PATH}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
 947         configure_file(${TOP_CMAKE_PATH}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 948         add_definitions(-DLYX_ENABLE_PCH)
 949
 950         if(MSVC)
 951                 macro(lyx_add_msvc_pch name_)
 952                         set_source_files_properties(${${name_}_sources} PROPERTIES
 953                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 954                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
 955                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 956                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
 957                                 ${TOP_BINARY_DIR}/pcheaders.h)
 958                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 959                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 960                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 961                 endmacro(lyx_add_msvc_pch)
 962                 macro(lyx_add_gcc_pch name_)
 963                 endmacro()
 964         else()
 965                 macro(lyx_add_msvc_pch name_)
 966                 endmacro()
 967                 macro(lyx_add_gcc_pch name_)
 968                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT)
 969                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
 970                 endmacro()
 971         endif()
 972 else()
 973         macro(lyx_add_msvc_pch)
 974         endmacro(lyx_add_msvc_pch)
 975         macro(lyx_add_gcc_pch name_)
 976         endmacro()
 977 endif()
 978
 979
 980 if(MSVC)
 981
 982         if(LYX_VLD)
 983                 set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/development/Win32/vld)
 984                 add_subdirectory(${vld_path}/cmake)
 985                 include(${vld_path}/cmake/vld.cmake) # forced include
 986                 set(vld_dll vld)
 987         endif()
 988
 989         if(LYX_WALL)
 990                 # Use the highest warning level
 991                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE STRING "Warning level" FORCE)
 992
 993                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 994                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 995                 else()
 996                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 997                 endif()
 998
 999                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
1000                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
1001                 else()
1002                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
1003                 endif()
1004
1005                 # add here warnings which should produce an error /weXXXX
1006                 set(MSVC_W_ERROR   "/we4101 /we4189")
1007                 # add here warnings which should be disabled /wdXXXX
1008                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
1009
1010                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1011                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1012                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1013
1014         else()
1015                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE STRING "Warning level" FORCE)
1016
1017                 # add here warnings which should produce an error /weXXXX
1018                 set(MSVC_W_ERROR   "/we4101 /we4189")
1019                 # add here warnings which should be disabled /wdXXXX
1020                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
1021
1022                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1023                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1024                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1025
1026         endif()
1027
1028         if (NOT Qt5Core_FOUND)
1029                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
1030                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
1031                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
1032         endif()
1033
1034         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
1035         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
1036         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
1037         message(STATUS "")
1038 endif()
1039
1040
1041 if(LYX_DEBUG_GLIBC)
1042         set(_GLIBCXX_DEBUG ON)
1043 endif()
1044
1045 if(LYX_DEBUG_GLIBC_PEDANTIC)
1046         set(_GLIBCXX_DEBUG_PEDANTIC ON)
1047 endif()
1048
1049 # Xcode compiler
1050 if (CMAKE_GENERATOR MATCHES Xcode)
1051         if (XCODE_VERSION VERSION_LESS "5.0")
1052                 # Automatically select the Xcode compiler if not set
1053                 if (NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
1054                         # XCode >= 3.1 has gcc 4.2 (up to actual Xcode)
1055                         if (XCODE_VERSION VERSION_GREATER "3.1")
1056                                 SET(CMAKE_XCODE_ATTRIBUTE_GCC_VERSION "com.apple.compilers.llvmgcc42")
1057                         ENDIF(XCODE_VERSION VERSION_GREATER "3.1")
1058                 ENDIF(NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
1059                 # Print the selected compiler version
1060         MESSAGE(STATUS "---- Using XCode compiler CMAKE_XCODE_ATTRIBUTE_GCC_VERSION=${CMAKE_XCODE_ATTRIBUTE_GCC_VERSION}")
1061         ENDIF(XCODE_VERSION VERSION_LESS "5.0")
1062 ENDIF(CMAKE_GENERATOR MATCHES Xcode)
1063
1064 if (WIN32 AND Qt5Core_FOUND)
1065         set(Z_PREFIX 1)
1066 endif()
1067
1068 # compiler tests, config.h generation LYX_CONFIGURE_CHECKS
1069 include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
1070 configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
1071
1072 unset(opts)
1073 foreach(_option ${LYX_OPTIONS})
1074   if(${_option}_show_message)
1075     string(SUBSTRING "${_option}                            " 0 31 _var)
1076     get_property(_prop CACHE ${_option} PROPERTY STRINGS)
1077     list(FIND LYX_OPTION_STRINGS ${_option} _index)
1078     if (${_index} GREATER -1)
1079       set(_isset ${${_option}})
1080     elseif(${_option})
1081       set(_isset ON)
1082     else()
1083       set(_isset OFF)
1084     endif()
1085     string(SUBSTRING "${_isset}           " 0 10 _val)
1086     set(opts "${opts} ${_option}(${${_option}})")
1087   endif()
1088 endforeach()
1089 set(tmp_vi "CMake Build")
1090 list(APPEND tmp_vi "  Host name:               ${CMAKE_HOST_SYSTEM_NAME}")
1091 list(APPEND tmp_vi "  Host processor:          ${CMAKE_HOST_SYSTEM_PROCESSOR}")
1092 list(APPEND tmp_vi "  Build flags:             ${opts}")
1093 list(APPEND tmp_vi "  C++ Compiler:            ${CMAKE_CXX_COMPILER_ID} (${CMAKE_CXX_COMPILER_VERSION})")
1094 list(APPEND tmp_vi "  C++ Compiler flags:      ${CMAKE_CXX_FLAGS}")
1095 if (LYX_DEBUG)
1096 list(APPEND tmp_vi "  C++ Compiler user flags: ${CMAKE_CXX_FLAGS_DEBUG}")
1097 else()
1098 list(APPEND tmp_vi "  C++ Compiler user flags: ${CMAKE_CXX_FLAGS_RELEASE}")
1099 endif()
1100 list(APPEND tmp_vi "  Qt version:              ${QTVERSION}")
1101 list(APPEND tmp_vi "  LyX binary dir:          ${CMAKE_INSTALL_PREFIX}/${LYX_UTILITIES_INSTALL_PATH}")
1102 get_data_destination(dest_data)
1103 list(APPEND tmp_vi "  LyX files dir:           ${CMAKE_INSTALL_PREFIX}/${dest_data}")
1104 string(REPLACE ";" "\\n" VERSION_INFO "${tmp_vi}")
1105
1106 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
1107 unset(opts)
1108 unset(tmp_vi)
1109
1110 if(QTVERSION MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+).*")
1111         MATH(EXPR QT4_VERSION "(${CMAKE_MATCH_1}<<16)|(${CMAKE_MATCH_2}<<8)|${CMAKE_MATCH_3}")
1112 endif()
1113
1114 if (NOT HAVE_REGEX)
1115         set(LYX_USE_STD_REGEX 0)
1116 endif()
1117
1118
1119 set (cmd ${CMAKE_CTEST_COMMAND})
1120 if (MSVC)
1121         set (cmd ${cmd} -C ${CMAKE_CFG_INTDIR})
1122 else ()
1123         set (cmd ${cmd} -C ${CMAKE_BUILD_TYPE})
1124 endif ()
1125 add_custom_target (lyx_run_tests COMMAND ${cmd})
1126 set_target_properties(lyx_run_tests PROPERTIES FOLDER "tests")
1127
1128 if(LYX_ASAN)
1129     set(LYX_CXX_FLAGS "-fsanitize=address -fno-omit-frame-pointer -g")
1130     message(STATUS)
1131     message(STATUS "Address sanitizer enabled. Usage:")
1132     message(STATUS "    wget https://llvm.org/svn/llvm-project/compiler-rt/trunk/lib/asan/scripts/asan_symbolize.py")
1133     message(STATUS "    chmod  +x ./asan_symbolize.py")
1134     message(STATUS "    ./bin/lyx2.2 2>&1 | ./asan_symbolize.py  | c++filt ")
1135     message(STATUS)
1136 endif()
1137
1138 if(LYX_INSTALL)
1139         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
1140                 message(STATUS "Python required to create doc!")
1141         else()
1142                 if(UNIX)
1143                         add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
1144                 endif()
1145                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
1146         endif()
1147 endif()
1148 include(../Install)
1149
1150 # By running the URL tests first, time can be saved when running the ctests in
1151 # parallel since the URL tests take a long time to run (e.g. 10 minutes).
1152 if(LYX_ENABLE_URLTESTS)
1153         add_subdirectory(development/checkurls "${TOP_BINARY_DIR}/checkurls")
1154 endif()
1155 add_subdirectory(src "${TOP_BINARY_DIR}/src")
1156 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
1157 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
1158 add_subdirectory(lib/examples "${TOP_BINARY_DIR}/lib/examples")
1159 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
1160 add_subdirectory(development/autotests "${TOP_BINARY_DIR}/autotests")
1161 add_subdirectory(development/batchtests "${TOP_BINARY_DIR}/batchtests")
1162
1163 message(STATUS)
1164 message(STATUS "Build params, switch LYX_* options by -DLYX_*=ON or OFF, LYX_* combos by -DLYX_*=value:")
1165 message(STATUS)
1166
1167 LYX_OPTION_LIST_ALL(used)
1168
1169
1170 if(LYX_NLS)
1171         message(STATUS)
1172         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
1173         message(STATUS)
1174         message(STATUS "  * iconv")
1175         message(STATUS "     - include: ${ICONV_INCLUDE_DIR}")
1176         message(STATUS "     - library: ${ICONV_LIBRARY}")
1177         message(STATUS "  * zlib")
1178         message(STATUS "     - include: ${ZLIB_INCLUDE_DIR}")
1179         message(STATUS "     - library: ${ZLIB_LIBRARY}")
1180         message(STATUS)
1181 endif()
1182
1183 # Apple has builtin native spell checker,
1184 # no need to warn for missing Aspell, Hunspell or Enchant
1185 if(NOT Spelling_FOUND AND NOT APPLE)
1186   if(LYX_REQUIRE_SPELLCHECK)
1187     set(_mode "FATAL_ERROR")
1188   else()
1189     set(_mode "STATUS")
1190   endif()
1191   message(${_mode} "No spellcheck libraries found. LyX will be unable use spellchecking")
1192 endif()
1193
1194 include("${TOP_CMAKE_PATH}/LyxPackaging.cmake")
1195
1196 if(ENABLE_DIST)
1197   # Use git to create the source package
1198   # git archive --format=tgz --output=/home/kornel/x.tar.gz master
1199   if(UNIX)
1200     set(DIST_FORMAT tgz)
1201   else()
1202     set(DIST_FORMAT zip)
1203   endif()
1204   set(DIST_NAME ${CMAKE_PROJECT_NAME}-${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}-${CMAKE_SYSTEM_NAME}.${DIST_FORMAT})
1205
1206   add_custom_command(
1207     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME}
1208     COMMAND  ${LYX_GITVERSION} archive --format=${DIST_FORMAT} --output=${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME} master
1209     WORKING_DIRECTORY ${TOP_SRC_DIR})
1210   add_custom_target(git-archive DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME})
1211 endif()
1212
1213 # Last directory to be included so that the fixup code (OS X)
1214 # can be run last
1215 add_subdirectory(development/cmake/post_install)
1216
1217 message(STATUS)