CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 3.1.0)
   8
   9 set(LYX_PROJECT LyX)
  10
  11 # Instruct cmake to not use gnu extensions,
  12 # this prevents the mix of '-std=c++*' and '-std=gnu++*' flags
  13 set(CMAKE_CXX_EXTENSIONS OFF)
  14
  15 enable_testing()
  16
  17 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README REALPATH) # Resolve symlinks
  18 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  19 message(STATUS "TOP_SRC_DIR = ${TOP_SRC_DIR}")
  20
  21 set(LYX_CMAKE_DIR "development/cmake")
  22 set(TOP_CMAKE_PATH "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}")
  23 set(TOP_MODULE_PATH "${TOP_CMAKE_PATH}/modules")
  24 set(TOP_SCRIPT_PATH "${TOP_CMAKE_PATH}/scripts")
  25
  26 set(CMAKE_MODULE_PATH "${TOP_MODULE_PATH}")
  27
  28 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  29
  30 message(STATUS)
  31 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  32         message(STATUS "Building in-source")
  33         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  34 else()
  35         message(STATUS "Building out-of-source")
  36         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  37 endif()
  38
  39 # This directory should be used if some test uses lyx-executable
  40 set(LYX_TESTS_USERDIR "${TOP_BINARY_DIR}/Testing/.lyx")
  41 file(MAKE_DIRECTORY "${LYX_TESTS_USERDIR}")
  42
  43 if(COMMAND cmake_policy)
  44         # Installing MACOSX_BUNDLE targets requires a BUNDLE DESTINATION
  45         cmake_policy(SET CMP0006 NEW)
  46         if(POLICY CMP0043)
  47                 # COMPILE_DEFINITIONS are not used yet. Enable new behavior.
  48                 cmake_policy(SET CMP0043 NEW)
  49         endif()
  50         cmake_policy(SET CMP0020 NEW)
  51         if(POLICY CMP0075)
  52                 cmake_policy(SET CMP0075 NEW)
  53         endif()
  54 endif()
  55
  56 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  57
  58 # Supress regeneration
  59 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  60
  61 if(LYX_XMINGW)
  62     set(CMAKE_SYSTEM_NAME Windows)
  63     set(TOOLNAME ${LYX_XMINGW})
  64     set(TOOLCHAIN "${TOOLNAME}-")
  65     set(CMAKE_C_COMPILER   "${TOOLCHAIN}gcc"     CACHE PATH "Mingw C compiler" FORCE)
  66     set(CMAKE_CXX_COMPILER "${TOOLCHAIN}g++"     CACHE PATH "Mingw C++ compiler" FORCE)
  67     set(CMAKE_RC_COMPILER  "${TOOLCHAIN}windres" CACHE PATH "Mingw rc compiler" FORCE)
  68
  69     set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM BOTH)
  70     set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY)
  71     set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY)
  72 endif()
  73
  74 if(NOT help AND NOT HELP)
  75   # 'project' triggers the searching for a compiler
  76   project(${LYX_PROJECT})
  77   if (CMAKE_COMPILER_IS_GNUCXX)
  78     if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS "4.0")
  79       message(STATUS "Gnu CXX compiler version = ${CMAKE_CXX_COMPILER_VERSION}")
  80       message(STATUS "is too old, should be >= 4.0")
  81       message(FATAL_ERROR "Exiting")
  82     endif()
  83   endif()
  84 endif()
  85
  86 if(UNIX)
  87         set(ARCH_TRIPLET )
  88         FIND_PROGRAM(DPKG_ARCHITECTURE_EXECUTABLE dpkg-architecture)
  89         if(DPKG_ARCHITECTURE_EXECUTABLE)
  90                 EXECUTE_PROCESS(COMMAND ${DPKG_ARCHITECTURE_EXECUTABLE} -qDEB_HOST_MULTIARCH
  91                                 OUTPUT_VARIABLE ARCH_TRIPLET
  92                                 ERROR_VARIABLE ERROR_ARCH_TRIPLET
  93                                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  94         endif()
  95 endif()
  96 if(ARCH_TRIPLET)
  97         set(SYSTEM_LIB_DIRS /usr/lib /usr/lib/${ARCH_TRIPLET} /usr/local/lib)
  98 else()
  99         set(SYSTEM_LIB_DIRS /usr/lib /usr/local/lib)
 100 endif()
 101
 102 include(LyXMacros)
 103 include(LyXDestinations)
 104
 105 # Try to get some informations from configure.ac
 106
 107 include(LyXPaths)
 108 determineversionandbuildtype("${TOP_SRC_DIR}/configure.ac" _package_list _version_list _envlist LYX_DATE LYX_BUILD_TYPE)
 109 list(GET _package_list 0 PACKAGE_BASE)
 110 list(GET _package_list 1 PACKAGE_VERSION)
 111 list(GET _package_list 2 PACKAGE_BUGREPORT)
 112 list(GET _envlist 0 LYX_DIR_VER)
 113 list(GET _envlist 1 LYX_USERDIR_VER)
 114 list(GET _version_list 0 LYX_VERSION)
 115 list(GET _version_list 1 LYX_MAJOR_VERSION)
 116 list(GET _version_list 2 LYX_MINOR_VERSION)
 117 list(GET _version_list 3 LYX_RELEASE_LEVEL)
 118 list(GET _version_list 4 LYX_RELEASE_PATCH)
 119
 120 # Usage LYX_OPTION
 121 # 1. parameter: option name without prefix 'LYX_'
 122 # 2. parameter: description
 123 # 3. parameter: default value, ON or OFF
 124 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
 125
 126 # Usage LYX_COMBO
 127 # 1. parameter: name without prefix 'LYX_'
 128 # 2. parameter: description
 129 # 3. parameter: default value
 130 # 4-n parameter: possible other string values
 131
 132 LYX_OPTION_INIT()
 133
 134 # Options for all compilers/systems
 135 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
 136 LYX_OPTION(LOCALVERSIONING  "Add version info to created package name (only used if LYX_CPACK option set)" OFF ALL)
 137 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
 138 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
 139 LYX_OPTION(REQUIRE_SPELLCHECK "Abort if no spellchecker available" OFF ALL)
 140 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
 141 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
 142 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
 143 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" OFF ALL)
 144 LYX_OPTION(DEBUG            "Enforce debug build"  OFF ALL)
 145 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
 146 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
 147 LYX_STRING(SUFFIX_VALUE     "Use this string as suffix" "")
 148 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
 149 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
 150 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
 151 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
 152 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
 153 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
 154 LYX_OPTION(ENABLE_URLTESTS  "Enable for URL tests" OFF ALL)
 155 LYX_OPTION(ENABLE_EXPORT_TESTS "Enable for export tests" OFF ALL)
 156 LYX_OPTION(ENABLE_KEYTESTS  "Enable for keytests" OFF ALL)
 157 if (NOT CMAKE_VERSION VERSION_LESS "3.17")
 158   LYX_OPTION(ENABLE_VALGRIND_TESTS  "Enable for tests involving valgrind" OFF ALL)
 159 else()
 160   if (LYX_ENABLE_VALGRIND_TESTS)
 161     unset(LYX_ENABLE_VALGRIND_TESTS CACHE)
 162   endif()
 163 endif()
 164 LYX_OPTION(ASAN             "Use address sanitizer" OFF ALL)
 165 #LYX_COMBO(USE_FILEDIALOG    "Use native or QT file dialog" QT NATIVE)
 166 LYX_COMBO(USE_QT            "Use Qt version as frontend" AUTO QT4 QT5)
 167 LYX_COMBO(USE_IPO           "Interprocedural optimization" OFF AUTO ON)
 168 #LYX_OPTION(3RDPARTY_BUILD   "Build 3rdparty libs" OFF ALL)
 169 LYX_OPTION(DISABLE_CALLSTACK_PRINTING "do not print a callstack when crashing" OFF ALL)
 170 LYX_OPTION(EXTERNAL_Z       "OFF := Build 3rdparty lib zlib" ON ALL)
 171 LYX_OPTION(EXTERNAL_DTL     "OFF := Build 3rdparty commands dt2dv and dv2dt" ON ALL)
 172 LYX_OPTION(EXTERNAL_ICONV   "OFF := Build 3rdparty lib iconvlib" ON ALL)
 173 LYX_OPTION(EXTERNAL_HUNSPELL "OFF := Build 3rdparty lib hunspelllib" ON ALL)
 174 LYX_COMBO(EXTERNAL_MYTHES   "OFF := Build 3rdparty lib mytheslib" AUTO OFF ON)
 175
 176 # GCC specific
 177 LYX_OPTION(PROFILE              "Build with options for gprof" OFF GCC)
 178 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" OFF GCC)
 179 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
 180 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
 181 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++ pedantic debug mode" OFF GCC)
 182 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" OFF GCC)
 183
 184 # MSVC specific
 185 LYX_OPTION(CONSOLE               "Show console on Windows" ON MSVC)
 186 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
 187 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
 188 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
 189
 190 # APPLE specific
 191 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
 192 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
 193
 194
 195 if(help OR HELP)
 196         message(STATUS)
 197         message(STATUS "Available options: (dis/enable with -DLYX_*=OFF/ON)")
 198         message(STATUS)
 199         LYX_OPTION_LIST_ALL(help)
 200         message(STATUS)
 201         RETURN()
 202 endif()
 203
 204 if ("${LYX_SUFFIX_VALUE}" MATCHES "")
 205   set(LYX_INSTALL_SUFFIX "${LYX_MAJOR_VERSION}.${LYX_MINOR_VERSION}")
 206 else()
 207   set(LYX_INSTALL_SUFFIX "${LYX_SUFFIX_VALUE}")
 208 endif()
 209
 210 # Check option dependencies
 211 if (LYX_ENABLE_VALGRIND_TESTS)
 212         find_program(VALGRIND_EXECUTABLE "valgrind")
 213         if (NOT VALGRIND_EXECUTABLE)
 214                 message(FATAL_ERROR "Cannot use valgrind tests, executable valgrind is missing. Please disable LYX_ENABLE_VALGRIND_TESTS")
 215         endif()
 216 endif()
 217 if (LYX_DEBUG_GLIBC OR LYX_DEBUG_GLIBC_PEDANTIC OR LYX_STDLIB_DEBUG)
 218   if (LYX_EXTERNAL_BOOST)
 219     message(FATAL_ERROR "Using external boost not compatible with debug mode for stdlib")
 220   endif()
 221 endif()
 222
 223 if(LYX_DMG)
 224         set(LYX_BUNDLE ON)
 225         set(LYX_CPACK ON)
 226 endif()
 227
 228 if(LYX_CPACK)
 229         set(LYX_INSTALL ON)
 230 endif()
 231
 232 if(LYX_INSTALL)
 233         set(LYX_NLS ON)
 234         if(WIN32 AND NOT MINGW)
 235                 set(LYX_HUNSPELL ON)
 236         endif()
 237         set(LYX_PACKAGE_SUFFIX ON)
 238         if(NOT LYX_DEBUG)
 239                 set(LYX_RELEASE ON)
 240         endif()
 241         set(LYX_PROFILE OFF)
 242 endif()
 243
 244
 245 if(LYX_MERGE_FILES)
 246         set(LYX_PCH OFF)
 247 else()
 248         set(LYX_MERGE_REBUILD OFF)
 249 endif()
 250
 251 if(LYX_DEPENDENCIES_DOWNLOAD)
 252         message(STATUS)
 253         if(MSVC14)
 254                 set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2015-deps)
 255                 set(deps_files lyx-windows-deps-msvc2015.zip)
 256                 set(deps_server http://ftp.lyx.de/LyX-Windows-Deps)
 257                 set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2015)
 258         elseif(MSVC10)
 259                 set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 260                 set(deps_files lyx-windows-deps-msvc2010.zip)
 261                 set(deps_server http://ftp.lyx.de/LyX-Windows-Deps)
 262                 set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2010)
 263         else()
 264                 message(FATAL_ERROR "error: no dependency package known for the selected MSVC version.")
 265         endif()
 266     message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 267         foreach(it ${deps_files})
 268                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 269                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 270                 if(NOT already_downloaded)
 271                         message(STATUS "Downloading ${it} ...")
 272                         file(DOWNLOAD ${deps_server}/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS STATUS status LOG log)
 273                         list(GET status 0 status_code)
 274                         list(GET status 1 status_string)
 275                         if(NOT status_code EQUAL 0)
 276                                 file(REMOVE ${LYX_DEPENDENCIES_DIR}/${it})
 277                                 message(FATAL_ERROR "error: downloading '${it}' failed. status_code: ${status_code}, status_string: ${status_string}. \nLog: ${log} ")
 278                         endif()
 279                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 280                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 281                 endif()
 282         endforeach()
 283 endif()
 284
 285 message(STATUS)
 286
 287 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 288 if(WIN32)
 289         set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 290 else()
 291         set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 292 endif()
 293
 294 set(LYX_IPO_SUPPORTED OFF)
 295 if (POLICY CMP0069)
 296   cmake_policy(SET CMP0069 NEW)
 297   if(LYX_USE_IPO MATCHES "AUTO")
 298     # Enable LTO if supported and not debugging
 299     if (NOT LYX_DEBUG)
 300       include(CheckIPOSupported)
 301       check_ipo_supported(RESULT LYX_IPO_SUPPORTED)
 302     endif()
 303   else()
 304     set(LYX_IPO_SUPPORTED ${LYX_USE_IPO})
 305   endif()
 306 endif()
 307 if (LYX_IPO_SUPPORTED)
 308   set(LYX_USE_IPO "ON" CACHE STRING "Use interprocedural optimization" FORCE)
 309 else()
 310   set(LYX_USE_IPO "OFF" CACHE STRING "Use interprocedural optimization" FORCE)
 311 endif()
 312
 313 # Set to some meaningful default
 314 find_package(CXX11Compiler)
 315 if(NOT CXX11COMPILER_FOUND)
 316         message(FATAL_ERROR "A C++11 compatible compiler is required.")
 317 endif()
 318 unset(LYX_GCC11_MODE)
 319 if(UNIX OR MINGW)
 320         if (CMAKE_CXX_COMPILER_ID MATCHES "^([cC]lang|AppleClang)$")
 321           # ignore the GCC_VERSION for clang
 322           # and use the resulting CXX11_STD_REGEX found in FindCXX11Compiler.cmake
 323           message(STATUS "Using clang")
 324           if(CXX11_STD_REGEX)
 325             set(LYX_USE_STD_REGEX 1)
 326           else()
 327             set(LYX_USE_STD_REGEX 0)
 328           endif()
 329         else()
 330           execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpfullversion OUTPUT_VARIABLE GCC_VERSION ERROR_VARIABLE _error RESULT_VARIABLE _err OUTPUT_STRIP_TRAILING_WHITESPACE)
 331           #message(STATUS "dumpfullversion: error = ${_error}, result = ${_err}")
 332           if (_err)
 333             # previous check failed, try again with _old_ parameter
 334             execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION ERROR_VARIABLE _error RESULT_VARIABLE _err OUTPUT_STRIP_TRAILING_WHITESPACE)
 335             #message(STATUS "dumpversion: error = ${_error}, result = ${_err}")
 336           endif()
 337           message(STATUS "Using GCC version ${GCC_VERSION}")
 338           if(GCC_VERSION VERSION_LESS 4.6)
 339                 message(FATAL_ERROR "gcc >= 4.6 is required.")
 340           elseif(GCC_VERSION VERSION_LESS 4.9)
 341                 # <regex> in gcc is unusable in versions less than 4.9.0
 342                 # see https://gcc.gnu.org/bugzilla/show_bug.cgi?id=53631
 343                 set(LYX_USE_STD_REGEX 0)
 344           else()
 345                 set(LYX_USE_STD_REGEX 1)
 346           endif()
 347         endif()
 348         set(LYX_GCC11_MODE "${CXX11_FLAG}")
 349 else()
 350         if(MSVC_VERSION LESS 1900)
 351                 # Drop support for msvc versions prior to 1900 (Visual Studio 2015)
 352                 message(FATAL_ERROR "Visual Studio >= 2015 is required.")
 353                 set(LYX_USE_STD_REGEX 0)
 354         else()
 355                 set(LYX_USE_STD_REGEX 1)
 356         endif()
 357 endif()
 358
 359 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 360
 361 if(WIN32)
 362         set(CMAKE_PREFIX_PATH Specify-path-to-Qt CACHE PATH "Used Qt version")
 363         if(MSVC)
 364                 set(LYX_3RDPARTY_BUILD ON CACHE BOOL "Build 3rdparty libraries" FORCE)
 365         endif()
 366         set(USE_WINDOWS_PACKAGING ON)
 367 elseif(APPLE)
 368         set(USE_MACOSX_PACKAGING ON)
 369 else()
 370         set(USE_POSIX_PACKAGING ON)
 371 endif()
 372
 373 if(LYX_3RDPARTY_BUILD)
 374   # LYX_3RDPARTY_BUILD is not cached anymore, but for compatibility reasons
 375   # this enables the build of all 3rd_party libs
 376   set(LYX_EXTERNAL_Z        OFF CACHE BOOL "Build 3rdparty lib zlib"    FORCE)
 377   set(LYX_EXTERNAL_ICONV    OFF CACHE BOOL "Build 3rdparty iconvlib"    FORCE)
 378   set(LYX_EXTERNAL_HUNSPELL OFF CACHE BOOL "Build 3rdparty hunspelllib" FORCE)
 379   set(LYX_EXTERNAL_MYTHES   OFF CACHE STRING "Build 3rdparty mytheslib" FORCE)
 380 endif()
 381
 382 FIND_PROGRAM(LYX_GITVERSION git)
 383 #message(STATUS "gitversion = ${LYX_GITVERSION}")
 384 set(LYX_REVISION_VERSION ${LYX_RELEASE_LEVEL})
 385 set(LYX_PACKAGE_RELEASE "UNDEFINED")
 386 if(LYX_GITVERSION)
 387   if (LYX_LOCALVERSIONING)
 388     # Find the revision number for later use
 389     EXECUTE_PROCESS(COMMAND ${LYX_GITVERSION} describe --match 2.0.0 HEAD
 390       WORKING_DIRECTORY "${TOP_SRC_DIR}"
 391       RESULT_VARIABLE tmp_GIT_RESULT
 392       OUTPUT_VARIABLE tmp_LYX_PACKAGE_RELEASE
 393       ERROR_VARIABLE tmp_GIT_ERROR
 394       OUTPUT_STRIP_TRAILING_WHITESPACE)
 395     if (tmp_GIT_RESULT EQUAL 0)
 396       if (tmp_LYX_PACKAGE_RELEASE MATCHES "^2\\.0\\.0\\-\([0-9]+\)\\-\(.*\)$")
 397         set(LYX_PACKAGE_RELEASE ${CMAKE_MATCH_2})
 398         # We will add offset of 40000 to get appropriate value to
 399         # previous svn.
 400         # We use this value than also to set the package-patch-value
 401         MATH(EXPR tmp_REVISION_VERSION "(${CMAKE_MATCH_1}+40000)")
 402         set(LYX_REVISION_VERSION "${LYX_RELEASE_LEVEL}-${tmp_REVISION_VERSION}git")
 403         set(ENABLE_DIST ON)
 404       endif()
 405     endif()
 406   endif()
 407 endif()
 408 if (LYX_PACKAGE_RELEASE MATCHES "UNDEFINED")
 409   set(LYX_PACKAGE_RELEASE  "1")
 410   if (LYX_RELEASE_PATCH GREATER 0)
 411     set(LYX_REVISION_VERSION "${LYX_RELEASE_LEVEL}.${LYX_RELEASE_PATCH}")
 412   endif()
 413 endif()
 414
 415 # Set the programs (lyx, tex2lyx, etc.) suffix
 416 # When building an OS X bundle, we will append
 417 # the suffix only to the bundle, not to the programs
 418 set(PROGRAM_SUFFIX "")
 419 if(LYX_PROGRAM_SUFFIX AND NOT (APPLE AND LYX_BUNDLE))
 420         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 421 endif()
 422 set(_lyx "${PACKAGE_BASE}${PROGRAM_SUFFIX}")
 423 set(_tex2lyx tex2lyx${PROGRAM_SUFFIX})
 424 set(_convert lyxconvert${PROGRAM_SUFFIX})
 425
 426 add_custom_target(lyx_version ALL
 427   COMMAND ${CMAKE_COMMAND} -DTOP_SRC_DIR=${TOP_SRC_DIR} -DTOP_CMAKE_PATH=${TOP_CMAKE_PATH} -DTOP_BINARY_DIR=${TOP_BINARY_DIR} -DLYX_DATE=${LYX_DATE} -P ${TOP_SCRIPT_PATH}/LyXGetVersion.cmake
 428   )
 429 set_target_properties(lyx_version PROPERTIES FOLDER "applications")
 430
 431 # Default paths for installed utilities (tex2lyx, lyxclient, etc.)
 432 set(LYX_UTILITIES_INSTALL_PATH bin)
 433
 434 if(LYX_BUNDLE)
 435         set(LYX_CPACK ON)
 436
 437         message(STATUS)
 438         message(STATUS "Bundle creation is enabled (experimental):")
 439         message(STATUS "    make")
 440         message(STATUS "    make install/strip")
 441         message(STATUS "    make package")
 442         if(APPLE)
 443                 set(MACOSX_BUNDLE TRUE)
 444                 # This sets the bundle + executable names
 445                 set(_lyx "${PACKAGE_BASE}${LYX_INSTALL_SUFFIX}")
 446                 # This sets the Info.plist executable name
 447                 set(osx_bundle_program_name ${_lyx})
 448                 # Bundle name
 449                 set(LYX_BUNDLE_NAME ${_lyx})
 450
 451                 # This will contain the list of files that need to be included
 452                 # in the bundle and their location within the bundle
 453                 set(OSX_BUNDLE_FILES "${TOP_SRC_DIR}/development/MacOSX/LyX.sdef;${TOP_SRC_DIR}/development/MacOSX/LyXapp.icns;${CMAKE_BINARY_DIR}/lyxrc.dist")
 454                 set(OSX_BUNDLE_DIRS "Resources;Resources;Resources")
 455
 456                 # Process Info.plist and lyxrc.dist
 457                 # See development/cmake/Install.cmake
 458                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/Info.plist.in" "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 459
 460                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 461                 set(LYX_DATA_SUBDIR ${LYX_BUNDLE_NAME}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 462
 463                 # Variables used by CPack
 464                 set(CPACK_BUNDLE_NAME ${LYX_BUNDLE_NAME})
 465                 set(CPACK_BUNDLE_PLIST "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 466                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${LYX_BUNDLE_NAME}.app)
 467
 468                 # Set the install paths
 469                 set(LYX_UTILITIES_INSTALL_PATH ${LYX_BUNDLE_NAME}.app/Contents/MacOS)
 470                 if(NOT LYX_INSTALL_PREFIX)
 471                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 472                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 473                 endif()
 474                 # Change the owner so that the install can work
 475                 install(CODE "set(BU_CHMOD_BUNDLE_ITEMS 1)" COMPONENT Runtime)
 476         elseif(UNIX)
 477                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 478                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 479                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 480         elseif(WIN32)
 481                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 482         endif()
 483 endif()
 484
 485 if(LYX_INSTALL_PREFIX)
 486         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 487         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 488 endif()
 489 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 490
 491 if(UNIX)
 492   set(SYSTEM_DATADIR "${CMAKE_INSTALL_PREFIX}/share")
 493 elseif(CMAKE_INSTALL_PREFIX MATCHES "/lyx${LYX_INSTALL_SUFFIX}$")
 494   string(REGEX REPLACE "/lyx${LYX_INSTALL_SUFFIX}$" "/share" SYSTEM_DATADIR ${CMAKE_INSTALL_PREFIX})
 495 else()
 496   set(SYSTEM_DATADIR "${CMAKE_INSTALL_PREFIX}")
 497 endif()
 498
 499 if(NOT CMAKE_COMPILER_IS_GNUCXX)
 500   # Not a GCC compiler, programs do not have a suffix
 501   set(suffixing ${LYX_PACKAGE_SUFFIX})
 502 elseif(WIN32 AND MINGW)
 503   # We want to use a suffix for the package in this case,
 504   # even if not for the program
 505   set(suffixing ${LYX_PACKAGE_SUFFIX})
 506 else()
 507   message(STATUS "CMAKE_COMPILER_IS_GNUCXX = ${CMAKE_COMPILER_IS_GNUCXX}")
 508   set(suffixing ${LYX_PROGRAM_SUFFIX})
 509 endif()
 510
 511 # The define PACKAGE below allows lyx-executable to find its default configuration files
 512 # see routines
 513 #    Package::messages_file()
 514 #    get_default_user_support_dir()
 515 #    relative_system_support_dir()
 516 # in src/support/Package.cpp
 517 if(suffixing)
 518         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 519 else()
 520         set(PACKAGE ${PACKAGE_BASE})
 521 endif()
 522
 523 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 524         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 525         if (UNIX)
 526                 # use the default "/usr/local"
 527                 # but respect the user-choice on the command-line
 528                 set(CMAKE_INSTALL_PREFIX "/usr/local" CACHE PATH "LyX default install prefix" FORCE)
 529         endif()
 530 endif()
 531 if(WIN32)
 532         set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 533 endif()
 534 if(IS_ABSOLUTE)
 535         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 536 else()
 537         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 538 endif()
 539
 540
 541
 542 if(NOT LYX_DATA_SUBDIR)
 543         if (WIN32)
 544                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 545         else()
 546                 set(LYX_DATA_SUBDIR "share/${_lyx}/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 547         endif()
 548 endif()
 549
 550 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}/${LYX_DATA_SUBDIR}")
 551 get_locale_destination(LYX_LOCALEDIR)
 552 set(LYX_ABS_INSTALLED_LOCALEDIR "${CMAKE_INSTALL_PREFIX}/${LYX_LOCALEDIR}")
 553 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 554
 555 if(LYX_BUNDLE AND APPLE)
 556         set(LYX_MAN_DIR_tmp "${LYX_DATA_SUBDIR}")
 557 else()
 558         if(WIN32)
 559                 set(LYX_MAN_DIR_tmp "${CMAKE_BINARY_DIR}/usr/local/man/")
 560         elseif(UNIX)
 561                 set(LYX_MAN_DIR_tmp "${CMAKE_INSTALL_PREFIX}/share/man/")
 562         else()
 563                 set(LYX_MAN_DIR_tmp "${CMAKE_INSTALL_PREFIX}/man/")
 564         endif()
 565 endif()
 566 if (NOT LYX_MAN_DIR_tmp EQUAL "${LYX_MAN_DIR}")
 567         unset(LYX_MAN_DIR CACHE)
 568         set(LYX_MAN_DIR "${LYX_MAN_DIR_tmp}" CACHE STRING "Install location for man pages.")
 569 endif()
 570 unset(LYX_MAN_DIR_tmp)
 571 mark_as_advanced(LYX_MAN_DIR)
 572
 573 # The Win installer cannot be built by CMake because one needs to install plugins for NSIS
 574 # see the Readme.txt of the installer
 575 #if(LYX_INSTALL AND WIN32)
 576 #       message(STATUS "Configuring NSIS files")
 577 #       configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 578 #       configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 579 #       configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 580 #       message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 581 #endif()
 582
 583 if(NOT GROUP_CODE)
 584         #set(GROUP_CODE "The Golden Code")
 585         set(GROUP_CODE flat)
 586 endif()
 587
 588 # lyx's source files
 589 set(LYX_CPP_FILES [a-zA-Z]*.cpp)
 590 set(LYX_HPP_FILES [a-zA-Z]*.h)
 591 set(LYX_MOC_FILES moc_*.cpp)
 592
 593 include(ProjectSourceGroup)
 594
 595
 596 if(LYX_PROFILE AND NOT MSVC)
 597         set(CMAKE_BUILD_TYPE Profile CACHE STRING "Profile build type" FORCE)
 598         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg")
 599         set(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS}  -pg")
 600 else()
 601         set(LYX_PROFILE OFF)
 602 endif()
 603
 604
 605 if(LYX_NO_OPTIMIZE)
 606         set(CMAKE_BUILD_TYPE None)
 607         set(LYX_DEBUG OFF)
 608         set(LYX_RELEASE OFF)
 609         set(LYX_PROFILE OFF)
 610 elseif(LYX_RELEASE)
 611         set(CMAKE_BUILD_TYPE Release)
 612         set(LYX_DEBUG OFF)
 613         set(LYX_PROFILE OFF)
 614 elseif(LYX_PROFILE)
 615         set(CMAKE_BUILD_TYPE Profile)
 616         set(LYX_DEBUG OFF)
 617 else()
 618         set(CMAKE_BUILD_TYPE Debug)
 619         set(LYX_DEBUG ON)
 620 endif()
 621
 622
 623 # When shared libs are supported enable this option
 624 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 625 if(LYX_SHARED_LIBRARIES)
 626         set(library_type SHARED)
 627 else()
 628         set(library_type STATIC)
 629 endif()
 630
 631 if(MSVC)
 632   if (CXX11_FLAG MATCHES "\\+\\+([0-9]+)")
 633     set(CMAKE_CXX_STANDARD ${CMAKE_MATCH_1})
 634     message(STATUS "CMAKE_CXX_STANDARD set to ${CMAKE_CXX_STANDARD}")
 635   endif()
 636 else()
 637         if(NOT LYX_QUIET)
 638                 set(CMAKE_VERBOSE_MAKEFILE ON)
 639         endif()
 640         set(LYX_CXX_FLAGS "-Wall -Wunused-parameter ${LYX_GCC11_MODE}")
 641         if(LYX_CXX_FLAGS MATCHES "\\+\\+(14|11|98)")
 642           # Thanks to Brad King <brad.king@kitware.com>
 643           # for the pointer to https://cmake.org/cmake/help/v3.6/variable/CMAKE_CXX_STANDARD.html
 644           # This allows us to use QT5.7 with recent g++ (version >= 4.9) compilers
 645           # and still use our own c++ extension tests
 646           set(CMAKE_CXX_STANDARD ${CMAKE_MATCH_1})
 647           message(STATUS "CMAKE_CXX_STANDARD set to ${CMAKE_CXX_STANDARD}")
 648         endif()
 649         if(LYX_STDLIB_DEBUG)
 650           set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 651         else()
 652           if(LYX_DEBUG_GLIBC)
 653             set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG")
 654           endif()
 655           if(LYX_DEBUG_GLIBC_PEDANTIC)
 656             set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG_PEDANTIC")
 657           endif()
 658         endif()
 659         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE STRING "Set CXX flags" FORCE)
 660         set(CMAKE_CXX_FLAGS_DEBUG "-O0 -g3 -D_DEBUG" CACHE STRING "Set debug flags" FORCE)
 661         if(MINGW)
 662                 set(CMAKE_CXX_FLAGS_RELEASE "-O2 -DNDEBUG" CACHE STRING "Set release flags for Mingw" FORCE)
 663         else()
 664                 set(CMAKE_CXX_FLAGS_RELEASE "-O3 -DNDEBUG" CACHE STRING "Set release flags" FORCE)
 665         endif()
 666 endif()
 667
 668 set(LYX_CXX_FLAGS_EXTRA "" CACHE STRING "Desired semicolon separated list of extra cxx compile flags, like '-Werror'")
 669 mark_as_advanced(LYX_CXX_FLAGS_EXTRA)
 670 if(LYX_CXX_FLAGS_EXTRA)
 671         foreach(_flag ${LYX_CXX_FLAGS_EXTRA})
 672                 add_definitions(${_flag})
 673         endforeach()
 674 endif()
 675
 676 if(LYX_XMINGW)
 677         list(APPEND CMAKE_FIND_ROOT_PATH ${GNUWIN32_DIR})
 678 endif()
 679
 680 set(min_qt5_version "5.6")
 681 if(LYX_USE_QT MATCHES "AUTO")
 682         # try qt5 first
 683         find_package(Qt5Core CONFIG QUIET)
 684         if(Qt5Core_FOUND)
 685                 set(LYX_USE_QT "QT5" CACHE STRING "Valid qt version" FORCE)
 686                 message(STATUS "Qt5Core_VERSION = ${Qt5Core_VERSION}")
 687                 if(Qt5Core_VERSION VERSION_LESS ${min_qt5_version})
 688                         find_package(Qt4 "4.5.0" QUIET)
 689                         if(QT4_FOUND)
 690                                 set(LYX_USE_QT "QT4" CACHE STRING "Valid qt version" FORCE)
 691                         endif()
 692                 endif()
 693         else()
 694                 set(LYX_USE_QT "QT4" CACHE STRING "Valid qt version" FORCE)
 695         endif()
 696 endif()
 697 if(LYX_USE_QT MATCHES "QT5")
 698         # set QPA_XCB if QT uses X11
 699         find_package(Qt5Core CONFIG REQUIRED)
 700         if (Qt5Core_FOUND)
 701                 find_package(Qt5Widgets CONFIG REQUIRED)
 702                 if(APPLE)
 703                         find_package(Qt5MacExtras CONFIG REQUIRED)
 704                 endif()
 705                 find_package(Qt5X11Extras CONFIG QUIET)
 706                 find_package(Qt5WinExtras CONFIG QUIET)
 707                 set(QTVERSION ${Qt5Core_VERSION})
 708                 if (QTVERSION VERSION_LESS ${min_qt5_version})
 709                         message(STATUS "QTVERSION = \"${QTVERSION}\"")
 710                         message(STATUS "This version is not recommended, try either option -DLYX_USE_QT=QT4 or")
 711                         message(STATUS "install QT-Version >= \"${min_qt5_version}\"")
 712                         # see thread in lyx-devel list
 713                         # From: Jean-Pierre Chrétien <jeanpierre.chretien@free.fr>
 714                         # Date 11.03.2017
 715                         # Subject: cmake compilation error
 716                         #message(FATAL_ERROR "Wrong Qt-Version")
 717                 endif()
 718                 macro (qt_use_modules lyxtarget)
 719                         foreach (_tg ${ARGN})
 720                                 find_package(Qt5${_tg} CONFIG REQUIRED)
 721                                 target_link_libraries(${lyxtarget} Qt5::${_tg})
 722                         endforeach()
 723                 endmacro()
 724                 macro (qt_add_resources)
 725                         qt5_add_resources(${ARGN})
 726                 endmacro()
 727                 macro (qt_wrap_uifiles)
 728                         qt5_wrap_ui(${ARGN})
 729                 endmacro()
 730                 message(STATUS "Found Qt-Version ${QTVERSION}")
 731                 if(WIN32)
 732                         set(LYX_QTMAIN_LIBRARY ${Qt5Core_QTMAIN_LIBRARIES})
 733                 endif()
 734         endif()
 735 elseif(LYX_USE_QT MATCHES "QT4")
 736         if(LYX_XMINGW)
 737                 set(QT_MINGW_DIR ${LYX_QT4} CACHE PATH "Qt for Mingw" FORCE)
 738                 list(APPEND CMAKE_FIND_ROOT_PATH ${QT_MINGW_DIR} ${GNUWIN32_DIR})
 739         endif()
 740         find_package(Qt4 "4.5.0" REQUIRED)
 741         macro (qt_use_modules)
 742         endmacro()
 743         macro (qt_add_resources)
 744                 qt4_add_resources(${ARGN})
 745         endmacro()
 746         macro (qt_wrap_uifiles)
 747                 qt4_wrap_ui(${ARGN})
 748         endmacro()
 749         set(LYX_QTMAIN_LIBRARY ${QT_QTSVG_LIBRARY})
 750         if(WIN32)
 751                 list(APPEND LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARIES})
 752         endif()
 753 else()
 754   message(FATAL_ERROR "Unhandled value for LYX_USE_QT (${LYX_USE_QT})")
 755 endif()
 756
 757 find_package(Magic)
 758 if(Magic_FOUND)
 759   set(HAVE_MAGIC_H 1)
 760   include_directories(${Magic_INCLUDE_DIR})
 761 endif()
 762
 763 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 764
 765 set(Spelling_FOUND OFF)
 766 set(Include_used_spellchecker)   # String will be inserted into config.h
 767
 768 if (LYX_EXTERNAL_MYTHES MATCHES "AUTO")
 769   # try system library first
 770   find_package(MyThesLIB)
 771   if (MYTHESLIB_FOUND)
 772     set(LYX_EXTERNAL_MYTHES ON CACHE STRING "OFF:= Build 3rdparty mytheslib" FORCE)
 773   else()
 774     set(LYX_EXTERNAL_MYTHES OFF CACHE STRING "OFF:= Build 3rdparty mytheslib" FORCE)
 775   endif()
 776 endif()
 777 if (LYX_EXTERNAL_MYTHES MATCHES "ON")
 778   find_package(MyThesLIB REQUIRED)
 779 else()
 780   add_subdirectory(3rdparty/mythes)
 781 endif()
 782 set(MYTHES_DIR ${MYTHESLIB_INCLUDE_DIR})
 783
 784 if(NOT LYX_EXTERNAL_HUNSPELL)
 785     add_subdirectory(3rdparty/hunspell)
 786     add_definitions(-DHUNSPELL_STATIC)
 787     set(HUNSPELL_FOUND ON)
 788     message(STATUS "  * Hunspell:")
 789     message(STATUS "     - include: ${HUNSPELL_INCLUDE_DIR}")
 790     message(STATUS "     - library: ${HUNSPELL_LIBRARY}")
 791 endif()
 792
 793 foreach(_spell "ASPELL" "ENCHANT" "HUNSPELL")
 794   string(TOUPPER ${_spell} _upspell)
 795   if (NOT ${_upspell}_FOUND)
 796     find_package(${_spell})
 797   endif()
 798   if (${_upspell}_FOUND)
 799     include_directories(${${_upspell}_INCLUDE_DIR})
 800     set(Spelling_FOUND ON)
 801     message(STATUS "Building with USE_${_upspell}")
 802     set(Include_used_spellchecker "${Include_used_spellchecker}#define USE_${_upspell} 1\n")
 803   else()
 804     if(LYX_${_upspell})
 805       message(FATAL_ERROR "Required ${_spell} devel package not found")
 806     else()
 807       message(STATUS "${_upspell} not found, building without ${_spell} support")
 808     endif()
 809   endif()
 810 endforeach()
 811
 812 if(GNUWIN32_DIR)
 813         list(APPEND CMAKE_PROGRAM_PATH "${GNUWIN32_DIR}/Python" )
 814 endif()
 815
 816 # Search for python default version first
 817 unset(PYTHON_EXECUTABLE CACHE)
 818 unset(LYX_PYTHON_EXECUTABLE CACHE)
 819 unset(PYTHON_VERSION_MAJOR)
 820 unset(PYTHON_VERSION_MINOR)
 821 unset(PYTHON_VERSION_STRING)
 822 if (CMAKE_VERSION VERSION_LESS "3.13")
 823   find_package(PythonInterp 3.5 QUIET)
 824   if(NOT PYTHONINTERP_FOUND)
 825     find_package(PythonInterp 2.0 REQUIRED)
 826     if(NOT PYTHON_VERSION_STRING VERSION_LESS 2.8)
 827       message(FATAL_ERROR "Python interpreter found, but is not suitable")
 828     endif()
 829   endif()
 830   set(LYX_PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 831 else()
 832   find_package(Python3 3.5 QUIET)
 833   if(NOT Python3_Interpreter_FOUND)
 834     unset(PYTHON_EXECUTABLE CACHE)
 835     find_package(Python2 2.0 REQUIRED)
 836     if(NOT Python2_VERSION VERSION_LESS 2.8)
 837       message(FATAL_ERROR "Python interpreter found, but is not suitable")
 838     endif()
 839     set(LYX_PYTHON_EXECUTABLE ${Python2_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 840   else()
 841     set(LYX_PYTHON_EXECUTABLE ${Python3_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 842   endif()
 843 endif()
 844
 845 if(LYX_NLS)
 846         find_package(LyXGettext)
 847         if(LYX_PYTHON_EXECUTABLE AND GETTEXT_FOUND)
 848                 add_subdirectory(po "${TOP_BINARY_DIR}/po")
 849         else()
 850                 # Install only supplied .gmo-files
 851                 file(GLOB _gmofiles RELATIVE "${TOP_SRC_DIR}/po" "${TOP_SRC_DIR}/po/*.gmo")
 852                 message(STATUS "Installing provided .gmo-files only")
 853                 foreach( _gmo ${_gmofiles})
 854                         string(REGEX REPLACE "\\.gmo$" "" _lang ${_gmo})
 855                         install(FILES "${TOP_SRC_DIR}/po/${_gmo}" DESTINATION ${LYX_LOCALEDIR}/${_lang}/LC_MESSAGES RENAME ${PACKAGE}.mo)
 856                 endforeach()
 857         endif()
 858 endif()
 859
 860 if(LYX_EXTERNAL_ICONV)
 861   find_package(ICONV REQUIRED)
 862 else()
 863   add_subdirectory(3rdparty/libiconv)
 864   set(HAVE_ICONV_CONST 1)
 865 endif()
 866
 867 if(LYX_EXTERNAL_Z)
 868   find_package(ZLIB REQUIRED)
 869 else()
 870   add_subdirectory(3rdparty/zlib)
 871 endif()
 872
 873 if(NOT LYX_EXTERNAL_DTL)
 874   add_subdirectory(3rdparty/dtl)
 875 endif()
 876
 877 if(LYX_USE_STD_REGEX)
 878   # Set only include path.
 879   # Use internal boost, which is known to exist
 880   # we don't need any libraries
 881   set(Lyx_Boost_Libraries)
 882   add_definitions(-DBOOST_USER_CONFIG=<config.h>)
 883   include_directories(${TOP_SRC_DIR}/3rdparty/boost)
 884 else()
 885   # Using boost-regex
 886   if(LYX_EXTERNAL_BOOST)
 887     message(STATUS "Searching for external boost")
 888     find_package(Boost COMPONENTS regex)
 889     if(Boost_FOUND)
 890       message(STATUS "Boost found")
 891       message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 892       set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 893       if (LYX_STDLIB_DEBUG OR LYX_DEBUG_GLIBC OR LYX_DEBUG_GLIBC_PEDANTIC)
 894         # Comment from  Jean-Marc Lasgouttes:
 895         # In general, system boost libraries are incompatible with
 896         # the use of stdlib-debug in libstdc++. See ticket #9736 for
 897         # details.
 898         message(FATAL_ERROR "Compiling LyX with stdlib-debug and system boost libraries may lead to crashes. Consider using '-DLYX_STDLIB_DEBUG=OFF -DLYX_DEBUG_GLIBC=OFF -DLYX_DEBUG_GLIBC_PEDANTIC=OFF' or using '-DLYX_EXTERNAL_BOOST=OFF'")
 899       endif()
 900     else()
 901       message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 902     endif()
 903   else()
 904     # Using included boost
 905     set(Lyx_Boost_Libraries boost_regex)
 906     add_definitions(-DBOOST_USER_CONFIG=<config.h>)
 907     include_directories(${TOP_SRC_DIR}/3rdparty/boost)
 908     add_subdirectory(3rdparty/boost "${TOP_BINARY_DIR}/3rdparty/boost")
 909   endif()
 910 endif()
 911
 912 if(WIN32)
 913         if(LYX_CONSOLE)
 914                 set(LYX_QTMAIN_LIBRARY)
 915         else()
 916                 set(WIN32_CONSOLE WIN32)
 917         endif()
 918         if(MSVC)
 919                 # -DPSAPI_VERSION=1 is needed to run on vista (bug 10186)
 920                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX -DPSAPI_VERSION=1)
 921                 # disable checked iterators for msvc release builds to get maximum speed
 922                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 923         else()
 924                 # -DPSAPI_VERSION=1 is not needed for mingw, since the mingw psapi.h
 925                 # does not use it and always declares the vista compatible API.
 926                 # If this ever changes then -DPSAPI_VERSION might be needed here as well.
 927                 add_definitions(-DWINVER=0x0500)
 928         endif()
 929 endif()
 930
 931 # Compute qt-version from ${QTVERSION}
 932
 933 message(STATUS "")
 934 foreach(_v PACKAGE PACKAGE_VERSION
 935         PROGRAM_SUFFIX LYX_VERSION LYX_DIR_VER LYX_USERDIR_VER
 936         LYX_ABS_TOP_SRCDIR
 937         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 938         if(NOT DEFINED ${_v})
 939                 message(FATAL_ERROR "${_v} not defined")
 940         endif()
 941         string(SUBSTRING "${_v}                            " 0 28 _v1)
 942         message(STATUS "----- ${_v1}: ${${_v}}")
 943 endforeach(_v)
 944 message(STATUS "")
 945
 946
 947 if(LYX_PCH)
 948         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 949         # Not sure if it works for all non-msvc compilers
 950         include(PCHSupport_26)
 951         configure_file(${TOP_CMAKE_PATH}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
 952         configure_file(${TOP_CMAKE_PATH}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 953         add_definitions(-DLYX_ENABLE_PCH)
 954
 955         if(MSVC)
 956                 macro(lyx_add_msvc_pch name_)
 957                         set_source_files_properties(${${name_}_sources} PROPERTIES
 958                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 959                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
 960                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 961                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
 962                                 ${TOP_BINARY_DIR}/pcheaders.h)
 963                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 964                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 965                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 966                 endmacro(lyx_add_msvc_pch)
 967                 macro(lyx_add_gcc_pch name_)
 968                 endmacro()
 969         else()
 970                 macro(lyx_add_msvc_pch name_)
 971                 endmacro()
 972                 macro(lyx_add_gcc_pch name_)
 973                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT)
 974                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
 975                 endmacro()
 976         endif()
 977 else()
 978         macro(lyx_add_msvc_pch)
 979         endmacro(lyx_add_msvc_pch)
 980         macro(lyx_add_gcc_pch name_)
 981         endmacro()
 982 endif()
 983
 984
 985 if(MSVC)
 986
 987         if(LYX_VLD)
 988                 set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/development/Win32/vld)
 989                 add_subdirectory(${vld_path}/cmake)
 990                 include(${vld_path}/cmake/vld.cmake) # forced include
 991                 set(vld_dll vld)
 992         endif()
 993
 994         if(LYX_WALL)
 995                 # Use the highest warning level
 996                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE STRING "Warning level" FORCE)
 997
 998                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 999                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
1000                 else()
1001                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
1002                 endif()
1003
1004                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
1005                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
1006                 else()
1007                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
1008                 endif()
1009
1010                 # add here warnings which should produce an error /weXXXX
1011                 set(MSVC_W_ERROR   "/we4101 /we4189")
1012                 # add here warnings which should be disabled /wdXXXX
1013                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
1014
1015                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1016                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1017                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1018
1019         else()
1020                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE STRING "Warning level" FORCE)
1021
1022                 # add here warnings which should produce an error /weXXXX
1023                 set(MSVC_W_ERROR   "/we4101 /we4189")
1024                 # add here warnings which should be disabled /wdXXXX
1025                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
1026
1027                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1028                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1029                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1030
1031         endif()
1032
1033         if (NOT Qt5Core_FOUND)
1034                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
1035                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
1036                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
1037         endif()
1038
1039         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
1040         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
1041         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
1042         message(STATUS "")
1043 endif()
1044
1045
1046 # Xcode compiler
1047 if (CMAKE_GENERATOR MATCHES Xcode)
1048         if (XCODE_VERSION VERSION_LESS "5.0")
1049                 # Automatically select the Xcode compiler if not set
1050                 if (NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
1051                         # XCode >= 3.1 has gcc 4.2 (up to actual Xcode)
1052                         if (XCODE_VERSION VERSION_GREATER "3.1")
1053                                 SET(CMAKE_XCODE_ATTRIBUTE_GCC_VERSION "com.apple.compilers.llvmgcc42")
1054                         ENDIF(XCODE_VERSION VERSION_GREATER "3.1")
1055                 ENDIF(NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
1056                 # Print the selected compiler version
1057         MESSAGE(STATUS "---- Using XCode compiler CMAKE_XCODE_ATTRIBUTE_GCC_VERSION=${CMAKE_XCODE_ATTRIBUTE_GCC_VERSION}")
1058         ENDIF(XCODE_VERSION VERSION_LESS "5.0")
1059 ENDIF(CMAKE_GENERATOR MATCHES Xcode)
1060
1061 if (WIN32 AND Qt5Core_FOUND)
1062         set(Z_PREFIX 1)
1063 endif()
1064
1065 # compiler tests, config.h generation LYX_CONFIGURE_CHECKS
1066 include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
1067 configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
1068
1069 unset(opts)
1070 foreach(_option ${LYX_OPTIONS})
1071   if(${_option}_show_message)
1072     string(SUBSTRING "${_option}                            " 0 31 _var)
1073     get_property(_prop CACHE ${_option} PROPERTY STRINGS)
1074     list(FIND LYX_OPTION_STRINGS ${_option} _index)
1075     if (${_index} GREATER -1)
1076       set(_isset ${${_option}})
1077     elseif(${_option})
1078       set(_isset ON)
1079     else()
1080       set(_isset OFF)
1081     endif()
1082     string(SUBSTRING "${_isset}           " 0 10 _val)
1083     set(opts "${opts} ${_option}(${${_option}})")
1084   endif()
1085 endforeach()
1086 set(tmp_vi "CMake Build")
1087 list(APPEND tmp_vi "  Host name:               ${CMAKE_HOST_SYSTEM_NAME}")
1088 list(APPEND tmp_vi "  Host processor:          ${CMAKE_HOST_SYSTEM_PROCESSOR}")
1089 list(APPEND tmp_vi "  Build flags:             ${opts}")
1090 list(APPEND tmp_vi "  C++ Compiler:            ${CMAKE_CXX_COMPILER_ID} (${CMAKE_CXX_COMPILER_VERSION})")
1091 list(APPEND tmp_vi "  C++ Compiler flags:      ${CMAKE_CXX_FLAGS}")
1092 if (LYX_DEBUG)
1093 list(APPEND tmp_vi "  C++ Compiler user flags: ${CMAKE_CXX_FLAGS_DEBUG}")
1094 else()
1095 list(APPEND tmp_vi "  C++ Compiler user flags: ${CMAKE_CXX_FLAGS_RELEASE}")
1096 endif()
1097 list(APPEND tmp_vi "  Qt version:              ${QTVERSION}")
1098 list(APPEND tmp_vi "  LyX binary dir:          ${CMAKE_INSTALL_PREFIX}/${LYX_UTILITIES_INSTALL_PATH}")
1099 get_data_destination(dest_data)
1100 list(APPEND tmp_vi "  LyX files dir:           ${CMAKE_INSTALL_PREFIX}/${dest_data}")
1101 string(REPLACE ";" "\\n" VERSION_INFO "${tmp_vi}")
1102
1103 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
1104 unset(opts)
1105 unset(tmp_vi)
1106
1107 if(QTVERSION MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+).*")
1108         MATH(EXPR QT4_VERSION "(${CMAKE_MATCH_1}<<16)|(${CMAKE_MATCH_2}<<8)|${CMAKE_MATCH_3}")
1109 endif()
1110
1111 if (NOT HAVE_REGEX)
1112         set(LYX_USE_STD_REGEX 0)
1113 endif()
1114
1115
1116 set (cmd ${CMAKE_CTEST_COMMAND})
1117 if (MSVC)
1118         set (cmd ${cmd} -C ${CMAKE_CFG_INTDIR})
1119 else ()
1120         set (cmd ${cmd} -C ${CMAKE_BUILD_TYPE})
1121 endif ()
1122 add_custom_target (lyx_run_tests COMMAND ${cmd})
1123 set_target_properties(lyx_run_tests PROPERTIES FOLDER "tests")
1124
1125 if(LYX_ASAN)
1126     set(LYX_CXX_FLAGS "-fsanitize=address -fno-omit-frame-pointer -g")
1127     message(STATUS)
1128     message(STATUS "Address sanitizer enabled. Usage:")
1129     message(STATUS "    wget https://llvm.org/svn/llvm-project/compiler-rt/trunk/lib/asan/scripts/asan_symbolize.py")
1130     message(STATUS "    chmod  +x ./asan_symbolize.py")
1131     message(STATUS "    ./bin/lyx2.2 2>&1 | ./asan_symbolize.py  | c++filt ")
1132     message(STATUS)
1133 endif()
1134
1135 if(LYX_INSTALL)
1136         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
1137                 message(STATUS "Python required to create doc!")
1138         else()
1139                 if(UNIX)
1140                         add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
1141                 endif()
1142                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
1143         endif()
1144 endif()
1145 include(../Install)
1146
1147 # By running the URL tests first, time can be saved when running the ctests in
1148 # parallel since the URL tests take a long time to run (e.g. 10 minutes).
1149 if(LYX_ENABLE_URLTESTS)
1150         add_subdirectory(development/checkurls "${TOP_BINARY_DIR}/checkurls")
1151 endif()
1152 add_subdirectory(src "${TOP_BINARY_DIR}/src")
1153 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
1154 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
1155 add_subdirectory(lib/examples "${TOP_BINARY_DIR}/lib/examples")
1156 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
1157 add_subdirectory(development/autotests "${TOP_BINARY_DIR}/autotests")
1158 add_subdirectory(development/batchtests "${TOP_BINARY_DIR}/batchtests")
1159
1160 message(STATUS)
1161 message(STATUS "Build params, switch LYX_* options by -DLYX_*=ON or OFF, LYX_* combos by -DLYX_*=value:")
1162 message(STATUS)
1163
1164 LYX_OPTION_LIST_ALL(used)
1165
1166
1167 if(LYX_NLS)
1168         message(STATUS)
1169         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
1170         message(STATUS)
1171         message(STATUS "  * iconv")
1172         message(STATUS "     - include: ${ICONV_INCLUDE_DIR}")
1173         message(STATUS "     - library: ${ICONV_LIBRARY}")
1174         message(STATUS "  * zlib")
1175         message(STATUS "     - include: ${ZLIB_INCLUDE_DIR}")
1176         message(STATUS "     - library: ${ZLIB_LIBRARY}")
1177         message(STATUS)
1178 endif()
1179
1180 # Apple has builtin native spell checker,
1181 # no need to warn for missing Aspell, Hunspell or Enchant
1182 if(NOT Spelling_FOUND AND NOT APPLE)
1183   if(LYX_REQUIRE_SPELLCHECK)
1184     set(_mode "FATAL_ERROR")
1185   else()
1186     set(_mode "STATUS")
1187   endif()
1188   message(${_mode} "No spellcheck libraries found. LyX will be unable use spellchecking")
1189 endif()
1190
1191 include("${TOP_CMAKE_PATH}/LyxPackaging.cmake")
1192
1193 if(ENABLE_DIST)
1194   # Use git to create the source package
1195   # git archive --format=tgz --output=/home/kornel/x.tar.gz master
1196   if(UNIX)
1197     set(DIST_FORMAT tgz)
1198   else()
1199     set(DIST_FORMAT zip)
1200   endif()
1201   set(DIST_NAME ${CMAKE_PROJECT_NAME}-${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}-${CMAKE_SYSTEM_NAME}.${DIST_FORMAT})
1202
1203   add_custom_command(
1204     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME}
1205     COMMAND  ${LYX_GITVERSION} archive --format=${DIST_FORMAT} --output=${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME} master
1206     WORKING_DIRECTORY ${TOP_SRC_DIR})
1207   add_custom_target(git-archive DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME})
1208 endif()
1209
1210 # Last directory to be included so that the fixup code (OS X)
1211 # can be run last
1212 add_subdirectory(development/cmake/post_install)
1213
1214 message(STATUS)