CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 3.1.0)
   8
   9 set(LYX_PROJECT LyX)
  10
  11 # Instruct cmake to not use gnu extensions,
  12 # this prevents the mix of '-std=c++*' and '-std=gnu++*' flags
  13 set(CMAKE_CXX_EXTENSIONS OFF)
  14
  15 enable_testing()
  16
  17 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README REALPATH) # Resolve symlinks
  18 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  19 message(STATUS "TOP_SRC_DIR = ${TOP_SRC_DIR}")
  20
  21 set(LYX_CMAKE_DIR "development/cmake")
  22 set(TOP_CMAKE_PATH "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}")
  23 set(TOP_MODULE_PATH "${TOP_CMAKE_PATH}/modules")
  24 set(TOP_SCRIPT_PATH "${TOP_CMAKE_PATH}/scripts")
  25
  26 set(CMAKE_MODULE_PATH "${TOP_MODULE_PATH}")
  27
  28 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  29
  30 message(STATUS)
  31 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  32         message(STATUS "Building in-source")
  33         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  34 else()
  35         message(STATUS "Building out-of-source")
  36         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  37 endif()
  38
  39 # This directory should be used if some test uses lyx-executable
  40 set(LYX_TESTS_USERDIR "${TOP_BINARY_DIR}/Testing/.lyx")
  41 file(MAKE_DIRECTORY "${LYX_TESTS_USERDIR}")
  42
  43 if(COMMAND cmake_policy)
  44         # Installing MACOSX_BUNDLE targets requires a BUNDLE DESTINATION
  45         cmake_policy(SET CMP0006 NEW)
  46         if(POLICY CMP0043)
  47                 # COMPILE_DEFINITIONS are not used yet. Enable new behavior.
  48                 cmake_policy(SET CMP0043 NEW)
  49         endif()
  50         cmake_policy(SET CMP0020 NEW)
  51         if(POLICY CMP0075)
  52                 cmake_policy(SET CMP0075 NEW)
  53         endif()
  54 endif()
  55
  56 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  57
  58 # Supress regeneration
  59 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  60
  61 if(LYX_XMINGW)
  62     set(CMAKE_SYSTEM_NAME Windows)
  63     set(TOOLNAME ${LYX_XMINGW})
  64     set(TOOLCHAIN "${TOOLNAME}-")
  65     set(CMAKE_C_COMPILER   "${TOOLCHAIN}gcc"     CACHE PATH "Mingw C compiler" FORCE)
  66     set(CMAKE_CXX_COMPILER "${TOOLCHAIN}g++"     CACHE PATH "Mingw C++ compiler" FORCE)
  67     set(CMAKE_RC_COMPILER  "${TOOLCHAIN}windres" CACHE PATH "Mingw rc compiler" FORCE)
  68
  69     set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM BOTH)
  70     set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY)
  71     set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY)
  72 endif()
  73
  74 if(NOT help AND NOT HELP)
  75   # 'project' triggers the searching for a compiler
  76   project(${LYX_PROJECT})
  77   if (CMAKE_COMPILER_IS_GNUCXX)
  78     if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS "4.0")
  79       message(STATUS "Gnu CXX compiler version = ${CMAKE_CXX_COMPILER_VERSION}")
  80       message(STATUS "is too old, should be >= 4.0")
  81       message(FATAL_ERROR "Exiting")
  82     endif()
  83   endif()
  84 endif()
  85
  86 if(UNIX)
  87         set(ARCH_TRIPLET )
  88         FIND_PROGRAM(DPKG_ARCHITECTURE_EXECUTABLE dpkg-architecture)
  89         if(DPKG_ARCHITECTURE_EXECUTABLE)
  90                 EXECUTE_PROCESS(COMMAND ${DPKG_ARCHITECTURE_EXECUTABLE} -qDEB_HOST_MULTIARCH
  91                                 OUTPUT_VARIABLE ARCH_TRIPLET
  92                                 ERROR_VARIABLE ERROR_ARCH_TRIPLET
  93                                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  94         endif()
  95 endif()
  96 if(ARCH_TRIPLET)
  97         set(SYSTEM_LIB_DIRS /usr/lib /usr/lib/${ARCH_TRIPLET} /usr/local/lib)
  98 else()
  99         set(SYSTEM_LIB_DIRS /usr/lib /usr/local/lib)
 100 endif()
 101
 102 include(LyXMacros)
 103 include(LyXDestinations)
 104
 105 # Usage LYX_OPTION
 106 # 1. parameter: option name without prefix 'LYX_'
 107 # 2. parameter: description
 108 # 3. parameter: default value, ON or OFF
 109 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
 110
 111 # Usage LYX_COMBO
 112 # 1. parameter: name without prefix 'LYX_'
 113 # 2. parameter: description
 114 # 3. parameter: default value
 115 # 4-n parameter: possible other string values
 116
 117 LYX_OPTION_INIT()
 118
 119 # Options for all compilers/systems
 120 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
 121 LYX_OPTION(LOCALVERSIONING  "Add version info to created package name (only used if LYX_CPACK option set)" OFF ALL)
 122 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
 123 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
 124 LYX_OPTION(REQUIRE_SPELLCHECK "Abort if no spellchecker available" OFF ALL)
 125 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
 126 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
 127 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
 128 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" OFF ALL)
 129 LYX_OPTION(DEBUG            "Enforce debug build"  OFF ALL)
 130 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
 131 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
 132 LYX_STRING(SUFFIX_VALUE     "Use this string as suffix" "")
 133 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
 134 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
 135 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
 136 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
 137 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
 138 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
 139 LYX_OPTION(ENABLE_URLTESTS  "Enable for URL tests" OFF ALL)
 140 LYX_OPTION(ENABLE_EXPORT_TESTS "Enable for export tests" OFF ALL)
 141 LYX_OPTION(ENABLE_KEYTESTS  "Enable for keytests" OFF ALL)
 142 if (NOT CMAKE_VERSION VERSION_LESS "3.17")
 143 LYX_OPTION(ENABLE_VALGRIND_TESTS  "Enable for tests involving valgrind" OFF ALL)
 144 else()
 145 unset(LYX_ENABLE_VALGRIND_TESTS CACHE)
 146 endif()
 147 LYX_OPTION(ASAN             "Use address sanitizer" OFF ALL)
 148 #LYX_COMBO(USE_FILEDIALOG    "Use native or QT file dialog" QT NATIVE)
 149 LYX_COMBO(USE_QT            "Use Qt version as frontend" AUTO QT4 QT5)
 150 LYX_COMBO(USE_IPO           "Interprocedural optimization" OFF AUTO ON)
 151 #LYX_OPTION(3RDPARTY_BUILD   "Build 3rdparty libs" OFF ALL)
 152 LYX_OPTION(DISABLE_CALLSTACK_PRINTING "do not print a callstack when crashing" OFF ALL)
 153 LYX_OPTION(EXTERNAL_Z       "OFF := Build 3rdparty lib zlib" ON ALL)
 154 LYX_OPTION(EXTERNAL_DTL     "OFF := Build 3rdparty commands dt2dv and dv2dt" ON ALL)
 155 LYX_OPTION(EXTERNAL_ICONV   "OFF := Build 3rdparty lib iconvlib" ON ALL)
 156 LYX_OPTION(EXTERNAL_HUNSPELL "OFF := Build 3rdparty lib hunspelllib" ON ALL)
 157 LYX_COMBO(EXTERNAL_MYTHES   "OFF := Build 3rdparty lib mytheslib" AUTO OFF ON)
 158
 159 # GCC specific
 160 LYX_OPTION(PROFILE              "Build with options for gprof" OFF GCC)
 161 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" OFF GCC)
 162 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
 163 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
 164 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++ pedantic debug mode" OFF GCC)
 165 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" OFF GCC)
 166
 167 # MSVC specific
 168 LYX_OPTION(CONSOLE               "Show console on Windows" ON MSVC)
 169 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
 170 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
 171 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
 172
 173 # APPLE specific
 174 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
 175 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
 176
 177
 178 if(help OR HELP)
 179         message(STATUS)
 180         message(STATUS "Available options: (dis/enable with -DLYX_*=OFF/ON)")
 181         message(STATUS)
 182         LYX_OPTION_LIST_ALL(help)
 183         message(STATUS)
 184         RETURN()
 185 endif()
 186
 187 # Check option dependencies
 188 if (LYX_ENABLE_VALGRIND_TESTS)
 189         find_program(VALGRIND_EXECUTABLE "valgrind")
 190         if (NOT VALGRIND_EXECUTABLE)
 191                 message(FATAL_ERROR "Cannot use valgrind tests, executable valgrind is missing. Please disable LYX_ENABLE_VALGRIND_TESTS")
 192         endif()
 193 endif()
 194 if (LYX_DEBUG_GLIBC OR LYX_DEBUG_GLIBC_PEDANTIC OR LYX_STDLIB_DEBUG)
 195   if (LYX_EXTERNAL_BOOST)
 196     message(FATAL_ERROR "Using external boost not compatible with debug mode for stdlib")
 197   endif()
 198 endif()
 199
 200 if(LYX_DMG)
 201         set(LYX_BUNDLE ON)
 202         set(LYX_CPACK ON)
 203 endif()
 204
 205 if(LYX_CPACK)
 206         set(LYX_INSTALL ON)
 207 endif()
 208
 209 if(LYX_INSTALL)
 210         set(LYX_NLS ON)
 211         if(WIN32 AND NOT MINGW)
 212                 set(LYX_HUNSPELL ON)
 213         endif()
 214         set(LYX_PACKAGE_SUFFIX ON)
 215         if(NOT LYX_DEBUG)
 216                 set(LYX_RELEASE ON)
 217         endif()
 218         set(LYX_PROFILE OFF)
 219 endif()
 220
 221
 222 if(LYX_MERGE_FILES)
 223         set(LYX_PCH OFF)
 224 else()
 225         set(LYX_MERGE_REBUILD OFF)
 226 endif()
 227
 228 if(LYX_DEPENDENCIES_DOWNLOAD)
 229         message(STATUS)
 230         if(MSVC14)
 231                 set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2015-deps)
 232                 set(deps_files lyx-windows-deps-msvc2015.zip)
 233                 set(deps_server http://ftp.lyx.de/LyX-Windows-Deps)
 234                 set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2015)
 235         elseif(MSVC10)
 236                 set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 237                 set(deps_files lyx-windows-deps-msvc2010.zip)
 238                 set(deps_server http://ftp.lyx.de/LyX-Windows-Deps)
 239                 set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2010)
 240         else()
 241                 message(FATAL_ERROR "error: no dependency package known for the selected MSVC version.")
 242         endif()
 243     message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 244         foreach(it ${deps_files})
 245                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 246                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 247                 if(NOT already_downloaded)
 248                         message(STATUS "Downloading ${it} ...")
 249                         file(DOWNLOAD ${deps_server}/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS STATUS status LOG log)
 250                         list(GET status 0 status_code)
 251                         list(GET status 1 status_string)
 252                         if(NOT status_code EQUAL 0)
 253                                 file(REMOVE ${LYX_DEPENDENCIES_DIR}/${it})
 254                                 message(FATAL_ERROR "error: downloading '${it}' failed. status_code: ${status_code}, status_string: ${status_string}. \nLog: ${log} ")
 255                         endif()
 256                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 257                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 258                 endif()
 259         endforeach()
 260 endif()
 261
 262 message(STATUS)
 263
 264 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 265 if(WIN32)
 266         set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 267 else()
 268         set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 269 endif()
 270
 271 set(LYX_IPO_SUPPORTED OFF)
 272 if (POLICY CMP0069)
 273   cmake_policy(SET CMP0069 NEW)
 274   if(LYX_USE_IPO MATCHES "AUTO")
 275     # Enable LTO if supported and not debugging
 276     if (NOT LYX_DEBUG)
 277       include(CheckIPOSupported)
 278       check_ipo_supported(RESULT LYX_IPO_SUPPORTED)
 279     endif()
 280   else()
 281     set(LYX_IPO_SUPPORTED ${LYX_USE_IPO})
 282   endif()
 283 endif()
 284 if (LYX_IPO_SUPPORTED)
 285   set(LYX_USE_IPO "ON" CACHE STRING "Use interprocedural optimization" FORCE)
 286 else()
 287   set(LYX_USE_IPO "OFF" CACHE STRING "Use interprocedural optimization" FORCE)
 288 endif()
 289
 290 # Set to some meaningful default
 291 find_package(CXX11Compiler)
 292 if(NOT CXX11COMPILER_FOUND)
 293         message(FATAL_ERROR "A C++11 compatible compiler is required.")
 294 endif()
 295 unset(LYX_GCC11_MODE)
 296 if(UNIX OR MINGW)
 297         if (CMAKE_CXX_COMPILER_ID MATCHES "^([cC]lang|AppleClang)$")
 298           # ignore the GCC_VERSION for clang
 299           # and use the resulting CXX11_STD_REGEX found in FindCXX11Compiler.cmake
 300           message(STATUS "Using clang")
 301           if(CXX11_STD_REGEX)
 302             set(LYX_USE_STD_REGEX 1)
 303           else()
 304             set(LYX_USE_STD_REGEX 0)
 305           endif()
 306         else()
 307           execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpfullversion OUTPUT_VARIABLE GCC_VERSION ERROR_VARIABLE _error RESULT_VARIABLE _err OUTPUT_STRIP_TRAILING_WHITESPACE)
 308           #message(STATUS "dumpfullversion: error = ${_error}, result = ${_err}")
 309           if (_err)
 310             # previous check failed, try again with _old_ parameter
 311             execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION ERROR_VARIABLE _error RESULT_VARIABLE _err OUTPUT_STRIP_TRAILING_WHITESPACE)
 312             #message(STATUS "dumpversion: error = ${_error}, result = ${_err}")
 313           endif()
 314           message(STATUS "Using GCC version ${GCC_VERSION}")
 315           if(GCC_VERSION VERSION_LESS 4.6)
 316                 message(FATAL_ERROR "gcc >= 4.6 is required.")
 317           elseif(GCC_VERSION VERSION_LESS 4.9)
 318                 # <regex> in gcc is unusable in versions less than 4.9.0
 319                 # see https://gcc.gnu.org/bugzilla/show_bug.cgi?id=53631
 320                 set(LYX_USE_STD_REGEX 0)
 321           else()
 322                 set(LYX_USE_STD_REGEX 1)
 323           endif()
 324         endif()
 325         set(LYX_GCC11_MODE "${CXX11_FLAG}")
 326 else()
 327         if(MSVC_VERSION LESS 1900)
 328                 # Drop support for msvc versions prior to 1900 (Visual Studio 2015)
 329                 message(FATAL_ERROR "Visual Studio >= 2015 is required.")
 330                 set(LYX_USE_STD_REGEX 0)
 331         else()
 332                 set(LYX_USE_STD_REGEX 1)
 333         endif()
 334 endif()
 335
 336
 337 # Try to get some informations from configure.ac
 338
 339 include(LyXPaths)
 340 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 341
 342 if(WIN32)
 343         set(CMAKE_PREFIX_PATH Specify-path-to-Qt CACHE PATH "Used Qt version")
 344         if(MSVC)
 345                 set(LYX_3RDPARTY_BUILD ON CACHE BOOL "Build 3rdparty libraries" FORCE)
 346         endif()
 347         set(USE_WINDOWS_PACKAGING ON)
 348 elseif(APPLE)
 349         set(USE_MACOSX_PACKAGING ON)
 350 else()
 351         set(USE_POSIX_PACKAGING ON)
 352 endif()
 353
 354 if(LYX_3RDPARTY_BUILD)
 355   # LYX_3RDPARTY_BUILD is not cached anymore, but for compatibility reasons
 356   # this enables the build of all 3rd_party libs
 357   set(LYX_EXTERNAL_Z        OFF CACHE BOOL "Build 3rdparty lib zlib"    FORCE)
 358   set(LYX_EXTERNAL_ICONV    OFF CACHE BOOL "Build 3rdparty iconvlib"    FORCE)
 359   set(LYX_EXTERNAL_HUNSPELL OFF CACHE BOOL "Build 3rdparty hunspelllib" FORCE)
 360   set(LYX_EXTERNAL_MYTHES   OFF CACHE STRING "Build 3rdparty mytheslib" FORCE)
 361 endif()
 362
 363 macro(setstripped _varname)
 364         if(${ARGC} GREATER 1)
 365                 string(STRIP "${ARGV1}" _v)
 366                 if (_v MATCHES "^\\[\(.+\)\\]$")
 367                   set(_v ${CMAKE_MATCH_1})
 368                 endif()
 369                 if(USE_POSIX_PACKAGING)
 370                         string(TOLOWER ${_v} ${_varname})
 371                 else()
 372                         set(${_varname} ${_v})
 373                 endif()
 374         else()
 375                 set(${_varname})
 376         endif()
 377 endmacro(setstripped)
 378
 379 foreach(_c_l ${_config_lines} )
 380         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 381                 # Not using CMAKE_MATCH_ directly is needed, because
 382                 # its value is now changed inside macro setstripped
 383                 set(_PB ${CMAKE_MATCH_1})
 384                 set(_PV ${CMAKE_MATCH_2})
 385                 set(_PBU ${CMAKE_MATCH_3})
 386                 setstripped(PACKAGE_BASE ${_PB})
 387                 setstripped(PACKAGE_VERSION ${_PV})
 388                 setstripped(PACKAGE_BUGREPORT ${_PBU})
 389                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\)\(\\.\([0-9]+\)\(\\.\([0-9]+\)\)?\)?.*$")
 390                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 391                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 392                         set(LYX_RELEASE_LEVEL ${CMAKE_MATCH_4})
 393                         set(LYX_RELEASE_PATCH ${CMAKE_MATCH_6})
 394                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 395                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 396                         if (NOT LYX_RELEASE_LEVEL)
 397                                 set(LYX_RELEASE_LEVEL 0)
 398                         endif()
 399                         if (NOT LYX_RELEASE_PATCH)
 400                                 set(LYX_RELEASE_PATCH 0)
 401                         endif()
 402                         set(LYX_VERSION "${LYX_MAJOR_VERSION}.${LYX_MINOR_VERSION}")
 403                         if ("${LYX_SUFFIX_VALUE}" MATCHES "")
 404                           set(LYX_INSTALL_SUFFIX "${LYX_MAJOR_VERSION}.${LYX_MINOR_VERSION}")
 405                         else()
 406                           set(LYX_INSTALL_SUFFIX "${LYX_SUFFIX_VALUE}")
 407                         endif()
 408                 endif()
 409         endif()
 410         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 411                 set(LYX_DATE "${CMAKE_MATCH_1}")
 412         endif()
 413 endforeach(_c_l)
 414 unset(_config_lines)
 415
 416 FIND_PROGRAM(LYX_GITVERSION git)
 417 #message(STATUS "gitversion = ${LYX_GITVERSION}")
 418 set(LYX_REVISION_VERSION ${LYX_RELEASE_LEVEL})
 419 set(LYX_PACKAGE_RELEASE "UNDEFINED")
 420 if(LYX_GITVERSION)
 421   if (LYX_LOCALVERSIONING)
 422     # Find the revision number for later use
 423     EXECUTE_PROCESS(COMMAND ${LYX_GITVERSION} describe --match 2.0.0 HEAD
 424       WORKING_DIRECTORY "${TOP_SRC_DIR}"
 425       RESULT_VARIABLE tmp_GIT_RESULT
 426       OUTPUT_VARIABLE tmp_LYX_PACKAGE_RELEASE
 427       ERROR_VARIABLE tmp_GIT_ERROR
 428       OUTPUT_STRIP_TRAILING_WHITESPACE)
 429     if (tmp_GIT_RESULT EQUAL 0)
 430       if (tmp_LYX_PACKAGE_RELEASE MATCHES "^2\\.0\\.0\\-\([0-9]+\)\\-\(.*\)$")
 431         set(LYX_PACKAGE_RELEASE ${CMAKE_MATCH_2})
 432         # We will add offset of 40000 to get appropriate value to
 433         # previous svn.
 434         # We use this value than also to set the package-patch-value
 435         MATH(EXPR tmp_REVISION_VERSION "(${CMAKE_MATCH_1}+40000)")
 436         set(LYX_REVISION_VERSION "${LYX_RELEASE_LEVEL}-${tmp_REVISION_VERSION}git")
 437         set(ENABLE_DIST ON)
 438       endif()
 439     endif()
 440   endif()
 441 endif()
 442 if (LYX_PACKAGE_RELEASE MATCHES "UNDEFINED")
 443   set(LYX_PACKAGE_RELEASE  "1")
 444   if (LYX_RELEASE_PATCH GREATER 0)
 445     set(LYX_REVISION_VERSION "${LYX_RELEASE_LEVEL}.${LYX_RELEASE_PATCH}")
 446   endif()
 447 endif()
 448
 449 # Set the programs (lyx, tex2lyx, etc.) suffix
 450 # When building an OS X bundle, we will append
 451 # the suffix only to the bundle, not to the programs
 452 set(PROGRAM_SUFFIX "")
 453 if(LYX_PROGRAM_SUFFIX AND NOT (APPLE AND LYX_BUNDLE))
 454         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 455 endif()
 456 set(_lyx "${PACKAGE_BASE}${PROGRAM_SUFFIX}")
 457 set(_tex2lyx tex2lyx${PROGRAM_SUFFIX})
 458 set(_convert lyxconvert${PROGRAM_SUFFIX})
 459
 460 add_custom_target(lyx_version ALL
 461   COMMAND ${CMAKE_COMMAND} -DTOP_SRC_DIR=${TOP_SRC_DIR} -DTOP_CMAKE_PATH=${TOP_CMAKE_PATH} -DTOP_BINARY_DIR=${TOP_BINARY_DIR} -DLYX_DATE=${LYX_DATE} -P ${TOP_SCRIPT_PATH}/LyXGetVersion.cmake
 462   )
 463 set_target_properties(lyx_version PROPERTIES FOLDER "applications")
 464
 465 # Default paths for installed utilities (tex2lyx, lyxclient, etc.)
 466 set(LYX_UTILITIES_INSTALL_PATH bin)
 467
 468 if(LYX_BUNDLE)
 469         set(LYX_CPACK ON)
 470
 471         message(STATUS)
 472         message(STATUS "Bundle creation is enabled (experimental):")
 473         message(STATUS "    make")
 474         message(STATUS "    make install/strip")
 475         message(STATUS "    make package")
 476         if(APPLE)
 477                 set(MACOSX_BUNDLE TRUE)
 478                 # This sets the bundle + executable names
 479                 set(_lyx "${PACKAGE_BASE}${LYX_INSTALL_SUFFIX}")
 480                 # This sets the Info.plist executable name
 481                 set(osx_bundle_program_name ${_lyx})
 482                 # Bundle name
 483                 set(LYX_BUNDLE_NAME ${_lyx})
 484
 485                 # This will contain the list of files that need to be included
 486                 # in the bundle and their location within the bundle
 487                 set(OSX_BUNDLE_FILES "${TOP_SRC_DIR}/development/MacOSX/LyX.sdef;${TOP_SRC_DIR}/development/MacOSX/LyXapp.icns;${CMAKE_BINARY_DIR}/lyxrc.dist")
 488                 set(OSX_BUNDLE_DIRS "Resources;Resources;Resources")
 489
 490                 # Process Info.plist and lyxrc.dist
 491                 # See development/cmake/Install.cmake
 492                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/Info.plist.in" "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 493
 494                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 495                 set(LYX_DATA_SUBDIR ${LYX_BUNDLE_NAME}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 496
 497                 # Variables used by CPack
 498                 set(CPACK_BUNDLE_NAME ${LYX_BUNDLE_NAME})
 499                 set(CPACK_BUNDLE_PLIST "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 500                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${LYX_BUNDLE_NAME}.app)
 501
 502                 # Set the install paths
 503                 set(LYX_UTILITIES_INSTALL_PATH ${LYX_BUNDLE_NAME}.app/Contents/MacOS)
 504                 if(NOT LYX_INSTALL_PREFIX)
 505                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 506                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 507                 endif()
 508                 # Change the owner so that the install can work
 509                 install(CODE "set(BU_CHMOD_BUNDLE_ITEMS 1)" COMPONENT Runtime)
 510         elseif(UNIX)
 511                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 512                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 513                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 514         elseif(WIN32)
 515                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 516         endif()
 517 endif()
 518
 519 if(LYX_INSTALL_PREFIX)
 520         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 521         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 522 endif()
 523 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 524
 525 if(UNIX)
 526   set(SYSTEM_DATADIR "${CMAKE_INSTALL_PREFIX}/share")
 527 elseif(CMAKE_INSTALL_PREFIX MATCHES "/lyx${LYX_INSTALL_SUFFIX}$")
 528   string(REGEX REPLACE "/lyx${LYX_INSTALL_SUFFIX}$" "/share" SYSTEM_DATADIR ${CMAKE_INSTALL_PREFIX})
 529 else()
 530   set(SYSTEM_DATADIR "${CMAKE_INSTALL_PREFIX}")
 531 endif()
 532
 533 if(NOT CMAKE_COMPILER_IS_GNUCXX)
 534   # Not a GCC compiler, programs do not have a suffix
 535   set(suffixing ${LYX_PACKAGE_SUFFIX})
 536 elseif(WIN32 AND MINGW)
 537   # We want to use a suffix for the package in this case,
 538   # even if not for the program
 539   set(suffixing ${LYX_PACKAGE_SUFFIX})
 540 else()
 541   message(STATUS "CMAKE_COMPILER_IS_GNUCXX = ${CMAKE_COMPILER_IS_GNUCXX}")
 542   set(suffixing ${LYX_PROGRAM_SUFFIX})
 543 endif()
 544
 545 # The define PACKAGE below allows lyx-executable to find its default configuration files
 546 # see routines
 547 #    Package::messages_file()
 548 #    get_default_user_support_dir()
 549 #    relative_system_support_dir()
 550 # in src/support/Package.cpp
 551 if(suffixing)
 552         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 553 else()
 554         set(PACKAGE ${PACKAGE_BASE})
 555 endif()
 556
 557 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 558         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 559         if (UNIX)
 560                 # use the default "/usr/local"
 561                 # but respect the user-choice on the command-line
 562                 set(CMAKE_INSTALL_PREFIX "/usr/local" CACHE PATH "LyX default install prefix" FORCE)
 563         endif()
 564 endif()
 565 if(WIN32)
 566         set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 567 endif()
 568 if(IS_ABSOLUTE)
 569         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 570 else()
 571         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 572 endif()
 573
 574
 575
 576 if(NOT LYX_DATA_SUBDIR)
 577         if (WIN32)
 578                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 579         else()
 580                 set(LYX_DATA_SUBDIR "share/${_lyx}/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 581         endif()
 582 endif()
 583
 584 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}/${LYX_DATA_SUBDIR}")
 585 get_locale_destination(LYX_LOCALEDIR)
 586 set(LYX_ABS_INSTALLED_LOCALEDIR "${CMAKE_INSTALL_PREFIX}/${LYX_LOCALEDIR}")
 587 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 588
 589 if(LYX_BUNDLE AND APPLE)
 590         set(LYX_MAN_DIR_tmp "${LYX_DATA_SUBDIR}")
 591 else()
 592         if(WIN32)
 593                 set(LYX_MAN_DIR_tmp "${CMAKE_BINARY_DIR}/usr/local/man/")
 594         elseif(UNIX)
 595                 set(LYX_MAN_DIR_tmp "${CMAKE_INSTALL_PREFIX}/share/man/")
 596         else()
 597                 set(LYX_MAN_DIR_tmp "${CMAKE_INSTALL_PREFIX}/man/")
 598         endif()
 599 endif()
 600 if (NOT LYX_MAN_DIR_tmp EQUAL "${LYX_MAN_DIR}")
 601         unset(LYX_MAN_DIR CACHE)
 602         set(LYX_MAN_DIR "${LYX_MAN_DIR_tmp}" CACHE STRING "Install location for man pages.")
 603 endif()
 604 unset(LYX_MAN_DIR_tmp)
 605 mark_as_advanced(LYX_MAN_DIR)
 606
 607 # The Win installer cannot be built by CMake because one needs to install plugins for NSIS
 608 # see the Readme.txt of the installer
 609 #if(LYX_INSTALL AND WIN32)
 610 #       message(STATUS "Configuring NSIS files")
 611 #       configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 612 #       configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 613 #       configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 614 #       message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 615 #endif()
 616
 617 if(NOT GROUP_CODE)
 618         #set(GROUP_CODE "The Golden Code")
 619         set(GROUP_CODE flat)
 620 endif()
 621
 622 # lyx's source files
 623 set(LYX_CPP_FILES [a-zA-Z]*.cpp)
 624 set(LYX_HPP_FILES [a-zA-Z]*.h)
 625 set(LYX_MOC_FILES moc_*.cpp)
 626
 627 include(ProjectSourceGroup)
 628
 629
 630 if(LYX_PROFILE AND NOT MSVC)
 631         set(CMAKE_BUILD_TYPE Profile CACHE STRING "Profile build type" FORCE)
 632         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg")
 633         set(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS}  -pg")
 634 else()
 635         set(LYX_PROFILE OFF)
 636 endif()
 637
 638
 639 if(LYX_NO_OPTIMIZE)
 640         set(CMAKE_BUILD_TYPE None)
 641         set(LYX_DEBUG OFF)
 642         set(LYX_RELEASE OFF)
 643         set(LYX_PROFILE OFF)
 644 elseif(LYX_RELEASE)
 645         set(CMAKE_BUILD_TYPE Release)
 646         set(LYX_DEBUG OFF)
 647         set(LYX_PROFILE OFF)
 648 elseif(LYX_PROFILE)
 649         set(CMAKE_BUILD_TYPE Profile)
 650         set(LYX_DEBUG OFF)
 651 else()
 652         set(CMAKE_BUILD_TYPE Debug)
 653         set(LYX_DEBUG ON)
 654 endif()
 655
 656
 657 # When shared libs are supported enable this option
 658 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 659 if(LYX_SHARED_LIBRARIES)
 660         set(library_type SHARED)
 661 else()
 662         set(library_type STATIC)
 663 endif()
 664
 665 if(MSVC)
 666   if (CXX11_FLAG MATCHES "\\+\\+([0-9]+)")
 667     set(CMAKE_CXX_STANDARD ${CMAKE_MATCH_1})
 668     message(STATUS "CMAKE_CXX_STANDARD set to ${CMAKE_CXX_STANDARD}")
 669   endif()
 670 else()
 671         if(NOT LYX_QUIET)
 672                 set(CMAKE_VERBOSE_MAKEFILE ON)
 673         endif()
 674         set(LYX_CXX_FLAGS "-Wall -Wunused-parameter ${LYX_GCC11_MODE}")
 675         if(LYX_CXX_FLAGS MATCHES "\\+\\+(14|11|98)")
 676           # Thanks to Brad King <brad.king@kitware.com>
 677           # for the pointer to https://cmake.org/cmake/help/v3.6/variable/CMAKE_CXX_STANDARD.html
 678           # This allows us to use QT5.7 with recent g++ (version >= 4.9) compilers
 679           # and still use our own c++ extension tests
 680           set(CMAKE_CXX_STANDARD ${CMAKE_MATCH_1})
 681           message(STATUS "CMAKE_CXX_STANDARD set to ${CMAKE_CXX_STANDARD}")
 682         endif()
 683         if(LYX_STDLIB_DEBUG)
 684           set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 685         else()
 686           if(LYX_DEBUG_GLIBC)
 687             set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG")
 688           endif()
 689           if(LYX_DEBUG_GLIBC_PEDANTIC)
 690             set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG_PEDANTIC")
 691           endif()
 692         endif()
 693         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE STRING "Set CXX flags" FORCE)
 694         set(CMAKE_CXX_FLAGS_DEBUG "-O0 -g3 -D_DEBUG" CACHE STRING "Set debug flags" FORCE)
 695         if(MINGW)
 696                 set(CMAKE_CXX_FLAGS_RELEASE "-O2 -DNDEBUG" CACHE STRING "Set release flags for Mingw" FORCE)
 697         else()
 698                 set(CMAKE_CXX_FLAGS_RELEASE "-O3 -DNDEBUG" CACHE STRING "Set release flags" FORCE)
 699         endif()
 700 endif()
 701
 702 set(LYX_CXX_FLAGS_EXTRA "" CACHE STRING "Desired semicolon separated list of extra cxx compile flags, like '-Werror'")
 703 mark_as_advanced(LYX_CXX_FLAGS_EXTRA)
 704 if(LYX_CXX_FLAGS_EXTRA)
 705         foreach(_flag ${LYX_CXX_FLAGS_EXTRA})
 706                 add_definitions(${_flag})
 707         endforeach()
 708 endif()
 709
 710 if(LYX_XMINGW)
 711         list(APPEND CMAKE_FIND_ROOT_PATH ${GNUWIN32_DIR})
 712 endif()
 713
 714 set(min_qt5_version "5.6")
 715 if(LYX_USE_QT MATCHES "AUTO")
 716         # try qt5 first
 717         find_package(Qt5Core CONFIG QUIET)
 718         if(Qt5Core_FOUND)
 719                 set(LYX_USE_QT "QT5" CACHE STRING "Valid qt version" FORCE)
 720                 message(STATUS "Qt5Core_VERSION = ${Qt5Core_VERSION}")
 721                 if(Qt5Core_VERSION VERSION_LESS ${min_qt5_version})
 722                         find_package(Qt4 "4.5.0" QUIET)
 723                         if(QT4_FOUND)
 724                                 set(LYX_USE_QT "QT4" CACHE STRING "Valid qt version" FORCE)
 725                         endif()
 726                 endif()
 727         else()
 728                 set(LYX_USE_QT "QT4" CACHE STRING "Valid qt version" FORCE)
 729         endif()
 730 endif()
 731 if(LYX_USE_QT MATCHES "QT5")
 732         # set QPA_XCB if QT uses X11
 733         find_package(Qt5Core CONFIG REQUIRED)
 734         if (Qt5Core_FOUND)
 735                 find_package(Qt5Widgets CONFIG REQUIRED)
 736                 if(APPLE)
 737                         find_package(Qt5MacExtras CONFIG REQUIRED)
 738                 endif()
 739                 find_package(Qt5X11Extras CONFIG QUIET)
 740                 find_package(Qt5WinExtras CONFIG QUIET)
 741                 set(QTVERSION ${Qt5Core_VERSION})
 742                 if (QTVERSION VERSION_LESS ${min_qt5_version})
 743                         message(STATUS "QTVERSION = \"${QTVERSION}\"")
 744                         message(STATUS "This version is not recommended, try either option -DLYX_USE_QT=QT4 or")
 745                         message(STATUS "install QT-Version >= \"${min_qt5_version}\"")
 746                         # see thread in lyx-devel list
 747                         # From: Jean-Pierre Chrétien <jeanpierre.chretien@free.fr>
 748                         # Date 11.03.2017
 749                         # Subject: cmake compilation error
 750                         #message(FATAL_ERROR "Wrong Qt-Version")
 751                 endif()
 752                 macro (qt_use_modules lyxtarget)
 753                         foreach (_tg ${ARGN})
 754                                 find_package(Qt5${_tg} CONFIG REQUIRED)
 755                                 target_link_libraries(${lyxtarget} Qt5::${_tg})
 756                         endforeach()
 757                 endmacro()
 758                 macro (qt_add_resources)
 759                         qt5_add_resources(${ARGN})
 760                 endmacro()
 761                 macro (qt_wrap_uifiles)
 762                         qt5_wrap_ui(${ARGN})
 763                 endmacro()
 764                 message(STATUS "Found Qt-Version ${QTVERSION}")
 765                 if(WIN32)
 766                         set(LYX_QTMAIN_LIBRARY ${Qt5Core_QTMAIN_LIBRARIES})
 767                 endif()
 768         endif()
 769 elseif(LYX_USE_QT MATCHES "QT4")
 770         if(LYX_XMINGW)
 771                 set(QT_MINGW_DIR ${LYX_QT4} CACHE PATH "Qt for Mingw" FORCE)
 772                 list(APPEND CMAKE_FIND_ROOT_PATH ${QT_MINGW_DIR} ${GNUWIN32_DIR})
 773         endif()
 774         find_package(Qt4 "4.5.0" REQUIRED)
 775         macro (qt_use_modules)
 776         endmacro()
 777         macro (qt_add_resources)
 778                 qt4_add_resources(${ARGN})
 779         endmacro()
 780         macro (qt_wrap_uifiles)
 781                 qt4_wrap_ui(${ARGN})
 782         endmacro()
 783         set(LYX_QTMAIN_LIBRARY ${QT_QTSVG_LIBRARY})
 784         if(WIN32)
 785                 list(APPEND LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARIES})
 786         endif()
 787 else()
 788   message(FATAL_ERROR "Unhandled value for LYX_USE_QT (${LYX_USE_QT})")
 789 endif()
 790
 791 find_package(Magic)
 792 if(Magic_FOUND)
 793   set(HAVE_MAGIC_H 1)
 794   include_directories(${Magic_INCLUDE_DIR})
 795 endif()
 796
 797 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 798
 799 set(Spelling_FOUND OFF)
 800 set(Include_used_spellchecker)   # String will be inserted into config.h
 801
 802 if (LYX_EXTERNAL_MYTHES MATCHES "AUTO")
 803   # try system library first
 804   find_package(MyThesLIB)
 805   if (MYTHESLIB_FOUND)
 806     set(LYX_EXTERNAL_MYTHES ON CACHE STRING "OFF:= Build 3rdparty mytheslib" FORCE)
 807   else()
 808     set(LYX_EXTERNAL_MYTHES OFF CACHE STRING "OFF:= Build 3rdparty mytheslib" FORCE)
 809   endif()
 810 endif()
 811 if (LYX_EXTERNAL_MYTHES MATCHES "ON")
 812   find_package(MyThesLIB REQUIRED)
 813 else()
 814   add_subdirectory(3rdparty/mythes)
 815 endif()
 816 set(MYTHES_DIR ${MYTHESLIB_INCLUDE_DIR})
 817
 818 if(NOT LYX_EXTERNAL_HUNSPELL)
 819     add_subdirectory(3rdparty/hunspell)
 820     add_definitions(-DHUNSPELL_STATIC)
 821     set(HUNSPELL_FOUND ON)
 822     message(STATUS "  * Hunspell:")
 823     message(STATUS "     - include: ${HUNSPELL_INCLUDE_DIR}")
 824     message(STATUS "     - library: ${HUNSPELL_LIBRARY}")
 825 endif()
 826
 827 foreach(_spell "ASPELL" "ENCHANT" "HUNSPELL")
 828   string(TOUPPER ${_spell} _upspell)
 829   if (NOT ${_upspell}_FOUND)
 830     find_package(${_spell})
 831   endif()
 832   if (${_upspell}_FOUND)
 833     include_directories(${${_upspell}_INCLUDE_DIR})
 834     set(Spelling_FOUND ON)
 835     message(STATUS "Building with USE_${_upspell}")
 836     set(Include_used_spellchecker "${Include_used_spellchecker}#define USE_${_upspell} 1\n")
 837   else()
 838     if(LYX_${_upspell})
 839       message(FATAL_ERROR "Required ${_spell} devel package not found")
 840     else()
 841       message(STATUS "${_upspell} not found, building without ${_spell} support")
 842     endif()
 843   endif()
 844 endforeach()
 845
 846 if(GNUWIN32_DIR)
 847         list(APPEND CMAKE_PROGRAM_PATH "${GNUWIN32_DIR}/Python" )
 848 endif()
 849
 850 # Search for python default version first
 851 unset(PYTHON_EXECUTABLE CACHE)
 852 unset(LYX_PYTHON_EXECUTABLE CACHE)
 853 unset(PYTHON_VERSION_MAJOR)
 854 unset(PYTHON_VERSION_MINOR)
 855 unset(PYTHON_VERSION_STRING)
 856 if (CMAKE_VERSION VERSION_LESS "3.13")
 857   find_package(PythonInterp 3.5 QUIET)
 858   if(NOT PYTHONINTERP_FOUND)
 859     find_package(PythonInterp 2.0 REQUIRED)
 860     if(NOT PYTHON_VERSION_STRING VERSION_LESS 2.8)
 861       message(FATAL_ERROR "Python interpreter found, but is not suitable")
 862     endif()
 863   endif()
 864   set(LYX_PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 865 else()
 866   find_package(Python3 3.5 QUIET)
 867   if(NOT Python3_Interpreter_FOUND)
 868     unset(PYTHON_EXECUTABLE CACHE)
 869     find_package(Python2 2.0 REQUIRED)
 870     if(NOT Python2_VERSION VERSION_LESS 2.8)
 871       message(FATAL_ERROR "Python interpreter found, but is not suitable")
 872     endif()
 873     set(LYX_PYTHON_EXECUTABLE ${Python2_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 874   else()
 875     set(LYX_PYTHON_EXECUTABLE ${Python3_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 876   endif()
 877 endif()
 878
 879 if(LYX_NLS)
 880         find_package(LyXGettext)
 881         if(LYX_PYTHON_EXECUTABLE AND GETTEXT_FOUND)
 882                 add_subdirectory(po "${TOP_BINARY_DIR}/po")
 883         else()
 884                 # Install only supplied .gmo-files
 885                 file(GLOB _gmofiles RELATIVE "${TOP_SRC_DIR}/po" "${TOP_SRC_DIR}/po/*.gmo")
 886                 message(STATUS "Installing provided .gmo-files only")
 887                 foreach( _gmo ${_gmofiles})
 888                         string(REGEX REPLACE "\\.gmo$" "" _lang ${_gmo})
 889                         install(FILES "${TOP_SRC_DIR}/po/${_gmo}" DESTINATION ${LYX_LOCALEDIR}/${_lang}/LC_MESSAGES RENAME ${PACKAGE}.mo)
 890                 endforeach()
 891         endif()
 892 endif()
 893
 894 if(LYX_EXTERNAL_ICONV)
 895   find_package(ICONV REQUIRED)
 896 else()
 897   add_subdirectory(3rdparty/libiconv)
 898   set(HAVE_ICONV_CONST 1)
 899 endif()
 900
 901 if(LYX_EXTERNAL_Z)
 902   find_package(ZLIB REQUIRED)
 903 else()
 904   add_subdirectory(3rdparty/zlib)
 905 endif()
 906
 907 if(NOT LYX_EXTERNAL_DTL)
 908   add_subdirectory(3rdparty/dtl)
 909 endif()
 910
 911 if(LYX_USE_STD_REGEX)
 912   # Set only include path.
 913   # Use internal boost, which is known to exist
 914   # we don't need any libraries
 915   set(Lyx_Boost_Libraries)
 916   add_definitions(-DBOOST_USER_CONFIG=<config.h>)
 917   include_directories(${TOP_SRC_DIR}/3rdparty/boost)
 918 else()
 919   # Using boost-regex
 920   if(LYX_EXTERNAL_BOOST)
 921     message(STATUS "Searching for external boost")
 922     find_package(Boost COMPONENTS regex)
 923     if(Boost_FOUND)
 924       message(STATUS "Boost found")
 925       message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 926       set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 927       if (LYX_STDLIB_DEBUG)
 928         # Comment from  Jean-Marc Lasgouttes:
 929         # In general, system boost libraries are incompatible with
 930         # the use of stdlib-debug in libstdc++. See ticket #9736 for
 931         # details.
 932         message(WARNING "Compiling LyX with stdlib-debug and system boost libraries may lead to crashes. Consider using '-DLYX_STDLIB_DEBUG=OFF' or using '-DLYX_EXTERNAL_BOOST=OFF'")
 933       endif()
 934     else()
 935       message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 936     endif()
 937   else()
 938     # Using included boost
 939     set(Lyx_Boost_Libraries boost_regex)
 940     add_definitions(-DBOOST_USER_CONFIG=<config.h>)
 941     include_directories(${TOP_SRC_DIR}/3rdparty/boost)
 942     add_subdirectory(3rdparty/boost "${TOP_BINARY_DIR}/3rdparty/boost")
 943   endif()
 944 endif()
 945
 946 if(WIN32)
 947         if(LYX_CONSOLE)
 948                 set(LYX_QTMAIN_LIBRARY)
 949         else()
 950                 set(WIN32_CONSOLE WIN32)
 951         endif()
 952         if(MSVC)
 953                 # -DPSAPI_VERSION=1 is needed to run on vista (bug 10186)
 954                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX -DPSAPI_VERSION=1)
 955                 # disable checked iterators for msvc release builds to get maximum speed
 956                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 957         else()
 958                 # -DPSAPI_VERSION=1 is not needed for mingw, since the mingw psapi.h
 959                 # does not use it and always declares the vista compatible API.
 960                 # If this ever changes then -DPSAPI_VERSION might be needed here as well.
 961                 add_definitions(-DWINVER=0x0500)
 962         endif()
 963 endif()
 964
 965 # Compute qt-version from ${QTVERSION}
 966
 967 message(STATUS "")
 968 foreach(_v PACKAGE PACKAGE_VERSION
 969         PROGRAM_SUFFIX LYX_VERSION LYX_DIR_VER LYX_USERDIR_VER
 970         LYX_ABS_TOP_SRCDIR
 971         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 972         if(NOT DEFINED ${_v})
 973                 message(FATAL_ERROR "${_v} not defined")
 974         endif()
 975         string(SUBSTRING "${_v}                            " 0 28 _v1)
 976         message(STATUS "----- ${_v1}: ${${_v}}")
 977 endforeach(_v)
 978 message(STATUS "")
 979
 980
 981 if(LYX_PCH)
 982         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 983         # Not sure if it works for all non-msvc compilers
 984         include(PCHSupport_26)
 985         configure_file(${TOP_CMAKE_PATH}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
 986         configure_file(${TOP_CMAKE_PATH}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 987         add_definitions(-DLYX_ENABLE_PCH)
 988
 989         if(MSVC)
 990                 macro(lyx_add_msvc_pch name_)
 991                         set_source_files_properties(${${name_}_sources} PROPERTIES
 992                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 993                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
 994                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 995                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
 996                                 ${TOP_BINARY_DIR}/pcheaders.h)
 997                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 998                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 999                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
1000                 endmacro(lyx_add_msvc_pch)
1001                 macro(lyx_add_gcc_pch name_)
1002                 endmacro()
1003         else()
1004                 macro(lyx_add_msvc_pch name_)
1005                 endmacro()
1006                 macro(lyx_add_gcc_pch name_)
1007                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT)
1008                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
1009                 endmacro()
1010         endif()
1011 else()
1012         macro(lyx_add_msvc_pch)
1013         endmacro(lyx_add_msvc_pch)
1014         macro(lyx_add_gcc_pch name_)
1015         endmacro()
1016 endif()
1017
1018
1019 if(MSVC)
1020
1021         if(LYX_VLD)
1022                 set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/development/Win32/vld)
1023                 add_subdirectory(${vld_path}/cmake)
1024                 include(${vld_path}/cmake/vld.cmake) # forced include
1025                 set(vld_dll vld)
1026         endif()
1027
1028         if(LYX_WALL)
1029                 # Use the highest warning level
1030                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE STRING "Warning level" FORCE)
1031
1032                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
1033                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
1034                 else()
1035                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
1036                 endif()
1037
1038                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
1039                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
1040                 else()
1041                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
1042                 endif()
1043
1044                 # add here warnings which should produce an error /weXXXX
1045                 set(MSVC_W_ERROR   "/we4101 /we4189")
1046                 # add here warnings which should be disabled /wdXXXX
1047                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
1048
1049                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1050                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1051                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1052
1053         else()
1054                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE STRING "Warning level" FORCE)
1055
1056                 # add here warnings which should produce an error /weXXXX
1057                 set(MSVC_W_ERROR   "/we4101 /we4189")
1058                 # add here warnings which should be disabled /wdXXXX
1059                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
1060
1061                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1062                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1063                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1064
1065         endif()
1066
1067         if (NOT Qt5Core_FOUND)
1068                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
1069                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
1070                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
1071         endif()
1072
1073         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
1074         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
1075         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
1076         message(STATUS "")
1077 endif()
1078
1079
1080 # Xcode compiler
1081 if (CMAKE_GENERATOR MATCHES Xcode)
1082         if (XCODE_VERSION VERSION_LESS "5.0")
1083                 # Automatically select the Xcode compiler if not set
1084                 if (NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
1085                         # XCode >= 3.1 has gcc 4.2 (up to actual Xcode)
1086                         if (XCODE_VERSION VERSION_GREATER "3.1")
1087                                 SET(CMAKE_XCODE_ATTRIBUTE_GCC_VERSION "com.apple.compilers.llvmgcc42")
1088                         ENDIF(XCODE_VERSION VERSION_GREATER "3.1")
1089                 ENDIF(NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
1090                 # Print the selected compiler version
1091         MESSAGE(STATUS "---- Using XCode compiler CMAKE_XCODE_ATTRIBUTE_GCC_VERSION=${CMAKE_XCODE_ATTRIBUTE_GCC_VERSION}")
1092         ENDIF(XCODE_VERSION VERSION_LESS "5.0")
1093 ENDIF(CMAKE_GENERATOR MATCHES Xcode)
1094
1095 if (WIN32 AND Qt5Core_FOUND)
1096         set(Z_PREFIX 1)
1097 endif()
1098
1099 # compiler tests, config.h generation LYX_CONFIGURE_CHECKS
1100 include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
1101 configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
1102
1103 unset(opts)
1104 foreach(_option ${LYX_OPTIONS})
1105   if(${_option}_show_message)
1106     string(SUBSTRING "${_option}                            " 0 31 _var)
1107     get_property(_prop CACHE ${_option} PROPERTY STRINGS)
1108     list(FIND LYX_OPTION_STRINGS ${_option} _index)
1109     if (${_index} GREATER -1)
1110       set(_isset ${${_option}})
1111     elseif(${_option})
1112       set(_isset ON)
1113     else()
1114       set(_isset OFF)
1115     endif()
1116     string(SUBSTRING "${_isset}           " 0 10 _val)
1117     set(opts "${opts} ${_option}(${${_option}})")
1118   endif()
1119 endforeach()
1120 set(tmp_vi "CMake Build")
1121 list(APPEND tmp_vi "  Host name:               ${CMAKE_HOST_SYSTEM_NAME}")
1122 list(APPEND tmp_vi "  Host processor:          ${CMAKE_HOST_SYSTEM_PROCESSOR}")
1123 list(APPEND tmp_vi "  Build flags:             ${opts}")
1124 list(APPEND tmp_vi "  C++ Compiler:            ${CMAKE_CXX_COMPILER_ID} (${CMAKE_CXX_COMPILER_VERSION})")
1125 list(APPEND tmp_vi "  C++ Compiler flags:      ${CMAKE_CXX_FLAGS}")
1126 if (LYX_DEBUG)
1127 list(APPEND tmp_vi "  C++ Compiler user flags: ${CMAKE_CXX_FLAGS_DEBUG}")
1128 else()
1129 list(APPEND tmp_vi "  C++ Compiler user flags: ${CMAKE_CXX_FLAGS_RELEASE}")
1130 endif()
1131 list(APPEND tmp_vi "  Qt version:              ${QTVERSION}")
1132 list(APPEND tmp_vi "  LyX binary dir:          ${CMAKE_INSTALL_PREFIX}/${LYX_UTILITIES_INSTALL_PATH}")
1133 get_data_destination(dest_data)
1134 list(APPEND tmp_vi "  LyX files dir:           ${CMAKE_INSTALL_PREFIX}/${dest_data}")
1135 string(REPLACE ";" "\\n" VERSION_INFO "${tmp_vi}")
1136
1137 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
1138 unset(opts)
1139 unset(tmp_vi)
1140
1141 if(QTVERSION MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+).*")
1142         MATH(EXPR QT4_VERSION "(${CMAKE_MATCH_1}<<16)|(${CMAKE_MATCH_2}<<8)|${CMAKE_MATCH_3}")
1143 endif()
1144
1145 if (NOT HAVE_REGEX)
1146         set(LYX_USE_STD_REGEX 0)
1147 endif()
1148
1149
1150 set (cmd ${CMAKE_CTEST_COMMAND})
1151 if (MSVC)
1152         set (cmd ${cmd} -C ${CMAKE_CFG_INTDIR})
1153 else ()
1154         set (cmd ${cmd} -C ${CMAKE_BUILD_TYPE})
1155 endif ()
1156 add_custom_target (lyx_run_tests COMMAND ${cmd})
1157 set_target_properties(lyx_run_tests PROPERTIES FOLDER "tests")
1158
1159 if(LYX_ASAN)
1160     set(LYX_CXX_FLAGS "-fsanitize=address -fno-omit-frame-pointer -g")
1161     message(STATUS)
1162     message(STATUS "Address sanitizer enabled. Usage:")
1163     message(STATUS "    wget https://llvm.org/svn/llvm-project/compiler-rt/trunk/lib/asan/scripts/asan_symbolize.py")
1164     message(STATUS "    chmod  +x ./asan_symbolize.py")
1165     message(STATUS "    ./bin/lyx2.2 2>&1 | ./asan_symbolize.py  | c++filt ")
1166     message(STATUS)
1167 endif()
1168
1169 if(LYX_INSTALL)
1170         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
1171                 message(STATUS "Python required to create doc!")
1172         else()
1173                 if(UNIX)
1174                         add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
1175                 endif()
1176                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
1177         endif()
1178 endif()
1179 include(../Install)
1180
1181 # By running the URL tests first, time can be saved when running the ctests in
1182 # parallel since the URL tests take a long time to run (e.g. 10 minutes).
1183 if(LYX_ENABLE_URLTESTS)
1184         add_subdirectory(development/checkurls "${TOP_BINARY_DIR}/checkurls")
1185 endif()
1186 add_subdirectory(src "${TOP_BINARY_DIR}/src")
1187 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
1188 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
1189 add_subdirectory(lib/examples "${TOP_BINARY_DIR}/lib/examples")
1190 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
1191 add_subdirectory(development/autotests "${TOP_BINARY_DIR}/autotests")
1192 add_subdirectory(development/batchtests "${TOP_BINARY_DIR}/batchtests")
1193
1194 message(STATUS)
1195 message(STATUS "Build params, switch LYX_* options by -DLYX_*=ON or OFF, LYX_* combos by -DLYX_*=value:")
1196 message(STATUS)
1197
1198 LYX_OPTION_LIST_ALL(used)
1199
1200
1201 if(LYX_NLS)
1202         message(STATUS)
1203         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
1204         message(STATUS)
1205         message(STATUS "  * iconv")
1206         message(STATUS "     - include: ${ICONV_INCLUDE_DIR}")
1207         message(STATUS "     - library: ${ICONV_LIBRARY}")
1208         message(STATUS "  * zlib")
1209         message(STATUS "     - include: ${ZLIB_INCLUDE_DIR}")
1210         message(STATUS "     - library: ${ZLIB_LIBRARY}")
1211         message(STATUS)
1212 endif()
1213
1214 # Apple has builtin native spell checker,
1215 # no need to warn for missing Aspell, Hunspell or Enchant
1216 if(NOT Spelling_FOUND AND NOT APPLE)
1217   if(LYX_REQUIRE_SPELLCHECK)
1218     set(_mode "FATAL_ERROR")
1219   else()
1220     set(_mode "STATUS")
1221   endif()
1222   message(${_mode} "No spellcheck libraries found. LyX will be unable use spellchecking")
1223 endif()
1224
1225 include("${TOP_CMAKE_PATH}/LyxPackaging.cmake")
1226
1227 if(ENABLE_DIST)
1228   # Use git to create the source package
1229   # git archive --format=tgz --output=/home/kornel/x.tar.gz master
1230   if(UNIX)
1231     set(DIST_FORMAT tgz)
1232   else()
1233     set(DIST_FORMAT zip)
1234   endif()
1235   set(DIST_NAME ${CMAKE_PROJECT_NAME}-${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}-${CMAKE_SYSTEM_NAME}.${DIST_FORMAT})
1236
1237   add_custom_command(
1238     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME}
1239     COMMAND  ${LYX_GITVERSION} archive --format=${DIST_FORMAT} --output=${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME} master
1240     WORKING_DIRECTORY ${TOP_SRC_DIR})
1241   add_custom_target(git-archive DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME})
1242 endif()
1243
1244 # Last directory to be included so that the fixup code (OS X)
1245 # can be run last
1246 add_subdirectory(development/cmake/post_install)
1247
1248 message(STATUS)