CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 2.6.4)
   8
   9
  10 set(LYX_PROJECT lyx)
  11
  12 set(LYX_CMAKE_DIR "development/cmake")
  13 set(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/${LYX_CMAKE_DIR}/modules")
  14
  15 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README ABSOLUTE)
  16 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  17
  18 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  19
  20 message(STATUS)
  21 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  22         message(STATUS "Building in-source")
  23         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  24 else()
  25         message(STATUS "Building out-of-source")
  26         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  27 endif()
  28
  29
  30 if(COMMAND cmake_policy)
  31         cmake_policy(SET CMP0003 OLD)
  32         cmake_policy(SET CMP0005 OLD)
  33 endif()
  34
  35 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  36
  37 # Supress regeneration
  38 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  39
  40 if(NOT help AND NOT HELP)
  41         # 'project' triggers the searching for a compiler
  42         project(${LYX_PROJECT})
  43 endif()
  44
  45 include(LyXMacros)
  46
  47 # Usage LYX_OPTION
  48 # 1. parameter: option name without prefix 'LYX_'
  49 # 2. parameter: description
  50 # 3. parameter: default value, ON or OFF
  51 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
  52
  53
  54 LYX_OPTION_INIT()
  55
  56 # Options for all compilers/systems
  57 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
  58 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
  59 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
  60 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
  61 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
  62 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
  63 LYX_OPTION(DEVEL_VERSION    "Build developer version" OFF ALL)
  64 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" OFF ALL)
  65 LYX_OPTION(DEBUG            "Enforce debug build"  OFF ALL)
  66 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
  67 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
  68 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
  69 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
  70 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
  71 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
  72 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
  73 LYX_OPTION(EXTERNAL_LIBINTL "Use external libintl" ON ALL)
  74 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
  75
  76 # GCC specific
  77 LYX_OPTION(PROFILE              "Build profile version" OFF GCC)
  78 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" OFF GCC)
  79 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
  80 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
  81 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++pedantic debug mode" OFF GCC)
  82 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" OFF GCC)
  83 LYX_OPTION(CONCEPT_CHECKS       "Enable concept-checks" OFF GCC)
  84
  85 # MSVC specific
  86 LYX_OPTION(CONSOLE               "Show console on Windows" ON MSVC)
  87 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
  88 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
  89 LYX_OPTION(CONFIGURE_CHECKS      "Also run configure checks for MSVC" OFF MSVC)
  90 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
  91
  92 # APPLE specific
  93 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
  94 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
  95
  96
  97 if(help OR HELP)
  98         message(STATUS)
  99         message(STATUS "Available options: (dis/enable with -D=0/1)")
 100         message(STATUS)
 101         LYX_OPTION_LIST_ALL(help)
 102         message(STATUS)
 103 else()
 104
 105
 106 # Check option dependencies
 107
 108 if(LYX_CPACK)
 109         set(LYX_INSTALL ON)
 110 endif()
 111
 112 if(LYX_DMG)
 113         set(LYX_BUNDLE 1)
 114         set(LYX_CPACK 1)
 115 endif()
 116
 117 if(LYX_INSTALL)
 118         set(LYX_NLS ON)
 119         if (WIN32)
 120                 set(LYX_HUNSPELL ON)
 121                 message(STATUS "Configuring NSIS files")
 122                 configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 123                 configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 124                 configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 125                 message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 126         endif()
 127         set(LYX_CONSOLE OFF)
 128         set(LYX_PACKAGE_SUFFIX ON)
 129         set(LYX_RELEASE ON)
 130         set(LYX_PROFILE OFF)
 131 endif()
 132
 133
 134 if(LYX_MERGE_FILES)
 135         set(LYX_PCH OFF)
 136 else()
 137         set(LYX_MERGE_REBUILD OFF)
 138 endif()
 139
 140 if(LYX_DEPENDENCIES_DOWNLOAD)
 141         message(STATUS)
 142         set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 143         message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 144         set(deps_files lyx20-deps-msvc2010-x86.zip)
 145         foreach(it ${deps_files})
 146                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 147                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 148                 if(NOT already_downloaded)
 149                         message(STATUS "Downloading ${it} ...")
 150                         file(DOWNLOAD ftp://ftp.devel.lyx.org/pub/contrib/windows/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS)
 151                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 152                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 153                 endif()
 154         endforeach()
 155         set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/deps20)
 156 endif()
 157
 158
 159
 160 message(STATUS)
 161
 162 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 163 set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 164
 165
 166
 167 if(UNIX OR MINGW)
 168         execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION)
 169         message(STATUS "Using GCC version ${GCC_VERSION}")
 170         if(NOT GCC_VERSION VERSION_LESS 4.4)
 171                 set(LYX_USE_TR1 1)
 172                 # GCC <= 4.5 does not support regex: there are linker errors
 173                 # http://gcc.gnu.org/onlinedocs/libstdc++/manual/status.html#status.iso.tr1
 174                 set(LYX_USE_TR1_REGEX 0)
 175         endif()
 176 else()
 177         if(MSVC10)
 178                 set(LYX_USE_TR1 1)
 179                 #set(LYX_USE_TR1_REGEX 1) #TODO should we use it in ECMAScript mode?
 180         endif()
 181 endif()
 182
 183
 184 set(VERSION_INFO "CMake Build")
 185
 186 # Try to get some informations from configure.ac
 187
 188 include(LyXPaths)
 189 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 190
 191 if(WIN32)
 192         set(USE_WINDOWS_PACKAGING 1)
 193 elseif(APPLE)
 194         set(USE_MACOSX_PACKAGING 1)
 195 else()
 196         set(USE_POSIX_PACKAGING 1)
 197 endif()
 198
 199 macro(setstripped _varname _value)
 200         string(STRIP ${_value} _v)
 201         if(USE_POSIX_PACKAGING)
 202                 string(TOLOWER ${_v} ${_varname})
 203         else()
 204                 set(${_varname} ${_v})
 205         endif()
 206 endmacro(setstripped)
 207
 208 foreach(_c_l ${_config_lines} )
 209         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 210                 setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 211                 setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 212                 setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 213                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\).*$")
 214                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 215                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 216                         set(LYX_PATCH_VERSION 0) # TODO 2.1.0svn, LYX_PATCH_VERSION == 0
 217                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 218                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 219                         set(LYX_INSTALL_SUFFIX "${CMAKE_MATCH_1}.${CMAKE_MATCH_2}")
 220                 endif()
 221         endif()
 222         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 223                 set(LYX_DATE "${CMAKE_MATCH_1}")
 224         endif()
 225 endforeach(_c_l)
 226
 227
 228 if(LYX_PROGRAM_SUFFIX)
 229         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 230 else()
 231         set(PROGRAM_SUFFIX "")
 232 endif()
 233
 234
 235 if(LYX_BUNDLE)
 236         set(LYX_CPACK 1)
 237         message(STATUS)
 238         message(STATUS "Bundle creation is enabled (experimental):")
 239         message(STATUS "    make")
 240         message(STATUS "    make install/strip")
 241         message(STATUS "    make package")
 242         if(APPLE)
 243                 set(CPACK_GENERATOR DragNDrop)
 244                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 245                 set(LYX_DATA_SUBDIR ${PACKAGE_BASE}${PROGRAM_SUFFIX}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 246                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${PACKAGE_BASE}${PROGRAM_SUFFIX}.app)
 247                 if(NOT LYX_INSTALL_PREFIX)
 248                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 249                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 250                 endif()
 251         elseif(UNIX)
 252                 set(CPACK_GENERATOR STGZ)
 253                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 254                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 255                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 256         elseif(WIN32)
 257                 set(CPACK_GENERATOR ZIP)
 258                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 259         endif()
 260 endif()
 261
 262
 263 if(LYX_INSTALL_PREFIX)
 264         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 265         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 266 endif()
 267 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 268
 269 if(LYX_PACKAGE_SUFFIX)
 270         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 271 else()
 272         set(PACKAGE ${PACKAGE_BASE})
 273 endif()
 274
 275
 276
 277 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 278         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 279         if (UNIX)
 280                 # don't use the default "/usr/local"
 281                 # but respect the user-choice on the command-line
 282                 if(LYX_INSTALL_SUFFIX)
 283                         set(CMAKE_INSTALL_PREFIX "/usr/local/lyx${LYX_INSTALL_SUFFIX}" CACHE PATH "LyX default install prefix" FORCE)
 284                 else()
 285                         set(CMAKE_INSTALL_PREFIX "/usr/local/${LYX_PROJECT}" CACHE PATH "LyX default install prefix" FORCE)
 286                 endif()
 287         endif()
 288         if(WIN32)
 289                 set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 290         endif()
 291 endif()
 292 if(IS_ABSOLUTE)
 293         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 294 else()
 295         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 296 endif()
 297
 298
 299
 300 if(NOT LYX_DATA_SUBDIR)
 301         if (WIN32)
 302                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 303         else()
 304                 set(LYX_DATA_SUBDIR "" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 305         endif()
 306 endif()
 307
 308 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 309 set(LYX_LOCALEDIR "locale")
 310 set(LYX_ABS_INSTALLED_LOCALEDIR "${LYX_ABS_INSTALLED_DATADIR}/${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}")
 311 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 312
 313
 314
 315 if(NOT GROUP_CODE)
 316         #set(GROUP_CODE "The Golden Code")
 317         set(GROUP_CODE flat)
 318 endif()
 319
 320 # lyx's source files
 321 set(LYX_CPP_FILES *.cpp)
 322 set(LYX_HPP_FILES *.h)
 323 set(LYX_MOC_FILES moc_*.cpp)
 324
 325 include(ProjectSourceGroup)
 326
 327
 328 if(LYX_PROFILE)
 329         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 330         set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -pg" CACHE TYPE STRING FORCE)
 331 endif()
 332
 333
 334 if(LYX_NO_OPTIMIZE)
 335         set(CMAKE_BUILD_TYPE None)
 336         set(LYX_DEBUG OFF)
 337         set(LYX_RELEASE OFF)
 338 elseif(LYX_RELEASE)
 339         set(CMAKE_BUILD_TYPE Release)
 340         set(LYX_DEBUG OFF)
 341 else()
 342         set(CMAKE_BUILD_TYPE Debug)
 343 endif()
 344
 345
 346 # When shared libs are supported enable this option
 347 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 348 if(LYX_SHARED_LIBRARIES)
 349         set(library_type SHARED)
 350 else()
 351         set(library_type STATIC)
 352 endif()
 353
 354 if(NOT MSVC)
 355         if(NOT LYX_QUIET)
 356                 set(CMAKE_VERBOSE_MAKEFILE ON)
 357         endif()
 358         set(LYX_CXX_FLAGS "-Wall -Wunused-parameter")
 359         if(LYX_STDLIB_DEBUG)
 360                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 361         endif()
 362         if(LYX_CONCEPT_CHECKS)
 363                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCPP_CONCEPT_CHECKS")
 364         endif()
 365         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 366         set(CMAKE_CXX_FLAGS_DEBUG "${LYX_CXX_FLAGS} -fno-strict-aliasing -O0 -g -D_DEBUG" CACHE TYPE STRING FORCE)
 367         if(MINGW)
 368                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 369         else()
 370                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 371         endif()
 372         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg" CACHE TYPE STRING FORCE)
 373 endif()
 374
 375
 376 find_package(Qt4 REQUIRED)
 377
 378
 379 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 380
 381 if(LYX_ASPELL)
 382         find_package(ASPELL)
 383         include_directories(${ASPELL_INCLUDE_DIR})
 384 endif()
 385
 386 if(LYX_ENCHANT)
 387         find_package(Enchant REQUIRED)
 388         include_directories(${ENCHANT_INCLUDE_DIR})
 389 endif()
 390
 391 if(LYX_HUNSPELL)
 392         find_package(Hunspell REQUIRED)
 393         include_directories(${HUNSPELL_INCLUDE_DIR})
 394 endif()
 395
 396 if(LYX_NLS)
 397         FIND_PROGRAM(LYX_PYTHON_EXECUTABLE python HINTS ${GNUWIN32_DIR}/python)
 398         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 399                 message(FATAL_ERROR "Python 2.6 needed!")
 400         endif()
 401         find_package(LyXGettext REQUIRED)
 402         include_directories(${TOP_SRC_DIR}/po)
 403         add_subdirectory(po "${TOP_BINARY_DIR}/po")
 404 endif()
 405
 406 if(LYX_NLS)
 407         if(LYX_EXTERNAL_LIBINTL)
 408                 find_package(Libintl REQUIRED)
 409                 if(DEFINED LIBINTL_LIBRARIES)
 410                         # find getext when configuring
 411                         list(APPEND CMAKE_REQUIRED_LIBRARIES ${LIBINTL_LIBRARIES})
 412                         # on mac use iconv also form ports
 413                         get_filename_component(ICONV_RELATIVE_TO_LIBINTL ${LIBINTL_LIBRARIES} PATH)
 414                 endif()
 415         else()
 416                 add_subdirectory(intl "${TOP_BINARY_DIR}/intl")
 417         endif()
 418 endif()
 419
 420 find_package(ICONV REQUIRED)
 421 find_package(ZLIB REQUIRED)
 422
 423 if(LYX_EXTERNAL_BOOST)
 424         message(STATUS "Searching for boost")
 425         find_package(Boost COMPONENTS signals regex) #TODO could REQUIRED be used
 426         if(Boost_FOUND)
 427                 message(STATUS "Boost found")
 428                 message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 429                 set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 430         else()
 431                 message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 432         endif()
 433 else()
 434         if(LYX_USE_TR1_REGEX)
 435                 set(Lyx_Boost_Libraries boost_signals)
 436         else()
 437                 set(Lyx_Boost_Libraries boost_signals boost_regex)
 438         endif()
 439         add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 440         include_directories(${TOP_SRC_DIR}/boost)
 441         add_subdirectory(boost "${TOP_BINARY_DIR}/boost")
 442 endif()
 443
 444
 445
 446
 447 if(WIN32)
 448         if(NOT LYX_CONSOLE)
 449                 set(WIN32_CONSOLE WIN32)
 450                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARY})
 451         endif()
 452         if(MSVC)
 453                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 454                 # disable checked iterators for msvc release builds to get maximum speed
 455                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 456         else()
 457                 add_definitions(-DWINVER=0x0500)
 458         endif()
 459 endif()
 460
 461 message(STATUS "")
 462 foreach(_v PACKAGE PACKAGE_VERSION
 463         PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 464         LYX_ABS_TOP_SRCDIR
 465         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 466         if(NOT DEFINED ${_v})
 467                 message(FATAL_ERROR "${_v} not defined")
 468         endif()
 469         string(SUBSTRING "${_v}                            " 0 28 _v1)
 470         message(STATUS "----- ${_v1}: ${${_v}}")
 471 endforeach(_v)
 472 message(STATUS "")
 473
 474
 475 if(LYX_PCH)
 476         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 477         # Not sure if it works for all non-msvc compilers
 478         include(PCHSupport_26)
 479         configure_file(${TOP_SRC_DIR}/${LYX_CMAKE_DIR}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
 480         configure_file(${TOP_SRC_DIR}/${LYX_CMAKE_DIR}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 481         add_definitions(-DLYX_ENABLE_PCH)
 482
 483         if(MSVC)
 484                 macro(lyx_add_msvc_pch name_)
 485                         set_source_files_properties(${${name_}_sources} PROPERTIES
 486                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 487                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
 488                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 489                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
 490                                 ${TOP_BINARY_DIR}/pcheaders.h)
 491                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 492                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 493                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 494                 endmacro(lyx_add_msvc_pch)
 495                 macro(lyx_add_gcc_pch name_)
 496                 endmacro()
 497         else()
 498                 macro(lyx_add_msvc_pch name_)
 499                 endmacro()
 500                 macro(lyx_add_gcc_pch name_)
 501                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT4)
 502                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
 503                 endmacro()
 504         endif()
 505 else()
 506         macro(lyx_add_msvc_pch)
 507         endmacro(lyx_add_msvc_pch)
 508         macro(lyx_add_gcc_pch name_)
 509         endmacro()
 510 endif()
 511
 512 if(MSVC)
 513         if(LYX_VLD)
 514                 set(LYX_LEAK_DETECTION 1 CACHE TYPE STRING FORCE)
 515                 set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 516                 set(LYX_VLD_PATH ${CMAKE_CURRENT_SOURCE_DIR}/../Win32/vld)
 517                 include(${LYX_VLD_PATH}/tools/cmake/vld.cmake)
 518         endif()
 519
 520         if(LYX_WALL)
 521                 # Use the highest warning level
 522                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 523
 524                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 525                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 526                 else()
 527                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 528                 endif()
 529
 530                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 531                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 532                 else()
 533                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 534                 endif()
 535
 536                 # add here warnings which should produce an error /weXXXX
 537                 set(MSVC_W_ERROR   "/we4101 /we4189")
 538                 # add here warnings which should be disabled /wdXXXX
 539                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 540
 541                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 542                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 543                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 544
 545         else()
 546                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 547
 548                 # add here warnings which should produce an error /weXXXX
 549                 set(MSVC_W_ERROR   "/we4101 /we4189")
 550                 # add here warnings which should be disabled /wdXXXX
 551                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 552
 553                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 554                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 555                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 556
 557         endif()
 558         set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 559         set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 560         set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 561
 562         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 563         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 564         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 565         message(STATUS "")
 566 endif()
 567
 568
 569 if(LYX_DEBUG_GLIBC)
 570         set(_GLIBCXX_DEBUG 1)
 571 endif()
 572
 573 if(LYX_DEBUG_GLIBC_PEDANTIC)
 574         set(_GLIBCXX_DEBUG_PEDANTIC 1)
 575 endif()
 576
 577 # compiler tests, config.h generation
 578 if(MSVC AND NOT LYX_CONFIGURE_CHECKS)
 579         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.msvc ${TOP_BINARY_DIR}/configCompiler.h)
 580 else()
 581         include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
 582         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
 583 endif()
 584
 585 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
 586
 587
 588 add_subdirectory(src "${TOP_BINARY_DIR}/src")
 589 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
 590 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
 591
 592
 593 if(LYX_INSTALL)
 594         #FIND_PROGRAM(LYX_PERL_EXECUTABLE perl)
 595         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 596                 message(STATUS "Python required to create doc!")
 597         else()
 598                 add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
 599                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
 600         endif()
 601         include(../Install)
 602 endif()
 603
 604 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
 605
 606 message(STATUS)
 607 message(STATUS "Build options, switch LYX_* variables by -DLYX_*=1 or 0:")
 608 message(STATUS)
 609 LYX_OPTION_LIST_ALL(used)
 610
 611
 612 if(LYX_NLS)
 613         message(STATUS)
 614         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
 615         message(STATUS)
 616         message(STATUS "  * intl")
 617         message(STATUS "     - header : ${LIBINTL_HEADER}")
 618         message(STATUS "     - library: ${LIBINTL_LIBRARIES}")
 619         message(STATUS "  * iconv")
 620         message(STATUS "     - header : ${ICONV_HEADER}")
 621         message(STATUS "     - library: ${ICONV_LIBRARY}")
 622         message(STATUS "  * zlib")
 623         message(STATUS "     - header : ${ZLIB_HEADER}")
 624         message(STATUS "     - library: ${ZLIB_LIBRARY}")
 625         message(STATUS)
 626 endif()
 627
 628
 629 # CPack packaging
 630 #
 631 # http://cmake.org/cmake/help/cmake-2-8-docs.html#module:CPack
 632
 633 set(CPACK_PACKAGE_VERSION_MAJOR "${LYX_MAJOR_VERSION}")
 634 set(CPACK_PACKAGE_VERSION_MINOR "${LYX_MINOR_VERSION}")
 635 FILE(STRINGS "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}/LyX_summary.txt" CPACK_PACKAGE_DESCRIPTION_SUMMARY)
 636
 637 set(CPACK_SOURCE_GENERATOR TGZ ZIP TBZ2)
 638 set(CPACK_SOURCE_INSTALLED_DIRECTORIES "${TOP_SRC_DIR};/") # http://www.mail-archive.com/cmake@cmake.org/msg33720.html
 639
 640 set(CPACK_PACKAGE_INSTALL_DIRECTORY "CMake ${LYX_INSTALL_SUFFIX}")
 641
 642 set(CPACK_SOURCE_GENERATOR TGZ ZIP TBZ2)
 643 set(CPACK_SOURCE_INSTALLED_DIRECTORIES "${TOP_SRC_DIR};/") # http://www.mail-archive.com/cmake@cmake.org/msg33720.html
 644 #
 645 # needed by rpm
 646 set(CPACK_SET_DESTDIR "ON")
 647 FILE(READ "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}/LyX_license.txt" CPACK_RPM_PACKAGE_LICENSE)
 648 set(CPACK_RPM_PACKAGE_GROUP "Applications/Publishing")
 649 set(CPACK_RPM_PACKAGE_VENDOR "The LyX team")
 650 #
 651 # the next ones are needed by deb
 652 set(CPACK_PACKAGE_CONTACT "${PACKAGE_BUGREPORT}")
 653 set(CPACK_SOURCE_PACKAGE_FILE_NAME "${LYX_PROJECT}-${LYX_INSTALL_SUFFIX}")
 654
 655 # This is experimental, valid on _my_ system (Kornel)
 656 set(CPACK_DEBIAN_PACKAGE_DEPENDS "libqtgui4 (>= 4.4.3-0)")
 657 if(ASPELL_FOUND)
 658         set(CPACK_DEBIAN_PACKAGE_DEPENDS "libaspell15 (>= 0.60.6-1),${CPACK_DEBIAN_PACKAGE_DEPENDS}")
 659 endif()
 660 if(ENCHANT_FOUND)
 661         set(CPACK_DEBIAN_PACKAGE_DEPENDS "libenchant1c2a (>= 1.6.0-0),${CPACK_DEBIAN_PACKAGE_DEPENDS}")
 662 endif()
 663 if(LYX_EXTERNAL_BOOST)
 664         if(Boost_FOUND)
 665                 set(CPACK_DEBIAN_PACKAGE_DEPENDS "libboost-regex1.40.0 (>= 1.40.0-4),libboost-signals1.40.0 (>= 1.40.0-4),${CPACK_DEBIAN_PACKAGE_DEPENDS}")
 666         endif()
 667 endif()
 668 #
 669 # for the next ones, cpack insists on data with values in some file
 670 set(CPACK_PACKAGE_DESCRIPTION_FILE "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}/LyX_description.txt")
 671 set(CPACK_RESOURCE_FILE_LICENSE "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}/LyX_license.txt")
 672
 673 # Find the revision number and use it as the release in rpm-package-build.
 674 # This way we may omit the otherwise needed "--force" parameter when
 675 # installing from that rpm package.
 676 FIND_PROGRAM(LYX_SVNVERSION svnversion)
 677 #message(STATUS "svnversion = ${LYX_SVNVERSION}")
 678 if(LYX_SVNVERSION)
 679         EXECUTE_PROCESS(COMMAND ${LYX_SVNVERSION} WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE CPACK_RPM_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 680         # We use this value also to set the package-patch-value
 681         if(CPACK_RPM_PACKAGE_RELEASE MATCHES "^\([0-9]+\)")
 682                 set(CPACK_PACKAGE_VERSION_PATCH ${CMAKE_MATCH_1}) # TODO this is not the patch level
 683                 set(LYX_REVISION_VERSION ${CMAKE_MATCH_1})
 684         endif()
 685 else()
 686         set(LYX_REVISION_VERSION svn) #TODO use date
 687 endif()
 688
 689
 690 # we do not have a readme or welcome data,
 691 # so we do not provide infofiles for
 692 # CPACK_RESOURCE_FILE_README and CPACK_RESOURCE_FILE_WELCOME
 693
 694 if(UNIX)
 695         set(CPACK_SOURCE_GENERATOR TGZ TBZ2)
 696 elseif(WIN32)
 697         set(CPACK_SOURCE_GENERATOR ZIP)
 698 endif()
 699
 700
 701 set(CPACK_STRIP_FILES 1)
 702
 703 # sources
 704 set(CPACK_SOURCE_INSTALLED_DIRECTORIES "${TOP_SRC_DIR};/") # http://www.mail-archive.com/cmake@cmake.org/msg33720.html
 705
 706
 707
 708 if(LYX_CPACK)
 709         include(CPack)
 710 endif()
 711
 712
 713 #Now it is possible to create some packages
 714 # cd <BuildDir>
 715 # make package
 716 #############################################################################################
 717 # So, e.g. for variables
 718 #    CMAKE_PROJECT_NAME                     : lyx
 719 #    CPACK_PACKAGE_VERSION_MAJOR            : 2
 720 #    CPACK_PACKAGE_VERSION_MINOR            : 0
 721 #    CPACK_PACKAGE_VERSION_PATCH            : 1
 722 #    CMAKE_SYSTEM_NAME                      : Linux
 723 #    CPACK_BINARY_DEB:BOOL                  : ON
 724 #
 725 # the package name builds as "lyx-2.0.1-Linux.deb"
 726 #
 727 ############################## rpm ################################### deb ##################
 728 # create    # cpack -G RPM --config CPackConfig.cmake   # cpack -G DEB --config CPackConfig.cmake
 729 # creates =># lyx-2.0.1-Linux.rpm                       # lyx-2.0.1-Linux.deb
 730 # list      # rpm -qlp lyx-2.0.1-Linux.rpm              # dpkg-deb -c lyx-2.0.1-Linux.deb
 731 # install   # rpm -U lyx-2.0.1-Linux.rpm                # dpkg -i lyx-2.0.1-Linux.deb
 732 #
 733 message(STATUS)
 734
 735 endif() #help
 736