CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2020 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 3.1.0)
   8
   9 set(GNUWIN32_DIR D:/LyX/lyx-unstable/lyx-windows-deps-msvc2017)
  10
  11 set(LYX_PROJECT LyX)
  12 # Instruct cmake to not use gnu extensions,
  13 # this prevents the mix of '-std=c++*' and '-std=gnu++*' flags
  14 set(CMAKE_CXX_EXTENSIONS OFF)
  15
  16 enable_testing()
  17
  18 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README REALPATH) # Resolve symlinks
  19 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  20 message(STATUS "TOP_SRC_DIR = ${TOP_SRC_DIR}")
  21
  22 set(LYX_CMAKE_DIR "development/cmake")
  23 set(TOP_CMAKE_PATH "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}")
  24 set(TOP_MODULE_PATH "${TOP_CMAKE_PATH}/modules")
  25 set(TOP_SCRIPT_PATH "${TOP_CMAKE_PATH}/scripts")
  26
  27 set(CMAKE_MODULE_PATH "${TOP_MODULE_PATH}")
  28
  29 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  30
  31 message(STATUS)
  32 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  33         message(STATUS "Building in-source")
  34         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  35 else()
  36         message(STATUS "Building out-of-source")
  37         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  38 endif()
  39
  40 # This directory should be used if some test uses lyx-executable
  41 set(LYX_TESTS_USERDIR "${TOP_BINARY_DIR}/Testing/.lyx")
  42 file(MAKE_DIRECTORY "${LYX_TESTS_USERDIR}")
  43
  44 if(COMMAND cmake_policy)
  45         # Installing MACOSX_BUNDLE targets requires a BUNDLE DESTINATION
  46         cmake_policy(SET CMP0006 NEW)
  47         if(POLICY CMP0043)
  48                 # COMPILE_DEFINITIONS are not used yet. Enable new behavior.
  49                 cmake_policy(SET CMP0043 NEW)
  50         endif()
  51         cmake_policy(SET CMP0020 NEW)
  52         if(POLICY CMP0075)
  53                 cmake_policy(SET CMP0075 NEW)
  54         endif()
  55         if(POLICY CMP0077)
  56                 cmake_policy(SET CMP0077 NEW)
  57         endif()
  58 endif()
  59
  60 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  61
  62 # Supress regeneration
  63 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  64
  65 if(LYX_XMINGW)
  66     set(CMAKE_SYSTEM_NAME Windows)
  67     set(TOOLNAME ${LYX_XMINGW})
  68     set(TOOLCHAIN "${TOOLNAME}-")
  69     set(CMAKE_C_COMPILER   "${TOOLCHAIN}gcc"     CACHE PATH "Mingw C compiler" FORCE)
  70     set(CMAKE_CXX_COMPILER "${TOOLCHAIN}g++"     CACHE PATH "Mingw C++ compiler" FORCE)
  71     set(CMAKE_RC_COMPILER  "${TOOLCHAIN}windres" CACHE PATH "Mingw rc compiler" FORCE)
  72
  73     set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM BOTH)
  74     set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY)
  75     set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY)
  76 endif()
  77
  78 if(NOT help AND NOT HELP)
  79   # 'project' triggers the searching for a compiler
  80   project(${LYX_PROJECT})
  81   if (CMAKE_COMPILER_IS_GNUCXX)
  82     if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS "4.0")
  83       message(STATUS "Gnu CXX compiler version = ${CMAKE_CXX_COMPILER_VERSION}")
  84       message(STATUS "is too old, should be >= 4.0")
  85       message(FATAL_ERROR "Exiting")
  86     endif()
  87   endif()
  88 endif()
  89
  90 if(UNIX)
  91         set(ARCH_TRIPLET )
  92         FIND_PROGRAM(DPKG_ARCHITECTURE_EXECUTABLE dpkg-architecture)
  93         if(DPKG_ARCHITECTURE_EXECUTABLE)
  94                 EXECUTE_PROCESS(COMMAND ${DPKG_ARCHITECTURE_EXECUTABLE} -qDEB_HOST_MULTIARCH
  95                                 OUTPUT_VARIABLE ARCH_TRIPLET
  96                                 ERROR_VARIABLE ERROR_ARCH_TRIPLET
  97                                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  98         endif()
  99 endif()
 100 if(ARCH_TRIPLET)
 101         set(SYSTEM_LIB_DIRS /usr/lib /usr/lib/${ARCH_TRIPLET} /usr/local/lib)
 102 else()
 103         set(SYSTEM_LIB_DIRS /usr/lib /usr/local/lib)
 104 endif()
 105
 106 include(LyXMacros)
 107 include(LyXDestinations)
 108
 109 # Try to get some informations from configure.ac
 110 include(LyXPaths)
 111
 112 # Value of USE_POSIX_PACKAGING is needed in determineversionandbuildtype()
 113 if(WIN32)
 114         set(CMAKE_PREFIX_PATH Specify-path-to-Qt CACHE PATH "Used Qt version")
 115         if(MSVC)
 116                 set(LYX_3RDPARTY_BUILD ON CACHE BOOL "Build 3rdparty libraries" FORCE)
 117         endif()
 118         set(USE_WINDOWS_PACKAGING ON)
 119 elseif(APPLE)
 120         set(USE_MACOSX_PACKAGING ON)
 121 else()
 122         set(USE_POSIX_PACKAGING ON)
 123 endif()
 124
 125 determineversionandbuildtype("${TOP_SRC_DIR}/configure.ac" _package_list _version_list _envlist LYX_DATE LYX_BUILD_TYPE)
 126 list(GET _package_list 0 PACKAGE_BASE)
 127 list(GET _package_list 1 PACKAGE_VERSION)
 128 list(GET _package_list 2 PACKAGE_BUGREPORT)
 129 list(GET _envlist 0 LYX_DIR_VER)
 130 list(GET _envlist 1 LYX_USERDIR_VER)
 131 list(GET _version_list 0 LYX_VERSION)
 132 list(GET _version_list 1 LYX_MAJOR_VERSION)
 133 list(GET _version_list 2 LYX_MINOR_VERSION)
 134 list(GET _version_list 3 LYX_RELEASE_LEVEL)
 135 list(GET _version_list 4 LYX_RELEASE_PATCH)
 136
 137 # Usage LYX_OPTION
 138 # 1. parameter: option name without prefix 'LYX_'
 139 # 2. parameter: description
 140 # 3. parameter: default value, ON or OFF
 141 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
 142
 143 # Usage LYX_COMBO
 144 # 1. parameter: name without prefix 'LYX_'
 145 # 2. parameter: description
 146 # 3. parameter: default value
 147 # 4-n parameter: possible other string values
 148
 149 LYX_OPTION_INIT()
 150 LYX_COMBO(ENABLE_BUILD_TYPE  "Allows to tweak the compiled code" AUTO release prerelease development gprof)
 151
 152 if(LYX_ENABLE_BUILD_TYPE MATCHES "AUTO")
 153   message(STATUS "Selecting build type defaults from configure.ac")
 154 else()
 155   set(LYX_BUILD_TYPE "${LYX_ENABLE_BUILD_TYPE}")
 156   message(STATUS "Selecting build type defaults from LYX_ENABLE_BUILD_TYPE")
 157 endif()
 158
 159 # Select some defaults depending on LYX_BUILD_TYPE
 160 # they can always be overwritten by the respective command line settings
 161 # These settings are only effective on fresh(==empty) CMakeCache.txt
 162 if(LYX_BUILD_TYPE STREQUAL "development")
 163   set(DefaultLyxDebug ON)
 164   set(DefaultLyxRelease OFF)
 165   set(DefaultLyxStdlibDebug ON)
 166   set(DefaultLyxEnableAssertions ON)
 167   set(DefaultLyxProfile OFF)
 168   set(DefaultExternalLibs OFF)
 169 elseif(LYX_BUILD_TYPE STREQUAL "prerelease")
 170   set(DefaultLyxDebug OFF)
 171   set(DefaultLyxRelease OFF)
 172   set(DefaultLyxStdlibDebug OFF)
 173   set(DefaultLyxEnableAssertions OFF)
 174   set(DefaultLyxProfile OFF)
 175   set(DefaultExternalLibs ON)
 176 elseif(LYX_BUILD_TYPE STREQUAL "release")
 177   set(DefaultLyxDebug OFF)
 178   set(DefaultLyxRelease ON)
 179   set(DefaultLyxStdlibDebug OFF)
 180   set(DefaultLyxEnableAssertions OFF)
 181   set(DefaultLyxProfile OFF)
 182   set(DefaultExternalLibs ON)
 183 elseif(LYX_BUILD_TYPE STREQUAL "gprof")
 184   set(DefaultLyxDebug ON)
 185   set(DefaultLyxRelease OFF)
 186   set(DefaultLyxStdlibDebug OFF)
 187   set(DefaultLyxEnableAssertions OFF)
 188   set(DefaultLyxProfile ON)
 189   set(DefaultExternalLibs OFF)
 190 else()
 191   message(FATAL_ERROR "Invalid build type (${LYX_BUILD_TYPE}) encountered")
 192 endif()
 193
 194 # Options for all compilers/systems
 195 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
 196 LYX_OPTION(LOCALVERSIONING  "Add version info to created package name (only used if LYX_CPACK option set)" OFF ALL)
 197 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
 198 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
 199 LYX_OPTION(REQUIRE_SPELLCHECK "Abort if no spellchecker available" OFF ALL)
 200 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
 201 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
 202 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
 203 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" ${DefaultLyxRelease} ALL)
 204 LYX_OPTION(DEBUG            "Enforce debug build"  ${DefaultLyxDebug} ALL)
 205 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
 206 LYX_OPTION(ENABLE_ASSERTIONS "Run sanity checks in the program"  ${DefaultLyxEnableAssertions} ALL)
 207 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
 208 LYX_STRING(SUFFIX_VALUE     "Use this string as suffix" "")
 209 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
 210 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
 211 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
 212 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
 213 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
 214 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
 215 LYX_OPTION(ENABLE_URLTESTS  "Enable for URL tests" OFF ALL)
 216 LYX_OPTION(ENABLE_EXPORT_TESTS "Enable for export tests" OFF ALL)
 217 LYX_OPTION(ENABLE_KEYTESTS  "Enable for keytests" OFF ALL)
 218 if (NOT CMAKE_VERSION VERSION_LESS "3.17")
 219   LYX_OPTION(ENABLE_VALGRIND_TESTS  "Enable for tests involving valgrind" OFF ALL)
 220 else()
 221   if (LYX_ENABLE_VALGRIND_TESTS)
 222     unset(LYX_ENABLE_VALGRIND_TESTS CACHE)
 223   endif()
 224 endif()
 225 LYX_OPTION(ASAN             "Use address sanitizer" OFF ALL)
 226 #LYX_COMBO(USE_FILEDIALOG    "Use native or QT file dialog" QT NATIVE)
 227 LYX_COMBO(USE_QT            "Use Qt version as frontend" AUTO QT4 QT5)
 228 LYX_COMBO(USE_IPO           "Interprocedural optimization" OFF AUTO ON)
 229 #LYX_OPTION(3RDPARTY_BUILD   "Build 3rdparty libs" OFF ALL)
 230 LYX_OPTION(DISABLE_CALLSTACK_PRINTING "do not print a callstack when crashing" OFF ALL)
 231 LYX_OPTION(EXTERNAL_Z       "OFF := Build 3rdparty lib zlib" ${DefaultExternalLibs} ALL)
 232 LYX_OPTION(EXTERNAL_DTL     "OFF := Build 3rdparty commands dt2dv and dv2dt" ${DefaultExternalLibs} ALL)
 233 LYX_OPTION(EXTERNAL_ICONV   "OFF := Build 3rdparty lib iconvlib" ${DefaultExternalLibs} ALL)
 234 LYX_OPTION(EXTERNAL_HUNSPELL "OFF := Build 3rdparty lib hunspelllib" ${DefaultExternalLibs} ALL)
 235 LYX_COMBO(EXTERNAL_MYTHES   "OFF := Build 3rdparty lib mytheslib" AUTO OFF ON)
 236
 237 # GCC specific
 238 LYX_OPTION(PROFILE              "Build with options for gprof" ${DefaultLyxProfile} GCC)
 239 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" ${DefaultExternalLibs} GCC)
 240 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
 241 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
 242 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++ pedantic debug mode" OFF GCC)
 243 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" ${DefaultLyxStdlibDebug} GCC)
 244
 245 # MSVC specific
 246 LYX_OPTION(CONSOLE               "Show console on Windows" ON MSVC)
 247 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
 248 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
 249 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
 250
 251 # APPLE specific
 252 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
 253 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
 254
 255
 256 if(help OR HELP)
 257         message(STATUS)
 258         message(STATUS "Available options: (dis/enable with -DLYX_*=OFF/ON)")
 259         message(STATUS)
 260         LYX_OPTION_LIST_ALL(help)
 261         message(STATUS)
 262         unset(help CACHE)
 263         unset(HELP CACHE)
 264         RETURN()
 265 endif()
 266
 267 if ("${LYX_SUFFIX_VALUE}" MATCHES "")
 268   set(LYX_INSTALL_SUFFIX "${LYX_MAJOR_VERSION}.${LYX_MINOR_VERSION}")
 269 else()
 270   set(LYX_INSTALL_SUFFIX "${LYX_SUFFIX_VALUE}")
 271 endif()
 272
 273 # Check option dependencies
 274 if (LYX_ENABLE_VALGRIND_TESTS)
 275         find_program(VALGRIND_EXECUTABLE "valgrind")
 276         if (NOT VALGRIND_EXECUTABLE)
 277                 message(FATAL_ERROR "Cannot use valgrind tests, executable valgrind is missing. Please disable LYX_ENABLE_VALGRIND_TESTS")
 278         endif()
 279 endif()
 280 if (LYX_DEBUG_GLIBC OR LYX_DEBUG_GLIBC_PEDANTIC OR LYX_STDLIB_DEBUG)
 281   if (LYX_EXTERNAL_BOOST)
 282     message(FATAL_ERROR "Using external boost not compatible with debug mode for stdlib")
 283   endif()
 284 endif()
 285
 286 if(LYX_DMG)
 287         set(LYX_BUNDLE ON)
 288         set(LYX_CPACK ON)
 289 endif()
 290
 291 if(LYX_CPACK)
 292         set(LYX_INSTALL ON)
 293 endif()
 294
 295 if(LYX_INSTALL)
 296         set(LYX_NLS ON)
 297         if(WIN32 AND NOT MINGW)
 298                 set(LYX_HUNSPELL ON)
 299         endif()
 300         set(LYX_PACKAGE_SUFFIX ON)
 301         if(NOT LYX_DEBUG)
 302                 set(LYX_RELEASE ON)
 303         endif()
 304         set(LYX_PROFILE OFF)
 305 endif()
 306
 307
 308 if(LYX_MERGE_FILES)
 309         set(LYX_PCH OFF)
 310 else()
 311         set(LYX_MERGE_REBUILD OFF)
 312 endif()
 313
 314 if(LYX_DEPENDENCIES_DOWNLOAD)
 315         message(STATUS)
 316         if(MSVC14)
 317                 set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2015-deps)
 318                 set(deps_files lyx-windows-deps-msvc2015.zip)
 319                 set(deps_server http://ftp.lyx.de/LyX-Windows-Deps)
 320                 set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2015)
 321         elseif(MSVC10)
 322                 set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 323                 set(deps_files lyx-windows-deps-msvc2010.zip)
 324                 set(deps_server http://ftp.lyx.de/LyX-Windows-Deps)
 325                 set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2010)
 326         else()
 327                 message(FATAL_ERROR "error: no dependency package known for the selected MSVC version.")
 328         endif()
 329     message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 330         foreach(it ${deps_files})
 331                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 332                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 333                 if(NOT already_downloaded)
 334                         message(STATUS "Downloading ${it} ...")
 335                         file(DOWNLOAD ${deps_server}/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS STATUS status LOG log)
 336                         list(GET status 0 status_code)
 337                         list(GET status 1 status_string)
 338                         if(NOT status_code EQUAL 0)
 339                                 file(REMOVE ${LYX_DEPENDENCIES_DIR}/${it})
 340                                 message(FATAL_ERROR "error: downloading '${it}' failed. status_code: ${status_code}, status_string: ${status_string}. \nLog: ${log} ")
 341                         endif()
 342                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 343                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 344                 endif()
 345         endforeach()
 346 endif()
 347
 348 message(STATUS)
 349
 350 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 351 if(WIN32)
 352         set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 353 else()
 354         set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 355 endif()
 356
 357 set(LYX_IPO_SUPPORTED OFF)
 358 if (POLICY CMP0069)
 359   cmake_policy(SET CMP0069 NEW)
 360   if(LYX_USE_IPO MATCHES "AUTO")
 361     # Enable LTO if supported and not debugging
 362     if (NOT LYX_DEBUG)
 363       include(CheckIPOSupported)
 364       check_ipo_supported(RESULT LYX_IPO_SUPPORTED)
 365     endif()
 366   else()
 367     set(LYX_IPO_SUPPORTED ${LYX_USE_IPO})
 368   endif()
 369 endif()
 370 if (LYX_IPO_SUPPORTED)
 371   set(LYX_USE_IPO "ON" CACHE STRING "Use interprocedural optimization" FORCE)
 372 else()
 373   set(LYX_USE_IPO "OFF" CACHE STRING "Use interprocedural optimization" FORCE)
 374 endif()
 375
 376 # Set to some meaningful default
 377 find_package(CXX11Compiler)
 378 if(NOT CXX11COMPILER_FOUND)
 379         message(FATAL_ERROR "A C++11 compatible compiler is required.")
 380 endif()
 381 unset(LYX_GCC11_MODE)
 382 if(UNIX OR MINGW)
 383         if (CMAKE_CXX_COMPILER_ID MATCHES "^([cC]lang|AppleClang)$")
 384           # ignore the GCC_VERSION for clang
 385           # and use the resulting CXX11_STD_REGEX found in FindCXX11Compiler.cmake
 386           message(STATUS "Using clang")
 387           if(CXX11_STD_REGEX)
 388             set(LYX_USE_STD_REGEX 1)
 389           else()
 390             set(LYX_USE_STD_REGEX 0)
 391           endif()
 392         else()
 393           execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpfullversion OUTPUT_VARIABLE GCC_VERSION ERROR_VARIABLE _error RESULT_VARIABLE _err OUTPUT_STRIP_TRAILING_WHITESPACE)
 394           #message(STATUS "dumpfullversion: error = ${_error}, result = ${_err}")
 395           if (_err)
 396             # previous check failed, try again with _old_ parameter
 397             execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION ERROR_VARIABLE _error RESULT_VARIABLE _err OUTPUT_STRIP_TRAILING_WHITESPACE)
 398             #message(STATUS "dumpversion: error = ${_error}, result = ${_err}")
 399           endif()
 400           message(STATUS "Using GCC version ${GCC_VERSION}")
 401           if(GCC_VERSION VERSION_LESS 4.6)
 402                 message(FATAL_ERROR "gcc >= 4.6 is required.")
 403           elseif(GCC_VERSION VERSION_LESS 4.9)
 404                 # <regex> in gcc is unusable in versions less than 4.9.0
 405                 # see https://gcc.gnu.org/bugzilla/show_bug.cgi?id=53631
 406                 set(LYX_USE_STD_REGEX 0)
 407           else()
 408                 set(LYX_USE_STD_REGEX 1)
 409           endif()
 410         endif()
 411         set(LYX_GCC11_MODE "${CXX11_FLAG}")
 412 else()
 413         if(MSVC_VERSION LESS 1900)
 414                 # Drop support for msvc versions prior to 1900 (Visual Studio 2015)
 415                 message(FATAL_ERROR "Visual Studio >= 2015 is required.")
 416                 set(LYX_USE_STD_REGEX 0)
 417         else()
 418                 set(LYX_USE_STD_REGEX 1)
 419         endif()
 420 endif()
 421
 422 if(LYX_3RDPARTY_BUILD)
 423   # LYX_3RDPARTY_BUILD is not cached anymore, but for compatibility reasons
 424   # this enables the build of all 3rd_party libs
 425   set(LYX_EXTERNAL_Z        OFF CACHE BOOL "Build 3rdparty lib zlib"    FORCE)
 426   set(LYX_EXTERNAL_ICONV    OFF CACHE BOOL "Build 3rdparty iconvlib"    FORCE)
 427   set(LYX_EXTERNAL_HUNSPELL OFF CACHE BOOL "Build 3rdparty hunspelllib" FORCE)
 428   set(LYX_EXTERNAL_MYTHES   OFF CACHE STRING "Build 3rdparty mytheslib" FORCE)
 429 endif()
 430
 431 FIND_PROGRAM(LYX_GITVERSION git)
 432 #message(STATUS "gitversion = ${LYX_GITVERSION}")
 433 set(LYX_REVISION_VERSION ${LYX_RELEASE_LEVEL})
 434 set(LYX_PACKAGE_RELEASE "UNDEFINED")
 435 if(LYX_GITVERSION)
 436   if (LYX_LOCALVERSIONING)
 437     # Find the revision number for later use
 438     EXECUTE_PROCESS(COMMAND ${LYX_GITVERSION} describe --match 2.0.0 HEAD
 439       WORKING_DIRECTORY "${TOP_SRC_DIR}"
 440       RESULT_VARIABLE tmp_GIT_RESULT
 441       OUTPUT_VARIABLE tmp_LYX_PACKAGE_RELEASE
 442       ERROR_VARIABLE tmp_GIT_ERROR
 443       OUTPUT_STRIP_TRAILING_WHITESPACE)
 444     if (tmp_GIT_RESULT EQUAL 0)
 445       if (tmp_LYX_PACKAGE_RELEASE MATCHES "^2\\.0\\.0\\-\([0-9]+\)\\-\(.*\)$")
 446         set(LYX_PACKAGE_RELEASE ${CMAKE_MATCH_2})
 447         # We will add offset of 40000 to get appropriate value to
 448         # previous svn.
 449         # We use this value than also to set the package-patch-value
 450         MATH(EXPR tmp_REVISION_VERSION "(${CMAKE_MATCH_1}+40000)")
 451         set(LYX_REVISION_VERSION "${LYX_RELEASE_LEVEL}-${tmp_REVISION_VERSION}git")
 452         set(ENABLE_DIST ON)
 453       endif()
 454     endif()
 455   endif()
 456 endif()
 457 if (LYX_PACKAGE_RELEASE MATCHES "UNDEFINED")
 458   set(LYX_PACKAGE_RELEASE  "1")
 459   if (LYX_RELEASE_PATCH GREATER 0)
 460     set(LYX_REVISION_VERSION "${LYX_RELEASE_LEVEL}.${LYX_RELEASE_PATCH}")
 461   endif()
 462 endif()
 463
 464 # Set the programs (lyx, tex2lyx, etc.) suffix
 465 # When building an OS X bundle, we will append
 466 # the suffix only to the bundle, not to the programs
 467 set(PROGRAM_SUFFIX "")
 468 if(LYX_PROGRAM_SUFFIX AND NOT (APPLE AND LYX_BUNDLE))
 469         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 470 endif()
 471 set(_lyx "${PACKAGE_BASE}${PROGRAM_SUFFIX}")
 472 set(_tex2lyx tex2lyx${PROGRAM_SUFFIX})
 473 set(_convert lyxconvert${PROGRAM_SUFFIX})
 474
 475 add_custom_target(lyx_version ALL
 476   COMMAND ${CMAKE_COMMAND} -DTOP_SRC_DIR=${TOP_SRC_DIR} -DTOP_CMAKE_PATH=${TOP_CMAKE_PATH} -DTOP_BINARY_DIR=${TOP_BINARY_DIR} -DLYX_DATE=${LYX_DATE} -P ${TOP_SCRIPT_PATH}/LyXGetVersion.cmake
 477   )
 478 set_target_properties(lyx_version PROPERTIES FOLDER "applications")
 479
 480 # Default paths for installed utilities (tex2lyx, lyxclient, etc.)
 481 set(LYX_UTILITIES_INSTALL_PATH bin)
 482
 483 if(LYX_BUNDLE)
 484         set(LYX_CPACK ON)
 485
 486         message(STATUS)
 487         message(STATUS "Bundle creation is enabled (experimental):")
 488         message(STATUS "    make")
 489         message(STATUS "    make install/strip")
 490         message(STATUS "    make package")
 491         if(APPLE)
 492                 set(MACOSX_BUNDLE TRUE)
 493                 # This sets the bundle + executable names
 494                 set(_lyx "${PACKAGE_BASE}${LYX_INSTALL_SUFFIX}")
 495                 # This sets the Info.plist executable name
 496                 set(osx_bundle_program_name ${_lyx})
 497                 # Bundle name
 498                 set(LYX_BUNDLE_NAME ${_lyx})
 499
 500                 # This will contain the list of files that need to be included
 501                 # in the bundle and their location within the bundle
 502                 set(OSX_BUNDLE_FILES "${TOP_SRC_DIR}/development/MacOSX/LyX.sdef;${TOP_SRC_DIR}/development/MacOSX/LyXapp.icns;${CMAKE_BINARY_DIR}/lyxrc.dist")
 503                 set(OSX_BUNDLE_DIRS "Resources;Resources;Resources")
 504
 505                 # Process Info.plist and lyxrc.dist
 506                 # See development/cmake/Install.cmake
 507                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/Info.plist.in" "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 508
 509                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 510                 set(LYX_DATA_SUBDIR ${LYX_BUNDLE_NAME}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 511
 512                 # Variables used by CPack
 513                 set(CPACK_BUNDLE_NAME ${LYX_BUNDLE_NAME})
 514                 set(CPACK_BUNDLE_PLIST "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 515                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${LYX_BUNDLE_NAME}.app)
 516
 517                 # Set the install paths
 518                 set(LYX_UTILITIES_INSTALL_PATH ${LYX_BUNDLE_NAME}.app/Contents/MacOS)
 519                 if(NOT LYX_INSTALL_PREFIX)
 520                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 521                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 522                 endif()
 523                 # Change the owner so that the install can work
 524                 install(CODE "set(BU_CHMOD_BUNDLE_ITEMS 1)" COMPONENT Runtime)
 525         elseif(UNIX)
 526                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 527                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 528                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 529         elseif(WIN32)
 530                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 531         endif()
 532 endif()
 533
 534 if(LYX_INSTALL_PREFIX)
 535         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 536         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 537 endif()
 538 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 539
 540 if(UNIX)
 541   set(SYSTEM_DATADIR "${CMAKE_INSTALL_PREFIX}/share")
 542 elseif(CMAKE_INSTALL_PREFIX MATCHES "/lyx${LYX_INSTALL_SUFFIX}$")
 543   string(REGEX REPLACE "/lyx${LYX_INSTALL_SUFFIX}$" "/share" SYSTEM_DATADIR ${CMAKE_INSTALL_PREFIX})
 544 else()
 545   set(SYSTEM_DATADIR "${CMAKE_INSTALL_PREFIX}")
 546 endif()
 547
 548 if(NOT CMAKE_COMPILER_IS_GNUCXX)
 549   # Not a GCC compiler, programs do not have a suffix
 550   set(suffixing ${LYX_PACKAGE_SUFFIX})
 551 elseif(WIN32 AND MINGW)
 552   # We want to use a suffix for the package in this case,
 553   # even if not for the program
 554   set(suffixing ${LYX_PACKAGE_SUFFIX})
 555 else()
 556   message(STATUS "CMAKE_COMPILER_IS_GNUCXX = ${CMAKE_COMPILER_IS_GNUCXX}")
 557   set(suffixing ${LYX_PROGRAM_SUFFIX})
 558 endif()
 559
 560 # The define PACKAGE below allows lyx-executable to find its default configuration files
 561 # see routines
 562 #    Package::messages_file()
 563 #    get_default_user_support_dir()
 564 #    relative_system_support_dir()
 565 # in src/support/Package.cpp
 566 if(suffixing)
 567         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 568 else()
 569         set(PACKAGE ${PACKAGE_BASE})
 570 endif()
 571
 572 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 573         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 574         if (UNIX)
 575                 # use the default "/usr/local"
 576                 # but respect the user-choice on the command-line
 577                 set(CMAKE_INSTALL_PREFIX "/usr/local" CACHE PATH "LyX default install prefix" FORCE)
 578         endif()
 579 endif()
 580 if(WIN32)
 581         set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 582 endif()
 583 if(IS_ABSOLUTE)
 584         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 585 else()
 586         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 587 endif()
 588
 589
 590
 591 if(NOT LYX_DATA_SUBDIR)
 592         if (WIN32)
 593                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 594         else()
 595                 set(LYX_DATA_SUBDIR "share/${_lyx}/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 596         endif()
 597 endif()
 598
 599 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}/${LYX_DATA_SUBDIR}")
 600 get_locale_destination(LYX_LOCALEDIR)
 601 set(LYX_ABS_INSTALLED_LOCALEDIR "${CMAKE_INSTALL_PREFIX}/${LYX_LOCALEDIR}")
 602 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 603
 604 if(LYX_BUNDLE AND APPLE)
 605         set(LYX_MAN_DIR_tmp "${LYX_DATA_SUBDIR}")
 606 else()
 607         if(WIN32)
 608                 set(LYX_MAN_DIR_tmp "${CMAKE_BINARY_DIR}/usr/local/man/")
 609         elseif(UNIX)
 610                 set(LYX_MAN_DIR_tmp "${CMAKE_INSTALL_PREFIX}/share/man/")
 611         else()
 612                 set(LYX_MAN_DIR_tmp "${CMAKE_INSTALL_PREFIX}/man/")
 613         endif()
 614 endif()
 615 if (NOT LYX_MAN_DIR_tmp EQUAL "${LYX_MAN_DIR}")
 616         unset(LYX_MAN_DIR CACHE)
 617         set(LYX_MAN_DIR "${LYX_MAN_DIR_tmp}" CACHE STRING "Install location for man pages.")
 618 endif()
 619 unset(LYX_MAN_DIR_tmp)
 620 mark_as_advanced(LYX_MAN_DIR)
 621
 622 # The Win installer cannot be built by CMake because one needs to install plugins for NSIS
 623 # see the Readme.txt of the installer
 624 #if(LYX_INSTALL AND WIN32)
 625 #       message(STATUS "Configuring NSIS files")
 626 #       configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 627 #       configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 628 #       configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 629 #       message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 630 #endif()
 631
 632 if(NOT GROUP_CODE)
 633         #set(GROUP_CODE "The Golden Code")
 634         set(GROUP_CODE flat)
 635 endif()
 636
 637 # lyx's source files
 638 set(LYX_CPP_FILES [a-zA-Z]*.cpp)
 639 set(LYX_HPP_FILES [a-zA-Z]*.h)
 640 set(LYX_MOC_FILES moc_*.cpp)
 641
 642 include(ProjectSourceGroup)
 643
 644
 645 if(LYX_PROFILE AND NOT MSVC)
 646         set(CMAKE_BUILD_TYPE Profile CACHE STRING "Profile build type" FORCE)
 647         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg")
 648         set(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS}  -pg")
 649 else()
 650         set(LYX_PROFILE OFF)
 651 endif()
 652
 653
 654 if(LYX_NO_OPTIMIZE)
 655         set(CMAKE_BUILD_TYPE None)
 656         set(LYX_DEBUG OFF)
 657         set(LYX_RELEASE OFF)
 658         set(LYX_PROFILE OFF)
 659 elseif(LYX_RELEASE)
 660         set(CMAKE_BUILD_TYPE Release)
 661         set(LYX_DEBUG OFF)
 662         set(LYX_PROFILE OFF)
 663 elseif(LYX_PROFILE)
 664         set(CMAKE_BUILD_TYPE Profile)
 665         set(LYX_DEBUG OFF)
 666 else()
 667         set(CMAKE_BUILD_TYPE Debug)
 668         set(LYX_DEBUG ON)
 669 endif()
 670
 671
 672 # When shared libs are supported enable this option
 673 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 674 if(LYX_SHARED_LIBRARIES)
 675         set(library_type SHARED)
 676 else()
 677         set(library_type STATIC)
 678 endif()
 679
 680 if(LYX_ENABLE_ASSERTIONS)
 681   set(LYX_CXX_FLAGS " -DENABLE_ASSERTIONS=1")
 682 else()
 683   set(LYX_CXX_FLAGS "")
 684 endif()
 685
 686 if(MSVC)
 687   if (CXX11_FLAG MATCHES "\\+\\+([0-9]+)")
 688     set(CMAKE_CXX_STANDARD ${CMAKE_MATCH_1})
 689     message(STATUS "CMAKE_CXX_STANDARD set to ${CMAKE_CXX_STANDARD}")
 690   endif()
 691   set(CMAKE_CXX_FLAGS       "${CMAKE_CXX_FLAGS}${LYX_CXX_FLAGS}")
 692 else()
 693         if(NOT LYX_QUIET)
 694                 set(CMAKE_VERBOSE_MAKEFILE ON)
 695         endif()
 696         if(LYX_GCC11_MODE MATCHES "\\+\\+([0-9][0-9])")
 697           # Thanks to Brad King <brad.king@kitware.com>
 698           # for the pointer to https://cmake.org/cmake/help/v3.6/variable/CMAKE_CXX_STANDARD.html
 699           # This allows us to use QT5.7 with recent g++ (version >= 4.9) compilers
 700           # and still use our own c++ extension tests
 701           set(std_num ${CMAKE_MATCH_1})
 702           set(CMAKE_CXX_STANDARD ${std_num})
 703         else()
 704           message(STATUS "Setting CMAKE_CXX_STANDARD 11 as fallback")
 705           set(CMAKE_CXX_STANDARD 11)
 706           set(LYX_GCC11_MODE "--std=c++11")
 707         endif()
 708         # The following setting with LYX_GCC11_MODE is needed because cmake does not honor
 709         # CMAKE_CXX_STANDARD while performing tests like
 710         # check_cxx_source_compiles("..." HAVE_DEF_MAKE_UNIQUE)
 711         set(LYX_CXX_FLAGS "-Wall -Wunused-parameter ${LYX_GCC11_MODE}${LYX_CXX_FLAGS}")
 712         if(LYX_STDLIB_DEBUG)
 713           set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 714         else()
 715           if(LYX_DEBUG_GLIBC)
 716             set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG")
 717           endif()
 718           if(LYX_DEBUG_GLIBC_PEDANTIC)
 719             set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG_PEDANTIC")
 720           endif()
 721         endif()
 722         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE STRING "Set CXX flags" FORCE)
 723         set(CMAKE_CXX_FLAGS_DEBUG "-O0 -g3 -D_DEBUG" CACHE STRING "Set debug flags" FORCE)
 724         if(MINGW)
 725                 set(CMAKE_CXX_FLAGS_RELEASE "-O2 -DNDEBUG" CACHE STRING "Set release flags for Mingw" FORCE)
 726         else()
 727                 set(CMAKE_CXX_FLAGS_RELEASE "-O3 -DNDEBUG" CACHE STRING "Set release flags" FORCE)
 728         endif()
 729 endif()
 730
 731 if(LYX_ASAN)
 732     set(CMAKE_CXX_FLAGS "-fsanitize=address -fno-omit-frame-pointer -g ${CMAKE_CXX_FLAGS}")
 733     message(STATUS)
 734     message(STATUS "Address sanitizer enabled. Usage:")
 735     message(STATUS "    wget https://llvm.org/svn/llvm-project/compiler-rt/trunk/lib/asan/scripts/asan_symbolize.py")
 736     message(STATUS "    chmod  +x ./asan_symbolize.py")
 737     message(STATUS "    ./bin/${_lyx} 2>&1 | ./asan_symbolize.py  | c++filt ")
 738     message(STATUS)
 739 endif()
 740
 741 set(LYX_CXX_FLAGS_EXTRA "" CACHE STRING "Desired semicolon separated list of extra cxx compile flags, like '-Werror'")
 742 mark_as_advanced(LYX_CXX_FLAGS_EXTRA)
 743 if(LYX_CXX_FLAGS_EXTRA)
 744         foreach(_flag ${LYX_CXX_FLAGS_EXTRA})
 745                 add_definitions(${_flag})
 746         endforeach()
 747 endif()
 748
 749 if(LYX_XMINGW)
 750         list(APPEND CMAKE_FIND_ROOT_PATH ${GNUWIN32_DIR})
 751 endif()
 752
 753 set(min_qt5_version "5.6")
 754 if(LYX_USE_QT MATCHES "AUTO")
 755         # try qt5 first
 756         find_package(Qt5Core CONFIG QUIET)
 757         if(Qt5Core_FOUND)
 758                 set(LYX_USE_QT "QT5" CACHE STRING "Valid qt version" FORCE)
 759                 message(STATUS "Qt5Core_VERSION = ${Qt5Core_VERSION}")
 760                 if(Qt5Core_VERSION VERSION_LESS ${min_qt5_version})
 761                         find_package(Qt4 "4.5.0" QUIET)
 762                         if(QT4_FOUND)
 763                                 set(LYX_USE_QT "QT4" CACHE STRING "Valid qt version" FORCE)
 764                         endif()
 765                 endif()
 766         else()
 767                 set(LYX_USE_QT "QT4" CACHE STRING "Valid qt version" FORCE)
 768         endif()
 769 endif()
 770 if(LYX_USE_QT MATCHES "QT5")
 771         # set QPA_XCB if QT uses X11
 772         find_package(Qt5Core CONFIG REQUIRED)
 773         if (Qt5Core_FOUND)
 774                 find_package(Qt5Widgets CONFIG REQUIRED)
 775                 if(APPLE)
 776                         find_package(Qt5MacExtras CONFIG REQUIRED)
 777                 endif()
 778                 find_package(Qt5X11Extras CONFIG QUIET)
 779                 find_package(Qt5WinExtras CONFIG QUIET)
 780                 set(QTVERSION ${Qt5Core_VERSION})
 781                 if (QTVERSION VERSION_LESS ${min_qt5_version})
 782                         message(STATUS "QTVERSION = \"${QTVERSION}\"")
 783                         message(STATUS "This version is not recommended, try either option -DLYX_USE_QT=QT4 or")
 784                         message(STATUS "install QT-Version >= \"${min_qt5_version}\"")
 785                         # see thread in lyx-devel list
 786                         # From: Jean-Pierre Chrétien <jeanpierre.chretien@free.fr>
 787                         # Date 11.03.2017
 788                         # Subject: cmake compilation error
 789                         #message(FATAL_ERROR "Wrong Qt-Version")
 790                 endif()
 791                 macro (qt_use_modules lyxtarget)
 792                         foreach (_tg ${ARGN})
 793                                 find_package(Qt5${_tg} CONFIG REQUIRED)
 794                                 target_link_libraries(${lyxtarget} Qt5::${_tg})
 795                         endforeach()
 796                 endmacro()
 797                 macro (qt_add_resources)
 798                         qt5_add_resources(${ARGN})
 799                 endmacro()
 800                 macro (qt_wrap_uifiles)
 801                         qt5_wrap_ui(${ARGN})
 802                 endmacro()
 803                 message(STATUS "Found Qt-Version ${QTVERSION}")
 804                 if(WIN32)
 805                         set(LYX_QTMAIN_LIBRARY ${Qt5Core_QTMAIN_LIBRARIES})
 806                 endif()
 807         endif()
 808 elseif(LYX_USE_QT MATCHES "QT4")
 809         if(LYX_XMINGW)
 810                 set(QT_MINGW_DIR ${LYX_QT4} CACHE PATH "Qt for Mingw" FORCE)
 811                 list(APPEND CMAKE_FIND_ROOT_PATH ${QT_MINGW_DIR} ${GNUWIN32_DIR})
 812         endif()
 813         find_package(Qt4 "4.5.0" REQUIRED)
 814         macro (qt_use_modules)
 815         endmacro()
 816         macro (qt_add_resources)
 817                 qt4_add_resources(${ARGN})
 818         endmacro()
 819         macro (qt_wrap_uifiles)
 820                 qt4_wrap_ui(${ARGN})
 821         endmacro()
 822         set(LYX_QTMAIN_LIBRARY ${QT_QTSVG_LIBRARY})
 823         if(WIN32)
 824                 list(APPEND LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARIES})
 825         endif()
 826 else()
 827   message(FATAL_ERROR "Unhandled value for LYX_USE_QT (${LYX_USE_QT})")
 828 endif()
 829
 830 find_package(Magic)
 831 if(Magic_FOUND)
 832   set(HAVE_MAGIC_H 1)
 833   include_directories(${Magic_INCLUDE_DIR})
 834 endif()
 835
 836 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 837
 838 set(Spelling_FOUND OFF)
 839 set(Include_used_spellchecker)   # String will be inserted into config.h
 840
 841 if (LYX_EXTERNAL_MYTHES MATCHES "AUTO")
 842   # try system library first
 843   find_package(MYTHESLIB)
 844   if (MYTHESLIB_FOUND)
 845     set(LYX_EXTERNAL_MYTHES ON CACHE STRING "OFF:= Build 3rdparty mytheslib" FORCE)
 846   else()
 847     set(LYX_EXTERNAL_MYTHES OFF CACHE STRING "OFF:= Build 3rdparty mytheslib" FORCE)
 848   endif()
 849 endif()
 850 if (LYX_EXTERNAL_MYTHES MATCHES "ON")
 851   find_package(MYTHESLIB REQUIRED)
 852 else()
 853   add_subdirectory(3rdparty/mythes)
 854 endif()
 855 set(MYTHES_DIR ${MYTHESLIB_INCLUDE_DIR})
 856
 857 if(NOT LYX_EXTERNAL_HUNSPELL)
 858     add_subdirectory(3rdparty/hunspell)
 859     add_definitions(-DHUNSPELL_STATIC)
 860     set(HUNSPELL_FOUND ON)
 861     message(STATUS "  * Hunspell:")
 862     message(STATUS "     - include: ${HUNSPELL_INCLUDE_DIR}")
 863     message(STATUS "     - library: ${HUNSPELL_LIBRARY}")
 864 endif()
 865
 866 foreach(_spell "ASPELL" "ENCHANT" "HUNSPELL")
 867   string(TOUPPER ${_spell} _upspell)
 868   if (NOT ${_upspell}_FOUND)
 869     find_package(${_spell})
 870   endif()
 871   if (${_upspell}_FOUND)
 872     include_directories(${${_upspell}_INCLUDE_DIR})
 873     set(Spelling_FOUND ON)
 874     message(STATUS "Building with USE_${_upspell}")
 875     set(Include_used_spellchecker "${Include_used_spellchecker}#define USE_${_upspell} 1\n")
 876   else()
 877     if(LYX_${_upspell})
 878       message(FATAL_ERROR "Required ${_spell} devel package not found")
 879     else()
 880       message(STATUS "${_upspell} not found, building without ${_spell} support")
 881     endif()
 882   endif()
 883 endforeach()
 884
 885 if(GNUWIN32_DIR)
 886         list(APPEND CMAKE_PROGRAM_PATH "${GNUWIN32_DIR}/Python" )
 887 endif()
 888
 889 # Search for python default version first
 890 unset(PYTHON_EXECUTABLE CACHE)
 891 unset(LYX_PYTHON_EXECUTABLE CACHE)
 892 unset(PYTHON_VERSION_MAJOR)
 893 unset(PYTHON_VERSION_MINOR)
 894 unset(PYTHON_VERSION_STRING)
 895 if (CMAKE_VERSION VERSION_LESS "3.13")
 896   find_package(PythonInterp 3.5 QUIET)
 897   if(NOT PYTHONINTERP_FOUND)
 898     find_package(PythonInterp 2.0 REQUIRED)
 899     if(NOT PYTHON_VERSION_STRING VERSION_LESS 2.8)
 900       message(FATAL_ERROR "Python interpreter found, but is not suitable")
 901     endif()
 902   endif()
 903   set(LYX_PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 904 else()
 905   find_package(Python3 3.5 QUIET)
 906   if(NOT Python3_Interpreter_FOUND)
 907     unset(PYTHON_EXECUTABLE CACHE)
 908     find_package(Python2 2.0 REQUIRED)
 909     if(NOT Python2_VERSION VERSION_LESS 2.8)
 910       message(FATAL_ERROR "Python interpreter found, but is not suitable")
 911     endif()
 912     set(LYX_PYTHON_EXECUTABLE ${Python2_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 913   else()
 914     set(LYX_PYTHON_EXECUTABLE ${Python3_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 915   endif()
 916 endif()
 917
 918 if(LYX_NLS)
 919         find_package(LyXGettext)
 920         if(LYX_PYTHON_EXECUTABLE AND GETTEXT_FOUND)
 921                 add_subdirectory(po "${TOP_BINARY_DIR}/po")
 922         else()
 923                 # Install only supplied .gmo-files
 924                 file(GLOB _gmofiles RELATIVE "${TOP_SRC_DIR}/po" "${TOP_SRC_DIR}/po/*.gmo")
 925                 message(STATUS "Installing provided .gmo-files only")
 926                 foreach( _gmo ${_gmofiles})
 927                         string(REGEX REPLACE "\\.gmo$" "" _lang ${_gmo})
 928                         install(FILES "${TOP_SRC_DIR}/po/${_gmo}" DESTINATION ${LYX_LOCALEDIR}/${_lang}/LC_MESSAGES RENAME ${PACKAGE}.mo)
 929                 endforeach()
 930         endif()
 931 endif()
 932
 933 if(LYX_EXTERNAL_ICONV)
 934   # Possible remnants of previous run without external iconv
 935   file(REMOVE_RECURSE "${CMAKE_BINARY_DIR}/libiconv" "${CMAKE_BINARY_DIR}/3rdparty/libiconv")
 936   find_package(ICONV REQUIRED)
 937 else()
 938   add_subdirectory(3rdparty/libiconv)
 939   set(HAVE_ICONV_CONST 1)
 940 endif()
 941
 942 if(LYX_EXTERNAL_Z)
 943   find_package(ZLIB REQUIRED)
 944 else()
 945   add_subdirectory(3rdparty/zlib)
 946 endif()
 947
 948 if(NOT LYX_EXTERNAL_DTL)
 949   add_subdirectory(3rdparty/dtl)
 950 endif()
 951
 952 if(LYX_USE_STD_REGEX)
 953   # Set only include path.
 954   # Use internal boost, which is known to exist
 955   # we don't need any libraries
 956   set(Lyx_Boost_Libraries)
 957   add_definitions(-DBOOST_USER_CONFIG=<config.h>)
 958   include_directories(${TOP_SRC_DIR}/3rdparty/boost)
 959 else()
 960   # Using boost-regex
 961   if(LYX_EXTERNAL_BOOST)
 962     message(STATUS "Searching for external boost")
 963     find_package(Boost COMPONENTS regex)
 964     if(Boost_FOUND)
 965       message(STATUS "Boost found")
 966       message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 967       set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 968       if (LYX_STDLIB_DEBUG OR LYX_DEBUG_GLIBC OR LYX_DEBUG_GLIBC_PEDANTIC)
 969         # Comment from  Jean-Marc Lasgouttes:
 970         # In general, system boost libraries are incompatible with
 971         # the use of stdlib-debug in libstdc++. See ticket #9736 for
 972         # details.
 973         message(FATAL_ERROR "Compiling LyX with stdlib-debug and system boost libraries may lead to crashes. Consider using '-DLYX_STDLIB_DEBUG=OFF -DLYX_DEBUG_GLIBC=OFF -DLYX_DEBUG_GLIBC_PEDANTIC=OFF' or using '-DLYX_EXTERNAL_BOOST=OFF'")
 974       endif()
 975     else()
 976       message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 977     endif()
 978   else()
 979     # Using included boost
 980     set(Lyx_Boost_Libraries boost_regex)
 981     add_definitions(-DBOOST_USER_CONFIG=<config.h>)
 982     include_directories(${TOP_SRC_DIR}/3rdparty/boost)
 983     add_subdirectory(3rdparty/boost "${TOP_BINARY_DIR}/3rdparty/boost")
 984   endif()
 985 endif()
 986
 987 if(WIN32)
 988         if(LYX_CONSOLE)
 989                 set(LYX_QTMAIN_LIBRARY)
 990         else()
 991                 set(WIN32_CONSOLE WIN32)
 992         endif()
 993         if(MSVC)
 994                 # -DPSAPI_VERSION=1 is needed to run on vista (bug 10186)
 995                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX -DPSAPI_VERSION=1)
 996                 # disable checked iterators for msvc release builds to get maximum speed
 997                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 998         else()
 999                 # -DPSAPI_VERSION=1 is not needed for mingw, since the mingw psapi.h
1000                 # does not use it and always declares the vista compatible API.
1001                 # If this ever changes then -DPSAPI_VERSION might be needed here as well.
1002                 add_definitions(-DWINVER=0x0500)
1003         endif()
1004 endif()
1005
1006 # Compute qt-version from ${QTVERSION}
1007
1008 message(STATUS "")
1009 foreach(_v PACKAGE PACKAGE_VERSION
1010         PROGRAM_SUFFIX LYX_VERSION LYX_DIR_VER LYX_USERDIR_VER
1011         LYX_ABS_TOP_SRCDIR
1012         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
1013         if(NOT DEFINED ${_v})
1014                 message(FATAL_ERROR "${_v} not defined")
1015         endif()
1016         string(SUBSTRING "${_v}                            " 0 28 _v1)
1017         message(STATUS "----- ${_v1}: ${${_v}}")
1018 endforeach(_v)
1019 message(STATUS "")
1020
1021
1022 if(LYX_PCH)
1023         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
1024         # Not sure if it works for all non-msvc compilers
1025         include(PCHSupport_26)
1026         configure_file(${TOP_CMAKE_PATH}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
1027         configure_file(${TOP_CMAKE_PATH}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
1028         add_definitions(-DLYX_ENABLE_PCH)
1029
1030         if(MSVC)
1031                 macro(lyx_add_msvc_pch name_)
1032                         set_source_files_properties(${${name_}_sources} PROPERTIES
1033                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
1034                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
1035                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
1036                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
1037                                 ${TOP_BINARY_DIR}/pcheaders.h)
1038                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
1039                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
1040                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
1041                 endmacro(lyx_add_msvc_pch)
1042                 macro(lyx_add_gcc_pch name_)
1043                 endmacro()
1044         else()
1045                 macro(lyx_add_msvc_pch name_)
1046                 endmacro()
1047                 macro(lyx_add_gcc_pch name_)
1048                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT)
1049                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
1050                 endmacro()
1051         endif()
1052 else()
1053         macro(lyx_add_msvc_pch)
1054         endmacro(lyx_add_msvc_pch)
1055         macro(lyx_add_gcc_pch name_)
1056         endmacro()
1057 endif()
1058
1059
1060 if(MSVC)
1061
1062         if(LYX_VLD)
1063                 set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/development/Win32/vld)
1064                 add_subdirectory(${vld_path}/cmake)
1065                 include(${vld_path}/cmake/vld.cmake) # forced include
1066                 set(vld_dll vld)
1067         endif()
1068
1069         if(LYX_WALL)
1070                 # Use the highest warning level
1071                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE STRING "Warning level" FORCE)
1072
1073                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
1074                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
1075                 else()
1076                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
1077                 endif()
1078
1079                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
1080                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
1081                 else()
1082                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
1083                 endif()
1084
1085                 # add here warnings which should produce an error /weXXXX
1086                 set(MSVC_W_ERROR   "/we4101 /we4189")
1087                 # add here warnings which should be disabled /wdXXXX
1088                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
1089
1090                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /W4 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1091                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /W4 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1092                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /W4 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1093
1094         else()
1095                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE STRING "Warning level" FORCE)
1096
1097                 # add here warnings which should produce an error /weXXXX
1098                 set(MSVC_W_ERROR   "/we4101 /we4189")
1099                 # add here warnings which should be disabled /wdXXXX
1100                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
1101
1102                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1103                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1104                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1105
1106         endif()
1107
1108         if (NOT Qt5Core_FOUND)
1109                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
1110                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
1111                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
1112         endif()
1113
1114         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
1115         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
1116         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
1117         message(STATUS "")
1118 endif()
1119
1120
1121 # Xcode compiler
1122 if (CMAKE_GENERATOR MATCHES Xcode)
1123         if (XCODE_VERSION VERSION_LESS "5.0")
1124                 # Automatically select the Xcode compiler if not set
1125                 if (NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
1126                         # XCode >= 3.1 has gcc 4.2 (up to actual Xcode)
1127                         if (XCODE_VERSION VERSION_GREATER "3.1")
1128                                 SET(CMAKE_XCODE_ATTRIBUTE_GCC_VERSION "com.apple.compilers.llvmgcc42")
1129                         ENDIF(XCODE_VERSION VERSION_GREATER "3.1")
1130                 ENDIF(NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
1131                 # Print the selected compiler version
1132         MESSAGE(STATUS "---- Using XCode compiler CMAKE_XCODE_ATTRIBUTE_GCC_VERSION=${CMAKE_XCODE_ATTRIBUTE_GCC_VERSION}")
1133         ENDIF(XCODE_VERSION VERSION_LESS "5.0")
1134 ENDIF(CMAKE_GENERATOR MATCHES Xcode)
1135
1136 if (WIN32 AND Qt5Core_FOUND)
1137         set(Z_PREFIX 1)
1138 endif()
1139
1140 # compiler tests, config.h generation LYX_CONFIGURE_CHECKS
1141 include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
1142 configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
1143
1144 unset(opts)
1145 foreach(_option ${LYX_OPTIONS})
1146   if(${_option}_show_message)
1147     string(SUBSTRING "${_option}                            " 0 31 _var)
1148     get_property(_prop CACHE ${_option} PROPERTY STRINGS)
1149     list(FIND LYX_OPTION_STRINGS ${_option} _index)
1150     if (${_index} GREATER -1)
1151       set(_isset ${${_option}})
1152     elseif(${_option})
1153       set(_isset ON)
1154     else()
1155       set(_isset OFF)
1156     endif()
1157     string(SUBSTRING "${_isset}           " 0 10 _val)
1158     set(opts "${opts} ${_option}(${${_option}})")
1159   endif()
1160 endforeach()
1161 set(tmp_vi "CMake Build")
1162 list(APPEND tmp_vi "  Host name:               ${CMAKE_HOST_SYSTEM_NAME}")
1163 list(APPEND tmp_vi "  Host processor:          ${CMAKE_HOST_SYSTEM_PROCESSOR}")
1164 list(APPEND tmp_vi "  Build flags:             ${opts}")
1165 list(APPEND tmp_vi "  C++ Compiler:            ${CMAKE_CXX_COMPILER_ID} (${CMAKE_CXX_COMPILER_VERSION})")
1166 list(APPEND tmp_vi "  C++ Compiler flags:      ${CMAKE_CXX_FLAGS}")
1167 if (LYX_DEBUG)
1168 list(APPEND tmp_vi "  C++ Compiler user flags: ${CMAKE_CXX_FLAGS_DEBUG}")
1169 else()
1170 list(APPEND tmp_vi "  C++ Compiler user flags: ${CMAKE_CXX_FLAGS_RELEASE}")
1171 endif()
1172 list(APPEND tmp_vi "  Qt version:              ${QTVERSION}")
1173 list(APPEND tmp_vi "  LyX binary dir:          ${CMAKE_INSTALL_PREFIX}/${LYX_UTILITIES_INSTALL_PATH}")
1174 get_data_destination(dest_data)
1175 list(APPEND tmp_vi "  LyX files dir:           ${CMAKE_INSTALL_PREFIX}/${dest_data}")
1176 string(REPLACE ";" "\\n" VERSION_INFO "${tmp_vi}")
1177
1178 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
1179 unset(opts)
1180 unset(tmp_vi)
1181
1182 if(QTVERSION MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+).*")
1183         MATH(EXPR QT4_VERSION "(${CMAKE_MATCH_1}<<16)|(${CMAKE_MATCH_2}<<8)|${CMAKE_MATCH_3}")
1184 endif()
1185
1186 if (NOT HAVE_REGEX)
1187         set(LYX_USE_STD_REGEX 0)
1188 endif()
1189
1190
1191 set (cmd ${CMAKE_CTEST_COMMAND})
1192 if (MSVC)
1193         set (cmd ${cmd} -C ${CMAKE_CFG_INTDIR})
1194 else ()
1195         set (cmd ${cmd} -C ${CMAKE_BUILD_TYPE})
1196 endif ()
1197 add_custom_target (lyx_run_tests COMMAND ${cmd})
1198 set_target_properties(lyx_run_tests PROPERTIES FOLDER "tests")
1199
1200 if(LYX_INSTALL)
1201         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
1202                 message(STATUS "Python required to create doc!")
1203         else()
1204                 if(UNIX)
1205                         add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
1206                 endif()
1207                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
1208         endif()
1209 endif()
1210 include(../Install)
1211
1212 # By running the URL tests first, time can be saved when running the ctests in
1213 # parallel since the URL tests take a long time to run (e.g. 10 minutes).
1214 if(LYX_ENABLE_URLTESTS)
1215         add_subdirectory(development/checkurls "${TOP_BINARY_DIR}/checkurls")
1216 endif()
1217 add_subdirectory(src "${TOP_BINARY_DIR}/src")
1218 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
1219 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
1220 add_subdirectory(lib/examples "${TOP_BINARY_DIR}/lib/examples")
1221 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
1222 add_subdirectory(development/autotests "${TOP_BINARY_DIR}/autotests")
1223 add_subdirectory(development/batchtests "${TOP_BINARY_DIR}/batchtests")
1224
1225 message(STATUS)
1226 message(STATUS "Build params, switch LYX_* options by -DLYX_*=ON or OFF, LYX_* combos by -DLYX_*=value:")
1227 message(STATUS)
1228
1229 LYX_OPTION_LIST_ALL(used)
1230
1231
1232 if(LYX_NLS)
1233         message(STATUS)
1234         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
1235         message(STATUS)
1236         message(STATUS "  * iconv")
1237         message(STATUS "     - include: ${ICONV_INCLUDE_DIR}")
1238         message(STATUS "     - library: ${ICONV_LIBRARY}")
1239         message(STATUS "  * zlib")
1240         message(STATUS "     - include: ${ZLIB_INCLUDE_DIR}")
1241         message(STATUS "     - library: ${ZLIB_LIBRARY}")
1242         message(STATUS)
1243 endif()
1244
1245 # Apple has builtin native spell checker,
1246 # no need to warn for missing Aspell, Hunspell or Enchant
1247 if(NOT Spelling_FOUND AND NOT APPLE)
1248   if(LYX_REQUIRE_SPELLCHECK)
1249     set(_mode "FATAL_ERROR")
1250   else()
1251     set(_mode "STATUS")
1252   endif()
1253   message(${_mode} "No spellcheck libraries found. LyX will be unable use spellchecking")
1254 endif()
1255
1256 include("${TOP_CMAKE_PATH}/LyxPackaging.cmake")
1257
1258 if(ENABLE_DIST)
1259   # Use git to create the source package
1260   # git archive --format=tgz --output=/home/kornel/x.tar.gz master
1261   if(UNIX)
1262     set(DIST_FORMAT tgz)
1263   else()
1264     set(DIST_FORMAT zip)
1265   endif()
1266   set(DIST_NAME ${CMAKE_PROJECT_NAME}-${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}-${CMAKE_SYSTEM_NAME}.${DIST_FORMAT})
1267
1268   add_custom_command(
1269     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME}
1270     COMMAND  ${LYX_GITVERSION} archive --format=${DIST_FORMAT} --output=${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME} master
1271     WORKING_DIRECTORY ${TOP_SRC_DIR})
1272   add_custom_target(git-archive DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME})
1273 endif()
1274
1275 # Last directory to be included so that the fixup code (OS X)
1276 # can be run last
1277 add_subdirectory(development/cmake/post_install)
1278
1279 message(STATUS)