CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 2.6.4)
   8
   9 set(LYX_PROJECT LyX)
  10
  11 enable_testing()
  12
  13 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README REALPATH) # Resolve symlinks
  14 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  15 message(STATUS "TOP_SRC_DIR = ${TOP_SRC_DIR}")
  16
  17 set(LYX_CMAKE_DIR "development/cmake")
  18 set(TOP_CMAKE_PATH "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}")
  19 set(TOP_MODULE_PATH "${TOP_CMAKE_PATH}/modules")
  20 set(TOP_SCRIPT_PATH "${TOP_CMAKE_PATH}/scripts")
  21
  22 set(CMAKE_MODULE_PATH "${TOP_MODULE_PATH}")
  23
  24 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  25
  26 message(STATUS)
  27 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  28         message(STATUS "Building in-source")
  29         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  30 else()
  31         message(STATUS "Building out-of-source")
  32         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  33 endif()
  34
  35 # This directory should be used if some test uses lyx-executable
  36 set(LYX_TESTS_USERDIR "${TOP_BINARY_DIR}/Testing/.lyx")
  37 file(MAKE_DIRECTORY "${LYX_TESTS_USERDIR}")
  38
  39 if(COMMAND cmake_policy)
  40         cmake_policy(SET CMP0003 OLD)
  41         cmake_policy(SET CMP0005 OLD)
  42         # Installing MACOSX_BUNDLE targets requires a BUNDLE DESTINATION
  43         cmake_policy(SET CMP0006 NEW)
  44         if(POLICY CMP0020)
  45                 cmake_policy(SET CMP0020 OLD)
  46         endif()
  47         if(POLICY CMP0028)
  48                 cmake_policy(SET CMP0028 OLD)
  49         endif()
  50         if(POLICY CMP0043)
  51                 # COMPILE_DEFINITIONS are not used yet. Enable new behavior.
  52                 cmake_policy(SET CMP0043 NEW)
  53         endif()
  54 endif()
  55
  56 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  57
  58 # Supress regeneration
  59 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  60
  61 if(LYX_XMINGW)
  62     set(CMAKE_SYSTEM_NAME Windows)
  63     set(TOOLNAME ${LYX_XMINGW})
  64     set(TOOLCHAIN "${TOOLNAME}-")
  65     set(CMAKE_C_COMPILER   "${TOOLCHAIN}gcc"     CACHE PATH "Mingw C compiler" FORCE)
  66     set(CMAKE_CXX_COMPILER "${TOOLCHAIN}g++"     CACHE PATH "Mingw C++ compiler" FORCE)
  67     set(CMAKE_RC_COMPILER  "${TOOLCHAIN}windres" CACHE PATH "Mingw rc compiler" FORCE)
  68
  69     set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM BOTH)
  70     set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY)
  71     set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY)
  72 endif()
  73
  74 if(NOT help AND NOT HELP)
  75   # 'project' triggers the searching for a compiler
  76   project(${LYX_PROJECT})
  77   if (CMAKE_COMPILER_IS_GNUCXX)
  78     if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS "4.0")
  79       message(STATUS "Gnu CXX compiler version = ${CMAKE_CXX_COMPILER_VERSION}")
  80       message(STATUS "is too old, should be >= 4.0")
  81       message(FATAL_ERROR "Exiting")
  82     endif()
  83   endif()
  84 endif()
  85
  86 if(UNIX)
  87         set(ARCH_TRIPLET )
  88         FIND_PROGRAM(DPKG_ARCHITECTURE_EXECUTABLE dpkg-architecture)
  89         if(DPKG_ARCHITECTURE_EXECUTABLE)
  90                 EXECUTE_PROCESS(COMMAND ${DPKG_ARCHITECTURE_EXECUTABLE} -qDEB_HOST_MULTIARCH
  91                                 OUTPUT_VARIABLE ARCH_TRIPLET
  92                                 ERROR_VARIABLE ERROR_ARCH_TRIPLET
  93                                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  94         endif()
  95 endif()
  96 if(ARCH_TRIPLET)
  97         set(SYSTEM_LIB_DIRS /usr/lib /usr/lib/${ARCH_TRIPLET} /usr/local/lib)
  98 else()
  99         set(SYSTEM_LIB_DIRS /usr/lib /usr/local/lib)
 100 endif()
 101
 102 include(LyXMacros)
 103 include(LyXDestinations)
 104
 105 # Usage LYX_OPTION
 106 # 1. parameter: option name without prefix 'LYX_'
 107 # 2. parameter: description
 108 # 3. parameter: default value, ON or OFF
 109 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
 110
 111 # Usage LYX_COMBO
 112 # 1. parameter: name without prefix 'LYX_'
 113 # 2. parameter: description
 114 # 3. parameter: default value
 115 # 4-n parameter: possible other string values
 116
 117 LYX_OPTION_INIT()
 118
 119 # Options for all compilers/systems
 120 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
 121 LYX_OPTION(LOCALVERSIONING  "Add version info to created package name (only used if LYX_CPACK option set)" OFF ALL)
 122 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
 123 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
 124 LYX_OPTION(REQUIRE_SPELLCHECK "Abort if no spellchecker available" OFF ALL)
 125 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
 126 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
 127 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
 128 LYX_OPTION(DEVEL_VERSION    "Build developer version" OFF ALL)
 129 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" OFF ALL)
 130 LYX_OPTION(DEBUG            "Enforce debug build"  OFF ALL)
 131 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
 132 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
 133 LYX_STRING(SUFFIX_VALUE     "Use this string as suffix" "")
 134 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
 135 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
 136 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
 137 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
 138 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
 139 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
 140 LYX_OPTION(ENABLE_URLTESTS  "Enable for URL tests" OFF ALL)
 141 LYX_OPTION(ENABLE_EXPORT_TESTS "Enable for export tests" OFF ALL)
 142 LYX_OPTION(ENABLE_KEYTESTS  "Enable for keytests" OFF ALL)
 143 LYX_OPTION(ASAN             "Use address sanitizer" OFF ALL)
 144 LYX_COMBO(USE_QT            "Use Qt version as frontend" QT4 QT5)
 145 #LYX_OPTION(3RDPARTY_BUILD   "Build 3rdparty libs" OFF ALL)
 146 LYX_OPTION(EXTERNAL_Z       "Do not build 3rdparty lib zlib" ON ALL)
 147 LYX_OPTION(EXTERNAL_ICONV   "Do not build 3rdparty lib iconvlib" ON ALL)
 148 LYX_OPTION(EXTERNAL_HUNSPELL "Do not build 3rdparty lib hunspelllib" ON ALL)
 149 LYX_OPTION(EXTERNAL_MYTHES  "Do not build 3rdparty lib mytheslib" OFF ALL)
 150
 151 # GCC specific
 152 LYX_OPTION(PROFILE              "Build profile version" OFF GCC)
 153 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" OFF GCC)
 154 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
 155 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
 156 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++ pedantic debug mode" OFF GCC)
 157 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" OFF GCC)
 158 LYX_OPTION(PROFILE              "Build with options for gprof" OFF GCC)
 159
 160 # MSVC specific
 161 LYX_OPTION(CONSOLE               "Show console on Windows, enforce with =FORCE" ON MSVC)
 162 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
 163 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
 164 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
 165
 166 # APPLE specific
 167 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
 168 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
 169
 170
 171 if(help OR HELP)
 172         message(STATUS)
 173         message(STATUS "Available options: (dis/enable with -DLYX_*=OFF/ON)")
 174         message(STATUS)
 175         LYX_OPTION_LIST_ALL(help)
 176         message(STATUS)
 177         RETURN()
 178 endif()
 179
 180 # Check option dependencies
 181
 182 if(LYX_DMG)
 183         set(LYX_BUNDLE ON)
 184         set(LYX_CPACK ON)
 185 endif()
 186
 187 if (LYX_EXTERNAL_MYTHES)
 188   message(FATAL_ERROR "Compilation with system mythes not supported yet")
 189 else()
 190   set(MYTHES_DIR "${TOP_SRC_DIR}/3rdparty/mythes/1.2.5")
 191 endif()
 192
 193 if(LYX_CPACK)
 194         set(LYX_INSTALL ON)
 195 endif()
 196
 197 if(LYX_INSTALL)
 198         set(LYX_NLS ON)
 199         if(WIN32 AND NOT MINGW)
 200                 set(LYX_HUNSPELL ON)
 201         endif()
 202         if(LYX_CONSOLE MATCHES "FORCE")
 203                 set(LYX_CONSOLE ON)
 204         else()
 205                 set(LYX_CONSOLE OFF)
 206         endif()
 207         set(LYX_PACKAGE_SUFFIX ON)
 208         if(NOT LYX_DEBUG)
 209                 set(LYX_RELEASE ON)
 210         endif()
 211         set(LYX_PROFILE OFF)
 212 endif()
 213
 214
 215 if(LYX_MERGE_FILES)
 216         set(LYX_PCH OFF)
 217 else()
 218         set(LYX_MERGE_REBUILD OFF)
 219 endif()
 220
 221 if(LYX_DEPENDENCIES_DOWNLOAD)
 222         message(STATUS)
 223         if(MSVC14)
 224                 set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2015-deps)
 225                 set(deps_files lyx-windows-deps-msvc2015.zip)
 226                 set(deps_server http://ftp.lyx.de/LyX-Windows-Deps)
 227                 set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2015)
 228         elseif(MSVC10)
 229                 set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 230                 set(deps_files lyx-windows-deps-msvc2010.zip)
 231                 set(deps_server http://ftp.lyx.de/LyX-Windows-Deps)
 232                 set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2010)
 233         else()
 234                 message(FATAL_ERROR "error: no dependency package known for the selected MSVC version.")
 235         endif()
 236     message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 237         foreach(it ${deps_files})
 238                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 239                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 240                 if(NOT already_downloaded)
 241                         message(STATUS "Downloading ${it} ...")
 242                         file(DOWNLOAD ${deps_server}/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS STATUS status LOG log)
 243                         list(GET status 0 status_code)
 244                         list(GET status 1 status_string)
 245                         if(NOT status_code EQUAL 0)
 246                                 file(REMOVE ${LYX_DEPENDENCIES_DIR}/${it})
 247                                 message(FATAL_ERROR "error: downloading '${it}' failed. status_code: ${status_code}, status_string: ${status_string}. \nLog: ${log} ")
 248                         endif()
 249                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 250                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 251                 endif()
 252         endforeach()
 253 endif()
 254
 255
 256
 257 message(STATUS)
 258
 259 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 260 if(WIN32)
 261         set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 262 else()
 263         set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 264 endif()
 265
 266
 267 # Set to some meaningful default
 268 find_package(CXX11Compiler)
 269 if(NOT CXX11COMPILER_FOUND)
 270         message(FATAL_ERROR "A C++11 compatible compiler is required.")
 271 endif()
 272 set(LYX_GCC11_MODE)
 273 if(UNIX OR MINGW)
 274         if (CMAKE_CXX_COMPILER_ID MATCHES "^[cC]lang$")
 275           # ignore the GCC_VERSION for clang
 276           # and use the resulting CXX11_STD_REGEX found in FindCXX11Compiler.cmake
 277           message(STATUS "Using clang")
 278           if(CXX11_STD_REGEX)
 279             set(LYX_USE_STD_REGEX 1)
 280           else()
 281             set(LYX_USE_STD_REGEX 0)
 282           endif()
 283         else()
 284           execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION OUTPUT_STRIP_TRAILING_WHITESPACE)
 285           message(STATUS "Using GCC version ${GCC_VERSION}")
 286           if(GCC_VERSION VERSION_LESS 4.9)
 287                   if(GCC_VERSION VERSION_LESS 4.6)
 288                           message(FATAL_ERROR "gcc >= 4.6 is required.")
 289                   endif()
 290                   # <regex> in gcc is unusable in versions less than 4.9.0
 291                   # see https://gcc.gnu.org/bugzilla/show_bug.cgi?id=53631
 292                   set(LYX_USE_STD_REGEX 0)
 293           else()
 294                   set(LYX_USE_STD_REGEX 0)
 295           endif()
 296         endif()
 297         set(LYX_GCC11_MODE "${CXX11_FLAG}")
 298 else()
 299         set(LYX_USE_STD_REGEX 0)
 300 #       if(MSVC10)
 301 #               set(LYX_USE_STD_REGEX 1) #TODO should we use it in ECMAScript mode?
 302 #       endif()
 303 endif()
 304
 305
 306 set(VERSION_INFO "CMake Build")
 307
 308 # Try to get some informations from configure.ac
 309
 310 include(LyXPaths)
 311 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 312
 313 if(WIN32)
 314         set(CMAKE_PREFIX_PATH Specify-path-to-Qt CACHE PATH "Used Qt version")
 315         if(MSVC)
 316                 set(LYX_3RDPARTY_BUILD ON CACHE BOOL "Build 3rdparty libraries" FORCE)
 317         endif()
 318         set(USE_WINDOWS_PACKAGING ON)
 319 elseif(APPLE)
 320         set(USE_MACOSX_PACKAGING ON)
 321 else()
 322         set(USE_POSIX_PACKAGING ON)
 323 endif()
 324
 325 if(LYX_3RDPARTY_BUILD)
 326   # LYX_3RDPARTY_BUILD is not cached anymore, but for compatibility reasons
 327   # this enables the build of all 3rd_party libs
 328   set(LYX_EXTERNAL_Z        OFF CACHE BOOL "Build 3rdparty lib zlib"    FORCE)
 329   set(LYX_EXTERNAL_ICONV    OFF CACHE BOOL "Build 3rdparty iconvlib"    FORCE)
 330   set(LYX_EXTERNAL_HUNSPELL OFF CACHE BOOL "Build 3rdparty hunspelllib" FORCE)
 331 endif()
 332
 333 macro(setstripped _varname)
 334         if(${ARGC} GREATER 1)
 335                 string(STRIP "${ARGV1}" _v)
 336                 if(USE_POSIX_PACKAGING)
 337                         string(TOLOWER ${_v} ${_varname})
 338                 else()
 339                         set(${_varname} ${_v})
 340                 endif()
 341         else()
 342                 set(${_varname})
 343         endif()
 344 endmacro(setstripped)
 345
 346 foreach(_c_l ${_config_lines} )
 347         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 348                 setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 349                 setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 350                 setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 351                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\)\(\\.\([0-9]+\)\)?.*$")
 352                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 353                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 354                         set(LYX_PATCH_VERSION ${CMAKE_MATCH_4})
 355                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 356                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 357                         if ("${LYX_SUFFIX_VALUE}" MATCHES "")
 358                           set(LYX_INSTALL_SUFFIX "${LYX_MAJOR_VERSION}.${LYX_MINOR_VERSION}")
 359                         else()
 360                           set(LYX_INSTALL_SUFFIX "${LYX_SUFFIX_VALUE}")
 361                         endif()
 362                 endif()
 363         endif()
 364         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 365                 set(LYX_DATE "${CMAKE_MATCH_1}")
 366         endif()
 367 endforeach(_c_l)
 368
 369 FIND_PROGRAM(LYX_GITVERSION git)
 370 #message(STATUS "gitversion = ${LYX_GITVERSION}")
 371 set(LYX_REVISION_VERSION ${LYX_PATCH_VERSION})
 372 if(LYX_GITVERSION)
 373   if (LYX_LOCALVERSIONING)
 374     # Find the revision number and for later use
 375     EXECUTE_PROCESS(COMMAND ${LYX_GITVERSION} describe --match 2.0.0 HEAD
 376       WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE LYX_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 377     if (LYX_PACKAGE_RELEASE MATCHES "^2\\.0\\.0\\-\([0-9]+\)\\-.*$")
 378       # We will add offset of 40000 to get appropriate value to
 379       # previous svn.
 380       # We use this value than also to set the package-patch-value
 381       MATH(EXPR tmp_REVISION_VERSION "(${CMAKE_MATCH_1}+40000)")
 382       set(LYX_REVISION_VERSION "${LYX_PATCH_VERSION}-${tmp_REVISION_VERSION}git")
 383       set(ENABLE_DIST ON)
 384     endif()
 385   endif()
 386 endif()
 387
 388 # Set the programs (lyx, tex2lyx, etc.) suffix
 389 # When building an OS X bundle, we will append
 390 # the suffix only to the bundle, not to the programs
 391 set(PROGRAM_SUFFIX "")
 392 if(LYX_PROGRAM_SUFFIX AND NOT (APPLE AND LYX_BUNDLE))
 393         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 394 endif()
 395 set(_lyx "${PACKAGE_BASE}${PROGRAM_SUFFIX}")
 396 set(_tex2lyx tex2lyx${PROGRAM_SUFFIX})
 397
 398 add_custom_target(lyx_version ALL
 399   COMMAND ${CMAKE_COMMAND} -DTOP_SRC_DIR=${TOP_SRC_DIR} -DTOP_CMAKE_PATH=${TOP_CMAKE_PATH} -DTOP_BINARY_DIR=${TOP_BINARY_DIR} -DLYX_DATE=${LYX_DATE} -P ${TOP_SCRIPT_PATH}/LyXGetVersion.cmake
 400   )
 401 set_target_properties(lyx_version PROPERTIES FOLDER "applications")
 402
 403 # Default paths for installed utilities (tex2lyx, lyxclient, etc.)
 404 set(LYX_UTILITIES_INSTALL_PATH bin)
 405
 406 if(LYX_BUNDLE)
 407         set(LYX_CPACK ON)
 408
 409         message(STATUS)
 410         message(STATUS "Bundle creation is enabled (experimental):")
 411         message(STATUS "    make")
 412         message(STATUS "    make install/strip")
 413         message(STATUS "    make package")
 414         if(APPLE)
 415                 set(MACOSX_BUNDLE TRUE)
 416                 # This sets the bundle + executable names
 417                 set(_lyx "${PACKAGE_BASE}${LYX_INSTALL_SUFFIX}")
 418                 # This sets the Info.plist executable name
 419                 set(osx_bundle_program_name ${_lyx})
 420                 # Bundle name
 421                 set(LYX_BUNDLE_NAME ${_lyx})
 422
 423                 # This will contain the list of files that need to be included
 424                 # in the bundle and their location within the bundle
 425                 set(OSX_BUNDLE_FILES "${TOP_SRC_DIR}/development/MacOSX/LyX.sdef;${TOP_SRC_DIR}/development/MacOSX/LyXapp.icns;${CMAKE_BINARY_DIR}/lyxrc.dist")
 426                 set(OSX_BUNDLE_DIRS "Resources;Resources;Resources")
 427
 428                 # Process Info.plist and lyxrc.dist
 429                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/Info.plist.in" "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 430                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/lyxrc.dist.in" "${CMAKE_CURRENT_BINARY_DIR}/lyxrc.dist")
 431
 432                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 433                 set(LYX_DATA_SUBDIR ${LYX_BUNDLE_NAME}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 434
 435                 # Variables used by CPack
 436                 set(CPACK_BUNDLE_NAME ${LYX_BUNDLE_NAME})
 437                 set(CPACK_BUNDLE_PLIST "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 438                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${LYX_BUNDLE_NAME}.app)
 439
 440                 # Set the install paths
 441                 set(LYX_UTILITIES_INSTALL_PATH ${LYX_BUNDLE_NAME}.app/Contents/MacOS)
 442                 if(NOT LYX_INSTALL_PREFIX)
 443                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 444                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 445                 endif()
 446                 # Change the owner so that the install can work
 447                 install(CODE "set(BU_CHMOD_BUNDLE_ITEMS 1)" COMPONENT Runtime)
 448         elseif(UNIX)
 449                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 450                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 451                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 452         elseif(WIN32)
 453                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 454         endif()
 455 endif()
 456
 457 if(LYX_INSTALL_PREFIX)
 458         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 459         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 460 endif()
 461 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 462
 463 if(UNIX)
 464   set(SYSTEM_DATADIR "${CMAKE_INSTALL_PREFIX}/share")
 465 elseif(CMAKE_INSTALL_PREFIX MATCHES "/lyx${LYX_INSTALL_SUFFIX}$")
 466   string(REGEX REPLACE "/lyx${LYX_INSTALL_SUFFIX}$" "/share" SYSTEM_DATADIR ${CMAKE_INSTALL_PREFIX})
 467 else()
 468   set(SYSTEM_DATADIR "${CMAKE_INSTALL_PREFIX}")
 469 endif()
 470
 471 # The define below allows lyx-executable to find its default configuration files
 472 # see routines
 473 #    Package::messages_file()
 474 #    get_default_user_support_dir()
 475 #    relative_system_support_dir()
 476 # in src/support/Package.cpp
 477 #
 478 if(LYX_PROGRAM_SUFFIX)
 479         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 480 else()
 481         set(PACKAGE ${PACKAGE_BASE})
 482 endif()
 483
 484 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 485         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 486         if (UNIX)
 487                 # use the default "/usr/local"
 488                 # but respect the user-choice on the command-line
 489                 set(CMAKE_INSTALL_PREFIX "/usr/local" CACHE PATH "LyX default install prefix" FORCE)
 490         endif()
 491 endif()
 492 if(WIN32)
 493         set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 494 endif()
 495 if(IS_ABSOLUTE)
 496         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 497 else()
 498         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 499 endif()
 500
 501
 502
 503 if(NOT LYX_DATA_SUBDIR)
 504         if (WIN32)
 505                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 506         else()
 507                 set(LYX_DATA_SUBDIR "share/${_lyx}/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 508         endif()
 509 endif()
 510
 511 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 512 get_locale_destination(LYX_LOCALEDIR)
 513 set(LYX_ABS_INSTALLED_LOCALEDIR "${CMAKE_INSTALL_PREFIX}/${LYX_LOCALEDIR}")
 514 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 515
 516 if(LYX_BUNDLE AND APPLE)
 517         set(LYX_MAN_DIR "${LYX_DATA_SUBDIR}" CACHE STRING "Install location for man pages.")
 518 else()
 519         if(WIN32)
 520                 set(LYX_MAN_DIR "${CMAKE_BINARY_DIR}/usr/local/man" CACHE STRING "Install location for man pages.")
 521         elseif(UNIX)
 522                 set(LYX_MAN_DIR "${CMAKE_INSTALL_PREFIX}/share/man" CACHE STRING "Install location for man pages.")
 523         else()
 524                 set(LYX_MAN_DIR "${CMAKE_INSTALL_PREFIX}/man" CACHE STRING "Install location for man pages.")
 525         endif()
 526 endif()
 527 mark_as_advanced(LYX_MAN_DIR)
 528
 529 if(LYX_INSTALL AND WIN32)
 530         message(STATUS "Configuring NSIS files")
 531         configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 532         configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 533         configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 534         message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 535 endif()
 536
 537 if(NOT GROUP_CODE)
 538         #set(GROUP_CODE "The Golden Code")
 539         set(GROUP_CODE flat)
 540 endif()
 541
 542 # lyx's source files
 543 set(LYX_CPP_FILES [a-zA-Z]*.cpp)
 544 set(LYX_HPP_FILES [a-zA-Z]*.h)
 545 set(LYX_MOC_FILES moc_*.cpp)
 546
 547 include(ProjectSourceGroup)
 548
 549
 550 if(LYX_PROFILE AND NOT MSVC)
 551         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 552         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg")
 553         set(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS}  -pg")
 554 else()
 555         set(LYX_PROFILE OFF)
 556 endif()
 557
 558
 559 if(LYX_NO_OPTIMIZE)
 560         set(CMAKE_BUILD_TYPE None)
 561         set(LYX_DEBUG OFF)
 562         set(LYX_RELEASE OFF)
 563         set(LYX_PROFILE OFF)
 564 elseif(LYX_RELEASE)
 565         set(CMAKE_BUILD_TYPE Release)
 566         set(LYX_DEBUG OFF)
 567         set(LYX_PROFILE OFF)
 568 elseif(LYX_PROFILE)
 569         set(CMAKE_BUILD_TYPE Profile)
 570         set(LYX_DEBUG OFF)
 571 else()
 572         set(CMAKE_BUILD_TYPE Debug)
 573         set(LYX_DEBUG ON)
 574 endif()
 575
 576
 577 # When shared libs are supported enable this option
 578 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 579 if(LYX_SHARED_LIBRARIES)
 580         set(library_type SHARED)
 581 else()
 582         set(library_type STATIC)
 583 endif()
 584
 585 if(NOT MSVC)
 586         if(NOT LYX_QUIET)
 587                 set(CMAKE_VERBOSE_MAKEFILE ON)
 588         endif()
 589         set(LYX_CXX_FLAGS "-Wall -Wunused-parameter ${LYX_GCC11_MODE}")
 590         if(LYX_CXX_FLAGS MATCHES "\\+\\+(14|11|98)")
 591           # Thanks to Brad King <brad.king@kitware.com>
 592           # for the pointer to https://cmake.org/cmake/help/v3.6/variable/CMAKE_CXX_STANDARD.html
 593           # This allows us to use QT5.7 with recent g++ (version >= 4.9) compilers
 594           # and still use our own c++ extension tests
 595           set(CMAKE_CXX_STANDARD ${CMAKE_MATCH_1})
 596           message(STATUS "CMAKE_CXX_STANDARD set to ${CMAKE_CXX_STANDARD}")
 597         endif()
 598         if(LYX_STDLIB_DEBUG)
 599                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 600         endif()
 601         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 602         set(CMAKE_CXX_FLAGS_DEBUG "${LYX_CXX_FLAGS} -fno-strict-aliasing -O0 -g3 -D_DEBUG" CACHE TYPE STRING FORCE)
 603         if(MINGW)
 604                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 605         else()
 606                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 607         endif()
 608 endif()
 609
 610 set(LYX_CXX_FLAGS_EXTRA "" CACHE STRING "Desired semicolon separated list of extra cxx compile flags, like '-Werror'")
 611 mark_as_advanced(LYX_CXX_FLAGS_EXTRA)
 612 if(LYX_CXX_FLAGS_EXTRA)
 613         foreach(_flag ${LYX_CXX_FLAGS_EXTRA})
 614                 add_definitions(${_flag})
 615         endforeach()
 616 endif()
 617
 618 if(LYX_XMINGW)
 619         list(APPEND CMAKE_FIND_ROOT_PATH ${GNUWIN32_DIR})
 620 endif()
 621
 622 if(LYX_USE_QT MATCHES "QT5")
 623         # set QPA_XCB if QT uses X11
 624         find_package(Qt5Core REQUIRED)
 625         if (Qt5Core_FOUND)
 626                 find_package(Qt5Widgets REQUIRED)
 627                 if(APPLE)
 628                         find_package(Qt5MacExtras REQUIRED)
 629                 endif()
 630                 find_package(Qt5X11Extras QUIET)
 631                 find_package(Qt5WinExtras QUIET)
 632                 set(QTVERSION ${Qt5Core_VERSION})
 633                 macro (qt_use_modules)
 634                         qt5_use_modules(${ARGN})
 635                 endmacro()
 636                 macro (qt_add_resources)
 637                         qt5_add_resources(${ARGN})
 638                 endmacro()
 639                 macro (qt_wrap_uifiles)
 640                         qt5_wrap_ui(${ARGN})
 641                 endmacro()
 642                 message(STATUS "Found Qt-Version ${QTVERSION}")
 643                 if(WIN32)
 644                         set(LYX_QTMAIN_LIBRARY ${Qt5Core_QTMAIN_LIBRARIES})
 645                 endif()
 646         endif()
 647 elseif(LYX_USE_QT MATCHES "QT4")
 648         if(LYX_XMINGW)
 649                 set(QT_MINGW_DIR ${LYX_QT4} CACHE PATH "Qt for Mingw" FORCE)
 650                 list(APPEND CMAKE_FIND_ROOT_PATH ${QT_MINGW_DIR} ${GNUWIN32_DIR})
 651         endif()
 652         find_package(Qt4 "4.5.0" REQUIRED)
 653         macro (qt_use_modules)
 654         endmacro()
 655         macro (qt_add_resources)
 656                 qt4_add_resources(${ARGN})
 657         endmacro()
 658         macro (qt_wrap_uifiles)
 659                 qt4_wrap_ui(${ARGN})
 660         endmacro()
 661         set(LYX_QTMAIN_LIBRARY ${QT_QTSVG_LIBRARY})
 662         if(WIN32)
 663                 list(APPEND LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARIES})
 664         endif()
 665 else()
 666   message(FATAL_ERROR "Unhandled value for LYX_USE_QT (${LYX_USE_QT})")
 667 endif()
 668
 669 find_package(Magic)
 670 if(Magic_FOUND)
 671         set(HAVE_MAGIC_H 1)
 672 endif()
 673
 674 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 675
 676 set(Spelling_FOUND OFF)
 677 set(Include_used_spellchecker)   # String will be inserted into config.h
 678
 679 if(NOT LYX_EXTERNAL_HUNSPELL)
 680     add_subdirectory(3rdparty/hunspell)
 681     add_definitions(-DHUNSPELL_STATIC)
 682     set(HUNSPELL_FOUND ON)
 683     message(STATUS "  * Hunspell:")
 684     message(STATUS "     - include: ${HUNSPELL_INCLUDE_DIR}")
 685     message(STATUS "     - library: ${HUNSPELL_LIBRARY}")
 686 endif()
 687
 688 foreach(_spell "ASPELL" "Enchant" "Hunspell")
 689   string(TOUPPER ${_spell} _upspell)
 690   if (NOT ${_upspell}_FOUND)
 691     find_package(${_spell})
 692   endif()
 693   if (${_upspell}_FOUND)
 694     include_directories(${${_upspell}_INCLUDE_DIR})
 695     set(Spelling_FOUND ON)
 696     message(STATUS "Building with USE_${_upspell}")
 697     set(Include_used_spellchecker "${Include_used_spellchecker}#define USE_${_upspell} 1\n")
 698   else()
 699     if(LYX_${_upspell})
 700       message(FATAL_ERROR "Required ${_spell} devel package not found")
 701     else()
 702       message(STATUS "${_upspell} not found, building without ${_spell} support")
 703     endif()
 704   endif()
 705 endforeach()
 706
 707 if(GNUWIN32_DIR)
 708         list(APPEND CMAKE_PROGRAM_PATH "${GNUWIN32_DIR}/Python" )
 709 endif()
 710
 711 find_package(PythonInterp 2.7 QUIET)
 712 if(PYTHONINTERP_FOUND)
 713         if(PYTHON_VERSION_STRING VERSION_GREATER 2.8)
 714         unset(PYTHONINTERP_FOUND)
 715         endif()
 716 endif()
 717
 718 if(NOT PYTHONINTERP_FOUND)
 719   unset(PYTHON_EXECUTABLE CACHE)
 720   unset(PYTHON_VERSION_MAJOR)
 721   unset(PYTHON_VERSION_MINOR)
 722   unset(PYTHON_VERSION_STRING)
 723   find_package(PythonInterp 3.3 REQUIRED)
 724 endif()
 725
 726 set(LYX_PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 727
 728 if(LYX_NLS)
 729         find_package(LyXGettext)
 730         if(LYX_PYTHON_EXECUTABLE AND GETTEXT_FOUND)
 731                 add_subdirectory(po "${TOP_BINARY_DIR}/po")
 732         else()
 733                 # Install only supplied .gmo-files
 734                 file(GLOB _gmofiles RELATIVE "${TOP_SRC_DIR}/po" "${TOP_SRC_DIR}/po/*.gmo")
 735                 message(STATUS "Installing provided .gmo-files only")
 736                 foreach( _gmo ${_gmofiles})
 737                         string(REGEX REPLACE "\\.gmo$" "" _lang ${_gmo})
 738                         install(FILES "${TOP_SRC_DIR}/po/${_gmo}" DESTINATION ${LYX_LOCALEDIR}/${_lang}/LC_MESSAGES RENAME ${PACKAGE}.mo)
 739                 endforeach()
 740         endif()
 741 endif()
 742
 743 if(LYX_EXTERNAL_ICONV)
 744   find_package(ICONV REQUIRED)
 745 else()
 746   add_subdirectory(3rdparty/libiconv)
 747   set(HAVE_ICONV_CONST 1)
 748 endif()
 749
 750 if(LYX_EXTERNAL_Z)
 751   find_package(ZLIB REQUIRED)
 752 else()
 753   add_subdirectory(3rdparty/zlib)
 754 endif()
 755
 756 if(LYX_EXTERNAL_BOOST)
 757         message(STATUS "Searching for boost")
 758         if(NOT LYX_USE_STD_REGEX)
 759                 find_package(Boost COMPONENTS regex)
 760         endif()
 761         if(Boost_FOUND)
 762                 message(STATUS "Boost found")
 763                 message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 764                 set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 765                 if (LYX_STDLIB_DEBUG)
 766                         # Comment from  Jean-Marc Lasgouttes:
 767                         # In general, system boost libraries are incompatible with
 768                         # the use of stdlib-debug in libstdc++. See ticket #9736 for
 769                         # details.
 770                         message(WARNING "Compiling LyX with stdlib-debug and system boost libraries may lead to crashes. Consider using '-DLYX_STDLIB_DEBUG=OFF' or using '-DLYX_EXTERNAL_BOOST=OFF'")
 771                 endif()
 772         else()
 773                 message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 774         endif()
 775 else()
 776         if(NOT LYX_USE_STD_REGEX)
 777                 set(Lyx_Boost_Libraries boost_regex)
 778         endif()
 779         add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 780         include_directories(${TOP_SRC_DIR}/3rdparty/boost)
 781         add_subdirectory(3rdparty/boost "${TOP_BINARY_DIR}/3rdparty/boost")
 782 endif()
 783
 784
 785
 786
 787 if(WIN32)
 788         if(LYX_CONSOLE)
 789                 set(LYX_QTMAIN_LIBRARY)
 790         else()
 791                 set(WIN32_CONSOLE WIN32)
 792         endif()
 793         if(MSVC)
 794                 # -DPSAPI_VERSION=1 is needed to run on vista (bug 10186)
 795                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX -DPSAPI_VERSION=1)
 796                 # disable checked iterators for msvc release builds to get maximum speed
 797                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 798         else()
 799                 # -DPSAPI_VERSION=1 is not needed for mingw, since the mingw psapi.h
 800                 # does not use it and always declares the vista compatible API.
 801                 # If this ever changes then -DPSAPI_VERSION might be needed here as well.
 802                 add_definitions(-DWINVER=0x0500)
 803         endif()
 804 endif()
 805
 806 # Compute qt4-version from ${QTVERSION}
 807
 808 message(STATUS "")
 809 foreach(_v PACKAGE PACKAGE_VERSION
 810         PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 811         LYX_ABS_TOP_SRCDIR
 812         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 813         if(NOT DEFINED ${_v})
 814                 message(FATAL_ERROR "${_v} not defined")
 815         endif()
 816         string(SUBSTRING "${_v}                            " 0 28 _v1)
 817         message(STATUS "----- ${_v1}: ${${_v}}")
 818 endforeach(_v)
 819 message(STATUS "")
 820
 821
 822 if(LYX_PCH)
 823         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 824         # Not sure if it works for all non-msvc compilers
 825         include(PCHSupport_26)
 826         configure_file(${TOP_CMAKE_PATH}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
 827         configure_file(${TOP_CMAKE_PATH}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 828         add_definitions(-DLYX_ENABLE_PCH)
 829
 830         if(MSVC)
 831                 macro(lyx_add_msvc_pch name_)
 832                         set_source_files_properties(${${name_}_sources} PROPERTIES
 833                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 834                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
 835                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 836                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
 837                                 ${TOP_BINARY_DIR}/pcheaders.h)
 838                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 839                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 840                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 841                 endmacro(lyx_add_msvc_pch)
 842                 macro(lyx_add_gcc_pch name_)
 843                 endmacro()
 844         else()
 845                 macro(lyx_add_msvc_pch name_)
 846                 endmacro()
 847                 macro(lyx_add_gcc_pch name_)
 848                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT)
 849                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
 850                 endmacro()
 851         endif()
 852 else()
 853         macro(lyx_add_msvc_pch)
 854         endmacro(lyx_add_msvc_pch)
 855         macro(lyx_add_gcc_pch name_)
 856         endmacro()
 857 endif()
 858
 859
 860 if(MSVC)
 861
 862         if(LYX_VLD)
 863                 set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/development/Win32/vld)
 864                 add_subdirectory(${vld_path}/cmake)
 865                 include(${vld_path}/cmake/vld.cmake) # forced include
 866                 set(vld_dll vld)
 867         endif()
 868
 869         if(LYX_WALL)
 870                 # Use the highest warning level
 871                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 872
 873                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 874                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 875                 else()
 876                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 877                 endif()
 878
 879                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 880                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 881                 else()
 882                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 883                 endif()
 884
 885                 # add here warnings which should produce an error /weXXXX
 886                 set(MSVC_W_ERROR   "/we4101 /we4189")
 887                 # add here warnings which should be disabled /wdXXXX
 888                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 889
 890                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 891                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 892                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 893
 894         else()
 895                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 896
 897                 # add here warnings which should produce an error /weXXXX
 898                 set(MSVC_W_ERROR   "/we4101 /we4189")
 899                 # add here warnings which should be disabled /wdXXXX
 900                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 901
 902                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 903                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 904                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 905
 906         endif()
 907
 908         if (NOT Qt5Core_FOUND)
 909                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 910                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 911                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 912         endif()
 913
 914         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 915         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 916         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 917         message(STATUS "")
 918 endif()
 919
 920
 921 if(LYX_DEBUG_GLIBC)
 922         set(_GLIBCXX_DEBUG ON)
 923 endif()
 924
 925 if(LYX_DEBUG_GLIBC_PEDANTIC)
 926         set(_GLIBCXX_DEBUG_PEDANTIC ON)
 927 endif()
 928
 929 # Xcode compiler
 930 if (CMAKE_GENERATOR MATCHES Xcode)
 931         if (XCODE_VERSION VERSION_LESS "5.0")
 932                 # Automatically select the Xcode compiler if not set
 933                 if (NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 934                         # XCode >= 3.1 has gcc 4.2 (up to actual Xcode)
 935                         if (XCODE_VERSION VERSION_GREATER "3.1")
 936                                 SET(CMAKE_XCODE_ATTRIBUTE_GCC_VERSION "com.apple.compilers.llvmgcc42")
 937                         ENDIF(XCODE_VERSION VERSION_GREATER "3.1")
 938                 ENDIF(NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 939                 # Print the selected compiler version
 940         MESSAGE(STATUS "---- Using XCode compiler CMAKE_XCODE_ATTRIBUTE_GCC_VERSION=${CMAKE_XCODE_ATTRIBUTE_GCC_VERSION}")
 941         ENDIF(XCODE_VERSION VERSION_LESS "5.0")
 942 ENDIF(CMAKE_GENERATOR MATCHES Xcode)
 943
 944 if (WIN32 AND Qt5Core_FOUND)
 945         set(Z_PREFIX 1)
 946 endif()
 947
 948 # compiler tests, config.h generation LYX_CONFIGURE_CHECKS
 949 include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
 950 configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
 951
 952 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
 953
 954 if(QTVERSION MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+).*")
 955         MATH(EXPR QT4_VERSION "(${CMAKE_MATCH_1}<<16)|(${CMAKE_MATCH_2}<<8)|${CMAKE_MATCH_3}")
 956 endif()
 957
 958 if (NOT HAVE_REGEX)
 959         set(LYX_USE_STD_REGEX 0)
 960 endif()
 961
 962
 963 set (cmd ${CMAKE_CTEST_COMMAND})
 964 if (MSVC)
 965         set (cmd ${cmd} -C ${CMAKE_CFG_INTDIR})
 966 else ()
 967         set (cmd ${cmd} -C ${CMAKE_BUILD_TYPE})
 968 endif ()
 969 add_custom_target (lyx_run_tests COMMAND ${cmd})
 970 set_target_properties(lyx_run_tests PROPERTIES FOLDER "tests")
 971
 972 if(LYX_ASAN)
 973     set(LYX_CXX_FLAGS "-fsanitize=address -fno-omit-frame-pointer -g")
 974     message(STATUS)
 975     message(STATUS "Address sanitizer enabled. Usage:")
 976     message(STATUS "    wget https://llvm.org/svn/llvm-project/compiler-rt/trunk/lib/asan/scripts/asan_symbolize.py")
 977     message(STATUS "    chmod  +x ./asan_symbolize.py")
 978     message(STATUS "    ./bin/lyx2.2 2>&1 | ./asan_symbolize.py  | c++filt ")
 979     message(STATUS)
 980 endif()
 981
 982 if(LYX_INSTALL)
 983         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 984                 message(STATUS "Python required to create doc!")
 985         else()
 986                 if(UNIX)
 987                         add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
 988                 endif()
 989                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
 990         endif()
 991         include(../Install)
 992 endif()
 993
 994 add_subdirectory(src "${TOP_BINARY_DIR}/src")
 995 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
 996 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
 997 add_subdirectory(lib/examples "${TOP_BINARY_DIR}/lib/examples")
 998 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
 999 add_subdirectory(development/autotests "${TOP_BINARY_DIR}/autotests")
1000 if(LYX_ENABLE_URLTESTS)
1001         add_subdirectory(development/checkurls "${TOP_BINARY_DIR}/checkurls")
1002 endif()
1003
1004 message(STATUS)
1005 message(STATUS "Build params, switch LYX_* options by -DLYX_*=ON or OFF, LYX_* combos by -DLYX_*=value:")
1006 message(STATUS)
1007
1008 LYX_OPTION_LIST_ALL(used)
1009
1010
1011 if(LYX_NLS)
1012         message(STATUS)
1013         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
1014         message(STATUS)
1015         message(STATUS "  * iconv")
1016         message(STATUS "     - include: ${ICONV_INCLUDE_DIR}")
1017         message(STATUS "     - library: ${ICONV_LIBRARY}")
1018         message(STATUS "  * zlib")
1019         message(STATUS "     - include: ${ZLIB_INCLUDE_DIR}")
1020         message(STATUS "     - library: ${ZLIB_LIBRARY}")
1021         message(STATUS)
1022 endif()
1023
1024 # Apple has builtin native spell checker,
1025 # no need to warn for missing Aspell, Hunspell or Enchant
1026 if(NOT Spelling_FOUND AND NOT APPLE)
1027   if(LYX_REQUIRE_SPELLCHECK)
1028     set(_mode "FATAL_ERROR")
1029   else()
1030     set(_mode "STATUS")
1031   endif()
1032   message(${_mode} "No spellcheck libraries found. LyX will be unable use spellchecking")
1033 endif()
1034
1035 include("${TOP_CMAKE_PATH}/LyxPackaging.cmake")
1036
1037 if(ENABLE_DIST)
1038   # Use git to create the source package
1039   # git archive --format=tgz --output=/home/kornel/x.tar.gz master
1040   if(UNIX)
1041     set(DIST_FORMAT tgz)
1042   else()
1043     set(DIST_FORMAT zip)
1044   endif()
1045   set(DIST_NAME ${CMAKE_PROJECT_NAME}-${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}-${CMAKE_SYSTEM_NAME}.${DIST_FORMAT})
1046
1047   add_custom_command(
1048     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME}
1049     COMMAND  ${LYX_GITVERSION} archive --format=${DIST_FORMAT} --output=${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME} master
1050     WORKING_DIRECTORY ${TOP_SRC_DIR})
1051   add_custom_target(git-archive DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME})
1052 endif()
1053
1054 # Last directory to be included so that the fixup code (OS X)
1055 # can be run last
1056 add_subdirectory(development/cmake/post_install)
1057
1058 message(STATUS)