CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 2.6.4)
   8
   9 set(LYX_PROJECT LyX)
  10
  11 enable_testing()
  12
  13 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README ABSOLUTE)
  14 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  15
  16 set(LYX_CMAKE_DIR "development/cmake")
  17 set(TOP_CMAKE_PATH "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}")
  18 set(TOP_MODULE_PATH "${TOP_CMAKE_PATH}/modules")
  19 set(TOP_SCRIPT_PATH "${TOP_CMAKE_PATH}/scripts")
  20
  21 set(CMAKE_MODULE_PATH "${TOP_MODULE_PATH}")
  22
  23 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  24
  25 message(STATUS)
  26 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  27         message(STATUS "Building in-source")
  28         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  29 else()
  30         message(STATUS "Building out-of-source")
  31         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  32 endif()
  33
  34 # This directory should be used if some test uses lyx-executable
  35 set(LYX_TESTS_USERDIR "${TOP_BINARY_DIR}/Testing/.lyx")
  36 file(MAKE_DIRECTORY "${LYX_TESTS_USERDIR}")
  37
  38 if(COMMAND cmake_policy)
  39         cmake_policy(SET CMP0003 OLD)
  40         cmake_policy(SET CMP0005 OLD)
  41         # Installing MACOSX_BUNDLE targets requires a BUNDLE DESTINATION
  42         cmake_policy(SET CMP0006 NEW)
  43 endif()
  44
  45 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  46
  47 # Supress regeneration
  48 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  49
  50 if(LYX_XMINGW)
  51     set(CMAKE_SYSTEM_NAME Windows)
  52     set(TOOLNAME ${LYX_XMINGW})
  53     set(TOOLCHAIN "${TOOLNAME}-")
  54     set(CMAKE_C_COMPILER   "${TOOLCHAIN}gcc"     CACHE PATH "Mingw C compiler" FORCE)
  55     set(CMAKE_CXX_COMPILER "${TOOLCHAIN}g++"     CACHE PATH "Mingw C++ compiler" FORCE)
  56     set(CMAKE_RC_COMPILER  "${TOOLCHAIN}windres" CACHE PATH "Mingw rc compiler" FORCE)
  57
  58     set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM BOTH)
  59     set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY)
  60     set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY)
  61 endif()
  62
  63 if(NOT help AND NOT HELP)
  64         # 'project' triggers the searching for a compiler
  65         project(${LYX_PROJECT})
  66 endif()
  67
  68 if(UNIX)
  69         set(ARCH_TRIPLET )
  70         FIND_PROGRAM(DPKG_ARCHITECTURE_EXECUTABLE dpkg-architecture)
  71         if(DPKG_ARCHITECTURE_EXECUTABLE)
  72                 EXECUTE_PROCESS(COMMAND ${DPKG_ARCHITECTURE_EXECUTABLE} -qDEB_HOST_MULTIARCH
  73                                 OUTPUT_VARIABLE ARCH_TRIPLET
  74                                 ERROR_VARIABLE ERROR_ARCH_TRIPLET
  75                                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  76         endif()
  77 endif()
  78 if(ARCH_TRIPLET)
  79         set(SYSTEM_LIB_DIRS /usr/lib /usr/lib/${ARCH_TRIPLET} /usr/local/lib)
  80 else()
  81         set(SYSTEM_LIB_DIRS /usr/lib /usr/local/lib)
  82 endif()
  83
  84 include(LyXMacros)
  85
  86 # Usage LYX_OPTION
  87 # 1. parameter: option name without prefix 'LYX_'
  88 # 2. parameter: description
  89 # 3. parameter: default value, ON or OFF
  90 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
  91
  92
  93 LYX_OPTION_INIT()
  94
  95 # Options for all compilers/systems
  96 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
  97 LYX_OPTION(LOCALVERSIONING  "Add version info to created package name (only used if LYX_CPACK option set)" OFF ALL)
  98 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
  99 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
 100 LYX_OPTION(REQUIRE_SPELLCHECK "Abort if no spellchecker available" OFF ALL)
 101 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
 102 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
 103 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
 104 LYX_OPTION(DEVEL_VERSION    "Build developer version" OFF ALL)
 105 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" OFF ALL)
 106 LYX_OPTION(DEBUG            "Enforce debug build"  OFF ALL)
 107 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
 108 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
 109 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
 110 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
 111 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
 112 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
 113 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
 114 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
 115 LYX_OPTION(ENABLE_URLTESTS  "Enable for URL tests" OFF ALL)
 116
 117 # GCC specific
 118 LYX_OPTION(PROFILE              "Build profile version" OFF GCC)
 119 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" OFF GCC)
 120 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
 121 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
 122 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++ pedantic debug mode" OFF GCC)
 123 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" OFF GCC)
 124 LYX_OPTION(CONCEPT_CHECKS       "Enable concept-checks" OFF GCC)
 125 LYX_OPTION(PROFILE              "Build with options for gprof" OFF GCC)
 126 LYX_OPTION(ENABLE_CXX11         "Build with options for c++11-mode" OFF GCC)
 127
 128 # MSVC specific
 129 LYX_OPTION(CONSOLE               "Show console on Windows, enforce with =FORCE" ON MSVC)
 130 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
 131 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
 132 LYX_OPTION(CONFIGURE_CHECKS      "Also run configure checks for MSVC" OFF MSVC)
 133 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
 134
 135 # APPLE specific
 136 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
 137 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
 138
 139
 140 if(help OR HELP)
 141         message(STATUS)
 142         message(STATUS "Available options: (dis/enable with -DLYX_*=OFF/ON)")
 143         message(STATUS)
 144         LYX_OPTION_LIST_ALL(help)
 145         message(STATUS)
 146         RETURN()
 147 endif()
 148
 149 # Check option dependencies
 150
 151 if(LYX_DMG)
 152         set(LYX_BUNDLE ON)
 153         set(LYX_CPACK ON)
 154 endif()
 155
 156 if(LYX_CPACK)
 157         set(LYX_INSTALL ON)
 158 endif()
 159
 160 if(LYX_INSTALL)
 161         set(LYX_NLS ON)
 162         if(WIN32 AND NOT MINGW)
 163                 set(LYX_HUNSPELL ON)
 164         endif()
 165         if(LYX_CONSOLE MATCHES "FORCE")
 166                 set(LYX_CONSOLE ON)
 167         else()
 168                 set(LYX_CONSOLE OFF)
 169         endif()
 170         set(LYX_PACKAGE_SUFFIX ON)
 171         if(NOT LYX_DEBUG)
 172                 set(LYX_RELEASE ON)
 173         endif()
 174         set(LYX_PROFILE OFF)
 175 endif()
 176
 177
 178 if(LYX_MERGE_FILES)
 179         set(LYX_PCH OFF)
 180 else()
 181         set(LYX_MERGE_REBUILD OFF)
 182 endif()
 183
 184
 185 if(LYX_DEPENDENCIES_DOWNLOAD)
 186         message(STATUS)
 187         set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 188         message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 189         set(deps_files lyx20-deps-msvc2010-x86.zip)
 190         set(deps_server http://downloads.sourceforge.net/project/lyx/Win_installers/Dependencies)
 191         foreach(it ${deps_files})
 192                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 193                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 194                 if(NOT already_downloaded)
 195                         message(STATUS "Downloading ${it} ...")
 196                         file(DOWNLOAD ${deps_server}/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS STATUS status LOG log)
 197                         list(GET status 0 status_code)
 198                         list(GET status 1 status_string)
 199                         if(NOT status_code EQUAL 0)
 200                                 file(REMOVE ${LYX_DEPENDENCIES_DIR}/${it})
 201                                 message(FATAL_ERROR "error: downloading '${it}' failed. status_code: ${status_code}, status_string: ${status_string}. \nLog: ${log} ")
 202                         endif()
 203                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 204                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 205                 endif()
 206         endforeach()
 207         set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/deps20)
 208 endif()
 209
 210
 211
 212 message(STATUS)
 213
 214 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 215 if(WIN32)
 216         set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 217 else()
 218         set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 219 endif()
 220
 221
 222 set(LYX_GCC11_MODE)
 223 if(UNIX OR MINGW)
 224         execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION)
 225         message(STATUS "Using GCC version ${GCC_VERSION}")
 226         if(NOT GCC_VERSION VERSION_LESS 4.4)
 227                 set(LYX_USE_TR1 1)
 228                 # GCC <= 4.5 does not support regex: there are linker errors
 229                 # http://gcc.gnu.org/onlinedocs/libstdc++/manual/status.html#status.iso.tr1
 230                 set(LYX_USE_TR1_REGEX 0)
 231         endif()
 232         if (LYX_ENABLE_CXX11)
 233                 find_package(CXX11Compiler)
 234                 if(NOT CXX11COMPILER_FOUND)
 235                         message(FATAL_ERROR "A C++11 compatible compiler is required.")
 236                 endif()
 237                 set(LYX_GCC11_MODE "${CXX11_FLAG}")
 238         endif()
 239 else()
 240         if(MSVC10)
 241                 set(LYX_USE_TR1 1)
 242                 #set(LYX_USE_TR1_REGEX 1) #TODO should we use it in ECMAScript mode?
 243         endif()
 244 endif()
 245
 246
 247 set(VERSION_INFO "CMake Build")
 248
 249 # Try to get some informations from configure.ac
 250
 251 include(LyXPaths)
 252 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 253
 254 if(WIN32)
 255         set(USE_WINDOWS_PACKAGING ON)
 256 elseif(APPLE)
 257         set(USE_MACOSX_PACKAGING ON)
 258 else()
 259         set(USE_POSIX_PACKAGING ON)
 260 endif()
 261
 262 macro(setstripped _varname)
 263         if(${ARGC} GREATER 1)
 264                 string(STRIP "${ARGV1}" _v)
 265                 if(USE_POSIX_PACKAGING)
 266                         string(TOLOWER ${_v} ${_varname})
 267                 else()
 268                         set(${_varname} ${_v})
 269                 endif()
 270         else()
 271                 set(${_varname})
 272         endif()
 273 endmacro(setstripped)
 274
 275 foreach(_c_l ${_config_lines} )
 276         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 277                 setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 278                 setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 279                 setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 280                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\)\(\\.\([0-9]+\)\)?.*$")
 281                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 282                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 283                         set(LYX_PATCH_VERSION ${CMAKE_MATCH_4})
 284                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 285                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 286                         set(LYX_INSTALL_SUFFIX "${CMAKE_MATCH_1}.${CMAKE_MATCH_2}")
 287                 endif()
 288         endif()
 289         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 290                 set(LYX_DATE "${CMAKE_MATCH_1}")
 291         endif()
 292 endforeach(_c_l)
 293
 294 if (LYX_LOCALVERSIONING)
 295         # Find the revision number and for later use
 296         FIND_PROGRAM(LYX_GITVERSION git)
 297         #message(STATUS "gitversion = ${LYX_GITVERSION}")
 298         if(LYX_GITVERSION)
 299                 EXECUTE_PROCESS(COMMAND ${LYX_GITVERSION} describe --match 2.0.0 HEAD
 300                 WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE LYX_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 301                 if (LYX_PACKAGE_RELEASE MATCHES "^2\\.0\\.0\\-\([0-9]+\)\\-.*$")
 302                   # We will add offset of 40000 to get appropriate value to
 303                   # previous svn.
 304                   # We use this value than also to set the package-patch-value
 305                   MATH(EXPR tmp_REVISION_VERSION "(${CMAKE_MATCH_1}+40000)")
 306                   set(LYX_REVISION_VERSION "${LYX_PATCH_VERSION}-${tmp_REVISION_VERSION}git")
 307                   set(ENABLE_DIST ON)
 308                 endif()
 309         else()
 310                 set(LYX_REVISION_VERSION git) #TODO use date
 311         endif()
 312 else()
 313         set(LYX_REVISION_VERSION ${LYX_PATCH_VERSION})
 314 endif()
 315
 316 # Set the programs (lyx, tex2lyx, etc.) suffix
 317 # When building an OS X bundle, we will append
 318 # the suffix only to the bundle, not to the programs
 319 set(PROGRAM_SUFFIX "")
 320 if(LYX_PROGRAM_SUFFIX AND NOT (APPLE AND LYX_BUNDLE))
 321         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 322 endif()
 323 set(_lyx "${PACKAGE_BASE}${PROGRAM_SUFFIX}")
 324 set(_tex2lyx tex2lyx${PROGRAM_SUFFIX})
 325
 326 add_custom_target(lyx_version ALL
 327   COMMAND ${CMAKE_COMMAND} -DTOP_SRC_DIR=${TOP_SRC_DIR} -DTOP_CMAKE_PATH=${TOP_CMAKE_PATH} -DTOP_BINARY_DIR=${TOP_BINARY_DIR} -DLYX_DATE=${LYX_DATE} -P ${TOP_SCRIPT_PATH}/LyXGetVersion.cmake
 328   )
 329 set_target_properties(lyx_version PROPERTIES FOLDER "applications")
 330
 331 # Default paths for installed utilities (tex2lyx, lyxclient, etc.)
 332 set(LYX_UTILITIES_INSTALL_PATH bin)
 333
 334 if(LYX_BUNDLE)
 335         set(LYX_CPACK ON)
 336
 337         message(STATUS)
 338         message(STATUS "Bundle creation is enabled (experimental):")
 339         message(STATUS "    make")
 340         message(STATUS "    make install/strip")
 341         message(STATUS "    make package")
 342         if(APPLE)
 343                 set(MACOSX_BUNDLE TRUE)
 344                 # This sets the bundle + executable names
 345                 set(_lyx "${PACKAGE_BASE}${LYX_INSTALL_SUFFIX}")
 346                 # This sets the Info.plist executable name
 347                 set(osx_bundle_program_name ${_lyx})
 348                 # Bundle name
 349                 set(LYX_BUNDLE_NAME ${_lyx})
 350
 351                 # This will contain the list of files that need to be included
 352                 # in the bundle and their location within the bundle
 353                 set(OSX_BUNDLE_FILES "${TOP_SRC_DIR}/development/MacOSX/LyX.sdef;${TOP_SRC_DIR}/development/MacOSX/LyXapp.icns;${CMAKE_BINARY_DIR}/lyxrc.dist")
 354                 set(OSX_BUNDLE_DIRS "Resources;Resources;Resources")
 355
 356                 # Process Info.plist and lyxrc.dist
 357                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/Info.plist.in" "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 358                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/lyxrc.dist.in" "${CMAKE_CURRENT_BINARY_DIR}/lyxrc.dist")
 359
 360                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 361                 set(LYX_DATA_SUBDIR ${LYX_BUNDLE_NAME}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 362
 363                 # Variables used by CPack
 364                 set(CPACK_BUNDLE_NAME ${LYX_BUNDLE_NAME})
 365                 set(CPACK_BUNDLE_PLIST "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 366                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${LYX_BUNDLE_NAME}.app)
 367
 368                 # Set the install paths
 369                 set(LYX_UTILITIES_INSTALL_PATH ${LYX_BUNDLE_NAME}.app/Contents/MacOS)
 370                 if(NOT LYX_INSTALL_PREFIX)
 371                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 372                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 373                 endif()
 374                 # Change the owner so that the install can work
 375                 install(CODE "set(BU_CHMOD_BUNDLE_ITEMS 1)" COMPONENT Runtime)
 376         elseif(UNIX)
 377                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 378                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 379                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 380         elseif(WIN32)
 381                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 382         endif()
 383 endif()
 384
 385 if(LYX_INSTALL_PREFIX)
 386         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 387         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 388 endif()
 389 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 390
 391 string(REGEX REPLACE "/lyx${LYX_INSTALL_SUFFIX}$" "/share" SYSTEM_DATADIR ${CMAKE_INSTALL_PREFIX})
 392
 393 if(LYX_PACKAGE_SUFFIX)
 394         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 395 else()
 396         set(PACKAGE ${PACKAGE_BASE})
 397 endif()
 398
 399 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 400         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 401         if (UNIX)
 402                 # don't use the default "/usr/local"
 403                 # but respect the user-choice on the command-line
 404                 if(LYX_INSTALL_SUFFIX)
 405                         set(CMAKE_INSTALL_PREFIX "/usr/local/lyx${LYX_INSTALL_SUFFIX}" CACHE PATH "LyX default install prefix" FORCE)
 406                 else()
 407                         set(CMAKE_INSTALL_PREFIX "/usr/local/${LYX_PROJECT}" CACHE PATH "LyX default install prefix" FORCE)
 408                 endif()
 409         endif()
 410         if(WIN32)
 411                 set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 412         endif()
 413 endif()
 414 if(IS_ABSOLUTE)
 415         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 416 else()
 417         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 418 endif()
 419
 420
 421
 422 if(NOT LYX_DATA_SUBDIR)
 423         if (WIN32)
 424                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 425         else()
 426                 set(LYX_DATA_SUBDIR "" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 427         endif()
 428 endif()
 429
 430 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 431 set(LYX_LOCALEDIR "locale")
 432 set(LYX_ABS_INSTALLED_LOCALEDIR "${LYX_ABS_INSTALLED_DATADIR}/${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}")
 433 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 434
 435 if(LYX_BUNDLE AND APPLE)
 436         set(LYX_MAN_DIR "${LYX_DATA_SUBDIR}" CACHE STRING "Install location for man pages.")
 437 else()
 438         set(LYX_MAN_DIR "/usr/local/man/man1" CACHE STRING "Install location for man pages.")
 439 endif()
 440 mark_as_advanced(LYX_MAN_DIR)
 441
 442 if(LYX_INSTALL AND WIN32)
 443         message(STATUS "Configuring NSIS files")
 444         configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 445         configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 446         configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 447         message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 448 endif()
 449
 450 if(NOT GROUP_CODE)
 451         #set(GROUP_CODE "The Golden Code")
 452         set(GROUP_CODE flat)
 453 endif()
 454
 455 # lyx's source files
 456 set(LYX_CPP_FILES *.cpp)
 457 set(LYX_HPP_FILES *.h)
 458 set(LYX_MOC_FILES moc_*.cpp)
 459
 460 include(ProjectSourceGroup)
 461
 462
 463 if(LYX_PROFILE AND NOT MSVC)
 464         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 465         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg")
 466         set(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS}  -pg")
 467 else()
 468         set(LYX_PROFILE OFF)
 469 endif()
 470
 471
 472 if(LYX_NO_OPTIMIZE)
 473         set(CMAKE_BUILD_TYPE None)
 474         set(LYX_DEBUG OFF)
 475         set(LYX_RELEASE OFF)
 476         set(LYX_PROFILE OFF)
 477 elseif(LYX_RELEASE)
 478         set(CMAKE_BUILD_TYPE Release)
 479         set(LYX_DEBUG OFF)
 480         set(LYX_PROFILE OFF)
 481 elseif(LYX_PROFILE)
 482         set(CMAKE_BUILD_TYPE Profile)
 483         set(LYX_DEBUG OFF)
 484 else()
 485         set(CMAKE_BUILD_TYPE Debug)
 486         set(LYX_DEBUG ON)
 487 endif()
 488
 489
 490 # When shared libs are supported enable this option
 491 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 492 if(LYX_SHARED_LIBRARIES)
 493         set(library_type SHARED)
 494 else()
 495         set(library_type STATIC)
 496 endif()
 497
 498 if(NOT MSVC)
 499         if(NOT LYX_QUIET)
 500                 set(CMAKE_VERBOSE_MAKEFILE ON)
 501         endif()
 502         set(LYX_CXX_FLAGS "-Wall -Wunused-parameter ${LYX_GCC11_MODE}")
 503         if(LYX_STDLIB_DEBUG)
 504                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 505         endif()
 506         if(LYX_CONCEPT_CHECKS)
 507                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCPP_CONCEPT_CHECKS")
 508         endif()
 509         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 510         set(CMAKE_CXX_FLAGS_DEBUG "${LYX_CXX_FLAGS} -fno-strict-aliasing -O0 -g3 -D_DEBUG" CACHE TYPE STRING FORCE)
 511         if(MINGW)
 512                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 513         else()
 514                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 515         endif()
 516 endif()
 517
 518 set(LYX_CXX_FLAGS_EXTRA "" CACHE STRING "Desired semicolon separated list of extra cxx compile flags, like '-Werror'")
 519 mark_as_advanced(LYX_CXX_FLAGS_EXTRA)
 520 if(LYX_CXX_FLAGS_EXTRA)
 521         foreach(_flag ${LYX_CXX_FLAGS_EXTRA})
 522                 add_definitions(${_flag})
 523         endforeach()
 524 endif()
 525
 526 if(LYX_XMINGW)
 527     set(QT_MINGW_DIR ${LYX_QT4} CACHE PATH "Qt for Mingw" FORCE)
 528     list(APPEND CMAKE_FIND_ROOT_PATH ${QT_MINGW_DIR} ${GNUWIN32_DIR})
 529 else()
 530     find_package(Qt5Core QUIET)
 531 endif()
 532 if (Qt5Core_FOUND)
 533         find_package(Qt5Widgets REQUIRED)
 534         find_package(Qt5X11Extras)
 535         set(QTVERSION ${Qt5Core_VERSION})
 536         macro (qt_use_modules)
 537                 qt5_use_modules(${ARGN})
 538         endmacro()
 539         macro (qt_add_resources)
 540                 qt5_add_resources(${ARGN})
 541         endmacro()
 542         macro (qt_wrap_uifiles)
 543                 qt5_wrap_ui(${ARGN})
 544         endmacro()
 545 else()
 546         find_package(Qt4 "4.5.0" REQUIRED)
 547         macro (qt_use_modules)
 548         endmacro()
 549         macro (qt_add_resources)
 550                 qt4_add_resources(${ARGN})
 551         endmacro()
 552         macro (qt_wrap_uifiles)
 553                 qt4_wrap_ui(${ARGN})
 554         endmacro()
 555 endif()
 556
 557 find_package(Magic)
 558 if(Magic_FOUND)
 559         set(HAVE_MAGIC_H 1)
 560 endif()
 561
 562 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 563
 564 set(Spelling_FOUND OFF)
 565 set(Include_used_spellchecker)   # String will be inserted into config.h
 566
 567 foreach(_spell "ASPELL" "Enchant" "Hunspell")
 568   string(TOUPPER ${_spell} _upspell)
 569   find_package(${_spell})
 570   if (${_upspell}_FOUND)
 571     include_directories(${${_upspell}_INCLUDE_DIR})
 572     set(Spelling_FOUND ON)
 573     message(STATUS "Building with USE_${_upspell}")
 574     set(Include_used_spellchecker "${Include_used_spellchecker}#define USE_${_upspell} 1\n")
 575   else()
 576     if(LYX_${_upspell})
 577       message(FATAL_ERROR "Required ${_spell} devel package not found")
 578     else()
 579       message(STATUS "${_upspell} not found, building without ${_spell} support")
 580     endif()
 581   endif()
 582 endforeach()
 583
 584 if(LYX_NLS)
 585         FIND_PROGRAM(LYX_PYTHON_EXECUTABLE python2 python HINTS ${GNUWIN32_DIR}/python)
 586         find_package(LyXGettext)
 587         if(LYX_PYTHON_EXECUTABLE AND GETTEXT_FOUND)
 588                 add_subdirectory(po "${TOP_BINARY_DIR}/po")
 589         else()
 590                 # Install only supplied .gmo-files
 591                 file(GLOB _gmofiles RELATIVE "${TOP_SRC_DIR}/po" "${TOP_SRC_DIR}/po/*.gmo")
 592                 message(STATUS "Installing provided .gmo-files only")
 593                 foreach( _gmo ${_gmofiles})
 594                         string(REGEX REPLACE "\\.gmo$" "" _lang ${_gmo})
 595                         install(FILES "${TOP_SRC_DIR}/po/${_gmo}" DESTINATION ${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}/${_lang}/LC_MESSAGES RENAME ${PACKAGE}.mo)
 596                 endforeach()
 597         endif()
 598 endif()
 599
 600
 601 find_package(ICONV REQUIRED)
 602 find_package(ZLIB REQUIRED)
 603
 604 if(LYX_EXTERNAL_BOOST)
 605         message(STATUS "Searching for boost")
 606         find_package(Boost COMPONENTS signals regex) #TODO could REQUIRED be used
 607         if(Boost_FOUND)
 608                 message(STATUS "Boost found")
 609                 message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 610                 set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 611         else()
 612                 message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 613         endif()
 614 else()
 615         if(LYX_USE_TR1_REGEX)
 616                 set(Lyx_Boost_Libraries boost_signals)
 617         else()
 618                 set(Lyx_Boost_Libraries boost_signals boost_regex)
 619         endif()
 620         add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 621         add_definitions(-DBOOST_SIGNALS_NO_DEPRECATION_WARNING=1)
 622         include_directories(${TOP_SRC_DIR}/boost)
 623         add_subdirectory(boost "${TOP_BINARY_DIR}/boost")
 624 endif()
 625
 626
 627
 628
 629 if(WIN32)
 630         if(NOT LYX_CONSOLE)
 631                 set(WIN32_CONSOLE WIN32)
 632                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARY})
 633         endif()
 634         if(MSVC)
 635                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 636                 # disable checked iterators for msvc release builds to get maximum speed
 637                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 638         else()
 639                 add_definitions(-DWINVER=0x0500)
 640         endif()
 641 endif()
 642
 643 # Compute qt4-version from ${QTVERSION}
 644
 645 message(STATUS "")
 646 foreach(_v PACKAGE PACKAGE_VERSION
 647         PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 648         LYX_ABS_TOP_SRCDIR
 649         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 650         if(NOT DEFINED ${_v})
 651                 message(FATAL_ERROR "${_v} not defined")
 652         endif()
 653         string(SUBSTRING "${_v}                            " 0 28 _v1)
 654         message(STATUS "----- ${_v1}: ${${_v}}")
 655 endforeach(_v)
 656 message(STATUS "")
 657
 658
 659 if(LYX_PCH)
 660         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 661         # Not sure if it works for all non-msvc compilers
 662         include(PCHSupport_26)
 663         configure_file(${TOP_CMAKE_PATH}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
 664         configure_file(${TOP_CMAKE_PATH}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 665         add_definitions(-DLYX_ENABLE_PCH)
 666
 667         if(MSVC)
 668                 macro(lyx_add_msvc_pch name_)
 669                         set_source_files_properties(${${name_}_sources} PROPERTIES
 670                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 671                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
 672                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 673                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
 674                                 ${TOP_BINARY_DIR}/pcheaders.h)
 675                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 676                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 677                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 678                 endmacro(lyx_add_msvc_pch)
 679                 macro(lyx_add_gcc_pch name_)
 680                 endmacro()
 681         else()
 682                 macro(lyx_add_msvc_pch name_)
 683                 endmacro()
 684                 macro(lyx_add_gcc_pch name_)
 685                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT4)
 686                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
 687                 endmacro()
 688         endif()
 689 else()
 690         macro(lyx_add_msvc_pch)
 691         endmacro(lyx_add_msvc_pch)
 692         macro(lyx_add_gcc_pch name_)
 693         endmacro()
 694 endif()
 695
 696
 697 if(MSVC)
 698
 699         if(LYX_VLD)
 700                 set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/development/Win32/vld)
 701                 add_subdirectory(${vld_path}/cmake)
 702                 include(${vld_path}/cmake/vld.cmake) # forced include
 703                 set(vld_dll vld)
 704         endif()
 705
 706         if(LYX_WALL)
 707                 # Use the highest warning level
 708                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 709
 710                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 711                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 712                 else()
 713                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 714                 endif()
 715
 716                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 717                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 718                 else()
 719                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 720                 endif()
 721
 722                 # add here warnings which should produce an error /weXXXX
 723                 set(MSVC_W_ERROR   "/we4101 /we4189")
 724                 # add here warnings which should be disabled /wdXXXX
 725                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 726
 727                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 728                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 729                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 730
 731         else()
 732                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 733
 734                 # add here warnings which should produce an error /weXXXX
 735                 set(MSVC_W_ERROR   "/we4101 /we4189")
 736                 # add here warnings which should be disabled /wdXXXX
 737                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 738
 739                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 740                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 741                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 742
 743         endif()
 744
 745         if (NOT Qt5Core_FOUND)
 746                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 747                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 748                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 749         endif()
 750
 751         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 752         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 753         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 754         message(STATUS "")
 755 endif()
 756
 757
 758 if(LYX_DEBUG_GLIBC)
 759         set(_GLIBCXX_DEBUG ON)
 760 endif()
 761
 762 if(LYX_DEBUG_GLIBC_PEDANTIC)
 763         set(_GLIBCXX_DEBUG_PEDANTIC ON)
 764 endif()
 765
 766 # Xcode compiler
 767 if (CMAKE_GENERATOR MATCHES Xcode)
 768         if (XCODE_VERSION VERSION_LESS "5.0")
 769                 # Automatically select the Xcode compiler if not set
 770                 if (NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 771                         # XCode >= 3.1 has gcc 4.2 (up to actual Xcode)
 772                         if (XCODE_VERSION VERSION_GREATER "3.1")
 773                                 SET(CMAKE_XCODE_ATTRIBUTE_GCC_VERSION "com.apple.compilers.llvmgcc42")
 774                         ENDIF(XCODE_VERSION VERSION_GREATER "3.1")
 775                 ENDIF(NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 776                 # Print the selected compiler version
 777         MESSAGE(STATUS "---- Using XCode compiler CMAKE_XCODE_ATTRIBUTE_GCC_VERSION=${CMAKE_XCODE_ATTRIBUTE_GCC_VERSION}")
 778         ENDIF(XCODE_VERSION VERSION_LESS "5.0")
 779 ENDIF(CMAKE_GENERATOR MATCHES Xcode)
 780
 781 if (WIN32 AND Qt5Core_FOUND)
 782         set(Z_PREFIX 1)
 783 endif()
 784
 785 # compiler tests, config.h generation
 786 if(MSVC AND NOT LYX_CONFIGURE_CHECKS)
 787         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.msvc ${TOP_BINARY_DIR}/configCompiler.h)
 788 else()
 789         include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
 790         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
 791 endif()
 792
 793 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
 794
 795 if(QTVERSION MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+).*")
 796         MATH(EXPR QT4_VERSION "(${CMAKE_MATCH_1}<<16)|(${CMAKE_MATCH_2}<<8)|${CMAKE_MATCH_3}")
 797 endif()
 798
 799
 800 set (cmd ${CMAKE_CTEST_COMMAND})
 801 if (MSVC)
 802         set (cmd ${cmd} -C ${CMAKE_CFG_INTDIR})
 803 else ()
 804         set (cmd ${cmd} -C ${CMAKE_BUILD_TYPE})
 805 endif ()
 806 add_custom_target (lyx_run_tests COMMAND ${cmd})
 807 set_target_properties(lyx_run_tests PROPERTIES FOLDER "tests")
 808
 809
 810 if(LYX_INSTALL)
 811         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 812                 message(STATUS "Python required to create doc!")
 813         else()
 814                 if(UNIX)
 815                         add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
 816                 endif()
 817                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
 818         endif()
 819         include(../Install)
 820 endif()
 821
 822 add_subdirectory(src "${TOP_BINARY_DIR}/src")
 823 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
 824 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
 825 add_subdirectory(lib/examples "${TOP_BINARY_DIR}/lib/examples")
 826 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
 827 add_subdirectory(development/autotests "${TOP_BINARY_DIR}/autotests")
 828 if(LYX_ENABLE_URLTESTS)
 829         add_subdirectory(development/checkurls "${TOP_BINARY_DIR}/checkurls")
 830 endif()
 831
 832 message(STATUS)
 833 message(STATUS "Build options, switch LYX_* variables by -DLYX_*=ON or OFF:")
 834 message(STATUS)
 835 LYX_OPTION_LIST_ALL(used)
 836
 837
 838 if(LYX_NLS)
 839         message(STATUS)
 840         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
 841         message(STATUS)
 842         message(STATUS "  * iconv")
 843         message(STATUS "     - header : ${ICONV_HEADER}")
 844         message(STATUS "     - library: ${ICONV_LIBRARY}")
 845         message(STATUS "  * zlib")
 846         message(STATUS "     - header : ${ZLIB_HEADER}")
 847         message(STATUS "     - library: ${ZLIB_LIBRARY}")
 848         message(STATUS)
 849 endif()
 850
 851 if(NOT Spelling_FOUND)
 852   if(LYX_REQUIRE_SPELLCHECK)
 853     set(_mode "FATAL_ERROR")
 854   else()
 855     set(_mode "STATUS")
 856   endif()
 857   message(${_mode} "No spellcheck libraries found. Lyx will be unable use spellchecking")
 858 endif()
 859
 860 include("${TOP_CMAKE_PATH}/LyxPackaging.cmake")
 861
 862 if(ENABLE_DIST)
 863   # Use git to create the source package
 864   # git archive --format=tgz --output=/home/kornel/x.tar.gz master
 865   if(UNIX)
 866     set(DIST_FORMAT tgz)
 867   else()
 868     set(DIST_FORMAT zip)
 869   endif()
 870   set(DIST_NAME ${CMAKE_PROJECT_NAME}-${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}-${CMAKE_SYSTEM_NAME}.${DIST_FORMAT})
 871
 872   add_custom_command(
 873     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME}
 874     COMMAND  ${LYX_GITVERSION} archive --format=${DIST_FORMAT} --output=${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME} master
 875     WORKING_DIRECTORY ${TOP_SRC_DIR})
 876   add_custom_target(git-archive DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME})
 877 endif()
 878
 879 # Last directory to be included so that the fixup code (OS X)
 880 # can be run last
 881 add_subdirectory(development/cmake/post_install)
 882
 883 message(STATUS)