CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 2.6.4)
   8
   9 set(LYX_PROJECT LyX)
  10
  11 enable_testing()
  12
  13 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README REALPATH) # Resolve symlinks
  14 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  15 message(STATUS "TOP_SRC_DIR = ${TOP_SRC_DIR}")
  16
  17 set(LYX_CMAKE_DIR "development/cmake")
  18 set(TOP_CMAKE_PATH "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}")
  19 set(TOP_MODULE_PATH "${TOP_CMAKE_PATH}/modules")
  20 set(TOP_SCRIPT_PATH "${TOP_CMAKE_PATH}/scripts")
  21
  22 set(CMAKE_MODULE_PATH "${TOP_MODULE_PATH}")
  23
  24 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  25
  26 message(STATUS)
  27 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  28         message(STATUS "Building in-source")
  29         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  30 else()
  31         message(STATUS "Building out-of-source")
  32         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  33 endif()
  34
  35 # This directory should be used if some test uses lyx-executable
  36 set(LYX_TESTS_USERDIR "${TOP_BINARY_DIR}/Testing/.lyx")
  37 file(MAKE_DIRECTORY "${LYX_TESTS_USERDIR}")
  38
  39 if(COMMAND cmake_policy)
  40         cmake_policy(SET CMP0003 OLD)
  41         cmake_policy(SET CMP0005 OLD)
  42         # Installing MACOSX_BUNDLE targets requires a BUNDLE DESTINATION
  43         cmake_policy(SET CMP0006 NEW)
  44         if(POLICY CMP0020)
  45                 cmake_policy(SET CMP0020 OLD)
  46         endif()
  47         if(POLICY CMP0028)
  48                 cmake_policy(SET CMP0028 OLD)
  49         endif()
  50         if(POLICY CMP0043)
  51                 # COMPILE_DEFINITIONS are not used yet. Enable new behavior.
  52                 cmake_policy(SET CMP0043 NEW)
  53         endif()
  54 endif()
  55
  56 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  57
  58 # Supress regeneration
  59 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  60
  61 if(LYX_XMINGW)
  62     set(CMAKE_SYSTEM_NAME Windows)
  63     set(TOOLNAME ${LYX_XMINGW})
  64     set(TOOLCHAIN "${TOOLNAME}-")
  65     set(CMAKE_C_COMPILER   "${TOOLCHAIN}gcc"     CACHE PATH "Mingw C compiler" FORCE)
  66     set(CMAKE_CXX_COMPILER "${TOOLCHAIN}g++"     CACHE PATH "Mingw C++ compiler" FORCE)
  67     set(CMAKE_RC_COMPILER  "${TOOLCHAIN}windres" CACHE PATH "Mingw rc compiler" FORCE)
  68
  69     set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM BOTH)
  70     set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY)
  71     set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY)
  72 endif()
  73
  74 if(NOT help AND NOT HELP)
  75   # 'project' triggers the searching for a compiler
  76   project(${LYX_PROJECT})
  77   if (CMAKE_COMPILER_IS_GNUCXX)
  78     if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS "4.0")
  79       message(STATUS "Gnu CXX compiler version = ${CMAKE_CXX_COMPILER_VERSION}")
  80       message(STATUS "is too old, should be >= 4.0")
  81       message(FATAL_ERROR "Exiting")
  82     endif()
  83   endif()
  84 endif()
  85
  86 if(UNIX)
  87         set(ARCH_TRIPLET )
  88         FIND_PROGRAM(DPKG_ARCHITECTURE_EXECUTABLE dpkg-architecture)
  89         if(DPKG_ARCHITECTURE_EXECUTABLE)
  90                 EXECUTE_PROCESS(COMMAND ${DPKG_ARCHITECTURE_EXECUTABLE} -qDEB_HOST_MULTIARCH
  91                                 OUTPUT_VARIABLE ARCH_TRIPLET
  92                                 ERROR_VARIABLE ERROR_ARCH_TRIPLET
  93                                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  94         endif()
  95 endif()
  96 if(ARCH_TRIPLET)
  97         set(SYSTEM_LIB_DIRS /usr/lib /usr/lib/${ARCH_TRIPLET} /usr/local/lib)
  98 else()
  99         set(SYSTEM_LIB_DIRS /usr/lib /usr/local/lib)
 100 endif()
 101
 102 include(LyXMacros)
 103
 104 # Usage LYX_OPTION
 105 # 1. parameter: option name without prefix 'LYX_'
 106 # 2. parameter: description
 107 # 3. parameter: default value, ON or OFF
 108 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
 109
 110 # Usage LYX_COMBO
 111 # 1. parameter: name without prefix 'LYX_'
 112 # 2. parameter: description
 113 # 3. parameter: default value
 114 # 4-n parameter: possible other string values
 115
 116 LYX_OPTION_INIT()
 117
 118 # Options for all compilers/systems
 119 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
 120 LYX_OPTION(LOCALVERSIONING  "Add version info to created package name (only used if LYX_CPACK option set)" OFF ALL)
 121 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
 122 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
 123 LYX_OPTION(REQUIRE_SPELLCHECK "Abort if no spellchecker available" OFF ALL)
 124 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
 125 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
 126 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
 127 LYX_OPTION(DEVEL_VERSION    "Build developer version" OFF ALL)
 128 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" OFF ALL)
 129 LYX_OPTION(DEBUG            "Enforce debug build"  OFF ALL)
 130 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
 131 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
 132 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
 133 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
 134 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
 135 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
 136 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
 137 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
 138 LYX_OPTION(ENABLE_URLTESTS  "Enable for URL tests" OFF ALL)
 139 LYX_OPTION(ENABLE_EXPORT_TESTS "Enable for export tests" OFF ALL)
 140 LYX_OPTION(ASAN             "Use address sanitizer" OFF ALL)
 141 LYX_COMBO(USE_QT            "Use Qt version as frontend" QT4 QT5)
 142 LYX_OPTION(3RDPARTY_BUILD   "Build 3rdparty libs" OFF ALL)
 143 LYX_COMBO(ENABLE_CXX11          "Build with options for c++11-mode" AUTO ON OFF)
 144
 145 # GCC specific
 146 LYX_OPTION(PROFILE              "Build profile version" OFF GCC)
 147 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" OFF GCC)
 148 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
 149 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
 150 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++ pedantic debug mode" OFF GCC)
 151 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" OFF GCC)
 152 LYX_OPTION(PROFILE              "Build with options for gprof" OFF GCC)
 153
 154 # MSVC specific
 155 LYX_OPTION(CONSOLE               "Show console on Windows, enforce with =FORCE" ON MSVC)
 156 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
 157 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
 158 LYX_OPTION(CONFIGURE_CHECKS      "Also run configure checks for MSVC" OFF MSVC)
 159 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
 160
 161 # APPLE specific
 162 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
 163 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
 164
 165
 166 if(help OR HELP)
 167         message(STATUS)
 168         message(STATUS "Available options: (dis/enable with -DLYX_*=OFF/ON)")
 169         message(STATUS)
 170         LYX_OPTION_LIST_ALL(help)
 171         message(STATUS)
 172         RETURN()
 173 endif()
 174
 175 # Check option dependencies
 176
 177 if(LYX_DMG)
 178         set(LYX_BUNDLE ON)
 179         set(LYX_CPACK ON)
 180 endif()
 181
 182 if(LYX_CPACK)
 183         set(LYX_INSTALL ON)
 184 endif()
 185
 186 if(LYX_INSTALL)
 187         set(LYX_NLS ON)
 188         if(WIN32 AND NOT MINGW)
 189                 set(LYX_HUNSPELL ON)
 190         endif()
 191         if(LYX_CONSOLE MATCHES "FORCE")
 192                 set(LYX_CONSOLE ON)
 193         else()
 194                 set(LYX_CONSOLE OFF)
 195         endif()
 196         set(LYX_PACKAGE_SUFFIX ON)
 197         if(NOT LYX_DEBUG)
 198                 set(LYX_RELEASE ON)
 199         endif()
 200         set(LYX_PROFILE OFF)
 201 endif()
 202
 203
 204 if(LYX_MERGE_FILES)
 205         set(LYX_PCH OFF)
 206 else()
 207         set(LYX_MERGE_REBUILD OFF)
 208 endif()
 209
 210
 211 if(LYX_DEPENDENCIES_DOWNLOAD)
 212         message(STATUS)
 213     if(MSVC12)
 214         set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2013-deps)
 215         set(deps_files lyx-windows-deps-msvc2013.zip)
 216         set(deps_server http://ftp.lyx.de/LyX-Windows-Deps)
 217         set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2013)
 218     else()
 219         set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 220             set(deps_files lyx20-deps-msvc2010-x86.zip)
 221             set(deps_server http://downloads.sourceforge.net/project/lyx/Win_installers/Dependencies)
 222         set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/deps20)
 223     endif()
 224     message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 225         foreach(it ${deps_files})
 226                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 227                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 228                 if(NOT already_downloaded)
 229                         message(STATUS "Downloading ${it} ...")
 230                         file(DOWNLOAD ${deps_server}/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS STATUS status LOG log)
 231                         list(GET status 0 status_code)
 232                         list(GET status 1 status_string)
 233                         if(NOT status_code EQUAL 0)
 234                                 file(REMOVE ${LYX_DEPENDENCIES_DIR}/${it})
 235                                 message(FATAL_ERROR "error: downloading '${it}' failed. status_code: ${status_code}, status_string: ${status_string}. \nLog: ${log} ")
 236                         endif()
 237                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 238                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 239                 endif()
 240         endforeach()
 241 endif()
 242
 243
 244
 245 message(STATUS)
 246
 247 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 248 if(WIN32)
 249         set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 250 else()
 251         set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 252 endif()
 253
 254
 255 if(LYX_ENABLE_CXX11 MATCHES "AUTO")
 256   # Set to some meaningful default
 257   find_package(CXX11Compiler)
 258   if(NOT CXX11COMPILER_FOUND)
 259     set(LYX_ENABLE_CXX11 OFF CACHE TYPE STRING FORCE)
 260   else()
 261     if(CMAKE_CXX_COMPILER_ID MATCHES "GNU")
 262       execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION OUTPUT_STRIP_TRAILING_WHITESPACE)
 263         set(LYX_ENABLE_CXX11 ON CACHE TYPE STRING FORCE)
 264     else()
 265       # Not a gnu compiler
 266       if(CMAKE_CXX_COMPILER_ID MATCHES "^[cC]lang$")
 267         set(LYX_ENABLE_CXX11 ON CACHE TYPE STRING FORCE)
 268       else()
 269         set(LYX_ENABLE_CXX11 OFF CACHE TYPE STRING FORCE)
 270       endif()
 271     endif()
 272   endif()
 273 endif()
 274 set(LYX_GCC11_MODE)
 275 if(UNIX OR MINGW)
 276         execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION OUTPUT_STRIP_TRAILING_WHITESPACE)
 277         message(STATUS "Using GCC version ${GCC_VERSION}")
 278         if(GCC_VERSION VERSION_LESS 4.9)
 279                 if(GCC_VERSION VERSION_LESS 4.3)
 280                         message(FATAL_ERROR "gcc >= 4.3 is required.")
 281                 endif()
 282                 # <regex> in gcc is unusable in versions less than 4.9.0
 283                 # see https://gcc.gnu.org/bugzilla/show_bug.cgi?id=53631
 284                 set(LYX_USE_STD_REGEX 0)
 285         else()
 286                 if (LYX_ENABLE_CXX11)
 287                         set(LYX_USE_STD_REGEX 1)
 288                 endif()
 289         endif()
 290         if (LYX_ENABLE_CXX11)
 291                 find_package(CXX11Compiler)
 292                 if(NOT CXX11COMPILER_FOUND)
 293                         message(FATAL_ERROR "A C++11 compatible compiler is required.")
 294                 endif()
 295                 set(LYX_GCC11_MODE "${CXX11_FLAG}")
 296         endif()
 297 else()
 298         set(LYX_USE_STD_REGEX 0)
 299 #       if(MSVC10)
 300 #               set(LYX_USE_STD_REGEX 1) #TODO should we use it in ECMAScript mode?
 301 #       endif()
 302 endif()
 303
 304
 305 set(VERSION_INFO "CMake Build")
 306
 307 # Try to get some informations from configure.ac
 308
 309 include(LyXPaths)
 310 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 311
 312 if(WIN32)
 313         set(CMAKE_PREFIX_PATH Specify-path-to-Qt CACHE PATH "Used Qt version")
 314         if(MSVC)
 315                 set(LYX_3RDPARTY_BUILD ON CACHE BOOL "Build 3rdparty libraries" FORCE)
 316         endif()
 317         set(USE_WINDOWS_PACKAGING ON)
 318 elseif(APPLE)
 319         set(USE_MACOSX_PACKAGING ON)
 320 else()
 321         set(USE_POSIX_PACKAGING ON)
 322 endif()
 323
 324 macro(setstripped _varname)
 325         if(${ARGC} GREATER 1)
 326                 string(STRIP "${ARGV1}" _v)
 327                 if(USE_POSIX_PACKAGING)
 328                         string(TOLOWER ${_v} ${_varname})
 329                 else()
 330                         set(${_varname} ${_v})
 331                 endif()
 332         else()
 333                 set(${_varname})
 334         endif()
 335 endmacro(setstripped)
 336
 337 foreach(_c_l ${_config_lines} )
 338         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 339                 setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 340                 setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 341                 setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 342                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\)\(\\.\([0-9]+\)\)?.*$")
 343                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 344                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 345                         set(LYX_PATCH_VERSION ${CMAKE_MATCH_4})
 346                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 347                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 348                         set(LYX_INSTALL_SUFFIX "${CMAKE_MATCH_1}.${CMAKE_MATCH_2}")
 349                 endif()
 350         endif()
 351         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 352                 set(LYX_DATE "${CMAKE_MATCH_1}")
 353         endif()
 354 endforeach(_c_l)
 355
 356 FIND_PROGRAM(LYX_GITVERSION git)
 357 #message(STATUS "gitversion = ${LYX_GITVERSION}")
 358 set(LYX_REVISION_VERSION ${LYX_PATCH_VERSION})
 359 if(LYX_GITVERSION)
 360   if (LYX_LOCALVERSIONING)
 361     # Find the revision number and for later use
 362     EXECUTE_PROCESS(COMMAND ${LYX_GITVERSION} describe --match 2.0.0 HEAD
 363       WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE LYX_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 364     if (LYX_PACKAGE_RELEASE MATCHES "^2\\.0\\.0\\-\([0-9]+\)\\-.*$")
 365       # We will add offset of 40000 to get appropriate value to
 366       # previous svn.
 367       # We use this value than also to set the package-patch-value
 368       MATH(EXPR tmp_REVISION_VERSION "(${CMAKE_MATCH_1}+40000)")
 369       set(LYX_REVISION_VERSION "${LYX_PATCH_VERSION}-${tmp_REVISION_VERSION}git")
 370       set(ENABLE_DIST ON)
 371     endif()
 372   endif()
 373 endif()
 374
 375 # Set the programs (lyx, tex2lyx, etc.) suffix
 376 # When building an OS X bundle, we will append
 377 # the suffix only to the bundle, not to the programs
 378 set(PROGRAM_SUFFIX "")
 379 if(LYX_PROGRAM_SUFFIX AND NOT (APPLE AND LYX_BUNDLE))
 380         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 381 endif()
 382 set(_lyx "${PACKAGE_BASE}${PROGRAM_SUFFIX}")
 383 set(_tex2lyx tex2lyx${PROGRAM_SUFFIX})
 384
 385 add_custom_target(lyx_version ALL
 386   COMMAND ${CMAKE_COMMAND} -DTOP_SRC_DIR=${TOP_SRC_DIR} -DTOP_CMAKE_PATH=${TOP_CMAKE_PATH} -DTOP_BINARY_DIR=${TOP_BINARY_DIR} -DLYX_DATE=${LYX_DATE} -P ${TOP_SCRIPT_PATH}/LyXGetVersion.cmake
 387   )
 388 set_target_properties(lyx_version PROPERTIES FOLDER "applications")
 389
 390 # Default paths for installed utilities (tex2lyx, lyxclient, etc.)
 391 set(LYX_UTILITIES_INSTALL_PATH bin)
 392
 393 if(LYX_BUNDLE)
 394         set(LYX_CPACK ON)
 395
 396         message(STATUS)
 397         message(STATUS "Bundle creation is enabled (experimental):")
 398         message(STATUS "    make")
 399         message(STATUS "    make install/strip")
 400         message(STATUS "    make package")
 401         if(APPLE)
 402                 set(MACOSX_BUNDLE TRUE)
 403                 # This sets the bundle + executable names
 404                 set(_lyx "${PACKAGE_BASE}${LYX_INSTALL_SUFFIX}")
 405                 # This sets the Info.plist executable name
 406                 set(osx_bundle_program_name ${_lyx})
 407                 # Bundle name
 408                 set(LYX_BUNDLE_NAME ${_lyx})
 409
 410                 # This will contain the list of files that need to be included
 411                 # in the bundle and their location within the bundle
 412                 set(OSX_BUNDLE_FILES "${TOP_SRC_DIR}/development/MacOSX/LyX.sdef;${TOP_SRC_DIR}/development/MacOSX/LyXapp.icns;${CMAKE_BINARY_DIR}/lyxrc.dist")
 413                 set(OSX_BUNDLE_DIRS "Resources;Resources;Resources")
 414
 415                 # Process Info.plist and lyxrc.dist
 416                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/Info.plist.in" "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 417                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/lyxrc.dist.in" "${CMAKE_CURRENT_BINARY_DIR}/lyxrc.dist")
 418
 419                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 420                 set(LYX_DATA_SUBDIR ${LYX_BUNDLE_NAME}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 421
 422                 # Variables used by CPack
 423                 set(CPACK_BUNDLE_NAME ${LYX_BUNDLE_NAME})
 424                 set(CPACK_BUNDLE_PLIST "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 425                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${LYX_BUNDLE_NAME}.app)
 426
 427                 # Set the install paths
 428                 set(LYX_UTILITIES_INSTALL_PATH ${LYX_BUNDLE_NAME}.app/Contents/MacOS)
 429                 if(NOT LYX_INSTALL_PREFIX)
 430                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 431                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 432                 endif()
 433                 # Change the owner so that the install can work
 434                 install(CODE "set(BU_CHMOD_BUNDLE_ITEMS 1)" COMPONENT Runtime)
 435         elseif(UNIX)
 436                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 437                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 438                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 439         elseif(WIN32)
 440                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 441         endif()
 442 endif()
 443
 444 if(LYX_INSTALL_PREFIX)
 445         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 446         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 447 endif()
 448 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 449
 450 string(REGEX REPLACE "/lyx${LYX_INSTALL_SUFFIX}$" "/share" SYSTEM_DATADIR ${CMAKE_INSTALL_PREFIX})
 451
 452 if(LYX_PACKAGE_SUFFIX)
 453         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 454 else()
 455         set(PACKAGE ${PACKAGE_BASE})
 456 endif()
 457
 458 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 459         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 460         if (UNIX)
 461                 # don't use the default "/usr/local"
 462                 # but respect the user-choice on the command-line
 463                 if(LYX_INSTALL_SUFFIX)
 464                         set(CMAKE_INSTALL_PREFIX "/usr/local/lyx${LYX_INSTALL_SUFFIX}" CACHE PATH "LyX default install prefix" FORCE)
 465                 else()
 466                         set(CMAKE_INSTALL_PREFIX "/usr/local/${LYX_PROJECT}" CACHE PATH "LyX default install prefix" FORCE)
 467                 endif()
 468         endif()
 469 endif()
 470 if(WIN32)
 471         set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 472 endif()
 473 if(IS_ABSOLUTE)
 474         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 475 else()
 476         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 477 endif()
 478
 479
 480
 481 if(NOT LYX_DATA_SUBDIR)
 482         if (WIN32)
 483                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 484         else()
 485                 set(LYX_DATA_SUBDIR "" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 486         endif()
 487 endif()
 488
 489 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 490 set(LYX_LOCALEDIR "locale")
 491 set(LYX_ABS_INSTALLED_LOCALEDIR "${LYX_ABS_INSTALLED_DATADIR}/${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}")
 492 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 493
 494 if(LYX_BUNDLE AND APPLE)
 495         set(LYX_MAN_DIR "${LYX_DATA_SUBDIR}" CACHE STRING "Install location for man pages.")
 496 else()
 497         if(WIN32)
 498                 set(LYX_MAN_DIR "${CMAKE_BINARY_DIR}/usr/local/man/man1" CACHE STRING "Install location for man pages.")
 499         else()
 500                 set(LYX_MAN_DIR "/usr/local/man/man1" CACHE STRING "Install location for man pages.")
 501         endif()
 502 endif()
 503 mark_as_advanced(LYX_MAN_DIR)
 504
 505 if(LYX_INSTALL AND WIN32)
 506         message(STATUS "Configuring NSIS files")
 507         configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 508         configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 509         configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 510         message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 511 endif()
 512
 513 if(NOT GROUP_CODE)
 514         #set(GROUP_CODE "The Golden Code")
 515         set(GROUP_CODE flat)
 516 endif()
 517
 518 # lyx's source files
 519 set(LYX_CPP_FILES [a-zA-Z]*.cpp)
 520 set(LYX_HPP_FILES [a-zA-Z]*.h)
 521 set(LYX_MOC_FILES moc_*.cpp)
 522
 523 include(ProjectSourceGroup)
 524
 525
 526 if(LYX_PROFILE AND NOT MSVC)
 527         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 528         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg")
 529         set(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS}  -pg")
 530 else()
 531         set(LYX_PROFILE OFF)
 532 endif()
 533
 534
 535 if(LYX_NO_OPTIMIZE)
 536         set(CMAKE_BUILD_TYPE None)
 537         set(LYX_DEBUG OFF)
 538         set(LYX_RELEASE OFF)
 539         set(LYX_PROFILE OFF)
 540 elseif(LYX_RELEASE)
 541         set(CMAKE_BUILD_TYPE Release)
 542         set(LYX_DEBUG OFF)
 543         set(LYX_PROFILE OFF)
 544 elseif(LYX_PROFILE)
 545         set(CMAKE_BUILD_TYPE Profile)
 546         set(LYX_DEBUG OFF)
 547 else()
 548         set(CMAKE_BUILD_TYPE Debug)
 549         set(LYX_DEBUG ON)
 550 endif()
 551
 552
 553 # When shared libs are supported enable this option
 554 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 555 if(LYX_SHARED_LIBRARIES)
 556         set(library_type SHARED)
 557 else()
 558         set(library_type STATIC)
 559 endif()
 560
 561 if(NOT MSVC)
 562         if(NOT LYX_QUIET)
 563                 set(CMAKE_VERBOSE_MAKEFILE ON)
 564         endif()
 565     set(LYX_CXX_FLAGS "-Wall -Wunused-parameter ${LYX_GCC11_MODE}")
 566         if(LYX_STDLIB_DEBUG)
 567                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 568         endif()
 569         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 570         set(CMAKE_CXX_FLAGS_DEBUG "${LYX_CXX_FLAGS} -fno-strict-aliasing -O0 -g3 -D_DEBUG" CACHE TYPE STRING FORCE)
 571         if(MINGW)
 572                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 573         else()
 574                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 575         endif()
 576 endif()
 577
 578 set(LYX_CXX_FLAGS_EXTRA "" CACHE STRING "Desired semicolon separated list of extra cxx compile flags, like '-Werror'")
 579 mark_as_advanced(LYX_CXX_FLAGS_EXTRA)
 580 if(LYX_CXX_FLAGS_EXTRA)
 581         foreach(_flag ${LYX_CXX_FLAGS_EXTRA})
 582                 add_definitions(${_flag})
 583         endforeach()
 584 endif()
 585
 586 if(LYX_XMINGW)
 587         list(APPEND CMAKE_FIND_ROOT_PATH ${GNUWIN32_DIR})
 588 endif()
 589
 590 set(QPA_XCB)
 591 if(LYX_USE_QT MATCHES "QT5")
 592         # set QPA_XCB if QT uses X11
 593         find_package(Qt5Core REQUIRED)
 594         if (Qt5Core_FOUND)
 595                 find_package(Qt5Widgets REQUIRED)
 596                 if(APPLE)
 597                         find_package(Qt5MacExtras REQUIRED)
 598                 endif()
 599                 find_package(Qt5X11Extras QUIET)
 600                 if(Qt5X11Extras_FOUND)
 601                   set(QPA_XCB 1)
 602                 endif()
 603                 find_package(Qt5WinExtras QUIET)
 604                 set(QTVERSION ${Qt5Core_VERSION})
 605                 macro (qt_use_modules)
 606                         qt5_use_modules(${ARGN})
 607                 endmacro()
 608                 macro (qt_add_resources)
 609                         qt5_add_resources(${ARGN})
 610                 endmacro()
 611                 macro (qt_wrap_uifiles)
 612                         qt5_wrap_ui(${ARGN})
 613                 endmacro()
 614                 message(STATUS "Found Qt-Version ${QTVERSION}")
 615                 if(WIN32)
 616                         set(LYX_QTMAIN_LIBRARY ${Qt5Core_QTMAIN_LIBRARIES})
 617                 endif()
 618         endif()
 619 elseif(LYX_USE_QT MATCHES "QT4")
 620         if(LYX_XMINGW)
 621                 set(QT_MINGW_DIR ${LYX_QT4} CACHE PATH "Qt for Mingw" FORCE)
 622                 list(APPEND CMAKE_FIND_ROOT_PATH ${QT_MINGW_DIR} ${GNUWIN32_DIR})
 623         endif()
 624         find_package(Qt4 "4.5.0" REQUIRED)
 625         macro (qt_use_modules)
 626         endmacro()
 627         macro (qt_add_resources)
 628                 qt4_add_resources(${ARGN})
 629         endmacro()
 630         macro (qt_wrap_uifiles)
 631                 qt4_wrap_ui(${ARGN})
 632         endmacro()
 633         if(WIN32)
 634                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARIES})
 635         endif()
 636 else()
 637   message(FATAL_ERROR "Unhandled value for LYX_USE_QT (${LYX_USE_QT})")
 638 endif()
 639
 640 find_package(Magic)
 641 if(Magic_FOUND)
 642         set(HAVE_MAGIC_H 1)
 643 endif()
 644
 645 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 646
 647 set(Spelling_FOUND OFF)
 648 set(Include_used_spellchecker)   # String will be inserted into config.h
 649
 650 if(LYX_3RDPARTY_BUILD)
 651     add_subdirectory(3rdparty/hunspell)
 652     add_definitions(-DHUNSPELL_STATIC)
 653     set(HUNSPELL_FOUND ON)
 654     message(STATUS "  * Hunspell:")
 655     message(STATUS "     - include: ${HUNSPELL_INCLUDE_DIR}")
 656     message(STATUS "     - library: ${HUNSPELL_LIBRARY}")
 657 endif()
 658
 659 foreach(_spell "ASPELL" "Enchant" "Hunspell")
 660   string(TOUPPER ${_spell} _upspell)
 661   if (NOT ${_upspell}_FOUND)
 662     find_package(${_spell})
 663   endif()
 664   if (${_upspell}_FOUND)
 665     include_directories(${${_upspell}_INCLUDE_DIR})
 666     set(Spelling_FOUND ON)
 667     message(STATUS "Building with USE_${_upspell}")
 668     set(Include_used_spellchecker "${Include_used_spellchecker}#define USE_${_upspell} 1\n")
 669   else()
 670     if(LYX_${_upspell})
 671       message(FATAL_ERROR "Required ${_spell} devel package not found")
 672     else()
 673       message(STATUS "${_upspell} not found, building without ${_spell} support")
 674     endif()
 675   endif()
 676 endforeach()
 677
 678 if(GNUWIN32_DIR)
 679         list(APPEND CMAKE_PROGRAM_PATH "${GNUWIN32_DIR}/Python" )
 680 endif()
 681
 682 find_package(PythonInterp 2.7 QUIET)
 683 if(PYTHONINTERP_FOUND)
 684         if(PYTHON_VERSION_STRING VERSION_GREATER 2.8)
 685         unset(PYTHONINTERP_FOUND)
 686         endif()
 687 endif()
 688
 689 if(NOT PYTHONINTERP_FOUND)
 690   unset(PYTHON_EXECUTABLE CACHE)
 691   unset(PYTHON_VERSION_MAJOR)
 692   unset(PYTHON_VERSION_MINOR)
 693   unset(PYTHON_VERSION_STRING)
 694   find_package(PythonInterp 3.3 REQUIRED)
 695 endif()
 696
 697 set(LYX_PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 698
 699 if(LYX_NLS)
 700         find_package(LyXGettext)
 701         if(LYX_PYTHON_EXECUTABLE AND GETTEXT_FOUND)
 702                 add_subdirectory(po "${TOP_BINARY_DIR}/po")
 703         else()
 704                 # Install only supplied .gmo-files
 705                 file(GLOB _gmofiles RELATIVE "${TOP_SRC_DIR}/po" "${TOP_SRC_DIR}/po/*.gmo")
 706                 message(STATUS "Installing provided .gmo-files only")
 707                 foreach( _gmo ${_gmofiles})
 708                         string(REGEX REPLACE "\\.gmo$" "" _lang ${_gmo})
 709                         install(FILES "${TOP_SRC_DIR}/po/${_gmo}" DESTINATION ${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}/${_lang}/LC_MESSAGES RENAME ${PACKAGE}.mo)
 710                 endforeach()
 711         endif()
 712 endif()
 713
 714 if(UNIX)
 715     find_package(ICONV REQUIRED)
 716     find_package(ZLIB REQUIRED)
 717 else()
 718     if(LYX_3RDPARTY_BUILD)
 719         add_subdirectory(3rdparty/libiconv)
 720         set(HAVE_ICONV_CONST 1)
 721         add_subdirectory(3rdparty/zlib)
 722     endif()
 723 endif()
 724
 725 if(LYX_EXTERNAL_BOOST)
 726         message(STATUS "Searching for boost")
 727         if(LYX_USE_STD_REGEX)
 728                 find_package(Boost COMPONENTS signals)
 729         else()
 730                 find_package(Boost COMPONENTS signals regex)
 731         endif()
 732         if(Boost_FOUND)
 733                 message(STATUS "Boost found")
 734                 message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 735                 set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 736                 if (LYX_STDLIB_DEBUG)
 737                         # Comment from  Jean-Marc Lasgouttes:
 738                         # In general, system boost libraries are incompatible with
 739                         # the use of stdlib-debug in libstdc++. See ticket #9736 for
 740                         # details.
 741                         message(WARNING "Compiling LyX with stdlib-debug and system boost libraries may lead to crashes. Consider using '-DLYX_STDLIB_DEBUG=OFF' or using '-DLYX_EXTERNAL_BOOST=OFF'")
 742                 endif()
 743         else()
 744                 message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 745         endif()
 746 else()
 747         if(LYX_USE_STD_REGEX)
 748                 set(Lyx_Boost_Libraries boost_signals)
 749         else()
 750                 set(Lyx_Boost_Libraries boost_signals boost_regex)
 751         endif()
 752         add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 753         add_definitions(-DBOOST_SIGNALS_NO_DEPRECATION_WARNING=1)
 754         include_directories(${TOP_SRC_DIR}/3rdparty/boost)
 755         add_subdirectory(3rdparty/boost "${TOP_BINARY_DIR}/3rdparty/boost")
 756 endif()
 757
 758
 759
 760
 761 if(WIN32)
 762         if(LYX_CONSOLE)
 763                 set(LYX_QTMAIN_LIBRARY)
 764         else()
 765                 set(WIN32_CONSOLE WIN32)
 766         endif()
 767         if(MSVC)
 768                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 769                 # disable checked iterators for msvc release builds to get maximum speed
 770                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 771         else()
 772                 add_definitions(-DWINVER=0x0500)
 773         endif()
 774 endif()
 775
 776 # Compute qt4-version from ${QTVERSION}
 777
 778 message(STATUS "")
 779 foreach(_v PACKAGE PACKAGE_VERSION
 780         PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 781         LYX_ABS_TOP_SRCDIR
 782         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 783         if(NOT DEFINED ${_v})
 784                 message(FATAL_ERROR "${_v} not defined")
 785         endif()
 786         string(SUBSTRING "${_v}                            " 0 28 _v1)
 787         message(STATUS "----- ${_v1}: ${${_v}}")
 788 endforeach(_v)
 789 message(STATUS "")
 790
 791
 792 if(LYX_PCH)
 793         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 794         # Not sure if it works for all non-msvc compilers
 795         include(PCHSupport_26)
 796         configure_file(${TOP_CMAKE_PATH}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
 797         configure_file(${TOP_CMAKE_PATH}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 798         add_definitions(-DLYX_ENABLE_PCH)
 799
 800         if(MSVC)
 801                 macro(lyx_add_msvc_pch name_)
 802                         set_source_files_properties(${${name_}_sources} PROPERTIES
 803                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 804                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
 805                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 806                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
 807                                 ${TOP_BINARY_DIR}/pcheaders.h)
 808                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 809                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 810                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 811                 endmacro(lyx_add_msvc_pch)
 812                 macro(lyx_add_gcc_pch name_)
 813                 endmacro()
 814         else()
 815                 macro(lyx_add_msvc_pch name_)
 816                 endmacro()
 817                 macro(lyx_add_gcc_pch name_)
 818                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT)
 819                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
 820                 endmacro()
 821         endif()
 822 else()
 823         macro(lyx_add_msvc_pch)
 824         endmacro(lyx_add_msvc_pch)
 825         macro(lyx_add_gcc_pch name_)
 826         endmacro()
 827 endif()
 828
 829
 830 if(MSVC)
 831
 832         if(LYX_VLD)
 833                 set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/development/Win32/vld)
 834                 add_subdirectory(${vld_path}/cmake)
 835                 include(${vld_path}/cmake/vld.cmake) # forced include
 836                 set(vld_dll vld)
 837         endif()
 838
 839         if(LYX_WALL)
 840                 # Use the highest warning level
 841                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 842
 843                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 844                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 845                 else()
 846                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 847                 endif()
 848
 849                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 850                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 851                 else()
 852                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 853                 endif()
 854
 855                 # add here warnings which should produce an error /weXXXX
 856                 set(MSVC_W_ERROR   "/we4101 /we4189")
 857                 # add here warnings which should be disabled /wdXXXX
 858                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 859
 860                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 861                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 862                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 863
 864         else()
 865                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 866
 867                 # add here warnings which should produce an error /weXXXX
 868                 set(MSVC_W_ERROR   "/we4101 /we4189")
 869                 # add here warnings which should be disabled /wdXXXX
 870                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 871
 872                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 873                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 874                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 875
 876         endif()
 877
 878         if (NOT Qt5Core_FOUND)
 879                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 880                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 881                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 882         endif()
 883
 884         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 885         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 886         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 887         message(STATUS "")
 888 endif()
 889
 890
 891 if(LYX_DEBUG_GLIBC)
 892         set(_GLIBCXX_DEBUG ON)
 893 endif()
 894
 895 if(LYX_DEBUG_GLIBC_PEDANTIC)
 896         set(_GLIBCXX_DEBUG_PEDANTIC ON)
 897 endif()
 898
 899 # Xcode compiler
 900 if (CMAKE_GENERATOR MATCHES Xcode)
 901         if (XCODE_VERSION VERSION_LESS "5.0")
 902                 # Automatically select the Xcode compiler if not set
 903                 if (NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 904                         # XCode >= 3.1 has gcc 4.2 (up to actual Xcode)
 905                         if (XCODE_VERSION VERSION_GREATER "3.1")
 906                                 SET(CMAKE_XCODE_ATTRIBUTE_GCC_VERSION "com.apple.compilers.llvmgcc42")
 907                         ENDIF(XCODE_VERSION VERSION_GREATER "3.1")
 908                 ENDIF(NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 909                 # Print the selected compiler version
 910         MESSAGE(STATUS "---- Using XCode compiler CMAKE_XCODE_ATTRIBUTE_GCC_VERSION=${CMAKE_XCODE_ATTRIBUTE_GCC_VERSION}")
 911         ENDIF(XCODE_VERSION VERSION_LESS "5.0")
 912 ENDIF(CMAKE_GENERATOR MATCHES Xcode)
 913
 914 if (WIN32 AND Qt5Core_FOUND)
 915         set(Z_PREFIX 1)
 916 endif()
 917
 918 # compiler tests, config.h generation
 919 if(MSVC AND NOT LYX_CONFIGURE_CHECKS)
 920         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.msvc ${TOP_BINARY_DIR}/configCompiler.h)
 921 else()
 922         include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
 923         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
 924 endif()
 925
 926 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
 927
 928 if(QTVERSION MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+).*")
 929         MATH(EXPR QT4_VERSION "(${CMAKE_MATCH_1}<<16)|(${CMAKE_MATCH_2}<<8)|${CMAKE_MATCH_3}")
 930 endif()
 931
 932 if (NOT HAVE_REGEX)
 933         set(LYX_USE_STD_REGEX 0)
 934 endif()
 935
 936
 937 set (cmd ${CMAKE_CTEST_COMMAND})
 938 if (MSVC)
 939         set (cmd ${cmd} -C ${CMAKE_CFG_INTDIR})
 940 else ()
 941         set (cmd ${cmd} -C ${CMAKE_BUILD_TYPE})
 942 endif ()
 943 add_custom_target (lyx_run_tests COMMAND ${cmd})
 944 set_target_properties(lyx_run_tests PROPERTIES FOLDER "tests")
 945
 946 if(LYX_ASAN)
 947     set(LYX_CXX_FLAGS "-fsanitize=address -fno-omit-frame-pointer -g")
 948     message(STATUS)
 949     message(STATUS "Address sanitizer enabled. Usage:")
 950     message(STATUS "    wget https://llvm.org/svn/llvm-project/compiler-rt/trunk/lib/asan/scripts/asan_symbolize.py")
 951     message(STATUS "    chmod  +x ./asan_symbolize.py")
 952     message(STATUS "    ./bin/lyx2.2 2>&1 | ./asan_symbolize.py  | c++filt ")
 953     message(STATUS)
 954 endif()
 955
 956 if(LYX_INSTALL)
 957         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 958                 message(STATUS "Python required to create doc!")
 959         else()
 960                 if(UNIX)
 961                         add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
 962                 endif()
 963                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
 964         endif()
 965         include(../Install)
 966 endif()
 967
 968 add_subdirectory(src "${TOP_BINARY_DIR}/src")
 969 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
 970 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
 971 add_subdirectory(lib/examples "${TOP_BINARY_DIR}/lib/examples")
 972 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
 973 add_subdirectory(development/autotests "${TOP_BINARY_DIR}/autotests")
 974 if(LYX_ENABLE_URLTESTS)
 975         add_subdirectory(development/checkurls "${TOP_BINARY_DIR}/checkurls")
 976 endif()
 977
 978 message(STATUS)
 979 message(STATUS "Build params, switch LYX_* options by -DLYX_*=ON or OFF, LYX_* combos by -DLYX_*=value:")
 980 message(STATUS)
 981
 982 LYX_OPTION_LIST_ALL(used)
 983
 984
 985 if(LYX_NLS)
 986         message(STATUS)
 987         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
 988         message(STATUS)
 989         message(STATUS "  * iconv")
 990         message(STATUS "     - include: ${ICONV_INCLUDE_DIR}")
 991         message(STATUS "     - library: ${ICONV_LIBRARY}")
 992         message(STATUS "  * zlib")
 993         message(STATUS "     - include: ${ZLIB_INCLUDE_DIR}")
 994         message(STATUS "     - library: ${ZLIB_LIBRARY}")
 995         message(STATUS)
 996 endif()
 997
 998 # Apple has builtin native spell checker,
 999 # no need to warn for missing Aspell, Hunspell or Enchant
1000 if(NOT Spelling_FOUND AND NOT APPLE)
1001   if(LYX_REQUIRE_SPELLCHECK)
1002     set(_mode "FATAL_ERROR")
1003   else()
1004     set(_mode "STATUS")
1005   endif()
1006   message(${_mode} "No spellcheck libraries found. LyX will be unable use spellchecking")
1007 endif()
1008
1009 include("${TOP_CMAKE_PATH}/LyxPackaging.cmake")
1010
1011 if(ENABLE_DIST)
1012   # Use git to create the source package
1013   # git archive --format=tgz --output=/home/kornel/x.tar.gz master
1014   if(UNIX)
1015     set(DIST_FORMAT tgz)
1016   else()
1017     set(DIST_FORMAT zip)
1018   endif()
1019   set(DIST_NAME ${CMAKE_PROJECT_NAME}-${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}-${CMAKE_SYSTEM_NAME}.${DIST_FORMAT})
1020
1021   add_custom_command(
1022     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME}
1023     COMMAND  ${LYX_GITVERSION} archive --format=${DIST_FORMAT} --output=${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME} master
1024     WORKING_DIRECTORY ${TOP_SRC_DIR})
1025   add_custom_target(git-archive DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME})
1026 endif()
1027
1028 # Last directory to be included so that the fixup code (OS X)
1029 # can be run last
1030 add_subdirectory(development/cmake/post_install)
1031
1032 message(STATUS)