CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 2.6.4)
   8
   9 set(LYX_PROJECT LyX)
  10
  11 # Instruct cmake to not use gnu extensions,
  12 # this prevents the mix of '-std=c++*' and '-std=gnu++*' flags
  13 set(CMAKE_CXX_EXTENSIONS OFF)
  14
  15 enable_testing()
  16
  17 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README REALPATH) # Resolve symlinks
  18 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  19 message(STATUS "TOP_SRC_DIR = ${TOP_SRC_DIR}")
  20
  21 set(LYX_CMAKE_DIR "development/cmake")
  22 set(TOP_CMAKE_PATH "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}")
  23 set(TOP_MODULE_PATH "${TOP_CMAKE_PATH}/modules")
  24 set(TOP_SCRIPT_PATH "${TOP_CMAKE_PATH}/scripts")
  25
  26 set(CMAKE_MODULE_PATH "${TOP_MODULE_PATH}")
  27
  28 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  29
  30 message(STATUS)
  31 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  32         message(STATUS "Building in-source")
  33         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  34 else()
  35         message(STATUS "Building out-of-source")
  36         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  37 endif()
  38
  39 # This directory should be used if some test uses lyx-executable
  40 set(LYX_TESTS_USERDIR "${TOP_BINARY_DIR}/Testing/.lyx")
  41 file(MAKE_DIRECTORY "${LYX_TESTS_USERDIR}")
  42
  43 if(COMMAND cmake_policy)
  44         # Installing MACOSX_BUNDLE targets requires a BUNDLE DESTINATION
  45         cmake_policy(SET CMP0006 NEW)
  46         if(POLICY CMP0043)
  47                 # COMPILE_DEFINITIONS are not used yet. Enable new behavior.
  48                 cmake_policy(SET CMP0043 NEW)
  49         endif()
  50 endif()
  51
  52 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  53
  54 # Supress regeneration
  55 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  56
  57 if(LYX_XMINGW)
  58     set(CMAKE_SYSTEM_NAME Windows)
  59     set(TOOLNAME ${LYX_XMINGW})
  60     set(TOOLCHAIN "${TOOLNAME}-")
  61     set(CMAKE_C_COMPILER   "${TOOLCHAIN}gcc"     CACHE PATH "Mingw C compiler" FORCE)
  62     set(CMAKE_CXX_COMPILER "${TOOLCHAIN}g++"     CACHE PATH "Mingw C++ compiler" FORCE)
  63     set(CMAKE_RC_COMPILER  "${TOOLCHAIN}windres" CACHE PATH "Mingw rc compiler" FORCE)
  64
  65     set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM BOTH)
  66     set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY)
  67     set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY)
  68 endif()
  69
  70 if(NOT help AND NOT HELP)
  71   # 'project' triggers the searching for a compiler
  72   project(${LYX_PROJECT})
  73   if (CMAKE_COMPILER_IS_GNUCXX)
  74     if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS "4.0")
  75       message(STATUS "Gnu CXX compiler version = ${CMAKE_CXX_COMPILER_VERSION}")
  76       message(STATUS "is too old, should be >= 4.0")
  77       message(FATAL_ERROR "Exiting")
  78     endif()
  79   endif()
  80 endif()
  81
  82 if(UNIX)
  83         set(ARCH_TRIPLET )
  84         FIND_PROGRAM(DPKG_ARCHITECTURE_EXECUTABLE dpkg-architecture)
  85         if(DPKG_ARCHITECTURE_EXECUTABLE)
  86                 EXECUTE_PROCESS(COMMAND ${DPKG_ARCHITECTURE_EXECUTABLE} -qDEB_HOST_MULTIARCH
  87                                 OUTPUT_VARIABLE ARCH_TRIPLET
  88                                 ERROR_VARIABLE ERROR_ARCH_TRIPLET
  89                                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  90         endif()
  91 endif()
  92 if(ARCH_TRIPLET)
  93         set(SYSTEM_LIB_DIRS /usr/lib /usr/lib/${ARCH_TRIPLET} /usr/local/lib)
  94 else()
  95         set(SYSTEM_LIB_DIRS /usr/lib /usr/local/lib)
  96 endif()
  97
  98 include(LyXMacros)
  99 include(LyXDestinations)
 100
 101 # Usage LYX_OPTION
 102 # 1. parameter: option name without prefix 'LYX_'
 103 # 2. parameter: description
 104 # 3. parameter: default value, ON or OFF
 105 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
 106
 107 # Usage LYX_COMBO
 108 # 1. parameter: name without prefix 'LYX_'
 109 # 2. parameter: description
 110 # 3. parameter: default value
 111 # 4-n parameter: possible other string values
 112
 113 LYX_OPTION_INIT()
 114
 115 # Options for all compilers/systems
 116 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
 117 LYX_OPTION(LOCALVERSIONING  "Add version info to created package name (only used if LYX_CPACK option set)" OFF ALL)
 118 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
 119 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
 120 LYX_OPTION(REQUIRE_SPELLCHECK "Abort if no spellchecker available" OFF ALL)
 121 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
 122 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
 123 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
 124 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" OFF ALL)
 125 LYX_OPTION(DEBUG            "Enforce debug build"  OFF ALL)
 126 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
 127 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
 128 LYX_STRING(SUFFIX_VALUE     "Use this string as suffix" "")
 129 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
 130 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
 131 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
 132 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
 133 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
 134 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
 135 LYX_OPTION(ENABLE_URLTESTS  "Enable for URL tests" OFF ALL)
 136 LYX_OPTION(ENABLE_EXPORT_TESTS "Enable for export tests" OFF ALL)
 137 LYX_OPTION(ENABLE_KEYTESTS  "Enable for keytests" OFF ALL)
 138 LYX_OPTION(ASAN             "Use address sanitizer" OFF ALL)
 139 LYX_COMBO(USE_QT            "Use Qt version as frontend" AUTO QT4 QT5)
 140 #LYX_OPTION(3RDPARTY_BUILD   "Build 3rdparty libs" OFF ALL)
 141 LYX_OPTION(EXTERNAL_Z       "OFF := Build 3rdparty lib zlib" ON ALL)
 142 LYX_OPTION(EXTERNAL_ICONV   "OFF := Build 3rdparty lib iconvlib" ON ALL)
 143 LYX_OPTION(EXTERNAL_HUNSPELL "OFF := Build 3rdparty lib hunspelllib" ON ALL)
 144 LYX_COMBO(EXTERNAL_MYTHES   "OFF := Build 3rdparty lib mytheslib" AUTO OFF ON)
 145
 146 # GCC specific
 147 LYX_OPTION(PROFILE              "Build profile version" OFF GCC)
 148 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" OFF GCC)
 149 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
 150 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
 151 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++ pedantic debug mode" OFF GCC)
 152 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" OFF GCC)
 153 LYX_OPTION(PROFILE              "Build with options for gprof" OFF GCC)
 154
 155 # MSVC specific
 156 LYX_OPTION(CONSOLE               "Show console on Windows, enforce with =FORCE" ON MSVC)
 157 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
 158 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
 159 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
 160
 161 # APPLE specific
 162 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
 163 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
 164
 165
 166 if(help OR HELP)
 167         message(STATUS)
 168         message(STATUS "Available options: (dis/enable with -DLYX_*=OFF/ON)")
 169         message(STATUS)
 170         LYX_OPTION_LIST_ALL(help)
 171         message(STATUS)
 172         RETURN()
 173 endif()
 174
 175 # Check option dependencies
 176
 177 if(LYX_DMG)
 178         set(LYX_BUNDLE ON)
 179         set(LYX_CPACK ON)
 180 endif()
 181
 182 if(LYX_CPACK)
 183         set(LYX_INSTALL ON)
 184 endif()
 185
 186 if(LYX_INSTALL)
 187         set(LYX_NLS ON)
 188         if(WIN32 AND NOT MINGW)
 189                 set(LYX_HUNSPELL ON)
 190         endif()
 191         if(LYX_CONSOLE MATCHES "FORCE")
 192                 set(LYX_CONSOLE ON)
 193         else()
 194                 set(LYX_CONSOLE OFF)
 195         endif()
 196         set(LYX_PACKAGE_SUFFIX ON)
 197         if(NOT LYX_DEBUG)
 198                 set(LYX_RELEASE ON)
 199         endif()
 200         set(LYX_PROFILE OFF)
 201 endif()
 202
 203
 204 if(LYX_MERGE_FILES)
 205         set(LYX_PCH OFF)
 206 else()
 207         set(LYX_MERGE_REBUILD OFF)
 208 endif()
 209
 210 if(LYX_DEPENDENCIES_DOWNLOAD)
 211         message(STATUS)
 212         if(MSVC14)
 213                 set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2015-deps)
 214                 set(deps_files lyx-windows-deps-msvc2015.zip)
 215                 set(deps_server http://ftp.lyx.de/LyX-Windows-Deps)
 216                 set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2015)
 217         elseif(MSVC10)
 218                 set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 219                 set(deps_files lyx-windows-deps-msvc2010.zip)
 220                 set(deps_server http://ftp.lyx.de/LyX-Windows-Deps)
 221                 set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2010)
 222         else()
 223                 message(FATAL_ERROR "error: no dependency package known for the selected MSVC version.")
 224         endif()
 225     message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 226         foreach(it ${deps_files})
 227                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 228                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 229                 if(NOT already_downloaded)
 230                         message(STATUS "Downloading ${it} ...")
 231                         file(DOWNLOAD ${deps_server}/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS STATUS status LOG log)
 232                         list(GET status 0 status_code)
 233                         list(GET status 1 status_string)
 234                         if(NOT status_code EQUAL 0)
 235                                 file(REMOVE ${LYX_DEPENDENCIES_DIR}/${it})
 236                                 message(FATAL_ERROR "error: downloading '${it}' failed. status_code: ${status_code}, status_string: ${status_string}. \nLog: ${log} ")
 237                         endif()
 238                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 239                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 240                 endif()
 241         endforeach()
 242 endif()
 243
 244
 245
 246 message(STATUS)
 247
 248 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 249 if(WIN32)
 250         set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 251 else()
 252         set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 253 endif()
 254
 255
 256 # Set to some meaningful default
 257 find_package(CXX11Compiler)
 258 if(NOT CXX11COMPILER_FOUND)
 259         message(FATAL_ERROR "A C++11 compatible compiler is required.")
 260 endif()
 261 set(LYX_GCC11_MODE)
 262 if(UNIX OR MINGW)
 263         if (CMAKE_CXX_COMPILER_ID MATCHES "^[cC]lang$")
 264           # ignore the GCC_VERSION for clang
 265           # and use the resulting CXX11_STD_REGEX found in FindCXX11Compiler.cmake
 266           message(STATUS "Using clang")
 267           if(CXX11_STD_REGEX)
 268             set(LYX_USE_STD_REGEX 1)
 269           else()
 270             set(LYX_USE_STD_REGEX 0)
 271           endif()
 272         else()
 273           execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION OUTPUT_STRIP_TRAILING_WHITESPACE)
 274           message(STATUS "Using GCC version ${GCC_VERSION}")
 275           if(GCC_VERSION VERSION_LESS 4.9)
 276                   if(GCC_VERSION VERSION_LESS 4.6)
 277                           message(FATAL_ERROR "gcc >= 4.6 is required.")
 278                   endif()
 279                   # <regex> in gcc is unusable in versions less than 4.9.0
 280                   # see https://gcc.gnu.org/bugzilla/show_bug.cgi?id=53631
 281                   set(LYX_USE_STD_REGEX 0)
 282           else()
 283                   set(LYX_USE_STD_REGEX 1)
 284           endif()
 285         endif()
 286         set(LYX_GCC11_MODE "${CXX11_FLAG}")
 287 else()
 288         set(LYX_USE_STD_REGEX 0)
 289 #       if(MSVC10)
 290 #               set(LYX_USE_STD_REGEX 1) #TODO should we use it in ECMAScript mode?
 291 #       endif()
 292 endif()
 293
 294
 295 set(VERSION_INFO "CMake Build")
 296
 297 # Try to get some informations from configure.ac
 298
 299 include(LyXPaths)
 300 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 301
 302 if(WIN32)
 303         set(CMAKE_PREFIX_PATH Specify-path-to-Qt CACHE PATH "Used Qt version")
 304         if(MSVC)
 305                 set(LYX_3RDPARTY_BUILD ON CACHE BOOL "Build 3rdparty libraries" FORCE)
 306         endif()
 307         set(USE_WINDOWS_PACKAGING ON)
 308 elseif(APPLE)
 309         set(USE_MACOSX_PACKAGING ON)
 310 else()
 311         set(USE_POSIX_PACKAGING ON)
 312 endif()
 313
 314 if(LYX_3RDPARTY_BUILD)
 315   # LYX_3RDPARTY_BUILD is not cached anymore, but for compatibility reasons
 316   # this enables the build of all 3rd_party libs
 317   set(LYX_EXTERNAL_Z        OFF CACHE BOOL "Build 3rdparty lib zlib"    FORCE)
 318   set(LYX_EXTERNAL_ICONV    OFF CACHE BOOL "Build 3rdparty iconvlib"    FORCE)
 319   set(LYX_EXTERNAL_HUNSPELL OFF CACHE BOOL "Build 3rdparty hunspelllib" FORCE)
 320   set(LYX_EXTERNAL_MYTHES   OFF CACHE STRING "Build 3rdparty mytheslib" FORCE)
 321 endif()
 322
 323 macro(setstripped _varname)
 324         if(${ARGC} GREATER 1)
 325                 string(STRIP "${ARGV1}" _v)
 326                 if(USE_POSIX_PACKAGING)
 327                         string(TOLOWER ${_v} ${_varname})
 328                 else()
 329                         set(${_varname} ${_v})
 330                 endif()
 331         else()
 332                 set(${_varname})
 333         endif()
 334 endmacro(setstripped)
 335
 336 foreach(_c_l ${_config_lines} )
 337         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 338                 setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 339                 setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 340                 setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 341                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\)\(\\.\([0-9]+\)\)?.*$")
 342                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 343                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 344                         set(LYX_PATCH_VERSION ${CMAKE_MATCH_4})
 345                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 346                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 347                         if ("${LYX_SUFFIX_VALUE}" MATCHES "")
 348                           set(LYX_INSTALL_SUFFIX "${LYX_MAJOR_VERSION}.${LYX_MINOR_VERSION}")
 349                         else()
 350                           set(LYX_INSTALL_SUFFIX "${LYX_SUFFIX_VALUE}")
 351                         endif()
 352                 endif()
 353         endif()
 354         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 355                 set(LYX_DATE "${CMAKE_MATCH_1}")
 356         endif()
 357 endforeach(_c_l)
 358
 359 FIND_PROGRAM(LYX_GITVERSION git)
 360 #message(STATUS "gitversion = ${LYX_GITVERSION}")
 361 set(LYX_REVISION_VERSION ${LYX_PATCH_VERSION})
 362 if(LYX_GITVERSION)
 363   if (LYX_LOCALVERSIONING)
 364     # Find the revision number and for later use
 365     EXECUTE_PROCESS(COMMAND ${LYX_GITVERSION} describe --match 2.0.0 HEAD
 366       WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE LYX_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 367     if (LYX_PACKAGE_RELEASE MATCHES "^2\\.0\\.0\\-\([0-9]+\)\\-.*$")
 368       # We will add offset of 40000 to get appropriate value to
 369       # previous svn.
 370       # We use this value than also to set the package-patch-value
 371       MATH(EXPR tmp_REVISION_VERSION "(${CMAKE_MATCH_1}+40000)")
 372       set(LYX_REVISION_VERSION "${LYX_PATCH_VERSION}-${tmp_REVISION_VERSION}git")
 373       set(ENABLE_DIST ON)
 374     endif()
 375   endif()
 376 endif()
 377
 378 # Set the programs (lyx, tex2lyx, etc.) suffix
 379 # When building an OS X bundle, we will append
 380 # the suffix only to the bundle, not to the programs
 381 set(PROGRAM_SUFFIX "")
 382 if(LYX_PROGRAM_SUFFIX AND NOT (APPLE AND LYX_BUNDLE))
 383         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 384 endif()
 385 set(_lyx "${PACKAGE_BASE}${PROGRAM_SUFFIX}")
 386 set(_tex2lyx tex2lyx${PROGRAM_SUFFIX})
 387 set(_convert lyxconvert${PROGRAM_SUFFIX})
 388
 389 add_custom_target(lyx_version ALL
 390   COMMAND ${CMAKE_COMMAND} -DTOP_SRC_DIR=${TOP_SRC_DIR} -DTOP_CMAKE_PATH=${TOP_CMAKE_PATH} -DTOP_BINARY_DIR=${TOP_BINARY_DIR} -DLYX_DATE=${LYX_DATE} -P ${TOP_SCRIPT_PATH}/LyXGetVersion.cmake
 391   )
 392 set_target_properties(lyx_version PROPERTIES FOLDER "applications")
 393
 394 # Default paths for installed utilities (tex2lyx, lyxclient, etc.)
 395 set(LYX_UTILITIES_INSTALL_PATH bin)
 396
 397 if(LYX_BUNDLE)
 398         set(LYX_CPACK ON)
 399
 400         message(STATUS)
 401         message(STATUS "Bundle creation is enabled (experimental):")
 402         message(STATUS "    make")
 403         message(STATUS "    make install/strip")
 404         message(STATUS "    make package")
 405         if(APPLE)
 406                 set(MACOSX_BUNDLE TRUE)
 407                 # This sets the bundle + executable names
 408                 set(_lyx "${PACKAGE_BASE}${LYX_INSTALL_SUFFIX}")
 409                 # This sets the Info.plist executable name
 410                 set(osx_bundle_program_name ${_lyx})
 411                 # Bundle name
 412                 set(LYX_BUNDLE_NAME ${_lyx})
 413
 414                 # This will contain the list of files that need to be included
 415                 # in the bundle and their location within the bundle
 416                 set(OSX_BUNDLE_FILES "${TOP_SRC_DIR}/development/MacOSX/LyX.sdef;${TOP_SRC_DIR}/development/MacOSX/LyXapp.icns;${CMAKE_BINARY_DIR}/lyxrc.dist")
 417                 set(OSX_BUNDLE_DIRS "Resources;Resources;Resources")
 418
 419                 # Process Info.plist and lyxrc.dist
 420                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/Info.plist.in" "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 421                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/lyxrc.dist.in" "${CMAKE_CURRENT_BINARY_DIR}/lyxrc.dist")
 422
 423                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 424                 set(LYX_DATA_SUBDIR ${LYX_BUNDLE_NAME}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 425
 426                 # Variables used by CPack
 427                 set(CPACK_BUNDLE_NAME ${LYX_BUNDLE_NAME})
 428                 set(CPACK_BUNDLE_PLIST "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 429                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${LYX_BUNDLE_NAME}.app)
 430
 431                 # Set the install paths
 432                 set(LYX_UTILITIES_INSTALL_PATH ${LYX_BUNDLE_NAME}.app/Contents/MacOS)
 433                 if(NOT LYX_INSTALL_PREFIX)
 434                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 435                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 436                 endif()
 437                 # Change the owner so that the install can work
 438                 install(CODE "set(BU_CHMOD_BUNDLE_ITEMS 1)" COMPONENT Runtime)
 439         elseif(UNIX)
 440                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 441                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 442                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 443         elseif(WIN32)
 444                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 445         endif()
 446 endif()
 447
 448 if(LYX_INSTALL_PREFIX)
 449         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 450         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 451 endif()
 452 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 453
 454 if(UNIX)
 455   set(SYSTEM_DATADIR "${CMAKE_INSTALL_PREFIX}/share")
 456 elseif(CMAKE_INSTALL_PREFIX MATCHES "/lyx${LYX_INSTALL_SUFFIX}$")
 457   string(REGEX REPLACE "/lyx${LYX_INSTALL_SUFFIX}$" "/share" SYSTEM_DATADIR ${CMAKE_INSTALL_PREFIX})
 458 else()
 459   set(SYSTEM_DATADIR "${CMAKE_INSTALL_PREFIX}")
 460 endif()
 461
 462 if(CMAKE_COMPILER_IS_GNUCXX)
 463   message(STATUS "CMAKE_COMPILER_IS_GNUCXX = ${CMAKE_COMPILER_IS_GNUCXX}")
 464   set(suffixing ${LYX_PROGRAM_SUFFIX})
 465 else()
 466   # Not a GCC compiler, programs do not have a suffix
 467   set(suffixing ${LYX_PACKAGE_SUFFIX})
 468 endif()
 469
 470 # The define PACKAGE below allows lyx-executable to find its default configuration files
 471 # see routines
 472 #    Package::messages_file()
 473 #    get_default_user_support_dir()
 474 #    relative_system_support_dir()
 475 # in src/support/Package.cpp
 476 #
 477 if(suffixing)
 478         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 479 else()
 480         set(PACKAGE ${PACKAGE_BASE})
 481 endif()
 482
 483 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 484         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 485         if (UNIX)
 486                 # use the default "/usr/local"
 487                 # but respect the user-choice on the command-line
 488                 set(CMAKE_INSTALL_PREFIX "/usr/local" CACHE PATH "LyX default install prefix" FORCE)
 489         endif()
 490 endif()
 491 if(WIN32)
 492         set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 493 endif()
 494 if(IS_ABSOLUTE)
 495         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 496 else()
 497         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 498 endif()
 499
 500
 501
 502 if(NOT LYX_DATA_SUBDIR)
 503         if (WIN32)
 504                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 505         else()
 506                 set(LYX_DATA_SUBDIR "share/${_lyx}/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 507         endif()
 508 endif()
 509
 510 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 511 get_locale_destination(LYX_LOCALEDIR)
 512 set(LYX_ABS_INSTALLED_LOCALEDIR "${CMAKE_INSTALL_PREFIX}/${LYX_LOCALEDIR}")
 513 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 514
 515 if(LYX_BUNDLE AND APPLE)
 516         set(LYX_MAN_DIR "${LYX_DATA_SUBDIR}" CACHE STRING "Install location for man pages.")
 517 else()
 518         if(WIN32)
 519                 set(LYX_MAN_DIR "${CMAKE_BINARY_DIR}/usr/local/man" CACHE STRING "Install location for man pages.")
 520         elseif(UNIX)
 521                 set(LYX_MAN_DIR "${CMAKE_INSTALL_PREFIX}/share/man" CACHE STRING "Install location for man pages.")
 522         else()
 523                 set(LYX_MAN_DIR "${CMAKE_INSTALL_PREFIX}/man" CACHE STRING "Install location for man pages.")
 524         endif()
 525 endif()
 526 mark_as_advanced(LYX_MAN_DIR)
 527
 528 if(LYX_INSTALL AND WIN32)
 529         message(STATUS "Configuring NSIS files")
 530         configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 531         configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 532         configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 533         message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 534 endif()
 535
 536 if(NOT GROUP_CODE)
 537         #set(GROUP_CODE "The Golden Code")
 538         set(GROUP_CODE flat)
 539 endif()
 540
 541 # lyx's source files
 542 set(LYX_CPP_FILES [a-zA-Z]*.cpp)
 543 set(LYX_HPP_FILES [a-zA-Z]*.h)
 544 set(LYX_MOC_FILES moc_*.cpp)
 545
 546 include(ProjectSourceGroup)
 547
 548
 549 if(LYX_PROFILE AND NOT MSVC)
 550         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 551         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg")
 552         set(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS}  -pg")
 553 else()
 554         set(LYX_PROFILE OFF)
 555 endif()
 556
 557
 558 if(LYX_NO_OPTIMIZE)
 559         set(CMAKE_BUILD_TYPE None)
 560         set(LYX_DEBUG OFF)
 561         set(LYX_RELEASE OFF)
 562         set(LYX_PROFILE OFF)
 563 elseif(LYX_RELEASE)
 564         set(CMAKE_BUILD_TYPE Release)
 565         set(LYX_DEBUG OFF)
 566         set(LYX_PROFILE OFF)
 567 elseif(LYX_PROFILE)
 568         set(CMAKE_BUILD_TYPE Profile)
 569         set(LYX_DEBUG OFF)
 570 else()
 571         set(CMAKE_BUILD_TYPE Debug)
 572         set(LYX_DEBUG ON)
 573 endif()
 574
 575
 576 # When shared libs are supported enable this option
 577 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 578 if(LYX_SHARED_LIBRARIES)
 579         set(library_type SHARED)
 580 else()
 581         set(library_type STATIC)
 582 endif()
 583
 584 if(NOT MSVC)
 585         if(NOT LYX_QUIET)
 586                 set(CMAKE_VERBOSE_MAKEFILE ON)
 587         endif()
 588         set(LYX_CXX_FLAGS "-Wall -Wunused-parameter ${LYX_GCC11_MODE}")
 589         if(LYX_CXX_FLAGS MATCHES "\\+\\+(14|11|98)")
 590           # Thanks to Brad King <brad.king@kitware.com>
 591           # for the pointer to https://cmake.org/cmake/help/v3.6/variable/CMAKE_CXX_STANDARD.html
 592           # This allows us to use QT5.7 with recent g++ (version >= 4.9) compilers
 593           # and still use our own c++ extension tests
 594           set(CMAKE_CXX_STANDARD ${CMAKE_MATCH_1})
 595           message(STATUS "CMAKE_CXX_STANDARD set to ${CMAKE_CXX_STANDARD}")
 596         endif()
 597         if(LYX_STDLIB_DEBUG)
 598                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 599         endif()
 600         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 601         set(CMAKE_CXX_FLAGS_DEBUG "-O0 -g3 -D_DEBUG" CACHE TYPE STRING FORCE)
 602         if(MINGW)
 603                 set(CMAKE_CXX_FLAGS_RELEASE "-O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 604         else()
 605                 set(CMAKE_CXX_FLAGS_RELEASE "-O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 606         endif()
 607 endif()
 608
 609 set(LYX_CXX_FLAGS_EXTRA "" CACHE STRING "Desired semicolon separated list of extra cxx compile flags, like '-Werror'")
 610 mark_as_advanced(LYX_CXX_FLAGS_EXTRA)
 611 if(LYX_CXX_FLAGS_EXTRA)
 612         foreach(_flag ${LYX_CXX_FLAGS_EXTRA})
 613                 add_definitions(${_flag})
 614         endforeach()
 615 endif()
 616
 617 if(LYX_XMINGW)
 618         list(APPEND CMAKE_FIND_ROOT_PATH ${GNUWIN32_DIR})
 619 endif()
 620
 621 set(min_qt5_version "5.6")
 622 if(LYX_USE_QT MATCHES "AUTO")
 623         # try qt5 first
 624         find_package(Qt5Core QUIET)
 625         if(Qt5Core_FOUND)
 626                 set(LYX_USE_QT "QT5" CACHE STRING "Valid qt version" FORCE)
 627                 message(STATUS "Qt5Core_VERSION = ${Qt5Core_VERSION}")
 628                 if(Qt5Core_VERSION VERSION_LESS ${min_qt5_version})
 629                         find_package(Qt4 "4.5.0" QUIET)
 630                         if(QT4_FOUND)
 631                                 set(LYX_USE_QT "QT4" CACHE STRING "Valid qt version" FORCE)
 632                         endif()
 633                 endif()
 634         else()
 635                 set(LYX_USE_QT "QT4" CACHE STRING "Valid qt version" FORCE)
 636         endif()
 637 endif()
 638 if(LYX_USE_QT MATCHES "QT5")
 639         # set QPA_XCB if QT uses X11
 640         find_package(Qt5Core REQUIRED)
 641         if (Qt5Core_FOUND)
 642                 find_package(Qt5Widgets REQUIRED)
 643                 if(APPLE)
 644                         find_package(Qt5MacExtras REQUIRED)
 645                 endif()
 646                 find_package(Qt5X11Extras QUIET)
 647                 find_package(Qt5WinExtras QUIET)
 648                 set(QTVERSION ${Qt5Core_VERSION})
 649                 if (QTVERSION VERSION_LESS ${min_qt5_version})
 650                         message(STATUS "QTVERSION = \"${QTVERSION}\"")
 651                         message(STATUS "This version is not recommended, try either option -DLYX_USE_QT=QT4 or")
 652                         message(STATUS "install QT-Version >= \"${min_qt5_version}\"")
 653                         # see thread in lyx-devel list
 654                         # From: Jean-Pierre Chrétien <jeanpierre.chretien@free.fr>
 655                         # Date 11.03.2017
 656                         # Subject: cmake compilation error
 657                         #message(FATAL_ERROR "Wrong Qt-Version")
 658                 endif()
 659                 macro (qt_use_modules)
 660                         qt5_use_modules(${ARGN})
 661                 endmacro()
 662                 macro (qt_add_resources)
 663                         qt5_add_resources(${ARGN})
 664                 endmacro()
 665                 macro (qt_wrap_uifiles)
 666                         qt5_wrap_ui(${ARGN})
 667                 endmacro()
 668                 message(STATUS "Found Qt-Version ${QTVERSION}")
 669                 if(WIN32)
 670                         set(LYX_QTMAIN_LIBRARY ${Qt5Core_QTMAIN_LIBRARIES})
 671                 endif()
 672         endif()
 673 elseif(LYX_USE_QT MATCHES "QT4")
 674         if(LYX_XMINGW)
 675                 set(QT_MINGW_DIR ${LYX_QT4} CACHE PATH "Qt for Mingw" FORCE)
 676                 list(APPEND CMAKE_FIND_ROOT_PATH ${QT_MINGW_DIR} ${GNUWIN32_DIR})
 677         endif()
 678         find_package(Qt4 "4.5.0" REQUIRED)
 679         macro (qt_use_modules)
 680         endmacro()
 681         macro (qt_add_resources)
 682                 qt4_add_resources(${ARGN})
 683         endmacro()
 684         macro (qt_wrap_uifiles)
 685                 qt4_wrap_ui(${ARGN})
 686         endmacro()
 687         set(LYX_QTMAIN_LIBRARY ${QT_QTSVG_LIBRARY})
 688         if(WIN32)
 689                 list(APPEND LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARIES})
 690         endif()
 691 else()
 692   message(FATAL_ERROR "Unhandled value for LYX_USE_QT (${LYX_USE_QT})")
 693 endif()
 694
 695 find_package(Magic)
 696 if(Magic_FOUND)
 697         set(HAVE_MAGIC_H 1)
 698 endif()
 699
 700 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 701
 702 set(Spelling_FOUND OFF)
 703 set(Include_used_spellchecker)   # String will be inserted into config.h
 704
 705 if (LYX_EXTERNAL_MYTHES MATCHES "AUTO")
 706   # try system library first
 707   find_package(MyThesLIB)
 708   if (MYTHESLIB_FOUND)
 709     set(LYX_EXTERNAL_MYTHES ON CACHE STRING "OFF:= Build 3rdparty mytheslib" FORCE)
 710   else()
 711     set(LYX_EXTERNAL_MYTHES OFF CACHE STRING "OFF:= Build 3rdparty mytheslib" FORCE)
 712   endif()
 713 endif()
 714 if (LYX_EXTERNAL_MYTHES MATCHES "ON")
 715   find_package(MyThesLIB REQUIRED)
 716 else()
 717   add_subdirectory(3rdparty/mythes)
 718 endif()
 719 set(MYTHES_DIR ${MYTHESLIB_INCLUDE_DIR})
 720
 721 if(NOT LYX_EXTERNAL_HUNSPELL)
 722     add_subdirectory(3rdparty/hunspell)
 723     add_definitions(-DHUNSPELL_STATIC)
 724     set(HUNSPELL_FOUND ON)
 725     message(STATUS "  * Hunspell:")
 726     message(STATUS "     - include: ${HUNSPELL_INCLUDE_DIR}")
 727     message(STATUS "     - library: ${HUNSPELL_LIBRARY}")
 728 endif()
 729
 730 foreach(_spell "ASPELL" "Enchant" "Hunspell")
 731   string(TOUPPER ${_spell} _upspell)
 732   if (NOT ${_upspell}_FOUND)
 733     find_package(${_spell})
 734   endif()
 735   if (${_upspell}_FOUND)
 736     include_directories(${${_upspell}_INCLUDE_DIR})
 737     set(Spelling_FOUND ON)
 738     message(STATUS "Building with USE_${_upspell}")
 739     set(Include_used_spellchecker "${Include_used_spellchecker}#define USE_${_upspell} 1\n")
 740   else()
 741     if(LYX_${_upspell})
 742       message(FATAL_ERROR "Required ${_spell} devel package not found")
 743     else()
 744       message(STATUS "${_upspell} not found, building without ${_spell} support")
 745     endif()
 746   endif()
 747 endforeach()
 748
 749 if(GNUWIN32_DIR)
 750         list(APPEND CMAKE_PROGRAM_PATH "${GNUWIN32_DIR}/Python" )
 751 endif()
 752
 753 # Search for python default version first
 754 unset(PYTHON_EXECUTABLE CACHE)
 755 unset(LYX_PYTHON_EXECUTABLE CACHE)
 756 unset(PYTHON_VERSION_MAJOR)
 757 unset(PYTHON_VERSION_MINOR)
 758 unset(PYTHON_VERSION_STRING)
 759 find_package(PythonInterp 3.3 QUIET)
 760 if(NOT PYTHONINTERP_FOUND)
 761   unset(PYTHON_EXECUTABLE CACHE)
 762   find_package(PythonInterp 2.0 REQUIRED)
 763   if(NOT PYTHON_VERSION_STRING VERSION_LESS 2.8)
 764     message(FATAL_ERROR "Python interpreter found, but is not suitable")
 765   endif()
 766 endif()
 767
 768 set(LYX_PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 769
 770 if(LYX_NLS)
 771         find_package(LyXGettext)
 772         if(LYX_PYTHON_EXECUTABLE AND GETTEXT_FOUND)
 773                 add_subdirectory(po "${TOP_BINARY_DIR}/po")
 774         else()
 775                 # Install only supplied .gmo-files
 776                 file(GLOB _gmofiles RELATIVE "${TOP_SRC_DIR}/po" "${TOP_SRC_DIR}/po/*.gmo")
 777                 message(STATUS "Installing provided .gmo-files only")
 778                 foreach( _gmo ${_gmofiles})
 779                         string(REGEX REPLACE "\\.gmo$" "" _lang ${_gmo})
 780                         install(FILES "${TOP_SRC_DIR}/po/${_gmo}" DESTINATION ${LYX_LOCALEDIR}/${_lang}/LC_MESSAGES RENAME ${PACKAGE}.mo)
 781                 endforeach()
 782         endif()
 783 endif()
 784
 785 if(LYX_EXTERNAL_ICONV)
 786   find_package(ICONV REQUIRED)
 787 else()
 788   add_subdirectory(3rdparty/libiconv)
 789   set(HAVE_ICONV_CONST 1)
 790 endif()
 791
 792 if(LYX_EXTERNAL_Z)
 793   find_package(ZLIB REQUIRED)
 794 else()
 795   add_subdirectory(3rdparty/zlib)
 796 endif()
 797
 798 if(LYX_USE_STD_REGEX)
 799   # Set only include path.
 800   # Use internal boost, which is known to exist
 801   # we don't need any libraries
 802   set(Lyx_Boost_Libraries)
 803   add_definitions(-DBOOST_USER_CONFIG=<config.h>)
 804   include_directories(${TOP_SRC_DIR}/3rdparty/boost)
 805 else()
 806   # Using boost-regex
 807   if(LYX_EXTERNAL_BOOST)
 808     message(STATUS "Searching for external boost")
 809     find_package(Boost COMPONENTS regex)
 810     if(Boost_FOUND)
 811       message(STATUS "Boost found")
 812       message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 813       set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 814       if (LYX_STDLIB_DEBUG)
 815         # Comment from  Jean-Marc Lasgouttes:
 816         # In general, system boost libraries are incompatible with
 817         # the use of stdlib-debug in libstdc++. See ticket #9736 for
 818         # details.
 819         message(WARNING "Compiling LyX with stdlib-debug and system boost libraries may lead to crashes. Consider using '-DLYX_STDLIB_DEBUG=OFF' or using '-DLYX_EXTERNAL_BOOST=OFF'")
 820       endif()
 821     else()
 822       message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 823     endif()
 824   else()
 825     # Using included boost
 826     set(Lyx_Boost_Libraries boost_regex)
 827     add_definitions(-DBOOST_USER_CONFIG=<config.h>)
 828     include_directories(${TOP_SRC_DIR}/3rdparty/boost)
 829     add_subdirectory(3rdparty/boost "${TOP_BINARY_DIR}/3rdparty/boost")
 830   endif()
 831 endif()
 832
 833 if(WIN32)
 834         if(LYX_CONSOLE)
 835                 set(LYX_QTMAIN_LIBRARY)
 836         else()
 837                 set(WIN32_CONSOLE WIN32)
 838         endif()
 839         if(MSVC)
 840                 # -DPSAPI_VERSION=1 is needed to run on vista (bug 10186)
 841                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX -DPSAPI_VERSION=1)
 842                 # disable checked iterators for msvc release builds to get maximum speed
 843                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 844         else()
 845                 # -DPSAPI_VERSION=1 is not needed for mingw, since the mingw psapi.h
 846                 # does not use it and always declares the vista compatible API.
 847                 # If this ever changes then -DPSAPI_VERSION might be needed here as well.
 848                 add_definitions(-DWINVER=0x0500)
 849         endif()
 850 endif()
 851
 852 # Compute qt-version from ${QTVERSION}
 853
 854 message(STATUS "")
 855 foreach(_v PACKAGE PACKAGE_VERSION
 856         PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 857         LYX_ABS_TOP_SRCDIR
 858         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 859         if(NOT DEFINED ${_v})
 860                 message(FATAL_ERROR "${_v} not defined")
 861         endif()
 862         string(SUBSTRING "${_v}                            " 0 28 _v1)
 863         message(STATUS "----- ${_v1}: ${${_v}}")
 864 endforeach(_v)
 865 message(STATUS "")
 866
 867
 868 if(LYX_PCH)
 869         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 870         # Not sure if it works for all non-msvc compilers
 871         include(PCHSupport_26)
 872         configure_file(${TOP_CMAKE_PATH}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
 873         configure_file(${TOP_CMAKE_PATH}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 874         add_definitions(-DLYX_ENABLE_PCH)
 875
 876         if(MSVC)
 877                 macro(lyx_add_msvc_pch name_)
 878                         set_source_files_properties(${${name_}_sources} PROPERTIES
 879                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 880                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
 881                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 882                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
 883                                 ${TOP_BINARY_DIR}/pcheaders.h)
 884                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 885                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 886                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 887                 endmacro(lyx_add_msvc_pch)
 888                 macro(lyx_add_gcc_pch name_)
 889                 endmacro()
 890         else()
 891                 macro(lyx_add_msvc_pch name_)
 892                 endmacro()
 893                 macro(lyx_add_gcc_pch name_)
 894                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT)
 895                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
 896                 endmacro()
 897         endif()
 898 else()
 899         macro(lyx_add_msvc_pch)
 900         endmacro(lyx_add_msvc_pch)
 901         macro(lyx_add_gcc_pch name_)
 902         endmacro()
 903 endif()
 904
 905
 906 if(MSVC)
 907
 908         if(LYX_VLD)
 909                 set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/development/Win32/vld)
 910                 add_subdirectory(${vld_path}/cmake)
 911                 include(${vld_path}/cmake/vld.cmake) # forced include
 912                 set(vld_dll vld)
 913         endif()
 914
 915         if(LYX_WALL)
 916                 # Use the highest warning level
 917                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 918
 919                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 920                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 921                 else()
 922                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 923                 endif()
 924
 925                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 926                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 927                 else()
 928                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 929                 endif()
 930
 931                 # add here warnings which should produce an error /weXXXX
 932                 set(MSVC_W_ERROR   "/we4101 /we4189")
 933                 # add here warnings which should be disabled /wdXXXX
 934                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 935
 936                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 937                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 938                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 939
 940         else()
 941                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 942
 943                 # add here warnings which should produce an error /weXXXX
 944                 set(MSVC_W_ERROR   "/we4101 /we4189")
 945                 # add here warnings which should be disabled /wdXXXX
 946                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 947
 948                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 949                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 950                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 951
 952         endif()
 953
 954         if (NOT Qt5Core_FOUND)
 955                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 956                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 957                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 958         endif()
 959
 960         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 961         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 962         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 963         message(STATUS "")
 964 endif()
 965
 966
 967 if(LYX_DEBUG_GLIBC)
 968         set(_GLIBCXX_DEBUG ON)
 969 endif()
 970
 971 if(LYX_DEBUG_GLIBC_PEDANTIC)
 972         set(_GLIBCXX_DEBUG_PEDANTIC ON)
 973 endif()
 974
 975 # Xcode compiler
 976 if (CMAKE_GENERATOR MATCHES Xcode)
 977         if (XCODE_VERSION VERSION_LESS "5.0")
 978                 # Automatically select the Xcode compiler if not set
 979                 if (NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 980                         # XCode >= 3.1 has gcc 4.2 (up to actual Xcode)
 981                         if (XCODE_VERSION VERSION_GREATER "3.1")
 982                                 SET(CMAKE_XCODE_ATTRIBUTE_GCC_VERSION "com.apple.compilers.llvmgcc42")
 983                         ENDIF(XCODE_VERSION VERSION_GREATER "3.1")
 984                 ENDIF(NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 985                 # Print the selected compiler version
 986         MESSAGE(STATUS "---- Using XCode compiler CMAKE_XCODE_ATTRIBUTE_GCC_VERSION=${CMAKE_XCODE_ATTRIBUTE_GCC_VERSION}")
 987         ENDIF(XCODE_VERSION VERSION_LESS "5.0")
 988 ENDIF(CMAKE_GENERATOR MATCHES Xcode)
 989
 990 if (WIN32 AND Qt5Core_FOUND)
 991         set(Z_PREFIX 1)
 992 endif()
 993
 994 # compiler tests, config.h generation LYX_CONFIGURE_CHECKS
 995 include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
 996 configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
 997
 998 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
 999
1000 if(QTVERSION MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+).*")
1001         MATH(EXPR QT4_VERSION "(${CMAKE_MATCH_1}<<16)|(${CMAKE_MATCH_2}<<8)|${CMAKE_MATCH_3}")
1002 endif()
1003
1004 if (NOT HAVE_REGEX)
1005         set(LYX_USE_STD_REGEX 0)
1006 endif()
1007
1008
1009 set (cmd ${CMAKE_CTEST_COMMAND})
1010 if (MSVC)
1011         set (cmd ${cmd} -C ${CMAKE_CFG_INTDIR})
1012 else ()
1013         set (cmd ${cmd} -C ${CMAKE_BUILD_TYPE})
1014 endif ()
1015 add_custom_target (lyx_run_tests COMMAND ${cmd})
1016 set_target_properties(lyx_run_tests PROPERTIES FOLDER "tests")
1017
1018 if(LYX_ASAN)
1019     set(LYX_CXX_FLAGS "-fsanitize=address -fno-omit-frame-pointer -g")
1020     message(STATUS)
1021     message(STATUS "Address sanitizer enabled. Usage:")
1022     message(STATUS "    wget https://llvm.org/svn/llvm-project/compiler-rt/trunk/lib/asan/scripts/asan_symbolize.py")
1023     message(STATUS "    chmod  +x ./asan_symbolize.py")
1024     message(STATUS "    ./bin/lyx2.2 2>&1 | ./asan_symbolize.py  | c++filt ")
1025     message(STATUS)
1026 endif()
1027
1028 if(LYX_INSTALL)
1029         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
1030                 message(STATUS "Python required to create doc!")
1031         else()
1032                 if(UNIX)
1033                         add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
1034                 endif()
1035                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
1036         endif()
1037 endif()
1038 include(../Install)
1039
1040 add_subdirectory(src "${TOP_BINARY_DIR}/src")
1041 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
1042 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
1043 add_subdirectory(lib/examples "${TOP_BINARY_DIR}/lib/examples")
1044 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
1045 add_subdirectory(development/autotests "${TOP_BINARY_DIR}/autotests")
1046 if(LYX_ENABLE_URLTESTS)
1047         add_subdirectory(development/checkurls "${TOP_BINARY_DIR}/checkurls")
1048 endif()
1049
1050 message(STATUS)
1051 message(STATUS "Build params, switch LYX_* options by -DLYX_*=ON or OFF, LYX_* combos by -DLYX_*=value:")
1052 message(STATUS)
1053
1054 LYX_OPTION_LIST_ALL(used)
1055
1056
1057 if(LYX_NLS)
1058         message(STATUS)
1059         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
1060         message(STATUS)
1061         message(STATUS "  * iconv")
1062         message(STATUS "     - include: ${ICONV_INCLUDE_DIR}")
1063         message(STATUS "     - library: ${ICONV_LIBRARY}")
1064         message(STATUS "  * zlib")
1065         message(STATUS "     - include: ${ZLIB_INCLUDE_DIR}")
1066         message(STATUS "     - library: ${ZLIB_LIBRARY}")
1067         message(STATUS)
1068 endif()
1069
1070 # Apple has builtin native spell checker,
1071 # no need to warn for missing Aspell, Hunspell or Enchant
1072 if(NOT Spelling_FOUND AND NOT APPLE)
1073   if(LYX_REQUIRE_SPELLCHECK)
1074     set(_mode "FATAL_ERROR")
1075   else()
1076     set(_mode "STATUS")
1077   endif()
1078   message(${_mode} "No spellcheck libraries found. LyX will be unable use spellchecking")
1079 endif()
1080
1081 include("${TOP_CMAKE_PATH}/LyxPackaging.cmake")
1082
1083 if(ENABLE_DIST)
1084   # Use git to create the source package
1085   # git archive --format=tgz --output=/home/kornel/x.tar.gz master
1086   if(UNIX)
1087     set(DIST_FORMAT tgz)
1088   else()
1089     set(DIST_FORMAT zip)
1090   endif()
1091   set(DIST_NAME ${CMAKE_PROJECT_NAME}-${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}-${CMAKE_SYSTEM_NAME}.${DIST_FORMAT})
1092
1093   add_custom_command(
1094     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME}
1095     COMMAND  ${LYX_GITVERSION} archive --format=${DIST_FORMAT} --output=${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME} master
1096     WORKING_DIRECTORY ${TOP_SRC_DIR})
1097   add_custom_target(git-archive DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME})
1098 endif()
1099
1100 # Last directory to be included so that the fixup code (OS X)
1101 # can be run last
1102 add_subdirectory(development/cmake/post_install)
1103
1104 message(STATUS)