CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 2.6.4)
   8
   9 set(LYX_PROJECT LyX)
  10
  11 enable_testing()
  12
  13 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README ABSOLUTE)
  14 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  15
  16 set(LYX_CMAKE_DIR "development/cmake")
  17 set(TOP_CMAKE_PATH "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}")
  18 set(TOP_MODULE_PATH "${TOP_CMAKE_PATH}/modules")
  19 set(TOP_SCRIPT_PATH "${TOP_CMAKE_PATH}/scripts")
  20
  21 set(CMAKE_MODULE_PATH "${TOP_MODULE_PATH}")
  22
  23 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  24
  25 message(STATUS)
  26 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  27         message(STATUS "Building in-source")
  28         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  29 else()
  30         message(STATUS "Building out-of-source")
  31         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  32 endif()
  33
  34 # This directory should be used if some test uses lyx-executable
  35 set(LYX_TESTS_USERDIR "${TOP_BINARY_DIR}/Testing/.lyx")
  36 file(MAKE_DIRECTORY "${LYX_TESTS_USERDIR}")
  37
  38 if(COMMAND cmake_policy)
  39         cmake_policy(SET CMP0003 OLD)
  40         cmake_policy(SET CMP0005 OLD)
  41         # Installing MACOSX_BUNDLE targets requires a BUNDLE DESTINATION
  42         cmake_policy(SET CMP0006 NEW)
  43         if(POLICY CMP0028)
  44                 cmake_policy(SET CMP0028 OLD)
  45         endif()
  46         if(POLICY CMP0043)
  47                 # COMPILE_DEFINITIONS are not used yet. Enable new behavior.
  48                 cmake_policy(SET CMP0043 NEW)
  49         endif()
  50 endif()
  51
  52 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  53
  54 # Supress regeneration
  55 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  56
  57 if(LYX_XMINGW)
  58     set(CMAKE_SYSTEM_NAME Windows)
  59     set(TOOLNAME ${LYX_XMINGW})
  60     set(TOOLCHAIN "${TOOLNAME}-")
  61     set(CMAKE_C_COMPILER   "${TOOLCHAIN}gcc"     CACHE PATH "Mingw C compiler" FORCE)
  62     set(CMAKE_CXX_COMPILER "${TOOLCHAIN}g++"     CACHE PATH "Mingw C++ compiler" FORCE)
  63     set(CMAKE_RC_COMPILER  "${TOOLCHAIN}windres" CACHE PATH "Mingw rc compiler" FORCE)
  64
  65     set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM BOTH)
  66     set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY)
  67     set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY)
  68 endif()
  69
  70 if(NOT help AND NOT HELP)
  71         # 'project' triggers the searching for a compiler
  72         project(${LYX_PROJECT})
  73 endif()
  74
  75 if(UNIX)
  76         set(ARCH_TRIPLET )
  77         FIND_PROGRAM(DPKG_ARCHITECTURE_EXECUTABLE dpkg-architecture)
  78         if(DPKG_ARCHITECTURE_EXECUTABLE)
  79                 EXECUTE_PROCESS(COMMAND ${DPKG_ARCHITECTURE_EXECUTABLE} -qDEB_HOST_MULTIARCH
  80                                 OUTPUT_VARIABLE ARCH_TRIPLET
  81                                 ERROR_VARIABLE ERROR_ARCH_TRIPLET
  82                                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  83         endif()
  84 endif()
  85 if(ARCH_TRIPLET)
  86         set(SYSTEM_LIB_DIRS /usr/lib /usr/lib/${ARCH_TRIPLET} /usr/local/lib)
  87 else()
  88         set(SYSTEM_LIB_DIRS /usr/lib /usr/local/lib)
  89 endif()
  90
  91 include(LyXMacros)
  92
  93 # Usage LYX_OPTION
  94 # 1. parameter: option name without prefix 'LYX_'
  95 # 2. parameter: description
  96 # 3. parameter: default value, ON or OFF
  97 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
  98
  99 # Usage LYX_COMBO
 100 # 1. parameter: name without prefix 'LYX_'
 101 # 2. parameter: description
 102 # 3. parameter: default value
 103 # 4-n parameter: possible other string values
 104
 105 LYX_OPTION_INIT()
 106
 107 # Options for all compilers/systems
 108 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
 109 LYX_OPTION(LOCALVERSIONING  "Add version info to created package name (only used if LYX_CPACK option set)" OFF ALL)
 110 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
 111 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
 112 LYX_OPTION(REQUIRE_SPELLCHECK "Abort if no spellchecker available" OFF ALL)
 113 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
 114 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
 115 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
 116 LYX_OPTION(DEVEL_VERSION    "Build developer version" OFF ALL)
 117 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" OFF ALL)
 118 LYX_OPTION(DEBUG            "Enforce debug build"  OFF ALL)
 119 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
 120 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
 121 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
 122 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
 123 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
 124 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
 125 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
 126 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
 127 LYX_OPTION(ENABLE_URLTESTS  "Enable for URL tests" OFF ALL)
 128 LYX_OPTION(ENABLE_EXPORT_TESTS "Enable for export tests" OFF ALL)
 129 LYX_OPTION(ASAN             "Use address sanitizer" OFF ALL)
 130
 131 # GCC specific
 132 LYX_OPTION(PROFILE              "Build profile version" OFF GCC)
 133 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" OFF GCC)
 134 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
 135 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
 136 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++ pedantic debug mode" OFF GCC)
 137 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" OFF GCC)
 138 LYX_OPTION(CONCEPT_CHECKS       "Enable concept-checks" OFF GCC)
 139 LYX_OPTION(PROFILE              "Build with options for gprof" OFF GCC)
 140 LYX_OPTION(ENABLE_CXX11         "Build with options for c++11-mode" OFF GCC)
 141
 142 # MSVC specific
 143 LYX_OPTION(CONSOLE               "Show console on Windows, enforce with =FORCE" ON MSVC)
 144 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
 145 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
 146 LYX_OPTION(CONFIGURE_CHECKS      "Also run configure checks for MSVC" OFF MSVC)
 147 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
 148
 149 # APPLE specific
 150 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
 151 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
 152 if(LYX_XMINGW)
 153   LYX_COMBO(USE_QT               "Use Qt version as frontend for MINGW" QT4)
 154 else()
 155   LYX_COMBO(USE_QT               "Use Qt version as frontend" QT4 QT5)
 156 endif()
 157
 158
 159 if(help OR HELP)
 160         message(STATUS)
 161         message(STATUS "Available options: (dis/enable with -DLYX_*=OFF/ON)")
 162         message(STATUS)
 163         LYX_OPTION_LIST_ALL(help)
 164         message(STATUS)
 165         RETURN()
 166 endif()
 167
 168 # Check option dependencies
 169
 170 if(LYX_DMG)
 171         set(LYX_BUNDLE ON)
 172         set(LYX_CPACK ON)
 173 endif()
 174
 175 if(LYX_CPACK)
 176         set(LYX_INSTALL ON)
 177 endif()
 178
 179 if(LYX_INSTALL)
 180         set(LYX_NLS ON)
 181         if(WIN32 AND NOT MINGW)
 182                 set(LYX_HUNSPELL ON)
 183         endif()
 184         if(LYX_CONSOLE MATCHES "FORCE")
 185                 set(LYX_CONSOLE ON)
 186         else()
 187                 set(LYX_CONSOLE OFF)
 188         endif()
 189         set(LYX_PACKAGE_SUFFIX ON)
 190         if(NOT LYX_DEBUG)
 191                 set(LYX_RELEASE ON)
 192         endif()
 193         set(LYX_PROFILE OFF)
 194 endif()
 195
 196
 197 if(LYX_MERGE_FILES)
 198         set(LYX_PCH OFF)
 199 else()
 200         set(LYX_MERGE_REBUILD OFF)
 201 endif()
 202
 203
 204 if(LYX_DEPENDENCIES_DOWNLOAD)
 205         message(STATUS)
 206         set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 207         message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 208         set(deps_files lyx20-deps-msvc2010-x86.zip)
 209         set(deps_server http://downloads.sourceforge.net/project/lyx/Win_installers/Dependencies)
 210         foreach(it ${deps_files})
 211                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 212                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 213                 if(NOT already_downloaded)
 214                         message(STATUS "Downloading ${it} ...")
 215                         file(DOWNLOAD ${deps_server}/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS STATUS status LOG log)
 216                         list(GET status 0 status_code)
 217                         list(GET status 1 status_string)
 218                         if(NOT status_code EQUAL 0)
 219                                 file(REMOVE ${LYX_DEPENDENCIES_DIR}/${it})
 220                                 message(FATAL_ERROR "error: downloading '${it}' failed. status_code: ${status_code}, status_string: ${status_string}. \nLog: ${log} ")
 221                         endif()
 222                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 223                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 224                 endif()
 225         endforeach()
 226         set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/deps20)
 227     if(MSVC12)
 228         # handle error in msvc12 when linking against msvc10 libs
 229         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /vd2")
 230     endif()
 231 endif()
 232
 233
 234
 235 message(STATUS)
 236
 237 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 238 if(WIN32)
 239         set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 240 else()
 241         set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 242 endif()
 243
 244
 245 set(LYX_GCC11_MODE)
 246 if(UNIX OR MINGW)
 247         execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION)
 248         message(STATUS "Using GCC version ${GCC_VERSION}")
 249         if(NOT GCC_VERSION VERSION_LESS 4.4)
 250                 set(LYX_USE_TR1 1)
 251                 # GCC <= 4.5 does not support regex: there are linker errors
 252                 # http://gcc.gnu.org/onlinedocs/libstdc++/manual/status.html#status.iso.tr1
 253                 set(LYX_USE_TR1_REGEX 0)
 254         endif()
 255         if (LYX_ENABLE_CXX11)
 256                 find_package(CXX11Compiler)
 257                 if(NOT CXX11COMPILER_FOUND)
 258                         message(FATAL_ERROR "A C++11 compatible compiler is required.")
 259                 endif()
 260                 set(LYX_GCC11_MODE "${CXX11_FLAG}")
 261         endif()
 262 else()
 263         if(MSVC10)
 264                 set(LYX_USE_TR1 1)
 265                 #set(LYX_USE_TR1_REGEX 1) #TODO should we use it in ECMAScript mode?
 266         endif()
 267 endif()
 268
 269
 270 set(VERSION_INFO "CMake Build")
 271
 272 # Try to get some informations from configure.ac
 273
 274 include(LyXPaths)
 275 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 276
 277 if(WIN32)
 278         set(USE_WINDOWS_PACKAGING ON)
 279 elseif(APPLE)
 280         set(USE_MACOSX_PACKAGING ON)
 281 else()
 282         set(USE_POSIX_PACKAGING ON)
 283 endif()
 284
 285 macro(setstripped _varname)
 286         if(${ARGC} GREATER 1)
 287                 string(STRIP "${ARGV1}" _v)
 288                 if(USE_POSIX_PACKAGING)
 289                         string(TOLOWER ${_v} ${_varname})
 290                 else()
 291                         set(${_varname} ${_v})
 292                 endif()
 293         else()
 294                 set(${_varname})
 295         endif()
 296 endmacro(setstripped)
 297
 298 foreach(_c_l ${_config_lines} )
 299         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 300                 setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 301                 setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 302                 setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 303                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\)\(\\.\([0-9]+\)\)?.*$")
 304                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 305                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 306                         set(LYX_PATCH_VERSION ${CMAKE_MATCH_4})
 307                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 308                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 309                         set(LYX_INSTALL_SUFFIX "${CMAKE_MATCH_1}.${CMAKE_MATCH_2}")
 310                 endif()
 311         endif()
 312         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 313                 set(LYX_DATE "${CMAKE_MATCH_1}")
 314         endif()
 315 endforeach(_c_l)
 316
 317 FIND_PROGRAM(LYX_GITVERSION git)
 318 #message(STATUS "gitversion = ${LYX_GITVERSION}")
 319 set(LYX_GIT_COMMIT_HASH "none")
 320 set(LYX_REVISION_VERSION ${LYX_PATCH_VERSION})
 321 if(LYX_GITVERSION)
 322   if (LYX_LOCALVERSIONING)
 323     # Find the revision number and for later use
 324     EXECUTE_PROCESS(COMMAND ${LYX_GITVERSION} describe --match 2.0.0 HEAD
 325       WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE LYX_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 326     if (LYX_PACKAGE_RELEASE MATCHES "^2\\.0\\.0\\-\([0-9]+\)\\-.*$")
 327       # We will add offset of 40000 to get appropriate value to
 328       # previous svn.
 329       # We use this value than also to set the package-patch-value
 330       MATH(EXPR tmp_REVISION_VERSION "(${CMAKE_MATCH_1}+40000)")
 331       set(LYX_REVISION_VERSION "${LYX_PATCH_VERSION}-${tmp_REVISION_VERSION}git")
 332       set(ENABLE_DIST ON)
 333     endif()
 334   endif()
 335   EXECUTE_PROCESS(COMMAND ${LYX_GITVERSION} log -1 "--pretty=format:%H"
 336     WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE lyxgitcommit OUTPUT_STRIP_TRAILING_WHITESPACE)
 337   if (lyxgitcommit MATCHES "^[0-9a-f]+$")
 338     set(LYX_GIT_COMMIT_HASH ${lyxgitcommit})
 339   endif()
 340 endif()
 341 #message(STATUS "LYX_GIT_COMMIT_HASH = ${LYX_GIT_COMMIT_HASH}")
 342
 343 # Set the programs (lyx, tex2lyx, etc.) suffix
 344 # When building an OS X bundle, we will append
 345 # the suffix only to the bundle, not to the programs
 346 set(PROGRAM_SUFFIX "")
 347 if(LYX_PROGRAM_SUFFIX AND NOT (APPLE AND LYX_BUNDLE))
 348         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 349 endif()
 350 set(_lyx "${PACKAGE_BASE}${PROGRAM_SUFFIX}")
 351 set(_tex2lyx tex2lyx${PROGRAM_SUFFIX})
 352
 353 add_custom_target(lyx_version ALL
 354   COMMAND ${CMAKE_COMMAND} -DTOP_SRC_DIR=${TOP_SRC_DIR} -DTOP_CMAKE_PATH=${TOP_CMAKE_PATH} -DTOP_BINARY_DIR=${TOP_BINARY_DIR} -DLYX_DATE=${LYX_DATE} -P ${TOP_SCRIPT_PATH}/LyXGetVersion.cmake
 355   )
 356 set_target_properties(lyx_version PROPERTIES FOLDER "applications")
 357
 358 # Default paths for installed utilities (tex2lyx, lyxclient, etc.)
 359 set(LYX_UTILITIES_INSTALL_PATH bin)
 360
 361 if(LYX_BUNDLE)
 362         set(LYX_CPACK ON)
 363
 364         message(STATUS)
 365         message(STATUS "Bundle creation is enabled (experimental):")
 366         message(STATUS "    make")
 367         message(STATUS "    make install/strip")
 368         message(STATUS "    make package")
 369         if(APPLE)
 370                 set(MACOSX_BUNDLE TRUE)
 371                 # This sets the bundle + executable names
 372                 set(_lyx "${PACKAGE_BASE}${LYX_INSTALL_SUFFIX}")
 373                 # This sets the Info.plist executable name
 374                 set(osx_bundle_program_name ${_lyx})
 375                 # Bundle name
 376                 set(LYX_BUNDLE_NAME ${_lyx})
 377
 378                 # This will contain the list of files that need to be included
 379                 # in the bundle and their location within the bundle
 380                 set(OSX_BUNDLE_FILES "${TOP_SRC_DIR}/development/MacOSX/LyX.sdef;${TOP_SRC_DIR}/development/MacOSX/LyXapp.icns;${CMAKE_BINARY_DIR}/lyxrc.dist")
 381                 set(OSX_BUNDLE_DIRS "Resources;Resources;Resources")
 382
 383                 # Process Info.plist and lyxrc.dist
 384                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/Info.plist.in" "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 385                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/lyxrc.dist.in" "${CMAKE_CURRENT_BINARY_DIR}/lyxrc.dist")
 386
 387                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 388                 set(LYX_DATA_SUBDIR ${LYX_BUNDLE_NAME}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 389
 390                 # Variables used by CPack
 391                 set(CPACK_BUNDLE_NAME ${LYX_BUNDLE_NAME})
 392                 set(CPACK_BUNDLE_PLIST "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 393                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${LYX_BUNDLE_NAME}.app)
 394
 395                 # Set the install paths
 396                 set(LYX_UTILITIES_INSTALL_PATH ${LYX_BUNDLE_NAME}.app/Contents/MacOS)
 397                 if(NOT LYX_INSTALL_PREFIX)
 398                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 399                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 400                 endif()
 401                 # Change the owner so that the install can work
 402                 install(CODE "set(BU_CHMOD_BUNDLE_ITEMS 1)" COMPONENT Runtime)
 403         elseif(UNIX)
 404                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 405                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 406                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 407         elseif(WIN32)
 408                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 409         endif()
 410 endif()
 411
 412 if(LYX_INSTALL_PREFIX)
 413         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 414         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 415 endif()
 416 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 417
 418 string(REGEX REPLACE "/lyx${LYX_INSTALL_SUFFIX}$" "/share" SYSTEM_DATADIR ${CMAKE_INSTALL_PREFIX})
 419
 420 if(LYX_PACKAGE_SUFFIX)
 421         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 422 else()
 423         set(PACKAGE ${PACKAGE_BASE})
 424 endif()
 425
 426 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 427         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 428         if (UNIX)
 429                 # don't use the default "/usr/local"
 430                 # but respect the user-choice on the command-line
 431                 if(LYX_INSTALL_SUFFIX)
 432                         set(CMAKE_INSTALL_PREFIX "/usr/local/lyx${LYX_INSTALL_SUFFIX}" CACHE PATH "LyX default install prefix" FORCE)
 433                 else()
 434                         set(CMAKE_INSTALL_PREFIX "/usr/local/${LYX_PROJECT}" CACHE PATH "LyX default install prefix" FORCE)
 435                 endif()
 436         endif()
 437         if(WIN32)
 438                 set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 439         endif()
 440 endif()
 441 if(IS_ABSOLUTE)
 442         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 443 else()
 444         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 445 endif()
 446
 447
 448
 449 if(NOT LYX_DATA_SUBDIR)
 450         if (WIN32)
 451                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 452         else()
 453                 set(LYX_DATA_SUBDIR "" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 454         endif()
 455 endif()
 456
 457 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 458 set(LYX_LOCALEDIR "locale")
 459 set(LYX_ABS_INSTALLED_LOCALEDIR "${LYX_ABS_INSTALLED_DATADIR}/${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}")
 460 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 461
 462 if(LYX_BUNDLE AND APPLE)
 463         set(LYX_MAN_DIR "${LYX_DATA_SUBDIR}" CACHE STRING "Install location for man pages.")
 464 else()
 465         set(LYX_MAN_DIR "/usr/local/man/man1" CACHE STRING "Install location for man pages.")
 466 endif()
 467 mark_as_advanced(LYX_MAN_DIR)
 468
 469 if(LYX_INSTALL AND WIN32)
 470         message(STATUS "Configuring NSIS files")
 471         configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 472         configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 473         configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 474         message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 475 endif()
 476
 477 if(NOT GROUP_CODE)
 478         #set(GROUP_CODE "The Golden Code")
 479         set(GROUP_CODE flat)
 480 endif()
 481
 482 # lyx's source files
 483 set(LYX_CPP_FILES *.cpp)
 484 set(LYX_HPP_FILES *.h)
 485 set(LYX_MOC_FILES moc_*.cpp)
 486
 487 include(ProjectSourceGroup)
 488
 489
 490 if(LYX_PROFILE AND NOT MSVC)
 491         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 492         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg")
 493         set(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS}  -pg")
 494 else()
 495         set(LYX_PROFILE OFF)
 496 endif()
 497
 498
 499 if(LYX_NO_OPTIMIZE)
 500         set(CMAKE_BUILD_TYPE None)
 501         set(LYX_DEBUG OFF)
 502         set(LYX_RELEASE OFF)
 503         set(LYX_PROFILE OFF)
 504 elseif(LYX_RELEASE)
 505         set(CMAKE_BUILD_TYPE Release)
 506         set(LYX_DEBUG OFF)
 507         set(LYX_PROFILE OFF)
 508 elseif(LYX_PROFILE)
 509         set(CMAKE_BUILD_TYPE Profile)
 510         set(LYX_DEBUG OFF)
 511 else()
 512         set(CMAKE_BUILD_TYPE Debug)
 513         set(LYX_DEBUG ON)
 514 endif()
 515
 516
 517 # When shared libs are supported enable this option
 518 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 519 if(LYX_SHARED_LIBRARIES)
 520         set(library_type SHARED)
 521 else()
 522         set(library_type STATIC)
 523 endif()
 524
 525 if(NOT MSVC)
 526         if(NOT LYX_QUIET)
 527                 set(CMAKE_VERBOSE_MAKEFILE ON)
 528         endif()
 529     set(LYX_CXX_FLAGS "-Wall -Wunused-parameter ${LYX_GCC11_MODE}")
 530         if(LYX_STDLIB_DEBUG)
 531                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 532         endif()
 533         if(LYX_CONCEPT_CHECKS)
 534                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCPP_CONCEPT_CHECKS")
 535         endif()
 536         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 537         set(CMAKE_CXX_FLAGS_DEBUG "${LYX_CXX_FLAGS} -fno-strict-aliasing -O0 -g3 -D_DEBUG" CACHE TYPE STRING FORCE)
 538         if(MINGW)
 539                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 540         else()
 541                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 542         endif()
 543 endif()
 544
 545 set(LYX_CXX_FLAGS_EXTRA "" CACHE STRING "Desired semicolon separated list of extra cxx compile flags, like '-Werror'")
 546 mark_as_advanced(LYX_CXX_FLAGS_EXTRA)
 547 if(LYX_CXX_FLAGS_EXTRA)
 548         foreach(_flag ${LYX_CXX_FLAGS_EXTRA})
 549                 add_definitions(${_flag})
 550         endforeach()
 551 endif()
 552
 553 if(LYX_XMINGW)
 554     set(QT_MINGW_DIR ${LYX_QT4} CACHE PATH "Qt for Mingw" FORCE)
 555     list(APPEND CMAKE_FIND_ROOT_PATH ${QT_MINGW_DIR} ${GNUWIN32_DIR})
 556 endif()
 557 if(LYX_USE_QT MATCHES "QT5")
 558         find_package(Qt5Core REQUIRED)
 559         if (Qt5Core_FOUND)
 560                 find_package(Qt5Widgets REQUIRED)
 561                 if(APPLE)
 562                         find_package(Qt5MacExtras REQUIRED)
 563                 endif()
 564                 find_package(Qt5X11Extras QUIET)
 565                 set(QTVERSION ${Qt5Core_VERSION})
 566                 macro (qt_use_modules)
 567                         qt5_use_modules(${ARGN})
 568                 endmacro()
 569                 macro (qt_add_resources)
 570                         qt5_add_resources(${ARGN})
 571                 endmacro()
 572                 macro (qt_wrap_uifiles)
 573                         qt5_wrap_ui(${ARGN})
 574                 endmacro()
 575                 message(STATUS "Found Qt-Version ${QTVERSION}")
 576         endif()
 577 elseif(LYX_USE_QT MATCHES "QT4")
 578         find_package(Qt4 "4.5.0" REQUIRED)
 579         macro (qt_use_modules)
 580         endmacro()
 581         macro (qt_add_resources)
 582                 qt4_add_resources(${ARGN})
 583         endmacro()
 584         macro (qt_wrap_uifiles)
 585                 qt4_wrap_ui(${ARGN})
 586         endmacro()
 587 else()
 588   message(FATAL_ERROR "Unhandled value for LYX_USE_QT (${LYX_USE_QT})")
 589 endif()
 590
 591 find_package(Magic)
 592 if(Magic_FOUND)
 593         set(HAVE_MAGIC_H 1)
 594 endif()
 595
 596 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 597
 598 set(Spelling_FOUND OFF)
 599 set(Include_used_spellchecker)   # String will be inserted into config.h
 600
 601 foreach(_spell "ASPELL" "Enchant" "Hunspell")
 602   string(TOUPPER ${_spell} _upspell)
 603   find_package(${_spell})
 604   if (${_upspell}_FOUND)
 605     include_directories(${${_upspell}_INCLUDE_DIR})
 606     set(Spelling_FOUND ON)
 607     message(STATUS "Building with USE_${_upspell}")
 608     set(Include_used_spellchecker "${Include_used_spellchecker}#define USE_${_upspell} 1\n")
 609   else()
 610     if(LYX_${_upspell})
 611       message(FATAL_ERROR "Required ${_spell} devel package not found")
 612     else()
 613       message(STATUS "${_upspell} not found, building without ${_spell} support")
 614     endif()
 615   endif()
 616 endforeach()
 617
 618 if(LYX_NLS)
 619         FIND_PROGRAM(LYX_PYTHON_EXECUTABLE python2 python HINTS ${GNUWIN32_DIR}/python)
 620         find_package(LyXGettext)
 621         if(LYX_PYTHON_EXECUTABLE AND GETTEXT_FOUND)
 622                 add_subdirectory(po "${TOP_BINARY_DIR}/po")
 623         else()
 624                 # Install only supplied .gmo-files
 625                 file(GLOB _gmofiles RELATIVE "${TOP_SRC_DIR}/po" "${TOP_SRC_DIR}/po/*.gmo")
 626                 message(STATUS "Installing provided .gmo-files only")
 627                 foreach( _gmo ${_gmofiles})
 628                         string(REGEX REPLACE "\\.gmo$" "" _lang ${_gmo})
 629                         install(FILES "${TOP_SRC_DIR}/po/${_gmo}" DESTINATION ${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}/${_lang}/LC_MESSAGES RENAME ${PACKAGE}.mo)
 630                 endforeach()
 631         endif()
 632 endif()
 633
 634
 635 find_package(ICONV REQUIRED)
 636 find_package(ZLIB REQUIRED)
 637
 638 if(LYX_EXTERNAL_BOOST)
 639         message(STATUS "Searching for boost")
 640         find_package(Boost COMPONENTS signals regex) #TODO could REQUIRED be used
 641         if(Boost_FOUND)
 642                 message(STATUS "Boost found")
 643                 message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 644                 set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 645         else()
 646                 message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 647         endif()
 648 else()
 649         if(LYX_USE_TR1_REGEX)
 650                 set(Lyx_Boost_Libraries boost_signals)
 651         else()
 652                 set(Lyx_Boost_Libraries boost_signals boost_regex)
 653         endif()
 654         add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 655         add_definitions(-DBOOST_SIGNALS_NO_DEPRECATION_WARNING=1)
 656         include_directories(${TOP_SRC_DIR}/boost)
 657         add_subdirectory(boost "${TOP_BINARY_DIR}/boost")
 658 endif()
 659
 660
 661
 662
 663 if(WIN32)
 664         if(NOT LYX_CONSOLE)
 665                 set(WIN32_CONSOLE WIN32)
 666                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARY})
 667         endif()
 668         if(MSVC)
 669                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 670                 # disable checked iterators for msvc release builds to get maximum speed
 671                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 672         else()
 673                 add_definitions(-DWINVER=0x0500)
 674         endif()
 675 endif()
 676
 677 # Compute qt4-version from ${QTVERSION}
 678
 679 message(STATUS "")
 680 foreach(_v PACKAGE PACKAGE_VERSION LYX_GIT_COMMIT_HASH
 681         PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 682         LYX_ABS_TOP_SRCDIR
 683         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 684         if(NOT DEFINED ${_v})
 685                 message(FATAL_ERROR "${_v} not defined")
 686         endif()
 687         string(SUBSTRING "${_v}                            " 0 28 _v1)
 688         message(STATUS "----- ${_v1}: ${${_v}}")
 689 endforeach(_v)
 690 message(STATUS "")
 691
 692
 693 if(LYX_PCH)
 694         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 695         # Not sure if it works for all non-msvc compilers
 696         include(PCHSupport_26)
 697         configure_file(${TOP_CMAKE_PATH}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
 698         configure_file(${TOP_CMAKE_PATH}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 699         add_definitions(-DLYX_ENABLE_PCH)
 700
 701         if(MSVC)
 702                 macro(lyx_add_msvc_pch name_)
 703                         set_source_files_properties(${${name_}_sources} PROPERTIES
 704                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 705                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
 706                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 707                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
 708                                 ${TOP_BINARY_DIR}/pcheaders.h)
 709                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 710                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 711                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 712                 endmacro(lyx_add_msvc_pch)
 713                 macro(lyx_add_gcc_pch name_)
 714                 endmacro()
 715         else()
 716                 macro(lyx_add_msvc_pch name_)
 717                 endmacro()
 718                 macro(lyx_add_gcc_pch name_)
 719                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT)
 720                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
 721                 endmacro()
 722         endif()
 723 else()
 724         macro(lyx_add_msvc_pch)
 725         endmacro(lyx_add_msvc_pch)
 726         macro(lyx_add_gcc_pch name_)
 727         endmacro()
 728 endif()
 729
 730
 731 if(MSVC)
 732
 733         if(LYX_VLD)
 734                 set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/development/Win32/vld)
 735                 add_subdirectory(${vld_path}/cmake)
 736                 include(${vld_path}/cmake/vld.cmake) # forced include
 737                 set(vld_dll vld)
 738         endif()
 739
 740         if(LYX_WALL)
 741                 # Use the highest warning level
 742                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 743
 744                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 745                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 746                 else()
 747                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 748                 endif()
 749
 750                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 751                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 752                 else()
 753                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 754                 endif()
 755
 756                 # add here warnings which should produce an error /weXXXX
 757                 set(MSVC_W_ERROR   "/we4101 /we4189")
 758                 # add here warnings which should be disabled /wdXXXX
 759                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 760
 761                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 762                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 763                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 764
 765         else()
 766                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 767
 768                 # add here warnings which should produce an error /weXXXX
 769                 set(MSVC_W_ERROR   "/we4101 /we4189")
 770                 # add here warnings which should be disabled /wdXXXX
 771                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 772
 773                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 774                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 775                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 776
 777         endif()
 778
 779         if (NOT Qt5Core_FOUND)
 780                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 781                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 782                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 783         endif()
 784
 785         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 786         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 787         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 788         message(STATUS "")
 789 endif()
 790
 791
 792 if(LYX_DEBUG_GLIBC)
 793         set(_GLIBCXX_DEBUG ON)
 794 endif()
 795
 796 if(LYX_DEBUG_GLIBC_PEDANTIC)
 797         set(_GLIBCXX_DEBUG_PEDANTIC ON)
 798 endif()
 799
 800 # Xcode compiler
 801 if (CMAKE_GENERATOR MATCHES Xcode)
 802         if (XCODE_VERSION VERSION_LESS "5.0")
 803                 # Automatically select the Xcode compiler if not set
 804                 if (NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 805                         # XCode >= 3.1 has gcc 4.2 (up to actual Xcode)
 806                         if (XCODE_VERSION VERSION_GREATER "3.1")
 807                                 SET(CMAKE_XCODE_ATTRIBUTE_GCC_VERSION "com.apple.compilers.llvmgcc42")
 808                         ENDIF(XCODE_VERSION VERSION_GREATER "3.1")
 809                 ENDIF(NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 810                 # Print the selected compiler version
 811         MESSAGE(STATUS "---- Using XCode compiler CMAKE_XCODE_ATTRIBUTE_GCC_VERSION=${CMAKE_XCODE_ATTRIBUTE_GCC_VERSION}")
 812         ENDIF(XCODE_VERSION VERSION_LESS "5.0")
 813 ENDIF(CMAKE_GENERATOR MATCHES Xcode)
 814
 815 if (WIN32 AND Qt5Core_FOUND)
 816         set(Z_PREFIX 1)
 817 endif()
 818
 819 # compiler tests, config.h generation
 820 if(MSVC AND NOT LYX_CONFIGURE_CHECKS)
 821         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.msvc ${TOP_BINARY_DIR}/configCompiler.h)
 822 else()
 823         include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
 824         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
 825 endif()
 826
 827 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
 828
 829 if(QTVERSION MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+).*")
 830         MATH(EXPR QT4_VERSION "(${CMAKE_MATCH_1}<<16)|(${CMAKE_MATCH_2}<<8)|${CMAKE_MATCH_3}")
 831 endif()
 832
 833
 834 set (cmd ${CMAKE_CTEST_COMMAND})
 835 if (MSVC)
 836         set (cmd ${cmd} -C ${CMAKE_CFG_INTDIR})
 837 else ()
 838         set (cmd ${cmd} -C ${CMAKE_BUILD_TYPE})
 839 endif ()
 840 add_custom_target (lyx_run_tests COMMAND ${cmd})
 841 set_target_properties(lyx_run_tests PROPERTIES FOLDER "tests")
 842
 843 if(LYX_ASAN)
 844     set(LYX_CXX_FLAGS "-fsanitize=address -fno-omit-frame-pointer -g")
 845     message(STATUS)
 846     message(STATUS "Address sanitizer enabled. Usage:")
 847     message(STATUS "    wget https://llvm.org/svn/llvm-project/compiler-rt/trunk/lib/asan/scripts/asan_symbolize.py")
 848     message(STATUS "    chmod  +x ./asan_symbolize.py")
 849     message(STATUS "    ./bin/lyx2.2 2>&1 | ./asan_symbolize.py  | c++filt ")
 850     message(STATUS)
 851 endif()
 852
 853 if(LYX_INSTALL)
 854         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 855                 message(STATUS "Python required to create doc!")
 856         else()
 857                 if(UNIX)
 858                         add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
 859                 endif()
 860                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
 861         endif()
 862         include(../Install)
 863 endif()
 864
 865 add_subdirectory(src "${TOP_BINARY_DIR}/src")
 866 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
 867 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
 868 add_subdirectory(lib/examples "${TOP_BINARY_DIR}/lib/examples")
 869 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
 870 add_subdirectory(development/autotests "${TOP_BINARY_DIR}/autotests")
 871 if(LYX_ENABLE_URLTESTS)
 872         add_subdirectory(development/checkurls "${TOP_BINARY_DIR}/checkurls")
 873 endif()
 874
 875 message(STATUS)
 876 message(STATUS "Build params, switch LYX_* options by -DLYX_*=ON or OFF, LYX_* combos by -DLYX_*=value:")
 877 message(STATUS)
 878
 879 LYX_OPTION_LIST_ALL(used)
 880
 881
 882 if(LYX_NLS)
 883         message(STATUS)
 884         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
 885         message(STATUS)
 886         message(STATUS "  * iconv")
 887         message(STATUS "     - header : ${ICONV_HEADER}")
 888         message(STATUS "     - library: ${ICONV_LIBRARY}")
 889         message(STATUS "  * zlib")
 890         message(STATUS "     - header : ${ZLIB_HEADER}")
 891         message(STATUS "     - library: ${ZLIB_LIBRARY}")
 892         message(STATUS)
 893 endif()
 894
 895 # Apple has builtin native spell checker,
 896 # no need to warn for missing Aspell, Hunspell or Enchant
 897 if(NOT Spelling_FOUND AND NOT APPLE)
 898   if(LYX_REQUIRE_SPELLCHECK)
 899     set(_mode "FATAL_ERROR")
 900   else()
 901     set(_mode "STATUS")
 902   endif()
 903   message(${_mode} "No spellcheck libraries found. LyX will be unable use spellchecking")
 904 endif()
 905
 906 include("${TOP_CMAKE_PATH}/LyxPackaging.cmake")
 907
 908 if(ENABLE_DIST)
 909   # Use git to create the source package
 910   # git archive --format=tgz --output=/home/kornel/x.tar.gz master
 911   if(UNIX)
 912     set(DIST_FORMAT tgz)
 913   else()
 914     set(DIST_FORMAT zip)
 915   endif()
 916   set(DIST_NAME ${CMAKE_PROJECT_NAME}-${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}-${CMAKE_SYSTEM_NAME}.${DIST_FORMAT})
 917
 918   add_custom_command(
 919     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME}
 920     COMMAND  ${LYX_GITVERSION} archive --format=${DIST_FORMAT} --output=${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME} master
 921     WORKING_DIRECTORY ${TOP_SRC_DIR})
 922   add_custom_target(git-archive DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME})
 923 endif()
 924
 925 # Last directory to be included so that the fixup code (OS X)
 926 # can be run last
 927 add_subdirectory(development/cmake/post_install)
 928
 929 message(STATUS)