CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 2.6.4)
   8
   9 set(LYX_PROJECT LyX)
  10
  11 enable_testing()
  12
  13 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README REALPATH) # Resolve symlinks
  14 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  15 message(STATUS "TOP_SRC_DIR = ${TOP_SRC_DIR}")
  16
  17 set(LYX_CMAKE_DIR "development/cmake")
  18 set(TOP_CMAKE_PATH "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}")
  19 set(TOP_MODULE_PATH "${TOP_CMAKE_PATH}/modules")
  20 set(TOP_SCRIPT_PATH "${TOP_CMAKE_PATH}/scripts")
  21
  22 set(CMAKE_MODULE_PATH "${TOP_MODULE_PATH}")
  23
  24 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  25
  26 message(STATUS)
  27 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  28         message(STATUS "Building in-source")
  29         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  30 else()
  31         message(STATUS "Building out-of-source")
  32         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  33 endif()
  34
  35 # This directory should be used if some test uses lyx-executable
  36 set(LYX_TESTS_USERDIR "${TOP_BINARY_DIR}/Testing/.lyx")
  37 file(MAKE_DIRECTORY "${LYX_TESTS_USERDIR}")
  38
  39 if(COMMAND cmake_policy)
  40         cmake_policy(SET CMP0003 OLD)
  41         cmake_policy(SET CMP0005 OLD)
  42         # Installing MACOSX_BUNDLE targets requires a BUNDLE DESTINATION
  43         cmake_policy(SET CMP0006 NEW)
  44         if(POLICY CMP0020)
  45                 cmake_policy(SET CMP0020 OLD)
  46         endif()
  47         if(POLICY CMP0028)
  48                 cmake_policy(SET CMP0028 OLD)
  49         endif()
  50         if(POLICY CMP0043)
  51                 # COMPILE_DEFINITIONS are not used yet. Enable new behavior.
  52                 cmake_policy(SET CMP0043 NEW)
  53         endif()
  54 endif()
  55
  56 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  57
  58 # Supress regeneration
  59 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  60
  61 if(LYX_XMINGW)
  62     set(CMAKE_SYSTEM_NAME Windows)
  63     set(TOOLNAME ${LYX_XMINGW})
  64     set(TOOLCHAIN "${TOOLNAME}-")
  65     set(CMAKE_C_COMPILER   "${TOOLCHAIN}gcc"     CACHE PATH "Mingw C compiler" FORCE)
  66     set(CMAKE_CXX_COMPILER "${TOOLCHAIN}g++"     CACHE PATH "Mingw C++ compiler" FORCE)
  67     set(CMAKE_RC_COMPILER  "${TOOLCHAIN}windres" CACHE PATH "Mingw rc compiler" FORCE)
  68
  69     set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM BOTH)
  70     set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY)
  71     set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY)
  72 endif()
  73
  74 if(NOT help AND NOT HELP)
  75   # 'project' triggers the searching for a compiler
  76   project(${LYX_PROJECT})
  77   if (CMAKE_COMPILER_IS_GNUCXX)
  78     if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS "4.0")
  79       message(STATUS "Gnu CXX compiler version = ${CMAKE_CXX_COMPILER_VERSION}")
  80       message(STATUS "is too old, should be >= 4.0")
  81       message(FATAL_ERROR "Exiting")
  82     endif()
  83   endif()
  84 endif()
  85
  86 if(UNIX)
  87         set(ARCH_TRIPLET )
  88         FIND_PROGRAM(DPKG_ARCHITECTURE_EXECUTABLE dpkg-architecture)
  89         if(DPKG_ARCHITECTURE_EXECUTABLE)
  90                 EXECUTE_PROCESS(COMMAND ${DPKG_ARCHITECTURE_EXECUTABLE} -qDEB_HOST_MULTIARCH
  91                                 OUTPUT_VARIABLE ARCH_TRIPLET
  92                                 ERROR_VARIABLE ERROR_ARCH_TRIPLET
  93                                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  94         endif()
  95 endif()
  96 if(ARCH_TRIPLET)
  97         set(SYSTEM_LIB_DIRS /usr/lib /usr/lib/${ARCH_TRIPLET} /usr/local/lib)
  98 else()
  99         set(SYSTEM_LIB_DIRS /usr/lib /usr/local/lib)
 100 endif()
 101
 102 include(LyXMacros)
 103
 104 # Usage LYX_OPTION
 105 # 1. parameter: option name without prefix 'LYX_'
 106 # 2. parameter: description
 107 # 3. parameter: default value, ON or OFF
 108 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
 109
 110 # Usage LYX_COMBO
 111 # 1. parameter: name without prefix 'LYX_'
 112 # 2. parameter: description
 113 # 3. parameter: default value
 114 # 4-n parameter: possible other string values
 115
 116 LYX_OPTION_INIT()
 117
 118 # Options for all compilers/systems
 119 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
 120 LYX_OPTION(LOCALVERSIONING  "Add version info to created package name (only used if LYX_CPACK option set)" OFF ALL)
 121 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
 122 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
 123 LYX_OPTION(REQUIRE_SPELLCHECK "Abort if no spellchecker available" OFF ALL)
 124 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
 125 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
 126 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
 127 LYX_OPTION(DEVEL_VERSION    "Build developer version" OFF ALL)
 128 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" OFF ALL)
 129 LYX_OPTION(DEBUG            "Enforce debug build"  OFF ALL)
 130 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
 131 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
 132 LYX_STRING(SUFFIX_VALUE     "Use this string as suffix" "")
 133 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
 134 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
 135 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
 136 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
 137 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
 138 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
 139 LYX_OPTION(ENABLE_URLTESTS  "Enable for URL tests" OFF ALL)
 140 LYX_OPTION(ENABLE_EXPORT_TESTS "Enable for export tests" OFF ALL)
 141 LYX_OPTION(ASAN             "Use address sanitizer" OFF ALL)
 142 LYX_COMBO(USE_QT            "Use Qt version as frontend" QT4 QT5)
 143 LYX_OPTION(3RDPARTY_BUILD   "Build 3rdparty libs" OFF ALL)
 144 LYX_COMBO(ENABLE_CXX11          "Build with options for c++11-mode" AUTO ON OFF)
 145
 146 # GCC specific
 147 LYX_OPTION(PROFILE              "Build profile version" OFF GCC)
 148 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" OFF GCC)
 149 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
 150 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
 151 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++ pedantic debug mode" OFF GCC)
 152 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" OFF GCC)
 153 LYX_OPTION(PROFILE              "Build with options for gprof" OFF GCC)
 154
 155 # MSVC specific
 156 LYX_OPTION(CONSOLE               "Show console on Windows, enforce with =FORCE" ON MSVC)
 157 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
 158 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
 159 LYX_OPTION(CONFIGURE_CHECKS      "Also run configure checks for MSVC" OFF MSVC)
 160 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
 161
 162 # APPLE specific
 163 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
 164 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
 165
 166
 167 if(help OR HELP)
 168         message(STATUS)
 169         message(STATUS "Available options: (dis/enable with -DLYX_*=OFF/ON)")
 170         message(STATUS)
 171         LYX_OPTION_LIST_ALL(help)
 172         message(STATUS)
 173         RETURN()
 174 endif()
 175
 176 # Check option dependencies
 177
 178 if(LYX_DMG)
 179         set(LYX_BUNDLE ON)
 180         set(LYX_CPACK ON)
 181 endif()
 182
 183 if(LYX_CPACK)
 184         set(LYX_INSTALL ON)
 185 endif()
 186
 187 if(LYX_INSTALL)
 188         set(LYX_NLS ON)
 189         if(WIN32 AND NOT MINGW)
 190                 set(LYX_HUNSPELL ON)
 191         endif()
 192         if(LYX_CONSOLE MATCHES "FORCE")
 193                 set(LYX_CONSOLE ON)
 194         else()
 195                 set(LYX_CONSOLE OFF)
 196         endif()
 197         set(LYX_PACKAGE_SUFFIX ON)
 198         if(NOT LYX_DEBUG)
 199                 set(LYX_RELEASE ON)
 200         endif()
 201         set(LYX_PROFILE OFF)
 202 endif()
 203
 204
 205 if(LYX_MERGE_FILES)
 206         set(LYX_PCH OFF)
 207 else()
 208         set(LYX_MERGE_REBUILD OFF)
 209 endif()
 210
 211
 212 if(LYX_DEPENDENCIES_DOWNLOAD)
 213         message(STATUS)
 214     if(MSVC12)
 215         set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2013-deps)
 216         set(deps_files lyx-windows-deps-msvc2013.zip)
 217         set(deps_server http://ftp.lyx.de/LyX-Windows-Deps)
 218         set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2013)
 219     else()
 220         set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 221             set(deps_files lyx20-deps-msvc2010-x86.zip)
 222             set(deps_server http://downloads.sourceforge.net/project/lyx/Win_installers/Dependencies)
 223         set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/deps20)
 224     endif()
 225     message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 226         foreach(it ${deps_files})
 227                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 228                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 229                 if(NOT already_downloaded)
 230                         message(STATUS "Downloading ${it} ...")
 231                         file(DOWNLOAD ${deps_server}/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS STATUS status LOG log)
 232                         list(GET status 0 status_code)
 233                         list(GET status 1 status_string)
 234                         if(NOT status_code EQUAL 0)
 235                                 file(REMOVE ${LYX_DEPENDENCIES_DIR}/${it})
 236                                 message(FATAL_ERROR "error: downloading '${it}' failed. status_code: ${status_code}, status_string: ${status_string}. \nLog: ${log} ")
 237                         endif()
 238                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 239                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 240                 endif()
 241         endforeach()
 242 endif()
 243
 244
 245
 246 message(STATUS)
 247
 248 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 249 if(WIN32)
 250         set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 251 else()
 252         set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 253 endif()
 254
 255
 256 if(LYX_ENABLE_CXX11 MATCHES "AUTO")
 257   # Set to some meaningful default
 258   find_package(CXX11Compiler)
 259   if(NOT CXX11COMPILER_FOUND)
 260     set(LYX_ENABLE_CXX11 OFF CACHE TYPE STRING FORCE)
 261   else()
 262     if(CMAKE_CXX_COMPILER_ID MATCHES "GNU")
 263       execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION OUTPUT_STRIP_TRAILING_WHITESPACE)
 264         set(LYX_ENABLE_CXX11 ON CACHE TYPE STRING FORCE)
 265     else()
 266       # Not a gnu compiler
 267       if(CMAKE_CXX_COMPILER_ID MATCHES "^[cC]lang$")
 268         set(LYX_ENABLE_CXX11 ON CACHE TYPE STRING FORCE)
 269       else()
 270         set(LYX_ENABLE_CXX11 OFF CACHE TYPE STRING FORCE)
 271       endif()
 272     endif()
 273   endif()
 274 endif()
 275 set(LYX_GCC11_MODE)
 276 if(UNIX OR MINGW)
 277         execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION OUTPUT_STRIP_TRAILING_WHITESPACE)
 278         message(STATUS "Using GCC version ${GCC_VERSION}")
 279         if(GCC_VERSION VERSION_LESS 4.9)
 280                 if(GCC_VERSION VERSION_LESS 4.3)
 281                         message(FATAL_ERROR "gcc >= 4.3 is required.")
 282                 endif()
 283                 # <regex> in gcc is unusable in versions less than 4.9.0
 284                 # see https://gcc.gnu.org/bugzilla/show_bug.cgi?id=53631
 285                 set(LYX_USE_STD_REGEX 0)
 286         else()
 287                 if (LYX_ENABLE_CXX11)
 288                         set(LYX_USE_STD_REGEX 1)
 289                 endif()
 290         endif()
 291         if (LYX_ENABLE_CXX11)
 292                 find_package(CXX11Compiler)
 293                 if(NOT CXX11COMPILER_FOUND)
 294                         message(FATAL_ERROR "A C++11 compatible compiler is required.")
 295                 endif()
 296                 set(LYX_GCC11_MODE "${CXX11_FLAG}")
 297         endif()
 298 else()
 299         set(LYX_USE_STD_REGEX 0)
 300 #       if(MSVC10)
 301 #               set(LYX_USE_STD_REGEX 1) #TODO should we use it in ECMAScript mode?
 302 #       endif()
 303 endif()
 304
 305
 306 set(VERSION_INFO "CMake Build")
 307
 308 # Try to get some informations from configure.ac
 309
 310 include(LyXPaths)
 311 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 312
 313 if(WIN32)
 314         set(CMAKE_PREFIX_PATH Specify-path-to-Qt CACHE PATH "Used Qt version")
 315         if(MSVC)
 316                 set(LYX_3RDPARTY_BUILD ON CACHE BOOL "Build 3rdparty libraries" FORCE)
 317         endif()
 318         set(USE_WINDOWS_PACKAGING ON)
 319 elseif(APPLE)
 320         set(USE_MACOSX_PACKAGING ON)
 321 else()
 322         set(USE_POSIX_PACKAGING ON)
 323 endif()
 324
 325 macro(setstripped _varname)
 326         if(${ARGC} GREATER 1)
 327                 string(STRIP "${ARGV1}" _v)
 328                 if(USE_POSIX_PACKAGING)
 329                         string(TOLOWER ${_v} ${_varname})
 330                 else()
 331                         set(${_varname} ${_v})
 332                 endif()
 333         else()
 334                 set(${_varname})
 335         endif()
 336 endmacro(setstripped)
 337
 338 foreach(_c_l ${_config_lines} )
 339         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 340                 setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 341                 setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 342                 setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 343                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\)\(\\.\([0-9]+\)\)?.*$")
 344                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 345                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 346                         set(LYX_PATCH_VERSION ${CMAKE_MATCH_4})
 347                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 348                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 349                         if ("${LYX_SUFFIX_VALUE}" MATCHES "")
 350                           set(LYX_INSTALL_SUFFIX "${LYX_MAJOR_VERSION}.${LYX_MINOR_VERSION}")
 351                         else()
 352                           set(LYX_INSTALL_SUFFIX "${LYX_SUFFIX_VALUE}")
 353                         endif()
 354                 endif()
 355         endif()
 356         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 357                 set(LYX_DATE "${CMAKE_MATCH_1}")
 358         endif()
 359 endforeach(_c_l)
 360
 361 FIND_PROGRAM(LYX_GITVERSION git)
 362 #message(STATUS "gitversion = ${LYX_GITVERSION}")
 363 set(LYX_REVISION_VERSION ${LYX_PATCH_VERSION})
 364 if(LYX_GITVERSION)
 365   if (LYX_LOCALVERSIONING)
 366     # Find the revision number and for later use
 367     EXECUTE_PROCESS(COMMAND ${LYX_GITVERSION} describe --match 2.0.0 HEAD
 368       WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE LYX_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 369     if (LYX_PACKAGE_RELEASE MATCHES "^2\\.0\\.0\\-\([0-9]+\)\\-.*$")
 370       # We will add offset of 40000 to get appropriate value to
 371       # previous svn.
 372       # We use this value than also to set the package-patch-value
 373       MATH(EXPR tmp_REVISION_VERSION "(${CMAKE_MATCH_1}+40000)")
 374       set(LYX_REVISION_VERSION "${LYX_PATCH_VERSION}-${tmp_REVISION_VERSION}git")
 375       set(ENABLE_DIST ON)
 376     endif()
 377   endif()
 378 endif()
 379
 380 # Set the programs (lyx, tex2lyx, etc.) suffix
 381 # When building an OS X bundle, we will append
 382 # the suffix only to the bundle, not to the programs
 383 set(PROGRAM_SUFFIX "")
 384 if(LYX_PROGRAM_SUFFIX AND NOT (APPLE AND LYX_BUNDLE))
 385         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 386 endif()
 387 set(_lyx "${PACKAGE_BASE}${PROGRAM_SUFFIX}")
 388 set(_tex2lyx tex2lyx${PROGRAM_SUFFIX})
 389
 390 add_custom_target(lyx_version ALL
 391   COMMAND ${CMAKE_COMMAND} -DTOP_SRC_DIR=${TOP_SRC_DIR} -DTOP_CMAKE_PATH=${TOP_CMAKE_PATH} -DTOP_BINARY_DIR=${TOP_BINARY_DIR} -DLYX_DATE=${LYX_DATE} -P ${TOP_SCRIPT_PATH}/LyXGetVersion.cmake
 392   )
 393 set_target_properties(lyx_version PROPERTIES FOLDER "applications")
 394
 395 # Default paths for installed utilities (tex2lyx, lyxclient, etc.)
 396 set(LYX_UTILITIES_INSTALL_PATH bin)
 397
 398 if(LYX_BUNDLE)
 399         set(LYX_CPACK ON)
 400
 401         message(STATUS)
 402         message(STATUS "Bundle creation is enabled (experimental):")
 403         message(STATUS "    make")
 404         message(STATUS "    make install/strip")
 405         message(STATUS "    make package")
 406         if(APPLE)
 407                 set(MACOSX_BUNDLE TRUE)
 408                 # This sets the bundle + executable names
 409                 set(_lyx "${PACKAGE_BASE}${LYX_INSTALL_SUFFIX}")
 410                 # This sets the Info.plist executable name
 411                 set(osx_bundle_program_name ${_lyx})
 412                 # Bundle name
 413                 set(LYX_BUNDLE_NAME ${_lyx})
 414
 415                 # This will contain the list of files that need to be included
 416                 # in the bundle and their location within the bundle
 417                 set(OSX_BUNDLE_FILES "${TOP_SRC_DIR}/development/MacOSX/LyX.sdef;${TOP_SRC_DIR}/development/MacOSX/LyXapp.icns;${CMAKE_BINARY_DIR}/lyxrc.dist")
 418                 set(OSX_BUNDLE_DIRS "Resources;Resources;Resources")
 419
 420                 # Process Info.plist and lyxrc.dist
 421                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/Info.plist.in" "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 422                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/lyxrc.dist.in" "${CMAKE_CURRENT_BINARY_DIR}/lyxrc.dist")
 423
 424                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 425                 set(LYX_DATA_SUBDIR ${LYX_BUNDLE_NAME}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 426
 427                 # Variables used by CPack
 428                 set(CPACK_BUNDLE_NAME ${LYX_BUNDLE_NAME})
 429                 set(CPACK_BUNDLE_PLIST "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 430                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${LYX_BUNDLE_NAME}.app)
 431
 432                 # Set the install paths
 433                 set(LYX_UTILITIES_INSTALL_PATH ${LYX_BUNDLE_NAME}.app/Contents/MacOS)
 434                 if(NOT LYX_INSTALL_PREFIX)
 435                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 436                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 437                 endif()
 438                 # Change the owner so that the install can work
 439                 install(CODE "set(BU_CHMOD_BUNDLE_ITEMS 1)" COMPONENT Runtime)
 440         elseif(UNIX)
 441                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 442                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 443                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 444         elseif(WIN32)
 445                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 446         endif()
 447 endif()
 448
 449 if(LYX_INSTALL_PREFIX)
 450         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 451         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 452 endif()
 453 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 454
 455 string(REGEX REPLACE "/lyx${LYX_INSTALL_SUFFIX}$" "/share" SYSTEM_DATADIR ${CMAKE_INSTALL_PREFIX})
 456
 457 if(LYX_PACKAGE_SUFFIX)
 458         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 459 else()
 460         set(PACKAGE ${PACKAGE_BASE})
 461 endif()
 462
 463 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 464         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 465         if (UNIX)
 466                 # don't use the default "/usr/local"
 467                 # but respect the user-choice on the command-line
 468                 if(LYX_INSTALL_SUFFIX)
 469                         set(CMAKE_INSTALL_PREFIX "/usr/local/lyx${LYX_INSTALL_SUFFIX}" CACHE PATH "LyX default install prefix" FORCE)
 470                 else()
 471                         set(CMAKE_INSTALL_PREFIX "/usr/local/${LYX_PROJECT}" CACHE PATH "LyX default install prefix" FORCE)
 472                 endif()
 473         endif()
 474 endif()
 475 if(WIN32)
 476         set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 477 endif()
 478 if(IS_ABSOLUTE)
 479         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 480 else()
 481         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 482 endif()
 483
 484
 485
 486 if(NOT LYX_DATA_SUBDIR)
 487         if (WIN32)
 488                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 489         else()
 490                 set(LYX_DATA_SUBDIR "" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 491         endif()
 492 endif()
 493
 494 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 495 set(LYX_LOCALEDIR "locale")
 496 set(LYX_ABS_INSTALLED_LOCALEDIR "${LYX_ABS_INSTALLED_DATADIR}/${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}")
 497 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 498
 499 if(LYX_BUNDLE AND APPLE)
 500         set(LYX_MAN_DIR "${LYX_DATA_SUBDIR}" CACHE STRING "Install location for man pages.")
 501 else()
 502         if(WIN32)
 503                 set(LYX_MAN_DIR "${CMAKE_BINARY_DIR}/usr/local/man/man1" CACHE STRING "Install location for man pages.")
 504         else()
 505                 set(LYX_MAN_DIR "/usr/local/man/man1" CACHE STRING "Install location for man pages.")
 506         endif()
 507 endif()
 508 mark_as_advanced(LYX_MAN_DIR)
 509
 510 if(LYX_INSTALL AND WIN32)
 511         message(STATUS "Configuring NSIS files")
 512         configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 513         configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 514         configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 515         message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 516 endif()
 517
 518 if(NOT GROUP_CODE)
 519         #set(GROUP_CODE "The Golden Code")
 520         set(GROUP_CODE flat)
 521 endif()
 522
 523 # lyx's source files
 524 set(LYX_CPP_FILES [a-zA-Z]*.cpp)
 525 set(LYX_HPP_FILES [a-zA-Z]*.h)
 526 set(LYX_MOC_FILES moc_*.cpp)
 527
 528 include(ProjectSourceGroup)
 529
 530
 531 if(LYX_PROFILE AND NOT MSVC)
 532         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 533         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg")
 534         set(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS}  -pg")
 535 else()
 536         set(LYX_PROFILE OFF)
 537 endif()
 538
 539
 540 if(LYX_NO_OPTIMIZE)
 541         set(CMAKE_BUILD_TYPE None)
 542         set(LYX_DEBUG OFF)
 543         set(LYX_RELEASE OFF)
 544         set(LYX_PROFILE OFF)
 545 elseif(LYX_RELEASE)
 546         set(CMAKE_BUILD_TYPE Release)
 547         set(LYX_DEBUG OFF)
 548         set(LYX_PROFILE OFF)
 549 elseif(LYX_PROFILE)
 550         set(CMAKE_BUILD_TYPE Profile)
 551         set(LYX_DEBUG OFF)
 552 else()
 553         set(CMAKE_BUILD_TYPE Debug)
 554         set(LYX_DEBUG ON)
 555 endif()
 556
 557
 558 # When shared libs are supported enable this option
 559 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 560 if(LYX_SHARED_LIBRARIES)
 561         set(library_type SHARED)
 562 else()
 563         set(library_type STATIC)
 564 endif()
 565
 566 if(NOT MSVC)
 567         if(NOT LYX_QUIET)
 568                 set(CMAKE_VERBOSE_MAKEFILE ON)
 569         endif()
 570     set(LYX_CXX_FLAGS "-Wall -Wunused-parameter ${LYX_GCC11_MODE}")
 571         if(LYX_STDLIB_DEBUG)
 572                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 573         endif()
 574         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 575         set(CMAKE_CXX_FLAGS_DEBUG "${LYX_CXX_FLAGS} -fno-strict-aliasing -O0 -g3 -D_DEBUG" CACHE TYPE STRING FORCE)
 576         if(MINGW)
 577                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 578         else()
 579                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 580         endif()
 581 endif()
 582
 583 set(LYX_CXX_FLAGS_EXTRA "" CACHE STRING "Desired semicolon separated list of extra cxx compile flags, like '-Werror'")
 584 mark_as_advanced(LYX_CXX_FLAGS_EXTRA)
 585 if(LYX_CXX_FLAGS_EXTRA)
 586         foreach(_flag ${LYX_CXX_FLAGS_EXTRA})
 587                 add_definitions(${_flag})
 588         endforeach()
 589 endif()
 590
 591 if(LYX_XMINGW)
 592         list(APPEND CMAKE_FIND_ROOT_PATH ${GNUWIN32_DIR})
 593 endif()
 594
 595 set(QPA_XCB)
 596 if(LYX_USE_QT MATCHES "QT5")
 597         # set QPA_XCB if QT uses X11
 598         find_package(Qt5Core REQUIRED)
 599         if (Qt5Core_FOUND)
 600                 find_package(Qt5Widgets REQUIRED)
 601                 if(APPLE)
 602                         find_package(Qt5MacExtras REQUIRED)
 603                 endif()
 604                 find_package(Qt5X11Extras QUIET)
 605                 if(Qt5X11Extras_FOUND)
 606                   set(QPA_XCB 1)
 607                 endif()
 608                 find_package(Qt5WinExtras QUIET)
 609                 set(QTVERSION ${Qt5Core_VERSION})
 610                 macro (qt_use_modules)
 611                         qt5_use_modules(${ARGN})
 612                 endmacro()
 613                 macro (qt_add_resources)
 614                         qt5_add_resources(${ARGN})
 615                 endmacro()
 616                 macro (qt_wrap_uifiles)
 617                         qt5_wrap_ui(${ARGN})
 618                 endmacro()
 619                 message(STATUS "Found Qt-Version ${QTVERSION}")
 620                 if(WIN32)
 621                         set(LYX_QTMAIN_LIBRARY ${Qt5Core_QTMAIN_LIBRARIES})
 622                 endif()
 623         endif()
 624 elseif(LYX_USE_QT MATCHES "QT4")
 625         if(LYX_XMINGW)
 626                 set(QT_MINGW_DIR ${LYX_QT4} CACHE PATH "Qt for Mingw" FORCE)
 627                 list(APPEND CMAKE_FIND_ROOT_PATH ${QT_MINGW_DIR} ${GNUWIN32_DIR})
 628         endif()
 629         find_package(Qt4 "4.5.0" REQUIRED)
 630         macro (qt_use_modules)
 631         endmacro()
 632         macro (qt_add_resources)
 633                 qt4_add_resources(${ARGN})
 634         endmacro()
 635         macro (qt_wrap_uifiles)
 636                 qt4_wrap_ui(${ARGN})
 637         endmacro()
 638         if(WIN32)
 639                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARIES})
 640         endif()
 641 else()
 642   message(FATAL_ERROR "Unhandled value for LYX_USE_QT (${LYX_USE_QT})")
 643 endif()
 644
 645 find_package(Magic)
 646 if(Magic_FOUND)
 647         set(HAVE_MAGIC_H 1)
 648 endif()
 649
 650 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 651
 652 set(Spelling_FOUND OFF)
 653 set(Include_used_spellchecker)   # String will be inserted into config.h
 654
 655 if(LYX_3RDPARTY_BUILD)
 656     add_subdirectory(3rdparty/hunspell)
 657     add_definitions(-DHUNSPELL_STATIC)
 658     set(HUNSPELL_FOUND ON)
 659     message(STATUS "  * Hunspell:")
 660     message(STATUS "     - include: ${HUNSPELL_INCLUDE_DIR}")
 661     message(STATUS "     - library: ${HUNSPELL_LIBRARY}")
 662 endif()
 663
 664 foreach(_spell "ASPELL" "Enchant" "Hunspell")
 665   string(TOUPPER ${_spell} _upspell)
 666   if (NOT ${_upspell}_FOUND)
 667     find_package(${_spell})
 668   endif()
 669   if (${_upspell}_FOUND)
 670     include_directories(${${_upspell}_INCLUDE_DIR})
 671     set(Spelling_FOUND ON)
 672     message(STATUS "Building with USE_${_upspell}")
 673     set(Include_used_spellchecker "${Include_used_spellchecker}#define USE_${_upspell} 1\n")
 674   else()
 675     if(LYX_${_upspell})
 676       message(FATAL_ERROR "Required ${_spell} devel package not found")
 677     else()
 678       message(STATUS "${_upspell} not found, building without ${_spell} support")
 679     endif()
 680   endif()
 681 endforeach()
 682
 683 if(GNUWIN32_DIR)
 684         list(APPEND CMAKE_PROGRAM_PATH "${GNUWIN32_DIR}/Python" )
 685 endif()
 686
 687 find_package(PythonInterp 2.7 QUIET)
 688 if(PYTHONINTERP_FOUND)
 689         if(PYTHON_VERSION_STRING VERSION_GREATER 2.8)
 690         unset(PYTHONINTERP_FOUND)
 691         endif()
 692 endif()
 693
 694 if(NOT PYTHONINTERP_FOUND)
 695   unset(PYTHON_EXECUTABLE CACHE)
 696   unset(PYTHON_VERSION_MAJOR)
 697   unset(PYTHON_VERSION_MINOR)
 698   unset(PYTHON_VERSION_STRING)
 699   find_package(PythonInterp 3.3 REQUIRED)
 700 endif()
 701
 702 set(LYX_PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 703
 704 if(LYX_NLS)
 705         find_package(LyXGettext)
 706         if(LYX_PYTHON_EXECUTABLE AND GETTEXT_FOUND)
 707                 add_subdirectory(po "${TOP_BINARY_DIR}/po")
 708         else()
 709                 # Install only supplied .gmo-files
 710                 file(GLOB _gmofiles RELATIVE "${TOP_SRC_DIR}/po" "${TOP_SRC_DIR}/po/*.gmo")
 711                 message(STATUS "Installing provided .gmo-files only")
 712                 foreach( _gmo ${_gmofiles})
 713                         string(REGEX REPLACE "\\.gmo$" "" _lang ${_gmo})
 714                         install(FILES "${TOP_SRC_DIR}/po/${_gmo}" DESTINATION ${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}/${_lang}/LC_MESSAGES RENAME ${PACKAGE}.mo)
 715                 endforeach()
 716         endif()
 717 endif()
 718
 719 if(UNIX)
 720     find_package(ICONV REQUIRED)
 721     find_package(ZLIB REQUIRED)
 722 else()
 723     if(LYX_3RDPARTY_BUILD)
 724         add_subdirectory(3rdparty/libiconv)
 725         set(HAVE_ICONV_CONST 1)
 726         add_subdirectory(3rdparty/zlib)
 727     endif()
 728 endif()
 729
 730 if(LYX_EXTERNAL_BOOST)
 731         message(STATUS "Searching for boost")
 732         if(LYX_USE_STD_REGEX)
 733                 find_package(Boost COMPONENTS signals)
 734         else()
 735                 find_package(Boost COMPONENTS signals regex)
 736         endif()
 737         if(Boost_FOUND)
 738                 message(STATUS "Boost found")
 739                 message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 740                 set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 741                 if (LYX_STDLIB_DEBUG)
 742                         # Comment from  Jean-Marc Lasgouttes:
 743                         # In general, system boost libraries are incompatible with
 744                         # the use of stdlib-debug in libstdc++. See ticket #9736 for
 745                         # details.
 746                         message(WARNING "Compiling LyX with stdlib-debug and system boost libraries may lead to crashes. Consider using '-DLYX_STDLIB_DEBUG=OFF' or using '-DLYX_EXTERNAL_BOOST=OFF'")
 747                 endif()
 748         else()
 749                 message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 750         endif()
 751 else()
 752         if(LYX_USE_STD_REGEX)
 753                 set(Lyx_Boost_Libraries boost_signals)
 754         else()
 755                 set(Lyx_Boost_Libraries boost_signals boost_regex)
 756         endif()
 757         add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 758         add_definitions(-DBOOST_SIGNALS_NO_DEPRECATION_WARNING=1)
 759         include_directories(${TOP_SRC_DIR}/3rdparty/boost)
 760         add_subdirectory(3rdparty/boost "${TOP_BINARY_DIR}/3rdparty/boost")
 761 endif()
 762
 763
 764
 765
 766 if(WIN32)
 767         if(LYX_CONSOLE)
 768                 set(LYX_QTMAIN_LIBRARY)
 769         else()
 770                 set(WIN32_CONSOLE WIN32)
 771         endif()
 772         if(MSVC)
 773                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 774                 # disable checked iterators for msvc release builds to get maximum speed
 775                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 776         else()
 777                 add_definitions(-DWINVER=0x0500)
 778         endif()
 779 endif()
 780
 781 # Compute qt4-version from ${QTVERSION}
 782
 783 message(STATUS "")
 784 foreach(_v PACKAGE PACKAGE_VERSION
 785         PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 786         LYX_ABS_TOP_SRCDIR
 787         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 788         if(NOT DEFINED ${_v})
 789                 message(FATAL_ERROR "${_v} not defined")
 790         endif()
 791         string(SUBSTRING "${_v}                            " 0 28 _v1)
 792         message(STATUS "----- ${_v1}: ${${_v}}")
 793 endforeach(_v)
 794 message(STATUS "")
 795
 796
 797 if(LYX_PCH)
 798         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 799         # Not sure if it works for all non-msvc compilers
 800         include(PCHSupport_26)
 801         configure_file(${TOP_CMAKE_PATH}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
 802         configure_file(${TOP_CMAKE_PATH}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 803         add_definitions(-DLYX_ENABLE_PCH)
 804
 805         if(MSVC)
 806                 macro(lyx_add_msvc_pch name_)
 807                         set_source_files_properties(${${name_}_sources} PROPERTIES
 808                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 809                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
 810                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 811                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
 812                                 ${TOP_BINARY_DIR}/pcheaders.h)
 813                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 814                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 815                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 816                 endmacro(lyx_add_msvc_pch)
 817                 macro(lyx_add_gcc_pch name_)
 818                 endmacro()
 819         else()
 820                 macro(lyx_add_msvc_pch name_)
 821                 endmacro()
 822                 macro(lyx_add_gcc_pch name_)
 823                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT)
 824                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
 825                 endmacro()
 826         endif()
 827 else()
 828         macro(lyx_add_msvc_pch)
 829         endmacro(lyx_add_msvc_pch)
 830         macro(lyx_add_gcc_pch name_)
 831         endmacro()
 832 endif()
 833
 834
 835 if(MSVC)
 836
 837         if(LYX_VLD)
 838                 set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/development/Win32/vld)
 839                 add_subdirectory(${vld_path}/cmake)
 840                 include(${vld_path}/cmake/vld.cmake) # forced include
 841                 set(vld_dll vld)
 842         endif()
 843
 844         if(LYX_WALL)
 845                 # Use the highest warning level
 846                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 847
 848                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 849                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 850                 else()
 851                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 852                 endif()
 853
 854                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 855                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 856                 else()
 857                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 858                 endif()
 859
 860                 # add here warnings which should produce an error /weXXXX
 861                 set(MSVC_W_ERROR   "/we4101 /we4189")
 862                 # add here warnings which should be disabled /wdXXXX
 863                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 864
 865                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 866                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 867                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 868
 869         else()
 870                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 871
 872                 # add here warnings which should produce an error /weXXXX
 873                 set(MSVC_W_ERROR   "/we4101 /we4189")
 874                 # add here warnings which should be disabled /wdXXXX
 875                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 876
 877                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 878                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 879                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 880
 881         endif()
 882
 883         if (NOT Qt5Core_FOUND)
 884                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 885                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 886                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 887         endif()
 888
 889         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 890         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 891         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 892         message(STATUS "")
 893 endif()
 894
 895
 896 if(LYX_DEBUG_GLIBC)
 897         set(_GLIBCXX_DEBUG ON)
 898 endif()
 899
 900 if(LYX_DEBUG_GLIBC_PEDANTIC)
 901         set(_GLIBCXX_DEBUG_PEDANTIC ON)
 902 endif()
 903
 904 # Xcode compiler
 905 if (CMAKE_GENERATOR MATCHES Xcode)
 906         if (XCODE_VERSION VERSION_LESS "5.0")
 907                 # Automatically select the Xcode compiler if not set
 908                 if (NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 909                         # XCode >= 3.1 has gcc 4.2 (up to actual Xcode)
 910                         if (XCODE_VERSION VERSION_GREATER "3.1")
 911                                 SET(CMAKE_XCODE_ATTRIBUTE_GCC_VERSION "com.apple.compilers.llvmgcc42")
 912                         ENDIF(XCODE_VERSION VERSION_GREATER "3.1")
 913                 ENDIF(NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 914                 # Print the selected compiler version
 915         MESSAGE(STATUS "---- Using XCode compiler CMAKE_XCODE_ATTRIBUTE_GCC_VERSION=${CMAKE_XCODE_ATTRIBUTE_GCC_VERSION}")
 916         ENDIF(XCODE_VERSION VERSION_LESS "5.0")
 917 ENDIF(CMAKE_GENERATOR MATCHES Xcode)
 918
 919 if (WIN32 AND Qt5Core_FOUND)
 920         set(Z_PREFIX 1)
 921 endif()
 922
 923 # compiler tests, config.h generation
 924 if(MSVC AND NOT LYX_CONFIGURE_CHECKS)
 925         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.msvc ${TOP_BINARY_DIR}/configCompiler.h)
 926 else()
 927         include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
 928         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
 929 endif()
 930
 931 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
 932
 933 if(QTVERSION MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+).*")
 934         MATH(EXPR QT4_VERSION "(${CMAKE_MATCH_1}<<16)|(${CMAKE_MATCH_2}<<8)|${CMAKE_MATCH_3}")
 935 endif()
 936
 937 if (NOT HAVE_REGEX)
 938         set(LYX_USE_STD_REGEX 0)
 939 endif()
 940
 941
 942 set (cmd ${CMAKE_CTEST_COMMAND})
 943 if (MSVC)
 944         set (cmd ${cmd} -C ${CMAKE_CFG_INTDIR})
 945 else ()
 946         set (cmd ${cmd} -C ${CMAKE_BUILD_TYPE})
 947 endif ()
 948 add_custom_target (lyx_run_tests COMMAND ${cmd})
 949 set_target_properties(lyx_run_tests PROPERTIES FOLDER "tests")
 950
 951 if(LYX_ASAN)
 952     set(LYX_CXX_FLAGS "-fsanitize=address -fno-omit-frame-pointer -g")
 953     message(STATUS)
 954     message(STATUS "Address sanitizer enabled. Usage:")
 955     message(STATUS "    wget https://llvm.org/svn/llvm-project/compiler-rt/trunk/lib/asan/scripts/asan_symbolize.py")
 956     message(STATUS "    chmod  +x ./asan_symbolize.py")
 957     message(STATUS "    ./bin/lyx2.2 2>&1 | ./asan_symbolize.py  | c++filt ")
 958     message(STATUS)
 959 endif()
 960
 961 if(LYX_INSTALL)
 962         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 963                 message(STATUS "Python required to create doc!")
 964         else()
 965                 if(UNIX)
 966                         add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
 967                 endif()
 968                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
 969         endif()
 970         include(../Install)
 971 endif()
 972
 973 add_subdirectory(src "${TOP_BINARY_DIR}/src")
 974 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
 975 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
 976 add_subdirectory(lib/examples "${TOP_BINARY_DIR}/lib/examples")
 977 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
 978 add_subdirectory(development/autotests "${TOP_BINARY_DIR}/autotests")
 979 if(LYX_ENABLE_URLTESTS)
 980         add_subdirectory(development/checkurls "${TOP_BINARY_DIR}/checkurls")
 981 endif()
 982
 983 message(STATUS)
 984 message(STATUS "Build params, switch LYX_* options by -DLYX_*=ON or OFF, LYX_* combos by -DLYX_*=value:")
 985 message(STATUS)
 986
 987 LYX_OPTION_LIST_ALL(used)
 988
 989
 990 if(LYX_NLS)
 991         message(STATUS)
 992         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
 993         message(STATUS)
 994         message(STATUS "  * iconv")
 995         message(STATUS "     - include: ${ICONV_INCLUDE_DIR}")
 996         message(STATUS "     - library: ${ICONV_LIBRARY}")
 997         message(STATUS "  * zlib")
 998         message(STATUS "     - include: ${ZLIB_INCLUDE_DIR}")
 999         message(STATUS "     - library: ${ZLIB_LIBRARY}")
1000         message(STATUS)
1001 endif()
1002
1003 # Apple has builtin native spell checker,
1004 # no need to warn for missing Aspell, Hunspell or Enchant
1005 if(NOT Spelling_FOUND AND NOT APPLE)
1006   if(LYX_REQUIRE_SPELLCHECK)
1007     set(_mode "FATAL_ERROR")
1008   else()
1009     set(_mode "STATUS")
1010   endif()
1011   message(${_mode} "No spellcheck libraries found. LyX will be unable use spellchecking")
1012 endif()
1013
1014 include("${TOP_CMAKE_PATH}/LyxPackaging.cmake")
1015
1016 if(ENABLE_DIST)
1017   # Use git to create the source package
1018   # git archive --format=tgz --output=/home/kornel/x.tar.gz master
1019   if(UNIX)
1020     set(DIST_FORMAT tgz)
1021   else()
1022     set(DIST_FORMAT zip)
1023   endif()
1024   set(DIST_NAME ${CMAKE_PROJECT_NAME}-${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}-${CMAKE_SYSTEM_NAME}.${DIST_FORMAT})
1025
1026   add_custom_command(
1027     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME}
1028     COMMAND  ${LYX_GITVERSION} archive --format=${DIST_FORMAT} --output=${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME} master
1029     WORKING_DIRECTORY ${TOP_SRC_DIR})
1030   add_custom_target(git-archive DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME})
1031 endif()
1032
1033 # Last directory to be included so that the fixup code (OS X)
1034 # can be run last
1035 add_subdirectory(development/cmake/post_install)
1036
1037 message(STATUS)