CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 2.6.4)
   8
   9 set(LYX_PROJECT LyX)
  10
  11 enable_testing()
  12
  13 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README ABSOLUTE)
  14 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  15
  16 set(LYX_CMAKE_DIR "development/cmake")
  17 set(TOP_CMAKE_PATH "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}")
  18 set(TOP_MODULE_PATH "${TOP_CMAKE_PATH}/modules")
  19 set(TOP_SCRIPT_PATH "${TOP_CMAKE_PATH}/scripts")
  20
  21 set(CMAKE_MODULE_PATH "${TOP_MODULE_PATH}")
  22
  23 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  24
  25 message(STATUS)
  26 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  27         message(STATUS "Building in-source")
  28         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  29 else()
  30         message(STATUS "Building out-of-source")
  31         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  32 endif()
  33
  34 # This directory should be used if some test uses lyx-executable
  35 set(LYX_TESTS_USERDIR "${TOP_BINARY_DIR}/Testing/.lyx")
  36 file(MAKE_DIRECTORY "${LYX_TESTS_USERDIR}")
  37
  38 if(COMMAND cmake_policy)
  39         cmake_policy(SET CMP0003 OLD)
  40         cmake_policy(SET CMP0005 OLD)
  41         # Installing MACOSX_BUNDLE targets requires a BUNDLE DESTINATION
  42         cmake_policy(SET CMP0006 NEW)
  43         if(POLICY CMP0028)
  44                 cmake_policy(SET CMP0028 OLD)
  45         endif()
  46         if(POLICY CMP0043)
  47                 # COMPILE_DEFINITIONS are not used yet. Enable new behavior.
  48                 cmake_policy(SET CMP0043 NEW)
  49         endif()
  50 endif()
  51
  52 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  53
  54 # Supress regeneration
  55 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  56
  57 if(LYX_XMINGW)
  58     set(CMAKE_SYSTEM_NAME Windows)
  59     set(TOOLNAME ${LYX_XMINGW})
  60     set(TOOLCHAIN "${TOOLNAME}-")
  61     set(CMAKE_C_COMPILER   "${TOOLCHAIN}gcc"     CACHE PATH "Mingw C compiler" FORCE)
  62     set(CMAKE_CXX_COMPILER "${TOOLCHAIN}g++"     CACHE PATH "Mingw C++ compiler" FORCE)
  63     set(CMAKE_RC_COMPILER  "${TOOLCHAIN}windres" CACHE PATH "Mingw rc compiler" FORCE)
  64
  65     set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM BOTH)
  66     set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY)
  67     set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY)
  68 endif()
  69
  70 if(NOT help AND NOT HELP)
  71   # 'project' triggers the searching for a compiler
  72   project(${LYX_PROJECT})
  73   if (CMAKE_COMPILER_IS_GNUCXX)
  74     if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS "4.0")
  75       message(STATUS "Gnu CXX compiler version = ${CMAKE_CXX_COMPILER_VERSION}")
  76       message(STATUS "is too old, should be >= 4.0")
  77       message(FATAL_ERROR "Exiting")
  78     endif()
  79   endif()
  80 endif()
  81
  82 if(UNIX)
  83         set(ARCH_TRIPLET )
  84         FIND_PROGRAM(DPKG_ARCHITECTURE_EXECUTABLE dpkg-architecture)
  85         if(DPKG_ARCHITECTURE_EXECUTABLE)
  86                 EXECUTE_PROCESS(COMMAND ${DPKG_ARCHITECTURE_EXECUTABLE} -qDEB_HOST_MULTIARCH
  87                                 OUTPUT_VARIABLE ARCH_TRIPLET
  88                                 ERROR_VARIABLE ERROR_ARCH_TRIPLET
  89                                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  90         endif()
  91 endif()
  92 if(ARCH_TRIPLET)
  93         set(SYSTEM_LIB_DIRS /usr/lib /usr/lib/${ARCH_TRIPLET} /usr/local/lib)
  94 else()
  95         set(SYSTEM_LIB_DIRS /usr/lib /usr/local/lib)
  96 endif()
  97
  98 include(LyXMacros)
  99
 100 # Usage LYX_OPTION
 101 # 1. parameter: option name without prefix 'LYX_'
 102 # 2. parameter: description
 103 # 3. parameter: default value, ON or OFF
 104 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
 105
 106 # Usage LYX_COMBO
 107 # 1. parameter: name without prefix 'LYX_'
 108 # 2. parameter: description
 109 # 3. parameter: default value
 110 # 4-n parameter: possible other string values
 111
 112 LYX_OPTION_INIT()
 113
 114 # Options for all compilers/systems
 115 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
 116 LYX_OPTION(LOCALVERSIONING  "Add version info to created package name (only used if LYX_CPACK option set)" OFF ALL)
 117 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
 118 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
 119 LYX_OPTION(REQUIRE_SPELLCHECK "Abort if no spellchecker available" OFF ALL)
 120 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
 121 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
 122 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
 123 LYX_OPTION(DEVEL_VERSION    "Build developer version" OFF ALL)
 124 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" OFF ALL)
 125 LYX_OPTION(DEBUG            "Enforce debug build"  OFF ALL)
 126 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
 127 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
 128 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
 129 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
 130 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
 131 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
 132 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
 133 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
 134 LYX_OPTION(ENABLE_URLTESTS  "Enable for URL tests" OFF ALL)
 135 LYX_OPTION(ENABLE_EXPORT_TESTS "Enable for export tests" OFF ALL)
 136 LYX_OPTION(ASAN             "Use address sanitizer" OFF ALL)
 137 LYX_COMBO(USE_QT            "Use Qt version as frontend" QT4 QT5)
 138
 139 # GCC specific
 140 LYX_OPTION(PROFILE              "Build profile version" OFF GCC)
 141 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" OFF GCC)
 142 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
 143 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
 144 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++ pedantic debug mode" OFF GCC)
 145 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" OFF GCC)
 146 LYX_OPTION(PROFILE              "Build with options for gprof" OFF GCC)
 147 LYX_OPTION(ENABLE_CXX11         "Build with options for c++11-mode" OFF GCC)
 148
 149 # MSVC specific
 150 LYX_OPTION(CONSOLE               "Show console on Windows, enforce with =FORCE" ON MSVC)
 151 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
 152 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
 153 LYX_OPTION(CONFIGURE_CHECKS      "Also run configure checks for MSVC" OFF MSVC)
 154 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
 155
 156 # APPLE specific
 157 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
 158 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
 159
 160
 161 if(help OR HELP)
 162         message(STATUS)
 163         message(STATUS "Available options: (dis/enable with -DLYX_*=OFF/ON)")
 164         message(STATUS)
 165         LYX_OPTION_LIST_ALL(help)
 166         message(STATUS)
 167         RETURN()
 168 endif()
 169
 170 # Check option dependencies
 171
 172 if(LYX_DMG)
 173         set(LYX_BUNDLE ON)
 174         set(LYX_CPACK ON)
 175 endif()
 176
 177 if(LYX_CPACK)
 178         set(LYX_INSTALL ON)
 179 endif()
 180
 181 if(LYX_INSTALL)
 182         set(LYX_NLS ON)
 183         if(WIN32 AND NOT MINGW)
 184                 set(LYX_HUNSPELL ON)
 185         endif()
 186         if(LYX_CONSOLE MATCHES "FORCE")
 187                 set(LYX_CONSOLE ON)
 188         else()
 189                 set(LYX_CONSOLE OFF)
 190         endif()
 191         set(LYX_PACKAGE_SUFFIX ON)
 192         if(NOT LYX_DEBUG)
 193                 set(LYX_RELEASE ON)
 194         endif()
 195         set(LYX_PROFILE OFF)
 196 endif()
 197
 198
 199 if(LYX_MERGE_FILES)
 200         set(LYX_PCH OFF)
 201 else()
 202         set(LYX_MERGE_REBUILD OFF)
 203 endif()
 204
 205
 206 if(LYX_DEPENDENCIES_DOWNLOAD)
 207         message(STATUS)
 208         set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 209         message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 210         set(deps_files lyx20-deps-msvc2010-x86.zip)
 211         set(deps_server http://downloads.sourceforge.net/project/lyx/Win_installers/Dependencies)
 212         foreach(it ${deps_files})
 213                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 214                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 215                 if(NOT already_downloaded)
 216                         message(STATUS "Downloading ${it} ...")
 217                         file(DOWNLOAD ${deps_server}/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS STATUS status LOG log)
 218                         list(GET status 0 status_code)
 219                         list(GET status 1 status_string)
 220                         if(NOT status_code EQUAL 0)
 221                                 file(REMOVE ${LYX_DEPENDENCIES_DIR}/${it})
 222                                 message(FATAL_ERROR "error: downloading '${it}' failed. status_code: ${status_code}, status_string: ${status_string}. \nLog: ${log} ")
 223                         endif()
 224                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 225                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 226                 endif()
 227         endforeach()
 228         set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/deps20)
 229     if(MSVC12)
 230         # handle error in msvc12 when linking against msvc10 libs
 231         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /vd2")
 232     endif()
 233 endif()
 234
 235
 236
 237 message(STATUS)
 238
 239 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 240 if(WIN32)
 241         set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 242 else()
 243         set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 244 endif()
 245
 246
 247 set(LYX_GCC11_MODE)
 248 if(UNIX OR MINGW)
 249         execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION)
 250         message(STATUS "Using GCC version ${GCC_VERSION}")
 251         if(GCC_VERSION VERSION_LESS 4.9)
 252                 # <regex> in gcc is unusable in versions less than 4.9.0
 253                 # see https://gcc.gnu.org/bugzilla/show_bug.cgi?id=53631
 254                 set(LYX_USE_STD_REGEX 0)
 255         endif()
 256         if (LYX_ENABLE_CXX11)
 257                 find_package(CXX11Compiler)
 258                 if(NOT CXX11COMPILER_FOUND)
 259                         message(FATAL_ERROR "A C++11 compatible compiler is required.")
 260                 endif()
 261                 set(LYX_GCC11_MODE "${CXX11_FLAG}")
 262         endif()
 263 else()
 264         set(LYX_USE_STD_REGEX 0)
 265 #       if(MSVC10)
 266 #               set(LYX_USE_STD_REGEX 1) #TODO should we use it in ECMAScript mode?
 267 #       endif()
 268 endif()
 269
 270
 271 set(VERSION_INFO "CMake Build")
 272
 273 # Try to get some informations from configure.ac
 274
 275 include(LyXPaths)
 276 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 277
 278 if(WIN32)
 279         set(USE_WINDOWS_PACKAGING ON)
 280 elseif(APPLE)
 281         set(USE_MACOSX_PACKAGING ON)
 282 else()
 283         set(USE_POSIX_PACKAGING ON)
 284 endif()
 285
 286 macro(setstripped _varname)
 287         if(${ARGC} GREATER 1)
 288                 string(STRIP "${ARGV1}" _v)
 289                 if(USE_POSIX_PACKAGING)
 290                         string(TOLOWER ${_v} ${_varname})
 291                 else()
 292                         set(${_varname} ${_v})
 293                 endif()
 294         else()
 295                 set(${_varname})
 296         endif()
 297 endmacro(setstripped)
 298
 299 foreach(_c_l ${_config_lines} )
 300         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 301                 setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 302                 setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 303                 setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 304                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\)\(\\.\([0-9]+\)\)?.*$")
 305                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 306                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 307                         set(LYX_PATCH_VERSION ${CMAKE_MATCH_4})
 308                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 309                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 310                         set(LYX_INSTALL_SUFFIX "${CMAKE_MATCH_1}.${CMAKE_MATCH_2}")
 311                 endif()
 312         endif()
 313         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 314                 set(LYX_DATE "${CMAKE_MATCH_1}")
 315         endif()
 316 endforeach(_c_l)
 317
 318 FIND_PROGRAM(LYX_GITVERSION git)
 319 #message(STATUS "gitversion = ${LYX_GITVERSION}")
 320 set(LYX_REVISION_VERSION ${LYX_PATCH_VERSION})
 321 if(LYX_GITVERSION)
 322   if (LYX_LOCALVERSIONING)
 323     # Find the revision number and for later use
 324     EXECUTE_PROCESS(COMMAND ${LYX_GITVERSION} describe --match 2.0.0 HEAD
 325       WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE LYX_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 326     if (LYX_PACKAGE_RELEASE MATCHES "^2\\.0\\.0\\-\([0-9]+\)\\-.*$")
 327       # We will add offset of 40000 to get appropriate value to
 328       # previous svn.
 329       # We use this value than also to set the package-patch-value
 330       MATH(EXPR tmp_REVISION_VERSION "(${CMAKE_MATCH_1}+40000)")
 331       set(LYX_REVISION_VERSION "${LYX_PATCH_VERSION}-${tmp_REVISION_VERSION}git")
 332       set(ENABLE_DIST ON)
 333     endif()
 334   endif()
 335 endif()
 336
 337 # Set the programs (lyx, tex2lyx, etc.) suffix
 338 # When building an OS X bundle, we will append
 339 # the suffix only to the bundle, not to the programs
 340 set(PROGRAM_SUFFIX "")
 341 if(LYX_PROGRAM_SUFFIX AND NOT (APPLE AND LYX_BUNDLE))
 342         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 343 endif()
 344 set(_lyx "${PACKAGE_BASE}${PROGRAM_SUFFIX}")
 345 set(_tex2lyx tex2lyx${PROGRAM_SUFFIX})
 346
 347 add_custom_target(lyx_version ALL
 348   COMMAND ${CMAKE_COMMAND} -DTOP_SRC_DIR=${TOP_SRC_DIR} -DTOP_CMAKE_PATH=${TOP_CMAKE_PATH} -DTOP_BINARY_DIR=${TOP_BINARY_DIR} -DLYX_DATE=${LYX_DATE} -P ${TOP_SCRIPT_PATH}/LyXGetVersion.cmake
 349   )
 350 set_target_properties(lyx_version PROPERTIES FOLDER "applications")
 351
 352 # Default paths for installed utilities (tex2lyx, lyxclient, etc.)
 353 set(LYX_UTILITIES_INSTALL_PATH bin)
 354
 355 if(LYX_BUNDLE)
 356         set(LYX_CPACK ON)
 357
 358         message(STATUS)
 359         message(STATUS "Bundle creation is enabled (experimental):")
 360         message(STATUS "    make")
 361         message(STATUS "    make install/strip")
 362         message(STATUS "    make package")
 363         if(APPLE)
 364                 set(MACOSX_BUNDLE TRUE)
 365                 # This sets the bundle + executable names
 366                 set(_lyx "${PACKAGE_BASE}${LYX_INSTALL_SUFFIX}")
 367                 # This sets the Info.plist executable name
 368                 set(osx_bundle_program_name ${_lyx})
 369                 # Bundle name
 370                 set(LYX_BUNDLE_NAME ${_lyx})
 371
 372                 # This will contain the list of files that need to be included
 373                 # in the bundle and their location within the bundle
 374                 set(OSX_BUNDLE_FILES "${TOP_SRC_DIR}/development/MacOSX/LyX.sdef;${TOP_SRC_DIR}/development/MacOSX/LyXapp.icns;${CMAKE_BINARY_DIR}/lyxrc.dist")
 375                 set(OSX_BUNDLE_DIRS "Resources;Resources;Resources")
 376
 377                 # Process Info.plist and lyxrc.dist
 378                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/Info.plist.in" "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 379                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/lyxrc.dist.in" "${CMAKE_CURRENT_BINARY_DIR}/lyxrc.dist")
 380
 381                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 382                 set(LYX_DATA_SUBDIR ${LYX_BUNDLE_NAME}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 383
 384                 # Variables used by CPack
 385                 set(CPACK_BUNDLE_NAME ${LYX_BUNDLE_NAME})
 386                 set(CPACK_BUNDLE_PLIST "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 387                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${LYX_BUNDLE_NAME}.app)
 388
 389                 # Set the install paths
 390                 set(LYX_UTILITIES_INSTALL_PATH ${LYX_BUNDLE_NAME}.app/Contents/MacOS)
 391                 if(NOT LYX_INSTALL_PREFIX)
 392                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 393                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 394                 endif()
 395                 # Change the owner so that the install can work
 396                 install(CODE "set(BU_CHMOD_BUNDLE_ITEMS 1)" COMPONENT Runtime)
 397         elseif(UNIX)
 398                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 399                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 400                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 401         elseif(WIN32)
 402                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 403         endif()
 404 endif()
 405
 406 if(LYX_INSTALL_PREFIX)
 407         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 408         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 409 endif()
 410 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 411
 412 string(REGEX REPLACE "/lyx${LYX_INSTALL_SUFFIX}$" "/share" SYSTEM_DATADIR ${CMAKE_INSTALL_PREFIX})
 413
 414 if(LYX_PACKAGE_SUFFIX)
 415         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 416 else()
 417         set(PACKAGE ${PACKAGE_BASE})
 418 endif()
 419
 420 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 421         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 422         if (UNIX)
 423                 # don't use the default "/usr/local"
 424                 # but respect the user-choice on the command-line
 425                 if(LYX_INSTALL_SUFFIX)
 426                         set(CMAKE_INSTALL_PREFIX "/usr/local/lyx${LYX_INSTALL_SUFFIX}" CACHE PATH "LyX default install prefix" FORCE)
 427                 else()
 428                         set(CMAKE_INSTALL_PREFIX "/usr/local/${LYX_PROJECT}" CACHE PATH "LyX default install prefix" FORCE)
 429                 endif()
 430         endif()
 431         if(WIN32)
 432                 set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 433         endif()
 434 endif()
 435 if(IS_ABSOLUTE)
 436         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 437 else()
 438         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 439 endif()
 440
 441
 442
 443 if(NOT LYX_DATA_SUBDIR)
 444         if (WIN32)
 445                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 446         else()
 447                 set(LYX_DATA_SUBDIR "" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 448         endif()
 449 endif()
 450
 451 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 452 set(LYX_LOCALEDIR "locale")
 453 set(LYX_ABS_INSTALLED_LOCALEDIR "${LYX_ABS_INSTALLED_DATADIR}/${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}")
 454 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 455
 456 if(LYX_BUNDLE AND APPLE)
 457         set(LYX_MAN_DIR "${LYX_DATA_SUBDIR}" CACHE STRING "Install location for man pages.")
 458 else()
 459         set(LYX_MAN_DIR "/usr/local/man/man1" CACHE STRING "Install location for man pages.")
 460 endif()
 461 mark_as_advanced(LYX_MAN_DIR)
 462
 463 if(LYX_INSTALL AND WIN32)
 464         message(STATUS "Configuring NSIS files")
 465         configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 466         configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 467         configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 468         message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 469 endif()
 470
 471 if(NOT GROUP_CODE)
 472         #set(GROUP_CODE "The Golden Code")
 473         set(GROUP_CODE flat)
 474 endif()
 475
 476 # lyx's source files
 477 set(LYX_CPP_FILES [a-zA-Z]*.cpp)
 478 set(LYX_HPP_FILES [a-zA-Z]*.h)
 479 set(LYX_MOC_FILES moc_*.cpp)
 480
 481 include(ProjectSourceGroup)
 482
 483
 484 if(LYX_PROFILE AND NOT MSVC)
 485         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 486         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg")
 487         set(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS}  -pg")
 488 else()
 489         set(LYX_PROFILE OFF)
 490 endif()
 491
 492
 493 if(LYX_NO_OPTIMIZE)
 494         set(CMAKE_BUILD_TYPE None)
 495         set(LYX_DEBUG OFF)
 496         set(LYX_RELEASE OFF)
 497         set(LYX_PROFILE OFF)
 498 elseif(LYX_RELEASE)
 499         set(CMAKE_BUILD_TYPE Release)
 500         set(LYX_DEBUG OFF)
 501         set(LYX_PROFILE OFF)
 502 elseif(LYX_PROFILE)
 503         set(CMAKE_BUILD_TYPE Profile)
 504         set(LYX_DEBUG OFF)
 505 else()
 506         set(CMAKE_BUILD_TYPE Debug)
 507         set(LYX_DEBUG ON)
 508 endif()
 509
 510
 511 # When shared libs are supported enable this option
 512 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 513 if(LYX_SHARED_LIBRARIES)
 514         set(library_type SHARED)
 515 else()
 516         set(library_type STATIC)
 517 endif()
 518
 519 if(NOT MSVC)
 520         if(NOT LYX_QUIET)
 521                 set(CMAKE_VERBOSE_MAKEFILE ON)
 522         endif()
 523     set(LYX_CXX_FLAGS "-Wall -Wunused-parameter ${LYX_GCC11_MODE}")
 524         if(LYX_STDLIB_DEBUG)
 525                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 526         endif()
 527         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 528         set(CMAKE_CXX_FLAGS_DEBUG "${LYX_CXX_FLAGS} -fno-strict-aliasing -O0 -g3 -D_DEBUG" CACHE TYPE STRING FORCE)
 529         if(MINGW)
 530                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 531         else()
 532                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 533         endif()
 534 endif()
 535
 536 set(LYX_CXX_FLAGS_EXTRA "" CACHE STRING "Desired semicolon separated list of extra cxx compile flags, like '-Werror'")
 537 mark_as_advanced(LYX_CXX_FLAGS_EXTRA)
 538 if(LYX_CXX_FLAGS_EXTRA)
 539         foreach(_flag ${LYX_CXX_FLAGS_EXTRA})
 540                 add_definitions(${_flag})
 541         endforeach()
 542 endif()
 543
 544 if(LYX_XMINGW)
 545     set(QT_MINGW_DIR ${LYX_QT4} CACHE PATH "Qt for Mingw" FORCE)
 546     list(APPEND CMAKE_FIND_ROOT_PATH ${QT_MINGW_DIR} ${GNUWIN32_DIR})
 547 endif()
 548 if(LYX_USE_QT MATCHES "QT5")
 549         find_package(Qt5Core REQUIRED)
 550         if (Qt5Core_FOUND)
 551                 find_package(Qt5Widgets REQUIRED)
 552                 if(APPLE)
 553                         find_package(Qt5MacExtras REQUIRED)
 554                 endif()
 555                 find_package(Qt5X11Extras QUIET)
 556                 find_package(Qt5WinExtras QUIET)
 557                 set(QTVERSION ${Qt5Core_VERSION})
 558                 macro (qt_use_modules)
 559                         qt5_use_modules(${ARGN})
 560                 endmacro()
 561                 macro (qt_add_resources)
 562                         qt5_add_resources(${ARGN})
 563                 endmacro()
 564                 macro (qt_wrap_uifiles)
 565                         qt5_wrap_ui(${ARGN})
 566                 endmacro()
 567                 message(STATUS "Found Qt-Version ${QTVERSION}")
 568         endif()
 569 elseif(LYX_USE_QT MATCHES "QT4")
 570         find_package(Qt4 "4.5.0" REQUIRED)
 571         macro (qt_use_modules)
 572         endmacro()
 573         macro (qt_add_resources)
 574                 qt4_add_resources(${ARGN})
 575         endmacro()
 576         macro (qt_wrap_uifiles)
 577                 qt4_wrap_ui(${ARGN})
 578         endmacro()
 579 else()
 580   message(FATAL_ERROR "Unhandled value for LYX_USE_QT (${LYX_USE_QT})")
 581 endif()
 582
 583 find_package(Magic)
 584 if(Magic_FOUND)
 585         set(HAVE_MAGIC_H 1)
 586 endif()
 587
 588 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 589
 590 set(Spelling_FOUND OFF)
 591 set(Include_used_spellchecker)   # String will be inserted into config.h
 592
 593 foreach(_spell "ASPELL" "Enchant" "Hunspell")
 594   string(TOUPPER ${_spell} _upspell)
 595   find_package(${_spell})
 596   if (${_upspell}_FOUND)
 597     include_directories(${${_upspell}_INCLUDE_DIR})
 598     set(Spelling_FOUND ON)
 599     message(STATUS "Building with USE_${_upspell}")
 600     set(Include_used_spellchecker "${Include_used_spellchecker}#define USE_${_upspell} 1\n")
 601   else()
 602     if(LYX_${_upspell})
 603       message(FATAL_ERROR "Required ${_spell} devel package not found")
 604     else()
 605       message(STATUS "${_upspell} not found, building without ${_spell} support")
 606     endif()
 607   endif()
 608 endforeach()
 609
 610 find_package(PythonInterp 2.7 QUIET)
 611 if(PYTHONINTERP_FOUND)
 612   if(PYTHON_VERSION_STRING VERSION_GREATER 2.8)
 613     unset(PYTHONINTERP_FOUND)
 614   endif()
 615 endif()
 616
 617 if (NOT PYTHONINTERP_FOUND)
 618   unset(PYTHON_EXECUTABLE CACHE)
 619   unset(PYTHON_VERSION_MAJOR)
 620   unset(PYTHON_VERSION_MINOR)
 621   unset(PYTHON_VERSION_STRING)
 622   find_package(PythonInterp 3.3 REQUIRED)
 623 endif()
 624
 625 set(LYX_PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 626
 627 if(LYX_NLS)
 628         find_package(LyXGettext)
 629         if(LYX_PYTHON_EXECUTABLE AND GETTEXT_FOUND)
 630                 add_subdirectory(po "${TOP_BINARY_DIR}/po")
 631         else()
 632                 # Install only supplied .gmo-files
 633                 file(GLOB _gmofiles RELATIVE "${TOP_SRC_DIR}/po" "${TOP_SRC_DIR}/po/*.gmo")
 634                 message(STATUS "Installing provided .gmo-files only")
 635                 foreach( _gmo ${_gmofiles})
 636                         string(REGEX REPLACE "\\.gmo$" "" _lang ${_gmo})
 637                         install(FILES "${TOP_SRC_DIR}/po/${_gmo}" DESTINATION ${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}/${_lang}/LC_MESSAGES RENAME ${PACKAGE}.mo)
 638                 endforeach()
 639         endif()
 640 endif()
 641
 642
 643 find_package(ICONV REQUIRED)
 644 find_package(ZLIB REQUIRED)
 645
 646 if(LYX_EXTERNAL_BOOST)
 647         message(STATUS "Searching for boost")
 648         if(LYX_USE_STD_REGEX)
 649                 find_package(Boost COMPONENTS signals)
 650         else()
 651                 find_package(Boost COMPONENTS signals regex)
 652         endif()
 653         if(Boost_FOUND)
 654                 message(STATUS "Boost found")
 655                 message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 656                 set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 657                 if (LYX_STDLIB_DEBUG)
 658                         # Comment from  Jean-Marc Lasgouttes:
 659                         # In general, system boost libraries are incompatible with
 660                         # the use of stdlib-debug in libstdc++. See ticket #9736 for
 661                         # details.
 662                         message(WARNING "Compiling LyX with stdlib-debug and system boost libraries may lead to crashes. Consider using '-DLYX_STDLIB_DEBUG=OFF' or using '-DLYX_EXTERNAL_BOOST=OFF'")
 663                 endif()
 664         else()
 665                 message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 666         endif()
 667 else()
 668         if(LYX_USE_STD_REGEX)
 669                 set(Lyx_Boost_Libraries boost_signals)
 670         else()
 671                 set(Lyx_Boost_Libraries boost_signals boost_regex)
 672         endif()
 673         add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 674         add_definitions(-DBOOST_SIGNALS_NO_DEPRECATION_WARNING=1)
 675         include_directories(${TOP_SRC_DIR}/boost)
 676         add_subdirectory(boost "${TOP_BINARY_DIR}/boost")
 677 endif()
 678
 679
 680
 681
 682 if(WIN32)
 683         if(NOT LYX_CONSOLE)
 684                 set(WIN32_CONSOLE WIN32)
 685                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARY})
 686         endif()
 687         if(MSVC)
 688                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 689                 # disable checked iterators for msvc release builds to get maximum speed
 690                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 691         else()
 692                 add_definitions(-DWINVER=0x0500)
 693         endif()
 694 endif()
 695
 696 # Compute qt4-version from ${QTVERSION}
 697
 698 message(STATUS "")
 699 foreach(_v PACKAGE PACKAGE_VERSION
 700         PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 701         LYX_ABS_TOP_SRCDIR
 702         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 703         if(NOT DEFINED ${_v})
 704                 message(FATAL_ERROR "${_v} not defined")
 705         endif()
 706         string(SUBSTRING "${_v}                            " 0 28 _v1)
 707         message(STATUS "----- ${_v1}: ${${_v}}")
 708 endforeach(_v)
 709 message(STATUS "")
 710
 711
 712 if(LYX_PCH)
 713         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 714         # Not sure if it works for all non-msvc compilers
 715         include(PCHSupport_26)
 716         configure_file(${TOP_CMAKE_PATH}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
 717         configure_file(${TOP_CMAKE_PATH}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 718         add_definitions(-DLYX_ENABLE_PCH)
 719
 720         if(MSVC)
 721                 macro(lyx_add_msvc_pch name_)
 722                         set_source_files_properties(${${name_}_sources} PROPERTIES
 723                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 724                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
 725                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 726                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
 727                                 ${TOP_BINARY_DIR}/pcheaders.h)
 728                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 729                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 730                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 731                 endmacro(lyx_add_msvc_pch)
 732                 macro(lyx_add_gcc_pch name_)
 733                 endmacro()
 734         else()
 735                 macro(lyx_add_msvc_pch name_)
 736                 endmacro()
 737                 macro(lyx_add_gcc_pch name_)
 738                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT)
 739                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
 740                 endmacro()
 741         endif()
 742 else()
 743         macro(lyx_add_msvc_pch)
 744         endmacro(lyx_add_msvc_pch)
 745         macro(lyx_add_gcc_pch name_)
 746         endmacro()
 747 endif()
 748
 749
 750 if(MSVC)
 751
 752         if(LYX_VLD)
 753                 set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/development/Win32/vld)
 754                 add_subdirectory(${vld_path}/cmake)
 755                 include(${vld_path}/cmake/vld.cmake) # forced include
 756                 set(vld_dll vld)
 757         endif()
 758
 759         if(LYX_WALL)
 760                 # Use the highest warning level
 761                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 762
 763                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 764                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 765                 else()
 766                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 767                 endif()
 768
 769                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 770                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 771                 else()
 772                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 773                 endif()
 774
 775                 # add here warnings which should produce an error /weXXXX
 776                 set(MSVC_W_ERROR   "/we4101 /we4189")
 777                 # add here warnings which should be disabled /wdXXXX
 778                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 779
 780                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 781                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 782                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 783
 784         else()
 785                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 786
 787                 # add here warnings which should produce an error /weXXXX
 788                 set(MSVC_W_ERROR   "/we4101 /we4189")
 789                 # add here warnings which should be disabled /wdXXXX
 790                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 791
 792                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 793                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 794                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 795
 796         endif()
 797
 798         if (NOT Qt5Core_FOUND)
 799                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 800                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 801                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 802         endif()
 803
 804         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 805         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 806         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 807         message(STATUS "")
 808 endif()
 809
 810
 811 if(LYX_DEBUG_GLIBC)
 812         set(_GLIBCXX_DEBUG ON)
 813 endif()
 814
 815 if(LYX_DEBUG_GLIBC_PEDANTIC)
 816         set(_GLIBCXX_DEBUG_PEDANTIC ON)
 817 endif()
 818
 819 # Xcode compiler
 820 if (CMAKE_GENERATOR MATCHES Xcode)
 821         if (XCODE_VERSION VERSION_LESS "5.0")
 822                 # Automatically select the Xcode compiler if not set
 823                 if (NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 824                         # XCode >= 3.1 has gcc 4.2 (up to actual Xcode)
 825                         if (XCODE_VERSION VERSION_GREATER "3.1")
 826                                 SET(CMAKE_XCODE_ATTRIBUTE_GCC_VERSION "com.apple.compilers.llvmgcc42")
 827                         ENDIF(XCODE_VERSION VERSION_GREATER "3.1")
 828                 ENDIF(NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 829                 # Print the selected compiler version
 830         MESSAGE(STATUS "---- Using XCode compiler CMAKE_XCODE_ATTRIBUTE_GCC_VERSION=${CMAKE_XCODE_ATTRIBUTE_GCC_VERSION}")
 831         ENDIF(XCODE_VERSION VERSION_LESS "5.0")
 832 ENDIF(CMAKE_GENERATOR MATCHES Xcode)
 833
 834 if (WIN32 AND Qt5Core_FOUND)
 835         set(Z_PREFIX 1)
 836 endif()
 837
 838 # compiler tests, config.h generation
 839 if(MSVC AND NOT LYX_CONFIGURE_CHECKS)
 840         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.msvc ${TOP_BINARY_DIR}/configCompiler.h)
 841 else()
 842         include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
 843         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
 844 endif()
 845
 846 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
 847
 848 if(QTVERSION MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+).*")
 849         MATH(EXPR QT4_VERSION "(${CMAKE_MATCH_1}<<16)|(${CMAKE_MATCH_2}<<8)|${CMAKE_MATCH_3}")
 850 endif()
 851
 852
 853 set (cmd ${CMAKE_CTEST_COMMAND})
 854 if (MSVC)
 855         set (cmd ${cmd} -C ${CMAKE_CFG_INTDIR})
 856 else ()
 857         set (cmd ${cmd} -C ${CMAKE_BUILD_TYPE})
 858 endif ()
 859 add_custom_target (lyx_run_tests COMMAND ${cmd})
 860 set_target_properties(lyx_run_tests PROPERTIES FOLDER "tests")
 861
 862 if(LYX_ASAN)
 863     set(LYX_CXX_FLAGS "-fsanitize=address -fno-omit-frame-pointer -g")
 864     message(STATUS)
 865     message(STATUS "Address sanitizer enabled. Usage:")
 866     message(STATUS "    wget https://llvm.org/svn/llvm-project/compiler-rt/trunk/lib/asan/scripts/asan_symbolize.py")
 867     message(STATUS "    chmod  +x ./asan_symbolize.py")
 868     message(STATUS "    ./bin/lyx2.2 2>&1 | ./asan_symbolize.py  | c++filt ")
 869     message(STATUS)
 870 endif()
 871
 872 if(LYX_INSTALL)
 873         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 874                 message(STATUS "Python required to create doc!")
 875         else()
 876                 if(UNIX)
 877                         add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
 878                 endif()
 879                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
 880         endif()
 881         include(../Install)
 882 endif()
 883
 884 add_subdirectory(src "${TOP_BINARY_DIR}/src")
 885 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
 886 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
 887 add_subdirectory(lib/examples "${TOP_BINARY_DIR}/lib/examples")
 888 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
 889 add_subdirectory(development/autotests "${TOP_BINARY_DIR}/autotests")
 890 if(LYX_ENABLE_URLTESTS)
 891         add_subdirectory(development/checkurls "${TOP_BINARY_DIR}/checkurls")
 892 endif()
 893
 894 message(STATUS)
 895 message(STATUS "Build params, switch LYX_* options by -DLYX_*=ON or OFF, LYX_* combos by -DLYX_*=value:")
 896 message(STATUS)
 897
 898 LYX_OPTION_LIST_ALL(used)
 899
 900
 901 if(LYX_NLS)
 902         message(STATUS)
 903         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
 904         message(STATUS)
 905         message(STATUS "  * iconv")
 906         message(STATUS "     - header : ${ICONV_HEADER}")
 907         message(STATUS "     - library: ${ICONV_LIBRARY}")
 908         message(STATUS "  * zlib")
 909         message(STATUS "     - header : ${ZLIB_HEADER}")
 910         message(STATUS "     - library: ${ZLIB_LIBRARY}")
 911         message(STATUS)
 912 endif()
 913
 914 # Apple has builtin native spell checker,
 915 # no need to warn for missing Aspell, Hunspell or Enchant
 916 if(NOT Spelling_FOUND AND NOT APPLE)
 917   if(LYX_REQUIRE_SPELLCHECK)
 918     set(_mode "FATAL_ERROR")
 919   else()
 920     set(_mode "STATUS")
 921   endif()
 922   message(${_mode} "No spellcheck libraries found. LyX will be unable use spellchecking")
 923 endif()
 924
 925 include("${TOP_CMAKE_PATH}/LyxPackaging.cmake")
 926
 927 if(ENABLE_DIST)
 928   # Use git to create the source package
 929   # git archive --format=tgz --output=/home/kornel/x.tar.gz master
 930   if(UNIX)
 931     set(DIST_FORMAT tgz)
 932   else()
 933     set(DIST_FORMAT zip)
 934   endif()
 935   set(DIST_NAME ${CMAKE_PROJECT_NAME}-${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}-${CMAKE_SYSTEM_NAME}.${DIST_FORMAT})
 936
 937   add_custom_command(
 938     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME}
 939     COMMAND  ${LYX_GITVERSION} archive --format=${DIST_FORMAT} --output=${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME} master
 940     WORKING_DIRECTORY ${TOP_SRC_DIR})
 941   add_custom_target(git-archive DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME})
 942 endif()
 943
 944 # Last directory to be included so that the fixup code (OS X)
 945 # can be run last
 946 add_subdirectory(development/cmake/post_install)
 947
 948 message(STATUS)