CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2020 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 3.1.0)
   8
   9 set(LYX_PROJECT LyX)
  10 # Instruct cmake to not use gnu extensions,
  11 # this prevents the mix of '-std=c++*' and '-std=gnu++*' flags
  12 set(CMAKE_CXX_EXTENSIONS OFF)
  13
  14 enable_testing()
  15
  16 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README REALPATH) # Resolve symlinks
  17 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  18 message(STATUS "TOP_SRC_DIR = ${TOP_SRC_DIR}")
  19
  20 set(LYX_CMAKE_DIR "development/cmake")
  21 set(TOP_CMAKE_PATH "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}")
  22 set(TOP_MODULE_PATH "${TOP_CMAKE_PATH}/modules")
  23 set(TOP_SCRIPT_PATH "${TOP_CMAKE_PATH}/scripts")
  24
  25 set(CMAKE_MODULE_PATH "${TOP_MODULE_PATH}")
  26
  27 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  28
  29 message(STATUS)
  30 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  31         message(STATUS "Building in-source")
  32         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  33 else()
  34         message(STATUS "Building out-of-source")
  35         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  36 endif()
  37
  38 # This directory should be used if some test uses lyx-executable
  39 set(LYX_TESTS_USERDIR "${TOP_BINARY_DIR}/Testing/.lyx")
  40 file(MAKE_DIRECTORY "${LYX_TESTS_USERDIR}")
  41
  42 if(COMMAND cmake_policy)
  43         # Installing MACOSX_BUNDLE targets requires a BUNDLE DESTINATION
  44         cmake_policy(SET CMP0006 NEW)
  45         if(POLICY CMP0043)
  46                 # COMPILE_DEFINITIONS are not used yet. Enable new behavior.
  47                 cmake_policy(SET CMP0043 NEW)
  48         endif()
  49         cmake_policy(SET CMP0020 NEW)
  50         if(POLICY CMP0075)
  51                 cmake_policy(SET CMP0075 NEW)
  52         endif()
  53         if(POLICY CMP0077)
  54                 cmake_policy(SET CMP0077 NEW)
  55         endif()
  56 endif()
  57
  58 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  59
  60 # Supress regeneration
  61 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  62
  63 if(LYX_XMINGW)
  64     set(CMAKE_SYSTEM_NAME Windows)
  65     set(TOOLNAME ${LYX_XMINGW})
  66     set(TOOLCHAIN "${TOOLNAME}-")
  67     set(CMAKE_C_COMPILER   "${TOOLCHAIN}gcc"     CACHE PATH "Mingw C compiler" FORCE)
  68     set(CMAKE_CXX_COMPILER "${TOOLCHAIN}g++"     CACHE PATH "Mingw C++ compiler" FORCE)
  69     set(CMAKE_RC_COMPILER  "${TOOLCHAIN}windres" CACHE PATH "Mingw rc compiler" FORCE)
  70
  71     set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM BOTH)
  72     set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY)
  73     set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY)
  74 endif()
  75
  76 if(NOT help AND NOT HELP)
  77   # 'project' triggers the searching for a compiler
  78   project(${LYX_PROJECT})
  79   if (CMAKE_COMPILER_IS_GNUCXX)
  80     if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS "4.9")
  81       message(STATUS "Gnu CXX compiler version = ${CMAKE_CXX_COMPILER_VERSION}")
  82       message(STATUS "is too old, should be >= 4.9")
  83       message(FATAL_ERROR "Exiting")
  84     endif()
  85   endif()
  86 endif()
  87
  88 if(UNIX)
  89         set(ARCH_TRIPLET )
  90         FIND_PROGRAM(DPKG_ARCHITECTURE_EXECUTABLE dpkg-architecture)
  91         if(DPKG_ARCHITECTURE_EXECUTABLE)
  92                 EXECUTE_PROCESS(COMMAND ${DPKG_ARCHITECTURE_EXECUTABLE} -qDEB_HOST_MULTIARCH
  93                                 OUTPUT_VARIABLE ARCH_TRIPLET
  94                                 ERROR_VARIABLE ERROR_ARCH_TRIPLET
  95                                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  96         endif()
  97 endif()
  98 if(ARCH_TRIPLET)
  99         set(SYSTEM_LIB_DIRS /usr/lib /usr/lib/${ARCH_TRIPLET} /usr/local/lib)
 100 else()
 101         set(SYSTEM_LIB_DIRS /usr/lib /usr/local/lib)
 102 endif()
 103
 104 include(LyXMacros)
 105 include(LyXDestinations)
 106
 107 # Value of USE_POSIX_PACKAGING is needed in determineversionandbuildtype()
 108 if(WIN32)
 109         set(CMAKE_PREFIX_PATH Specify-path-to-Qt CACHE PATH "Used Qt version")
 110         if(MSVC)
 111                 set(LYX_3RDPARTY_BUILD ON CACHE BOOL "Build 3rdparty libraries" FORCE)
 112         endif()
 113         set(USE_WINDOWS_PACKAGING ON)
 114 elseif(APPLE)
 115         set(USE_MACOSX_PACKAGING ON)
 116 else()
 117         set(USE_POSIX_PACKAGING ON)
 118 endif()
 119
 120 determineversionandbuildtype("${TOP_SRC_DIR}/configure.ac" _package_list _version_list _envlist LYX_DATE LYX_BUILD_TYPE)
 121 list(GET _package_list 0 PACKAGE_BASE)
 122 list(GET _package_list 1 PACKAGE_VERSION)
 123 list(GET _package_list 2 PACKAGE_BUGREPORT)
 124 list(GET _envlist 0 LYX_DIR_VER)
 125 list(GET _envlist 1 LYX_USERDIR_VER)
 126 list(GET _version_list 0 LYX_VERSION)
 127 list(GET _version_list 1 LYX_MAJOR_VERSION)
 128 list(GET _version_list 2 LYX_MINOR_VERSION)
 129 list(GET _version_list 3 LYX_RELEASE_LEVEL)
 130 list(GET _version_list 4 LYX_RELEASE_PATCH)
 131
 132 # Usage LYX_OPTION
 133 # 1. parameter: option name without prefix 'LYX_'
 134 # 2. parameter: description
 135 # 3. parameter: default value, ON or OFF
 136 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
 137
 138 # Usage LYX_COMBO
 139 # 1. parameter: name without prefix 'LYX_'
 140 # 2. parameter: description
 141 # 3. parameter: default value
 142 # 4-n parameter: possible other string values
 143
 144 LYX_OPTION_INIT()
 145 LYX_COMBO(ENABLE_BUILD_TYPE  "Allows to tweak the compiled code" AUTO release prerelease development gprof)
 146
 147 if(LYX_ENABLE_BUILD_TYPE MATCHES "AUTO")
 148   message(STATUS "Selecting build type defaults from configure.ac")
 149 else()
 150   set(LYX_BUILD_TYPE "${LYX_ENABLE_BUILD_TYPE}")
 151   message(STATUS "Selecting build type defaults from LYX_ENABLE_BUILD_TYPE")
 152 endif()
 153
 154 # Select some defaults depending on LYX_BUILD_TYPE
 155 # they can always be overwritten by the respective command line settings
 156 # These settings are only effective on fresh(==empty) CMakeCache.txt
 157 if(LYX_BUILD_TYPE STREQUAL "development")
 158   set(DefaultLyxDebug ON)
 159   set(DefaultLyxRelease OFF)
 160   set(DefaultLyxStdlibDebug ON)
 161   set(DefaultLyxEnableAssertions ON)
 162   set(DefaultLyxProfile OFF)
 163   set(DefaultExternalLibs OFF)
 164 elseif(LYX_BUILD_TYPE STREQUAL "prerelease")
 165   set(DefaultLyxDebug OFF)
 166   set(DefaultLyxRelease OFF)
 167   set(DefaultLyxStdlibDebug OFF)
 168   set(DefaultLyxEnableAssertions OFF)
 169   set(DefaultLyxProfile OFF)
 170   set(DefaultExternalLibs ON)
 171 elseif(LYX_BUILD_TYPE STREQUAL "release")
 172   set(DefaultLyxDebug OFF)
 173   set(DefaultLyxRelease ON)
 174   set(DefaultLyxStdlibDebug OFF)
 175   set(DefaultLyxEnableAssertions OFF)
 176   set(DefaultLyxProfile OFF)
 177   set(DefaultExternalLibs ON)
 178 elseif(LYX_BUILD_TYPE STREQUAL "gprof")
 179   set(DefaultLyxDebug ON)
 180   set(DefaultLyxRelease OFF)
 181   set(DefaultLyxStdlibDebug OFF)
 182   set(DefaultLyxEnableAssertions OFF)
 183   set(DefaultLyxProfile ON)
 184   set(DefaultExternalLibs OFF)
 185 else()
 186   message(FATAL_ERROR "Invalid build type (${LYX_BUILD_TYPE}) encountered")
 187 endif()
 188
 189 # Options for all compilers/systems
 190 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
 191 LYX_OPTION(LOCALVERSIONING  "Add version info to created package name (only used if LYX_CPACK option set)" OFF ALL)
 192 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
 193 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
 194 LYX_OPTION(REQUIRE_SPELLCHECK "Abort if no spellchecker available" OFF ALL)
 195 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
 196 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
 197 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
 198 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" ${DefaultLyxRelease} ALL)
 199 LYX_OPTION(DEBUG            "Enforce debug build"  ${DefaultLyxDebug} ALL)
 200 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
 201 LYX_OPTION(ENABLE_ASSERTIONS "Run sanity checks in the program"  ${DefaultLyxEnableAssertions} ALL)
 202 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
 203 LYX_STRING(SUFFIX_VALUE     "Use this string as suffix" "")
 204 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
 205 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
 206 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
 207 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
 208 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
 209 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
 210 LYX_OPTION(ENABLE_URLTESTS  "Enable for URL tests" OFF ALL)
 211 LYX_OPTION(ENABLE_EXPORT_TESTS "Enable for export tests" OFF ALL)
 212 LYX_OPTION(ENABLE_KEYTESTS  "Enable for keytests" OFF ALL)
 213 if (NOT CMAKE_VERSION VERSION_LESS "3.17")
 214   LYX_OPTION(ENABLE_VALGRIND_TESTS  "Enable for tests involving valgrind" OFF ALL)
 215 else()
 216   if (LYX_ENABLE_VALGRIND_TESTS)
 217     unset(LYX_ENABLE_VALGRIND_TESTS CACHE)
 218   endif()
 219 endif()
 220 LYX_OPTION(ASAN             "Use address sanitizer" OFF ALL)
 221 #LYX_COMBO(USE_FILEDIALOG    "Use native or QT file dialog" QT NATIVE)
 222 LYX_COMBO(USE_QT            "Use Qt version as frontend" AUTO QT4 QT5)
 223 LYX_COMBO(USE_IPO           "Interprocedural optimization" OFF AUTO ON)
 224 #LYX_OPTION(3RDPARTY_BUILD   "Build 3rdparty libs" OFF ALL)
 225 LYX_OPTION(DISABLE_CALLSTACK_PRINTING "do not print a callstack when crashing" OFF ALL)
 226 LYX_OPTION(EXTERNAL_Z       "OFF := Build 3rdparty lib zlib" ${DefaultExternalLibs} ALL)
 227 LYX_OPTION(EXTERNAL_DTL     "OFF := Build 3rdparty commands dt2dv and dv2dt" ${DefaultExternalLibs} ALL)
 228 LYX_OPTION(EXTERNAL_ICONV   "OFF := Build 3rdparty lib iconvlib" ${DefaultExternalLibs} ALL)
 229 LYX_OPTION(EXTERNAL_HUNSPELL "OFF := Build 3rdparty lib hunspelllib" ${DefaultExternalLibs} ALL)
 230 LYX_COMBO(EXTERNAL_MYTHES   "OFF := Build 3rdparty lib mytheslib" AUTO OFF ON)
 231
 232 # GCC specific
 233 LYX_OPTION(PROFILE              "Build with options for gprof" ${DefaultLyxProfile} GCC)
 234 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
 235 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
 236 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++ pedantic debug mode" OFF GCC)
 237 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" ${DefaultLyxStdlibDebug} GCC)
 238
 239 # MSVC specific
 240 LYX_OPTION(CONSOLE               "Show console on Windows" ON MSVC)
 241 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
 242 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
 243 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
 244
 245 # APPLE specific
 246 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
 247 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
 248
 249 # Try to get some informations from configure.ac
 250 include(LyXPaths)
 251
 252
 253 if(help OR HELP)
 254         message(STATUS)
 255         message(STATUS "Available options: (dis/enable with -DLYX_*=OFF/ON)")
 256         message(STATUS)
 257         LYX_OPTION_LIST_ALL(help)
 258         message(STATUS)
 259         unset(help CACHE)
 260         unset(HELP CACHE)
 261         RETURN()
 262 endif()
 263
 264 if ("${LYX_SUFFIX_VALUE}" MATCHES "")
 265   set(LYX_INSTALL_SUFFIX "${LYX_MAJOR_VERSION}.${LYX_MINOR_VERSION}")
 266 else()
 267   set(LYX_INSTALL_SUFFIX "${LYX_SUFFIX_VALUE}")
 268 endif()
 269
 270 # Check option dependencies
 271 if (LYX_ENABLE_VALGRIND_TESTS)
 272         find_program(VALGRIND_EXECUTABLE "valgrind")
 273         if (NOT VALGRIND_EXECUTABLE)
 274                 message(FATAL_ERROR "Cannot use valgrind tests, executable valgrind is missing. Please disable LYX_ENABLE_VALGRIND_TESTS")
 275         endif()
 276 endif()
 277
 278 if(LYX_DMG)
 279         set(LYX_BUNDLE ON)
 280         set(LYX_CPACK ON)
 281 endif()
 282
 283 if(LYX_CPACK)
 284         set(LYX_INSTALL ON)
 285 endif()
 286
 287 if(LYX_INSTALL)
 288         set(LYX_NLS ON)
 289         if(WIN32 AND NOT MINGW)
 290                 set(LYX_HUNSPELL ON)
 291         endif()
 292         set(LYX_PACKAGE_SUFFIX ON)
 293         if(NOT LYX_DEBUG)
 294                 set(LYX_RELEASE ON)
 295         endif()
 296         set(LYX_PROFILE OFF)
 297 endif()
 298
 299
 300 if(LYX_MERGE_FILES)
 301         set(LYX_PCH OFF)
 302 else()
 303         set(LYX_MERGE_REBUILD OFF)
 304 endif()
 305
 306 if(LYX_DEPENDENCIES_DOWNLOAD)
 307         message(STATUS)
 308         if(MSVC14)
 309                 set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2015-deps)
 310                 set(deps_files lyx-windows-deps-msvc2015.zip)
 311                 set(deps_server http://ftp.lyx.de/LyX-Windows-Deps)
 312                 set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2015)
 313         elseif(MSVC10)
 314                 set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 315                 set(deps_files lyx-windows-deps-msvc2010.zip)
 316                 set(deps_server http://ftp.lyx.de/LyX-Windows-Deps)
 317                 set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2010)
 318         else()
 319                 message(FATAL_ERROR "error: no dependency package known for the selected MSVC version.")
 320         endif()
 321     message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 322         foreach(it ${deps_files})
 323                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 324                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 325                 if(NOT already_downloaded)
 326                         message(STATUS "Downloading ${it} ...")
 327                         file(DOWNLOAD ${deps_server}/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS STATUS status LOG log)
 328                         list(GET status 0 status_code)
 329                         list(GET status 1 status_string)
 330                         if(NOT status_code EQUAL 0)
 331                                 file(REMOVE ${LYX_DEPENDENCIES_DIR}/${it})
 332                                 message(FATAL_ERROR "error: downloading '${it}' failed. status_code: ${status_code}, status_string: ${status_string}. \nLog: ${log} ")
 333                         endif()
 334                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 335                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 336                 endif()
 337         endforeach()
 338 endif()
 339
 340 message(STATUS)
 341
 342 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 343 if(WIN32)
 344         set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 345 else()
 346         set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 347 endif()
 348
 349 set(LYX_IPO_SUPPORTED OFF)
 350 if (POLICY CMP0069)
 351   cmake_policy(SET CMP0069 NEW)
 352   if(LYX_USE_IPO MATCHES "AUTO")
 353     # Enable LTO if supported and not debugging
 354     if (NOT LYX_DEBUG)
 355       include(CheckIPOSupported)
 356       check_ipo_supported(RESULT LYX_IPO_SUPPORTED)
 357     endif()
 358   else()
 359     set(LYX_IPO_SUPPORTED ${LYX_USE_IPO})
 360   endif()
 361 endif()
 362 if (LYX_IPO_SUPPORTED)
 363   set(LYX_USE_IPO "ON" CACHE STRING "Use interprocedural optimization" FORCE)
 364 else()
 365   set(LYX_USE_IPO "OFF" CACHE STRING "Use interprocedural optimization" FORCE)
 366 endif()
 367
 368 # Set to some meaningful default
 369 find_package(CXX11Compiler)
 370 if(NOT CXX11COMPILER_FOUND)
 371         message(FATAL_ERROR "A C++11 compatible compiler is required.")
 372 endif()
 373 unset(LYX_GCC11_MODE)
 374 if(UNIX OR MINGW)
 375         if (CMAKE_CXX_COMPILER_ID MATCHES "^([cC]lang|AppleClang)$")
 376           # ignore the GCC_VERSION for clang
 377           message(STATUS "Using clang")
 378         else()
 379           execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpfullversion OUTPUT_VARIABLE GCC_VERSION ERROR_VARIABLE _error RESULT_VARIABLE _err OUTPUT_STRIP_TRAILING_WHITESPACE)
 380           #message(STATUS "dumpfullversion: error = ${_error}, result = ${_err}")
 381           if (_err)
 382             # previous check failed, try again with _old_ parameter
 383             execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION ERROR_VARIABLE _error RESULT_VARIABLE _err OUTPUT_STRIP_TRAILING_WHITESPACE)
 384             #message(STATUS "dumpversion: error = ${_error}, result = ${_err}")
 385           endif()
 386           message(STATUS "Using GCC version ${GCC_VERSION}")
 387           if(GCC_VERSION VERSION_LESS 4.9)
 388                 message(FATAL_ERROR "gcc >= 4.9 is required.")
 389           endif()
 390         endif()
 391         set(LYX_GCC11_MODE "${CXX11_FLAG}")
 392 else()
 393         if(MSVC_VERSION LESS 1900)
 394                 # Drop support for msvc versions prior to 1900 (Visual Studio 2015)
 395                 message(FATAL_ERROR "Visual Studio >= 2015 is required.")
 396         endif()
 397 endif()
 398
 399 if(LYX_3RDPARTY_BUILD)
 400   # LYX_3RDPARTY_BUILD is not cached anymore, but for compatibility reasons
 401   # this enables the build of all 3rd_party libs
 402   set(LYX_EXTERNAL_Z        OFF CACHE BOOL "Build 3rdparty lib zlib"    FORCE)
 403   set(LYX_EXTERNAL_ICONV    OFF CACHE BOOL "Build 3rdparty iconvlib"    FORCE)
 404   set(LYX_EXTERNAL_HUNSPELL OFF CACHE BOOL "Build 3rdparty hunspelllib" FORCE)
 405   set(LYX_EXTERNAL_MYTHES   OFF CACHE STRING "Build 3rdparty mytheslib" FORCE)
 406 endif()
 407
 408 FIND_PROGRAM(LYX_GITVERSION git)
 409 #message(STATUS "gitversion = ${LYX_GITVERSION}")
 410 set(LYX_REVISION_VERSION ${LYX_RELEASE_LEVEL})
 411 set(LYX_PACKAGE_RELEASE "UNDEFINED")
 412 if(LYX_GITVERSION)
 413   if (LYX_LOCALVERSIONING)
 414     # Find the revision number for later use
 415     EXECUTE_PROCESS(COMMAND ${LYX_GITVERSION} describe --match 2.0.0 HEAD
 416       WORKING_DIRECTORY "${TOP_SRC_DIR}"
 417       RESULT_VARIABLE tmp_GIT_RESULT
 418       OUTPUT_VARIABLE tmp_LYX_PACKAGE_RELEASE
 419       ERROR_VARIABLE tmp_GIT_ERROR
 420       OUTPUT_STRIP_TRAILING_WHITESPACE)
 421     if (tmp_GIT_RESULT EQUAL 0)
 422       if (tmp_LYX_PACKAGE_RELEASE MATCHES "^2\\.0\\.0\\-\([0-9]+\)\\-\(.*\)$")
 423         set(LYX_PACKAGE_RELEASE ${CMAKE_MATCH_2})
 424         # We will add offset of 40000 to get appropriate value to
 425         # previous svn.
 426         # We use this value than also to set the package-patch-value
 427         MATH(EXPR tmp_REVISION_VERSION "(${CMAKE_MATCH_1}+40000)")
 428         set(LYX_REVISION_VERSION "${LYX_RELEASE_LEVEL}-${tmp_REVISION_VERSION}git")
 429         set(ENABLE_DIST ON)
 430       endif()
 431     endif()
 432   endif()
 433 endif()
 434 if (LYX_PACKAGE_RELEASE MATCHES "UNDEFINED")
 435   set(LYX_PACKAGE_RELEASE  "1")
 436   if (LYX_RELEASE_PATCH GREATER 0)
 437     set(LYX_REVISION_VERSION "${LYX_RELEASE_LEVEL}.${LYX_RELEASE_PATCH}")
 438   endif()
 439 endif()
 440
 441 # Set the programs (lyx, tex2lyx, etc.) suffix
 442 # When building an OS X bundle, we will append
 443 # the suffix only to the bundle, not to the programs
 444 set(PROGRAM_SUFFIX "")
 445 if(LYX_PROGRAM_SUFFIX AND NOT (APPLE AND LYX_BUNDLE))
 446         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 447 endif()
 448 set(_lyx "${PACKAGE_BASE}${PROGRAM_SUFFIX}")
 449 set(_tex2lyx tex2lyx${PROGRAM_SUFFIX})
 450 set(_convert lyxconvert${PROGRAM_SUFFIX})
 451
 452 add_custom_target(lyx_version ALL
 453   COMMAND ${CMAKE_COMMAND} -DTOP_SRC_DIR=${TOP_SRC_DIR} -DTOP_CMAKE_PATH=${TOP_CMAKE_PATH} -DTOP_BINARY_DIR=${TOP_BINARY_DIR} -DLYX_DATE=${LYX_DATE} -P ${TOP_SCRIPT_PATH}/LyXGetVersion.cmake
 454   )
 455 set_target_properties(lyx_version PROPERTIES FOLDER "applications")
 456
 457 # Default paths for installed utilities (tex2lyx, lyxclient, etc.)
 458 set(LYX_UTILITIES_INSTALL_PATH bin)
 459
 460 if(LYX_BUNDLE)
 461         set(LYX_CPACK ON)
 462
 463         message(STATUS)
 464         message(STATUS "Bundle creation is enabled (experimental):")
 465         message(STATUS "    make")
 466         message(STATUS "    make install/strip")
 467         message(STATUS "    make package")
 468         if(APPLE)
 469                 set(MACOSX_BUNDLE TRUE)
 470                 # This sets the bundle + executable names
 471                 set(_lyx "${PACKAGE_BASE}${LYX_INSTALL_SUFFIX}")
 472                 # This sets the Info.plist executable name
 473                 set(osx_bundle_program_name ${_lyx})
 474                 # Bundle name
 475                 set(LYX_BUNDLE_NAME ${_lyx})
 476
 477                 # This will contain the list of files that need to be included
 478                 # in the bundle and their location within the bundle
 479                 set(OSX_BUNDLE_FILES "${TOP_SRC_DIR}/development/MacOSX/LyX.sdef;${TOP_SRC_DIR}/development/MacOSX/LyXapp.icns;${CMAKE_BINARY_DIR}/lyxrc.dist")
 480                 set(OSX_BUNDLE_DIRS "Resources;Resources;Resources")
 481
 482                 # Process Info.plist and lyxrc.dist
 483                 # See development/cmake/Install.cmake
 484                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/Info.plist.in" "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 485
 486                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 487                 set(LYX_DATA_SUBDIR ${LYX_BUNDLE_NAME}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 488
 489                 # Variables used by CPack
 490                 set(CPACK_BUNDLE_NAME ${LYX_BUNDLE_NAME})
 491                 set(CPACK_BUNDLE_PLIST "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 492                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${LYX_BUNDLE_NAME}.app)
 493
 494                 # Set the install paths
 495                 set(LYX_UTILITIES_INSTALL_PATH ${LYX_BUNDLE_NAME}.app/Contents/MacOS)
 496                 if(NOT LYX_INSTALL_PREFIX)
 497                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 498                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 499                 endif()
 500                 # Change the owner so that the install can work
 501                 install(CODE "set(BU_CHMOD_BUNDLE_ITEMS 1)" COMPONENT Runtime)
 502         elseif(UNIX)
 503                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 504                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 505                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 506         elseif(WIN32)
 507                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 508         endif()
 509 endif()
 510
 511 if(LYX_INSTALL_PREFIX)
 512         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 513         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 514 endif()
 515 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 516
 517 if(UNIX)
 518   set(SYSTEM_DATADIR "${CMAKE_INSTALL_PREFIX}/share")
 519 elseif(CMAKE_INSTALL_PREFIX MATCHES "/lyx${LYX_INSTALL_SUFFIX}$")
 520   string(REGEX REPLACE "/lyx${LYX_INSTALL_SUFFIX}$" "/share" SYSTEM_DATADIR ${CMAKE_INSTALL_PREFIX})
 521 else()
 522   set(SYSTEM_DATADIR "${CMAKE_INSTALL_PREFIX}")
 523 endif()
 524
 525 if(NOT CMAKE_COMPILER_IS_GNUCXX)
 526   # Not a GCC compiler, programs do not have a suffix
 527   set(suffixing ${LYX_PACKAGE_SUFFIX})
 528 elseif(WIN32 AND MINGW)
 529   # We want to use a suffix for the package in this case,
 530   # even if not for the program
 531   set(suffixing ${LYX_PACKAGE_SUFFIX})
 532 else()
 533   message(STATUS "CMAKE_COMPILER_IS_GNUCXX = ${CMAKE_COMPILER_IS_GNUCXX}")
 534   set(suffixing ${LYX_PROGRAM_SUFFIX})
 535 endif()
 536
 537 # The define PACKAGE below allows lyx-executable to find its default configuration files
 538 # see routines
 539 #    Package::messages_file()
 540 #    get_default_user_support_dir()
 541 #    relative_system_support_dir()
 542 # in src/support/Package.cpp
 543 if(suffixing)
 544         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 545 else()
 546         set(PACKAGE ${PACKAGE_BASE})
 547 endif()
 548
 549 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 550         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 551         if (UNIX)
 552                 # use the default "/usr/local"
 553                 # but respect the user-choice on the command-line
 554                 set(CMAKE_INSTALL_PREFIX "/usr/local" CACHE PATH "LyX default install prefix" FORCE)
 555         endif()
 556 endif()
 557 if(WIN32)
 558         set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 559 endif()
 560 if(IS_ABSOLUTE)
 561         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 562 else()
 563         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 564 endif()
 565
 566
 567
 568 if(NOT LYX_DATA_SUBDIR)
 569         if (WIN32)
 570                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 571         else()
 572                 set(LYX_DATA_SUBDIR "share/${_lyx}/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 573         endif()
 574 endif()
 575
 576 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}/${LYX_DATA_SUBDIR}")
 577 get_locale_destination(LYX_LOCALEDIR)
 578 set(LYX_ABS_INSTALLED_LOCALEDIR "${CMAKE_INSTALL_PREFIX}/${LYX_LOCALEDIR}")
 579 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 580
 581 if(LYX_BUNDLE AND APPLE)
 582         set(LYX_MAN_DIR_tmp "${LYX_DATA_SUBDIR}")
 583 else()
 584         if(WIN32)
 585                 set(LYX_MAN_DIR_tmp "${CMAKE_BINARY_DIR}/usr/local/man/")
 586         elseif(UNIX)
 587                 set(LYX_MAN_DIR_tmp "${CMAKE_INSTALL_PREFIX}/share/man/")
 588         else()
 589                 set(LYX_MAN_DIR_tmp "${CMAKE_INSTALL_PREFIX}/man/")
 590         endif()
 591 endif()
 592 if (NOT LYX_MAN_DIR_tmp EQUAL "${LYX_MAN_DIR}")
 593         unset(LYX_MAN_DIR CACHE)
 594         set(LYX_MAN_DIR "${LYX_MAN_DIR_tmp}" CACHE STRING "Install location for man pages.")
 595 endif()
 596 unset(LYX_MAN_DIR_tmp)
 597 mark_as_advanced(LYX_MAN_DIR)
 598
 599 # The Win installer cannot be built by CMake because one needs to install plugins for NSIS
 600 # see the Readme.txt of the installer
 601 #if(LYX_INSTALL AND WIN32)
 602 #       message(STATUS "Configuring NSIS files")
 603 #       configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 604 #       configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 605 #       configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 606 #       message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 607 #endif()
 608
 609 if(NOT GROUP_CODE)
 610         #set(GROUP_CODE "The Golden Code")
 611         set(GROUP_CODE flat)
 612 endif()
 613
 614 # lyx's source files
 615 set(LYX_CPP_FILES [a-zA-Z]*.cpp)
 616 set(LYX_HPP_FILES [a-zA-Z]*.h)
 617 set(LYX_MOC_FILES moc_*.cpp)
 618
 619 include(ProjectSourceGroup)
 620
 621
 622 if(LYX_PROFILE AND NOT MSVC)
 623         set(CMAKE_BUILD_TYPE Profile CACHE STRING "Profile build type" FORCE)
 624         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg")
 625         set(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS}  -pg")
 626 else()
 627         set(LYX_PROFILE OFF)
 628 endif()
 629
 630
 631 if(LYX_NO_OPTIMIZE)
 632         set(CMAKE_BUILD_TYPE None)
 633         set(LYX_DEBUG OFF)
 634         set(LYX_RELEASE OFF)
 635         set(LYX_PROFILE OFF)
 636 elseif(LYX_RELEASE)
 637         set(CMAKE_BUILD_TYPE Release)
 638         set(LYX_DEBUG OFF)
 639         set(LYX_PROFILE OFF)
 640 elseif(LYX_PROFILE)
 641         set(CMAKE_BUILD_TYPE Profile)
 642         set(LYX_DEBUG OFF)
 643 else()
 644         set(CMAKE_BUILD_TYPE Debug)
 645         set(LYX_DEBUG ON)
 646 endif()
 647
 648
 649 # When shared libs are supported enable this option
 650 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 651 if(LYX_SHARED_LIBRARIES)
 652         set(library_type SHARED)
 653 else()
 654         set(library_type STATIC)
 655 endif()
 656
 657 if(LYX_ENABLE_ASSERTIONS)
 658   set(LYX_CXX_FLAGS " -DENABLE_ASSERTIONS=1")
 659 else()
 660   set(LYX_CXX_FLAGS "")
 661 endif()
 662
 663 if(MSVC)
 664   if (CXX11_FLAG MATCHES "\\+\\+([0-9]+)")
 665     set(CMAKE_CXX_STANDARD ${CMAKE_MATCH_1})
 666     message(STATUS "CMAKE_CXX_STANDARD set to ${CMAKE_CXX_STANDARD}")
 667   endif()
 668   set(CMAKE_CXX_FLAGS       "${CMAKE_CXX_FLAGS}${LYX_CXX_FLAGS}")
 669 else()
 670         if(NOT LYX_QUIET)
 671                 set(CMAKE_VERBOSE_MAKEFILE ON)
 672         endif()
 673         if(LYX_GCC11_MODE MATCHES "\\+\\+([0-9][0-9])")
 674           # Thanks to Brad King <brad.king@kitware.com>
 675           # for the pointer to https://cmake.org/cmake/help/v3.6/variable/CMAKE_CXX_STANDARD.html
 676           # This allows us to use QT5.7 with recent g++ (version >= 4.9) compilers
 677           # and still use our own c++ extension tests
 678           set(std_num ${CMAKE_MATCH_1})
 679           set(CMAKE_CXX_STANDARD ${std_num})
 680         else()
 681           message(STATUS "Setting CMAKE_CXX_STANDARD 11 as fallback")
 682           set(CMAKE_CXX_STANDARD 11)
 683           set(LYX_GCC11_MODE "--std=c++11")
 684         endif()
 685         # The following setting with LYX_GCC11_MODE is needed because cmake does not honor
 686         # CMAKE_CXX_STANDARD while performing tests like
 687         # check_cxx_source_compiles("..." HAVE_DEF_MAKE_UNIQUE)
 688         set(LYX_CXX_FLAGS "-Wall -Wextra -Wno-deprecated-copy ${LYX_GCC11_MODE}${LYX_CXX_FLAGS}")
 689         if(LYX_STDLIB_DEBUG)
 690           set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 691         else()
 692           if(LYX_DEBUG_GLIBC)
 693             set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG")
 694           endif()
 695           if(LYX_DEBUG_GLIBC_PEDANTIC)
 696             set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG_PEDANTIC")
 697           endif()
 698         endif()
 699         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE STRING "Set CXX flags" FORCE)
 700         set(CMAKE_CXX_FLAGS_DEBUG "-O0 -g3 -D_DEBUG" CACHE STRING "Set debug flags" FORCE)
 701         if(MINGW)
 702                 set(CMAKE_CXX_FLAGS_RELEASE "-O2 -DNDEBUG" CACHE STRING "Set release flags for Mingw" FORCE)
 703         else()
 704                 set(CMAKE_CXX_FLAGS_RELEASE "-O3 -DNDEBUG" CACHE STRING "Set release flags" FORCE)
 705         endif()
 706 endif()
 707
 708 if(LYX_ASAN)
 709     set(CMAKE_CXX_FLAGS "-fsanitize=address -fno-omit-frame-pointer -g ${CMAKE_CXX_FLAGS}")
 710     message(STATUS)
 711     message(STATUS "Address sanitizer enabled. Usage:")
 712     message(STATUS "    wget https://llvm.org/svn/llvm-project/compiler-rt/trunk/lib/asan/scripts/asan_symbolize.py")
 713     message(STATUS "    chmod  +x ./asan_symbolize.py")
 714     message(STATUS "    ./bin/${_lyx} 2>&1 | ./asan_symbolize.py  | c++filt ")
 715     message(STATUS)
 716 endif()
 717
 718 set(LYX_CXX_FLAGS_EXTRA "" CACHE STRING "Desired semicolon separated list of extra cxx compile flags, like '-Werror'")
 719 mark_as_advanced(LYX_CXX_FLAGS_EXTRA)
 720 if(LYX_CXX_FLAGS_EXTRA)
 721         foreach(_flag ${LYX_CXX_FLAGS_EXTRA})
 722                 add_definitions(${_flag})
 723         endforeach()
 724 endif()
 725
 726 if(LYX_XMINGW)
 727         list(APPEND CMAKE_FIND_ROOT_PATH ${GNUWIN32_DIR})
 728 endif()
 729
 730 set(min_qt5_version "5.6")
 731 if(LYX_USE_QT MATCHES "AUTO")
 732         # try qt5 first
 733         find_package(Qt5Core CONFIG QUIET)
 734         if(Qt5Core_FOUND)
 735                 set(LYX_USE_QT "QT5" CACHE STRING "Valid qt version" FORCE)
 736                 message(STATUS "Qt5Core_VERSION = ${Qt5Core_VERSION}")
 737                 if(Qt5Core_VERSION VERSION_LESS ${min_qt5_version})
 738                         find_package(Qt4 "4.5.0" QUIET)
 739                         if(QT4_FOUND)
 740                                 set(LYX_USE_QT "QT4" CACHE STRING "Valid qt version" FORCE)
 741                         endif()
 742                 endif()
 743         else()
 744                 set(LYX_USE_QT "QT4" CACHE STRING "Valid qt version" FORCE)
 745         endif()
 746 endif()
 747 if(LYX_USE_QT MATCHES "QT5")
 748         # set QPA_XCB if QT uses X11
 749         find_package(Qt5Core CONFIG REQUIRED)
 750         if (Qt5Core_FOUND)
 751                 find_package(Qt5Widgets CONFIG REQUIRED)
 752                 if(APPLE)
 753                         find_package(Qt5MacExtras CONFIG REQUIRED)
 754                 endif()
 755                 find_package(Qt5X11Extras CONFIG QUIET)
 756                 find_package(Qt5WinExtras CONFIG QUIET)
 757                 set(QTVERSION ${Qt5Core_VERSION})
 758                 if (QTVERSION VERSION_LESS ${min_qt5_version})
 759                         message(STATUS "QTVERSION = \"${QTVERSION}\"")
 760                         message(STATUS "This version is not recommended, try either option -DLYX_USE_QT=QT4 or")
 761                         message(STATUS "install QT-Version >= \"${min_qt5_version}\"")
 762                         # see thread in lyx-devel list
 763                         # From: Jean-Pierre Chrétien <jeanpierre.chretien@free.fr>
 764                         # Date 11.03.2017
 765                         # Subject: cmake compilation error
 766                         #message(FATAL_ERROR "Wrong Qt-Version")
 767                 endif()
 768                 macro (qt_use_modules lyxtarget)
 769                         foreach (_tg ${ARGN})
 770                                 find_package(Qt5${_tg} CONFIG REQUIRED)
 771                                 target_link_libraries(${lyxtarget} Qt5::${_tg})
 772                         endforeach()
 773                 endmacro()
 774                 macro (qt_add_resources)
 775                         qt5_add_resources(${ARGN})
 776                 endmacro()
 777                 macro (qt_wrap_uifiles)
 778                         qt5_wrap_ui(${ARGN})
 779                 endmacro()
 780                 message(STATUS "Found Qt-Version ${QTVERSION}")
 781                 if(WIN32)
 782                         set(LYX_QTMAIN_LIBRARY ${Qt5Core_QTMAIN_LIBRARIES})
 783                 endif()
 784         endif()
 785 elseif(LYX_USE_QT MATCHES "QT4")
 786         if(LYX_XMINGW)
 787                 set(QT_MINGW_DIR ${LYX_QT4} CACHE PATH "Qt for Mingw" FORCE)
 788                 list(APPEND CMAKE_FIND_ROOT_PATH ${QT_MINGW_DIR} ${GNUWIN32_DIR})
 789         endif()
 790         find_package(Qt4 "4.5.0" REQUIRED)
 791         macro (qt_use_modules)
 792         endmacro()
 793         macro (qt_add_resources)
 794                 qt4_add_resources(${ARGN})
 795         endmacro()
 796         macro (qt_wrap_uifiles)
 797                 qt4_wrap_ui(${ARGN})
 798         endmacro()
 799         set(LYX_QTMAIN_LIBRARY ${QT_QTSVG_LIBRARY})
 800         if(WIN32)
 801                 list(APPEND LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARIES})
 802         endif()
 803 else()
 804   message(FATAL_ERROR "Unhandled value for LYX_USE_QT (${LYX_USE_QT})")
 805 endif()
 806
 807 find_package(Magic)
 808 if(Magic_FOUND)
 809   set(HAVE_MAGIC_H 1)
 810   include_directories(${Magic_INCLUDE_DIR})
 811 endif()
 812
 813 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 814
 815 set(Spelling_FOUND OFF)
 816 set(Include_used_spellchecker)   # String will be inserted into config.h
 817
 818 if (LYX_EXTERNAL_MYTHES MATCHES "AUTO")
 819   # try system library first
 820   find_package(MYTHESLIB)
 821   if (MYTHESLIB_FOUND)
 822     set(LYX_EXTERNAL_MYTHES ON CACHE STRING "OFF:= Build 3rdparty mytheslib" FORCE)
 823   else()
 824     set(LYX_EXTERNAL_MYTHES OFF CACHE STRING "OFF:= Build 3rdparty mytheslib" FORCE)
 825   endif()
 826 endif()
 827 if (LYX_EXTERNAL_MYTHES MATCHES "ON")
 828   find_package(MYTHESLIB REQUIRED)
 829 else()
 830   add_subdirectory(3rdparty/mythes)
 831 endif()
 832 set(MYTHES_DIR ${MYTHESLIB_INCLUDE_DIR})
 833
 834 if(NOT LYX_EXTERNAL_HUNSPELL)
 835     add_subdirectory(3rdparty/hunspell)
 836     add_definitions(-DHUNSPELL_STATIC)
 837     set(HUNSPELL_FOUND ON)
 838     message(STATUS "  * Hunspell:")
 839     message(STATUS "     - include: ${HUNSPELL_INCLUDE_DIR}")
 840     message(STATUS "     - library: ${HUNSPELL_LIBRARY}")
 841 endif()
 842
 843 foreach(_spell "ASPELL" "ENCHANT" "HUNSPELL")
 844   string(TOUPPER ${_spell} _upspell)
 845   if (NOT ${_upspell}_FOUND)
 846     find_package(${_spell})
 847   endif()
 848   if (${_upspell}_FOUND)
 849     include_directories(${${_upspell}_INCLUDE_DIR})
 850     set(Spelling_FOUND ON)
 851     message(STATUS "Building with USE_${_upspell}")
 852     set(Include_used_spellchecker "${Include_used_spellchecker}#define USE_${_upspell} 1\n")
 853   else()
 854     if(LYX_${_upspell})
 855       message(FATAL_ERROR "Required ${_spell} devel package not found")
 856     else()
 857       message(STATUS "${_upspell} not found, building without ${_spell} support")
 858     endif()
 859   endif()
 860 endforeach()
 861
 862 if(GNUWIN32_DIR)
 863         list(APPEND CMAKE_PROGRAM_PATH "${GNUWIN32_DIR}/Python" )
 864         list(APPEND CMAKE_PROGRAM_PATH "${GNUWIN32_DIR}/Perl/bin" )
 865 endif()
 866
 867 # Search for python default version first
 868 unset(PYTHON_EXECUTABLE CACHE)
 869 unset(LYX_PYTHON_EXECUTABLE CACHE)
 870 unset(PYTHON_VERSION_MAJOR)
 871 unset(PYTHON_VERSION_MINOR)
 872 unset(PYTHON_VERSION_STRING)
 873 if (CMAKE_VERSION VERSION_LESS "3.13")
 874   find_package(PythonInterp 3.5 QUIET)
 875   if(NOT PYTHONINTERP_FOUND)
 876     find_package(PythonInterp 2.0 REQUIRED)
 877     if(NOT PYTHON_VERSION_STRING VERSION_LESS 2.8)
 878       message(FATAL_ERROR "Python interpreter found, but is not suitable")
 879     endif()
 880   endif()
 881   set(LYX_PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 882 else()
 883   find_package(Python3 3.5 QUIET)
 884   if(NOT Python3_Interpreter_FOUND)
 885     unset(PYTHON_EXECUTABLE CACHE)
 886     find_package(Python2 2.0 REQUIRED)
 887     if(NOT Python2_VERSION VERSION_LESS 2.8)
 888       message(FATAL_ERROR "Python interpreter found, but is not suitable")
 889     endif()
 890     set(LYX_PYTHON_EXECUTABLE ${Python2_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 891   else()
 892     set(LYX_PYTHON_EXECUTABLE ${Python3_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 893   endif()
 894 endif()
 895
 896 if(LYX_NLS)
 897         find_package(LyXGettext)
 898         if(LYX_PYTHON_EXECUTABLE AND GETTEXT_FOUND)
 899                 add_subdirectory(po "${TOP_BINARY_DIR}/po")
 900         else()
 901                 # Install only supplied .gmo-files
 902                 file(GLOB _gmofiles RELATIVE "${TOP_SRC_DIR}/po" "${TOP_SRC_DIR}/po/*.gmo")
 903                 message(STATUS "Installing provided .gmo-files only")
 904                 foreach( _gmo ${_gmofiles})
 905                         string(REGEX REPLACE "\\.gmo$" "" _lang ${_gmo})
 906                         install(FILES "${TOP_SRC_DIR}/po/${_gmo}" DESTINATION ${LYX_LOCALEDIR}/${_lang}/LC_MESSAGES RENAME ${PACKAGE}.mo)
 907                 endforeach()
 908         endif()
 909 endif()
 910
 911 if(LYX_EXTERNAL_ICONV)
 912   # Possible remnants of previous run without external iconv
 913   file(REMOVE_RECURSE "${CMAKE_BINARY_DIR}/libiconv" "${CMAKE_BINARY_DIR}/3rdparty/libiconv")
 914   find_package(ICONV REQUIRED)
 915 else()
 916   add_subdirectory(3rdparty/libiconv)
 917   set(HAVE_ICONV_CONST 1)
 918 endif()
 919
 920 if(LYX_EXTERNAL_Z)
 921   find_package(ZLIB REQUIRED)
 922 else()
 923   add_subdirectory(3rdparty/zlib)
 924 endif()
 925
 926 if(NOT LYX_EXTERNAL_DTL)
 927   add_subdirectory(3rdparty/dtl)
 928 endif()
 929
 930 if(WIN32)
 931         if(LYX_CONSOLE)
 932                 set(LYX_QTMAIN_LIBRARY)
 933         else()
 934                 set(WIN32_CONSOLE WIN32)
 935         endif()
 936         if(MSVC)
 937                 # -DPSAPI_VERSION=1 is needed to run on vista (bug 10186)
 938                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX -DPSAPI_VERSION=1)
 939                 # disable checked iterators for msvc release builds to get maximum speed
 940                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 941         else()
 942                 # -DPSAPI_VERSION=1 is not needed for mingw, since the mingw psapi.h
 943                 # does not use it and always declares the vista compatible API.
 944                 # If this ever changes then -DPSAPI_VERSION might be needed here as well.
 945                 add_definitions(-DWINVER=0x0500)
 946         endif()
 947 endif()
 948
 949 # Compute qt-version from ${QTVERSION}
 950
 951 message(STATUS "")
 952 foreach(_v PACKAGE PACKAGE_VERSION
 953         PROGRAM_SUFFIX LYX_VERSION LYX_DIR_VER LYX_USERDIR_VER
 954         LYX_ABS_TOP_SRCDIR
 955         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 956         if(NOT DEFINED ${_v})
 957                 message(FATAL_ERROR "${_v} not defined")
 958         endif()
 959         string(SUBSTRING "${_v}                            " 0 28 _v1)
 960         message(STATUS "----- ${_v1}: ${${_v}}")
 961 endforeach(_v)
 962 message(STATUS "")
 963
 964
 965 if(LYX_PCH)
 966         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 967         # Not sure if it works for all non-msvc compilers
 968         include(PCHSupport_26)
 969         configure_file(${TOP_CMAKE_PATH}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
 970         configure_file(${TOP_CMAKE_PATH}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 971         add_definitions(-DLYX_ENABLE_PCH)
 972
 973         if(MSVC)
 974                 macro(lyx_add_msvc_pch name_)
 975                         set_source_files_properties(${${name_}_sources} PROPERTIES
 976                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 977                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
 978                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 979                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
 980                                 ${TOP_BINARY_DIR}/pcheaders.h)
 981                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_QT")
 982                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_QT")
 983                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL")
 984                 endmacro(lyx_add_msvc_pch)
 985                 macro(lyx_add_gcc_pch name_)
 986                 endmacro()
 987         else()
 988                 macro(lyx_add_msvc_pch name_)
 989                 endmacro()
 990                 macro(lyx_add_gcc_pch name_)
 991                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_QT)
 992                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
 993                 endmacro()
 994         endif()
 995 else()
 996         macro(lyx_add_msvc_pch)
 997         endmacro(lyx_add_msvc_pch)
 998         macro(lyx_add_gcc_pch name_)
 999         endmacro()
1000 endif()
1001
1002
1003 if(MSVC)
1004
1005         if(LYX_VLD)
1006                 set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/development/Win32/vld)
1007                 add_subdirectory(${vld_path}/cmake)
1008                 include(${vld_path}/cmake/vld.cmake) # forced include
1009                 set(vld_dll vld)
1010         endif()
1011
1012         if(LYX_WALL)
1013                 # Use the highest warning level
1014                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE STRING "Warning level" FORCE)
1015
1016                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
1017                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
1018                 else()
1019                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
1020                 endif()
1021
1022                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
1023                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
1024                 else()
1025                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
1026                 endif()
1027
1028                 # add here warnings which should produce an error /weXXXX
1029                 set(MSVC_W_ERROR   "/we4101 /we4189")
1030                 # add here warnings which should be disabled /wdXXXX
1031                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
1032
1033                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /W4 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1034                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /W4 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1035                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /W4 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1036
1037         else()
1038                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE STRING "Warning level" FORCE)
1039
1040                 # add here warnings which should produce an error /weXXXX
1041                 set(MSVC_W_ERROR   "/we4101 /we4189")
1042                 # add here warnings which should be disabled /wdXXXX
1043                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
1044
1045                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1046                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1047                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1048
1049         endif()
1050
1051         if (NOT Qt5Core_FOUND)
1052                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
1053                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
1054                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
1055         endif()
1056
1057         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
1058         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
1059         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
1060         message(STATUS "")
1061 endif()
1062
1063
1064 # Xcode compiler
1065 if (CMAKE_GENERATOR MATCHES Xcode)
1066         if (XCODE_VERSION VERSION_LESS "5.0")
1067                 # Automatically select the Xcode compiler if not set
1068                 if (NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
1069                         # XCode >= 3.1 has gcc 4.2 (up to actual Xcode)
1070                         if (XCODE_VERSION VERSION_GREATER "3.1")
1071                                 SET(CMAKE_XCODE_ATTRIBUTE_GCC_VERSION "com.apple.compilers.llvmgcc42")
1072                         ENDIF(XCODE_VERSION VERSION_GREATER "3.1")
1073                 ENDIF(NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
1074                 # Print the selected compiler version
1075         MESSAGE(STATUS "---- Using XCode compiler CMAKE_XCODE_ATTRIBUTE_GCC_VERSION=${CMAKE_XCODE_ATTRIBUTE_GCC_VERSION}")
1076         ENDIF(XCODE_VERSION VERSION_LESS "5.0")
1077 ENDIF(CMAKE_GENERATOR MATCHES Xcode)
1078
1079 if (WIN32 AND Qt5Core_FOUND)
1080         set(Z_PREFIX 1)
1081 endif()
1082
1083 # compiler tests, config.h generation LYX_CONFIGURE_CHECKS
1084 include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
1085 configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
1086
1087 unset(opts)
1088 foreach(_option ${LYX_OPTIONS})
1089   if(${_option}_show_message)
1090     string(SUBSTRING "${_option}                            " 0 31 _var)
1091     get_property(_prop CACHE ${_option} PROPERTY STRINGS)
1092     list(FIND LYX_OPTION_STRINGS ${_option} _index)
1093     if (${_index} GREATER -1)
1094       set(_isset ${${_option}})
1095     elseif(${_option})
1096       set(_isset ON)
1097     else()
1098       set(_isset OFF)
1099     endif()
1100     string(SUBSTRING "${_isset}           " 0 10 _val)
1101     set(opts "${opts} ${_option}(${${_option}})")
1102   endif()
1103 endforeach()
1104 set(tmp_vi "CMake Build")
1105 list(APPEND tmp_vi "  Host name:               ${CMAKE_HOST_SYSTEM_NAME}")
1106 list(APPEND tmp_vi "  Host processor:          ${CMAKE_HOST_SYSTEM_PROCESSOR}")
1107 list(APPEND tmp_vi "  Build flags:             ${opts}")
1108 list(APPEND tmp_vi "  C++ Compiler:            ${CMAKE_CXX_COMPILER_ID} (${CMAKE_CXX_COMPILER_VERSION})")
1109 list(APPEND tmp_vi "  C++ Compiler flags:      ${CMAKE_CXX_FLAGS}")
1110 if (LYX_DEBUG)
1111 list(APPEND tmp_vi "  C++ Compiler user flags: ${CMAKE_CXX_FLAGS_DEBUG}")
1112 else()
1113 list(APPEND tmp_vi "  C++ Compiler user flags: ${CMAKE_CXX_FLAGS_RELEASE}")
1114 endif()
1115 list(APPEND tmp_vi "  Qt version:              ${QTVERSION}")
1116 list(APPEND tmp_vi "  LyX binary dir:          ${CMAKE_INSTALL_PREFIX}/${LYX_UTILITIES_INSTALL_PATH}")
1117 get_data_destination(dest_data)
1118 list(APPEND tmp_vi "  LyX files dir:           ${CMAKE_INSTALL_PREFIX}/${dest_data}")
1119 string(REPLACE ";" "\\n" VERSION_INFO "${tmp_vi}")
1120
1121 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
1122 unset(opts)
1123 unset(tmp_vi)
1124
1125 if(QTVERSION MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+).*")
1126         MATH(EXPR QT4_VERSION "(${CMAKE_MATCH_1}<<16)|(${CMAKE_MATCH_2}<<8)|${CMAKE_MATCH_3}")
1127 endif()
1128
1129
1130 set (cmd ${CMAKE_CTEST_COMMAND})
1131 if (MSVC)
1132         set (cmd ${cmd} -C ${CMAKE_CFG_INTDIR})
1133 else ()
1134         set (cmd ${cmd} -C ${CMAKE_BUILD_TYPE})
1135 endif ()
1136 add_custom_target (lyx_run_tests COMMAND ${cmd})
1137 set_target_properties(lyx_run_tests PROPERTIES FOLDER "tests")
1138
1139 if(LYX_INSTALL)
1140         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
1141                 message(STATUS "Python required to create doc!")
1142         else()
1143                 if(UNIX)
1144                         add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
1145                 endif()
1146                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
1147         endif()
1148 endif()
1149 include(../Install)
1150
1151 # By running the URL tests first, time can be saved when running the ctests in
1152 # parallel since the URL tests take a long time to run (e.g. 10 minutes).
1153
1154 # Needed, because of perl scripts in checkurls autotests and batchtests
1155 find_package(Perl REQUIRED)
1156
1157 if(LYX_ENABLE_URLTESTS)
1158         add_subdirectory(development/checkurls "${TOP_BINARY_DIR}/checkurls")
1159 endif()
1160 add_subdirectory(src "${TOP_BINARY_DIR}/src")
1161 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
1162 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
1163 add_subdirectory(lib/examples "${TOP_BINARY_DIR}/lib/examples")
1164 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
1165 add_subdirectory(development/autotests "${TOP_BINARY_DIR}/autotests")
1166 add_subdirectory(development/batchtests "${TOP_BINARY_DIR}/batchtests")
1167
1168 message(STATUS)
1169 message(STATUS "Build params, switch LYX_* options by -DLYX_*=ON or OFF, LYX_* combos by -DLYX_*=value:")
1170 message(STATUS)
1171
1172 LYX_OPTION_LIST_ALL(used)
1173
1174
1175 if(LYX_NLS)
1176         message(STATUS)
1177         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
1178         message(STATUS)
1179         message(STATUS "  * iconv")
1180         message(STATUS "     - include: ${ICONV_INCLUDE_DIR}")
1181         message(STATUS "     - library: ${ICONV_LIBRARY}")
1182         message(STATUS "  * zlib")
1183         message(STATUS "     - include: ${ZLIB_INCLUDE_DIR}")
1184         message(STATUS "     - library: ${ZLIB_LIBRARY}")
1185         message(STATUS)
1186 endif()
1187
1188 # Apple has builtin native spell checker,
1189 # no need to warn for missing Aspell, Hunspell or Enchant
1190 if(NOT Spelling_FOUND AND NOT APPLE)
1191   if(LYX_REQUIRE_SPELLCHECK)
1192     set(_mode "FATAL_ERROR")
1193   else()
1194     set(_mode "STATUS")
1195   endif()
1196   message(${_mode} "No spellcheck libraries found. LyX will be unable use spellchecking")
1197 endif()
1198
1199 include("${TOP_CMAKE_PATH}/LyxPackaging.cmake")
1200
1201 if(ENABLE_DIST)
1202   # Use git to create the source package
1203   # git archive --format=tgz --output=/home/kornel/x.tar.gz master
1204   if(UNIX)
1205     set(DIST_FORMAT tgz)
1206   else()
1207     set(DIST_FORMAT zip)
1208   endif()
1209   set(DIST_NAME ${CMAKE_PROJECT_NAME}-${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}-${CMAKE_SYSTEM_NAME}.${DIST_FORMAT})
1210
1211   add_custom_command(
1212     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME}
1213     COMMAND  ${LYX_GITVERSION} archive --format=${DIST_FORMAT} --output=${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME} master
1214     WORKING_DIRECTORY ${TOP_SRC_DIR})
1215   add_custom_target(git-archive DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME})
1216 endif()
1217
1218 # Last directory to be included so that the fixup code (OS X)
1219 # can be run last
1220 add_subdirectory(development/cmake/post_install)
1221
1222 string(TIMESTAMP current_date "%Y-%m-%d %H:%M")
1223 execute_process(COMMAND ${LYX_GITVERSION} describe --tags
1224         WORKING_DIRECTORY "${TOP_SRC_DIR}"
1225         OUTPUT_VARIABLE current_version
1226         OUTPUT_STRIP_TRAILING_WHITESPACE)
1227 file(APPEND "${TOP_BINARY_DIR}/Testing/IgnoredCount" "${current_date} ${current_version} Ignored tests = ${LYX_ignored_count}\n")
1228 message(STATUS)