CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 2.6.4)
   8
   9 set(LYX_PROJECT LyX)
  10
  11 enable_testing()
  12
  13 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README ABSOLUTE)
  14 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  15
  16 set(LYX_CMAKE_DIR "development/cmake")
  17 set(TOP_CMAKE_PATH "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}")
  18 set(TOP_MODULE_PATH "${TOP_CMAKE_PATH}/modules")
  19 set(TOP_SCRIPT_PATH "${TOP_CMAKE_PATH}/scripts")
  20
  21 set(CMAKE_MODULE_PATH "${TOP_MODULE_PATH}")
  22
  23 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  24
  25 message(STATUS)
  26 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  27         message(STATUS "Building in-source")
  28         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  29 else()
  30         message(STATUS "Building out-of-source")
  31         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  32 endif()
  33
  34 # This directory should be used if some test uses lyx-executable
  35 set(LYX_TESTS_USERDIR "${TOP_BINARY_DIR}/Testing/.lyx")
  36 file(MAKE_DIRECTORY "${LYX_TESTS_USERDIR}")
  37
  38 if(COMMAND cmake_policy)
  39         cmake_policy(SET CMP0003 OLD)
  40         cmake_policy(SET CMP0005 OLD)
  41         # Installing MACOSX_BUNDLE targets requires a BUNDLE DESTINATION
  42         cmake_policy(SET CMP0006 NEW)
  43         if(POLICY CMP0028)
  44                 cmake_policy(SET CMP0028 OLD)
  45         endif()
  46         if(POLICY CMP0043)
  47                 # COMPILE_DEFINITIONS are not used yet. Enable new behavior.
  48                 cmake_policy(SET CMP0043 NEW)
  49         endif()
  50 endif()
  51
  52 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  53
  54 # Supress regeneration
  55 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  56
  57 if(LYX_XMINGW)
  58     set(CMAKE_SYSTEM_NAME Windows)
  59     set(TOOLNAME ${LYX_XMINGW})
  60     set(TOOLCHAIN "${TOOLNAME}-")
  61     set(CMAKE_C_COMPILER   "${TOOLCHAIN}gcc"     CACHE PATH "Mingw C compiler" FORCE)
  62     set(CMAKE_CXX_COMPILER "${TOOLCHAIN}g++"     CACHE PATH "Mingw C++ compiler" FORCE)
  63     set(CMAKE_RC_COMPILER  "${TOOLCHAIN}windres" CACHE PATH "Mingw rc compiler" FORCE)
  64
  65     set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM BOTH)
  66     set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY)
  67     set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY)
  68 endif()
  69
  70 if(NOT help AND NOT HELP)
  71         # 'project' triggers the searching for a compiler
  72         project(${LYX_PROJECT})
  73 endif()
  74
  75 if(UNIX)
  76         set(ARCH_TRIPLET )
  77         FIND_PROGRAM(DPKG_ARCHITECTURE_EXECUTABLE dpkg-architecture)
  78         if(DPKG_ARCHITECTURE_EXECUTABLE)
  79                 EXECUTE_PROCESS(COMMAND ${DPKG_ARCHITECTURE_EXECUTABLE} -qDEB_HOST_MULTIARCH
  80                                 OUTPUT_VARIABLE ARCH_TRIPLET
  81                                 ERROR_VARIABLE ERROR_ARCH_TRIPLET
  82                                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  83         endif()
  84 endif()
  85 if(ARCH_TRIPLET)
  86         set(SYSTEM_LIB_DIRS /usr/lib /usr/lib/${ARCH_TRIPLET} /usr/local/lib)
  87 else()
  88         set(SYSTEM_LIB_DIRS /usr/lib /usr/local/lib)
  89 endif()
  90
  91 include(LyXMacros)
  92
  93 # Usage LYX_OPTION
  94 # 1. parameter: option name without prefix 'LYX_'
  95 # 2. parameter: description
  96 # 3. parameter: default value, ON or OFF
  97 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
  98
  99 # Usage LYX_COMBO
 100 # 1. parameter: name without prefix 'LYX_'
 101 # 2. parameter: description
 102 # 3. parameter: default value
 103 # 4-n parameter: possible other string values
 104
 105 LYX_OPTION_INIT()
 106
 107 # Options for all compilers/systems
 108 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
 109 LYX_OPTION(LOCALVERSIONING  "Add version info to created package name (only used if LYX_CPACK option set)" OFF ALL)
 110 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
 111 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
 112 LYX_OPTION(REQUIRE_SPELLCHECK "Abort if no spellchecker available" OFF ALL)
 113 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
 114 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
 115 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
 116 LYX_OPTION(DEVEL_VERSION    "Build developer version" OFF ALL)
 117 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" OFF ALL)
 118 LYX_OPTION(DEBUG            "Enforce debug build"  OFF ALL)
 119 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
 120 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
 121 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
 122 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
 123 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
 124 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
 125 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
 126 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
 127 LYX_OPTION(ENABLE_URLTESTS  "Enable for URL tests" OFF ALL)
 128 LYX_OPTION(ENABLE_EXPORT_TESTS "Enable for export tests" OFF ALL)
 129 LYX_OPTION(ASAN             "Use address sanitizer" OFF ALL)
 130
 131 # GCC specific
 132 LYX_OPTION(PROFILE              "Build profile version" OFF GCC)
 133 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" OFF GCC)
 134 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
 135 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
 136 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++ pedantic debug mode" OFF GCC)
 137 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" OFF GCC)
 138 LYX_OPTION(CONCEPT_CHECKS       "Enable concept-checks" OFF GCC)
 139 LYX_OPTION(PROFILE              "Build with options for gprof" OFF GCC)
 140 LYX_OPTION(ENABLE_CXX11         "Build with options for c++11-mode" OFF GCC)
 141
 142 # MSVC specific
 143 LYX_OPTION(CONSOLE               "Show console on Windows, enforce with =FORCE" ON MSVC)
 144 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
 145 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
 146 LYX_OPTION(CONFIGURE_CHECKS      "Also run configure checks for MSVC" OFF MSVC)
 147 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
 148
 149 # APPLE specific
 150 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
 151 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
 152 if(LYX_XMINGW)
 153   LYX_COMBO(USE_QT               "Use Qt version as frontend for MINGW" QT4)
 154 else()
 155   LYX_COMBO(USE_QT               "Use Qt version as frontend" QT4 QT5)
 156 endif()
 157
 158
 159 if(help OR HELP)
 160         message(STATUS)
 161         message(STATUS "Available options: (dis/enable with -DLYX_*=OFF/ON)")
 162         message(STATUS)
 163         LYX_OPTION_LIST_ALL(help)
 164         message(STATUS)
 165         RETURN()
 166 endif()
 167
 168 # Check option dependencies
 169
 170 if(LYX_DMG)
 171         set(LYX_BUNDLE ON)
 172         set(LYX_CPACK ON)
 173 endif()
 174
 175 if(LYX_CPACK)
 176         set(LYX_INSTALL ON)
 177 endif()
 178
 179 if(LYX_INSTALL)
 180         set(LYX_NLS ON)
 181         if(WIN32 AND NOT MINGW)
 182                 set(LYX_HUNSPELL ON)
 183         endif()
 184         if(LYX_CONSOLE MATCHES "FORCE")
 185                 set(LYX_CONSOLE ON)
 186         else()
 187                 set(LYX_CONSOLE OFF)
 188         endif()
 189         set(LYX_PACKAGE_SUFFIX ON)
 190         if(NOT LYX_DEBUG)
 191                 set(LYX_RELEASE ON)
 192         endif()
 193         set(LYX_PROFILE OFF)
 194 endif()
 195
 196
 197 if(LYX_MERGE_FILES)
 198         set(LYX_PCH OFF)
 199 else()
 200         set(LYX_MERGE_REBUILD OFF)
 201 endif()
 202
 203
 204 if(LYX_DEPENDENCIES_DOWNLOAD)
 205         message(STATUS)
 206         set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 207         message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 208         set(deps_files lyx20-deps-msvc2010-x86.zip)
 209         set(deps_server http://downloads.sourceforge.net/project/lyx/Win_installers/Dependencies)
 210         foreach(it ${deps_files})
 211                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 212                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 213                 if(NOT already_downloaded)
 214                         message(STATUS "Downloading ${it} ...")
 215                         file(DOWNLOAD ${deps_server}/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS STATUS status LOG log)
 216                         list(GET status 0 status_code)
 217                         list(GET status 1 status_string)
 218                         if(NOT status_code EQUAL 0)
 219                                 file(REMOVE ${LYX_DEPENDENCIES_DIR}/${it})
 220                                 message(FATAL_ERROR "error: downloading '${it}' failed. status_code: ${status_code}, status_string: ${status_string}. \nLog: ${log} ")
 221                         endif()
 222                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 223                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 224                 endif()
 225         endforeach()
 226         set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/deps20)
 227     if(MSVC12)
 228         # handle error in msvc12 when linking against msvc10 libs
 229         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /vd2")
 230     endif()
 231 endif()
 232
 233
 234
 235 message(STATUS)
 236
 237 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 238 if(WIN32)
 239         set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 240 else()
 241         set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 242 endif()
 243
 244
 245 set(LYX_GCC11_MODE)
 246 if(UNIX OR MINGW)
 247         execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION)
 248         message(STATUS "Using GCC version ${GCC_VERSION}")
 249 # disabled because of missing match_partial
 250 #       if(GCC_VERSION VERSION_LESS 4.9)
 251                 # <regex> in gcc is unusable in versions less than 4.9.0
 252                 # see https://gcc.gnu.org/bugzilla/show_bug.cgi?id=53631
 253                 set(LYX_USE_STD_REGEX 0)
 254 #       endif()
 255         if (LYX_ENABLE_CXX11)
 256                 find_package(CXX11Compiler)
 257                 if(NOT CXX11COMPILER_FOUND)
 258                         message(FATAL_ERROR "A C++11 compatible compiler is required.")
 259                 endif()
 260                 set(LYX_GCC11_MODE "${CXX11_FLAG}")
 261         endif()
 262 else()
 263 # disabled because of missing match_partial
 264         set(LYX_USE_STD_REGEX 0)
 265 #       if(MSVC10)
 266 #               set(LYX_USE_STD_REGEX 1) #TODO should we use it in ECMAScript mode?
 267 #       endif()
 268 endif()
 269
 270
 271 set(VERSION_INFO "CMake Build")
 272
 273 # Try to get some informations from configure.ac
 274
 275 include(LyXPaths)
 276 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 277
 278 if(WIN32)
 279         set(USE_WINDOWS_PACKAGING ON)
 280 elseif(APPLE)
 281         set(USE_MACOSX_PACKAGING ON)
 282 else()
 283         set(USE_POSIX_PACKAGING ON)
 284 endif()
 285
 286 macro(setstripped _varname)
 287         if(${ARGC} GREATER 1)
 288                 string(STRIP "${ARGV1}" _v)
 289                 if(USE_POSIX_PACKAGING)
 290                         string(TOLOWER ${_v} ${_varname})
 291                 else()
 292                         set(${_varname} ${_v})
 293                 endif()
 294         else()
 295                 set(${_varname})
 296         endif()
 297 endmacro(setstripped)
 298
 299 foreach(_c_l ${_config_lines} )
 300         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 301                 setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 302                 setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 303                 setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 304                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\)\(\\.\([0-9]+\)\)?.*$")
 305                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 306                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 307                         set(LYX_PATCH_VERSION ${CMAKE_MATCH_4})
 308                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 309                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 310                         set(LYX_INSTALL_SUFFIX "${CMAKE_MATCH_1}.${CMAKE_MATCH_2}")
 311                 endif()
 312         endif()
 313         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 314                 set(LYX_DATE "${CMAKE_MATCH_1}")
 315         endif()
 316 endforeach(_c_l)
 317
 318 FIND_PROGRAM(LYX_GITVERSION git)
 319 #message(STATUS "gitversion = ${LYX_GITVERSION}")
 320 set(LYX_REVISION_VERSION ${LYX_PATCH_VERSION})
 321 if(LYX_GITVERSION)
 322   if (LYX_LOCALVERSIONING)
 323     # Find the revision number and for later use
 324     EXECUTE_PROCESS(COMMAND ${LYX_GITVERSION} describe --match 2.0.0 HEAD
 325       WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE LYX_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 326     if (LYX_PACKAGE_RELEASE MATCHES "^2\\.0\\.0\\-\([0-9]+\)\\-.*$")
 327       # We will add offset of 40000 to get appropriate value to
 328       # previous svn.
 329       # We use this value than also to set the package-patch-value
 330       MATH(EXPR tmp_REVISION_VERSION "(${CMAKE_MATCH_1}+40000)")
 331       set(LYX_REVISION_VERSION "${LYX_PATCH_VERSION}-${tmp_REVISION_VERSION}git")
 332       set(ENABLE_DIST ON)
 333     endif()
 334   endif()
 335 endif()
 336
 337 # Set the programs (lyx, tex2lyx, etc.) suffix
 338 # When building an OS X bundle, we will append
 339 # the suffix only to the bundle, not to the programs
 340 set(PROGRAM_SUFFIX "")
 341 if(LYX_PROGRAM_SUFFIX AND NOT (APPLE AND LYX_BUNDLE))
 342         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 343 endif()
 344 set(_lyx "${PACKAGE_BASE}${PROGRAM_SUFFIX}")
 345 set(_tex2lyx tex2lyx${PROGRAM_SUFFIX})
 346
 347 add_custom_target(lyx_version ALL
 348   COMMAND ${CMAKE_COMMAND} -DTOP_SRC_DIR=${TOP_SRC_DIR} -DTOP_CMAKE_PATH=${TOP_CMAKE_PATH} -DTOP_BINARY_DIR=${TOP_BINARY_DIR} -DLYX_DATE=${LYX_DATE} -P ${TOP_SCRIPT_PATH}/LyXGetVersion.cmake
 349   )
 350 set_target_properties(lyx_version PROPERTIES FOLDER "applications")
 351
 352 # Default paths for installed utilities (tex2lyx, lyxclient, etc.)
 353 set(LYX_UTILITIES_INSTALL_PATH bin)
 354
 355 if(LYX_BUNDLE)
 356         set(LYX_CPACK ON)
 357
 358         message(STATUS)
 359         message(STATUS "Bundle creation is enabled (experimental):")
 360         message(STATUS "    make")
 361         message(STATUS "    make install/strip")
 362         message(STATUS "    make package")
 363         if(APPLE)
 364                 set(MACOSX_BUNDLE TRUE)
 365                 # This sets the bundle + executable names
 366                 set(_lyx "${PACKAGE_BASE}${LYX_INSTALL_SUFFIX}")
 367                 # This sets the Info.plist executable name
 368                 set(osx_bundle_program_name ${_lyx})
 369                 # Bundle name
 370                 set(LYX_BUNDLE_NAME ${_lyx})
 371
 372                 # This will contain the list of files that need to be included
 373                 # in the bundle and their location within the bundle
 374                 set(OSX_BUNDLE_FILES "${TOP_SRC_DIR}/development/MacOSX/LyX.sdef;${TOP_SRC_DIR}/development/MacOSX/LyXapp.icns;${CMAKE_BINARY_DIR}/lyxrc.dist")
 375                 set(OSX_BUNDLE_DIRS "Resources;Resources;Resources")
 376
 377                 # Process Info.plist and lyxrc.dist
 378                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/Info.plist.in" "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 379                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/lyxrc.dist.in" "${CMAKE_CURRENT_BINARY_DIR}/lyxrc.dist")
 380
 381                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 382                 set(LYX_DATA_SUBDIR ${LYX_BUNDLE_NAME}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 383
 384                 # Variables used by CPack
 385                 set(CPACK_BUNDLE_NAME ${LYX_BUNDLE_NAME})
 386                 set(CPACK_BUNDLE_PLIST "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 387                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${LYX_BUNDLE_NAME}.app)
 388
 389                 # Set the install paths
 390                 set(LYX_UTILITIES_INSTALL_PATH ${LYX_BUNDLE_NAME}.app/Contents/MacOS)
 391                 if(NOT LYX_INSTALL_PREFIX)
 392                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 393                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 394                 endif()
 395                 # Change the owner so that the install can work
 396                 install(CODE "set(BU_CHMOD_BUNDLE_ITEMS 1)" COMPONENT Runtime)
 397         elseif(UNIX)
 398                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 399                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 400                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 401         elseif(WIN32)
 402                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 403         endif()
 404 endif()
 405
 406 if(LYX_INSTALL_PREFIX)
 407         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 408         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 409 endif()
 410 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 411
 412 string(REGEX REPLACE "/lyx${LYX_INSTALL_SUFFIX}$" "/share" SYSTEM_DATADIR ${CMAKE_INSTALL_PREFIX})
 413
 414 if(LYX_PACKAGE_SUFFIX)
 415         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 416 else()
 417         set(PACKAGE ${PACKAGE_BASE})
 418 endif()
 419
 420 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 421         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 422         if (UNIX)
 423                 # don't use the default "/usr/local"
 424                 # but respect the user-choice on the command-line
 425                 if(LYX_INSTALL_SUFFIX)
 426                         set(CMAKE_INSTALL_PREFIX "/usr/local/lyx${LYX_INSTALL_SUFFIX}" CACHE PATH "LyX default install prefix" FORCE)
 427                 else()
 428                         set(CMAKE_INSTALL_PREFIX "/usr/local/${LYX_PROJECT}" CACHE PATH "LyX default install prefix" FORCE)
 429                 endif()
 430         endif()
 431         if(WIN32)
 432                 set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 433         endif()
 434 endif()
 435 if(IS_ABSOLUTE)
 436         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 437 else()
 438         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 439 endif()
 440
 441
 442
 443 if(NOT LYX_DATA_SUBDIR)
 444         if (WIN32)
 445                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 446         else()
 447                 set(LYX_DATA_SUBDIR "" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 448         endif()
 449 endif()
 450
 451 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 452 set(LYX_LOCALEDIR "locale")
 453 set(LYX_ABS_INSTALLED_LOCALEDIR "${LYX_ABS_INSTALLED_DATADIR}/${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}")
 454 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 455
 456 if(LYX_BUNDLE AND APPLE)
 457         set(LYX_MAN_DIR "${LYX_DATA_SUBDIR}" CACHE STRING "Install location for man pages.")
 458 else()
 459         set(LYX_MAN_DIR "/usr/local/man/man1" CACHE STRING "Install location for man pages.")
 460 endif()
 461 mark_as_advanced(LYX_MAN_DIR)
 462
 463 if(LYX_INSTALL AND WIN32)
 464         message(STATUS "Configuring NSIS files")
 465         configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 466         configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 467         configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 468         message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 469 endif()
 470
 471 if(NOT GROUP_CODE)
 472         #set(GROUP_CODE "The Golden Code")
 473         set(GROUP_CODE flat)
 474 endif()
 475
 476 # lyx's source files
 477 set(LYX_CPP_FILES [a-zA-Z]*.cpp)
 478 set(LYX_HPP_FILES [a-zA-Z]*.h)
 479 set(LYX_MOC_FILES moc_*.cpp)
 480
 481 include(ProjectSourceGroup)
 482
 483
 484 if(LYX_PROFILE AND NOT MSVC)
 485         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 486         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg")
 487         set(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS}  -pg")
 488 else()
 489         set(LYX_PROFILE OFF)
 490 endif()
 491
 492
 493 if(LYX_NO_OPTIMIZE)
 494         set(CMAKE_BUILD_TYPE None)
 495         set(LYX_DEBUG OFF)
 496         set(LYX_RELEASE OFF)
 497         set(LYX_PROFILE OFF)
 498 elseif(LYX_RELEASE)
 499         set(CMAKE_BUILD_TYPE Release)
 500         set(LYX_DEBUG OFF)
 501         set(LYX_PROFILE OFF)
 502 elseif(LYX_PROFILE)
 503         set(CMAKE_BUILD_TYPE Profile)
 504         set(LYX_DEBUG OFF)
 505 else()
 506         set(CMAKE_BUILD_TYPE Debug)
 507         set(LYX_DEBUG ON)
 508 endif()
 509
 510
 511 # When shared libs are supported enable this option
 512 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 513 if(LYX_SHARED_LIBRARIES)
 514         set(library_type SHARED)
 515 else()
 516         set(library_type STATIC)
 517 endif()
 518
 519 if(NOT MSVC)
 520         if(NOT LYX_QUIET)
 521                 set(CMAKE_VERBOSE_MAKEFILE ON)
 522         endif()
 523     set(LYX_CXX_FLAGS "-Wall -Wunused-parameter ${LYX_GCC11_MODE}")
 524         if(LYX_STDLIB_DEBUG)
 525                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 526         endif()
 527         if(LYX_CONCEPT_CHECKS)
 528                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCPP_CONCEPT_CHECKS")
 529         endif()
 530         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 531         set(CMAKE_CXX_FLAGS_DEBUG "${LYX_CXX_FLAGS} -fno-strict-aliasing -O0 -g3 -D_DEBUG" CACHE TYPE STRING FORCE)
 532         if(MINGW)
 533                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 534         else()
 535                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 536         endif()
 537 endif()
 538
 539 set(LYX_CXX_FLAGS_EXTRA "" CACHE STRING "Desired semicolon separated list of extra cxx compile flags, like '-Werror'")
 540 mark_as_advanced(LYX_CXX_FLAGS_EXTRA)
 541 if(LYX_CXX_FLAGS_EXTRA)
 542         foreach(_flag ${LYX_CXX_FLAGS_EXTRA})
 543                 add_definitions(${_flag})
 544         endforeach()
 545 endif()
 546
 547 if(LYX_XMINGW)
 548     set(QT_MINGW_DIR ${LYX_QT4} CACHE PATH "Qt for Mingw" FORCE)
 549     list(APPEND CMAKE_FIND_ROOT_PATH ${QT_MINGW_DIR} ${GNUWIN32_DIR})
 550 endif()
 551 if(LYX_USE_QT MATCHES "QT5")
 552         find_package(Qt5Core REQUIRED)
 553         if (Qt5Core_FOUND)
 554                 find_package(Qt5Widgets REQUIRED)
 555                 if(APPLE)
 556                         find_package(Qt5MacExtras REQUIRED)
 557                 endif()
 558                 find_package(Qt5X11Extras QUIET)
 559                 find_package(Qt5WinExtras QUIET)
 560                 set(QTVERSION ${Qt5Core_VERSION})
 561                 macro (qt_use_modules)
 562                         qt5_use_modules(${ARGN})
 563                 endmacro()
 564                 macro (qt_add_resources)
 565                         qt5_add_resources(${ARGN})
 566                 endmacro()
 567                 macro (qt_wrap_uifiles)
 568                         qt5_wrap_ui(${ARGN})
 569                 endmacro()
 570                 message(STATUS "Found Qt-Version ${QTVERSION}")
 571         endif()
 572 elseif(LYX_USE_QT MATCHES "QT4")
 573         find_package(Qt4 "4.5.0" REQUIRED)
 574         macro (qt_use_modules)
 575         endmacro()
 576         macro (qt_add_resources)
 577                 qt4_add_resources(${ARGN})
 578         endmacro()
 579         macro (qt_wrap_uifiles)
 580                 qt4_wrap_ui(${ARGN})
 581         endmacro()
 582 else()
 583   message(FATAL_ERROR "Unhandled value for LYX_USE_QT (${LYX_USE_QT})")
 584 endif()
 585
 586 find_package(Magic)
 587 if(Magic_FOUND)
 588         set(HAVE_MAGIC_H 1)
 589 endif()
 590
 591 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 592
 593 set(Spelling_FOUND OFF)
 594 set(Include_used_spellchecker)   # String will be inserted into config.h
 595
 596 foreach(_spell "ASPELL" "Enchant" "Hunspell")
 597   string(TOUPPER ${_spell} _upspell)
 598   find_package(${_spell})
 599   if (${_upspell}_FOUND)
 600     include_directories(${${_upspell}_INCLUDE_DIR})
 601     set(Spelling_FOUND ON)
 602     message(STATUS "Building with USE_${_upspell}")
 603     set(Include_used_spellchecker "${Include_used_spellchecker}#define USE_${_upspell} 1\n")
 604   else()
 605     if(LYX_${_upspell})
 606       message(FATAL_ERROR "Required ${_spell} devel package not found")
 607     else()
 608       message(STATUS "${_upspell} not found, building without ${_spell} support")
 609     endif()
 610   endif()
 611 endforeach()
 612
 613 if(LYX_NLS)
 614         FIND_PROGRAM(LYX_PYTHON_EXECUTABLE python2 python HINTS ${GNUWIN32_DIR}/python)
 615         find_package(LyXGettext)
 616         if(LYX_PYTHON_EXECUTABLE AND GETTEXT_FOUND)
 617                 add_subdirectory(po "${TOP_BINARY_DIR}/po")
 618         else()
 619                 # Install only supplied .gmo-files
 620                 file(GLOB _gmofiles RELATIVE "${TOP_SRC_DIR}/po" "${TOP_SRC_DIR}/po/*.gmo")
 621                 message(STATUS "Installing provided .gmo-files only")
 622                 foreach( _gmo ${_gmofiles})
 623                         string(REGEX REPLACE "\\.gmo$" "" _lang ${_gmo})
 624                         install(FILES "${TOP_SRC_DIR}/po/${_gmo}" DESTINATION ${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}/${_lang}/LC_MESSAGES RENAME ${PACKAGE}.mo)
 625                 endforeach()
 626         endif()
 627 endif()
 628
 629
 630 find_package(ICONV REQUIRED)
 631 find_package(ZLIB REQUIRED)
 632
 633 if(LYX_EXTERNAL_BOOST)
 634         message(STATUS "Searching for boost")
 635         find_package(Boost COMPONENTS signals regex) #TODO could REQUIRED be used
 636         if(Boost_FOUND)
 637                 message(STATUS "Boost found")
 638                 message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 639                 set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 640         else()
 641                 message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 642         endif()
 643 else()
 644         if(LYX_USE_STD_REGEX)
 645                 set(Lyx_Boost_Libraries boost_signals)
 646         else()
 647                 set(Lyx_Boost_Libraries boost_signals boost_regex)
 648         endif()
 649         add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 650         add_definitions(-DBOOST_SIGNALS_NO_DEPRECATION_WARNING=1)
 651         include_directories(${TOP_SRC_DIR}/boost)
 652         add_subdirectory(boost "${TOP_BINARY_DIR}/boost")
 653 endif()
 654
 655
 656
 657
 658 if(WIN32)
 659         if(NOT LYX_CONSOLE)
 660                 set(WIN32_CONSOLE WIN32)
 661                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARY})
 662         endif()
 663         if(MSVC)
 664                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 665                 # disable checked iterators for msvc release builds to get maximum speed
 666                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 667         else()
 668                 add_definitions(-DWINVER=0x0500)
 669         endif()
 670 endif()
 671
 672 # Compute qt4-version from ${QTVERSION}
 673
 674 message(STATUS "")
 675 foreach(_v PACKAGE PACKAGE_VERSION
 676         PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 677         LYX_ABS_TOP_SRCDIR
 678         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 679         if(NOT DEFINED ${_v})
 680                 message(FATAL_ERROR "${_v} not defined")
 681         endif()
 682         string(SUBSTRING "${_v}                            " 0 28 _v1)
 683         message(STATUS "----- ${_v1}: ${${_v}}")
 684 endforeach(_v)
 685 message(STATUS "")
 686
 687
 688 if(LYX_PCH)
 689         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 690         # Not sure if it works for all non-msvc compilers
 691         include(PCHSupport_26)
 692         configure_file(${TOP_CMAKE_PATH}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
 693         configure_file(${TOP_CMAKE_PATH}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 694         add_definitions(-DLYX_ENABLE_PCH)
 695
 696         if(MSVC)
 697                 macro(lyx_add_msvc_pch name_)
 698                         set_source_files_properties(${${name_}_sources} PROPERTIES
 699                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 700                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
 701                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 702                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
 703                                 ${TOP_BINARY_DIR}/pcheaders.h)
 704                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 705                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 706                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 707                 endmacro(lyx_add_msvc_pch)
 708                 macro(lyx_add_gcc_pch name_)
 709                 endmacro()
 710         else()
 711                 macro(lyx_add_msvc_pch name_)
 712                 endmacro()
 713                 macro(lyx_add_gcc_pch name_)
 714                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT)
 715                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
 716                 endmacro()
 717         endif()
 718 else()
 719         macro(lyx_add_msvc_pch)
 720         endmacro(lyx_add_msvc_pch)
 721         macro(lyx_add_gcc_pch name_)
 722         endmacro()
 723 endif()
 724
 725
 726 if(MSVC)
 727
 728         if(LYX_VLD)
 729                 set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/development/Win32/vld)
 730                 add_subdirectory(${vld_path}/cmake)
 731                 include(${vld_path}/cmake/vld.cmake) # forced include
 732                 set(vld_dll vld)
 733         endif()
 734
 735         if(LYX_WALL)
 736                 # Use the highest warning level
 737                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 738
 739                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 740                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 741                 else()
 742                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 743                 endif()
 744
 745                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 746                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 747                 else()
 748                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 749                 endif()
 750
 751                 # add here warnings which should produce an error /weXXXX
 752                 set(MSVC_W_ERROR   "/we4101 /we4189")
 753                 # add here warnings which should be disabled /wdXXXX
 754                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 755
 756                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 757                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 758                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 759
 760         else()
 761                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 762
 763                 # add here warnings which should produce an error /weXXXX
 764                 set(MSVC_W_ERROR   "/we4101 /we4189")
 765                 # add here warnings which should be disabled /wdXXXX
 766                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 767
 768                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 769                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 770                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 771
 772         endif()
 773
 774         if (NOT Qt5Core_FOUND)
 775                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 776                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 777                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 778         endif()
 779
 780         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 781         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 782         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 783         message(STATUS "")
 784 endif()
 785
 786
 787 if(LYX_DEBUG_GLIBC)
 788         set(_GLIBCXX_DEBUG ON)
 789 endif()
 790
 791 if(LYX_DEBUG_GLIBC_PEDANTIC)
 792         set(_GLIBCXX_DEBUG_PEDANTIC ON)
 793 endif()
 794
 795 # Xcode compiler
 796 if (CMAKE_GENERATOR MATCHES Xcode)
 797         if (XCODE_VERSION VERSION_LESS "5.0")
 798                 # Automatically select the Xcode compiler if not set
 799                 if (NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 800                         # XCode >= 3.1 has gcc 4.2 (up to actual Xcode)
 801                         if (XCODE_VERSION VERSION_GREATER "3.1")
 802                                 SET(CMAKE_XCODE_ATTRIBUTE_GCC_VERSION "com.apple.compilers.llvmgcc42")
 803                         ENDIF(XCODE_VERSION VERSION_GREATER "3.1")
 804                 ENDIF(NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 805                 # Print the selected compiler version
 806         MESSAGE(STATUS "---- Using XCode compiler CMAKE_XCODE_ATTRIBUTE_GCC_VERSION=${CMAKE_XCODE_ATTRIBUTE_GCC_VERSION}")
 807         ENDIF(XCODE_VERSION VERSION_LESS "5.0")
 808 ENDIF(CMAKE_GENERATOR MATCHES Xcode)
 809
 810 if (WIN32 AND Qt5Core_FOUND)
 811         set(Z_PREFIX 1)
 812 endif()
 813
 814 # compiler tests, config.h generation
 815 if(MSVC AND NOT LYX_CONFIGURE_CHECKS)
 816         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.msvc ${TOP_BINARY_DIR}/configCompiler.h)
 817 else()
 818         include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
 819         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
 820 endif()
 821
 822 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
 823
 824 if(QTVERSION MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+).*")
 825         MATH(EXPR QT4_VERSION "(${CMAKE_MATCH_1}<<16)|(${CMAKE_MATCH_2}<<8)|${CMAKE_MATCH_3}")
 826 endif()
 827
 828
 829 set (cmd ${CMAKE_CTEST_COMMAND})
 830 if (MSVC)
 831         set (cmd ${cmd} -C ${CMAKE_CFG_INTDIR})
 832 else ()
 833         set (cmd ${cmd} -C ${CMAKE_BUILD_TYPE})
 834 endif ()
 835 add_custom_target (lyx_run_tests COMMAND ${cmd})
 836 set_target_properties(lyx_run_tests PROPERTIES FOLDER "tests")
 837
 838 if(LYX_ASAN)
 839     set(LYX_CXX_FLAGS "-fsanitize=address -fno-omit-frame-pointer -g")
 840     message(STATUS)
 841     message(STATUS "Address sanitizer enabled. Usage:")
 842     message(STATUS "    wget https://llvm.org/svn/llvm-project/compiler-rt/trunk/lib/asan/scripts/asan_symbolize.py")
 843     message(STATUS "    chmod  +x ./asan_symbolize.py")
 844     message(STATUS "    ./bin/lyx2.2 2>&1 | ./asan_symbolize.py  | c++filt ")
 845     message(STATUS)
 846 endif()
 847
 848 if(LYX_INSTALL)
 849         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 850                 message(STATUS "Python required to create doc!")
 851         else()
 852                 if(UNIX)
 853                         add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
 854                 endif()
 855                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
 856         endif()
 857         include(../Install)
 858 endif()
 859
 860 add_subdirectory(src "${TOP_BINARY_DIR}/src")
 861 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
 862 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
 863 add_subdirectory(lib/examples "${TOP_BINARY_DIR}/lib/examples")
 864 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
 865 add_subdirectory(development/autotests "${TOP_BINARY_DIR}/autotests")
 866 if(LYX_ENABLE_URLTESTS)
 867         add_subdirectory(development/checkurls "${TOP_BINARY_DIR}/checkurls")
 868 endif()
 869
 870 message(STATUS)
 871 message(STATUS "Build params, switch LYX_* options by -DLYX_*=ON or OFF, LYX_* combos by -DLYX_*=value:")
 872 message(STATUS)
 873
 874 LYX_OPTION_LIST_ALL(used)
 875
 876
 877 if(LYX_NLS)
 878         message(STATUS)
 879         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
 880         message(STATUS)
 881         message(STATUS "  * iconv")
 882         message(STATUS "     - header : ${ICONV_HEADER}")
 883         message(STATUS "     - library: ${ICONV_LIBRARY}")
 884         message(STATUS "  * zlib")
 885         message(STATUS "     - header : ${ZLIB_HEADER}")
 886         message(STATUS "     - library: ${ZLIB_LIBRARY}")
 887         message(STATUS)
 888 endif()
 889
 890 # Apple has builtin native spell checker,
 891 # no need to warn for missing Aspell, Hunspell or Enchant
 892 if(NOT Spelling_FOUND AND NOT APPLE)
 893   if(LYX_REQUIRE_SPELLCHECK)
 894     set(_mode "FATAL_ERROR")
 895   else()
 896     set(_mode "STATUS")
 897   endif()
 898   message(${_mode} "No spellcheck libraries found. LyX will be unable use spellchecking")
 899 endif()
 900
 901 include("${TOP_CMAKE_PATH}/LyxPackaging.cmake")
 902
 903 if(ENABLE_DIST)
 904   # Use git to create the source package
 905   # git archive --format=tgz --output=/home/kornel/x.tar.gz master
 906   if(UNIX)
 907     set(DIST_FORMAT tgz)
 908   else()
 909     set(DIST_FORMAT zip)
 910   endif()
 911   set(DIST_NAME ${CMAKE_PROJECT_NAME}-${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}-${CMAKE_SYSTEM_NAME}.${DIST_FORMAT})
 912
 913   add_custom_command(
 914     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME}
 915     COMMAND  ${LYX_GITVERSION} archive --format=${DIST_FORMAT} --output=${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME} master
 916     WORKING_DIRECTORY ${TOP_SRC_DIR})
 917   add_custom_target(git-archive DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME})
 918 endif()
 919
 920 # Last directory to be included so that the fixup code (OS X)
 921 # can be run last
 922 add_subdirectory(development/cmake/post_install)
 923
 924 message(STATUS)