CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 2.6.4)
   8
   9 set(LYX_PROJECT LyX)
  10
  11 enable_testing()
  12
  13 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README REALPATH) # Resolve symlinks
  14 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  15 message(STATUS "TOP_SRC_DIR = ${TOP_SRC_DIR}")
  16
  17 set(LYX_CMAKE_DIR "development/cmake")
  18 set(TOP_CMAKE_PATH "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}")
  19 set(TOP_MODULE_PATH "${TOP_CMAKE_PATH}/modules")
  20 set(TOP_SCRIPT_PATH "${TOP_CMAKE_PATH}/scripts")
  21
  22 set(CMAKE_MODULE_PATH "${TOP_MODULE_PATH}")
  23
  24 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  25
  26 message(STATUS)
  27 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  28         message(STATUS "Building in-source")
  29         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  30 else()
  31         message(STATUS "Building out-of-source")
  32         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  33 endif()
  34
  35 # This directory should be used if some test uses lyx-executable
  36 set(LYX_TESTS_USERDIR "${TOP_BINARY_DIR}/Testing/.lyx")
  37 file(MAKE_DIRECTORY "${LYX_TESTS_USERDIR}")
  38
  39 if(COMMAND cmake_policy)
  40         cmake_policy(SET CMP0003 OLD)
  41         cmake_policy(SET CMP0005 OLD)
  42         # Installing MACOSX_BUNDLE targets requires a BUNDLE DESTINATION
  43         cmake_policy(SET CMP0006 NEW)
  44         if(POLICY CMP0020)
  45                 cmake_policy(SET CMP0020 OLD)
  46         endif()
  47         if(POLICY CMP0028)
  48                 cmake_policy(SET CMP0028 OLD)
  49         endif()
  50         if(POLICY CMP0043)
  51                 # COMPILE_DEFINITIONS are not used yet. Enable new behavior.
  52                 cmake_policy(SET CMP0043 NEW)
  53         endif()
  54 endif()
  55
  56 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  57
  58 # Supress regeneration
  59 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  60
  61 if(LYX_XMINGW)
  62     set(CMAKE_SYSTEM_NAME Windows)
  63     set(TOOLNAME ${LYX_XMINGW})
  64     set(TOOLCHAIN "${TOOLNAME}-")
  65     set(CMAKE_C_COMPILER   "${TOOLCHAIN}gcc"     CACHE PATH "Mingw C compiler" FORCE)
  66     set(CMAKE_CXX_COMPILER "${TOOLCHAIN}g++"     CACHE PATH "Mingw C++ compiler" FORCE)
  67     set(CMAKE_RC_COMPILER  "${TOOLCHAIN}windres" CACHE PATH "Mingw rc compiler" FORCE)
  68
  69     set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM BOTH)
  70     set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY)
  71     set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY)
  72 endif()
  73
  74 if(NOT help AND NOT HELP)
  75   # 'project' triggers the searching for a compiler
  76   project(${LYX_PROJECT})
  77   if (CMAKE_COMPILER_IS_GNUCXX)
  78     if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS "4.0")
  79       message(STATUS "Gnu CXX compiler version = ${CMAKE_CXX_COMPILER_VERSION}")
  80       message(STATUS "is too old, should be >= 4.0")
  81       message(FATAL_ERROR "Exiting")
  82     endif()
  83   endif()
  84 endif()
  85
  86 if(UNIX)
  87         set(ARCH_TRIPLET )
  88         FIND_PROGRAM(DPKG_ARCHITECTURE_EXECUTABLE dpkg-architecture)
  89         if(DPKG_ARCHITECTURE_EXECUTABLE)
  90                 EXECUTE_PROCESS(COMMAND ${DPKG_ARCHITECTURE_EXECUTABLE} -qDEB_HOST_MULTIARCH
  91                                 OUTPUT_VARIABLE ARCH_TRIPLET
  92                                 ERROR_VARIABLE ERROR_ARCH_TRIPLET
  93                                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  94         endif()
  95 endif()
  96 if(ARCH_TRIPLET)
  97         set(SYSTEM_LIB_DIRS /usr/lib /usr/lib/${ARCH_TRIPLET} /usr/local/lib)
  98 else()
  99         set(SYSTEM_LIB_DIRS /usr/lib /usr/local/lib)
 100 endif()
 101
 102 include(LyXMacros)
 103
 104 # Usage LYX_OPTION
 105 # 1. parameter: option name without prefix 'LYX_'
 106 # 2. parameter: description
 107 # 3. parameter: default value, ON or OFF
 108 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
 109
 110 # Usage LYX_COMBO
 111 # 1. parameter: name without prefix 'LYX_'
 112 # 2. parameter: description
 113 # 3. parameter: default value
 114 # 4-n parameter: possible other string values
 115
 116 LYX_OPTION_INIT()
 117
 118 # Options for all compilers/systems
 119 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
 120 LYX_OPTION(LOCALVERSIONING  "Add version info to created package name (only used if LYX_CPACK option set)" OFF ALL)
 121 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
 122 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
 123 LYX_OPTION(REQUIRE_SPELLCHECK "Abort if no spellchecker available" OFF ALL)
 124 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
 125 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
 126 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
 127 LYX_OPTION(DEVEL_VERSION    "Build developer version" OFF ALL)
 128 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" OFF ALL)
 129 LYX_OPTION(DEBUG            "Enforce debug build"  OFF ALL)
 130 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
 131 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
 132 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
 133 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
 134 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
 135 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
 136 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
 137 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
 138 LYX_OPTION(ENABLE_URLTESTS  "Enable for URL tests" OFF ALL)
 139 LYX_OPTION(ENABLE_EXPORT_TESTS "Enable for export tests" OFF ALL)
 140 LYX_OPTION(ASAN             "Use address sanitizer" OFF ALL)
 141 LYX_COMBO(USE_QT            "Use Qt version as frontend" QT4 QT5)
 142 LYX_OPTION(3RDPARTY_BUILD   "Build 3rdparty libs" OFF ALL)
 143
 144 # GCC specific
 145 LYX_OPTION(PROFILE              "Build profile version" OFF GCC)
 146 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" OFF GCC)
 147 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
 148 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
 149 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++ pedantic debug mode" OFF GCC)
 150 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" OFF GCC)
 151 LYX_OPTION(PROFILE              "Build with options for gprof" OFF GCC)
 152 LYX_OPTION(ENABLE_CXX11         "Build with options for c++11-mode" OFF GCC)
 153
 154 # MSVC specific
 155 LYX_OPTION(CONSOLE               "Show console on Windows, enforce with =FORCE" ON MSVC)
 156 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
 157 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
 158 LYX_OPTION(CONFIGURE_CHECKS      "Also run configure checks for MSVC" OFF MSVC)
 159 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
 160
 161 # APPLE specific
 162 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
 163 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
 164
 165
 166 if(help OR HELP)
 167         message(STATUS)
 168         message(STATUS "Available options: (dis/enable with -DLYX_*=OFF/ON)")
 169         message(STATUS)
 170         LYX_OPTION_LIST_ALL(help)
 171         message(STATUS)
 172         RETURN()
 173 endif()
 174
 175 # Check option dependencies
 176
 177 if(LYX_DMG)
 178         set(LYX_BUNDLE ON)
 179         set(LYX_CPACK ON)
 180 endif()
 181
 182 if(LYX_CPACK)
 183         set(LYX_INSTALL ON)
 184 endif()
 185
 186 if(LYX_INSTALL)
 187         set(LYX_NLS ON)
 188         if(WIN32 AND NOT MINGW)
 189                 set(LYX_HUNSPELL ON)
 190         endif()
 191         if(LYX_CONSOLE MATCHES "FORCE")
 192                 set(LYX_CONSOLE ON)
 193         else()
 194                 set(LYX_CONSOLE OFF)
 195         endif()
 196         set(LYX_PACKAGE_SUFFIX ON)
 197         if(NOT LYX_DEBUG)
 198                 set(LYX_RELEASE ON)
 199         endif()
 200         set(LYX_PROFILE OFF)
 201 endif()
 202
 203
 204 if(LYX_MERGE_FILES)
 205         set(LYX_PCH OFF)
 206 else()
 207         set(LYX_MERGE_REBUILD OFF)
 208 endif()
 209
 210
 211 if(LYX_DEPENDENCIES_DOWNLOAD)
 212         message(STATUS)
 213     if(MSVC12)
 214         set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2013-deps)
 215         set(deps_files lyx-windows-deps-msvc2013.zip)
 216         set(deps_server http://ftp.lyx.de/LyX-Windows-Deps)
 217         set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2013)
 218     else()
 219         set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 220             set(deps_files lyx20-deps-msvc2010-x86.zip)
 221             set(deps_server http://downloads.sourceforge.net/project/lyx/Win_installers/Dependencies)
 222         set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/deps20)
 223     endif()
 224     message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 225         foreach(it ${deps_files})
 226                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 227                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 228                 if(NOT already_downloaded)
 229                         message(STATUS "Downloading ${it} ...")
 230                         file(DOWNLOAD ${deps_server}/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS STATUS status LOG log)
 231                         list(GET status 0 status_code)
 232                         list(GET status 1 status_string)
 233                         if(NOT status_code EQUAL 0)
 234                                 file(REMOVE ${LYX_DEPENDENCIES_DIR}/${it})
 235                                 message(FATAL_ERROR "error: downloading '${it}' failed. status_code: ${status_code}, status_string: ${status_string}. \nLog: ${log} ")
 236                         endif()
 237                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 238                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 239                 endif()
 240         endforeach()
 241 endif()
 242
 243
 244
 245 message(STATUS)
 246
 247 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 248 if(WIN32)
 249         set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 250 else()
 251         set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 252 endif()
 253
 254
 255 set(LYX_GCC11_MODE)
 256 if(UNIX OR MINGW)
 257         execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION OUTPUT_STRIP_TRAILING_WHITESPACE)
 258         message(STATUS "Using GCC version ${GCC_VERSION}")
 259         if(GCC_VERSION VERSION_LESS 4.9)
 260                 # <regex> in gcc is unusable in versions less than 4.9.0
 261                 # see https://gcc.gnu.org/bugzilla/show_bug.cgi?id=53631
 262                 set(LYX_USE_STD_REGEX 0)
 263         else()
 264                 if (LYX_ENABLE_CXX11)
 265                         set(LYX_USE_STD_REGEX 1)
 266                 endif()
 267         endif()
 268         if (LYX_ENABLE_CXX11)
 269                 find_package(CXX11Compiler)
 270                 if(NOT CXX11COMPILER_FOUND)
 271                         message(FATAL_ERROR "A C++11 compatible compiler is required.")
 272                 endif()
 273                 set(LYX_GCC11_MODE "${CXX11_FLAG}")
 274         endif()
 275 else()
 276         set(LYX_USE_STD_REGEX 0)
 277 #       if(MSVC10)
 278 #               set(LYX_USE_STD_REGEX 1) #TODO should we use it in ECMAScript mode?
 279 #       endif()
 280 endif()
 281
 282
 283 set(VERSION_INFO "CMake Build")
 284
 285 # Try to get some informations from configure.ac
 286
 287 include(LyXPaths)
 288 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 289
 290 if(WIN32)
 291         set(CMAKE_PREFIX_PATH Specify-path-to-Qt CACHE PATH "Used Qt version")
 292         if(MSVC)
 293                 set(LYX_3RDPARTY_BUILD ON CACHE BOOL "Build 3rdparty libraries" FORCE)
 294         endif()
 295         set(USE_WINDOWS_PACKAGING ON)
 296 elseif(APPLE)
 297         set(USE_MACOSX_PACKAGING ON)
 298 else()
 299         set(USE_POSIX_PACKAGING ON)
 300 endif()
 301
 302 macro(setstripped _varname)
 303         if(${ARGC} GREATER 1)
 304                 string(STRIP "${ARGV1}" _v)
 305                 if(USE_POSIX_PACKAGING)
 306                         string(TOLOWER ${_v} ${_varname})
 307                 else()
 308                         set(${_varname} ${_v})
 309                 endif()
 310         else()
 311                 set(${_varname})
 312         endif()
 313 endmacro(setstripped)
 314
 315 foreach(_c_l ${_config_lines} )
 316         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 317                 setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 318                 setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 319                 setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 320                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\)\(\\.\([0-9]+\)\)?.*$")
 321                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 322                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 323                         set(LYX_PATCH_VERSION ${CMAKE_MATCH_4})
 324                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 325                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 326                         set(LYX_INSTALL_SUFFIX "${CMAKE_MATCH_1}.${CMAKE_MATCH_2}")
 327                 endif()
 328         endif()
 329         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 330                 set(LYX_DATE "${CMAKE_MATCH_1}")
 331         endif()
 332 endforeach(_c_l)
 333
 334 FIND_PROGRAM(LYX_GITVERSION git)
 335 #message(STATUS "gitversion = ${LYX_GITVERSION}")
 336 set(LYX_REVISION_VERSION ${LYX_PATCH_VERSION})
 337 if(LYX_GITVERSION)
 338   if (LYX_LOCALVERSIONING)
 339     # Find the revision number and for later use
 340     EXECUTE_PROCESS(COMMAND ${LYX_GITVERSION} describe --match 2.0.0 HEAD
 341       WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE LYX_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 342     if (LYX_PACKAGE_RELEASE MATCHES "^2\\.0\\.0\\-\([0-9]+\)\\-.*$")
 343       # We will add offset of 40000 to get appropriate value to
 344       # previous svn.
 345       # We use this value than also to set the package-patch-value
 346       MATH(EXPR tmp_REVISION_VERSION "(${CMAKE_MATCH_1}+40000)")
 347       set(LYX_REVISION_VERSION "${LYX_PATCH_VERSION}-${tmp_REVISION_VERSION}git")
 348       set(ENABLE_DIST ON)
 349     endif()
 350   endif()
 351 endif()
 352
 353 # Set the programs (lyx, tex2lyx, etc.) suffix
 354 # When building an OS X bundle, we will append
 355 # the suffix only to the bundle, not to the programs
 356 set(PROGRAM_SUFFIX "")
 357 if(LYX_PROGRAM_SUFFIX AND NOT (APPLE AND LYX_BUNDLE))
 358         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 359 endif()
 360 set(_lyx "${PACKAGE_BASE}${PROGRAM_SUFFIX}")
 361 set(_tex2lyx tex2lyx${PROGRAM_SUFFIX})
 362
 363 add_custom_target(lyx_version ALL
 364   COMMAND ${CMAKE_COMMAND} -DTOP_SRC_DIR=${TOP_SRC_DIR} -DTOP_CMAKE_PATH=${TOP_CMAKE_PATH} -DTOP_BINARY_DIR=${TOP_BINARY_DIR} -DLYX_DATE=${LYX_DATE} -P ${TOP_SCRIPT_PATH}/LyXGetVersion.cmake
 365   )
 366 set_target_properties(lyx_version PROPERTIES FOLDER "applications")
 367
 368 # Default paths for installed utilities (tex2lyx, lyxclient, etc.)
 369 set(LYX_UTILITIES_INSTALL_PATH bin)
 370
 371 if(LYX_BUNDLE)
 372         set(LYX_CPACK ON)
 373
 374         message(STATUS)
 375         message(STATUS "Bundle creation is enabled (experimental):")
 376         message(STATUS "    make")
 377         message(STATUS "    make install/strip")
 378         message(STATUS "    make package")
 379         if(APPLE)
 380                 set(MACOSX_BUNDLE TRUE)
 381                 # This sets the bundle + executable names
 382                 set(_lyx "${PACKAGE_BASE}${LYX_INSTALL_SUFFIX}")
 383                 # This sets the Info.plist executable name
 384                 set(osx_bundle_program_name ${_lyx})
 385                 # Bundle name
 386                 set(LYX_BUNDLE_NAME ${_lyx})
 387
 388                 # This will contain the list of files that need to be included
 389                 # in the bundle and their location within the bundle
 390                 set(OSX_BUNDLE_FILES "${TOP_SRC_DIR}/development/MacOSX/LyX.sdef;${TOP_SRC_DIR}/development/MacOSX/LyXapp.icns;${CMAKE_BINARY_DIR}/lyxrc.dist")
 391                 set(OSX_BUNDLE_DIRS "Resources;Resources;Resources")
 392
 393                 # Process Info.plist and lyxrc.dist
 394                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/Info.plist.in" "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 395                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/lyxrc.dist.in" "${CMAKE_CURRENT_BINARY_DIR}/lyxrc.dist")
 396
 397                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 398                 set(LYX_DATA_SUBDIR ${LYX_BUNDLE_NAME}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 399
 400                 # Variables used by CPack
 401                 set(CPACK_BUNDLE_NAME ${LYX_BUNDLE_NAME})
 402                 set(CPACK_BUNDLE_PLIST "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 403                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${LYX_BUNDLE_NAME}.app)
 404
 405                 # Set the install paths
 406                 set(LYX_UTILITIES_INSTALL_PATH ${LYX_BUNDLE_NAME}.app/Contents/MacOS)
 407                 if(NOT LYX_INSTALL_PREFIX)
 408                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 409                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 410                 endif()
 411                 # Change the owner so that the install can work
 412                 install(CODE "set(BU_CHMOD_BUNDLE_ITEMS 1)" COMPONENT Runtime)
 413         elseif(UNIX)
 414                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 415                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 416                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 417         elseif(WIN32)
 418                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 419         endif()
 420 endif()
 421
 422 if(LYX_INSTALL_PREFIX)
 423         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 424         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 425 endif()
 426 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 427
 428 string(REGEX REPLACE "/lyx${LYX_INSTALL_SUFFIX}$" "/share" SYSTEM_DATADIR ${CMAKE_INSTALL_PREFIX})
 429
 430 if(LYX_PACKAGE_SUFFIX)
 431         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 432 else()
 433         set(PACKAGE ${PACKAGE_BASE})
 434 endif()
 435
 436 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 437         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 438         if (UNIX)
 439                 # don't use the default "/usr/local"
 440                 # but respect the user-choice on the command-line
 441                 if(LYX_INSTALL_SUFFIX)
 442                         set(CMAKE_INSTALL_PREFIX "/usr/local/lyx${LYX_INSTALL_SUFFIX}" CACHE PATH "LyX default install prefix" FORCE)
 443                 else()
 444                         set(CMAKE_INSTALL_PREFIX "/usr/local/${LYX_PROJECT}" CACHE PATH "LyX default install prefix" FORCE)
 445                 endif()
 446         endif()
 447 endif()
 448 if(WIN32)
 449         set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 450 endif()
 451 if(IS_ABSOLUTE)
 452         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 453 else()
 454         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 455 endif()
 456
 457
 458
 459 if(NOT LYX_DATA_SUBDIR)
 460         if (WIN32)
 461                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 462         else()
 463                 set(LYX_DATA_SUBDIR "" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 464         endif()
 465 endif()
 466
 467 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 468 set(LYX_LOCALEDIR "locale")
 469 set(LYX_ABS_INSTALLED_LOCALEDIR "${LYX_ABS_INSTALLED_DATADIR}/${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}")
 470 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 471
 472 if(LYX_BUNDLE AND APPLE)
 473         set(LYX_MAN_DIR "${LYX_DATA_SUBDIR}" CACHE STRING "Install location for man pages.")
 474 else()
 475         if(WIN32)
 476                 set(LYX_MAN_DIR "${CMAKE_BINARY_DIR}/usr/local/man/man1" CACHE STRING "Install location for man pages.")
 477         else()
 478                 set(LYX_MAN_DIR "/usr/local/man/man1" CACHE STRING "Install location for man pages.")
 479         endif()
 480 endif()
 481 mark_as_advanced(LYX_MAN_DIR)
 482
 483 if(LYX_INSTALL AND WIN32)
 484         message(STATUS "Configuring NSIS files")
 485         configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 486         configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 487         configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 488         message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 489 endif()
 490
 491 if(NOT GROUP_CODE)
 492         #set(GROUP_CODE "The Golden Code")
 493         set(GROUP_CODE flat)
 494 endif()
 495
 496 # lyx's source files
 497 set(LYX_CPP_FILES [a-zA-Z]*.cpp)
 498 set(LYX_HPP_FILES [a-zA-Z]*.h)
 499 set(LYX_MOC_FILES moc_*.cpp)
 500
 501 include(ProjectSourceGroup)
 502
 503
 504 if(LYX_PROFILE AND NOT MSVC)
 505         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 506         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg")
 507         set(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS}  -pg")
 508 else()
 509         set(LYX_PROFILE OFF)
 510 endif()
 511
 512
 513 if(LYX_NO_OPTIMIZE)
 514         set(CMAKE_BUILD_TYPE None)
 515         set(LYX_DEBUG OFF)
 516         set(LYX_RELEASE OFF)
 517         set(LYX_PROFILE OFF)
 518 elseif(LYX_RELEASE)
 519         set(CMAKE_BUILD_TYPE Release)
 520         set(LYX_DEBUG OFF)
 521         set(LYX_PROFILE OFF)
 522 elseif(LYX_PROFILE)
 523         set(CMAKE_BUILD_TYPE Profile)
 524         set(LYX_DEBUG OFF)
 525 else()
 526         set(CMAKE_BUILD_TYPE Debug)
 527         set(LYX_DEBUG ON)
 528 endif()
 529
 530
 531 # When shared libs are supported enable this option
 532 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 533 if(LYX_SHARED_LIBRARIES)
 534         set(library_type SHARED)
 535 else()
 536         set(library_type STATIC)
 537 endif()
 538
 539 if(NOT MSVC)
 540         if(NOT LYX_QUIET)
 541                 set(CMAKE_VERBOSE_MAKEFILE ON)
 542         endif()
 543     set(LYX_CXX_FLAGS "-Wall -Wunused-parameter ${LYX_GCC11_MODE}")
 544         if(LYX_STDLIB_DEBUG)
 545                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 546         endif()
 547         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 548         set(CMAKE_CXX_FLAGS_DEBUG "${LYX_CXX_FLAGS} -fno-strict-aliasing -O0 -g3 -D_DEBUG" CACHE TYPE STRING FORCE)
 549         if(MINGW)
 550                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 551         else()
 552                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 553         endif()
 554 endif()
 555
 556 set(LYX_CXX_FLAGS_EXTRA "" CACHE STRING "Desired semicolon separated list of extra cxx compile flags, like '-Werror'")
 557 mark_as_advanced(LYX_CXX_FLAGS_EXTRA)
 558 if(LYX_CXX_FLAGS_EXTRA)
 559         foreach(_flag ${LYX_CXX_FLAGS_EXTRA})
 560                 add_definitions(${_flag})
 561         endforeach()
 562 endif()
 563
 564 if(LYX_XMINGW)
 565         list(APPEND CMAKE_FIND_ROOT_PATH ${GNUWIN32_DIR})
 566 endif()
 567
 568 if(LYX_USE_QT MATCHES "QT5")
 569         find_package(Qt5Core REQUIRED)
 570         if (Qt5Core_FOUND)
 571                 find_package(Qt5Widgets REQUIRED)
 572                 if(APPLE)
 573                         find_package(Qt5MacExtras REQUIRED)
 574                 endif()
 575                 find_package(Qt5X11Extras QUIET)
 576                 find_package(Qt5WinExtras QUIET)
 577                 set(QTVERSION ${Qt5Core_VERSION})
 578                 macro (qt_use_modules)
 579                         qt5_use_modules(${ARGN})
 580                 endmacro()
 581                 macro (qt_add_resources)
 582                         qt5_add_resources(${ARGN})
 583                 endmacro()
 584                 macro (qt_wrap_uifiles)
 585                         qt5_wrap_ui(${ARGN})
 586                 endmacro()
 587                 message(STATUS "Found Qt-Version ${QTVERSION}")
 588                 if(WIN32)
 589                         set(LYX_QTMAIN_LIBRARY ${Qt5Core_QTMAIN_LIBRARIES})
 590                 endif()
 591         endif()
 592 elseif(LYX_USE_QT MATCHES "QT4")
 593         if(LYX_XMINGW)
 594                 set(QT_MINGW_DIR ${LYX_QT4} CACHE PATH "Qt for Mingw" FORCE)
 595                 list(APPEND CMAKE_FIND_ROOT_PATH ${QT_MINGW_DIR} ${GNUWIN32_DIR})
 596         endif()
 597         find_package(Qt4 "4.5.0" REQUIRED)
 598         macro (qt_use_modules)
 599         endmacro()
 600         macro (qt_add_resources)
 601                 qt4_add_resources(${ARGN})
 602         endmacro()
 603         macro (qt_wrap_uifiles)
 604                 qt4_wrap_ui(${ARGN})
 605         endmacro()
 606         if(WIN32)
 607                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARIES})
 608         endif()
 609 else()
 610   message(FATAL_ERROR "Unhandled value for LYX_USE_QT (${LYX_USE_QT})")
 611 endif()
 612
 613 find_package(Magic)
 614 if(Magic_FOUND)
 615         set(HAVE_MAGIC_H 1)
 616 endif()
 617
 618 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 619
 620 set(Spelling_FOUND OFF)
 621 set(Include_used_spellchecker)   # String will be inserted into config.h
 622
 623 if(LYX_3RDPARTY_BUILD)
 624     add_subdirectory(3rdparty/hunspell)
 625     add_definitions(-DHUNSPELL_STATIC)
 626     set(HUNSPELL_FOUND ON)
 627     message(STATUS "  * Hunspell:")
 628     message(STATUS "     - include: ${HUNSPELL_INCLUDE_DIR}")
 629     message(STATUS "     - library: ${HUNSPELL_LIBRARY}")
 630 endif()
 631
 632 foreach(_spell "ASPELL" "Enchant" "Hunspell")
 633   string(TOUPPER ${_spell} _upspell)
 634   if (NOT ${_upspell}_FOUND)
 635     find_package(${_spell})
 636   endif()
 637   if (${_upspell}_FOUND)
 638     include_directories(${${_upspell}_INCLUDE_DIR})
 639     set(Spelling_FOUND ON)
 640     message(STATUS "Building with USE_${_upspell}")
 641     set(Include_used_spellchecker "${Include_used_spellchecker}#define USE_${_upspell} 1\n")
 642   else()
 643     if(LYX_${_upspell})
 644       message(FATAL_ERROR "Required ${_spell} devel package not found")
 645     else()
 646       message(STATUS "${_upspell} not found, building without ${_spell} support")
 647     endif()
 648   endif()
 649 endforeach()
 650
 651 if(GNUWIN32_DIR)
 652         list(APPEND CMAKE_PROGRAM_PATH "${GNUWIN32_DIR}/Python" )
 653 endif()
 654
 655 find_package(PythonInterp 2.7 QUIET)
 656 if(PYTHONINTERP_FOUND)
 657         if(PYTHON_VERSION_STRING VERSION_GREATER 2.8)
 658         unset(PYTHONINTERP_FOUND)
 659         endif()
 660 endif()
 661
 662 if(NOT PYTHONINTERP_FOUND)
 663   unset(PYTHON_EXECUTABLE CACHE)
 664   unset(PYTHON_VERSION_MAJOR)
 665   unset(PYTHON_VERSION_MINOR)
 666   unset(PYTHON_VERSION_STRING)
 667   find_package(PythonInterp 3.3 REQUIRED)
 668 endif()
 669
 670 set(LYX_PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 671
 672 if(LYX_NLS)
 673         find_package(LyXGettext)
 674         if(LYX_PYTHON_EXECUTABLE AND GETTEXT_FOUND)
 675                 add_subdirectory(po "${TOP_BINARY_DIR}/po")
 676         else()
 677                 # Install only supplied .gmo-files
 678                 file(GLOB _gmofiles RELATIVE "${TOP_SRC_DIR}/po" "${TOP_SRC_DIR}/po/*.gmo")
 679                 message(STATUS "Installing provided .gmo-files only")
 680                 foreach( _gmo ${_gmofiles})
 681                         string(REGEX REPLACE "\\.gmo$" "" _lang ${_gmo})
 682                         install(FILES "${TOP_SRC_DIR}/po/${_gmo}" DESTINATION ${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}/${_lang}/LC_MESSAGES RENAME ${PACKAGE}.mo)
 683                 endforeach()
 684         endif()
 685 endif()
 686
 687 if(UNIX)
 688     find_package(ICONV REQUIRED)
 689     find_package(ZLIB REQUIRED)
 690 else()
 691     if(LYX_3RDPARTY_BUILD)
 692         add_subdirectory(3rdparty/libiconv)
 693         set(HAVE_ICONV_CONST 1)
 694         add_subdirectory(3rdparty/zlib)
 695     endif()
 696 endif()
 697
 698 if(LYX_EXTERNAL_BOOST)
 699         message(STATUS "Searching for boost")
 700         if(LYX_USE_STD_REGEX)
 701                 find_package(Boost COMPONENTS signals)
 702         else()
 703                 find_package(Boost COMPONENTS signals regex)
 704         endif()
 705         if(Boost_FOUND)
 706                 message(STATUS "Boost found")
 707                 message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 708                 set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 709                 if (LYX_STDLIB_DEBUG)
 710                         # Comment from  Jean-Marc Lasgouttes:
 711                         # In general, system boost libraries are incompatible with
 712                         # the use of stdlib-debug in libstdc++. See ticket #9736 for
 713                         # details.
 714                         message(WARNING "Compiling LyX with stdlib-debug and system boost libraries may lead to crashes. Consider using '-DLYX_STDLIB_DEBUG=OFF' or using '-DLYX_EXTERNAL_BOOST=OFF'")
 715                 endif()
 716         else()
 717                 message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 718         endif()
 719 else()
 720         if(LYX_USE_STD_REGEX)
 721                 set(Lyx_Boost_Libraries boost_signals)
 722         else()
 723                 set(Lyx_Boost_Libraries boost_signals boost_regex)
 724         endif()
 725         add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 726         add_definitions(-DBOOST_SIGNALS_NO_DEPRECATION_WARNING=1)
 727         include_directories(${TOP_SRC_DIR}/3rdparty/boost)
 728         add_subdirectory(3rdparty/boost "${TOP_BINARY_DIR}/3rdparty/boost")
 729 endif()
 730
 731
 732
 733
 734 if(WIN32)
 735         if(LYX_CONSOLE)
 736                 set(LYX_QTMAIN_LIBRARY)
 737         else()
 738                 set(WIN32_CONSOLE WIN32)
 739         endif()
 740         if(MSVC)
 741                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 742                 # disable checked iterators for msvc release builds to get maximum speed
 743                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 744         else()
 745                 add_definitions(-DWINVER=0x0500)
 746         endif()
 747 endif()
 748
 749 # Compute qt4-version from ${QTVERSION}
 750
 751 message(STATUS "")
 752 foreach(_v PACKAGE PACKAGE_VERSION
 753         PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 754         LYX_ABS_TOP_SRCDIR
 755         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 756         if(NOT DEFINED ${_v})
 757                 message(FATAL_ERROR "${_v} not defined")
 758         endif()
 759         string(SUBSTRING "${_v}                            " 0 28 _v1)
 760         message(STATUS "----- ${_v1}: ${${_v}}")
 761 endforeach(_v)
 762 message(STATUS "")
 763
 764
 765 if(LYX_PCH)
 766         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 767         # Not sure if it works for all non-msvc compilers
 768         include(PCHSupport_26)
 769         configure_file(${TOP_CMAKE_PATH}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
 770         configure_file(${TOP_CMAKE_PATH}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 771         add_definitions(-DLYX_ENABLE_PCH)
 772
 773         if(MSVC)
 774                 macro(lyx_add_msvc_pch name_)
 775                         set_source_files_properties(${${name_}_sources} PROPERTIES
 776                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 777                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
 778                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 779                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
 780                                 ${TOP_BINARY_DIR}/pcheaders.h)
 781                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 782                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 783                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 784                 endmacro(lyx_add_msvc_pch)
 785                 macro(lyx_add_gcc_pch name_)
 786                 endmacro()
 787         else()
 788                 macro(lyx_add_msvc_pch name_)
 789                 endmacro()
 790                 macro(lyx_add_gcc_pch name_)
 791                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT)
 792                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
 793                 endmacro()
 794         endif()
 795 else()
 796         macro(lyx_add_msvc_pch)
 797         endmacro(lyx_add_msvc_pch)
 798         macro(lyx_add_gcc_pch name_)
 799         endmacro()
 800 endif()
 801
 802
 803 if(MSVC)
 804
 805         if(LYX_VLD)
 806                 set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/development/Win32/vld)
 807                 add_subdirectory(${vld_path}/cmake)
 808                 include(${vld_path}/cmake/vld.cmake) # forced include
 809                 set(vld_dll vld)
 810         endif()
 811
 812         if(LYX_WALL)
 813                 # Use the highest warning level
 814                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 815
 816                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 817                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 818                 else()
 819                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 820                 endif()
 821
 822                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 823                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 824                 else()
 825                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 826                 endif()
 827
 828                 # add here warnings which should produce an error /weXXXX
 829                 set(MSVC_W_ERROR   "/we4101 /we4189")
 830                 # add here warnings which should be disabled /wdXXXX
 831                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 832
 833                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 834                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 835                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 836
 837         else()
 838                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 839
 840                 # add here warnings which should produce an error /weXXXX
 841                 set(MSVC_W_ERROR   "/we4101 /we4189")
 842                 # add here warnings which should be disabled /wdXXXX
 843                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 844
 845                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 846                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 847                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 848
 849         endif()
 850
 851         if (NOT Qt5Core_FOUND)
 852                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 853                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 854                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 855         endif()
 856
 857         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 858         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 859         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 860         message(STATUS "")
 861 endif()
 862
 863
 864 if(LYX_DEBUG_GLIBC)
 865         set(_GLIBCXX_DEBUG ON)
 866 endif()
 867
 868 if(LYX_DEBUG_GLIBC_PEDANTIC)
 869         set(_GLIBCXX_DEBUG_PEDANTIC ON)
 870 endif()
 871
 872 # Xcode compiler
 873 if (CMAKE_GENERATOR MATCHES Xcode)
 874         if (XCODE_VERSION VERSION_LESS "5.0")
 875                 # Automatically select the Xcode compiler if not set
 876                 if (NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 877                         # XCode >= 3.1 has gcc 4.2 (up to actual Xcode)
 878                         if (XCODE_VERSION VERSION_GREATER "3.1")
 879                                 SET(CMAKE_XCODE_ATTRIBUTE_GCC_VERSION "com.apple.compilers.llvmgcc42")
 880                         ENDIF(XCODE_VERSION VERSION_GREATER "3.1")
 881                 ENDIF(NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 882                 # Print the selected compiler version
 883         MESSAGE(STATUS "---- Using XCode compiler CMAKE_XCODE_ATTRIBUTE_GCC_VERSION=${CMAKE_XCODE_ATTRIBUTE_GCC_VERSION}")
 884         ENDIF(XCODE_VERSION VERSION_LESS "5.0")
 885 ENDIF(CMAKE_GENERATOR MATCHES Xcode)
 886
 887 if (WIN32 AND Qt5Core_FOUND)
 888         set(Z_PREFIX 1)
 889 endif()
 890
 891 # compiler tests, config.h generation
 892 if(MSVC AND NOT LYX_CONFIGURE_CHECKS)
 893         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.msvc ${TOP_BINARY_DIR}/configCompiler.h)
 894 else()
 895         include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
 896         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
 897 endif()
 898
 899 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
 900
 901 if(QTVERSION MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+).*")
 902         MATH(EXPR QT4_VERSION "(${CMAKE_MATCH_1}<<16)|(${CMAKE_MATCH_2}<<8)|${CMAKE_MATCH_3}")
 903 endif()
 904
 905 if (NOT HAVE_REGEX)
 906         set(LYX_USE_STD_REGEX 0)
 907 endif()
 908
 909
 910 set (cmd ${CMAKE_CTEST_COMMAND})
 911 if (MSVC)
 912         set (cmd ${cmd} -C ${CMAKE_CFG_INTDIR})
 913 else ()
 914         set (cmd ${cmd} -C ${CMAKE_BUILD_TYPE})
 915 endif ()
 916 add_custom_target (lyx_run_tests COMMAND ${cmd})
 917 set_target_properties(lyx_run_tests PROPERTIES FOLDER "tests")
 918
 919 if(LYX_ASAN)
 920     set(LYX_CXX_FLAGS "-fsanitize=address -fno-omit-frame-pointer -g")
 921     message(STATUS)
 922     message(STATUS "Address sanitizer enabled. Usage:")
 923     message(STATUS "    wget https://llvm.org/svn/llvm-project/compiler-rt/trunk/lib/asan/scripts/asan_symbolize.py")
 924     message(STATUS "    chmod  +x ./asan_symbolize.py")
 925     message(STATUS "    ./bin/lyx2.2 2>&1 | ./asan_symbolize.py  | c++filt ")
 926     message(STATUS)
 927 endif()
 928
 929 if(LYX_INSTALL)
 930         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 931                 message(STATUS "Python required to create doc!")
 932         else()
 933                 if(UNIX)
 934                         add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
 935                 endif()
 936                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
 937         endif()
 938         include(../Install)
 939 endif()
 940
 941 add_subdirectory(src "${TOP_BINARY_DIR}/src")
 942 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
 943 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
 944 add_subdirectory(lib/examples "${TOP_BINARY_DIR}/lib/examples")
 945 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
 946 add_subdirectory(development/autotests "${TOP_BINARY_DIR}/autotests")
 947 if(LYX_ENABLE_URLTESTS)
 948         add_subdirectory(development/checkurls "${TOP_BINARY_DIR}/checkurls")
 949 endif()
 950
 951 message(STATUS)
 952 message(STATUS "Build params, switch LYX_* options by -DLYX_*=ON or OFF, LYX_* combos by -DLYX_*=value:")
 953 message(STATUS)
 954
 955 LYX_OPTION_LIST_ALL(used)
 956
 957
 958 if(LYX_NLS)
 959         message(STATUS)
 960         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
 961         message(STATUS)
 962         message(STATUS "  * iconv")
 963         message(STATUS "     - include: ${ICONV_INCLUDE_DIR}")
 964         message(STATUS "     - library: ${ICONV_LIBRARY}")
 965         message(STATUS "  * zlib")
 966         message(STATUS "     - include: ${ZLIB_INCLUDE_DIR}")
 967         message(STATUS "     - library: ${ZLIB_LIBRARY}")
 968         message(STATUS)
 969 endif()
 970
 971 # Apple has builtin native spell checker,
 972 # no need to warn for missing Aspell, Hunspell or Enchant
 973 if(NOT Spelling_FOUND AND NOT APPLE)
 974   if(LYX_REQUIRE_SPELLCHECK)
 975     set(_mode "FATAL_ERROR")
 976   else()
 977     set(_mode "STATUS")
 978   endif()
 979   message(${_mode} "No spellcheck libraries found. LyX will be unable use spellchecking")
 980 endif()
 981
 982 include("${TOP_CMAKE_PATH}/LyxPackaging.cmake")
 983
 984 if(ENABLE_DIST)
 985   # Use git to create the source package
 986   # git archive --format=tgz --output=/home/kornel/x.tar.gz master
 987   if(UNIX)
 988     set(DIST_FORMAT tgz)
 989   else()
 990     set(DIST_FORMAT zip)
 991   endif()
 992   set(DIST_NAME ${CMAKE_PROJECT_NAME}-${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}-${CMAKE_SYSTEM_NAME}.${DIST_FORMAT})
 993
 994   add_custom_command(
 995     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME}
 996     COMMAND  ${LYX_GITVERSION} archive --format=${DIST_FORMAT} --output=${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME} master
 997     WORKING_DIRECTORY ${TOP_SRC_DIR})
 998   add_custom_target(git-archive DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME})
 999 endif()
1000
1001 # Last directory to be included so that the fixup code (OS X)
1002 # can be run last
1003 add_subdirectory(development/cmake/post_install)
1004
1005 message(STATUS)