CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 3.1.0)
   8
   9 set(CMAKE_CXX_STANDARD 20)
  10 set(GNUWIN32_DIR D:/LyX/lyx-unstable/lyx-windows-deps-msvc2017)
  11 set(LYX_USE_QT "QT5")
  12 set(LYX_REQUIRE_SPELLCHECK true)
  13
  14 set(LYX_PROJECT LyX)
  15
  16 # Instruct cmake to not use gnu extensions,
  17 # this prevents the mix of '-std=c++*' and '-std=gnu++*' flags
  18 set(CMAKE_CXX_EXTENSIONS OFF)
  19
  20 enable_testing()
  21
  22 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README REALPATH) # Resolve symlinks
  23 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  24 message(STATUS "TOP_SRC_DIR = ${TOP_SRC_DIR}")
  25
  26 set(LYX_CMAKE_DIR "development/cmake")
  27 set(TOP_CMAKE_PATH "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}")
  28 set(TOP_MODULE_PATH "${TOP_CMAKE_PATH}/modules")
  29 set(TOP_SCRIPT_PATH "${TOP_CMAKE_PATH}/scripts")
  30
  31 set(CMAKE_MODULE_PATH "${TOP_MODULE_PATH}")
  32
  33 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  34
  35 message(STATUS)
  36 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  37         message(STATUS "Building in-source")
  38         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  39 else()
  40         message(STATUS "Building out-of-source")
  41         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  42 endif()
  43
  44 # This directory should be used if some test uses lyx-executable
  45 set(LYX_TESTS_USERDIR "${TOP_BINARY_DIR}/Testing/.lyx")
  46 file(MAKE_DIRECTORY "${LYX_TESTS_USERDIR}")
  47
  48 if(COMMAND cmake_policy)
  49         # Installing MACOSX_BUNDLE targets requires a BUNDLE DESTINATION
  50         cmake_policy(SET CMP0006 NEW)
  51         if(POLICY CMP0043)
  52                 # COMPILE_DEFINITIONS are not used yet. Enable new behavior.
  53                 cmake_policy(SET CMP0043 NEW)
  54         endif()
  55         cmake_policy(SET CMP0020 NEW)
  56         if(POLICY CMP0075)
  57                 cmake_policy(SET CMP0075 NEW)
  58         endif()
  59 endif()
  60
  61 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  62
  63 # Supress regeneration
  64 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  65
  66 if(LYX_XMINGW)
  67     set(CMAKE_SYSTEM_NAME Windows)
  68     set(TOOLNAME ${LYX_XMINGW})
  69     set(TOOLCHAIN "${TOOLNAME}-")
  70     set(CMAKE_C_COMPILER   "${TOOLCHAIN}gcc"     CACHE PATH "Mingw C compiler" FORCE)
  71     set(CMAKE_CXX_COMPILER "${TOOLCHAIN}g++"     CACHE PATH "Mingw C++ compiler" FORCE)
  72     set(CMAKE_RC_COMPILER  "${TOOLCHAIN}windres" CACHE PATH "Mingw rc compiler" FORCE)
  73
  74     set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM BOTH)
  75     set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY)
  76     set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY)
  77 endif()
  78
  79 if(NOT help AND NOT HELP)
  80   # 'project' triggers the searching for a compiler
  81   project(${LYX_PROJECT})
  82   if (CMAKE_COMPILER_IS_GNUCXX)
  83     if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS "4.0")
  84       message(STATUS "Gnu CXX compiler version = ${CMAKE_CXX_COMPILER_VERSION}")
  85       message(STATUS "is too old, should be >= 4.0")
  86       message(FATAL_ERROR "Exiting")
  87     endif()
  88   endif()
  89 endif()
  90
  91 if(UNIX)
  92         set(ARCH_TRIPLET )
  93         FIND_PROGRAM(DPKG_ARCHITECTURE_EXECUTABLE dpkg-architecture)
  94         if(DPKG_ARCHITECTURE_EXECUTABLE)
  95                 EXECUTE_PROCESS(COMMAND ${DPKG_ARCHITECTURE_EXECUTABLE} -qDEB_HOST_MULTIARCH
  96                                 OUTPUT_VARIABLE ARCH_TRIPLET
  97                                 ERROR_VARIABLE ERROR_ARCH_TRIPLET
  98                                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  99         endif()
 100 endif()
 101 if(ARCH_TRIPLET)
 102         set(SYSTEM_LIB_DIRS /usr/lib /usr/lib/${ARCH_TRIPLET} /usr/local/lib)
 103 else()
 104         set(SYSTEM_LIB_DIRS /usr/lib /usr/local/lib)
 105 endif()
 106
 107 include(LyXMacros)
 108 include(LyXDestinations)
 109
 110 # Try to get some informations from configure.ac
 111 include(LyXPaths)
 112
 113 # Value of USE_POSIX_PACKAGING is needed in determineversionandbuildtype()
 114 if(WIN32)
 115         set(CMAKE_PREFIX_PATH Specify-path-to-Qt CACHE PATH "Used Qt version")
 116         if(MSVC)
 117                 set(LYX_3RDPARTY_BUILD ON CACHE BOOL "Build 3rdparty libraries" FORCE)
 118         endif()
 119         set(USE_WINDOWS_PACKAGING ON)
 120 elseif(APPLE)
 121         set(USE_MACOSX_PACKAGING ON)
 122 else()
 123         set(USE_POSIX_PACKAGING ON)
 124 endif()
 125
 126 determineversionandbuildtype("${TOP_SRC_DIR}/configure.ac" _package_list _version_list _envlist LYX_DATE LYX_BUILD_TYPE)
 127 list(GET _package_list 0 PACKAGE_BASE)
 128 list(GET _package_list 1 PACKAGE_VERSION)
 129 list(GET _package_list 2 PACKAGE_BUGREPORT)
 130 list(GET _envlist 0 LYX_DIR_VER)
 131 list(GET _envlist 1 LYX_USERDIR_VER)
 132 list(GET _version_list 0 LYX_VERSION)
 133 list(GET _version_list 1 LYX_MAJOR_VERSION)
 134 list(GET _version_list 2 LYX_MINOR_VERSION)
 135 list(GET _version_list 3 LYX_RELEASE_LEVEL)
 136 list(GET _version_list 4 LYX_RELEASE_PATCH)
 137
 138 # Usage LYX_OPTION
 139 # 1. parameter: option name without prefix 'LYX_'
 140 # 2. parameter: description
 141 # 3. parameter: default value, ON or OFF
 142 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
 143
 144 # Usage LYX_COMBO
 145 # 1. parameter: name without prefix 'LYX_'
 146 # 2. parameter: description
 147 # 3. parameter: default value
 148 # 4-n parameter: possible other string values
 149
 150 LYX_OPTION_INIT()
 151 LYX_COMBO(ENABLE_BUILD_TYPE  "Allows to tweak the compiled code" AUTO release prerelease development gprof)
 152
 153 if(LYX_ENABLE_BUILD_TYPE MATCHES "AUTO")
 154   message(STATUS "Selecting build type defaults from configure.ac")
 155 else()
 156   set(LYX_BUILD_TYPE "${LYX_ENABLE_BUILD_TYPE}")
 157   message(STATUS "Selecting build type defaults from LYX_ENABLE_BUILD_TYPE")
 158 endif()
 159
 160 # Select some defaults depending on LYX_BUILD_TYPE
 161 # they can always be overwritten by the respective command line settings
 162 # These settings are only effective on fresh(==empty) CMakeCache.txt
 163 if(LYX_BUILD_TYPE STREQUAL "development")
 164   set(DefaultLyxDebug ON)
 165   set(DefaultLyxRelease OFF)
 166   set(DefaultLyxStdlibDebug ON)
 167   set(DefaultLyxEnableAssertions ON)
 168   set(DefaultLyxProfile OFF)
 169   set(DefaultExternalLibs OFF)
 170 elseif(LYX_BUILD_TYPE STREQUAL "prerelease")
 171   set(DefaultLyxDebug OFF)
 172   set(DefaultLyxRelease OFF)
 173   set(DefaultLyxStdlibDebug OFF)
 174   set(DefaultLyxEnableAssertions OFF)
 175   set(DefaultLyxProfile OFF)
 176   set(DefaultExternalLibs ON)
 177 elseif(LYX_BUILD_TYPE STREQUAL "release")
 178   set(DefaultLyxDebug OFF)
 179   set(DefaultLyxRelease ON)
 180   set(DefaultLyxStdlibDebug OFF)
 181   set(DefaultLyxEnableAssertions OFF)
 182   set(DefaultLyxProfile OFF)
 183   set(DefaultExternalLibs ON)
 184 elseif(LYX_BUILD_TYPE STREQUAL "gprof")
 185   set(DefaultLyxDebug ON)
 186   set(DefaultLyxRelease OFF)
 187   set(DefaultLyxStdlibDebug OFF)
 188   set(DefaultLyxEnableAssertions OFF)
 189   set(DefaultLyxProfile ON)
 190   set(DefaultExternalLibs OFF)
 191 else()
 192   message(FATAL_ERROR "Invalid build type (${LYX_BUILD_TYPE}) encountered")
 193 endif()
 194
 195 # Options for all compilers/systems
 196 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
 197 LYX_OPTION(LOCALVERSIONING  "Add version info to created package name (only used if LYX_CPACK option set)" OFF ALL)
 198 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
 199 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
 200 LYX_OPTION(REQUIRE_SPELLCHECK "Abort if no spellchecker available" OFF ALL)
 201 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
 202 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
 203 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
 204 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" ${DefaultLyxRelease} ALL)
 205 LYX_OPTION(DEBUG            "Enforce debug build"  ${DefaultLyxDebug} ALL)
 206 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
 207 LYX_OPTION(ENABLE_ASSERTIONS "Run sanity checks in the program"  ${DefaultLyxEnableAssertions} ALL)
 208 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
 209 LYX_STRING(SUFFIX_VALUE     "Use this string as suffix" "")
 210 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
 211 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
 212 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
 213 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
 214 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
 215 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
 216 LYX_OPTION(ENABLE_URLTESTS  "Enable for URL tests" OFF ALL)
 217 LYX_OPTION(ENABLE_EXPORT_TESTS "Enable for export tests" OFF ALL)
 218 LYX_OPTION(ENABLE_KEYTESTS  "Enable for keytests" OFF ALL)
 219 if (NOT CMAKE_VERSION VERSION_LESS "3.17")
 220   LYX_OPTION(ENABLE_VALGRIND_TESTS  "Enable for tests involving valgrind" OFF ALL)
 221 else()
 222   if (LYX_ENABLE_VALGRIND_TESTS)
 223     unset(LYX_ENABLE_VALGRIND_TESTS CACHE)
 224   endif()
 225 endif()
 226 LYX_OPTION(ASAN             "Use address sanitizer" OFF ALL)
 227 #LYX_COMBO(USE_FILEDIALOG    "Use native or QT file dialog" QT NATIVE)
 228 LYX_COMBO(USE_QT            "Use Qt version as frontend" AUTO QT4 QT5)
 229 LYX_COMBO(USE_IPO           "Interprocedural optimization" OFF AUTO ON)
 230 #LYX_OPTION(3RDPARTY_BUILD   "Build 3rdparty libs" OFF ALL)
 231 LYX_OPTION(DISABLE_CALLSTACK_PRINTING "do not print a callstack when crashing" OFF ALL)
 232 LYX_OPTION(EXTERNAL_Z       "OFF := Build 3rdparty lib zlib" ${DefaultExternalLibs} ALL)
 233 LYX_OPTION(EXTERNAL_DTL     "OFF := Build 3rdparty commands dt2dv and dv2dt" ${DefaultExternalLibs} ALL)
 234 LYX_OPTION(EXTERNAL_ICONV   "OFF := Build 3rdparty lib iconvlib" ${DefaultExternalLibs} ALL)
 235 LYX_OPTION(EXTERNAL_HUNSPELL "OFF := Build 3rdparty lib hunspelllib" ${DefaultExternalLibs} ALL)
 236 LYX_COMBO(EXTERNAL_MYTHES   "OFF := Build 3rdparty lib mytheslib" AUTO OFF ON)
 237
 238 # GCC specific
 239 LYX_OPTION(PROFILE              "Build with options for gprof" ${DefaultLyxProfile} GCC)
 240 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" ${DefaultExternalLibs} GCC)
 241 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
 242 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
 243 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++ pedantic debug mode" OFF GCC)
 244 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" ${DefaultLyxStdlibDebug} GCC)
 245
 246 # MSVC specific
 247 LYX_OPTION(CONSOLE               "Show console on Windows" ON MSVC)
 248 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
 249 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
 250 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
 251
 252 # APPLE specific
 253 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
 254 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
 255
 256
 257 if(help OR HELP)
 258         message(STATUS)
 259         message(STATUS "Available options: (dis/enable with -DLYX_*=OFF/ON)")
 260         message(STATUS)
 261         LYX_OPTION_LIST_ALL(help)
 262         message(STATUS)
 263         RETURN()
 264 endif()
 265
 266 if ("${LYX_SUFFIX_VALUE}" MATCHES "")
 267   set(LYX_INSTALL_SUFFIX "${LYX_MAJOR_VERSION}.${LYX_MINOR_VERSION}")
 268 else()
 269   set(LYX_INSTALL_SUFFIX "${LYX_SUFFIX_VALUE}")
 270 endif()
 271
 272 # Check option dependencies
 273 if (LYX_ENABLE_VALGRIND_TESTS)
 274         find_program(VALGRIND_EXECUTABLE "valgrind")
 275         if (NOT VALGRIND_EXECUTABLE)
 276                 message(FATAL_ERROR "Cannot use valgrind tests, executable valgrind is missing. Please disable LYX_ENABLE_VALGRIND_TESTS")
 277         endif()
 278 endif()
 279 if (LYX_DEBUG_GLIBC OR LYX_DEBUG_GLIBC_PEDANTIC OR LYX_STDLIB_DEBUG)
 280   if (LYX_EXTERNAL_BOOST)
 281     message(FATAL_ERROR "Using external boost not compatible with debug mode for stdlib")
 282   endif()
 283 endif()
 284
 285 if(LYX_DMG)
 286         set(LYX_BUNDLE ON)
 287         set(LYX_CPACK ON)
 288 endif()
 289
 290 if(LYX_CPACK)
 291         set(LYX_INSTALL ON)
 292 endif()
 293
 294 if(LYX_INSTALL)
 295         set(LYX_NLS ON)
 296         if(WIN32 AND NOT MINGW)
 297                 set(LYX_HUNSPELL ON)
 298         endif()
 299         set(LYX_PACKAGE_SUFFIX ON)
 300         if(NOT LYX_DEBUG)
 301                 set(LYX_RELEASE ON)
 302         endif()
 303         set(LYX_PROFILE OFF)
 304 endif()
 305
 306
 307 if(LYX_MERGE_FILES)
 308         set(LYX_PCH OFF)
 309 else()
 310         set(LYX_MERGE_REBUILD OFF)
 311 endif()
 312
 313 if(LYX_DEPENDENCIES_DOWNLOAD)
 314         message(STATUS)
 315         if(MSVC14)
 316                 set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2015-deps)
 317                 set(deps_files lyx-windows-deps-msvc2015.zip)
 318                 set(deps_server http://ftp.lyx.de/LyX-Windows-Deps)
 319                 set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2015)
 320         elseif(MSVC10)
 321                 set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 322                 set(deps_files lyx-windows-deps-msvc2010.zip)
 323                 set(deps_server http://ftp.lyx.de/LyX-Windows-Deps)
 324                 set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2010)
 325         else()
 326                 message(FATAL_ERROR "error: no dependency package known for the selected MSVC version.")
 327         endif()
 328     message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 329         foreach(it ${deps_files})
 330                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 331                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 332                 if(NOT already_downloaded)
 333                         message(STATUS "Downloading ${it} ...")
 334                         file(DOWNLOAD ${deps_server}/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS STATUS status LOG log)
 335                         list(GET status 0 status_code)
 336                         list(GET status 1 status_string)
 337                         if(NOT status_code EQUAL 0)
 338                                 file(REMOVE ${LYX_DEPENDENCIES_DIR}/${it})
 339                                 message(FATAL_ERROR "error: downloading '${it}' failed. status_code: ${status_code}, status_string: ${status_string}. \nLog: ${log} ")
 340                         endif()
 341                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 342                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 343                 endif()
 344         endforeach()
 345 endif()
 346
 347 message(STATUS)
 348
 349 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 350 if(WIN32)
 351         set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 352 else()
 353         set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 354 endif()
 355
 356 set(LYX_IPO_SUPPORTED OFF)
 357 if (POLICY CMP0069)
 358   cmake_policy(SET CMP0069 NEW)
 359   if(LYX_USE_IPO MATCHES "AUTO")
 360     # Enable LTO if supported and not debugging
 361     if (NOT LYX_DEBUG)
 362       include(CheckIPOSupported)
 363       check_ipo_supported(RESULT LYX_IPO_SUPPORTED)
 364     endif()
 365   else()
 366     set(LYX_IPO_SUPPORTED ${LYX_USE_IPO})
 367   endif()
 368 endif()
 369 if (LYX_IPO_SUPPORTED)
 370   set(LYX_USE_IPO "ON" CACHE STRING "Use interprocedural optimization" FORCE)
 371 else()
 372   set(LYX_USE_IPO "OFF" CACHE STRING "Use interprocedural optimization" FORCE)
 373 endif()
 374
 375 # Set to some meaningful default
 376 find_package(CXX11Compiler)
 377 if(NOT CXX11COMPILER_FOUND)
 378         message(FATAL_ERROR "A C++11 compatible compiler is required.")
 379 endif()
 380 unset(LYX_GCC11_MODE)
 381 if(UNIX OR MINGW)
 382         if (CMAKE_CXX_COMPILER_ID MATCHES "^([cC]lang|AppleClang)$")
 383           # ignore the GCC_VERSION for clang
 384           # and use the resulting CXX11_STD_REGEX found in FindCXX11Compiler.cmake
 385           message(STATUS "Using clang")
 386           if(CXX11_STD_REGEX)
 387             set(LYX_USE_STD_REGEX 1)
 388           else()
 389             set(LYX_USE_STD_REGEX 0)
 390           endif()
 391         else()
 392           execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpfullversion OUTPUT_VARIABLE GCC_VERSION ERROR_VARIABLE _error RESULT_VARIABLE _err OUTPUT_STRIP_TRAILING_WHITESPACE)
 393           #message(STATUS "dumpfullversion: error = ${_error}, result = ${_err}")
 394           if (_err)
 395             # previous check failed, try again with _old_ parameter
 396             execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION ERROR_VARIABLE _error RESULT_VARIABLE _err OUTPUT_STRIP_TRAILING_WHITESPACE)
 397             #message(STATUS "dumpversion: error = ${_error}, result = ${_err}")
 398           endif()
 399           message(STATUS "Using GCC version ${GCC_VERSION}")
 400           if(GCC_VERSION VERSION_LESS 4.6)
 401                 message(FATAL_ERROR "gcc >= 4.6 is required.")
 402           elseif(GCC_VERSION VERSION_LESS 4.9)
 403                 # <regex> in gcc is unusable in versions less than 4.9.0
 404                 # see https://gcc.gnu.org/bugzilla/show_bug.cgi?id=53631
 405                 set(LYX_USE_STD_REGEX 0)
 406           else()
 407                 set(LYX_USE_STD_REGEX 1)
 408           endif()
 409         endif()
 410         set(LYX_GCC11_MODE "${CXX11_FLAG}")
 411 else()
 412         if(MSVC_VERSION LESS 1900)
 413                 # Drop support for msvc versions prior to 1900 (Visual Studio 2015)
 414                 message(FATAL_ERROR "Visual Studio >= 2015 is required.")
 415                 set(LYX_USE_STD_REGEX 0)
 416         else()
 417                 set(LYX_USE_STD_REGEX 1)
 418         endif()
 419 endif()
 420
 421 if(LYX_3RDPARTY_BUILD)
 422   # LYX_3RDPARTY_BUILD is not cached anymore, but for compatibility reasons
 423   # this enables the build of all 3rd_party libs
 424   set(LYX_EXTERNAL_Z        OFF CACHE BOOL "Build 3rdparty lib zlib"    FORCE)
 425   set(LYX_EXTERNAL_ICONV    OFF CACHE BOOL "Build 3rdparty iconvlib"    FORCE)
 426   set(LYX_EXTERNAL_HUNSPELL OFF CACHE BOOL "Build 3rdparty hunspelllib" FORCE)
 427   set(LYX_EXTERNAL_MYTHES   OFF CACHE STRING "Build 3rdparty mytheslib" FORCE)
 428 endif()
 429
 430 FIND_PROGRAM(LYX_GITVERSION git)
 431 #message(STATUS "gitversion = ${LYX_GITVERSION}")
 432 set(LYX_REVISION_VERSION ${LYX_RELEASE_LEVEL})
 433 set(LYX_PACKAGE_RELEASE "UNDEFINED")
 434 if(LYX_GITVERSION)
 435   if (LYX_LOCALVERSIONING)
 436     # Find the revision number for later use
 437     EXECUTE_PROCESS(COMMAND ${LYX_GITVERSION} describe --match 2.0.0 HEAD
 438       WORKING_DIRECTORY "${TOP_SRC_DIR}"
 439       RESULT_VARIABLE tmp_GIT_RESULT
 440       OUTPUT_VARIABLE tmp_LYX_PACKAGE_RELEASE
 441       ERROR_VARIABLE tmp_GIT_ERROR
 442       OUTPUT_STRIP_TRAILING_WHITESPACE)
 443     if (tmp_GIT_RESULT EQUAL 0)
 444       if (tmp_LYX_PACKAGE_RELEASE MATCHES "^2\\.0\\.0\\-\([0-9]+\)\\-\(.*\)$")
 445         set(LYX_PACKAGE_RELEASE ${CMAKE_MATCH_2})
 446         # We will add offset of 40000 to get appropriate value to
 447         # previous svn.
 448         # We use this value than also to set the package-patch-value
 449         MATH(EXPR tmp_REVISION_VERSION "(${CMAKE_MATCH_1}+40000)")
 450         set(LYX_REVISION_VERSION "${LYX_RELEASE_LEVEL}-${tmp_REVISION_VERSION}git")
 451         set(ENABLE_DIST ON)
 452       endif()
 453     endif()
 454   endif()
 455 endif()
 456 if (LYX_PACKAGE_RELEASE MATCHES "UNDEFINED")
 457   set(LYX_PACKAGE_RELEASE  "1")
 458   if (LYX_RELEASE_PATCH GREATER 0)
 459     set(LYX_REVISION_VERSION "${LYX_RELEASE_LEVEL}.${LYX_RELEASE_PATCH}")
 460   endif()
 461 endif()
 462
 463 # Set the programs (lyx, tex2lyx, etc.) suffix
 464 # When building an OS X bundle, we will append
 465 # the suffix only to the bundle, not to the programs
 466 set(PROGRAM_SUFFIX "")
 467 if(LYX_PROGRAM_SUFFIX AND NOT (APPLE AND LYX_BUNDLE))
 468         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 469 endif()
 470 set(_lyx "${PACKAGE_BASE}${PROGRAM_SUFFIX}")
 471 set(_tex2lyx tex2lyx${PROGRAM_SUFFIX})
 472 set(_convert lyxconvert${PROGRAM_SUFFIX})
 473
 474 add_custom_target(lyx_version ALL
 475   COMMAND ${CMAKE_COMMAND} -DTOP_SRC_DIR=${TOP_SRC_DIR} -DTOP_CMAKE_PATH=${TOP_CMAKE_PATH} -DTOP_BINARY_DIR=${TOP_BINARY_DIR} -DLYX_DATE=${LYX_DATE} -P ${TOP_SCRIPT_PATH}/LyXGetVersion.cmake
 476   )
 477 set_target_properties(lyx_version PROPERTIES FOLDER "applications")
 478
 479 # Default paths for installed utilities (tex2lyx, lyxclient, etc.)
 480 set(LYX_UTILITIES_INSTALL_PATH bin)
 481
 482 if(LYX_BUNDLE)
 483         set(LYX_CPACK ON)
 484
 485         message(STATUS)
 486         message(STATUS "Bundle creation is enabled (experimental):")
 487         message(STATUS "    make")
 488         message(STATUS "    make install/strip")
 489         message(STATUS "    make package")
 490         if(APPLE)
 491                 set(MACOSX_BUNDLE TRUE)
 492                 # This sets the bundle + executable names
 493                 set(_lyx "${PACKAGE_BASE}${LYX_INSTALL_SUFFIX}")
 494                 # This sets the Info.plist executable name
 495                 set(osx_bundle_program_name ${_lyx})
 496                 # Bundle name
 497                 set(LYX_BUNDLE_NAME ${_lyx})
 498
 499                 # This will contain the list of files that need to be included
 500                 # in the bundle and their location within the bundle
 501                 set(OSX_BUNDLE_FILES "${TOP_SRC_DIR}/development/MacOSX/LyX.sdef;${TOP_SRC_DIR}/development/MacOSX/LyXapp.icns;${CMAKE_BINARY_DIR}/lyxrc.dist")
 502                 set(OSX_BUNDLE_DIRS "Resources;Resources;Resources")
 503
 504                 # Process Info.plist and lyxrc.dist
 505                 # See development/cmake/Install.cmake
 506                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/Info.plist.in" "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 507
 508                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 509                 set(LYX_DATA_SUBDIR ${LYX_BUNDLE_NAME}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 510
 511                 # Variables used by CPack
 512                 set(CPACK_BUNDLE_NAME ${LYX_BUNDLE_NAME})
 513                 set(CPACK_BUNDLE_PLIST "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 514                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${LYX_BUNDLE_NAME}.app)
 515
 516                 # Set the install paths
 517                 set(LYX_UTILITIES_INSTALL_PATH ${LYX_BUNDLE_NAME}.app/Contents/MacOS)
 518                 if(NOT LYX_INSTALL_PREFIX)
 519                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 520                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 521                 endif()
 522                 # Change the owner so that the install can work
 523                 install(CODE "set(BU_CHMOD_BUNDLE_ITEMS 1)" COMPONENT Runtime)
 524         elseif(UNIX)
 525                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 526                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 527                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 528         elseif(WIN32)
 529                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 530         endif()
 531 endif()
 532
 533 if(LYX_INSTALL_PREFIX)
 534         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 535         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 536 endif()
 537 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 538
 539 if(UNIX)
 540   set(SYSTEM_DATADIR "${CMAKE_INSTALL_PREFIX}/share")
 541 elseif(CMAKE_INSTALL_PREFIX MATCHES "/lyx${LYX_INSTALL_SUFFIX}$")
 542   string(REGEX REPLACE "/lyx${LYX_INSTALL_SUFFIX}$" "/share" SYSTEM_DATADIR ${CMAKE_INSTALL_PREFIX})
 543 else()
 544   set(SYSTEM_DATADIR "${CMAKE_INSTALL_PREFIX}")
 545 endif()
 546
 547 if(NOT CMAKE_COMPILER_IS_GNUCXX)
 548   # Not a GCC compiler, programs do not have a suffix
 549   set(suffixing ${LYX_PACKAGE_SUFFIX})
 550 elseif(WIN32 AND MINGW)
 551   # We want to use a suffix for the package in this case,
 552   # even if not for the program
 553   set(suffixing ${LYX_PACKAGE_SUFFIX})
 554 else()
 555   message(STATUS "CMAKE_COMPILER_IS_GNUCXX = ${CMAKE_COMPILER_IS_GNUCXX}")
 556   set(suffixing ${LYX_PROGRAM_SUFFIX})
 557 endif()
 558
 559 # The define PACKAGE below allows lyx-executable to find its default configuration files
 560 # see routines
 561 #    Package::messages_file()
 562 #    get_default_user_support_dir()
 563 #    relative_system_support_dir()
 564 # in src/support/Package.cpp
 565 if(suffixing)
 566         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 567 else()
 568         set(PACKAGE ${PACKAGE_BASE})
 569 endif()
 570
 571 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 572         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 573         if (UNIX)
 574                 # use the default "/usr/local"
 575                 # but respect the user-choice on the command-line
 576                 set(CMAKE_INSTALL_PREFIX "/usr/local" CACHE PATH "LyX default install prefix" FORCE)
 577         endif()
 578 endif()
 579 if(WIN32)
 580         set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 581 endif()
 582 if(IS_ABSOLUTE)
 583         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 584 else()
 585         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 586 endif()
 587
 588
 589
 590 if(NOT LYX_DATA_SUBDIR)
 591         if (WIN32)
 592                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 593         else()
 594                 set(LYX_DATA_SUBDIR "share/${_lyx}/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 595         endif()
 596 endif()
 597
 598 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}/${LYX_DATA_SUBDIR}")
 599 get_locale_destination(LYX_LOCALEDIR)
 600 set(LYX_ABS_INSTALLED_LOCALEDIR "${CMAKE_INSTALL_PREFIX}/${LYX_LOCALEDIR}")
 601 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 602
 603 if(LYX_BUNDLE AND APPLE)
 604         set(LYX_MAN_DIR_tmp "${LYX_DATA_SUBDIR}")
 605 else()
 606         if(WIN32)
 607                 set(LYX_MAN_DIR_tmp "${CMAKE_BINARY_DIR}/usr/local/man/")
 608         elseif(UNIX)
 609                 set(LYX_MAN_DIR_tmp "${CMAKE_INSTALL_PREFIX}/share/man/")
 610         else()
 611                 set(LYX_MAN_DIR_tmp "${CMAKE_INSTALL_PREFIX}/man/")
 612         endif()
 613 endif()
 614 if (NOT LYX_MAN_DIR_tmp EQUAL "${LYX_MAN_DIR}")
 615         unset(LYX_MAN_DIR CACHE)
 616         set(LYX_MAN_DIR "${LYX_MAN_DIR_tmp}" CACHE STRING "Install location for man pages.")
 617 endif()
 618 unset(LYX_MAN_DIR_tmp)
 619 mark_as_advanced(LYX_MAN_DIR)
 620
 621 # The Win installer cannot be built by CMake because one needs to install plugins for NSIS
 622 # see the Readme.txt of the installer
 623 #if(LYX_INSTALL AND WIN32)
 624 #       message(STATUS "Configuring NSIS files")
 625 #       configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 626 #       configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 627 #       configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 628 #       message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 629 #endif()
 630
 631 if(NOT GROUP_CODE)
 632         #set(GROUP_CODE "The Golden Code")
 633         set(GROUP_CODE flat)
 634 endif()
 635
 636 # lyx's source files
 637 set(LYX_CPP_FILES [a-zA-Z]*.cpp)
 638 set(LYX_HPP_FILES [a-zA-Z]*.h)
 639 set(LYX_MOC_FILES moc_*.cpp)
 640
 641 include(ProjectSourceGroup)
 642
 643
 644 if(LYX_PROFILE AND NOT MSVC)
 645         set(CMAKE_BUILD_TYPE Profile CACHE STRING "Profile build type" FORCE)
 646         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg")
 647         set(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS}  -pg")
 648 else()
 649         set(LYX_PROFILE OFF)
 650 endif()
 651
 652
 653 if(LYX_NO_OPTIMIZE)
 654         set(CMAKE_BUILD_TYPE None)
 655         set(LYX_DEBUG OFF)
 656         set(LYX_RELEASE OFF)
 657         set(LYX_PROFILE OFF)
 658 elseif(LYX_RELEASE)
 659         set(CMAKE_BUILD_TYPE Release)
 660         set(LYX_DEBUG OFF)
 661         set(LYX_PROFILE OFF)
 662 elseif(LYX_PROFILE)
 663         set(CMAKE_BUILD_TYPE Profile)
 664         set(LYX_DEBUG OFF)
 665 else()
 666         set(CMAKE_BUILD_TYPE Debug)
 667         set(LYX_DEBUG ON)
 668 endif()
 669
 670
 671 # When shared libs are supported enable this option
 672 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 673 if(LYX_SHARED_LIBRARIES)
 674         set(library_type SHARED)
 675 else()
 676         set(library_type STATIC)
 677 endif()
 678
 679 if(LYX_ENABLE_ASSERTIONS)
 680   set(LYX_CXX_FLAGS " -DENABLE_ASSERTIONS=1")
 681 else()
 682   set(LYX_CXX_FLAGS "")
 683 endif()
 684
 685 if(MSVC)
 686   if (CXX11_FLAG MATCHES "\\+\\+([0-9]+)")
 687     set(CMAKE_CXX_STANDARD ${CMAKE_MATCH_1})
 688     message(STATUS "CMAKE_CXX_STANDARD set to ${CMAKE_CXX_STANDARD}")
 689   endif()
 690   set(CMAKE_CXX_FLAGS       "${CMAKE_CXX_FLAGS}${LYX_CXX_FLAGS}")
 691 else()
 692         if(NOT LYX_QUIET)
 693                 set(CMAKE_VERBOSE_MAKEFILE ON)
 694         endif()
 695         if(LYX_GCC11_MODE MATCHES "\\+\\+([0-9][0-9])")
 696           # Thanks to Brad King <brad.king@kitware.com>
 697           # for the pointer to https://cmake.org/cmake/help/v3.6/variable/CMAKE_CXX_STANDARD.html
 698           # This allows us to use QT5.7 with recent g++ (version >= 4.9) compilers
 699           # and still use our own c++ extension tests
 700           set(CMAKE_CXX_STANDARD ${CMAKE_MATCH_1})
 701           message(STATUS "CMAKE_CXX_STANDARD set to ${CMAKE_CXX_STANDARD}")
 702           set(LYX_CXX_FLAGS "-Wall -Wunused-parameter ${LYX_CXX_FLAGS}")
 703         else()
 704           set(LYX_CXX_FLAGS "-Wall -Wunused-parameter ${LYX_GCC11_MODE}${LYX_CXX_FLAGS}")
 705         endif()
 706         if(LYX_STDLIB_DEBUG)
 707           set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 708         else()
 709           if(LYX_DEBUG_GLIBC)
 710             set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG")
 711           endif()
 712           if(LYX_DEBUG_GLIBC_PEDANTIC)
 713             set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG_PEDANTIC")
 714           endif()
 715         endif()
 716         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE STRING "Set CXX flags" FORCE)
 717         set(CMAKE_CXX_FLAGS_DEBUG "-O0 -g3 -D_DEBUG" CACHE STRING "Set debug flags" FORCE)
 718         if(MINGW)
 719                 set(CMAKE_CXX_FLAGS_RELEASE "-O2 -DNDEBUG" CACHE STRING "Set release flags for Mingw" FORCE)
 720         else()
 721                 set(CMAKE_CXX_FLAGS_RELEASE "-O3 -DNDEBUG" CACHE STRING "Set release flags" FORCE)
 722         endif()
 723 endif()
 724
 725 if(LYX_ASAN)
 726     set(CMAKE_CXX_FLAGS "-fsanitize=address -fno-omit-frame-pointer -g ${CMAKE_CXX_FLAGS}")
 727     message(STATUS)
 728     message(STATUS "Address sanitizer enabled. Usage:")
 729     message(STATUS "    wget https://llvm.org/svn/llvm-project/compiler-rt/trunk/lib/asan/scripts/asan_symbolize.py")
 730     message(STATUS "    chmod  +x ./asan_symbolize.py")
 731     message(STATUS "    ./bin/${_lyx} 2>&1 | ./asan_symbolize.py  | c++filt ")
 732     message(STATUS)
 733 endif()
 734
 735 set(LYX_CXX_FLAGS_EXTRA "" CACHE STRING "Desired semicolon separated list of extra cxx compile flags, like '-Werror'")
 736 mark_as_advanced(LYX_CXX_FLAGS_EXTRA)
 737 if(LYX_CXX_FLAGS_EXTRA)
 738         foreach(_flag ${LYX_CXX_FLAGS_EXTRA})
 739                 add_definitions(${_flag})
 740         endforeach()
 741 endif()
 742
 743 if(LYX_XMINGW)
 744         list(APPEND CMAKE_FIND_ROOT_PATH ${GNUWIN32_DIR})
 745 endif()
 746
 747 set(min_qt5_version "5.6")
 748 if(LYX_USE_QT MATCHES "AUTO")
 749         # try qt5 first
 750         find_package(Qt5Core CONFIG QUIET)
 751         if(Qt5Core_FOUND)
 752                 set(LYX_USE_QT "QT5" CACHE STRING "Valid qt version" FORCE)
 753                 message(STATUS "Qt5Core_VERSION = ${Qt5Core_VERSION}")
 754                 if(Qt5Core_VERSION VERSION_LESS ${min_qt5_version})
 755                         find_package(Qt4 "4.5.0" QUIET)
 756                         if(QT4_FOUND)
 757                                 set(LYX_USE_QT "QT4" CACHE STRING "Valid qt version" FORCE)
 758                         endif()
 759                 endif()
 760         else()
 761                 set(LYX_USE_QT "QT4" CACHE STRING "Valid qt version" FORCE)
 762         endif()
 763 endif()
 764 if(LYX_USE_QT MATCHES "QT5")
 765         # set QPA_XCB if QT uses X11
 766         find_package(Qt5Core CONFIG REQUIRED)
 767         if (Qt5Core_FOUND)
 768                 find_package(Qt5Widgets CONFIG REQUIRED)
 769                 if(APPLE)
 770                         find_package(Qt5MacExtras CONFIG REQUIRED)
 771                 endif()
 772                 find_package(Qt5X11Extras CONFIG QUIET)
 773                 find_package(Qt5WinExtras CONFIG QUIET)
 774                 set(QTVERSION ${Qt5Core_VERSION})
 775                 if (QTVERSION VERSION_LESS ${min_qt5_version})
 776                         message(STATUS "QTVERSION = \"${QTVERSION}\"")
 777                         message(STATUS "This version is not recommended, try either option -DLYX_USE_QT=QT4 or")
 778                         message(STATUS "install QT-Version >= \"${min_qt5_version}\"")
 779                         # see thread in lyx-devel list
 780                         # From: Jean-Pierre Chrétien <jeanpierre.chretien@free.fr>
 781                         # Date 11.03.2017
 782                         # Subject: cmake compilation error
 783                         #message(FATAL_ERROR "Wrong Qt-Version")
 784                 endif()
 785                 macro (qt_use_modules lyxtarget)
 786                         foreach (_tg ${ARGN})
 787                                 find_package(Qt5${_tg} CONFIG REQUIRED)
 788                                 target_link_libraries(${lyxtarget} Qt5::${_tg})
 789                         endforeach()
 790                 endmacro()
 791                 macro (qt_add_resources)
 792                         qt5_add_resources(${ARGN})
 793                 endmacro()
 794                 macro (qt_wrap_uifiles)
 795                         qt5_wrap_ui(${ARGN})
 796                 endmacro()
 797                 message(STATUS "Found Qt-Version ${QTVERSION}")
 798                 if(WIN32)
 799                         set(LYX_QTMAIN_LIBRARY ${Qt5Core_QTMAIN_LIBRARIES})
 800                 endif()
 801         endif()
 802 elseif(LYX_USE_QT MATCHES "QT4")
 803         if(LYX_XMINGW)
 804                 set(QT_MINGW_DIR ${LYX_QT4} CACHE PATH "Qt for Mingw" FORCE)
 805                 list(APPEND CMAKE_FIND_ROOT_PATH ${QT_MINGW_DIR} ${GNUWIN32_DIR})
 806         endif()
 807         find_package(Qt4 "4.5.0" REQUIRED)
 808         macro (qt_use_modules)
 809         endmacro()
 810         macro (qt_add_resources)
 811                 qt4_add_resources(${ARGN})
 812         endmacro()
 813         macro (qt_wrap_uifiles)
 814                 qt4_wrap_ui(${ARGN})
 815         endmacro()
 816         set(LYX_QTMAIN_LIBRARY ${QT_QTSVG_LIBRARY})
 817         if(WIN32)
 818                 list(APPEND LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARIES})
 819         endif()
 820 else()
 821   message(FATAL_ERROR "Unhandled value for LYX_USE_QT (${LYX_USE_QT})")
 822 endif()
 823
 824 find_package(Magic)
 825 if(Magic_FOUND)
 826   set(HAVE_MAGIC_H 1)
 827   include_directories(${Magic_INCLUDE_DIR})
 828 endif()
 829
 830 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 831
 832 set(Spelling_FOUND OFF)
 833 set(Include_used_spellchecker)   # String will be inserted into config.h
 834
 835 if (LYX_EXTERNAL_MYTHES MATCHES "AUTO")
 836   # try system library first
 837   find_package(MYTHESLIB)
 838   if (MYTHESLIB_FOUND)
 839     set(LYX_EXTERNAL_MYTHES ON CACHE STRING "OFF:= Build 3rdparty mytheslib" FORCE)
 840   else()
 841     set(LYX_EXTERNAL_MYTHES OFF CACHE STRING "OFF:= Build 3rdparty mytheslib" FORCE)
 842   endif()
 843 endif()
 844 if (LYX_EXTERNAL_MYTHES MATCHES "ON")
 845   find_package(MYTHESLIB REQUIRED)
 846 else()
 847   add_subdirectory(3rdparty/mythes)
 848 endif()
 849 set(MYTHES_DIR ${MYTHESLIB_INCLUDE_DIR})
 850
 851 if(NOT LYX_EXTERNAL_HUNSPELL)
 852     add_subdirectory(3rdparty/hunspell)
 853     add_definitions(-DHUNSPELL_STATIC)
 854     set(HUNSPELL_FOUND ON)
 855     message(STATUS "  * Hunspell:")
 856     message(STATUS "     - include: ${HUNSPELL_INCLUDE_DIR}")
 857     message(STATUS "     - library: ${HUNSPELL_LIBRARY}")
 858 endif()
 859
 860 foreach(_spell "ASPELL" "ENCHANT" "HUNSPELL")
 861   string(TOUPPER ${_spell} _upspell)
 862   if (NOT ${_upspell}_FOUND)
 863     find_package(${_spell})
 864   endif()
 865   if (${_upspell}_FOUND)
 866     include_directories(${${_upspell}_INCLUDE_DIR})
 867     set(Spelling_FOUND ON)
 868     message(STATUS "Building with USE_${_upspell}")
 869     set(Include_used_spellchecker "${Include_used_spellchecker}#define USE_${_upspell} 1\n")
 870   else()
 871     if(LYX_${_upspell})
 872       message(FATAL_ERROR "Required ${_spell} devel package not found")
 873     else()
 874       message(STATUS "${_upspell} not found, building without ${_spell} support")
 875     endif()
 876   endif()
 877 endforeach()
 878
 879 if(GNUWIN32_DIR)
 880         list(APPEND CMAKE_PROGRAM_PATH "${GNUWIN32_DIR}/Python" )
 881 endif()
 882
 883 # Search for python default version first
 884 unset(PYTHON_EXECUTABLE CACHE)
 885 unset(LYX_PYTHON_EXECUTABLE CACHE)
 886 unset(PYTHON_VERSION_MAJOR)
 887 unset(PYTHON_VERSION_MINOR)
 888 unset(PYTHON_VERSION_STRING)
 889 if (CMAKE_VERSION VERSION_LESS "3.13")
 890   find_package(PythonInterp 3.5 QUIET)
 891   if(NOT PYTHONINTERP_FOUND)
 892     find_package(PythonInterp 2.0 REQUIRED)
 893     if(NOT PYTHON_VERSION_STRING VERSION_LESS 2.8)
 894       message(FATAL_ERROR "Python interpreter found, but is not suitable")
 895     endif()
 896   endif()
 897   set(LYX_PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 898 else()
 899   find_package(Python3 3.5 QUIET)
 900   if(NOT Python3_Interpreter_FOUND)
 901     unset(PYTHON_EXECUTABLE CACHE)
 902     find_package(Python2 2.0 REQUIRED)
 903     if(NOT Python2_VERSION VERSION_LESS 2.8)
 904       message(FATAL_ERROR "Python interpreter found, but is not suitable")
 905     endif()
 906     set(LYX_PYTHON_EXECUTABLE ${Python2_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 907   else()
 908     set(LYX_PYTHON_EXECUTABLE ${Python3_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 909   endif()
 910 endif()
 911
 912 if(LYX_NLS)
 913         find_package(LyXGettext)
 914         if(LYX_PYTHON_EXECUTABLE AND GETTEXT_FOUND)
 915                 add_subdirectory(po "${TOP_BINARY_DIR}/po")
 916         else()
 917                 # Install only supplied .gmo-files
 918                 file(GLOB _gmofiles RELATIVE "${TOP_SRC_DIR}/po" "${TOP_SRC_DIR}/po/*.gmo")
 919                 message(STATUS "Installing provided .gmo-files only")
 920                 foreach( _gmo ${_gmofiles})
 921                         string(REGEX REPLACE "\\.gmo$" "" _lang ${_gmo})
 922                         install(FILES "${TOP_SRC_DIR}/po/${_gmo}" DESTINATION ${LYX_LOCALEDIR}/${_lang}/LC_MESSAGES RENAME ${PACKAGE}.mo)
 923                 endforeach()
 924         endif()
 925 endif()
 926
 927 if(LYX_EXTERNAL_ICONV)
 928   find_package(ICONV REQUIRED)
 929 else()
 930   add_subdirectory(3rdparty/libiconv)
 931   set(HAVE_ICONV_CONST 1)
 932 endif()
 933
 934 if(LYX_EXTERNAL_Z)
 935   find_package(ZLIB REQUIRED)
 936 else()
 937   add_subdirectory(3rdparty/zlib)
 938 endif()
 939
 940 if(NOT LYX_EXTERNAL_DTL)
 941   add_subdirectory(3rdparty/dtl)
 942 endif()
 943
 944 if(LYX_USE_STD_REGEX)
 945   # Set only include path.
 946   # Use internal boost, which is known to exist
 947   # we don't need any libraries
 948   set(Lyx_Boost_Libraries)
 949   add_definitions(-DBOOST_USER_CONFIG=<config.h>)
 950   include_directories(${TOP_SRC_DIR}/3rdparty/boost)
 951 else()
 952   # Using boost-regex
 953   if(LYX_EXTERNAL_BOOST)
 954     message(STATUS "Searching for external boost")
 955     find_package(Boost COMPONENTS regex)
 956     if(Boost_FOUND)
 957       message(STATUS "Boost found")
 958       message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 959       set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 960       if (LYX_STDLIB_DEBUG OR LYX_DEBUG_GLIBC OR LYX_DEBUG_GLIBC_PEDANTIC)
 961         # Comment from  Jean-Marc Lasgouttes:
 962         # In general, system boost libraries are incompatible with
 963         # the use of stdlib-debug in libstdc++. See ticket #9736 for
 964         # details.
 965         message(FATAL_ERROR "Compiling LyX with stdlib-debug and system boost libraries may lead to crashes. Consider using '-DLYX_STDLIB_DEBUG=OFF -DLYX_DEBUG_GLIBC=OFF -DLYX_DEBUG_GLIBC_PEDANTIC=OFF' or using '-DLYX_EXTERNAL_BOOST=OFF'")
 966       endif()
 967     else()
 968       message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 969     endif()
 970   else()
 971     # Using included boost
 972     set(Lyx_Boost_Libraries boost_regex)
 973     add_definitions(-DBOOST_USER_CONFIG=<config.h>)
 974     include_directories(${TOP_SRC_DIR}/3rdparty/boost)
 975     add_subdirectory(3rdparty/boost "${TOP_BINARY_DIR}/3rdparty/boost")
 976   endif()
 977 endif()
 978
 979 if(WIN32)
 980         if(LYX_CONSOLE)
 981                 set(LYX_QTMAIN_LIBRARY)
 982         else()
 983                 set(WIN32_CONSOLE WIN32)
 984         endif()
 985         if(MSVC)
 986                 # -DPSAPI_VERSION=1 is needed to run on vista (bug 10186)
 987                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX -DPSAPI_VERSION=1)
 988                 # disable checked iterators for msvc release builds to get maximum speed
 989                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 990         else()
 991                 # -DPSAPI_VERSION=1 is not needed for mingw, since the mingw psapi.h
 992                 # does not use it and always declares the vista compatible API.
 993                 # If this ever changes then -DPSAPI_VERSION might be needed here as well.
 994                 add_definitions(-DWINVER=0x0500)
 995         endif()
 996 endif()
 997
 998 # Compute qt-version from ${QTVERSION}
 999
1000 message(STATUS "")
1001 foreach(_v PACKAGE PACKAGE_VERSION
1002         PROGRAM_SUFFIX LYX_VERSION LYX_DIR_VER LYX_USERDIR_VER
1003         LYX_ABS_TOP_SRCDIR
1004         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
1005         if(NOT DEFINED ${_v})
1006                 message(FATAL_ERROR "${_v} not defined")
1007         endif()
1008         string(SUBSTRING "${_v}                            " 0 28 _v1)
1009         message(STATUS "----- ${_v1}: ${${_v}}")
1010 endforeach(_v)
1011 message(STATUS "")
1012
1013
1014 if(LYX_PCH)
1015         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
1016         # Not sure if it works for all non-msvc compilers
1017         include(PCHSupport_26)
1018         configure_file(${TOP_CMAKE_PATH}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
1019         configure_file(${TOP_CMAKE_PATH}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
1020         add_definitions(-DLYX_ENABLE_PCH)
1021
1022         if(MSVC)
1023                 macro(lyx_add_msvc_pch name_)
1024                         set_source_files_properties(${${name_}_sources} PROPERTIES
1025                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
1026                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
1027                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
1028                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
1029                                 ${TOP_BINARY_DIR}/pcheaders.h)
1030                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
1031                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
1032                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
1033                 endmacro(lyx_add_msvc_pch)
1034                 macro(lyx_add_gcc_pch name_)
1035                 endmacro()
1036         else()
1037                 macro(lyx_add_msvc_pch name_)
1038                 endmacro()
1039                 macro(lyx_add_gcc_pch name_)
1040                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT)
1041                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
1042                 endmacro()
1043         endif()
1044 else()
1045         macro(lyx_add_msvc_pch)
1046         endmacro(lyx_add_msvc_pch)
1047         macro(lyx_add_gcc_pch name_)
1048         endmacro()
1049 endif()
1050
1051
1052 if(MSVC)
1053
1054         if(LYX_VLD)
1055                 set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/development/Win32/vld)
1056                 add_subdirectory(${vld_path}/cmake)
1057                 include(${vld_path}/cmake/vld.cmake) # forced include
1058                 set(vld_dll vld)
1059         endif()
1060
1061         if(LYX_WALL)
1062                 # Use the highest warning level
1063                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE STRING "Warning level" FORCE)
1064
1065                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
1066                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
1067                 else()
1068                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
1069                 endif()
1070
1071                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
1072                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
1073                 else()
1074                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
1075                 endif()
1076
1077                 # add here warnings which should produce an error /weXXXX
1078                 set(MSVC_W_ERROR   "/we4101 /we4189")
1079                 # add here warnings which should be disabled /wdXXXX
1080                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
1081
1082                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /W4 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1083                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /W4 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1084                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /W4 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1085
1086         else()
1087                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE STRING "Warning level" FORCE)
1088
1089                 # add here warnings which should produce an error /weXXXX
1090                 set(MSVC_W_ERROR   "/we4101 /we4189")
1091                 # add here warnings which should be disabled /wdXXXX
1092                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
1093
1094                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1095                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1096                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1097
1098         endif()
1099
1100         if (NOT Qt5Core_FOUND)
1101                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
1102                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
1103                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
1104         endif()
1105
1106         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
1107         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
1108         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
1109         message(STATUS "")
1110 endif()
1111
1112
1113 # Xcode compiler
1114 if (CMAKE_GENERATOR MATCHES Xcode)
1115         if (XCODE_VERSION VERSION_LESS "5.0")
1116                 # Automatically select the Xcode compiler if not set
1117                 if (NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
1118                         # XCode >= 3.1 has gcc 4.2 (up to actual Xcode)
1119                         if (XCODE_VERSION VERSION_GREATER "3.1")
1120                                 SET(CMAKE_XCODE_ATTRIBUTE_GCC_VERSION "com.apple.compilers.llvmgcc42")
1121                         ENDIF(XCODE_VERSION VERSION_GREATER "3.1")
1122                 ENDIF(NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
1123                 # Print the selected compiler version
1124         MESSAGE(STATUS "---- Using XCode compiler CMAKE_XCODE_ATTRIBUTE_GCC_VERSION=${CMAKE_XCODE_ATTRIBUTE_GCC_VERSION}")
1125         ENDIF(XCODE_VERSION VERSION_LESS "5.0")
1126 ENDIF(CMAKE_GENERATOR MATCHES Xcode)
1127
1128 if (WIN32 AND Qt5Core_FOUND)
1129         set(Z_PREFIX 1)
1130 endif()
1131
1132 # compiler tests, config.h generation LYX_CONFIGURE_CHECKS
1133 include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
1134 configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
1135
1136 unset(opts)
1137 foreach(_option ${LYX_OPTIONS})
1138   if(${_option}_show_message)
1139     string(SUBSTRING "${_option}                            " 0 31 _var)
1140     get_property(_prop CACHE ${_option} PROPERTY STRINGS)
1141     list(FIND LYX_OPTION_STRINGS ${_option} _index)
1142     if (${_index} GREATER -1)
1143       set(_isset ${${_option}})
1144     elseif(${_option})
1145       set(_isset ON)
1146     else()
1147       set(_isset OFF)
1148     endif()
1149     string(SUBSTRING "${_isset}           " 0 10 _val)
1150     set(opts "${opts} ${_option}(${${_option}})")
1151   endif()
1152 endforeach()
1153 set(tmp_vi "CMake Build")
1154 list(APPEND tmp_vi "  Host name:               ${CMAKE_HOST_SYSTEM_NAME}")
1155 list(APPEND tmp_vi "  Host processor:          ${CMAKE_HOST_SYSTEM_PROCESSOR}")
1156 list(APPEND tmp_vi "  Build flags:             ${opts}")
1157 list(APPEND tmp_vi "  C++ Compiler:            ${CMAKE_CXX_COMPILER_ID} (${CMAKE_CXX_COMPILER_VERSION})")
1158 list(APPEND tmp_vi "  C++ Compiler flags:      ${CMAKE_CXX_FLAGS}")
1159 if (LYX_DEBUG)
1160 list(APPEND tmp_vi "  C++ Compiler user flags: ${CMAKE_CXX_FLAGS_DEBUG}")
1161 else()
1162 list(APPEND tmp_vi "  C++ Compiler user flags: ${CMAKE_CXX_FLAGS_RELEASE}")
1163 endif()
1164 list(APPEND tmp_vi "  Qt version:              ${QTVERSION}")
1165 list(APPEND tmp_vi "  LyX binary dir:          ${CMAKE_INSTALL_PREFIX}/${LYX_UTILITIES_INSTALL_PATH}")
1166 get_data_destination(dest_data)
1167 list(APPEND tmp_vi "  LyX files dir:           ${CMAKE_INSTALL_PREFIX}/${dest_data}")
1168 string(REPLACE ";" "\\n" VERSION_INFO "${tmp_vi}")
1169
1170 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
1171 unset(opts)
1172 unset(tmp_vi)
1173
1174 if(QTVERSION MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+).*")
1175         MATH(EXPR QT4_VERSION "(${CMAKE_MATCH_1}<<16)|(${CMAKE_MATCH_2}<<8)|${CMAKE_MATCH_3}")
1176 endif()
1177
1178 if (NOT HAVE_REGEX)
1179         set(LYX_USE_STD_REGEX 0)
1180 endif()
1181
1182
1183 set (cmd ${CMAKE_CTEST_COMMAND})
1184 if (MSVC)
1185         set (cmd ${cmd} -C ${CMAKE_CFG_INTDIR})
1186 else ()
1187         set (cmd ${cmd} -C ${CMAKE_BUILD_TYPE})
1188 endif ()
1189 add_custom_target (lyx_run_tests COMMAND ${cmd})
1190 set_target_properties(lyx_run_tests PROPERTIES FOLDER "tests")
1191
1192 if(LYX_INSTALL)
1193         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
1194                 message(STATUS "Python required to create doc!")
1195         else()
1196                 if(UNIX)
1197                         add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
1198                 endif()
1199                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
1200         endif()
1201 endif()
1202 include(../Install)
1203
1204 # By running the URL tests first, time can be saved when running the ctests in
1205 # parallel since the URL tests take a long time to run (e.g. 10 minutes).
1206 if(LYX_ENABLE_URLTESTS)
1207         add_subdirectory(development/checkurls "${TOP_BINARY_DIR}/checkurls")
1208 endif()
1209 add_subdirectory(src "${TOP_BINARY_DIR}/src")
1210 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
1211 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
1212 add_subdirectory(lib/examples "${TOP_BINARY_DIR}/lib/examples")
1213 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
1214 add_subdirectory(development/autotests "${TOP_BINARY_DIR}/autotests")
1215 add_subdirectory(development/batchtests "${TOP_BINARY_DIR}/batchtests")
1216
1217 message(STATUS)
1218 message(STATUS "Build params, switch LYX_* options by -DLYX_*=ON or OFF, LYX_* combos by -DLYX_*=value:")
1219 message(STATUS)
1220
1221 LYX_OPTION_LIST_ALL(used)
1222
1223
1224 if(LYX_NLS)
1225         message(STATUS)
1226         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
1227         message(STATUS)
1228         message(STATUS "  * iconv")
1229         message(STATUS "     - include: ${ICONV_INCLUDE_DIR}")
1230         message(STATUS "     - library: ${ICONV_LIBRARY}")
1231         message(STATUS "  * zlib")
1232         message(STATUS "     - include: ${ZLIB_INCLUDE_DIR}")
1233         message(STATUS "     - library: ${ZLIB_LIBRARY}")
1234         message(STATUS)
1235 endif()
1236
1237 # Apple has builtin native spell checker,
1238 # no need to warn for missing Aspell, Hunspell or Enchant
1239 if(NOT Spelling_FOUND AND NOT APPLE)
1240   if(LYX_REQUIRE_SPELLCHECK)
1241     set(_mode "FATAL_ERROR")
1242   else()
1243     set(_mode "STATUS")
1244   endif()
1245   message(${_mode} "No spellcheck libraries found. LyX will be unable use spellchecking")
1246 endif()
1247
1248 include("${TOP_CMAKE_PATH}/LyxPackaging.cmake")
1249
1250 if(ENABLE_DIST)
1251   # Use git to create the source package
1252   # git archive --format=tgz --output=/home/kornel/x.tar.gz master
1253   if(UNIX)
1254     set(DIST_FORMAT tgz)
1255   else()
1256     set(DIST_FORMAT zip)
1257   endif()
1258   set(DIST_NAME ${CMAKE_PROJECT_NAME}-${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}-${CMAKE_SYSTEM_NAME}.${DIST_FORMAT})
1259
1260   add_custom_command(
1261     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME}
1262     COMMAND  ${LYX_GITVERSION} archive --format=${DIST_FORMAT} --output=${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME} master
1263     WORKING_DIRECTORY ${TOP_SRC_DIR})
1264   add_custom_target(git-archive DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME})
1265 endif()
1266
1267 # Last directory to be included so that the fixup code (OS X)
1268 # can be run last
1269 add_subdirectory(development/cmake/post_install)
1270
1271 message(STATUS)