CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 2.6.4)
   8
   9 set(LYX_PROJECT LyX)
  10
  11 enable_testing()
  12
  13 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README REALPATH) # Resolve symlinks
  14 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  15 message(STATUS "TOP_SRC_DIR = ${TOP_SRC_DIR}")
  16
  17 set(LYX_CMAKE_DIR "development/cmake")
  18 set(TOP_CMAKE_PATH "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}")
  19 set(TOP_MODULE_PATH "${TOP_CMAKE_PATH}/modules")
  20 set(TOP_SCRIPT_PATH "${TOP_CMAKE_PATH}/scripts")
  21
  22 set(CMAKE_MODULE_PATH "${TOP_MODULE_PATH}")
  23
  24 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  25
  26 message(STATUS)
  27 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  28         message(STATUS "Building in-source")
  29         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  30 else()
  31         message(STATUS "Building out-of-source")
  32         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  33 endif()
  34
  35 # This directory should be used if some test uses lyx-executable
  36 set(LYX_TESTS_USERDIR "${TOP_BINARY_DIR}/Testing/.lyx")
  37 file(MAKE_DIRECTORY "${LYX_TESTS_USERDIR}")
  38
  39 if(COMMAND cmake_policy)
  40         cmake_policy(SET CMP0003 OLD)
  41         cmake_policy(SET CMP0005 OLD)
  42         # Installing MACOSX_BUNDLE targets requires a BUNDLE DESTINATION
  43         cmake_policy(SET CMP0006 NEW)
  44         if(POLICY CMP0020)
  45                 cmake_policy(SET CMP0020 OLD)
  46         endif()
  47         if(POLICY CMP0028)
  48                 cmake_policy(SET CMP0028 OLD)
  49         endif()
  50         if(POLICY CMP0043)
  51                 # COMPILE_DEFINITIONS are not used yet. Enable new behavior.
  52                 cmake_policy(SET CMP0043 NEW)
  53         endif()
  54 endif()
  55
  56 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  57
  58 # Supress regeneration
  59 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  60
  61 if(LYX_XMINGW)
  62     set(CMAKE_SYSTEM_NAME Windows)
  63     set(TOOLNAME ${LYX_XMINGW})
  64     set(TOOLCHAIN "${TOOLNAME}-")
  65     set(CMAKE_C_COMPILER   "${TOOLCHAIN}gcc"     CACHE PATH "Mingw C compiler" FORCE)
  66     set(CMAKE_CXX_COMPILER "${TOOLCHAIN}g++"     CACHE PATH "Mingw C++ compiler" FORCE)
  67     set(CMAKE_RC_COMPILER  "${TOOLCHAIN}windres" CACHE PATH "Mingw rc compiler" FORCE)
  68
  69     set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM BOTH)
  70     set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY)
  71     set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY)
  72 endif()
  73
  74 if(NOT help AND NOT HELP)
  75   # 'project' triggers the searching for a compiler
  76   project(${LYX_PROJECT})
  77   if (CMAKE_COMPILER_IS_GNUCXX)
  78     if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS "4.0")
  79       message(STATUS "Gnu CXX compiler version = ${CMAKE_CXX_COMPILER_VERSION}")
  80       message(STATUS "is too old, should be >= 4.0")
  81       message(FATAL_ERROR "Exiting")
  82     endif()
  83   endif()
  84 endif()
  85
  86 if(UNIX)
  87         set(ARCH_TRIPLET )
  88         FIND_PROGRAM(DPKG_ARCHITECTURE_EXECUTABLE dpkg-architecture)
  89         if(DPKG_ARCHITECTURE_EXECUTABLE)
  90                 EXECUTE_PROCESS(COMMAND ${DPKG_ARCHITECTURE_EXECUTABLE} -qDEB_HOST_MULTIARCH
  91                                 OUTPUT_VARIABLE ARCH_TRIPLET
  92                                 ERROR_VARIABLE ERROR_ARCH_TRIPLET
  93                                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  94         endif()
  95 endif()
  96 if(ARCH_TRIPLET)
  97         set(SYSTEM_LIB_DIRS /usr/lib /usr/lib/${ARCH_TRIPLET} /usr/local/lib)
  98 else()
  99         set(SYSTEM_LIB_DIRS /usr/lib /usr/local/lib)
 100 endif()
 101
 102 include(LyXMacros)
 103 include(LyXDestinations)
 104
 105 # Usage LYX_OPTION
 106 # 1. parameter: option name without prefix 'LYX_'
 107 # 2. parameter: description
 108 # 3. parameter: default value, ON or OFF
 109 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
 110
 111 # Usage LYX_COMBO
 112 # 1. parameter: name without prefix 'LYX_'
 113 # 2. parameter: description
 114 # 3. parameter: default value
 115 # 4-n parameter: possible other string values
 116
 117 LYX_OPTION_INIT()
 118
 119 # Options for all compilers/systems
 120 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
 121 LYX_OPTION(LOCALVERSIONING  "Add version info to created package name (only used if LYX_CPACK option set)" OFF ALL)
 122 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
 123 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
 124 LYX_OPTION(REQUIRE_SPELLCHECK "Abort if no spellchecker available" OFF ALL)
 125 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
 126 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
 127 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
 128 LYX_OPTION(DEVEL_VERSION    "Build developer version" OFF ALL)
 129 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" OFF ALL)
 130 LYX_OPTION(DEBUG            "Enforce debug build"  OFF ALL)
 131 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
 132 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
 133 LYX_STRING(SUFFIX_VALUE     "Use this string as suffix" "")
 134 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
 135 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
 136 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
 137 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
 138 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
 139 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
 140 LYX_OPTION(ENABLE_URLTESTS  "Enable for URL tests" OFF ALL)
 141 LYX_OPTION(ENABLE_EXPORT_TESTS "Enable for export tests" OFF ALL)
 142 LYX_OPTION(ASAN             "Use address sanitizer" OFF ALL)
 143 LYX_COMBO(USE_QT            "Use Qt version as frontend" QT4 QT5)
 144 LYX_OPTION(3RDPARTY_BUILD   "Build 3rdparty libs" OFF ALL)
 145 LYX_COMBO(ENABLE_CXX11          "Build with options for c++11-mode" AUTO ON OFF)
 146
 147 # GCC specific
 148 LYX_OPTION(PROFILE              "Build profile version" OFF GCC)
 149 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" OFF GCC)
 150 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
 151 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
 152 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++ pedantic debug mode" OFF GCC)
 153 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" OFF GCC)
 154 LYX_OPTION(PROFILE              "Build with options for gprof" OFF GCC)
 155
 156 # MSVC specific
 157 LYX_OPTION(CONSOLE               "Show console on Windows, enforce with =FORCE" ON MSVC)
 158 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
 159 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
 160 LYX_OPTION(CONFIGURE_CHECKS      "Also run configure checks for MSVC" OFF MSVC)
 161 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
 162
 163 # APPLE specific
 164 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
 165 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
 166
 167
 168 if(help OR HELP)
 169         message(STATUS)
 170         message(STATUS "Available options: (dis/enable with -DLYX_*=OFF/ON)")
 171         message(STATUS)
 172         LYX_OPTION_LIST_ALL(help)
 173         message(STATUS)
 174         RETURN()
 175 endif()
 176
 177 # Check option dependencies
 178
 179 if(LYX_DMG)
 180         set(LYX_BUNDLE ON)
 181         set(LYX_CPACK ON)
 182 endif()
 183
 184 if(LYX_CPACK)
 185         set(LYX_INSTALL ON)
 186 endif()
 187
 188 if(LYX_INSTALL)
 189         set(LYX_NLS ON)
 190         if(WIN32 AND NOT MINGW)
 191                 set(LYX_HUNSPELL ON)
 192         endif()
 193         if(LYX_CONSOLE MATCHES "FORCE")
 194                 set(LYX_CONSOLE ON)
 195         else()
 196                 set(LYX_CONSOLE OFF)
 197         endif()
 198         set(LYX_PACKAGE_SUFFIX ON)
 199         if(NOT LYX_DEBUG)
 200                 set(LYX_RELEASE ON)
 201         endif()
 202         set(LYX_PROFILE OFF)
 203 endif()
 204
 205
 206 if(LYX_MERGE_FILES)
 207         set(LYX_PCH OFF)
 208 else()
 209         set(LYX_MERGE_REBUILD OFF)
 210 endif()
 211
 212
 213 if(LYX_DEPENDENCIES_DOWNLOAD)
 214         message(STATUS)
 215     if(MSVC12)
 216         set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2013-deps)
 217         set(deps_files lyx-windows-deps-msvc2013.zip)
 218         set(deps_server http://ftp.lyx.de/LyX-Windows-Deps)
 219         set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2013)
 220     else()
 221         set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 222             set(deps_files lyx20-deps-msvc2010-x86.zip)
 223             set(deps_server http://downloads.sourceforge.net/project/lyx/Win_installers/Dependencies)
 224         set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/deps20)
 225     endif()
 226     message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 227         foreach(it ${deps_files})
 228                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 229                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 230                 if(NOT already_downloaded)
 231                         message(STATUS "Downloading ${it} ...")
 232                         file(DOWNLOAD ${deps_server}/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS STATUS status LOG log)
 233                         list(GET status 0 status_code)
 234                         list(GET status 1 status_string)
 235                         if(NOT status_code EQUAL 0)
 236                                 file(REMOVE ${LYX_DEPENDENCIES_DIR}/${it})
 237                                 message(FATAL_ERROR "error: downloading '${it}' failed. status_code: ${status_code}, status_string: ${status_string}. \nLog: ${log} ")
 238                         endif()
 239                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 240                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 241                 endif()
 242         endforeach()
 243 endif()
 244
 245
 246
 247 message(STATUS)
 248
 249 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 250 if(WIN32)
 251         set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 252 else()
 253         set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 254 endif()
 255
 256
 257 if(LYX_ENABLE_CXX11 MATCHES "AUTO")
 258   # Set to some meaningful default
 259   find_package(CXX11Compiler)
 260   if(NOT CXX11COMPILER_FOUND)
 261     set(LYX_ENABLE_CXX11 OFF CACHE TYPE STRING FORCE)
 262   else()
 263     if(CMAKE_CXX_COMPILER_ID MATCHES "GNU")
 264       execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION OUTPUT_STRIP_TRAILING_WHITESPACE)
 265         set(LYX_ENABLE_CXX11 ON CACHE TYPE STRING FORCE)
 266     else()
 267       # Not a gnu compiler
 268       if(CMAKE_CXX_COMPILER_ID MATCHES "^[cC]lang$")
 269         set(LYX_ENABLE_CXX11 ON CACHE TYPE STRING FORCE)
 270       else()
 271         set(LYX_ENABLE_CXX11 OFF CACHE TYPE STRING FORCE)
 272       endif()
 273     endif()
 274   endif()
 275 endif()
 276 set(LYX_GCC11_MODE)
 277 if(UNIX OR MINGW)
 278         execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION OUTPUT_STRIP_TRAILING_WHITESPACE)
 279         message(STATUS "Using GCC version ${GCC_VERSION}")
 280         if(GCC_VERSION VERSION_LESS 4.9)
 281                 if(GCC_VERSION VERSION_LESS 4.3)
 282                         message(FATAL_ERROR "gcc >= 4.3 is required.")
 283                 endif()
 284                 # <regex> in gcc is unusable in versions less than 4.9.0
 285                 # see https://gcc.gnu.org/bugzilla/show_bug.cgi?id=53631
 286                 set(LYX_USE_STD_REGEX 0)
 287         else()
 288                 if (LYX_ENABLE_CXX11)
 289                         set(LYX_USE_STD_REGEX 1)
 290                 endif()
 291         endif()
 292         if (LYX_ENABLE_CXX11)
 293                 find_package(CXX11Compiler)
 294                 if(NOT CXX11COMPILER_FOUND)
 295                         message(FATAL_ERROR "A C++11 compatible compiler is required.")
 296                 endif()
 297                 set(LYX_GCC11_MODE "${CXX11_FLAG}")
 298         endif()
 299 else()
 300         set(LYX_USE_STD_REGEX 0)
 301 #       if(MSVC10)
 302 #               set(LYX_USE_STD_REGEX 1) #TODO should we use it in ECMAScript mode?
 303 #       endif()
 304 endif()
 305
 306
 307 set(VERSION_INFO "CMake Build")
 308
 309 # Try to get some informations from configure.ac
 310
 311 include(LyXPaths)
 312 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 313
 314 if(WIN32)
 315         set(CMAKE_PREFIX_PATH Specify-path-to-Qt CACHE PATH "Used Qt version")
 316         if(MSVC)
 317                 set(LYX_3RDPARTY_BUILD ON CACHE BOOL "Build 3rdparty libraries" FORCE)
 318         endif()
 319         set(USE_WINDOWS_PACKAGING ON)
 320 elseif(APPLE)
 321         set(USE_MACOSX_PACKAGING ON)
 322 else()
 323         set(USE_POSIX_PACKAGING ON)
 324 endif()
 325
 326 macro(setstripped _varname)
 327         if(${ARGC} GREATER 1)
 328                 string(STRIP "${ARGV1}" _v)
 329                 if(USE_POSIX_PACKAGING)
 330                         string(TOLOWER ${_v} ${_varname})
 331                 else()
 332                         set(${_varname} ${_v})
 333                 endif()
 334         else()
 335                 set(${_varname})
 336         endif()
 337 endmacro(setstripped)
 338
 339 foreach(_c_l ${_config_lines} )
 340         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 341                 setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 342                 setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 343                 setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 344                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\)\(\\.\([0-9]+\)\)?.*$")
 345                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 346                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 347                         set(LYX_PATCH_VERSION ${CMAKE_MATCH_4})
 348                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 349                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 350                         if ("${LYX_SUFFIX_VALUE}" MATCHES "")
 351                           set(LYX_INSTALL_SUFFIX "${LYX_MAJOR_VERSION}.${LYX_MINOR_VERSION}")
 352                         else()
 353                           set(LYX_INSTALL_SUFFIX "${LYX_SUFFIX_VALUE}")
 354                         endif()
 355                 endif()
 356         endif()
 357         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 358                 set(LYX_DATE "${CMAKE_MATCH_1}")
 359         endif()
 360 endforeach(_c_l)
 361
 362 FIND_PROGRAM(LYX_GITVERSION git)
 363 #message(STATUS "gitversion = ${LYX_GITVERSION}")
 364 set(LYX_REVISION_VERSION ${LYX_PATCH_VERSION})
 365 if(LYX_GITVERSION)
 366   if (LYX_LOCALVERSIONING)
 367     # Find the revision number and for later use
 368     EXECUTE_PROCESS(COMMAND ${LYX_GITVERSION} describe --match 2.0.0 HEAD
 369       WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE LYX_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 370     if (LYX_PACKAGE_RELEASE MATCHES "^2\\.0\\.0\\-\([0-9]+\)\\-.*$")
 371       # We will add offset of 40000 to get appropriate value to
 372       # previous svn.
 373       # We use this value than also to set the package-patch-value
 374       MATH(EXPR tmp_REVISION_VERSION "(${CMAKE_MATCH_1}+40000)")
 375       set(LYX_REVISION_VERSION "${LYX_PATCH_VERSION}-${tmp_REVISION_VERSION}git")
 376       set(ENABLE_DIST ON)
 377     endif()
 378   endif()
 379 endif()
 380
 381 # Set the programs (lyx, tex2lyx, etc.) suffix
 382 # When building an OS X bundle, we will append
 383 # the suffix only to the bundle, not to the programs
 384 set(PROGRAM_SUFFIX "")
 385 if(LYX_PROGRAM_SUFFIX AND NOT (APPLE AND LYX_BUNDLE))
 386         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 387 endif()
 388 set(_lyx "${PACKAGE_BASE}${PROGRAM_SUFFIX}")
 389 set(_tex2lyx tex2lyx${PROGRAM_SUFFIX})
 390
 391 add_custom_target(lyx_version ALL
 392   COMMAND ${CMAKE_COMMAND} -DTOP_SRC_DIR=${TOP_SRC_DIR} -DTOP_CMAKE_PATH=${TOP_CMAKE_PATH} -DTOP_BINARY_DIR=${TOP_BINARY_DIR} -DLYX_DATE=${LYX_DATE} -P ${TOP_SCRIPT_PATH}/LyXGetVersion.cmake
 393   )
 394 set_target_properties(lyx_version PROPERTIES FOLDER "applications")
 395
 396 # Default paths for installed utilities (tex2lyx, lyxclient, etc.)
 397 set(LYX_UTILITIES_INSTALL_PATH bin)
 398
 399 if(LYX_BUNDLE)
 400         set(LYX_CPACK ON)
 401
 402         message(STATUS)
 403         message(STATUS "Bundle creation is enabled (experimental):")
 404         message(STATUS "    make")
 405         message(STATUS "    make install/strip")
 406         message(STATUS "    make package")
 407         if(APPLE)
 408                 set(MACOSX_BUNDLE TRUE)
 409                 # This sets the bundle + executable names
 410                 set(_lyx "${PACKAGE_BASE}${LYX_INSTALL_SUFFIX}")
 411                 # This sets the Info.plist executable name
 412                 set(osx_bundle_program_name ${_lyx})
 413                 # Bundle name
 414                 set(LYX_BUNDLE_NAME ${_lyx})
 415
 416                 # This will contain the list of files that need to be included
 417                 # in the bundle and their location within the bundle
 418                 set(OSX_BUNDLE_FILES "${TOP_SRC_DIR}/development/MacOSX/LyX.sdef;${TOP_SRC_DIR}/development/MacOSX/LyXapp.icns;${CMAKE_BINARY_DIR}/lyxrc.dist")
 419                 set(OSX_BUNDLE_DIRS "Resources;Resources;Resources")
 420
 421                 # Process Info.plist and lyxrc.dist
 422                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/Info.plist.in" "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 423                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/lyxrc.dist.in" "${CMAKE_CURRENT_BINARY_DIR}/lyxrc.dist")
 424
 425                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 426                 set(LYX_DATA_SUBDIR ${LYX_BUNDLE_NAME}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 427
 428                 # Variables used by CPack
 429                 set(CPACK_BUNDLE_NAME ${LYX_BUNDLE_NAME})
 430                 set(CPACK_BUNDLE_PLIST "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 431                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${LYX_BUNDLE_NAME}.app)
 432
 433                 # Set the install paths
 434                 set(LYX_UTILITIES_INSTALL_PATH ${LYX_BUNDLE_NAME}.app/Contents/MacOS)
 435                 if(NOT LYX_INSTALL_PREFIX)
 436                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 437                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 438                 endif()
 439                 # Change the owner so that the install can work
 440                 install(CODE "set(BU_CHMOD_BUNDLE_ITEMS 1)" COMPONENT Runtime)
 441         elseif(UNIX)
 442                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 443                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 444                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 445         elseif(WIN32)
 446                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 447         endif()
 448 endif()
 449
 450 if(LYX_INSTALL_PREFIX)
 451         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 452         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 453 endif()
 454 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 455
 456 string(REGEX REPLACE "/lyx${LYX_INSTALL_SUFFIX}$" "/share" SYSTEM_DATADIR ${CMAKE_INSTALL_PREFIX})
 457
 458 if(LYX_PACKAGE_SUFFIX)
 459         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 460 else()
 461         set(PACKAGE ${PACKAGE_BASE})
 462 endif()
 463
 464 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 465         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 466         if (UNIX)
 467                 # use the default "/usr/local"
 468                 # but respect the user-choice on the command-line
 469                 set(CMAKE_INSTALL_PREFIX "/usr/local" CACHE PATH "LyX default install prefix" FORCE)
 470         endif()
 471 endif()
 472 if(WIN32)
 473         set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 474 endif()
 475 if(IS_ABSOLUTE)
 476         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 477 else()
 478         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 479 endif()
 480
 481
 482
 483 if(NOT LYX_DATA_SUBDIR)
 484         if (WIN32)
 485                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 486         else()
 487                 set(LYX_DATA_SUBDIR "share/${_lyx}/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 488         endif()
 489 endif()
 490
 491 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 492 get_locale_destination(LYX_LOCALEDIR)
 493 set(LYX_ABS_INSTALLED_LOCALEDIR "${CMAKE_INSTALL_PREFIX}/${LYX_LOCALEDIR}")
 494 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 495
 496 if(LYX_BUNDLE AND APPLE)
 497         set(LYX_MAN_DIR "${LYX_DATA_SUBDIR}" CACHE STRING "Install location for man pages.")
 498 else()
 499         if(WIN32)
 500                 set(LYX_MAN_DIR "${CMAKE_BINARY_DIR}/usr/local/man" CACHE STRING "Install location for man pages.")
 501         elseif(UNIX)
 502                 set(LYX_MAN_DIR "${CMAKE_INSTALL_PREFIX}/share/man" CACHE STRING "Install location for man pages.")
 503         else()
 504                 set(LYX_MAN_DIR "${CMAKE_INSTALL_PREFIX}/man" CACHE STRING "Install location for man pages.")
 505         endif()
 506 endif()
 507 mark_as_advanced(LYX_MAN_DIR)
 508
 509 if(LYX_INSTALL AND WIN32)
 510         message(STATUS "Configuring NSIS files")
 511         configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 512         configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 513         configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 514         message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 515 endif()
 516
 517 if(NOT GROUP_CODE)
 518         #set(GROUP_CODE "The Golden Code")
 519         set(GROUP_CODE flat)
 520 endif()
 521
 522 # lyx's source files
 523 set(LYX_CPP_FILES [a-zA-Z]*.cpp)
 524 set(LYX_HPP_FILES [a-zA-Z]*.h)
 525 set(LYX_MOC_FILES moc_*.cpp)
 526
 527 include(ProjectSourceGroup)
 528
 529
 530 if(LYX_PROFILE AND NOT MSVC)
 531         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 532         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg")
 533         set(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS}  -pg")
 534 else()
 535         set(LYX_PROFILE OFF)
 536 endif()
 537
 538
 539 if(LYX_NO_OPTIMIZE)
 540         set(CMAKE_BUILD_TYPE None)
 541         set(LYX_DEBUG OFF)
 542         set(LYX_RELEASE OFF)
 543         set(LYX_PROFILE OFF)
 544 elseif(LYX_RELEASE)
 545         set(CMAKE_BUILD_TYPE Release)
 546         set(LYX_DEBUG OFF)
 547         set(LYX_PROFILE OFF)
 548 elseif(LYX_PROFILE)
 549         set(CMAKE_BUILD_TYPE Profile)
 550         set(LYX_DEBUG OFF)
 551 else()
 552         set(CMAKE_BUILD_TYPE Debug)
 553         set(LYX_DEBUG ON)
 554 endif()
 555
 556
 557 # When shared libs are supported enable this option
 558 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 559 if(LYX_SHARED_LIBRARIES)
 560         set(library_type SHARED)
 561 else()
 562         set(library_type STATIC)
 563 endif()
 564
 565 if(NOT MSVC)
 566         if(NOT LYX_QUIET)
 567                 set(CMAKE_VERBOSE_MAKEFILE ON)
 568         endif()
 569     set(LYX_CXX_FLAGS "-Wall -Wunused-parameter ${LYX_GCC11_MODE}")
 570         if(LYX_STDLIB_DEBUG)
 571                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 572         endif()
 573         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 574         set(CMAKE_CXX_FLAGS_DEBUG "${LYX_CXX_FLAGS} -fno-strict-aliasing -O0 -g3 -D_DEBUG" CACHE TYPE STRING FORCE)
 575         if(MINGW)
 576                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 577         else()
 578                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 579         endif()
 580 endif()
 581
 582 set(LYX_CXX_FLAGS_EXTRA "" CACHE STRING "Desired semicolon separated list of extra cxx compile flags, like '-Werror'")
 583 mark_as_advanced(LYX_CXX_FLAGS_EXTRA)
 584 if(LYX_CXX_FLAGS_EXTRA)
 585         foreach(_flag ${LYX_CXX_FLAGS_EXTRA})
 586                 add_definitions(${_flag})
 587         endforeach()
 588 endif()
 589
 590 if(LYX_XMINGW)
 591         list(APPEND CMAKE_FIND_ROOT_PATH ${GNUWIN32_DIR})
 592 endif()
 593
 594 set(QPA_XCB)
 595 if(LYX_USE_QT MATCHES "QT5")
 596         # set QPA_XCB if QT uses X11
 597         find_package(Qt5Core REQUIRED)
 598         if (Qt5Core_FOUND)
 599                 find_package(Qt5Widgets REQUIRED)
 600                 if(APPLE)
 601                         find_package(Qt5MacExtras REQUIRED)
 602                 endif()
 603                 find_package(Qt5X11Extras QUIET)
 604                 if(Qt5X11Extras_FOUND)
 605                   set(QPA_XCB 1)
 606                 endif()
 607                 find_package(Qt5WinExtras QUIET)
 608                 set(QTVERSION ${Qt5Core_VERSION})
 609                 macro (qt_use_modules)
 610                         qt5_use_modules(${ARGN})
 611                 endmacro()
 612                 macro (qt_add_resources)
 613                         qt5_add_resources(${ARGN})
 614                 endmacro()
 615                 macro (qt_wrap_uifiles)
 616                         qt5_wrap_ui(${ARGN})
 617                 endmacro()
 618                 message(STATUS "Found Qt-Version ${QTVERSION}")
 619                 if(WIN32)
 620                         set(LYX_QTMAIN_LIBRARY ${Qt5Core_QTMAIN_LIBRARIES})
 621                 endif()
 622         endif()
 623 elseif(LYX_USE_QT MATCHES "QT4")
 624         if(LYX_XMINGW)
 625                 set(QT_MINGW_DIR ${LYX_QT4} CACHE PATH "Qt for Mingw" FORCE)
 626                 list(APPEND CMAKE_FIND_ROOT_PATH ${QT_MINGW_DIR} ${GNUWIN32_DIR})
 627         endif()
 628         find_package(Qt4 "4.5.0" REQUIRED)
 629         macro (qt_use_modules)
 630         endmacro()
 631         macro (qt_add_resources)
 632                 qt4_add_resources(${ARGN})
 633         endmacro()
 634         macro (qt_wrap_uifiles)
 635                 qt4_wrap_ui(${ARGN})
 636         endmacro()
 637         if(WIN32)
 638                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARIES})
 639         endif()
 640 else()
 641   message(FATAL_ERROR "Unhandled value for LYX_USE_QT (${LYX_USE_QT})")
 642 endif()
 643
 644 find_package(Magic)
 645 if(Magic_FOUND)
 646         set(HAVE_MAGIC_H 1)
 647 endif()
 648
 649 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 650
 651 set(Spelling_FOUND OFF)
 652 set(Include_used_spellchecker)   # String will be inserted into config.h
 653
 654 if(LYX_3RDPARTY_BUILD)
 655     add_subdirectory(3rdparty/hunspell)
 656     add_definitions(-DHUNSPELL_STATIC)
 657     set(HUNSPELL_FOUND ON)
 658     message(STATUS "  * Hunspell:")
 659     message(STATUS "     - include: ${HUNSPELL_INCLUDE_DIR}")
 660     message(STATUS "     - library: ${HUNSPELL_LIBRARY}")
 661 endif()
 662
 663 foreach(_spell "ASPELL" "Enchant" "Hunspell")
 664   string(TOUPPER ${_spell} _upspell)
 665   if (NOT ${_upspell}_FOUND)
 666     find_package(${_spell})
 667   endif()
 668   if (${_upspell}_FOUND)
 669     include_directories(${${_upspell}_INCLUDE_DIR})
 670     set(Spelling_FOUND ON)
 671     message(STATUS "Building with USE_${_upspell}")
 672     set(Include_used_spellchecker "${Include_used_spellchecker}#define USE_${_upspell} 1\n")
 673   else()
 674     if(LYX_${_upspell})
 675       message(FATAL_ERROR "Required ${_spell} devel package not found")
 676     else()
 677       message(STATUS "${_upspell} not found, building without ${_spell} support")
 678     endif()
 679   endif()
 680 endforeach()
 681
 682 if(GNUWIN32_DIR)
 683         list(APPEND CMAKE_PROGRAM_PATH "${GNUWIN32_DIR}/Python" )
 684 endif()
 685
 686 find_package(PythonInterp 2.7 QUIET)
 687 if(PYTHONINTERP_FOUND)
 688         if(PYTHON_VERSION_STRING VERSION_GREATER 2.8)
 689         unset(PYTHONINTERP_FOUND)
 690         endif()
 691 endif()
 692
 693 if(NOT PYTHONINTERP_FOUND)
 694   unset(PYTHON_EXECUTABLE CACHE)
 695   unset(PYTHON_VERSION_MAJOR)
 696   unset(PYTHON_VERSION_MINOR)
 697   unset(PYTHON_VERSION_STRING)
 698   find_package(PythonInterp 3.3 REQUIRED)
 699 endif()
 700
 701 set(LYX_PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 702
 703 if(LYX_NLS)
 704         find_package(LyXGettext)
 705         if(LYX_PYTHON_EXECUTABLE AND GETTEXT_FOUND)
 706                 add_subdirectory(po "${TOP_BINARY_DIR}/po")
 707         else()
 708                 # Install only supplied .gmo-files
 709                 file(GLOB _gmofiles RELATIVE "${TOP_SRC_DIR}/po" "${TOP_SRC_DIR}/po/*.gmo")
 710                 message(STATUS "Installing provided .gmo-files only")
 711                 foreach( _gmo ${_gmofiles})
 712                         string(REGEX REPLACE "\\.gmo$" "" _lang ${_gmo})
 713                         install(FILES "${TOP_SRC_DIR}/po/${_gmo}" DESTINATION ${LYX_LOCALEDIR}/${_lang}/LC_MESSAGES RENAME ${PACKAGE}.mo)
 714                 endforeach()
 715         endif()
 716 endif()
 717
 718 if(UNIX)
 719     find_package(ICONV REQUIRED)
 720     find_package(ZLIB REQUIRED)
 721 else()
 722     if(LYX_3RDPARTY_BUILD)
 723         add_subdirectory(3rdparty/libiconv)
 724         set(HAVE_ICONV_CONST 1)
 725         add_subdirectory(3rdparty/zlib)
 726     endif()
 727 endif()
 728
 729 if(LYX_EXTERNAL_BOOST)
 730         message(STATUS "Searching for boost")
 731         if(LYX_USE_STD_REGEX)
 732                 find_package(Boost COMPONENTS signals)
 733         else()
 734                 find_package(Boost COMPONENTS signals regex)
 735         endif()
 736         if(Boost_FOUND)
 737                 message(STATUS "Boost found")
 738                 message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 739                 set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 740                 if (LYX_STDLIB_DEBUG)
 741                         # Comment from  Jean-Marc Lasgouttes:
 742                         # In general, system boost libraries are incompatible with
 743                         # the use of stdlib-debug in libstdc++. See ticket #9736 for
 744                         # details.
 745                         message(WARNING "Compiling LyX with stdlib-debug and system boost libraries may lead to crashes. Consider using '-DLYX_STDLIB_DEBUG=OFF' or using '-DLYX_EXTERNAL_BOOST=OFF'")
 746                 endif()
 747         else()
 748                 message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 749         endif()
 750 else()
 751         if(LYX_USE_STD_REGEX)
 752                 set(Lyx_Boost_Libraries boost_signals)
 753         else()
 754                 set(Lyx_Boost_Libraries boost_signals boost_regex)
 755         endif()
 756         add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 757         add_definitions(-DBOOST_SIGNALS_NO_DEPRECATION_WARNING=1)
 758         include_directories(${TOP_SRC_DIR}/3rdparty/boost)
 759         add_subdirectory(3rdparty/boost "${TOP_BINARY_DIR}/3rdparty/boost")
 760 endif()
 761
 762
 763
 764
 765 if(WIN32)
 766         if(LYX_CONSOLE)
 767                 set(LYX_QTMAIN_LIBRARY)
 768         else()
 769                 set(WIN32_CONSOLE WIN32)
 770         endif()
 771         if(MSVC)
 772                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 773                 # disable checked iterators for msvc release builds to get maximum speed
 774                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 775         else()
 776                 add_definitions(-DWINVER=0x0500)
 777         endif()
 778 endif()
 779
 780 # Compute qt4-version from ${QTVERSION}
 781
 782 message(STATUS "")
 783 foreach(_v PACKAGE PACKAGE_VERSION
 784         PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 785         LYX_ABS_TOP_SRCDIR
 786         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 787         if(NOT DEFINED ${_v})
 788                 message(FATAL_ERROR "${_v} not defined")
 789         endif()
 790         string(SUBSTRING "${_v}                            " 0 28 _v1)
 791         message(STATUS "----- ${_v1}: ${${_v}}")
 792 endforeach(_v)
 793 message(STATUS "")
 794
 795
 796 if(LYX_PCH)
 797         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 798         # Not sure if it works for all non-msvc compilers
 799         include(PCHSupport_26)
 800         configure_file(${TOP_CMAKE_PATH}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
 801         configure_file(${TOP_CMAKE_PATH}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 802         add_definitions(-DLYX_ENABLE_PCH)
 803
 804         if(MSVC)
 805                 macro(lyx_add_msvc_pch name_)
 806                         set_source_files_properties(${${name_}_sources} PROPERTIES
 807                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 808                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
 809                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 810                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
 811                                 ${TOP_BINARY_DIR}/pcheaders.h)
 812                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 813                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 814                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 815                 endmacro(lyx_add_msvc_pch)
 816                 macro(lyx_add_gcc_pch name_)
 817                 endmacro()
 818         else()
 819                 macro(lyx_add_msvc_pch name_)
 820                 endmacro()
 821                 macro(lyx_add_gcc_pch name_)
 822                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT)
 823                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
 824                 endmacro()
 825         endif()
 826 else()
 827         macro(lyx_add_msvc_pch)
 828         endmacro(lyx_add_msvc_pch)
 829         macro(lyx_add_gcc_pch name_)
 830         endmacro()
 831 endif()
 832
 833
 834 if(MSVC)
 835
 836         if(LYX_VLD)
 837                 set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/development/Win32/vld)
 838                 add_subdirectory(${vld_path}/cmake)
 839                 include(${vld_path}/cmake/vld.cmake) # forced include
 840                 set(vld_dll vld)
 841         endif()
 842
 843         if(LYX_WALL)
 844                 # Use the highest warning level
 845                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 846
 847                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 848                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 849                 else()
 850                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 851                 endif()
 852
 853                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 854                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 855                 else()
 856                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 857                 endif()
 858
 859                 # add here warnings which should produce an error /weXXXX
 860                 set(MSVC_W_ERROR   "/we4101 /we4189")
 861                 # add here warnings which should be disabled /wdXXXX
 862                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 863
 864                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 865                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 866                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 867
 868         else()
 869                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 870
 871                 # add here warnings which should produce an error /weXXXX
 872                 set(MSVC_W_ERROR   "/we4101 /we4189")
 873                 # add here warnings which should be disabled /wdXXXX
 874                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 875
 876                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 877                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 878                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 879
 880         endif()
 881
 882         if (NOT Qt5Core_FOUND)
 883                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 884                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 885                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 886         endif()
 887
 888         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 889         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 890         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 891         message(STATUS "")
 892 endif()
 893
 894
 895 if(LYX_DEBUG_GLIBC)
 896         set(_GLIBCXX_DEBUG ON)
 897 endif()
 898
 899 if(LYX_DEBUG_GLIBC_PEDANTIC)
 900         set(_GLIBCXX_DEBUG_PEDANTIC ON)
 901 endif()
 902
 903 # Xcode compiler
 904 if (CMAKE_GENERATOR MATCHES Xcode)
 905         if (XCODE_VERSION VERSION_LESS "5.0")
 906                 # Automatically select the Xcode compiler if not set
 907                 if (NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 908                         # XCode >= 3.1 has gcc 4.2 (up to actual Xcode)
 909                         if (XCODE_VERSION VERSION_GREATER "3.1")
 910                                 SET(CMAKE_XCODE_ATTRIBUTE_GCC_VERSION "com.apple.compilers.llvmgcc42")
 911                         ENDIF(XCODE_VERSION VERSION_GREATER "3.1")
 912                 ENDIF(NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 913                 # Print the selected compiler version
 914         MESSAGE(STATUS "---- Using XCode compiler CMAKE_XCODE_ATTRIBUTE_GCC_VERSION=${CMAKE_XCODE_ATTRIBUTE_GCC_VERSION}")
 915         ENDIF(XCODE_VERSION VERSION_LESS "5.0")
 916 ENDIF(CMAKE_GENERATOR MATCHES Xcode)
 917
 918 if (WIN32 AND Qt5Core_FOUND)
 919         set(Z_PREFIX 1)
 920 endif()
 921
 922 # compiler tests, config.h generation
 923 if(MSVC AND NOT LYX_CONFIGURE_CHECKS)
 924         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.msvc ${TOP_BINARY_DIR}/configCompiler.h)
 925 else()
 926         include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
 927         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
 928 endif()
 929
 930 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
 931
 932 if(QTVERSION MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+).*")
 933         MATH(EXPR QT4_VERSION "(${CMAKE_MATCH_1}<<16)|(${CMAKE_MATCH_2}<<8)|${CMAKE_MATCH_3}")
 934 endif()
 935
 936 if (NOT HAVE_REGEX)
 937         set(LYX_USE_STD_REGEX 0)
 938 endif()
 939
 940
 941 set (cmd ${CMAKE_CTEST_COMMAND})
 942 if (MSVC)
 943         set (cmd ${cmd} -C ${CMAKE_CFG_INTDIR})
 944 else ()
 945         set (cmd ${cmd} -C ${CMAKE_BUILD_TYPE})
 946 endif ()
 947 add_custom_target (lyx_run_tests COMMAND ${cmd})
 948 set_target_properties(lyx_run_tests PROPERTIES FOLDER "tests")
 949
 950 if(LYX_ASAN)
 951     set(LYX_CXX_FLAGS "-fsanitize=address -fno-omit-frame-pointer -g")
 952     message(STATUS)
 953     message(STATUS "Address sanitizer enabled. Usage:")
 954     message(STATUS "    wget https://llvm.org/svn/llvm-project/compiler-rt/trunk/lib/asan/scripts/asan_symbolize.py")
 955     message(STATUS "    chmod  +x ./asan_symbolize.py")
 956     message(STATUS "    ./bin/lyx2.2 2>&1 | ./asan_symbolize.py  | c++filt ")
 957     message(STATUS)
 958 endif()
 959
 960 if(LYX_INSTALL)
 961         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 962                 message(STATUS "Python required to create doc!")
 963         else()
 964                 if(UNIX)
 965                         add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
 966                 endif()
 967                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
 968         endif()
 969         include(../Install)
 970 endif()
 971
 972 add_subdirectory(src "${TOP_BINARY_DIR}/src")
 973 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
 974 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
 975 add_subdirectory(lib/examples "${TOP_BINARY_DIR}/lib/examples")
 976 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
 977 add_subdirectory(development/autotests "${TOP_BINARY_DIR}/autotests")
 978 if(LYX_ENABLE_URLTESTS)
 979         add_subdirectory(development/checkurls "${TOP_BINARY_DIR}/checkurls")
 980 endif()
 981
 982 message(STATUS)
 983 message(STATUS "Build params, switch LYX_* options by -DLYX_*=ON or OFF, LYX_* combos by -DLYX_*=value:")
 984 message(STATUS)
 985
 986 LYX_OPTION_LIST_ALL(used)
 987
 988
 989 if(LYX_NLS)
 990         message(STATUS)
 991         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
 992         message(STATUS)
 993         message(STATUS "  * iconv")
 994         message(STATUS "     - include: ${ICONV_INCLUDE_DIR}")
 995         message(STATUS "     - library: ${ICONV_LIBRARY}")
 996         message(STATUS "  * zlib")
 997         message(STATUS "     - include: ${ZLIB_INCLUDE_DIR}")
 998         message(STATUS "     - library: ${ZLIB_LIBRARY}")
 999         message(STATUS)
1000 endif()
1001
1002 # Apple has builtin native spell checker,
1003 # no need to warn for missing Aspell, Hunspell or Enchant
1004 if(NOT Spelling_FOUND AND NOT APPLE)
1005   if(LYX_REQUIRE_SPELLCHECK)
1006     set(_mode "FATAL_ERROR")
1007   else()
1008     set(_mode "STATUS")
1009   endif()
1010   message(${_mode} "No spellcheck libraries found. LyX will be unable use spellchecking")
1011 endif()
1012
1013 include("${TOP_CMAKE_PATH}/LyxPackaging.cmake")
1014
1015 if(ENABLE_DIST)
1016   # Use git to create the source package
1017   # git archive --format=tgz --output=/home/kornel/x.tar.gz master
1018   if(UNIX)
1019     set(DIST_FORMAT tgz)
1020   else()
1021     set(DIST_FORMAT zip)
1022   endif()
1023   set(DIST_NAME ${CMAKE_PROJECT_NAME}-${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}-${CMAKE_SYSTEM_NAME}.${DIST_FORMAT})
1024
1025   add_custom_command(
1026     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME}
1027     COMMAND  ${LYX_GITVERSION} archive --format=${DIST_FORMAT} --output=${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME} master
1028     WORKING_DIRECTORY ${TOP_SRC_DIR})
1029   add_custom_target(git-archive DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME})
1030 endif()
1031
1032 # Last directory to be included so that the fixup code (OS X)
1033 # can be run last
1034 add_subdirectory(development/cmake/post_install)
1035
1036 message(STATUS)