CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 2.6.4)
   8
   9 set(LYX_PROJECT LyX)
  10
  11 enable_testing()
  12
  13 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README ABSOLUTE)
  14 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  15
  16 set(LYX_CMAKE_DIR "development/cmake")
  17 set(TOP_CMAKE_PATH "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}")
  18 set(TOP_MODULE_PATH "${TOP_CMAKE_PATH}/modules")
  19 set(TOP_SCRIPT_PATH "${TOP_CMAKE_PATH}/scripts")
  20
  21 set(CMAKE_MODULE_PATH "${TOP_MODULE_PATH}")
  22
  23 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  24
  25 message(STATUS)
  26 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  27         message(STATUS "Building in-source")
  28         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  29 else()
  30         message(STATUS "Building out-of-source")
  31         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  32 endif()
  33
  34 # This directory should be used if some test uses lyx-executable
  35 set(LYX_TESTS_USERDIR "${TOP_BINARY_DIR}/Testing/.lyx")
  36 file(MAKE_DIRECTORY "${LYX_TESTS_USERDIR}")
  37
  38 if(COMMAND cmake_policy)
  39         cmake_policy(SET CMP0003 OLD)
  40         cmake_policy(SET CMP0005 OLD)
  41         # Installing MACOSX_BUNDLE targets requires a BUNDLE DESTINATION
  42         cmake_policy(SET CMP0006 NEW)
  43 endif()
  44
  45 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  46
  47 # Supress regeneration
  48 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  49
  50 if(LYX_XMINGW)
  51     set(CMAKE_SYSTEM_NAME Windows)
  52     set(TOOLNAME ${LYX_XMINGW})
  53     set(TOOLCHAIN "${TOOLNAME}-")
  54     set(CMAKE_C_COMPILER   "${TOOLCHAIN}gcc"     CACHE PATH "Mingw C compiler" FORCE)
  55     set(CMAKE_CXX_COMPILER "${TOOLCHAIN}g++"     CACHE PATH "Mingw C++ compiler" FORCE)
  56     set(CMAKE_RC_COMPILER  "${TOOLCHAIN}windres" CACHE PATH "Mingw rc compiler" FORCE)
  57
  58     set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM BOTH)
  59     set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY)
  60     set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY)
  61 endif()
  62
  63 if(NOT help AND NOT HELP)
  64         # 'project' triggers the searching for a compiler
  65         project(${LYX_PROJECT})
  66 endif()
  67
  68 if(UNIX)
  69         set(ARCH_TRIPLET )
  70         FIND_PROGRAM(DPKG_ARCHITECTURE_EXECUTABLE dpkg-architecture)
  71         if(DPKG_ARCHITECTURE_EXECUTABLE)
  72                 EXECUTE_PROCESS(COMMAND ${DPKG_ARCHITECTURE_EXECUTABLE} -qDEB_HOST_MULTIARCH
  73                                 OUTPUT_VARIABLE ARCH_TRIPLET
  74                                 ERROR_VARIABLE ERROR_ARCH_TRIPLET
  75                                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  76         endif()
  77 endif()
  78 if(ARCH_TRIPLET)
  79         set(SYSTEM_LIB_DIRS /usr/lib /usr/lib/${ARCH_TRIPLET} /usr/local/lib)
  80 else()
  81         set(SYSTEM_LIB_DIRS /usr/lib /usr/local/lib)
  82 endif()
  83
  84 include(LyXMacros)
  85
  86 # Usage LYX_OPTION
  87 # 1. parameter: option name without prefix 'LYX_'
  88 # 2. parameter: description
  89 # 3. parameter: default value, ON or OFF
  90 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
  91
  92 # Usage LYX_COMBO
  93 # 1. parameter: name without prefix 'LYX_'
  94 # 2. parameter: description
  95 # 3. parameter: default value
  96 # 4-n parameter: possible other string values
  97
  98 LYX_OPTION_INIT()
  99
 100 # Options for all compilers/systems
 101 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
 102 LYX_OPTION(LOCALVERSIONING  "Add version info to created package name (only used if LYX_CPACK option set)" OFF ALL)
 103 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
 104 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
 105 LYX_OPTION(REQUIRE_SPELLCHECK "Abort if no spellchecker available" OFF ALL)
 106 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
 107 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
 108 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
 109 LYX_OPTION(DEVEL_VERSION    "Build developer version" OFF ALL)
 110 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" OFF ALL)
 111 LYX_OPTION(DEBUG            "Enforce debug build"  OFF ALL)
 112 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
 113 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
 114 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
 115 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
 116 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
 117 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
 118 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
 119 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
 120 LYX_OPTION(ENABLE_URLTESTS  "Enable for URL tests" OFF ALL)
 121 LYX_OPTION(ENABLE_EXPORT_TESTS "Enable for export tests" OFF ALL)
 122 LYX_OPTION(ASAN             "Use address sanitizer" OFF ALL)
 123
 124 # GCC specific
 125 LYX_OPTION(PROFILE              "Build profile version" OFF GCC)
 126 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" OFF GCC)
 127 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
 128 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
 129 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++ pedantic debug mode" OFF GCC)
 130 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" OFF GCC)
 131 LYX_OPTION(CONCEPT_CHECKS       "Enable concept-checks" OFF GCC)
 132 LYX_OPTION(PROFILE              "Build with options for gprof" OFF GCC)
 133 LYX_OPTION(ENABLE_CXX11         "Build with options for c++11-mode" OFF GCC)
 134
 135 # MSVC specific
 136 LYX_OPTION(CONSOLE               "Show console on Windows, enforce with =FORCE" ON MSVC)
 137 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
 138 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
 139 LYX_OPTION(CONFIGURE_CHECKS      "Also run configure checks for MSVC" OFF MSVC)
 140 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
 141
 142 # APPLE specific
 143 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
 144 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
 145 if(LYX_XMINGW)
 146   LYX_COMBO(USE_QT               "Use Qt version as frontend for MINGW" QT4)
 147 else()
 148   LYX_COMBO(USE_QT               "Use Qt version as frontend" QT4 QT5)
 149 endif()
 150
 151
 152 if(help OR HELP)
 153         message(STATUS)
 154         message(STATUS "Available options: (dis/enable with -DLYX_*=OFF/ON)")
 155         message(STATUS)
 156         LYX_OPTION_LIST_ALL(help)
 157         message(STATUS)
 158         RETURN()
 159 endif()
 160
 161 # Check option dependencies
 162
 163 if(LYX_DMG)
 164         set(LYX_BUNDLE ON)
 165         set(LYX_CPACK ON)
 166 endif()
 167
 168 if(LYX_CPACK)
 169         set(LYX_INSTALL ON)
 170 endif()
 171
 172 if(LYX_INSTALL)
 173         set(LYX_NLS ON)
 174         if(WIN32 AND NOT MINGW)
 175                 set(LYX_HUNSPELL ON)
 176         endif()
 177         if(LYX_CONSOLE MATCHES "FORCE")
 178                 set(LYX_CONSOLE ON)
 179         else()
 180                 set(LYX_CONSOLE OFF)
 181         endif()
 182         set(LYX_PACKAGE_SUFFIX ON)
 183         if(NOT LYX_DEBUG)
 184                 set(LYX_RELEASE ON)
 185         endif()
 186         set(LYX_PROFILE OFF)
 187 endif()
 188
 189
 190 if(LYX_MERGE_FILES)
 191         set(LYX_PCH OFF)
 192 else()
 193         set(LYX_MERGE_REBUILD OFF)
 194 endif()
 195
 196
 197 if(LYX_DEPENDENCIES_DOWNLOAD)
 198         message(STATUS)
 199         set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 200         message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 201         set(deps_files lyx20-deps-msvc2010-x86.zip)
 202         set(deps_server http://downloads.sourceforge.net/project/lyx/Win_installers/Dependencies)
 203         foreach(it ${deps_files})
 204                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 205                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 206                 if(NOT already_downloaded)
 207                         message(STATUS "Downloading ${it} ...")
 208                         file(DOWNLOAD ${deps_server}/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS STATUS status LOG log)
 209                         list(GET status 0 status_code)
 210                         list(GET status 1 status_string)
 211                         if(NOT status_code EQUAL 0)
 212                                 file(REMOVE ${LYX_DEPENDENCIES_DIR}/${it})
 213                                 message(FATAL_ERROR "error: downloading '${it}' failed. status_code: ${status_code}, status_string: ${status_string}. \nLog: ${log} ")
 214                         endif()
 215                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 216                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 217                 endif()
 218         endforeach()
 219         set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/deps20)
 220     if(MSVC12)
 221         # handle error in msvc12 when linking against msvc10 libs
 222         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /vd2")
 223     endif()
 224 endif()
 225
 226
 227
 228 message(STATUS)
 229
 230 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 231 if(WIN32)
 232         set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 233 else()
 234         set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 235 endif()
 236
 237
 238 set(LYX_GCC11_MODE)
 239 if(UNIX OR MINGW)
 240         execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION)
 241         message(STATUS "Using GCC version ${GCC_VERSION}")
 242         if(NOT GCC_VERSION VERSION_LESS 4.4)
 243                 set(LYX_USE_TR1 1)
 244                 # GCC <= 4.5 does not support regex: there are linker errors
 245                 # http://gcc.gnu.org/onlinedocs/libstdc++/manual/status.html#status.iso.tr1
 246                 set(LYX_USE_TR1_REGEX 0)
 247         endif()
 248         if (LYX_ENABLE_CXX11)
 249                 find_package(CXX11Compiler)
 250                 if(NOT CXX11COMPILER_FOUND)
 251                         message(FATAL_ERROR "A C++11 compatible compiler is required.")
 252                 endif()
 253                 set(LYX_GCC11_MODE "${CXX11_FLAG}")
 254         endif()
 255 else()
 256         if(MSVC10)
 257                 set(LYX_USE_TR1 1)
 258                 #set(LYX_USE_TR1_REGEX 1) #TODO should we use it in ECMAScript mode?
 259         endif()
 260 endif()
 261
 262
 263 set(VERSION_INFO "CMake Build")
 264
 265 # Try to get some informations from configure.ac
 266
 267 include(LyXPaths)
 268 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 269
 270 if(WIN32)
 271         set(USE_WINDOWS_PACKAGING ON)
 272 elseif(APPLE)
 273         set(USE_MACOSX_PACKAGING ON)
 274 else()
 275         set(USE_POSIX_PACKAGING ON)
 276 endif()
 277
 278 macro(setstripped _varname)
 279         if(${ARGC} GREATER 1)
 280                 string(STRIP "${ARGV1}" _v)
 281                 if(USE_POSIX_PACKAGING)
 282                         string(TOLOWER ${_v} ${_varname})
 283                 else()
 284                         set(${_varname} ${_v})
 285                 endif()
 286         else()
 287                 set(${_varname})
 288         endif()
 289 endmacro(setstripped)
 290
 291 foreach(_c_l ${_config_lines} )
 292         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 293                 setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 294                 setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 295                 setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 296                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\)\(\\.\([0-9]+\)\)?.*$")
 297                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 298                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 299                         set(LYX_PATCH_VERSION ${CMAKE_MATCH_4})
 300                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 301                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 302                         set(LYX_INSTALL_SUFFIX "${CMAKE_MATCH_1}.${CMAKE_MATCH_2}")
 303                 endif()
 304         endif()
 305         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 306                 set(LYX_DATE "${CMAKE_MATCH_1}")
 307         endif()
 308 endforeach(_c_l)
 309
 310 if (LYX_LOCALVERSIONING)
 311         # Find the revision number and for later use
 312         FIND_PROGRAM(LYX_GITVERSION git)
 313         #message(STATUS "gitversion = ${LYX_GITVERSION}")
 314         if(LYX_GITVERSION)
 315                 EXECUTE_PROCESS(COMMAND ${LYX_GITVERSION} describe --match 2.0.0 HEAD
 316                 WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE LYX_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 317                 if (LYX_PACKAGE_RELEASE MATCHES "^2\\.0\\.0\\-\([0-9]+\)\\-.*$")
 318                   # We will add offset of 40000 to get appropriate value to
 319                   # previous svn.
 320                   # We use this value than also to set the package-patch-value
 321                   MATH(EXPR tmp_REVISION_VERSION "(${CMAKE_MATCH_1}+40000)")
 322                   set(LYX_REVISION_VERSION "${LYX_PATCH_VERSION}-${tmp_REVISION_VERSION}git")
 323                   set(ENABLE_DIST ON)
 324                 endif()
 325         else()
 326                 set(LYX_REVISION_VERSION git) #TODO use date
 327         endif()
 328 else()
 329         set(LYX_REVISION_VERSION ${LYX_PATCH_VERSION})
 330 endif()
 331
 332 # Set the programs (lyx, tex2lyx, etc.) suffix
 333 # When building an OS X bundle, we will append
 334 # the suffix only to the bundle, not to the programs
 335 set(PROGRAM_SUFFIX "")
 336 if(LYX_PROGRAM_SUFFIX AND NOT (APPLE AND LYX_BUNDLE))
 337         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 338 endif()
 339 set(_lyx "${PACKAGE_BASE}${PROGRAM_SUFFIX}")
 340 set(_tex2lyx tex2lyx${PROGRAM_SUFFIX})
 341
 342 add_custom_target(lyx_version ALL
 343   COMMAND ${CMAKE_COMMAND} -DTOP_SRC_DIR=${TOP_SRC_DIR} -DTOP_CMAKE_PATH=${TOP_CMAKE_PATH} -DTOP_BINARY_DIR=${TOP_BINARY_DIR} -DLYX_DATE=${LYX_DATE} -P ${TOP_SCRIPT_PATH}/LyXGetVersion.cmake
 344   )
 345 set_target_properties(lyx_version PROPERTIES FOLDER "applications")
 346
 347 # Default paths for installed utilities (tex2lyx, lyxclient, etc.)
 348 set(LYX_UTILITIES_INSTALL_PATH bin)
 349
 350 if(LYX_BUNDLE)
 351         set(LYX_CPACK ON)
 352
 353         message(STATUS)
 354         message(STATUS "Bundle creation is enabled (experimental):")
 355         message(STATUS "    make")
 356         message(STATUS "    make install/strip")
 357         message(STATUS "    make package")
 358         if(APPLE)
 359                 set(MACOSX_BUNDLE TRUE)
 360                 # This sets the bundle + executable names
 361                 set(_lyx "${PACKAGE_BASE}${LYX_INSTALL_SUFFIX}")
 362                 # This sets the Info.plist executable name
 363                 set(osx_bundle_program_name ${_lyx})
 364                 # Bundle name
 365                 set(LYX_BUNDLE_NAME ${_lyx})
 366
 367                 # This will contain the list of files that need to be included
 368                 # in the bundle and their location within the bundle
 369                 set(OSX_BUNDLE_FILES "${TOP_SRC_DIR}/development/MacOSX/LyX.sdef;${TOP_SRC_DIR}/development/MacOSX/LyXapp.icns;${CMAKE_BINARY_DIR}/lyxrc.dist")
 370                 set(OSX_BUNDLE_DIRS "Resources;Resources;Resources")
 371
 372                 # Process Info.plist and lyxrc.dist
 373                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/Info.plist.in" "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 374                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/lyxrc.dist.in" "${CMAKE_CURRENT_BINARY_DIR}/lyxrc.dist")
 375
 376                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 377                 set(LYX_DATA_SUBDIR ${LYX_BUNDLE_NAME}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 378
 379                 # Variables used by CPack
 380                 set(CPACK_BUNDLE_NAME ${LYX_BUNDLE_NAME})
 381                 set(CPACK_BUNDLE_PLIST "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 382                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${LYX_BUNDLE_NAME}.app)
 383
 384                 # Set the install paths
 385                 set(LYX_UTILITIES_INSTALL_PATH ${LYX_BUNDLE_NAME}.app/Contents/MacOS)
 386                 if(NOT LYX_INSTALL_PREFIX)
 387                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 388                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 389                 endif()
 390                 # Change the owner so that the install can work
 391                 install(CODE "set(BU_CHMOD_BUNDLE_ITEMS 1)" COMPONENT Runtime)
 392         elseif(UNIX)
 393                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 394                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 395                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 396         elseif(WIN32)
 397                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 398         endif()
 399 endif()
 400
 401 if(LYX_INSTALL_PREFIX)
 402         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 403         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 404 endif()
 405 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 406
 407 string(REGEX REPLACE "/lyx${LYX_INSTALL_SUFFIX}$" "/share" SYSTEM_DATADIR ${CMAKE_INSTALL_PREFIX})
 408
 409 if(LYX_PACKAGE_SUFFIX)
 410         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 411 else()
 412         set(PACKAGE ${PACKAGE_BASE})
 413 endif()
 414
 415 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 416         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 417         if (UNIX)
 418                 # don't use the default "/usr/local"
 419                 # but respect the user-choice on the command-line
 420                 if(LYX_INSTALL_SUFFIX)
 421                         set(CMAKE_INSTALL_PREFIX "/usr/local/lyx${LYX_INSTALL_SUFFIX}" CACHE PATH "LyX default install prefix" FORCE)
 422                 else()
 423                         set(CMAKE_INSTALL_PREFIX "/usr/local/${LYX_PROJECT}" CACHE PATH "LyX default install prefix" FORCE)
 424                 endif()
 425         endif()
 426         if(WIN32)
 427                 set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 428         endif()
 429 endif()
 430 if(IS_ABSOLUTE)
 431         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 432 else()
 433         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 434 endif()
 435
 436
 437
 438 if(NOT LYX_DATA_SUBDIR)
 439         if (WIN32)
 440                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 441         else()
 442                 set(LYX_DATA_SUBDIR "" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 443         endif()
 444 endif()
 445
 446 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 447 set(LYX_LOCALEDIR "locale")
 448 set(LYX_ABS_INSTALLED_LOCALEDIR "${LYX_ABS_INSTALLED_DATADIR}/${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}")
 449 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 450
 451 if(LYX_BUNDLE AND APPLE)
 452         set(LYX_MAN_DIR "${LYX_DATA_SUBDIR}" CACHE STRING "Install location for man pages.")
 453 else()
 454         set(LYX_MAN_DIR "/usr/local/man/man1" CACHE STRING "Install location for man pages.")
 455 endif()
 456 mark_as_advanced(LYX_MAN_DIR)
 457
 458 if(LYX_INSTALL AND WIN32)
 459         message(STATUS "Configuring NSIS files")
 460         configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 461         configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 462         configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 463         message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 464 endif()
 465
 466 if(NOT GROUP_CODE)
 467         #set(GROUP_CODE "The Golden Code")
 468         set(GROUP_CODE flat)
 469 endif()
 470
 471 # lyx's source files
 472 set(LYX_CPP_FILES *.cpp)
 473 set(LYX_HPP_FILES *.h)
 474 set(LYX_MOC_FILES moc_*.cpp)
 475
 476 include(ProjectSourceGroup)
 477
 478
 479 if(LYX_PROFILE AND NOT MSVC)
 480         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 481         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg")
 482         set(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS}  -pg")
 483 else()
 484         set(LYX_PROFILE OFF)
 485 endif()
 486
 487
 488 if(LYX_NO_OPTIMIZE)
 489         set(CMAKE_BUILD_TYPE None)
 490         set(LYX_DEBUG OFF)
 491         set(LYX_RELEASE OFF)
 492         set(LYX_PROFILE OFF)
 493 elseif(LYX_RELEASE)
 494         set(CMAKE_BUILD_TYPE Release)
 495         set(LYX_DEBUG OFF)
 496         set(LYX_PROFILE OFF)
 497 elseif(LYX_PROFILE)
 498         set(CMAKE_BUILD_TYPE Profile)
 499         set(LYX_DEBUG OFF)
 500 else()
 501         set(CMAKE_BUILD_TYPE Debug)
 502         set(LYX_DEBUG ON)
 503 endif()
 504
 505
 506 # When shared libs are supported enable this option
 507 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 508 if(LYX_SHARED_LIBRARIES)
 509         set(library_type SHARED)
 510 else()
 511         set(library_type STATIC)
 512 endif()
 513
 514 if(NOT MSVC)
 515         if(NOT LYX_QUIET)
 516                 set(CMAKE_VERBOSE_MAKEFILE ON)
 517         endif()
 518     set(LYX_CXX_FLAGS "-Wall -Wunused-parameter ${LYX_GCC11_MODE}")
 519         if(LYX_STDLIB_DEBUG)
 520                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 521         endif()
 522         if(LYX_CONCEPT_CHECKS)
 523                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCPP_CONCEPT_CHECKS")
 524         endif()
 525         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 526         set(CMAKE_CXX_FLAGS_DEBUG "${LYX_CXX_FLAGS} -fno-strict-aliasing -O0 -g3 -D_DEBUG" CACHE TYPE STRING FORCE)
 527         if(MINGW)
 528                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 529         else()
 530                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 531         endif()
 532 endif()
 533
 534 set(LYX_CXX_FLAGS_EXTRA "" CACHE STRING "Desired semicolon separated list of extra cxx compile flags, like '-Werror'")
 535 mark_as_advanced(LYX_CXX_FLAGS_EXTRA)
 536 if(LYX_CXX_FLAGS_EXTRA)
 537         foreach(_flag ${LYX_CXX_FLAGS_EXTRA})
 538                 add_definitions(${_flag})
 539         endforeach()
 540 endif()
 541
 542 if(LYX_XMINGW)
 543     set(QT_MINGW_DIR ${LYX_QT4} CACHE PATH "Qt for Mingw" FORCE)
 544     list(APPEND CMAKE_FIND_ROOT_PATH ${QT_MINGW_DIR} ${GNUWIN32_DIR})
 545 endif()
 546 if(LYX_USE_QT MATCHES "QT5")
 547   find_package(Qt5Core REQUIRED)
 548   if (Qt5Core_FOUND)
 549         find_package(Qt5Widgets REQUIRED)
 550         find_package(Qt5X11Extras)
 551         set(QTVERSION ${Qt5Core_VERSION})
 552         macro (qt_use_modules)
 553                 qt5_use_modules(${ARGN})
 554         endmacro()
 555         macro (qt_add_resources)
 556                 qt5_add_resources(${ARGN})
 557         endmacro()
 558         macro (qt_wrap_uifiles)
 559                 qt5_wrap_ui(${ARGN})
 560         endmacro()
 561   endif()
 562 elseif(LYX_USE_QT MATCHES "QT4")
 563         find_package(Qt4 "4.5.0" REQUIRED)
 564         macro (qt_use_modules)
 565         endmacro()
 566         macro (qt_add_resources)
 567                 qt4_add_resources(${ARGN})
 568         endmacro()
 569         macro (qt_wrap_uifiles)
 570                 qt4_wrap_ui(${ARGN})
 571         endmacro()
 572 else()
 573   message(FATAL_ERROR "Unhandled value for LYX_USE_QT (${LYX_USE_QT})")
 574 endif()
 575
 576 find_package(Magic)
 577 if(Magic_FOUND)
 578         set(HAVE_MAGIC_H 1)
 579 endif()
 580
 581 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 582
 583 set(Spelling_FOUND OFF)
 584 set(Include_used_spellchecker)   # String will be inserted into config.h
 585
 586 foreach(_spell "ASPELL" "Enchant" "Hunspell")
 587   string(TOUPPER ${_spell} _upspell)
 588   find_package(${_spell})
 589   if (${_upspell}_FOUND)
 590     include_directories(${${_upspell}_INCLUDE_DIR})
 591     set(Spelling_FOUND ON)
 592     message(STATUS "Building with USE_${_upspell}")
 593     set(Include_used_spellchecker "${Include_used_spellchecker}#define USE_${_upspell} 1\n")
 594   else()
 595     if(LYX_${_upspell})
 596       message(FATAL_ERROR "Required ${_spell} devel package not found")
 597     else()
 598       message(STATUS "${_upspell} not found, building without ${_spell} support")
 599     endif()
 600   endif()
 601 endforeach()
 602
 603 if(LYX_NLS)
 604         FIND_PROGRAM(LYX_PYTHON_EXECUTABLE python2 python HINTS ${GNUWIN32_DIR}/python)
 605         find_package(LyXGettext)
 606         if(LYX_PYTHON_EXECUTABLE AND GETTEXT_FOUND)
 607                 add_subdirectory(po "${TOP_BINARY_DIR}/po")
 608         else()
 609                 # Install only supplied .gmo-files
 610                 file(GLOB _gmofiles RELATIVE "${TOP_SRC_DIR}/po" "${TOP_SRC_DIR}/po/*.gmo")
 611                 message(STATUS "Installing provided .gmo-files only")
 612                 foreach( _gmo ${_gmofiles})
 613                         string(REGEX REPLACE "\\.gmo$" "" _lang ${_gmo})
 614                         install(FILES "${TOP_SRC_DIR}/po/${_gmo}" DESTINATION ${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}/${_lang}/LC_MESSAGES RENAME ${PACKAGE}.mo)
 615                 endforeach()
 616         endif()
 617 endif()
 618
 619
 620 find_package(ICONV REQUIRED)
 621 find_package(ZLIB REQUIRED)
 622
 623 if(LYX_EXTERNAL_BOOST)
 624         message(STATUS "Searching for boost")
 625         find_package(Boost COMPONENTS signals regex) #TODO could REQUIRED be used
 626         if(Boost_FOUND)
 627                 message(STATUS "Boost found")
 628                 message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 629                 set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 630         else()
 631                 message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 632         endif()
 633 else()
 634         if(LYX_USE_TR1_REGEX)
 635                 set(Lyx_Boost_Libraries boost_signals)
 636         else()
 637                 set(Lyx_Boost_Libraries boost_signals boost_regex)
 638         endif()
 639         add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 640         add_definitions(-DBOOST_SIGNALS_NO_DEPRECATION_WARNING=1)
 641         include_directories(${TOP_SRC_DIR}/boost)
 642         add_subdirectory(boost "${TOP_BINARY_DIR}/boost")
 643 endif()
 644
 645
 646
 647
 648 if(WIN32)
 649         if(NOT LYX_CONSOLE)
 650                 set(WIN32_CONSOLE WIN32)
 651                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARY})
 652         endif()
 653         if(MSVC)
 654                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 655                 # disable checked iterators for msvc release builds to get maximum speed
 656                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 657         else()
 658                 add_definitions(-DWINVER=0x0500)
 659         endif()
 660 endif()
 661
 662 # Compute qt4-version from ${QTVERSION}
 663
 664 message(STATUS "")
 665 foreach(_v PACKAGE PACKAGE_VERSION
 666         PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 667         LYX_ABS_TOP_SRCDIR
 668         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 669         if(NOT DEFINED ${_v})
 670                 message(FATAL_ERROR "${_v} not defined")
 671         endif()
 672         string(SUBSTRING "${_v}                            " 0 28 _v1)
 673         message(STATUS "----- ${_v1}: ${${_v}}")
 674 endforeach(_v)
 675 message(STATUS "")
 676
 677
 678 if(LYX_PCH)
 679         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 680         # Not sure if it works for all non-msvc compilers
 681         include(PCHSupport_26)
 682         configure_file(${TOP_CMAKE_PATH}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
 683         configure_file(${TOP_CMAKE_PATH}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 684         add_definitions(-DLYX_ENABLE_PCH)
 685
 686         if(MSVC)
 687                 macro(lyx_add_msvc_pch name_)
 688                         set_source_files_properties(${${name_}_sources} PROPERTIES
 689                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 690                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
 691                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 692                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
 693                                 ${TOP_BINARY_DIR}/pcheaders.h)
 694                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 695                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 696                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 697                 endmacro(lyx_add_msvc_pch)
 698                 macro(lyx_add_gcc_pch name_)
 699                 endmacro()
 700         else()
 701                 macro(lyx_add_msvc_pch name_)
 702                 endmacro()
 703                 macro(lyx_add_gcc_pch name_)
 704                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT)
 705                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
 706                 endmacro()
 707         endif()
 708 else()
 709         macro(lyx_add_msvc_pch)
 710         endmacro(lyx_add_msvc_pch)
 711         macro(lyx_add_gcc_pch name_)
 712         endmacro()
 713 endif()
 714
 715
 716 if(MSVC)
 717
 718         if(LYX_VLD)
 719                 set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/development/Win32/vld)
 720                 add_subdirectory(${vld_path}/cmake)
 721                 include(${vld_path}/cmake/vld.cmake) # forced include
 722                 set(vld_dll vld)
 723         endif()
 724
 725         if(LYX_WALL)
 726                 # Use the highest warning level
 727                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 728
 729                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 730                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 731                 else()
 732                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 733                 endif()
 734
 735                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 736                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 737                 else()
 738                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 739                 endif()
 740
 741                 # add here warnings which should produce an error /weXXXX
 742                 set(MSVC_W_ERROR   "/we4101 /we4189")
 743                 # add here warnings which should be disabled /wdXXXX
 744                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 745
 746                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 747                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 748                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 749
 750         else()
 751                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 752
 753                 # add here warnings which should produce an error /weXXXX
 754                 set(MSVC_W_ERROR   "/we4101 /we4189")
 755                 # add here warnings which should be disabled /wdXXXX
 756                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 757
 758                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 759                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 760                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 761
 762         endif()
 763
 764         if (NOT Qt5Core_FOUND)
 765                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 766                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 767                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 768         endif()
 769
 770         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 771         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 772         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 773         message(STATUS "")
 774 endif()
 775
 776
 777 if(LYX_DEBUG_GLIBC)
 778         set(_GLIBCXX_DEBUG ON)
 779 endif()
 780
 781 if(LYX_DEBUG_GLIBC_PEDANTIC)
 782         set(_GLIBCXX_DEBUG_PEDANTIC ON)
 783 endif()
 784
 785 # Xcode compiler
 786 if (CMAKE_GENERATOR MATCHES Xcode)
 787         if (XCODE_VERSION VERSION_LESS "5.0")
 788                 # Automatically select the Xcode compiler if not set
 789                 if (NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 790                         # XCode >= 3.1 has gcc 4.2 (up to actual Xcode)
 791                         if (XCODE_VERSION VERSION_GREATER "3.1")
 792                                 SET(CMAKE_XCODE_ATTRIBUTE_GCC_VERSION "com.apple.compilers.llvmgcc42")
 793                         ENDIF(XCODE_VERSION VERSION_GREATER "3.1")
 794                 ENDIF(NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 795                 # Print the selected compiler version
 796         MESSAGE(STATUS "---- Using XCode compiler CMAKE_XCODE_ATTRIBUTE_GCC_VERSION=${CMAKE_XCODE_ATTRIBUTE_GCC_VERSION}")
 797         ENDIF(XCODE_VERSION VERSION_LESS "5.0")
 798 ENDIF(CMAKE_GENERATOR MATCHES Xcode)
 799
 800 if (WIN32 AND Qt5Core_FOUND)
 801         set(Z_PREFIX 1)
 802 endif()
 803
 804 # compiler tests, config.h generation
 805 if(MSVC AND NOT LYX_CONFIGURE_CHECKS)
 806         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.msvc ${TOP_BINARY_DIR}/configCompiler.h)
 807 else()
 808         include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
 809         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
 810 endif()
 811
 812 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
 813
 814 if(QTVERSION MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+).*")
 815         MATH(EXPR QT4_VERSION "(${CMAKE_MATCH_1}<<16)|(${CMAKE_MATCH_2}<<8)|${CMAKE_MATCH_3}")
 816 endif()
 817
 818
 819 set (cmd ${CMAKE_CTEST_COMMAND})
 820 if (MSVC)
 821         set (cmd ${cmd} -C ${CMAKE_CFG_INTDIR})
 822 else ()
 823         set (cmd ${cmd} -C ${CMAKE_BUILD_TYPE})
 824 endif ()
 825 add_custom_target (lyx_run_tests COMMAND ${cmd})
 826 set_target_properties(lyx_run_tests PROPERTIES FOLDER "tests")
 827
 828 if(LYX_ASAN)
 829     set(LYX_CXX_FLAGS "-fsanitize=address -fno-omit-frame-pointer -g")
 830     message(STATUS)
 831     message(STATUS "Address sanitizer enabled. Usage:")
 832     message(STATUS "    wget https://llvm.org/svn/llvm-project/compiler-rt/trunk/lib/asan/scripts/asan_symbolize.py")
 833     message(STATUS "    chmod  +x ./asan_symbolize.py")
 834     message(STATUS "    ./bin/lyx2.2 2>&1 | ./asan_symbolize.py  | c++filt ")
 835     message(STATUS)
 836 endif()
 837
 838 if(LYX_INSTALL)
 839         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 840                 message(STATUS "Python required to create doc!")
 841         else()
 842                 if(UNIX)
 843                         add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
 844                 endif()
 845                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
 846         endif()
 847         include(../Install)
 848 endif()
 849
 850 add_subdirectory(src "${TOP_BINARY_DIR}/src")
 851 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
 852 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
 853 add_subdirectory(lib/examples "${TOP_BINARY_DIR}/lib/examples")
 854 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
 855 add_subdirectory(development/autotests "${TOP_BINARY_DIR}/autotests")
 856 if(LYX_ENABLE_URLTESTS)
 857         add_subdirectory(development/checkurls "${TOP_BINARY_DIR}/checkurls")
 858 endif()
 859
 860 message(STATUS)
 861 message(STATUS "Build params, switch LYX_* options by -DLYX_*=ON or OFF, LYX_* combos by -DLYX_*=value:")
 862 message(STATUS)
 863
 864 LYX_OPTION_LIST_ALL(used)
 865
 866
 867 if(LYX_NLS)
 868         message(STATUS)
 869         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
 870         message(STATUS)
 871         message(STATUS "  * iconv")
 872         message(STATUS "     - header : ${ICONV_HEADER}")
 873         message(STATUS "     - library: ${ICONV_LIBRARY}")
 874         message(STATUS "  * zlib")
 875         message(STATUS "     - header : ${ZLIB_HEADER}")
 876         message(STATUS "     - library: ${ZLIB_LIBRARY}")
 877         message(STATUS)
 878 endif()
 879
 880 # Apple has builtin native spell checker,
 881 # no need to warn for missing Aspell, Hunspell or Enchant
 882 if(NOT Spelling_FOUND AND NOT APPLE)
 883   if(LYX_REQUIRE_SPELLCHECK)
 884     set(_mode "FATAL_ERROR")
 885   else()
 886     set(_mode "STATUS")
 887   endif()
 888   message(${_mode} "No spellcheck libraries found. LyX will be unable use spellchecking")
 889 endif()
 890
 891 include("${TOP_CMAKE_PATH}/LyxPackaging.cmake")
 892
 893 if(ENABLE_DIST)
 894   # Use git to create the source package
 895   # git archive --format=tgz --output=/home/kornel/x.tar.gz master
 896   if(UNIX)
 897     set(DIST_FORMAT tgz)
 898   else()
 899     set(DIST_FORMAT zip)
 900   endif()
 901   set(DIST_NAME ${CMAKE_PROJECT_NAME}-${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}-${CMAKE_SYSTEM_NAME}.${DIST_FORMAT})
 902
 903   add_custom_command(
 904     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME}
 905     COMMAND  ${LYX_GITVERSION} archive --format=${DIST_FORMAT} --output=${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME} master
 906     WORKING_DIRECTORY ${TOP_SRC_DIR})
 907   add_custom_target(git-archive DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME})
 908 endif()
 909
 910 # Last directory to be included so that the fixup code (OS X)
 911 # can be run last
 912 add_subdirectory(development/cmake/post_install)
 913
 914 message(STATUS)