CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 2.6.4)
   8
   9
  10 set(LYX_PROJECT lyx)
  11
  12 set(LYX_CMAKE_DIR "development/cmake")
  13 set(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/${LYX_CMAKE_DIR}/modules")
  14
  15 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README ABSOLUTE)
  16 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  17
  18 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  19
  20 message(STATUS)
  21 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  22         message(STATUS "Building in-source")
  23         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  24 else()
  25         message(STATUS "Building out-of-source")
  26         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  27 endif()
  28
  29
  30 if(COMMAND cmake_policy)
  31         cmake_policy(SET CMP0003 OLD)
  32         cmake_policy(SET CMP0005 OLD)
  33 endif()
  34
  35 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  36
  37 # Supress regeneration
  38 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  39
  40 if(NOT help AND NOT HELP)
  41         # 'project' triggers the searching for a compiler
  42         project(${LYX_PROJECT})
  43 endif()
  44
  45 if(UNIX)
  46         set(ARCH_TRIPLET )
  47         FIND_PROGRAM(DPKG_ARCHITECTURE_EXECUTABLE dpkg-architecture)
  48         if(DPKG_ARCHITECTURE_EXECUTABLE)
  49                 EXECUTE_PROCESS(COMMAND ${DPKG_ARCHITECTURE_EXECUTABLE} -qDEB_HOST_MULTIARCH
  50                                 OUTPUT_VARIABLE ARCH_TRIPLET
  51                                 ERROR_VARIABLE ERROR_ARCH_TRIPLET
  52                                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  53         endif()
  54 endif()
  55 if(ARCH_TRIPLET)
  56         set(SYSTEM_LIB_DIRS /usr/lib /usr/lib/${ARCH_TRIPLET} /usr/local/lib)
  57 else()
  58         set(SYSTEM_LIB_DIRS /usr/lib /usr/local/lib)
  59 endif()
  60
  61 include(LyXMacros)
  62
  63 # Usage LYX_OPTION
  64 # 1. parameter: option name without prefix 'LYX_'
  65 # 2. parameter: description
  66 # 3. parameter: default value, ON or OFF
  67 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
  68
  69
  70 LYX_OPTION_INIT()
  71
  72 # Options for all compilers/systems
  73 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
  74 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
  75 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
  76 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
  77 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
  78 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
  79 LYX_OPTION(DEVEL_VERSION    "Build developer version" OFF ALL)
  80 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" OFF ALL)
  81 LYX_OPTION(DEBUG            "Enforce debug build"  OFF ALL)
  82 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
  83 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
  84 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
  85 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
  86 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
  87 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
  88 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
  89 LYX_OPTION(EXTERNAL_LIBINTL "Use external libintl" ON ALL)
  90 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
  91
  92 # GCC specific
  93 LYX_OPTION(PROFILE              "Build profile version" OFF GCC)
  94 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" OFF GCC)
  95 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
  96 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
  97 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++pedantic debug mode" OFF GCC)
  98 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" OFF GCC)
  99 LYX_OPTION(CONCEPT_CHECKS       "Enable concept-checks" OFF GCC)
 100 LYX_OPTION(PROFILE              "Build with options for gprof" OFF GCC)
 101
 102 # MSVC specific
 103 LYX_OPTION(CONSOLE               "Show console on Windows" ON MSVC)
 104 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
 105 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
 106 LYX_OPTION(CONFIGURE_CHECKS      "Also run configure checks for MSVC" OFF MSVC)
 107 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
 108
 109 # APPLE specific
 110 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
 111 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
 112
 113
 114 if(help OR HELP)
 115         message(STATUS)
 116         message(STATUS "Available options: (dis/enable with -DLYX_*=OFF/ON)")
 117         message(STATUS)
 118         LYX_OPTION_LIST_ALL(help)
 119         message(STATUS)
 120         RETURN()
 121 endif()
 122
 123 # Check option dependencies
 124
 125 if(LYX_CPACK)
 126         set(LYX_INSTALL ON)
 127 endif()
 128
 129 if(LYX_DMG)
 130         set(LYX_BUNDLE ON)
 131         set(LYX_CPACK ON)
 132 endif()
 133
 134 if(LYX_INSTALL)
 135         set(LYX_NLS ON)
 136         if (WIN32)
 137                 set(LYX_HUNSPELL ON)
 138         endif()
 139         set(LYX_CONSOLE OFF)
 140         set(LYX_PACKAGE_SUFFIX ON)
 141         set(LYX_RELEASE ON)
 142         set(LYX_PROFILE OFF)
 143 endif()
 144
 145
 146 if(LYX_MERGE_FILES)
 147         set(LYX_PCH OFF)
 148 else()
 149         set(LYX_MERGE_REBUILD OFF)
 150 endif()
 151
 152 if(LYX_DEPENDENCIES_DOWNLOAD)
 153         message(STATUS)
 154         set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 155         message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 156         set(deps_files lyx20-deps-msvc2010.zip)
 157         set(deps_server http://downloads.sourceforge.net/project/lyx/Win_installers/Dependencies)
 158         foreach(it ${deps_files})
 159                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 160                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 161                 if(NOT already_downloaded)
 162                         message(STATUS "Downloading ${it} ...")
 163                         file(DOWNLOAD ${deps_server}/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS STATUS status LOG log)
 164                         list(GET status 0 status_code)
 165                         list(GET status 1 status_string)
 166                         if(NOT status_code EQUAL 0)
 167                                 file(REMOVE ${LYX_DEPENDENCIES_DIR}/${it})
 168                                 message(FATAL_ERROR "error: downloading '${it}' failed. status_code: ${status_code}, status_string: ${status_string}. \nLog: ${log} ")
 169                         endif()
 170                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 171                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 172                 endif()
 173         endforeach()
 174         set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/deps20)
 175 endif()
 176
 177
 178
 179 message(STATUS)
 180
 181 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 182 if(WIN32)
 183         set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 184 else()
 185         set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 186 endif()
 187
 188
 189 if(UNIX OR MINGW)
 190         execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION)
 191         message(STATUS "Using GCC version ${GCC_VERSION}")
 192         if(NOT GCC_VERSION VERSION_LESS 4.4)
 193                 set(LYX_USE_TR1 1)
 194                 # GCC <= 4.5 does not support regex: there are linker errors
 195                 # http://gcc.gnu.org/onlinedocs/libstdc++/manual/status.html#status.iso.tr1
 196                 set(LYX_USE_TR1_REGEX 0)
 197         endif()
 198 else()
 199         if(MSVC10)
 200                 set(LYX_USE_TR1 1)
 201                 #set(LYX_USE_TR1_REGEX 1) #TODO should we use it in ECMAScript mode?
 202         endif()
 203 endif()
 204
 205
 206 set(VERSION_INFO "CMake Build")
 207
 208 # Try to get some informations from configure.ac
 209
 210 include(LyXPaths)
 211 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 212
 213 if(WIN32)
 214         set(USE_WINDOWS_PACKAGING ON)
 215 elseif(APPLE)
 216         set(USE_MACOSX_PACKAGING ON)
 217 else()
 218         set(USE_POSIX_PACKAGING ON)
 219 endif()
 220
 221 macro(setstripped _varname _value)
 222         string(STRIP ${_value} _v)
 223         if(USE_POSIX_PACKAGING)
 224                 string(TOLOWER ${_v} ${_varname})
 225         else()
 226                 set(${_varname} ${_v})
 227         endif()
 228 endmacro(setstripped)
 229
 230 foreach(_c_l ${_config_lines} )
 231         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 232                 setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 233                 setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 234                 setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 235                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\)\(\\.\([0-9]+\)\)?.*$")
 236                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 237                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 238                         set(LYX_PATCH_VERSION ${CMAKE_MATCH_4})
 239                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 240                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 241                         set(LYX_INSTALL_SUFFIX "${CMAKE_MATCH_1}.${CMAKE_MATCH_2}")
 242                 endif()
 243         endif()
 244         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 245                 set(LYX_DATE "${CMAKE_MATCH_1}")
 246         endif()
 247 endforeach(_c_l)
 248
 249 # Find the revision number and for later use
 250 FIND_PROGRAM(LYX_SVNVERSION svnversion)
 251 #message(STATUS "svnversion = ${LYX_SVNVERSION}")
 252 if(LYX_SVNVERSION)
 253         EXECUTE_PROCESS(COMMAND ${LYX_SVNVERSION} WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE LYX_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 254         # We use this value also to set the package-patch-value
 255         if(LYX_PACKAGE_RELEASE MATCHES "^\([0-9]+\)")
 256                 set(LYX_REVISION_VERSION ${CMAKE_MATCH_1})
 257         endif()
 258 else()
 259         set(LYX_REVISION_VERSION svn) #TODO use date
 260 endif()
 261
 262
 263 if(LYX_PROGRAM_SUFFIX)
 264         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 265 else()
 266         set(PROGRAM_SUFFIX "")
 267 endif()
 268
 269
 270 if(LYX_BUNDLE)
 271         set(LYX_CPACK ON)
 272         message(STATUS)
 273         message(STATUS "Bundle creation is enabled (experimental):")
 274         message(STATUS "    make")
 275         message(STATUS "    make install/strip")
 276         message(STATUS "    make package")
 277         if(APPLE)
 278                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 279                 set(LYX_DATA_SUBDIR ${PACKAGE_BASE}${PROGRAM_SUFFIX}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 280                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${PACKAGE_BASE}${PROGRAM_SUFFIX}.app)
 281                 if(NOT LYX_INSTALL_PREFIX)
 282                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 283                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 284                 endif()
 285         elseif(UNIX)
 286                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 287                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 288                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 289         elseif(WIN32)
 290                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 291         endif()
 292 endif()
 293
 294 if(LYX_INSTALL_PREFIX)
 295         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 296         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 297 endif()
 298 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 299
 300 if(LYX_PACKAGE_SUFFIX)
 301         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 302 else()
 303         set(PACKAGE ${PACKAGE_BASE})
 304 endif()
 305
 306
 307 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 308         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 309         if (UNIX)
 310                 # don't use the default "/usr/local"
 311                 # but respect the user-choice on the command-line
 312                 if(LYX_INSTALL_SUFFIX)
 313                         set(CMAKE_INSTALL_PREFIX "/usr/local/lyx${LYX_INSTALL_SUFFIX}" CACHE PATH "LyX default install prefix" FORCE)
 314                 else()
 315                         set(CMAKE_INSTALL_PREFIX "/usr/local/${LYX_PROJECT}" CACHE PATH "LyX default install prefix" FORCE)
 316                 endif()
 317         endif()
 318         if(WIN32)
 319                 set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 320         endif()
 321 endif()
 322 if(IS_ABSOLUTE)
 323         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 324 else()
 325         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 326 endif()
 327
 328
 329
 330 if(NOT LYX_DATA_SUBDIR)
 331         if (WIN32)
 332                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 333         else()
 334                 set(LYX_DATA_SUBDIR "" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 335         endif()
 336 endif()
 337
 338 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 339 set(LYX_LOCALEDIR "locale")
 340 set(LYX_ABS_INSTALLED_LOCALEDIR "${LYX_ABS_INSTALLED_DATADIR}/${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}")
 341 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 342
 343
 344 if(LYX_INSTALL AND WIN32)
 345         message(STATUS "Configuring NSIS files")
 346         configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 347         configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 348         configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 349         message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 350 endif()
 351
 352 if(NOT GROUP_CODE)
 353         #set(GROUP_CODE "The Golden Code")
 354         set(GROUP_CODE flat)
 355 endif()
 356
 357 # lyx's source files
 358 set(LYX_CPP_FILES *.cpp)
 359 set(LYX_HPP_FILES *.h)
 360 set(LYX_MOC_FILES moc_*.cpp)
 361
 362 include(ProjectSourceGroup)
 363
 364
 365 if(LYX_PROFILE AND NOT MSVC)
 366         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 367         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg")
 368         set(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS}  -pg")
 369 else()
 370         set(LYX_PROFILE OFF)
 371 endif()
 372
 373
 374 if(LYX_NO_OPTIMIZE)
 375         set(CMAKE_BUILD_TYPE None)
 376         set(LYX_DEBUG OFF)
 377         set(LYX_RELEASE OFF)
 378         set(LYX_PROFILE OFF)
 379 elseif(LYX_RELEASE)
 380         set(CMAKE_BUILD_TYPE Release)
 381         set(LYX_DEBUG OFF)
 382         set(LYX_PROFILE OFF)
 383 elseif(LYX_PROFILE)
 384         set(CMAKE_BUILD_TYPE Profile)
 385         set(LYX_DEBUG OFF)
 386 else()
 387         set(CMAKE_BUILD_TYPE Debug)
 388         set(LYX_DEBUG ON)
 389 endif()
 390
 391
 392 # When shared libs are supported enable this option
 393 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 394 if(LYX_SHARED_LIBRARIES)
 395         set(library_type SHARED)
 396 else()
 397         set(library_type STATIC)
 398 endif()
 399
 400 if(NOT MSVC)
 401         if(NOT LYX_QUIET)
 402                 set(CMAKE_VERBOSE_MAKEFILE ON)
 403         endif()
 404         set(LYX_CXX_FLAGS "-Wall -Wunused-parameter")
 405         if(LYX_STDLIB_DEBUG)
 406                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 407         endif()
 408         if(LYX_CONCEPT_CHECKS)
 409                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCPP_CONCEPT_CHECKS")
 410         endif()
 411         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 412         set(CMAKE_CXX_FLAGS_DEBUG "${LYX_CXX_FLAGS} -fno-strict-aliasing -O0 -g -D_DEBUG" CACHE TYPE STRING FORCE)
 413         if(MINGW)
 414                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 415         else()
 416                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 417         endif()
 418 endif()
 419
 420
 421 find_package(Qt4 REQUIRED)
 422
 423
 424 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 425
 426 if(LYX_ASPELL)
 427         find_package(ASPELL)
 428         include_directories(${ASPELL_INCLUDE_DIR})
 429 endif()
 430
 431 if(LYX_ENCHANT)
 432         find_package(Enchant REQUIRED)
 433         include_directories(${ENCHANT_INCLUDE_DIR})
 434 endif()
 435
 436 if(LYX_HUNSPELL)
 437         find_package(Hunspell REQUIRED)
 438         include_directories(${HUNSPELL_INCLUDE_DIR})
 439 endif()
 440
 441 if(LYX_NLS)
 442         FIND_PROGRAM(LYX_PYTHON_EXECUTABLE python HINTS ${GNUWIN32_DIR}/python)
 443         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 444                 message(FATAL_ERROR "Python 2.6 needed!")
 445         endif()
 446         find_package(LyXGettext REQUIRED)
 447         include_directories(${TOP_SRC_DIR}/po)
 448         add_subdirectory(po "${TOP_BINARY_DIR}/po")
 449 endif()
 450
 451 if(LYX_NLS)
 452         if(LYX_EXTERNAL_LIBINTL)
 453                 find_package(Libintl REQUIRED)
 454                 if(DEFINED LIBINTL_LIBRARIES)
 455                         # find getext when configuring
 456                         list(APPEND CMAKE_REQUIRED_LIBRARIES ${LIBINTL_LIBRARIES})
 457                         # on mac use iconv also form ports
 458                         get_filename_component(ICONV_RELATIVE_TO_LIBINTL ${LIBINTL_LIBRARIES} PATH)
 459                 endif()
 460         else()
 461                 add_subdirectory(intl "${TOP_BINARY_DIR}/intl")
 462         endif()
 463 endif()
 464
 465 find_package(ICONV REQUIRED)
 466 find_package(ZLIB REQUIRED)
 467
 468 if(LYX_EXTERNAL_BOOST)
 469         message(STATUS "Searching for boost")
 470         find_package(Boost COMPONENTS signals regex) #TODO could REQUIRED be used
 471         if(Boost_FOUND)
 472                 message(STATUS "Boost found")
 473                 message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 474                 set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 475         else()
 476                 message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 477         endif()
 478 else()
 479         if(LYX_USE_TR1_REGEX)
 480                 set(Lyx_Boost_Libraries boost_signals)
 481         else()
 482                 set(Lyx_Boost_Libraries boost_signals boost_regex)
 483         endif()
 484         add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 485         include_directories(${TOP_SRC_DIR}/boost)
 486         add_subdirectory(boost "${TOP_BINARY_DIR}/boost")
 487 endif()
 488
 489
 490
 491
 492 if(WIN32)
 493         if(NOT LYX_CONSOLE)
 494                 set(WIN32_CONSOLE WIN32)
 495                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARY})
 496         endif()
 497         if(MSVC)
 498                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 499                 # disable checked iterators for msvc release builds to get maximum speed
 500                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 501         else()
 502                 add_definitions(-DWINVER=0x0500)
 503         endif()
 504 endif()
 505
 506 message(STATUS "")
 507 foreach(_v PACKAGE PACKAGE_VERSION
 508         PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 509         LYX_ABS_TOP_SRCDIR
 510         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 511         if(NOT DEFINED ${_v})
 512                 message(FATAL_ERROR "${_v} not defined")
 513         endif()
 514         string(SUBSTRING "${_v}                            " 0 28 _v1)
 515         message(STATUS "----- ${_v1}: ${${_v}}")
 516 endforeach(_v)
 517 message(STATUS "")
 518
 519
 520 if(LYX_PCH)
 521         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 522         # Not sure if it works for all non-msvc compilers
 523         include(PCHSupport_26)
 524         configure_file(${TOP_SRC_DIR}/${LYX_CMAKE_DIR}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
 525         configure_file(${TOP_SRC_DIR}/${LYX_CMAKE_DIR}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 526         add_definitions(-DLYX_ENABLE_PCH)
 527
 528         if(MSVC)
 529                 macro(lyx_add_msvc_pch name_)
 530                         set_source_files_properties(${${name_}_sources} PROPERTIES
 531                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 532                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
 533                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 534                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
 535                                 ${TOP_BINARY_DIR}/pcheaders.h)
 536                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 537                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 538                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 539                 endmacro(lyx_add_msvc_pch)
 540                 macro(lyx_add_gcc_pch name_)
 541                 endmacro()
 542         else()
 543                 macro(lyx_add_msvc_pch name_)
 544                 endmacro()
 545                 macro(lyx_add_gcc_pch name_)
 546                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT4)
 547                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
 548                 endmacro()
 549         endif()
 550 else()
 551         macro(lyx_add_msvc_pch)
 552         endmacro(lyx_add_msvc_pch)
 553         macro(lyx_add_gcc_pch name_)
 554         endmacro()
 555 endif()
 556
 557
 558 if(MSVC)
 559
 560         if(LYX_VLD)
 561                 set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/development/Win32/vld)
 562                 add_subdirectory(${vld_path}/cmake)
 563                 include(${vld_path}/cmake/vld.cmake) # forced include
 564                 set(vld_dll vld)
 565         endif()
 566
 567         if(LYX_WALL)
 568                 # Use the highest warning level
 569                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 570
 571                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 572                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 573                 else()
 574                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 575                 endif()
 576
 577                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 578                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 579                 else()
 580                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 581                 endif()
 582
 583                 # add here warnings which should produce an error /weXXXX
 584                 set(MSVC_W_ERROR   "/we4101 /we4189")
 585                 # add here warnings which should be disabled /wdXXXX
 586                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 587
 588                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 589                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 590                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 591
 592         else()
 593                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 594
 595                 # add here warnings which should produce an error /weXXXX
 596                 set(MSVC_W_ERROR   "/we4101 /we4189")
 597                 # add here warnings which should be disabled /wdXXXX
 598                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 599
 600                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 601                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 602                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 603
 604         endif()
 605         set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 606         set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 607         set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 608
 609         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 610         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 611         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 612         message(STATUS "")
 613 endif()
 614
 615
 616 if(LYX_DEBUG_GLIBC)
 617         set(_GLIBCXX_DEBUG ON)
 618 endif()
 619
 620 if(LYX_DEBUG_GLIBC_PEDANTIC)
 621         set(_GLIBCXX_DEBUG_PEDANTIC ON)
 622 endif()
 623
 624 # compiler tests, config.h generation
 625 if(MSVC AND NOT LYX_CONFIGURE_CHECKS)
 626         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.msvc ${TOP_BINARY_DIR}/configCompiler.h)
 627 else()
 628         include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
 629         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
 630 endif()
 631
 632 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
 633
 634 # Compute qt4-version from ${QTVERSION}
 635 if(QTVERSION MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+).*")
 636         MATH(EXPR QT4_VERSION "(${CMAKE_MATCH_1}<<16)|(${CMAKE_MATCH_2}<<8)|${CMAKE_MATCH_3}")
 637 endif()
 638
 639 add_subdirectory(src "${TOP_BINARY_DIR}/src")
 640 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
 641 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
 642
 643
 644 if(LYX_INSTALL)
 645         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 646                 message(STATUS "Python required to create doc!")
 647         else()
 648                 add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
 649                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
 650         endif()
 651         include(../Install)
 652 endif()
 653
 654 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
 655
 656 message(STATUS)
 657 message(STATUS "Build options, switch LYX_* variables by -DLYX_*=ON or OFF:")
 658 message(STATUS)
 659 LYX_OPTION_LIST_ALL(used)
 660
 661
 662 if(LYX_NLS)
 663         message(STATUS)
 664         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
 665         message(STATUS)
 666         message(STATUS "  * intl")
 667         message(STATUS "     - header : ${LIBINTL_HEADER}")
 668         message(STATUS "     - library: ${LIBINTL_LIBRARIES}")
 669         message(STATUS "  * iconv")
 670         message(STATUS "     - header : ${ICONV_HEADER}")
 671         message(STATUS "     - library: ${ICONV_LIBRARY}")
 672         message(STATUS "  * zlib")
 673         message(STATUS "     - header : ${ZLIB_HEADER}")
 674         message(STATUS "     - library: ${ZLIB_LIBRARY}")
 675         message(STATUS)
 676 endif()
 677
 678 include("${TOP_SRC_DIR}/${LYX_CMAKE_DIR}/LyxPackaging.cmake")
 679
 680 message(STATUS)