CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 2.6.4)
   8
   9 set(LYX_PROJECT LyX)
  10
  11 enable_testing()
  12
  13 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README ABSOLUTE)
  14 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  15
  16 set(LYX_CMAKE_DIR "development/cmake")
  17 set(TOP_CMAKE_PATH "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}")
  18 set(TOP_MODULE_PATH "${TOP_CMAKE_PATH}/modules")
  19 set(TOP_SCRIPT_PATH "${TOP_CMAKE_PATH}/scripts")
  20
  21 set(CMAKE_MODULE_PATH "${TOP_MODULE_PATH}")
  22
  23 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  24
  25 message(STATUS)
  26 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  27         message(STATUS "Building in-source")
  28         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  29 else()
  30         message(STATUS "Building out-of-source")
  31         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  32 endif()
  33
  34
  35 if(COMMAND cmake_policy)
  36         cmake_policy(SET CMP0003 OLD)
  37         cmake_policy(SET CMP0005 OLD)
  38 endif()
  39
  40 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  41
  42 # Supress regeneration
  43 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  44
  45 if(NOT help AND NOT HELP)
  46         # 'project' triggers the searching for a compiler
  47         project(${LYX_PROJECT})
  48 endif()
  49
  50 if(UNIX)
  51         set(ARCH_TRIPLET )
  52         FIND_PROGRAM(DPKG_ARCHITECTURE_EXECUTABLE dpkg-architecture)
  53         if(DPKG_ARCHITECTURE_EXECUTABLE)
  54                 EXECUTE_PROCESS(COMMAND ${DPKG_ARCHITECTURE_EXECUTABLE} -qDEB_HOST_MULTIARCH
  55                                 OUTPUT_VARIABLE ARCH_TRIPLET
  56                                 ERROR_VARIABLE ERROR_ARCH_TRIPLET
  57                                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  58         endif()
  59 endif()
  60 if(ARCH_TRIPLET)
  61         set(SYSTEM_LIB_DIRS /usr/lib /usr/lib/${ARCH_TRIPLET} /usr/local/lib)
  62 else()
  63         set(SYSTEM_LIB_DIRS /usr/lib /usr/local/lib)
  64 endif()
  65
  66 include(LyXMacros)
  67
  68 # Usage LYX_OPTION
  69 # 1. parameter: option name without prefix 'LYX_'
  70 # 2. parameter: description
  71 # 3. parameter: default value, ON or OFF
  72 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
  73
  74
  75 LYX_OPTION_INIT()
  76
  77 # Options for all compilers/systems
  78 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
  79 LYX_OPTION(LOCALVERSIONING  "Add version info to created package name (only used if LYX_CPACK option set)" OFF ALL)
  80 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
  81 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
  82 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
  83 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
  84 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
  85 LYX_OPTION(DEVEL_VERSION    "Build developer version" OFF ALL)
  86 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" OFF ALL)
  87 LYX_OPTION(DEBUG            "Enforce debug build"  OFF ALL)
  88 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
  89 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
  90 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
  91 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
  92 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
  93 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
  94 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
  95 LYX_OPTION(EXTERNAL_LIBINTL "Use external libintl" ON ALL)
  96 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
  97
  98 # GCC specific
  99 LYX_OPTION(PROFILE              "Build profile version" OFF GCC)
 100 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" OFF GCC)
 101 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
 102 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
 103 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++pedantic debug mode" OFF GCC)
 104 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" OFF GCC)
 105 LYX_OPTION(CONCEPT_CHECKS       "Enable concept-checks" OFF GCC)
 106 LYX_OPTION(PROFILE              "Build with options for gprof" OFF GCC)
 107 LYX_OPTION(ENABLE_CXX11         "Build with options for c++11-mode" OFF GCC)
 108
 109 # MSVC specific
 110 LYX_OPTION(CONSOLE               "Show console on Windows, enforce with =FORCE" ON MSVC)
 111 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
 112 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
 113 LYX_OPTION(CONFIGURE_CHECKS      "Also run configure checks for MSVC" OFF MSVC)
 114 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
 115
 116 # APPLE specific
 117 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
 118 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
 119
 120
 121 if(help OR HELP)
 122         message(STATUS)
 123         message(STATUS "Available options: (dis/enable with -DLYX_*=OFF/ON)")
 124         message(STATUS)
 125         LYX_OPTION_LIST_ALL(help)
 126         message(STATUS)
 127         RETURN()
 128 endif()
 129
 130 # Check option dependencies
 131
 132 if(LYX_CPACK)
 133         set(LYX_INSTALL ON)
 134 endif()
 135
 136 if(LYX_DMG)
 137         set(LYX_BUNDLE ON)
 138         set(LYX_CPACK ON)
 139 endif()
 140
 141 if(LYX_INSTALL)
 142         set(LYX_NLS ON)
 143         if (WIN32)
 144                 set(LYX_HUNSPELL ON)
 145         endif()
 146         if(LYX_CONSOLE MATCHES "FORCE")
 147                 set(LYX_CONSOLE ON)
 148         else()
 149                 set(LYX_CONSOLE OFF)
 150         endif()
 151         set(LYX_PACKAGE_SUFFIX ON)
 152         set(LYX_RELEASE ON)
 153         set(LYX_PROFILE OFF)
 154 endif()
 155
 156
 157 if(LYX_MERGE_FILES)
 158         set(LYX_PCH OFF)
 159 else()
 160         set(LYX_MERGE_REBUILD OFF)
 161 endif()
 162
 163 if(LYX_DEPENDENCIES_DOWNLOAD)
 164         message(STATUS)
 165         set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 166         message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 167         set(deps_files lyx20-deps-msvc2010-x86.zip)
 168         set(deps_server http://downloads.sourceforge.net/project/lyx/Win_installers/Dependencies)
 169         foreach(it ${deps_files})
 170                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 171                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 172                 if(NOT already_downloaded)
 173                         message(STATUS "Downloading ${it} ...")
 174                         file(DOWNLOAD ${deps_server}/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS STATUS status LOG log)
 175                         list(GET status 0 status_code)
 176                         list(GET status 1 status_string)
 177                         if(NOT status_code EQUAL 0)
 178                                 file(REMOVE ${LYX_DEPENDENCIES_DIR}/${it})
 179                                 message(FATAL_ERROR "error: downloading '${it}' failed. status_code: ${status_code}, status_string: ${status_string}. \nLog: ${log} ")
 180                         endif()
 181                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 182                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 183                 endif()
 184         endforeach()
 185         set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/deps20)
 186 endif()
 187
 188
 189
 190 message(STATUS)
 191
 192 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 193 if(WIN32)
 194         set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 195 else()
 196         set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 197 endif()
 198
 199
 200 set(LYX_GCC11_MODE)
 201 if(UNIX OR MINGW)
 202         execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION)
 203         message(STATUS "Using GCC version ${GCC_VERSION}")
 204         if(NOT GCC_VERSION VERSION_LESS 4.4)
 205                 set(LYX_USE_TR1 1)
 206                 # GCC <= 4.5 does not support regex: there are linker errors
 207                 # http://gcc.gnu.org/onlinedocs/libstdc++/manual/status.html#status.iso.tr1
 208                 set(LYX_USE_TR1_REGEX 0)
 209         endif()
 210         if (LYX_ENABLE_CXX11)
 211                 if(GCC_VERSION VERSION_GREATER 4.7)
 212                         set(LYX_GCC11_MODE "-std=gnu++11")
 213                 elseif(GCC_VERSION VERSION_GREATER 4.2)
 214                         set(LYX_GCC11_MODE "-std=gnu++0x")
 215                 endif()
 216         endif()
 217 else()
 218         if(MSVC10)
 219                 set(LYX_USE_TR1 1)
 220                 #set(LYX_USE_TR1_REGEX 1) #TODO should we use it in ECMAScript mode?
 221         endif()
 222 endif()
 223
 224
 225 set(VERSION_INFO "CMake Build")
 226
 227 # Try to get some informations from configure.ac
 228
 229 include(LyXPaths)
 230 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 231
 232 if(WIN32)
 233         set(USE_WINDOWS_PACKAGING ON)
 234 elseif(APPLE)
 235         set(USE_MACOSX_PACKAGING ON)
 236 else()
 237         set(USE_POSIX_PACKAGING ON)
 238 endif()
 239
 240 macro(setstripped _varname _value)
 241         string(STRIP ${_value} _v)
 242         if(USE_POSIX_PACKAGING)
 243                 string(TOLOWER ${_v} ${_varname})
 244         else()
 245                 set(${_varname} ${_v})
 246         endif()
 247 endmacro(setstripped)
 248
 249 foreach(_c_l ${_config_lines} )
 250         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 251                 setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 252                 setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 253                 setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 254                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\)\(\\.\([0-9]+\)\)?.*$")
 255                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 256                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 257                         set(LYX_PATCH_VERSION ${CMAKE_MATCH_4})
 258                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 259                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 260                         set(LYX_INSTALL_SUFFIX "${CMAKE_MATCH_1}.${CMAKE_MATCH_2}")
 261                 endif()
 262         endif()
 263         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 264                 set(LYX_DATE "${CMAKE_MATCH_1}")
 265         endif()
 266 endforeach(_c_l)
 267
 268 if (LYX_LOCALVERSIONING)
 269         # Find the revision number and for later use
 270         FIND_PROGRAM(LYX_GITVERSION git)
 271         #message(STATUS "gitversion = ${LYX_GITVERSION}")
 272         if(LYX_GITVERSION)
 273                 EXECUTE_PROCESS(COMMAND ${LYX_GITVERSION} "describe" WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE LYX_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 274                 if (LYX_PACKAGE_RELEASE MATCHES "^2\\.0\\.0\\-\([0-9]+\)\\-.*$")
 275                   # We will add offset of 40000 to get appropriate value to
 276                   # previous svn.
 277                   # We use this value than also to set the package-patch-value
 278                   MATH(EXPR tmp_REVISION_VERSION "(${CMAKE_MATCH_1}+40000)")
 279                   set(LYX_REVISION_VERSION "${LYX_PATCH_VERSION}-${tmp_REVISION_VERSION}git")
 280                 endif()
 281         else()
 282                 set(LYX_REVISION_VERSION git) #TODO use date
 283         endif()
 284 else()
 285         set(LYX_REVISION_VERSION ${LYX_PATCH_VERSION})
 286 endif()
 287
 288 if(LYX_PROGRAM_SUFFIX)
 289         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 290 else()
 291         set(PROGRAM_SUFFIX "")
 292 endif()
 293
 294 add_custom_target(lyx_version ALL
 295   COMMAND ${CMAKE_COMMAND} -DTOP_SRC_DIR=${TOP_SRC_DIR} -DTOP_CMAKE_PATH=${TOP_CMAKE_PATH} -DTOP_BINARY_DIR=${TOP_BINARY_DIR} -DLYX_DATE=${LYX_DATE} -P ${TOP_SCRIPT_PATH}/LyXGetVersion.cmake
 296   )
 297 set_target_properties(lyx_version PROPERTIES FOLDER "applications")
 298
 299 if(APPLE)
 300         set(osx_bundle_program_name ${PACKAGE_BASE}${PROGRAM_SUFFIX})
 301         configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/Info.plist.in" "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 302 endif()
 303
 304 if(LYX_BUNDLE)
 305         set(LYX_CPACK ON)
 306         message(STATUS)
 307         message(STATUS "Bundle creation is enabled (experimental):")
 308         message(STATUS "    make")
 309         message(STATUS "    make install/strip")
 310         message(STATUS "    make package")
 311         if(APPLE)
 312                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 313                 set(CPACK_BUNDLE_NAME ${PACKAGE_BASE}${PROGRAM_SUFFIX})
 314                 set(CPACK_BUNDLE_PLIST "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 315                 set(LYX_DATA_SUBDIR ${PACKAGE_BASE}${PROGRAM_SUFFIX}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 316                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${PACKAGE_BASE}${PROGRAM_SUFFIX}.app)
 317                 if(NOT LYX_INSTALL_PREFIX)
 318                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 319                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 320                 endif()
 321                 # Change the owner so that the install can work
 322                 install(CODE "set(BU_CHMOD_BUNDLE_ITEMS 1)")
 323         elseif(UNIX)
 324                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 325                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 326                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 327         elseif(WIN32)
 328                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 329         endif()
 330 endif()
 331
 332 if(LYX_INSTALL_PREFIX)
 333         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 334         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 335 endif()
 336 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 337
 338 if(LYX_PACKAGE_SUFFIX)
 339         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 340 else()
 341         set(PACKAGE ${PACKAGE_BASE})
 342 endif()
 343
 344
 345 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 346         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 347         if (UNIX)
 348                 # don't use the default "/usr/local"
 349                 # but respect the user-choice on the command-line
 350                 if(LYX_INSTALL_SUFFIX)
 351                         set(CMAKE_INSTALL_PREFIX "/usr/local/lyx${LYX_INSTALL_SUFFIX}" CACHE PATH "LyX default install prefix" FORCE)
 352                 else()
 353                         set(CMAKE_INSTALL_PREFIX "/usr/local/${LYX_PROJECT}" CACHE PATH "LyX default install prefix" FORCE)
 354                 endif()
 355         endif()
 356         if(WIN32)
 357                 set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 358         endif()
 359 endif()
 360 if(IS_ABSOLUTE)
 361         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 362 else()
 363         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 364 endif()
 365
 366
 367
 368 if(NOT LYX_DATA_SUBDIR)
 369         if (WIN32)
 370                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 371         else()
 372                 set(LYX_DATA_SUBDIR "" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 373         endif()
 374 endif()
 375
 376 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 377 set(LYX_LOCALEDIR "locale")
 378 set(LYX_ABS_INSTALLED_LOCALEDIR "${LYX_ABS_INSTALLED_DATADIR}/${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}")
 379 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 380
 381
 382 if(LYX_INSTALL AND WIN32)
 383         message(STATUS "Configuring NSIS files")
 384         configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 385         configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 386         configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 387         message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 388 endif()
 389
 390 if(NOT GROUP_CODE)
 391         #set(GROUP_CODE "The Golden Code")
 392         set(GROUP_CODE flat)
 393 endif()
 394
 395 # lyx's source files
 396 set(LYX_CPP_FILES *.cpp)
 397 set(LYX_HPP_FILES *.h)
 398 set(LYX_MOC_FILES moc_*.cpp)
 399
 400 include(ProjectSourceGroup)
 401
 402
 403 if(LYX_PROFILE AND NOT MSVC)
 404         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 405         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg")
 406         set(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS}  -pg")
 407 else()
 408         set(LYX_PROFILE OFF)
 409 endif()
 410
 411
 412 if(LYX_NO_OPTIMIZE)
 413         set(CMAKE_BUILD_TYPE None)
 414         set(LYX_DEBUG OFF)
 415         set(LYX_RELEASE OFF)
 416         set(LYX_PROFILE OFF)
 417 elseif(LYX_RELEASE)
 418         set(CMAKE_BUILD_TYPE Release)
 419         set(LYX_DEBUG OFF)
 420         set(LYX_PROFILE OFF)
 421 elseif(LYX_PROFILE)
 422         set(CMAKE_BUILD_TYPE Profile)
 423         set(LYX_DEBUG OFF)
 424 else()
 425         set(CMAKE_BUILD_TYPE Debug)
 426         set(LYX_DEBUG ON)
 427 endif()
 428
 429
 430 # When shared libs are supported enable this option
 431 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 432 if(LYX_SHARED_LIBRARIES)
 433         set(library_type SHARED)
 434 else()
 435         set(library_type STATIC)
 436 endif()
 437
 438 if(NOT MSVC)
 439         if(NOT LYX_QUIET)
 440                 set(CMAKE_VERBOSE_MAKEFILE ON)
 441         endif()
 442         set(LYX_CXX_FLAGS "-Wall -Wunused-parameter ${LYX_GCC11_MODE}")
 443         if(LYX_STDLIB_DEBUG)
 444                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 445         endif()
 446         if(LYX_CONCEPT_CHECKS)
 447                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCPP_CONCEPT_CHECKS")
 448         endif()
 449         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 450         set(CMAKE_CXX_FLAGS_DEBUG "${LYX_CXX_FLAGS} -fno-strict-aliasing -O0 -g -D_DEBUG" CACHE TYPE STRING FORCE)
 451         if(MINGW)
 452                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 453         else()
 454                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 455         endif()
 456 endif()
 457
 458
 459 find_package(Qt4 REQUIRED)
 460 find_package(Magic)
 461 if(Magic_FOUND)
 462         set(HAVE_MAGIC_H 1)
 463 endif()
 464
 465 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 466
 467 if(LYX_ASPELL)
 468         find_package(ASPELL)
 469         include_directories(${ASPELL_INCLUDE_DIR})
 470 endif()
 471
 472 if(LYX_ENCHANT)
 473         find_package(Enchant REQUIRED)
 474         include_directories(${ENCHANT_INCLUDE_DIR})
 475 endif()
 476
 477 if(LYX_HUNSPELL)
 478         find_package(Hunspell REQUIRED)
 479         include_directories(${HUNSPELL_INCLUDE_DIR})
 480 endif()
 481
 482 if(LYX_NLS)
 483         FIND_PROGRAM(LYX_PYTHON_EXECUTABLE python2 python HINTS ${GNUWIN32_DIR}/python)
 484         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 485                 message(FATAL_ERROR "Python 2.6 needed!")
 486         endif()
 487         find_package(LyXGettext REQUIRED)
 488         add_subdirectory(po "${TOP_BINARY_DIR}/po")
 489 endif()
 490
 491 if(LYX_NLS)
 492         if(LYX_EXTERNAL_LIBINTL)
 493                 find_package(Libintl REQUIRED)
 494                 if(DEFINED LIBINTL_LIBRARIES)
 495                         # find getext when configuring
 496                         list(APPEND CMAKE_REQUIRED_LIBRARIES ${LIBINTL_LIBRARIES})
 497                         # on mac use iconv also form ports
 498                         get_filename_component(ICONV_RELATIVE_TO_LIBINTL ${LIBINTL_LIBRARIES} PATH)
 499                 endif()
 500         else()
 501                 add_subdirectory(intl "${TOP_BINARY_DIR}/intl")
 502         endif()
 503 endif()
 504
 505 if(LYX_EXTERNAL_LIBINTL)
 506         set(intl_link ${LIBINTL_LIBRARIES})
 507 else()
 508         set(intl_link intl)
 509 endif()
 510
 511 find_package(ICONV REQUIRED)
 512 find_package(ZLIB REQUIRED)
 513
 514 if(LYX_EXTERNAL_BOOST)
 515         message(STATUS "Searching for boost")
 516         find_package(Boost COMPONENTS signals regex) #TODO could REQUIRED be used
 517         if(Boost_FOUND)
 518                 message(STATUS "Boost found")
 519                 message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 520                 set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 521         else()
 522                 message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 523         endif()
 524 else()
 525         if(LYX_USE_TR1_REGEX)
 526                 set(Lyx_Boost_Libraries boost_signals)
 527         else()
 528                 set(Lyx_Boost_Libraries boost_signals boost_regex)
 529         endif()
 530         add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 531         include_directories(${TOP_SRC_DIR}/boost)
 532         add_subdirectory(boost "${TOP_BINARY_DIR}/boost")
 533 endif()
 534
 535
 536
 537
 538 if(WIN32)
 539         if(NOT LYX_CONSOLE)
 540                 set(WIN32_CONSOLE WIN32)
 541                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARY})
 542         endif()
 543         if(MSVC)
 544                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 545                 # disable checked iterators for msvc release builds to get maximum speed
 546                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 547         else()
 548                 add_definitions(-DWINVER=0x0500)
 549         endif()
 550 endif()
 551
 552 # Compute qt4-version from ${QTVERSION}
 553
 554 message(STATUS "")
 555 foreach(_v PACKAGE PACKAGE_VERSION
 556         PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 557         LYX_ABS_TOP_SRCDIR
 558         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 559         if(NOT DEFINED ${_v})
 560                 message(FATAL_ERROR "${_v} not defined")
 561         endif()
 562         string(SUBSTRING "${_v}                            " 0 28 _v1)
 563         message(STATUS "----- ${_v1}: ${${_v}}")
 564 endforeach(_v)
 565 message(STATUS "")
 566
 567
 568 if(LYX_PCH)
 569         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 570         # Not sure if it works for all non-msvc compilers
 571         include(PCHSupport_26)
 572         configure_file(${TOP_CMAKE_PATH}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
 573         configure_file(${TOP_CMAKE_PATH}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 574         add_definitions(-DLYX_ENABLE_PCH)
 575
 576         if(MSVC)
 577                 macro(lyx_add_msvc_pch name_)
 578                         set_source_files_properties(${${name_}_sources} PROPERTIES
 579                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 580                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
 581                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 582                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
 583                                 ${TOP_BINARY_DIR}/pcheaders.h)
 584                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 585                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 586                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 587                 endmacro(lyx_add_msvc_pch)
 588                 macro(lyx_add_gcc_pch name_)
 589                 endmacro()
 590         else()
 591                 macro(lyx_add_msvc_pch name_)
 592                 endmacro()
 593                 macro(lyx_add_gcc_pch name_)
 594                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT4)
 595                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
 596                 endmacro()
 597         endif()
 598 else()
 599         macro(lyx_add_msvc_pch)
 600         endmacro(lyx_add_msvc_pch)
 601         macro(lyx_add_gcc_pch name_)
 602         endmacro()
 603 endif()
 604
 605
 606 if(MSVC)
 607
 608         if(LYX_VLD)
 609                 set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/development/Win32/vld)
 610                 add_subdirectory(${vld_path}/cmake)
 611                 include(${vld_path}/cmake/vld.cmake) # forced include
 612                 set(vld_dll vld)
 613         endif()
 614
 615         if(LYX_WALL)
 616                 # Use the highest warning level
 617                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 618
 619                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 620                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 621                 else()
 622                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 623                 endif()
 624
 625                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 626                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 627                 else()
 628                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 629                 endif()
 630
 631                 # add here warnings which should produce an error /weXXXX
 632                 set(MSVC_W_ERROR   "/we4101 /we4189")
 633                 # add here warnings which should be disabled /wdXXXX
 634                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 635
 636                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 637                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 638                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 639
 640         else()
 641                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 642
 643                 # add here warnings which should produce an error /weXXXX
 644                 set(MSVC_W_ERROR   "/we4101 /we4189")
 645                 # add here warnings which should be disabled /wdXXXX
 646                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 647
 648                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 649                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 650                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 651
 652         endif()
 653         set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 654         set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 655         set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 656
 657         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 658         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 659         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 660         message(STATUS "")
 661 endif()
 662
 663
 664 if(LYX_DEBUG_GLIBC)
 665         set(_GLIBCXX_DEBUG ON)
 666 endif()
 667
 668 if(LYX_DEBUG_GLIBC_PEDANTIC)
 669         set(_GLIBCXX_DEBUG_PEDANTIC ON)
 670 endif()
 671
 672 # Xcode compiler
 673 if (CMAKE_GENERATOR MATCHES Xcode)
 674         # Automatically select the Xcode compiler if not set
 675         if (NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 676                 # XCode >= 3.1 has gcc 4.2 (up to actual Xcode)
 677                 if (XCODE_VERSION VERSION_GREATER "3.1")
 678                         SET(CMAKE_XCODE_ATTRIBUTE_GCC_VERSION "com.apple.compilers.llvmgcc42")
 679                 ENDIF(XCODE_VERSION VERSION_GREATER "3.1")
 680         ENDIF(NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 681
 682         # Print the selected compiler version
 683     MESSAGE(STATUS "---- Using XCode compiler CMAKE_XCODE_ATTRIBUTE_GCC_VERSION=${CMAKE_XCODE_ATTRIBUTE_GCC_VERSION}")
 684 ENDIF(CMAKE_GENERATOR MATCHES Xcode)
 685
 686
 687 # compiler tests, config.h generation
 688 if(MSVC AND NOT LYX_CONFIGURE_CHECKS)
 689         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.msvc ${TOP_BINARY_DIR}/configCompiler.h)
 690 else()
 691         include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
 692         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
 693 endif()
 694
 695 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
 696
 697 if(QTVERSION MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+).*")
 698         MATH(EXPR QT4_VERSION "(${CMAKE_MATCH_1}<<16)|(${CMAKE_MATCH_2}<<8)|${CMAKE_MATCH_3}")
 699 endif()
 700
 701 set(_lyx "${PACKAGE_BASE}${PROGRAM_SUFFIX}")
 702 set(_tex2lyx tex2lyx${PROGRAM_SUFFIX})
 703 add_subdirectory(src "${TOP_BINARY_DIR}/src")
 704 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
 705 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
 706 add_subdirectory(lib/examples "${TOP_BINARY_DIR}/lib/examples")
 707
 708
 709 if(LYX_INSTALL)
 710         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 711                 message(STATUS "Python required to create doc!")
 712         else()
 713                 add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
 714                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
 715         endif()
 716         if(NOT(LYX_BUNDLE AND APPLE))
 717                 include(../Install)
 718         endif()
 719 endif()
 720
 721 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
 722 add_subdirectory(development/autotests "${TOP_BINARY_DIR}/autotests")
 723
 724 message(STATUS)
 725 message(STATUS "Build options, switch LYX_* variables by -DLYX_*=ON or OFF:")
 726 message(STATUS)
 727 LYX_OPTION_LIST_ALL(used)
 728
 729
 730 if(LYX_NLS)
 731         message(STATUS)
 732         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
 733         message(STATUS)
 734         message(STATUS "  * intl")
 735         message(STATUS "     - header : ${LIBINTL_HEADER}")
 736         message(STATUS "     - library: ${LIBINTL_LIBRARIES}")
 737         message(STATUS "  * iconv")
 738         message(STATUS "     - header : ${ICONV_HEADER}")
 739         message(STATUS "     - library: ${ICONV_LIBRARY}")
 740         message(STATUS "  * zlib")
 741         message(STATUS "     - header : ${ZLIB_HEADER}")
 742         message(STATUS "     - library: ${ZLIB_LIBRARY}")
 743         message(STATUS)
 744 endif()
 745
 746 include("${TOP_CMAKE_PATH}/LyxPackaging.cmake")
 747
 748 message(STATUS)