CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 2.6.4)
   8
   9 set(LYX_PROJECT LyX)
  10
  11 enable_testing()
  12
  13 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README REALPATH) # Resolve symlinks
  14 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  15 message(STATUS "TOP_SRC_DIR = ${TOP_SRC_DIR}")
  16
  17 set(LYX_CMAKE_DIR "development/cmake")
  18 set(TOP_CMAKE_PATH "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}")
  19 set(TOP_MODULE_PATH "${TOP_CMAKE_PATH}/modules")
  20 set(TOP_SCRIPT_PATH "${TOP_CMAKE_PATH}/scripts")
  21
  22 set(CMAKE_MODULE_PATH "${TOP_MODULE_PATH}")
  23
  24 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  25
  26 message(STATUS)
  27 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  28         message(STATUS "Building in-source")
  29         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  30 else()
  31         message(STATUS "Building out-of-source")
  32         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  33 endif()
  34
  35 # This directory should be used if some test uses lyx-executable
  36 set(LYX_TESTS_USERDIR "${TOP_BINARY_DIR}/Testing/.lyx")
  37 file(MAKE_DIRECTORY "${LYX_TESTS_USERDIR}")
  38
  39 if(COMMAND cmake_policy)
  40         # Installing MACOSX_BUNDLE targets requires a BUNDLE DESTINATION
  41         cmake_policy(SET CMP0006 NEW)
  42         if(POLICY CMP0043)
  43                 # COMPILE_DEFINITIONS are not used yet. Enable new behavior.
  44                 cmake_policy(SET CMP0043 NEW)
  45         endif()
  46 endif()
  47
  48 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  49
  50 # Supress regeneration
  51 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  52
  53 if(LYX_XMINGW)
  54     set(CMAKE_SYSTEM_NAME Windows)
  55     set(TOOLNAME ${LYX_XMINGW})
  56     set(TOOLCHAIN "${TOOLNAME}-")
  57     set(CMAKE_C_COMPILER   "${TOOLCHAIN}gcc"     CACHE PATH "Mingw C compiler" FORCE)
  58     set(CMAKE_CXX_COMPILER "${TOOLCHAIN}g++"     CACHE PATH "Mingw C++ compiler" FORCE)
  59     set(CMAKE_RC_COMPILER  "${TOOLCHAIN}windres" CACHE PATH "Mingw rc compiler" FORCE)
  60
  61     set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM BOTH)
  62     set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY)
  63     set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY)
  64 endif()
  65
  66 if(NOT help AND NOT HELP)
  67   # 'project' triggers the searching for a compiler
  68   project(${LYX_PROJECT})
  69   if (CMAKE_COMPILER_IS_GNUCXX)
  70     if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS "4.0")
  71       message(STATUS "Gnu CXX compiler version = ${CMAKE_CXX_COMPILER_VERSION}")
  72       message(STATUS "is too old, should be >= 4.0")
  73       message(FATAL_ERROR "Exiting")
  74     endif()
  75   endif()
  76 endif()
  77
  78 if(UNIX)
  79         set(ARCH_TRIPLET )
  80         FIND_PROGRAM(DPKG_ARCHITECTURE_EXECUTABLE dpkg-architecture)
  81         if(DPKG_ARCHITECTURE_EXECUTABLE)
  82                 EXECUTE_PROCESS(COMMAND ${DPKG_ARCHITECTURE_EXECUTABLE} -qDEB_HOST_MULTIARCH
  83                                 OUTPUT_VARIABLE ARCH_TRIPLET
  84                                 ERROR_VARIABLE ERROR_ARCH_TRIPLET
  85                                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  86         endif()
  87 endif()
  88 if(ARCH_TRIPLET)
  89         set(SYSTEM_LIB_DIRS /usr/lib /usr/lib/${ARCH_TRIPLET} /usr/local/lib)
  90 else()
  91         set(SYSTEM_LIB_DIRS /usr/lib /usr/local/lib)
  92 endif()
  93
  94 include(LyXMacros)
  95 include(LyXDestinations)
  96
  97 # Usage LYX_OPTION
  98 # 1. parameter: option name without prefix 'LYX_'
  99 # 2. parameter: description
 100 # 3. parameter: default value, ON or OFF
 101 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
 102
 103 # Usage LYX_COMBO
 104 # 1. parameter: name without prefix 'LYX_'
 105 # 2. parameter: description
 106 # 3. parameter: default value
 107 # 4-n parameter: possible other string values
 108
 109 LYX_OPTION_INIT()
 110
 111 # Options for all compilers/systems
 112 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
 113 LYX_OPTION(LOCALVERSIONING  "Add version info to created package name (only used if LYX_CPACK option set)" OFF ALL)
 114 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
 115 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
 116 LYX_OPTION(REQUIRE_SPELLCHECK "Abort if no spellchecker available" OFF ALL)
 117 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
 118 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
 119 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
 120 LYX_OPTION(DEVEL_VERSION    "Build developer version" OFF ALL)
 121 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" OFF ALL)
 122 LYX_OPTION(DEBUG            "Enforce debug build"  OFF ALL)
 123 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
 124 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
 125 LYX_STRING(SUFFIX_VALUE     "Use this string as suffix" "")
 126 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
 127 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
 128 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
 129 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
 130 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
 131 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
 132 LYX_OPTION(ENABLE_URLTESTS  "Enable for URL tests" OFF ALL)
 133 LYX_OPTION(ENABLE_EXPORT_TESTS "Enable for export tests" OFF ALL)
 134 LYX_OPTION(ENABLE_KEYTESTS  "Enable for keytests" OFF ALL)
 135 LYX_OPTION(ASAN             "Use address sanitizer" OFF ALL)
 136 LYX_COMBO(USE_QT            "Use Qt version as frontend" QT4 QT5)
 137 #LYX_OPTION(3RDPARTY_BUILD   "Build 3rdparty libs" OFF ALL)
 138 LYX_OPTION(EXTERNAL_Z       "OFF := Build 3rdparty lib zlib" ON ALL)
 139 LYX_OPTION(EXTERNAL_ICONV   "OFF := Build 3rdparty lib iconvlib" ON ALL)
 140 LYX_OPTION(EXTERNAL_HUNSPELL "OFF := Build 3rdparty lib hunspelllib" ON ALL)
 141 LYX_COMBO(EXTERNAL_MYTHES   "OFF := Build 3rdparty lib mytheslib" AUTO OFF ON)
 142
 143 # GCC specific
 144 LYX_OPTION(PROFILE              "Build profile version" OFF GCC)
 145 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" OFF GCC)
 146 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
 147 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
 148 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++ pedantic debug mode" OFF GCC)
 149 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" OFF GCC)
 150 LYX_OPTION(PROFILE              "Build with options for gprof" OFF GCC)
 151
 152 # MSVC specific
 153 LYX_OPTION(CONSOLE               "Show console on Windows, enforce with =FORCE" ON MSVC)
 154 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
 155 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
 156 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
 157
 158 # APPLE specific
 159 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
 160 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
 161
 162
 163 if(help OR HELP)
 164         message(STATUS)
 165         message(STATUS "Available options: (dis/enable with -DLYX_*=OFF/ON)")
 166         message(STATUS)
 167         LYX_OPTION_LIST_ALL(help)
 168         message(STATUS)
 169         RETURN()
 170 endif()
 171
 172 # Check option dependencies
 173
 174 if(LYX_DMG)
 175         set(LYX_BUNDLE ON)
 176         set(LYX_CPACK ON)
 177 endif()
 178
 179 if(LYX_CPACK)
 180         set(LYX_INSTALL ON)
 181 endif()
 182
 183 if(LYX_INSTALL)
 184         set(LYX_NLS ON)
 185         if(WIN32 AND NOT MINGW)
 186                 set(LYX_HUNSPELL ON)
 187         endif()
 188         if(LYX_CONSOLE MATCHES "FORCE")
 189                 set(LYX_CONSOLE ON)
 190         else()
 191                 set(LYX_CONSOLE OFF)
 192         endif()
 193         set(LYX_PACKAGE_SUFFIX ON)
 194         if(NOT LYX_DEBUG)
 195                 set(LYX_RELEASE ON)
 196         endif()
 197         set(LYX_PROFILE OFF)
 198 endif()
 199
 200
 201 if(LYX_MERGE_FILES)
 202         set(LYX_PCH OFF)
 203 else()
 204         set(LYX_MERGE_REBUILD OFF)
 205 endif()
 206
 207 if(LYX_DEPENDENCIES_DOWNLOAD)
 208         message(STATUS)
 209         if(MSVC14)
 210                 set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2015-deps)
 211                 set(deps_files lyx-windows-deps-msvc2015.zip)
 212                 set(deps_server http://ftp.lyx.de/LyX-Windows-Deps)
 213                 set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2015)
 214         elseif(MSVC10)
 215                 set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 216                 set(deps_files lyx-windows-deps-msvc2010.zip)
 217                 set(deps_server http://ftp.lyx.de/LyX-Windows-Deps)
 218                 set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2010)
 219         else()
 220                 message(FATAL_ERROR "error: no dependency package known for the selected MSVC version.")
 221         endif()
 222     message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 223         foreach(it ${deps_files})
 224                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 225                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 226                 if(NOT already_downloaded)
 227                         message(STATUS "Downloading ${it} ...")
 228                         file(DOWNLOAD ${deps_server}/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS STATUS status LOG log)
 229                         list(GET status 0 status_code)
 230                         list(GET status 1 status_string)
 231                         if(NOT status_code EQUAL 0)
 232                                 file(REMOVE ${LYX_DEPENDENCIES_DIR}/${it})
 233                                 message(FATAL_ERROR "error: downloading '${it}' failed. status_code: ${status_code}, status_string: ${status_string}. \nLog: ${log} ")
 234                         endif()
 235                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 236                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 237                 endif()
 238         endforeach()
 239 endif()
 240
 241
 242
 243 message(STATUS)
 244
 245 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 246 if(WIN32)
 247         set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 248 else()
 249         set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 250 endif()
 251
 252
 253 # Set to some meaningful default
 254 find_package(CXX11Compiler)
 255 if(NOT CXX11COMPILER_FOUND)
 256         message(FATAL_ERROR "A C++11 compatible compiler is required.")
 257 endif()
 258 set(LYX_GCC11_MODE)
 259 if(UNIX OR MINGW)
 260         if (CMAKE_CXX_COMPILER_ID MATCHES "^[cC]lang$")
 261           # ignore the GCC_VERSION for clang
 262           # and use the resulting CXX11_STD_REGEX found in FindCXX11Compiler.cmake
 263           message(STATUS "Using clang")
 264           if(CXX11_STD_REGEX)
 265             set(LYX_USE_STD_REGEX 1)
 266           else()
 267             set(LYX_USE_STD_REGEX 0)
 268           endif()
 269         else()
 270           execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION OUTPUT_STRIP_TRAILING_WHITESPACE)
 271           message(STATUS "Using GCC version ${GCC_VERSION}")
 272           if(GCC_VERSION VERSION_LESS 4.9)
 273                   if(GCC_VERSION VERSION_LESS 4.6)
 274                           message(FATAL_ERROR "gcc >= 4.6 is required.")
 275                   endif()
 276                   # <regex> in gcc is unusable in versions less than 4.9.0
 277                   # see https://gcc.gnu.org/bugzilla/show_bug.cgi?id=53631
 278                   set(LYX_USE_STD_REGEX 0)
 279           else()
 280                   set(LYX_USE_STD_REGEX 1)
 281           endif()
 282         endif()
 283         set(LYX_GCC11_MODE "${CXX11_FLAG}")
 284 else()
 285         set(LYX_USE_STD_REGEX 0)
 286 #       if(MSVC10)
 287 #               set(LYX_USE_STD_REGEX 1) #TODO should we use it in ECMAScript mode?
 288 #       endif()
 289 endif()
 290
 291
 292 set(VERSION_INFO "CMake Build")
 293
 294 # Try to get some informations from configure.ac
 295
 296 include(LyXPaths)
 297 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 298
 299 if(WIN32)
 300         set(CMAKE_PREFIX_PATH Specify-path-to-Qt CACHE PATH "Used Qt version")
 301         if(MSVC)
 302                 set(LYX_3RDPARTY_BUILD ON CACHE BOOL "Build 3rdparty libraries" FORCE)
 303         endif()
 304         set(USE_WINDOWS_PACKAGING ON)
 305 elseif(APPLE)
 306         set(USE_MACOSX_PACKAGING ON)
 307 else()
 308         set(USE_POSIX_PACKAGING ON)
 309 endif()
 310
 311 if(LYX_3RDPARTY_BUILD)
 312   # LYX_3RDPARTY_BUILD is not cached anymore, but for compatibility reasons
 313   # this enables the build of all 3rd_party libs
 314   set(LYX_EXTERNAL_Z        OFF CACHE BOOL "Build 3rdparty lib zlib"    FORCE)
 315   set(LYX_EXTERNAL_ICONV    OFF CACHE BOOL "Build 3rdparty iconvlib"    FORCE)
 316   set(LYX_EXTERNAL_HUNSPELL OFF CACHE BOOL "Build 3rdparty hunspelllib" FORCE)
 317   set(LYX_EXTERNAL_MYTHES   OFF CACHE STRING "Build 3rdparty mytheslib" FORCE)
 318 endif()
 319
 320 macro(setstripped _varname)
 321         if(${ARGC} GREATER 1)
 322                 string(STRIP "${ARGV1}" _v)
 323                 if(USE_POSIX_PACKAGING)
 324                         string(TOLOWER ${_v} ${_varname})
 325                 else()
 326                         set(${_varname} ${_v})
 327                 endif()
 328         else()
 329                 set(${_varname})
 330         endif()
 331 endmacro(setstripped)
 332
 333 foreach(_c_l ${_config_lines} )
 334         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 335                 setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 336                 setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 337                 setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 338                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\)\(\\.\([0-9]+\)\)?.*$")
 339                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 340                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 341                         set(LYX_PATCH_VERSION ${CMAKE_MATCH_4})
 342                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 343                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 344                         if ("${LYX_SUFFIX_VALUE}" MATCHES "")
 345                           set(LYX_INSTALL_SUFFIX "${LYX_MAJOR_VERSION}.${LYX_MINOR_VERSION}")
 346                         else()
 347                           set(LYX_INSTALL_SUFFIX "${LYX_SUFFIX_VALUE}")
 348                         endif()
 349                 endif()
 350         endif()
 351         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 352                 set(LYX_DATE "${CMAKE_MATCH_1}")
 353         endif()
 354 endforeach(_c_l)
 355
 356 FIND_PROGRAM(LYX_GITVERSION git)
 357 #message(STATUS "gitversion = ${LYX_GITVERSION}")
 358 set(LYX_REVISION_VERSION ${LYX_PATCH_VERSION})
 359 if(LYX_GITVERSION)
 360   if (LYX_LOCALVERSIONING)
 361     # Find the revision number and for later use
 362     EXECUTE_PROCESS(COMMAND ${LYX_GITVERSION} describe --match 2.0.0 HEAD
 363       WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE LYX_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 364     if (LYX_PACKAGE_RELEASE MATCHES "^2\\.0\\.0\\-\([0-9]+\)\\-.*$")
 365       # We will add offset of 40000 to get appropriate value to
 366       # previous svn.
 367       # We use this value than also to set the package-patch-value
 368       MATH(EXPR tmp_REVISION_VERSION "(${CMAKE_MATCH_1}+40000)")
 369       set(LYX_REVISION_VERSION "${LYX_PATCH_VERSION}-${tmp_REVISION_VERSION}git")
 370       set(ENABLE_DIST ON)
 371     endif()
 372   endif()
 373 endif()
 374
 375 # Set the programs (lyx, tex2lyx, etc.) suffix
 376 # When building an OS X bundle, we will append
 377 # the suffix only to the bundle, not to the programs
 378 set(PROGRAM_SUFFIX "")
 379 if(LYX_PROGRAM_SUFFIX AND NOT (APPLE AND LYX_BUNDLE))
 380         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 381 endif()
 382 set(_lyx "${PACKAGE_BASE}${PROGRAM_SUFFIX}")
 383 set(_tex2lyx tex2lyx${PROGRAM_SUFFIX})
 384
 385 add_custom_target(lyx_version ALL
 386   COMMAND ${CMAKE_COMMAND} -DTOP_SRC_DIR=${TOP_SRC_DIR} -DTOP_CMAKE_PATH=${TOP_CMAKE_PATH} -DTOP_BINARY_DIR=${TOP_BINARY_DIR} -DLYX_DATE=${LYX_DATE} -P ${TOP_SCRIPT_PATH}/LyXGetVersion.cmake
 387   )
 388 set_target_properties(lyx_version PROPERTIES FOLDER "applications")
 389
 390 # Default paths for installed utilities (tex2lyx, lyxclient, etc.)
 391 set(LYX_UTILITIES_INSTALL_PATH bin)
 392
 393 if(LYX_BUNDLE)
 394         set(LYX_CPACK ON)
 395
 396         message(STATUS)
 397         message(STATUS "Bundle creation is enabled (experimental):")
 398         message(STATUS "    make")
 399         message(STATUS "    make install/strip")
 400         message(STATUS "    make package")
 401         if(APPLE)
 402                 set(MACOSX_BUNDLE TRUE)
 403                 # This sets the bundle + executable names
 404                 set(_lyx "${PACKAGE_BASE}${LYX_INSTALL_SUFFIX}")
 405                 # This sets the Info.plist executable name
 406                 set(osx_bundle_program_name ${_lyx})
 407                 # Bundle name
 408                 set(LYX_BUNDLE_NAME ${_lyx})
 409
 410                 # This will contain the list of files that need to be included
 411                 # in the bundle and their location within the bundle
 412                 set(OSX_BUNDLE_FILES "${TOP_SRC_DIR}/development/MacOSX/LyX.sdef;${TOP_SRC_DIR}/development/MacOSX/LyXapp.icns;${CMAKE_BINARY_DIR}/lyxrc.dist")
 413                 set(OSX_BUNDLE_DIRS "Resources;Resources;Resources")
 414
 415                 # Process Info.plist and lyxrc.dist
 416                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/Info.plist.in" "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 417                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/lyxrc.dist.in" "${CMAKE_CURRENT_BINARY_DIR}/lyxrc.dist")
 418
 419                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 420                 set(LYX_DATA_SUBDIR ${LYX_BUNDLE_NAME}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 421
 422                 # Variables used by CPack
 423                 set(CPACK_BUNDLE_NAME ${LYX_BUNDLE_NAME})
 424                 set(CPACK_BUNDLE_PLIST "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 425                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${LYX_BUNDLE_NAME}.app)
 426
 427                 # Set the install paths
 428                 set(LYX_UTILITIES_INSTALL_PATH ${LYX_BUNDLE_NAME}.app/Contents/MacOS)
 429                 if(NOT LYX_INSTALL_PREFIX)
 430                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 431                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 432                 endif()
 433                 # Change the owner so that the install can work
 434                 install(CODE "set(BU_CHMOD_BUNDLE_ITEMS 1)" COMPONENT Runtime)
 435         elseif(UNIX)
 436                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 437                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 438                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 439         elseif(WIN32)
 440                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 441         endif()
 442 endif()
 443
 444 if(LYX_INSTALL_PREFIX)
 445         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 446         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 447 endif()
 448 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 449
 450 if(UNIX)
 451   set(SYSTEM_DATADIR "${CMAKE_INSTALL_PREFIX}/share")
 452 elseif(CMAKE_INSTALL_PREFIX MATCHES "/lyx${LYX_INSTALL_SUFFIX}$")
 453   string(REGEX REPLACE "/lyx${LYX_INSTALL_SUFFIX}$" "/share" SYSTEM_DATADIR ${CMAKE_INSTALL_PREFIX})
 454 else()
 455   set(SYSTEM_DATADIR "${CMAKE_INSTALL_PREFIX}")
 456 endif()
 457
 458 # The define below allows lyx-executable to find its default configuration files
 459 # see routines
 460 #    Package::messages_file()
 461 #    get_default_user_support_dir()
 462 #    relative_system_support_dir()
 463 # in src/support/Package.cpp
 464 #
 465 if(LYX_PROGRAM_SUFFIX)
 466         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 467 else()
 468         set(PACKAGE ${PACKAGE_BASE})
 469 endif()
 470
 471 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 472         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 473         if (UNIX)
 474                 # use the default "/usr/local"
 475                 # but respect the user-choice on the command-line
 476                 set(CMAKE_INSTALL_PREFIX "/usr/local" CACHE PATH "LyX default install prefix" FORCE)
 477         endif()
 478 endif()
 479 if(WIN32)
 480         set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 481 endif()
 482 if(IS_ABSOLUTE)
 483         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 484 else()
 485         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 486 endif()
 487
 488
 489
 490 if(NOT LYX_DATA_SUBDIR)
 491         if (WIN32)
 492                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 493         else()
 494                 set(LYX_DATA_SUBDIR "share/${_lyx}/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 495         endif()
 496 endif()
 497
 498 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 499 get_locale_destination(LYX_LOCALEDIR)
 500 set(LYX_ABS_INSTALLED_LOCALEDIR "${CMAKE_INSTALL_PREFIX}/${LYX_LOCALEDIR}")
 501 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 502
 503 if(LYX_BUNDLE AND APPLE)
 504         set(LYX_MAN_DIR "${LYX_DATA_SUBDIR}" CACHE STRING "Install location for man pages.")
 505 else()
 506         if(WIN32)
 507                 set(LYX_MAN_DIR "${CMAKE_BINARY_DIR}/usr/local/man" CACHE STRING "Install location for man pages.")
 508         elseif(UNIX)
 509                 set(LYX_MAN_DIR "${CMAKE_INSTALL_PREFIX}/share/man" CACHE STRING "Install location for man pages.")
 510         else()
 511                 set(LYX_MAN_DIR "${CMAKE_INSTALL_PREFIX}/man" CACHE STRING "Install location for man pages.")
 512         endif()
 513 endif()
 514 mark_as_advanced(LYX_MAN_DIR)
 515
 516 if(LYX_INSTALL AND WIN32)
 517         message(STATUS "Configuring NSIS files")
 518         configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 519         configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 520         configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 521         message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 522 endif()
 523
 524 if(NOT GROUP_CODE)
 525         #set(GROUP_CODE "The Golden Code")
 526         set(GROUP_CODE flat)
 527 endif()
 528
 529 # lyx's source files
 530 set(LYX_CPP_FILES [a-zA-Z]*.cpp)
 531 set(LYX_HPP_FILES [a-zA-Z]*.h)
 532 set(LYX_MOC_FILES moc_*.cpp)
 533
 534 include(ProjectSourceGroup)
 535
 536
 537 if(LYX_PROFILE AND NOT MSVC)
 538         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 539         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg")
 540         set(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS}  -pg")
 541 else()
 542         set(LYX_PROFILE OFF)
 543 endif()
 544
 545
 546 if(LYX_NO_OPTIMIZE)
 547         set(CMAKE_BUILD_TYPE None)
 548         set(LYX_DEBUG OFF)
 549         set(LYX_RELEASE OFF)
 550         set(LYX_PROFILE OFF)
 551 elseif(LYX_RELEASE)
 552         set(CMAKE_BUILD_TYPE Release)
 553         set(LYX_DEBUG OFF)
 554         set(LYX_PROFILE OFF)
 555 elseif(LYX_PROFILE)
 556         set(CMAKE_BUILD_TYPE Profile)
 557         set(LYX_DEBUG OFF)
 558 else()
 559         set(CMAKE_BUILD_TYPE Debug)
 560         set(LYX_DEBUG ON)
 561 endif()
 562
 563
 564 # When shared libs are supported enable this option
 565 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 566 if(LYX_SHARED_LIBRARIES)
 567         set(library_type SHARED)
 568 else()
 569         set(library_type STATIC)
 570 endif()
 571
 572 if(NOT MSVC)
 573         if(NOT LYX_QUIET)
 574                 set(CMAKE_VERBOSE_MAKEFILE ON)
 575         endif()
 576         set(LYX_CXX_FLAGS "-Wall -Wunused-parameter ${LYX_GCC11_MODE}")
 577         if(LYX_CXX_FLAGS MATCHES "\\+\\+(14|11|98)")
 578           # Thanks to Brad King <brad.king@kitware.com>
 579           # for the pointer to https://cmake.org/cmake/help/v3.6/variable/CMAKE_CXX_STANDARD.html
 580           # This allows us to use QT5.7 with recent g++ (version >= 4.9) compilers
 581           # and still use our own c++ extension tests
 582           set(CMAKE_CXX_STANDARD ${CMAKE_MATCH_1})
 583           message(STATUS "CMAKE_CXX_STANDARD set to ${CMAKE_CXX_STANDARD}")
 584         endif()
 585         if(LYX_STDLIB_DEBUG)
 586                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 587         endif()
 588         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 589         set(CMAKE_CXX_FLAGS_DEBUG "${LYX_CXX_FLAGS} -fno-strict-aliasing -O0 -g3 -D_DEBUG" CACHE TYPE STRING FORCE)
 590         if(MINGW)
 591                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 592         else()
 593                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 594         endif()
 595 endif()
 596
 597 set(LYX_CXX_FLAGS_EXTRA "" CACHE STRING "Desired semicolon separated list of extra cxx compile flags, like '-Werror'")
 598 mark_as_advanced(LYX_CXX_FLAGS_EXTRA)
 599 if(LYX_CXX_FLAGS_EXTRA)
 600         foreach(_flag ${LYX_CXX_FLAGS_EXTRA})
 601                 add_definitions(${_flag})
 602         endforeach()
 603 endif()
 604
 605 if(LYX_XMINGW)
 606         list(APPEND CMAKE_FIND_ROOT_PATH ${GNUWIN32_DIR})
 607 endif()
 608
 609 if(LYX_USE_QT MATCHES "QT5")
 610         # set QPA_XCB if QT uses X11
 611         find_package(Qt5Core REQUIRED)
 612         if (Qt5Core_FOUND)
 613                 find_package(Qt5Widgets REQUIRED)
 614                 if(APPLE)
 615                         find_package(Qt5MacExtras REQUIRED)
 616                 endif()
 617                 find_package(Qt5X11Extras QUIET)
 618                 find_package(Qt5WinExtras QUIET)
 619                 set(QTVERSION ${Qt5Core_VERSION})
 620                 if (QTVERSION VERSION_LESS "5.4")
 621                         message(STATUS "QTVERSION = \"${QTVERSION}\"")
 622                         message(STATUS "This version is not recommended, try either option -DLYX_USE_QT=QT4 or")
 623                         message(STATUS "install QT-Version >= \"5.4\"")
 624                         # see thread in lyx-devel list
 625                         # From: Jean-Pierre Chrétien <jeanpierre.chretien@free.fr>
 626                         # Date 11.03.2017
 627                         # Subject: cmake compilation error
 628                         #message(FATAL_ERROR "Wrong Qt-Version")
 629                 endif()
 630                 macro (qt_use_modules)
 631                         qt5_use_modules(${ARGN})
 632                 endmacro()
 633                 macro (qt_add_resources)
 634                         qt5_add_resources(${ARGN})
 635                 endmacro()
 636                 macro (qt_wrap_uifiles)
 637                         qt5_wrap_ui(${ARGN})
 638                 endmacro()
 639                 message(STATUS "Found Qt-Version ${QTVERSION}")
 640                 if(WIN32)
 641                         set(LYX_QTMAIN_LIBRARY ${Qt5Core_QTMAIN_LIBRARIES})
 642                 endif()
 643         endif()
 644 elseif(LYX_USE_QT MATCHES "QT4")
 645         if(LYX_XMINGW)
 646                 set(QT_MINGW_DIR ${LYX_QT4} CACHE PATH "Qt for Mingw" FORCE)
 647                 list(APPEND CMAKE_FIND_ROOT_PATH ${QT_MINGW_DIR} ${GNUWIN32_DIR})
 648         endif()
 649         find_package(Qt4 "4.5.0" REQUIRED)
 650         macro (qt_use_modules)
 651         endmacro()
 652         macro (qt_add_resources)
 653                 qt4_add_resources(${ARGN})
 654         endmacro()
 655         macro (qt_wrap_uifiles)
 656                 qt4_wrap_ui(${ARGN})
 657         endmacro()
 658         set(LYX_QTMAIN_LIBRARY ${QT_QTSVG_LIBRARY})
 659         if(WIN32)
 660                 list(APPEND LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARIES})
 661         endif()
 662 else()
 663   message(FATAL_ERROR "Unhandled value for LYX_USE_QT (${LYX_USE_QT})")
 664 endif()
 665
 666 find_package(Magic)
 667 if(Magic_FOUND)
 668         set(HAVE_MAGIC_H 1)
 669 endif()
 670
 671 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 672
 673 set(Spelling_FOUND OFF)
 674 set(Include_used_spellchecker)   # String will be inserted into config.h
 675
 676 if (LYX_EXTERNAL_MYTHES MATCHES "AUTO")
 677   # try system library first
 678   find_package(MyThesLIB)
 679   if (MYTHESLIB_FOUND)
 680     set(LYX_EXTERNAL_MYTHES ON CACHE STRING "OFF:= Build 3rdparty mytheslib" FORCE)
 681   else()
 682     set(LYX_EXTERNAL_MYTHES OFF CACHE STRING "OFF:= Build 3rdparty mytheslib" FORCE)
 683   endif()
 684 endif()
 685 if (LYX_EXTERNAL_MYTHES MATCHES "ON")
 686   find_package(MyThesLIB REQUIRED)
 687 else()
 688   add_subdirectory(3rdparty/mythes)
 689 endif()
 690 set(MYTHES_DIR ${MYTHESLIB_INCLUDE_DIR})
 691
 692 if(NOT LYX_EXTERNAL_HUNSPELL)
 693     add_subdirectory(3rdparty/hunspell)
 694     add_definitions(-DHUNSPELL_STATIC)
 695     set(HUNSPELL_FOUND ON)
 696     message(STATUS "  * Hunspell:")
 697     message(STATUS "     - include: ${HUNSPELL_INCLUDE_DIR}")
 698     message(STATUS "     - library: ${HUNSPELL_LIBRARY}")
 699 endif()
 700
 701 foreach(_spell "ASPELL" "Enchant" "Hunspell")
 702   string(TOUPPER ${_spell} _upspell)
 703   if (NOT ${_upspell}_FOUND)
 704     find_package(${_spell})
 705   endif()
 706   if (${_upspell}_FOUND)
 707     include_directories(${${_upspell}_INCLUDE_DIR})
 708     set(Spelling_FOUND ON)
 709     message(STATUS "Building with USE_${_upspell}")
 710     set(Include_used_spellchecker "${Include_used_spellchecker}#define USE_${_upspell} 1\n")
 711   else()
 712     if(LYX_${_upspell})
 713       message(FATAL_ERROR "Required ${_spell} devel package not found")
 714     else()
 715       message(STATUS "${_upspell} not found, building without ${_spell} support")
 716     endif()
 717   endif()
 718 endforeach()
 719
 720 if(GNUWIN32_DIR)
 721         list(APPEND CMAKE_PROGRAM_PATH "${GNUWIN32_DIR}/Python" )
 722 endif()
 723
 724 # Search for python default version first
 725 unset(PYTHON_EXECUTABLE CACHE)
 726 unset(LYX_PYTHON_EXECUTABLE CACHE)
 727 unset(PYTHON_VERSION_MAJOR)
 728 unset(PYTHON_VERSION_MINOR)
 729 unset(PYTHON_VERSION_STRING)
 730 find_package(PythonInterp 3.3 QUIET)
 731 if(NOT PYTHONINTERP_FOUND)
 732   unset(PYTHON_EXECUTABLE CACHE)
 733   find_package(PythonInterp 2.0 REQUIRED)
 734   if(NOT PYTHON_VERSION_STRING VERSION_LESS 2.8)
 735     message(FATAL_ERROR "Python interpreter found, but is not suitable")
 736   endif()
 737 endif()
 738
 739 set(LYX_PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 740
 741 if(LYX_NLS)
 742         find_package(LyXGettext)
 743         if(LYX_PYTHON_EXECUTABLE AND GETTEXT_FOUND)
 744                 add_subdirectory(po "${TOP_BINARY_DIR}/po")
 745         else()
 746                 # Install only supplied .gmo-files
 747                 file(GLOB _gmofiles RELATIVE "${TOP_SRC_DIR}/po" "${TOP_SRC_DIR}/po/*.gmo")
 748                 message(STATUS "Installing provided .gmo-files only")
 749                 foreach( _gmo ${_gmofiles})
 750                         string(REGEX REPLACE "\\.gmo$" "" _lang ${_gmo})
 751                         install(FILES "${TOP_SRC_DIR}/po/${_gmo}" DESTINATION ${LYX_LOCALEDIR}/${_lang}/LC_MESSAGES RENAME ${PACKAGE}.mo)
 752                 endforeach()
 753         endif()
 754 endif()
 755
 756 if(LYX_EXTERNAL_ICONV)
 757   find_package(ICONV REQUIRED)
 758 else()
 759   add_subdirectory(3rdparty/libiconv)
 760   set(HAVE_ICONV_CONST 1)
 761 endif()
 762
 763 if(LYX_EXTERNAL_Z)
 764   find_package(ZLIB REQUIRED)
 765 else()
 766   add_subdirectory(3rdparty/zlib)
 767 endif()
 768
 769 if(LYX_EXTERNAL_BOOST)
 770         message(STATUS "Searching for boost")
 771         if(NOT LYX_USE_STD_REGEX)
 772                 find_package(Boost COMPONENTS regex)
 773         endif()
 774         if(Boost_FOUND)
 775                 message(STATUS "Boost found")
 776                 message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 777                 set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 778                 if (LYX_STDLIB_DEBUG)
 779                         # Comment from  Jean-Marc Lasgouttes:
 780                         # In general, system boost libraries are incompatible with
 781                         # the use of stdlib-debug in libstdc++. See ticket #9736 for
 782                         # details.
 783                         message(WARNING "Compiling LyX with stdlib-debug and system boost libraries may lead to crashes. Consider using '-DLYX_STDLIB_DEBUG=OFF' or using '-DLYX_EXTERNAL_BOOST=OFF'")
 784                 endif()
 785         else()
 786                 message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 787         endif()
 788 else()
 789         if(NOT LYX_USE_STD_REGEX)
 790                 set(Lyx_Boost_Libraries boost_regex)
 791         endif()
 792         add_definitions(-DBOOST_USER_CONFIG=<config.h>)
 793         include_directories(${TOP_SRC_DIR}/3rdparty/boost)
 794         add_subdirectory(3rdparty/boost "${TOP_BINARY_DIR}/3rdparty/boost")
 795 endif()
 796
 797
 798
 799
 800 if(WIN32)
 801         if(LYX_CONSOLE)
 802                 set(LYX_QTMAIN_LIBRARY)
 803         else()
 804                 set(WIN32_CONSOLE WIN32)
 805         endif()
 806         if(MSVC)
 807                 # -DPSAPI_VERSION=1 is needed to run on vista (bug 10186)
 808                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX -DPSAPI_VERSION=1)
 809                 # disable checked iterators for msvc release builds to get maximum speed
 810                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 811         else()
 812                 # -DPSAPI_VERSION=1 is not needed for mingw, since the mingw psapi.h
 813                 # does not use it and always declares the vista compatible API.
 814                 # If this ever changes then -DPSAPI_VERSION might be needed here as well.
 815                 add_definitions(-DWINVER=0x0500)
 816         endif()
 817 endif()
 818
 819 # Compute qt-version from ${QTVERSION}
 820
 821 message(STATUS "")
 822 foreach(_v PACKAGE PACKAGE_VERSION
 823         PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 824         LYX_ABS_TOP_SRCDIR
 825         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 826         if(NOT DEFINED ${_v})
 827                 message(FATAL_ERROR "${_v} not defined")
 828         endif()
 829         string(SUBSTRING "${_v}                            " 0 28 _v1)
 830         message(STATUS "----- ${_v1}: ${${_v}}")
 831 endforeach(_v)
 832 message(STATUS "")
 833
 834
 835 if(LYX_PCH)
 836         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 837         # Not sure if it works for all non-msvc compilers
 838         include(PCHSupport_26)
 839         configure_file(${TOP_CMAKE_PATH}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
 840         configure_file(${TOP_CMAKE_PATH}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 841         add_definitions(-DLYX_ENABLE_PCH)
 842
 843         if(MSVC)
 844                 macro(lyx_add_msvc_pch name_)
 845                         set_source_files_properties(${${name_}_sources} PROPERTIES
 846                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 847                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
 848                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 849                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
 850                                 ${TOP_BINARY_DIR}/pcheaders.h)
 851                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 852                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 853                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 854                 endmacro(lyx_add_msvc_pch)
 855                 macro(lyx_add_gcc_pch name_)
 856                 endmacro()
 857         else()
 858                 macro(lyx_add_msvc_pch name_)
 859                 endmacro()
 860                 macro(lyx_add_gcc_pch name_)
 861                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT)
 862                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
 863                 endmacro()
 864         endif()
 865 else()
 866         macro(lyx_add_msvc_pch)
 867         endmacro(lyx_add_msvc_pch)
 868         macro(lyx_add_gcc_pch name_)
 869         endmacro()
 870 endif()
 871
 872
 873 if(MSVC)
 874
 875         if(LYX_VLD)
 876                 set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/development/Win32/vld)
 877                 add_subdirectory(${vld_path}/cmake)
 878                 include(${vld_path}/cmake/vld.cmake) # forced include
 879                 set(vld_dll vld)
 880         endif()
 881
 882         if(LYX_WALL)
 883                 # Use the highest warning level
 884                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 885
 886                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 887                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 888                 else()
 889                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 890                 endif()
 891
 892                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 893                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 894                 else()
 895                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 896                 endif()
 897
 898                 # add here warnings which should produce an error /weXXXX
 899                 set(MSVC_W_ERROR   "/we4101 /we4189")
 900                 # add here warnings which should be disabled /wdXXXX
 901                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 902
 903                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 904                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 905                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 906
 907         else()
 908                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 909
 910                 # add here warnings which should produce an error /weXXXX
 911                 set(MSVC_W_ERROR   "/we4101 /we4189")
 912                 # add here warnings which should be disabled /wdXXXX
 913                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 914
 915                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 916                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 917                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 918
 919         endif()
 920
 921         if (NOT Qt5Core_FOUND)
 922                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 923                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 924                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 925         endif()
 926
 927         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 928         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 929         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 930         message(STATUS "")
 931 endif()
 932
 933
 934 if(LYX_DEBUG_GLIBC)
 935         set(_GLIBCXX_DEBUG ON)
 936 endif()
 937
 938 if(LYX_DEBUG_GLIBC_PEDANTIC)
 939         set(_GLIBCXX_DEBUG_PEDANTIC ON)
 940 endif()
 941
 942 # Xcode compiler
 943 if (CMAKE_GENERATOR MATCHES Xcode)
 944         if (XCODE_VERSION VERSION_LESS "5.0")
 945                 # Automatically select the Xcode compiler if not set
 946                 if (NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 947                         # XCode >= 3.1 has gcc 4.2 (up to actual Xcode)
 948                         if (XCODE_VERSION VERSION_GREATER "3.1")
 949                                 SET(CMAKE_XCODE_ATTRIBUTE_GCC_VERSION "com.apple.compilers.llvmgcc42")
 950                         ENDIF(XCODE_VERSION VERSION_GREATER "3.1")
 951                 ENDIF(NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 952                 # Print the selected compiler version
 953         MESSAGE(STATUS "---- Using XCode compiler CMAKE_XCODE_ATTRIBUTE_GCC_VERSION=${CMAKE_XCODE_ATTRIBUTE_GCC_VERSION}")
 954         ENDIF(XCODE_VERSION VERSION_LESS "5.0")
 955 ENDIF(CMAKE_GENERATOR MATCHES Xcode)
 956
 957 if (WIN32 AND Qt5Core_FOUND)
 958         set(Z_PREFIX 1)
 959 endif()
 960
 961 # compiler tests, config.h generation LYX_CONFIGURE_CHECKS
 962 include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
 963 configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
 964
 965 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
 966
 967 if(QTVERSION MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+).*")
 968         MATH(EXPR QT4_VERSION "(${CMAKE_MATCH_1}<<16)|(${CMAKE_MATCH_2}<<8)|${CMAKE_MATCH_3}")
 969 endif()
 970
 971 if (NOT HAVE_REGEX)
 972         set(LYX_USE_STD_REGEX 0)
 973 endif()
 974
 975
 976 set (cmd ${CMAKE_CTEST_COMMAND})
 977 if (MSVC)
 978         set (cmd ${cmd} -C ${CMAKE_CFG_INTDIR})
 979 else ()
 980         set (cmd ${cmd} -C ${CMAKE_BUILD_TYPE})
 981 endif ()
 982 add_custom_target (lyx_run_tests COMMAND ${cmd})
 983 set_target_properties(lyx_run_tests PROPERTIES FOLDER "tests")
 984
 985 if(LYX_ASAN)
 986     set(LYX_CXX_FLAGS "-fsanitize=address -fno-omit-frame-pointer -g")
 987     message(STATUS)
 988     message(STATUS "Address sanitizer enabled. Usage:")
 989     message(STATUS "    wget https://llvm.org/svn/llvm-project/compiler-rt/trunk/lib/asan/scripts/asan_symbolize.py")
 990     message(STATUS "    chmod  +x ./asan_symbolize.py")
 991     message(STATUS "    ./bin/lyx2.2 2>&1 | ./asan_symbolize.py  | c++filt ")
 992     message(STATUS)
 993 endif()
 994
 995 if(LYX_INSTALL)
 996         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 997                 message(STATUS "Python required to create doc!")
 998         else()
 999                 if(UNIX)
1000                         add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
1001                 endif()
1002                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
1003         endif()
1004         include(../Install)
1005 endif()
1006
1007 add_subdirectory(src "${TOP_BINARY_DIR}/src")
1008 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
1009 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
1010 add_subdirectory(lib/examples "${TOP_BINARY_DIR}/lib/examples")
1011 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
1012 add_subdirectory(development/autotests "${TOP_BINARY_DIR}/autotests")
1013 if(LYX_ENABLE_URLTESTS)
1014         add_subdirectory(development/checkurls "${TOP_BINARY_DIR}/checkurls")
1015 endif()
1016
1017 message(STATUS)
1018 message(STATUS "Build params, switch LYX_* options by -DLYX_*=ON or OFF, LYX_* combos by -DLYX_*=value:")
1019 message(STATUS)
1020
1021 LYX_OPTION_LIST_ALL(used)
1022
1023
1024 if(LYX_NLS)
1025         message(STATUS)
1026         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
1027         message(STATUS)
1028         message(STATUS "  * iconv")
1029         message(STATUS "     - include: ${ICONV_INCLUDE_DIR}")
1030         message(STATUS "     - library: ${ICONV_LIBRARY}")
1031         message(STATUS "  * zlib")
1032         message(STATUS "     - include: ${ZLIB_INCLUDE_DIR}")
1033         message(STATUS "     - library: ${ZLIB_LIBRARY}")
1034         message(STATUS)
1035 endif()
1036
1037 # Apple has builtin native spell checker,
1038 # no need to warn for missing Aspell, Hunspell or Enchant
1039 if(NOT Spelling_FOUND AND NOT APPLE)
1040   if(LYX_REQUIRE_SPELLCHECK)
1041     set(_mode "FATAL_ERROR")
1042   else()
1043     set(_mode "STATUS")
1044   endif()
1045   message(${_mode} "No spellcheck libraries found. LyX will be unable use spellchecking")
1046 endif()
1047
1048 include("${TOP_CMAKE_PATH}/LyxPackaging.cmake")
1049
1050 if(ENABLE_DIST)
1051   # Use git to create the source package
1052   # git archive --format=tgz --output=/home/kornel/x.tar.gz master
1053   if(UNIX)
1054     set(DIST_FORMAT tgz)
1055   else()
1056     set(DIST_FORMAT zip)
1057   endif()
1058   set(DIST_NAME ${CMAKE_PROJECT_NAME}-${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}-${CMAKE_SYSTEM_NAME}.${DIST_FORMAT})
1059
1060   add_custom_command(
1061     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME}
1062     COMMAND  ${LYX_GITVERSION} archive --format=${DIST_FORMAT} --output=${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME} master
1063     WORKING_DIRECTORY ${TOP_SRC_DIR})
1064   add_custom_target(git-archive DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME})
1065 endif()
1066
1067 # Last directory to be included so that the fixup code (OS X)
1068 # can be run last
1069 add_subdirectory(development/cmake/post_install)
1070
1071 message(STATUS)