CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 3.1.0)
   8
   9 set(LYX_PROJECT LyX)
  10
  11 # Instruct cmake to not use gnu extensions,
  12 # this prevents the mix of '-std=c++*' and '-std=gnu++*' flags
  13 set(CMAKE_CXX_EXTENSIONS OFF)
  14
  15 enable_testing()
  16
  17 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README REALPATH) # Resolve symlinks
  18 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  19 message(STATUS "TOP_SRC_DIR = ${TOP_SRC_DIR}")
  20
  21 set(LYX_CMAKE_DIR "development/cmake")
  22 set(TOP_CMAKE_PATH "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}")
  23 set(TOP_MODULE_PATH "${TOP_CMAKE_PATH}/modules")
  24 set(TOP_SCRIPT_PATH "${TOP_CMAKE_PATH}/scripts")
  25
  26 set(CMAKE_MODULE_PATH "${TOP_MODULE_PATH}")
  27
  28 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  29
  30 message(STATUS)
  31 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  32         message(STATUS "Building in-source")
  33         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  34 else()
  35         message(STATUS "Building out-of-source")
  36         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  37 endif()
  38
  39 # This directory should be used if some test uses lyx-executable
  40 set(LYX_TESTS_USERDIR "${TOP_BINARY_DIR}/Testing/.lyx")
  41 file(MAKE_DIRECTORY "${LYX_TESTS_USERDIR}")
  42
  43 if(COMMAND cmake_policy)
  44         # Installing MACOSX_BUNDLE targets requires a BUNDLE DESTINATION
  45         cmake_policy(SET CMP0006 NEW)
  46         if(POLICY CMP0043)
  47                 # COMPILE_DEFINITIONS are not used yet. Enable new behavior.
  48                 cmake_policy(SET CMP0043 NEW)
  49         endif()
  50         cmake_policy(SET CMP0020 NEW)
  51         cmake_policy(SET CMP0075 OLD)
  52 endif()
  53
  54 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  55
  56 # Supress regeneration
  57 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  58
  59 if(LYX_XMINGW)
  60     set(CMAKE_SYSTEM_NAME Windows)
  61     set(TOOLNAME ${LYX_XMINGW})
  62     set(TOOLCHAIN "${TOOLNAME}-")
  63     set(CMAKE_C_COMPILER   "${TOOLCHAIN}gcc"     CACHE PATH "Mingw C compiler" FORCE)
  64     set(CMAKE_CXX_COMPILER "${TOOLCHAIN}g++"     CACHE PATH "Mingw C++ compiler" FORCE)
  65     set(CMAKE_RC_COMPILER  "${TOOLCHAIN}windres" CACHE PATH "Mingw rc compiler" FORCE)
  66
  67     set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM BOTH)
  68     set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY)
  69     set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY)
  70 endif()
  71
  72 if(NOT help AND NOT HELP)
  73   # 'project' triggers the searching for a compiler
  74   project(${LYX_PROJECT})
  75   if (CMAKE_COMPILER_IS_GNUCXX)
  76     if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS "4.0")
  77       message(STATUS "Gnu CXX compiler version = ${CMAKE_CXX_COMPILER_VERSION}")
  78       message(STATUS "is too old, should be >= 4.0")
  79       message(FATAL_ERROR "Exiting")
  80     endif()
  81   endif()
  82 endif()
  83
  84 if(UNIX)
  85         set(ARCH_TRIPLET )
  86         FIND_PROGRAM(DPKG_ARCHITECTURE_EXECUTABLE dpkg-architecture)
  87         if(DPKG_ARCHITECTURE_EXECUTABLE)
  88                 EXECUTE_PROCESS(COMMAND ${DPKG_ARCHITECTURE_EXECUTABLE} -qDEB_HOST_MULTIARCH
  89                                 OUTPUT_VARIABLE ARCH_TRIPLET
  90                                 ERROR_VARIABLE ERROR_ARCH_TRIPLET
  91                                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  92         endif()
  93 endif()
  94 if(ARCH_TRIPLET)
  95         set(SYSTEM_LIB_DIRS /usr/lib /usr/lib/${ARCH_TRIPLET} /usr/local/lib)
  96 else()
  97         set(SYSTEM_LIB_DIRS /usr/lib /usr/local/lib)
  98 endif()
  99
 100 include(LyXMacros)
 101 include(LyXDestinations)
 102
 103 # Usage LYX_OPTION
 104 # 1. parameter: option name without prefix 'LYX_'
 105 # 2. parameter: description
 106 # 3. parameter: default value, ON or OFF
 107 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
 108
 109 # Usage LYX_COMBO
 110 # 1. parameter: name without prefix 'LYX_'
 111 # 2. parameter: description
 112 # 3. parameter: default value
 113 # 4-n parameter: possible other string values
 114
 115 LYX_OPTION_INIT()
 116
 117 # Options for all compilers/systems
 118 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
 119 LYX_OPTION(LOCALVERSIONING  "Add version info to created package name (only used if LYX_CPACK option set)" OFF ALL)
 120 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
 121 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
 122 LYX_OPTION(REQUIRE_SPELLCHECK "Abort if no spellchecker available" OFF ALL)
 123 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
 124 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
 125 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
 126 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" OFF ALL)
 127 LYX_OPTION(DEBUG            "Enforce debug build"  OFF ALL)
 128 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
 129 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
 130 LYX_STRING(SUFFIX_VALUE     "Use this string as suffix" "")
 131 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
 132 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
 133 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
 134 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
 135 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
 136 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
 137 LYX_OPTION(ENABLE_URLTESTS  "Enable for URL tests" OFF ALL)
 138 LYX_OPTION(ENABLE_EXPORT_TESTS "Enable for export tests" OFF ALL)
 139 LYX_OPTION(ENABLE_KEYTESTS  "Enable for keytests" OFF ALL)
 140 LYX_OPTION(ASAN             "Use address sanitizer" OFF ALL)
 141 LYX_COMBO(USE_FILEDIALOG    "Use native or QT file dialog" QT NATIVE)
 142 LYX_COMBO(USE_QT            "Use Qt version as frontend" AUTO QT4 QT5)
 143 #LYX_OPTION(3RDPARTY_BUILD   "Build 3rdparty libs" OFF ALL)
 144 LYX_OPTION(EXTERNAL_Z       "OFF := Build 3rdparty lib zlib" ON ALL)
 145 LYX_OPTION(EXTERNAL_ICONV   "OFF := Build 3rdparty lib iconvlib" ON ALL)
 146 LYX_OPTION(EXTERNAL_HUNSPELL "OFF := Build 3rdparty lib hunspelllib" ON ALL)
 147 LYX_COMBO(EXTERNAL_MYTHES   "OFF := Build 3rdparty lib mytheslib" AUTO OFF ON)
 148
 149 # GCC specific
 150 LYX_OPTION(PROFILE              "Build profile version" OFF GCC)
 151 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" OFF GCC)
 152 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
 153 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
 154 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++ pedantic debug mode" OFF GCC)
 155 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" OFF GCC)
 156 LYX_OPTION(PROFILE              "Build with options for gprof" OFF GCC)
 157
 158 # MSVC specific
 159 LYX_OPTION(CONSOLE               "Show console on Windows" ON MSVC)
 160 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
 161 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
 162 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
 163
 164 # APPLE specific
 165 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
 166 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
 167
 168
 169 if(help OR HELP)
 170         message(STATUS)
 171         message(STATUS "Available options: (dis/enable with -DLYX_*=OFF/ON)")
 172         message(STATUS)
 173         LYX_OPTION_LIST_ALL(help)
 174         message(STATUS)
 175         RETURN()
 176 endif()
 177
 178 # Check option dependencies
 179
 180 if(LYX_DMG)
 181         set(LYX_BUNDLE ON)
 182         set(LYX_CPACK ON)
 183 endif()
 184
 185 if(LYX_CPACK)
 186         set(LYX_INSTALL ON)
 187 endif()
 188
 189 if(LYX_INSTALL)
 190         set(LYX_NLS ON)
 191         if(WIN32 AND NOT MINGW)
 192                 set(LYX_HUNSPELL ON)
 193         endif()
 194         set(LYX_PACKAGE_SUFFIX ON)
 195         if(NOT LYX_DEBUG)
 196                 set(LYX_RELEASE ON)
 197         endif()
 198         set(LYX_PROFILE OFF)
 199 endif()
 200
 201
 202 if(LYX_MERGE_FILES)
 203         set(LYX_PCH OFF)
 204 else()
 205         set(LYX_MERGE_REBUILD OFF)
 206 endif()
 207
 208 if(LYX_DEPENDENCIES_DOWNLOAD)
 209         message(STATUS)
 210         if(MSVC14)
 211                 set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2015-deps)
 212                 set(deps_files lyx-windows-deps-msvc2015.zip)
 213                 set(deps_server http://ftp.lyx.de/LyX-Windows-Deps)
 214                 set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2015)
 215         elseif(MSVC10)
 216                 set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 217                 set(deps_files lyx-windows-deps-msvc2010.zip)
 218                 set(deps_server http://ftp.lyx.de/LyX-Windows-Deps)
 219                 set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2010)
 220         else()
 221                 message(FATAL_ERROR "error: no dependency package known for the selected MSVC version.")
 222         endif()
 223     message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 224         foreach(it ${deps_files})
 225                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 226                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 227                 if(NOT already_downloaded)
 228                         message(STATUS "Downloading ${it} ...")
 229                         file(DOWNLOAD ${deps_server}/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS STATUS status LOG log)
 230                         list(GET status 0 status_code)
 231                         list(GET status 1 status_string)
 232                         if(NOT status_code EQUAL 0)
 233                                 file(REMOVE ${LYX_DEPENDENCIES_DIR}/${it})
 234                                 message(FATAL_ERROR "error: downloading '${it}' failed. status_code: ${status_code}, status_string: ${status_string}. \nLog: ${log} ")
 235                         endif()
 236                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 237                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 238                 endif()
 239         endforeach()
 240 endif()
 241
 242
 243
 244 message(STATUS)
 245
 246 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 247 if(WIN32)
 248         set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 249 else()
 250         set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 251 endif()
 252
 253
 254 # Set to some meaningful default
 255 find_package(CXX11Compiler)
 256 if(NOT CXX11COMPILER_FOUND)
 257         message(FATAL_ERROR "A C++11 compatible compiler is required.")
 258 endif()
 259 set(LYX_GCC11_MODE)
 260 if(UNIX OR MINGW)
 261         if (CMAKE_CXX_COMPILER_ID MATCHES "^[cC]lang$")
 262           # ignore the GCC_VERSION for clang
 263           # and use the resulting CXX11_STD_REGEX found in FindCXX11Compiler.cmake
 264           message(STATUS "Using clang")
 265           if(CXX11_STD_REGEX)
 266             set(LYX_USE_STD_REGEX 1)
 267           else()
 268             set(LYX_USE_STD_REGEX 0)
 269           endif()
 270         else()
 271           execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION OUTPUT_STRIP_TRAILING_WHITESPACE)
 272           message(STATUS "Using GCC version ${GCC_VERSION}")
 273           if(GCC_VERSION VERSION_LESS 4.9)
 274                   if(GCC_VERSION VERSION_LESS 4.6)
 275                           message(FATAL_ERROR "gcc >= 4.6 is required.")
 276                   endif()
 277                   # <regex> in gcc is unusable in versions less than 4.9.0
 278                   # see https://gcc.gnu.org/bugzilla/show_bug.cgi?id=53631
 279                   set(LYX_USE_STD_REGEX 0)
 280           else()
 281                   set(LYX_USE_STD_REGEX 1)
 282           endif()
 283         endif()
 284         set(LYX_GCC11_MODE "${CXX11_FLAG}")
 285 else()
 286         set(LYX_USE_STD_REGEX 0)
 287 #       if(MSVC10)
 288 #               set(LYX_USE_STD_REGEX 1) #TODO should we use it in ECMAScript mode?
 289 #       endif()
 290 endif()
 291
 292
 293 set(VERSION_INFO "CMake Build")
 294
 295 # Try to get some informations from configure.ac
 296
 297 include(LyXPaths)
 298 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 299
 300 if(WIN32)
 301         set(CMAKE_PREFIX_PATH Specify-path-to-Qt CACHE PATH "Used Qt version")
 302         if(MSVC)
 303                 set(LYX_3RDPARTY_BUILD ON CACHE BOOL "Build 3rdparty libraries" FORCE)
 304         endif()
 305         set(USE_WINDOWS_PACKAGING ON)
 306 elseif(APPLE)
 307         set(USE_MACOSX_PACKAGING ON)
 308 else()
 309         set(USE_POSIX_PACKAGING ON)
 310 endif()
 311
 312 if(LYX_3RDPARTY_BUILD)
 313   # LYX_3RDPARTY_BUILD is not cached anymore, but for compatibility reasons
 314   # this enables the build of all 3rd_party libs
 315   set(LYX_EXTERNAL_Z        OFF CACHE BOOL "Build 3rdparty lib zlib"    FORCE)
 316   set(LYX_EXTERNAL_ICONV    OFF CACHE BOOL "Build 3rdparty iconvlib"    FORCE)
 317   set(LYX_EXTERNAL_HUNSPELL OFF CACHE BOOL "Build 3rdparty hunspelllib" FORCE)
 318   set(LYX_EXTERNAL_MYTHES   OFF CACHE STRING "Build 3rdparty mytheslib" FORCE)
 319 endif()
 320
 321 macro(setstripped _varname)
 322         if(${ARGC} GREATER 1)
 323                 string(STRIP "${ARGV1}" _v)
 324                 if(USE_POSIX_PACKAGING)
 325                         string(TOLOWER ${_v} ${_varname})
 326                 else()
 327                         set(${_varname} ${_v})
 328                 endif()
 329         else()
 330                 set(${_varname})
 331         endif()
 332 endmacro(setstripped)
 333
 334 foreach(_c_l ${_config_lines} )
 335         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 336                 setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 337                 setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 338                 setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 339                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\)\(\\.\([0-9]+\)\)?.*$")
 340                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 341                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 342                         set(LYX_RELEASE_VERSION ${CMAKE_MATCH_4})
 343                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 344                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 345                         if ("${LYX_SUFFIX_VALUE}" MATCHES "")
 346                           set(LYX_INSTALL_SUFFIX "${LYX_MAJOR_VERSION}.${LYX_MINOR_VERSION}")
 347                         else()
 348                           set(LYX_INSTALL_SUFFIX "${LYX_SUFFIX_VALUE}")
 349                         endif()
 350                 endif()
 351         endif()
 352         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 353                 set(LYX_DATE "${CMAKE_MATCH_1}")
 354         endif()
 355 endforeach(_c_l)
 356
 357 FIND_PROGRAM(LYX_GITVERSION git)
 358 #message(STATUS "gitversion = ${LYX_GITVERSION}")
 359 set(LYX_REVISION_VERSION ${LYX_RELEASE_VERSION})
 360 set(LYX_PACKAGE_RELEASE "1")
 361 if(LYX_GITVERSION)
 362   if (LYX_LOCALVERSIONING)
 363     # Find the revision number and for later use
 364     EXECUTE_PROCESS(COMMAND ${LYX_GITVERSION} describe --match 2.0.0 HEAD
 365       WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE tmp_LYX_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 366     if (tmp_LYX_PACKAGE_RELEASE MATCHES "^2\\.0\\.0\\-\([0-9]+\)\\-\(.*\)$")
 367       set(LYX_PACKAGE_RELEASE ${CMAKE_MATCH_2})
 368       # We will add offset of 40000 to get appropriate value to
 369       # previous svn.
 370       # We use this value than also to set the package-patch-value
 371       MATH(EXPR tmp_REVISION_VERSION "(${CMAKE_MATCH_1}+40000)")
 372       set(LYX_REVISION_VERSION "${LYX_RELEASE_VERSION}-${tmp_REVISION_VERSION}git")
 373       set(ENABLE_DIST ON)
 374     endif()
 375   endif()
 376 endif()
 377
 378 # Set the programs (lyx, tex2lyx, etc.) suffix
 379 # When building an OS X bundle, we will append
 380 # the suffix only to the bundle, not to the programs
 381 set(PROGRAM_SUFFIX "")
 382 if(LYX_PROGRAM_SUFFIX AND NOT (APPLE AND LYX_BUNDLE))
 383         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 384 endif()
 385 set(_lyx "${PACKAGE_BASE}${PROGRAM_SUFFIX}")
 386 set(_tex2lyx tex2lyx${PROGRAM_SUFFIX})
 387 set(_convert lyxconvert${PROGRAM_SUFFIX})
 388
 389 add_custom_target(lyx_version ALL
 390   COMMAND ${CMAKE_COMMAND} -DTOP_SRC_DIR=${TOP_SRC_DIR} -DTOP_CMAKE_PATH=${TOP_CMAKE_PATH} -DTOP_BINARY_DIR=${TOP_BINARY_DIR} -DLYX_DATE=${LYX_DATE} -P ${TOP_SCRIPT_PATH}/LyXGetVersion.cmake
 391   )
 392 set_target_properties(lyx_version PROPERTIES FOLDER "applications")
 393
 394 # Default paths for installed utilities (tex2lyx, lyxclient, etc.)
 395 set(LYX_UTILITIES_INSTALL_PATH bin)
 396
 397 if(LYX_BUNDLE)
 398         set(LYX_CPACK ON)
 399
 400         message(STATUS)
 401         message(STATUS "Bundle creation is enabled (experimental):")
 402         message(STATUS "    make")
 403         message(STATUS "    make install/strip")
 404         message(STATUS "    make package")
 405         if(APPLE)
 406                 set(MACOSX_BUNDLE TRUE)
 407                 # This sets the bundle + executable names
 408                 set(_lyx "${PACKAGE_BASE}${LYX_INSTALL_SUFFIX}")
 409                 # This sets the Info.plist executable name
 410                 set(osx_bundle_program_name ${_lyx})
 411                 # Bundle name
 412                 set(LYX_BUNDLE_NAME ${_lyx})
 413
 414                 # This will contain the list of files that need to be included
 415                 # in the bundle and their location within the bundle
 416                 set(OSX_BUNDLE_FILES "${TOP_SRC_DIR}/development/MacOSX/LyX.sdef;${TOP_SRC_DIR}/development/MacOSX/LyXapp.icns;${CMAKE_BINARY_DIR}/lyxrc.dist")
 417                 set(OSX_BUNDLE_DIRS "Resources;Resources;Resources")
 418
 419                 # Process Info.plist and lyxrc.dist
 420                 # See development/cmake/Install.cmake
 421                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/Info.plist.in" "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 422
 423                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 424                 set(LYX_DATA_SUBDIR ${LYX_BUNDLE_NAME}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 425
 426                 # Variables used by CPack
 427                 set(CPACK_BUNDLE_NAME ${LYX_BUNDLE_NAME})
 428                 set(CPACK_BUNDLE_PLIST "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 429                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${LYX_BUNDLE_NAME}.app)
 430
 431                 # Set the install paths
 432                 set(LYX_UTILITIES_INSTALL_PATH ${LYX_BUNDLE_NAME}.app/Contents/MacOS)
 433                 if(NOT LYX_INSTALL_PREFIX)
 434                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 435                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 436                 endif()
 437                 # Change the owner so that the install can work
 438                 install(CODE "set(BU_CHMOD_BUNDLE_ITEMS 1)" COMPONENT Runtime)
 439         elseif(UNIX)
 440                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 441                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 442                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 443         elseif(WIN32)
 444                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 445         endif()
 446 endif()
 447
 448 if(LYX_INSTALL_PREFIX)
 449         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 450         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 451 endif()
 452 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 453
 454 if(UNIX)
 455   set(SYSTEM_DATADIR "${CMAKE_INSTALL_PREFIX}/share")
 456 elseif(CMAKE_INSTALL_PREFIX MATCHES "/lyx${LYX_INSTALL_SUFFIX}$")
 457   string(REGEX REPLACE "/lyx${LYX_INSTALL_SUFFIX}$" "/share" SYSTEM_DATADIR ${CMAKE_INSTALL_PREFIX})
 458 else()
 459   set(SYSTEM_DATADIR "${CMAKE_INSTALL_PREFIX}")
 460 endif()
 461
 462 if(CMAKE_COMPILER_IS_GNUCXX)
 463   message(STATUS "CMAKE_COMPILER_IS_GNUCXX = ${CMAKE_COMPILER_IS_GNUCXX}")
 464   set(suffixing ${LYX_PROGRAM_SUFFIX})
 465 else()
 466   # Not a GCC compiler, programs do not have a suffix
 467   set(suffixing ${LYX_PACKAGE_SUFFIX})
 468 endif()
 469
 470 # The define PACKAGE below allows lyx-executable to find its default configuration files
 471 # see routines
 472 #    Package::messages_file()
 473 #    get_default_user_support_dir()
 474 #    relative_system_support_dir()
 475 # in src/support/Package.cpp
 476 #
 477 if(suffixing)
 478         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 479 else()
 480         set(PACKAGE ${PACKAGE_BASE})
 481 endif()
 482
 483 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 484         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 485         if (UNIX)
 486                 # use the default "/usr/local"
 487                 # but respect the user-choice on the command-line
 488                 set(CMAKE_INSTALL_PREFIX "/usr/local" CACHE PATH "LyX default install prefix" FORCE)
 489         endif()
 490 endif()
 491 if(WIN32)
 492         set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 493 endif()
 494 if(IS_ABSOLUTE)
 495         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 496 else()
 497         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 498 endif()
 499
 500
 501
 502 if(NOT LYX_DATA_SUBDIR)
 503         if (WIN32)
 504                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 505         else()
 506                 set(LYX_DATA_SUBDIR "share/${_lyx}/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 507         endif()
 508 endif()
 509
 510 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 511 get_locale_destination(LYX_LOCALEDIR)
 512 set(LYX_ABS_INSTALLED_LOCALEDIR "${CMAKE_INSTALL_PREFIX}/${LYX_LOCALEDIR}")
 513 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 514
 515 if(LYX_BUNDLE AND APPLE)
 516         set(LYX_MAN_DIR "${LYX_DATA_SUBDIR}" CACHE STRING "Install location for man pages.")
 517 else()
 518         if(WIN32)
 519                 set(LYX_MAN_DIR "${CMAKE_BINARY_DIR}/usr/local/man" CACHE STRING "Install location for man pages.")
 520         elseif(UNIX)
 521                 set(LYX_MAN_DIR "${CMAKE_INSTALL_PREFIX}/share/man" CACHE STRING "Install location for man pages.")
 522         else()
 523                 set(LYX_MAN_DIR "${CMAKE_INSTALL_PREFIX}/man" CACHE STRING "Install location for man pages.")
 524         endif()
 525 endif()
 526 mark_as_advanced(LYX_MAN_DIR)
 527
 528 # The Win installer cannot be built by CMake because one needs to install plugins for NSIS
 529 # see the Readme.txt of the installer
 530 #if(LYX_INSTALL AND WIN32)
 531 #       message(STATUS "Configuring NSIS files")
 532 #       configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 533 #       configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 534 #       configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 535 #       message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 536 #endif()
 537
 538 if(NOT GROUP_CODE)
 539         #set(GROUP_CODE "The Golden Code")
 540         set(GROUP_CODE flat)
 541 endif()
 542
 543 # lyx's source files
 544 set(LYX_CPP_FILES [a-zA-Z]*.cpp)
 545 set(LYX_HPP_FILES [a-zA-Z]*.h)
 546 set(LYX_MOC_FILES moc_*.cpp)
 547
 548 include(ProjectSourceGroup)
 549
 550
 551 if(LYX_PROFILE AND NOT MSVC)
 552         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 553         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg")
 554         set(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS}  -pg")
 555 else()
 556         set(LYX_PROFILE OFF)
 557 endif()
 558
 559
 560 if(LYX_NO_OPTIMIZE)
 561         set(CMAKE_BUILD_TYPE None)
 562         set(LYX_DEBUG OFF)
 563         set(LYX_RELEASE OFF)
 564         set(LYX_PROFILE OFF)
 565 elseif(LYX_RELEASE)
 566         set(CMAKE_BUILD_TYPE Release)
 567         set(LYX_DEBUG OFF)
 568         set(LYX_PROFILE OFF)
 569 elseif(LYX_PROFILE)
 570         set(CMAKE_BUILD_TYPE Profile)
 571         set(LYX_DEBUG OFF)
 572 else()
 573         set(CMAKE_BUILD_TYPE Debug)
 574         set(LYX_DEBUG ON)
 575 endif()
 576
 577
 578 # When shared libs are supported enable this option
 579 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 580 if(LYX_SHARED_LIBRARIES)
 581         set(library_type SHARED)
 582 else()
 583         set(library_type STATIC)
 584 endif()
 585
 586 if(NOT MSVC)
 587         if(NOT LYX_QUIET)
 588                 set(CMAKE_VERBOSE_MAKEFILE ON)
 589         endif()
 590         set(LYX_CXX_FLAGS "-Wall -Wunused-parameter ${LYX_GCC11_MODE}")
 591         if(LYX_CXX_FLAGS MATCHES "\\+\\+(14|11|98)")
 592           # Thanks to Brad King <brad.king@kitware.com>
 593           # for the pointer to https://cmake.org/cmake/help/v3.6/variable/CMAKE_CXX_STANDARD.html
 594           # This allows us to use QT5.7 with recent g++ (version >= 4.9) compilers
 595           # and still use our own c++ extension tests
 596           set(CMAKE_CXX_STANDARD ${CMAKE_MATCH_1})
 597           message(STATUS "CMAKE_CXX_STANDARD set to ${CMAKE_CXX_STANDARD}")
 598         endif()
 599         if(LYX_STDLIB_DEBUG)
 600                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 601         endif()
 602         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 603         set(CMAKE_CXX_FLAGS_DEBUG "-O0 -g3 -D_DEBUG" CACHE TYPE STRING FORCE)
 604         if(MINGW)
 605                 set(CMAKE_CXX_FLAGS_RELEASE "-O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 606         else()
 607                 set(CMAKE_CXX_FLAGS_RELEASE "-O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 608         endif()
 609 endif()
 610
 611 set(LYX_CXX_FLAGS_EXTRA "" CACHE STRING "Desired semicolon separated list of extra cxx compile flags, like '-Werror'")
 612 mark_as_advanced(LYX_CXX_FLAGS_EXTRA)
 613 if(LYX_CXX_FLAGS_EXTRA)
 614         foreach(_flag ${LYX_CXX_FLAGS_EXTRA})
 615                 add_definitions(${_flag})
 616         endforeach()
 617 endif()
 618
 619 if(LYX_XMINGW)
 620         list(APPEND CMAKE_FIND_ROOT_PATH ${GNUWIN32_DIR})
 621 endif()
 622
 623 set(min_qt5_version "5.6")
 624 if(LYX_USE_QT MATCHES "AUTO")
 625         # try qt5 first
 626         find_package(Qt5Core CONFIG QUIET)
 627         if(Qt5Core_FOUND)
 628                 set(LYX_USE_QT "QT5" CACHE STRING "Valid qt version" FORCE)
 629                 message(STATUS "Qt5Core_VERSION = ${Qt5Core_VERSION}")
 630                 if(Qt5Core_VERSION VERSION_LESS ${min_qt5_version})
 631                         find_package(Qt4 "4.5.0" QUIET)
 632                         if(QT4_FOUND)
 633                                 set(LYX_USE_QT "QT4" CACHE STRING "Valid qt version" FORCE)
 634                         endif()
 635                 endif()
 636         else()
 637                 set(LYX_USE_QT "QT4" CACHE STRING "Valid qt version" FORCE)
 638         endif()
 639 endif()
 640 if(LYX_USE_QT MATCHES "QT5")
 641         # set QPA_XCB if QT uses X11
 642         find_package(Qt5Core CONFIG REQUIRED)
 643         if (Qt5Core_FOUND)
 644                 find_package(Qt5Widgets CONFIG REQUIRED)
 645                 if(APPLE)
 646                         find_package(Qt5MacExtras CONFIG REQUIRED)
 647                 endif()
 648                 find_package(Qt5X11Extras CONFIG QUIET)
 649                 find_package(Qt5WinExtras CONFIG QUIET)
 650                 set(QTVERSION ${Qt5Core_VERSION})
 651                 if (QTVERSION VERSION_LESS ${min_qt5_version})
 652                         message(STATUS "QTVERSION = \"${QTVERSION}\"")
 653                         message(STATUS "This version is not recommended, try either option -DLYX_USE_QT=QT4 or")
 654                         message(STATUS "install QT-Version >= \"${min_qt5_version}\"")
 655                         # see thread in lyx-devel list
 656                         # From: Jean-Pierre Chrétien <jeanpierre.chretien@free.fr>
 657                         # Date 11.03.2017
 658                         # Subject: cmake compilation error
 659                         #message(FATAL_ERROR "Wrong Qt-Version")
 660                 endif()
 661                 macro (qt_use_modules lyxtarget)
 662                         foreach (_tg ${ARGN})
 663                                 find_package(Qt5${_tg} CONFIG REQUIRED)
 664                                 target_link_libraries(${lyxtarget} Qt5::${_tg})
 665                         endforeach()
 666                 endmacro()
 667                 macro (qt_add_resources)
 668                         qt5_add_resources(${ARGN})
 669                 endmacro()
 670                 macro (qt_wrap_uifiles)
 671                         qt5_wrap_ui(${ARGN})
 672                 endmacro()
 673                 message(STATUS "Found Qt-Version ${QTVERSION}")
 674                 if(WIN32)
 675                         set(LYX_QTMAIN_LIBRARY ${Qt5Core_QTMAIN_LIBRARIES})
 676                 endif()
 677         endif()
 678 elseif(LYX_USE_QT MATCHES "QT4")
 679         if(LYX_XMINGW)
 680                 set(QT_MINGW_DIR ${LYX_QT4} CACHE PATH "Qt for Mingw" FORCE)
 681                 list(APPEND CMAKE_FIND_ROOT_PATH ${QT_MINGW_DIR} ${GNUWIN32_DIR})
 682         endif()
 683         find_package(Qt4 "4.5.0" REQUIRED)
 684         macro (qt_use_modules)
 685         endmacro()
 686         macro (qt_add_resources)
 687                 qt4_add_resources(${ARGN})
 688         endmacro()
 689         macro (qt_wrap_uifiles)
 690                 qt4_wrap_ui(${ARGN})
 691         endmacro()
 692         set(LYX_QTMAIN_LIBRARY ${QT_QTSVG_LIBRARY})
 693         if(WIN32)
 694                 list(APPEND LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARIES})
 695         endif()
 696 else()
 697   message(FATAL_ERROR "Unhandled value for LYX_USE_QT (${LYX_USE_QT})")
 698 endif()
 699
 700 find_package(Magic)
 701 if(Magic_FOUND)
 702   set(HAVE_MAGIC_H 1)
 703   include_directories(${Magic_INCLUDE_DIR})
 704 endif()
 705
 706 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 707
 708 set(Spelling_FOUND OFF)
 709 set(Include_used_spellchecker)   # String will be inserted into config.h
 710
 711 if (LYX_EXTERNAL_MYTHES MATCHES "AUTO")
 712   # try system library first
 713   find_package(MyThesLIB)
 714   if (MYTHESLIB_FOUND)
 715     set(LYX_EXTERNAL_MYTHES ON CACHE STRING "OFF:= Build 3rdparty mytheslib" FORCE)
 716   else()
 717     set(LYX_EXTERNAL_MYTHES OFF CACHE STRING "OFF:= Build 3rdparty mytheslib" FORCE)
 718   endif()
 719 endif()
 720 if (LYX_EXTERNAL_MYTHES MATCHES "ON")
 721   find_package(MyThesLIB REQUIRED)
 722 else()
 723   add_subdirectory(3rdparty/mythes)
 724 endif()
 725 set(MYTHES_DIR ${MYTHESLIB_INCLUDE_DIR})
 726
 727 if(NOT LYX_EXTERNAL_HUNSPELL)
 728     add_subdirectory(3rdparty/hunspell)
 729     add_definitions(-DHUNSPELL_STATIC)
 730     set(HUNSPELL_FOUND ON)
 731     message(STATUS "  * Hunspell:")
 732     message(STATUS "     - include: ${HUNSPELL_INCLUDE_DIR}")
 733     message(STATUS "     - library: ${HUNSPELL_LIBRARY}")
 734 endif()
 735
 736 foreach(_spell "ASPELL" "Enchant" "Hunspell")
 737   string(TOUPPER ${_spell} _upspell)
 738   if (NOT ${_upspell}_FOUND)
 739     find_package(${_spell})
 740   endif()
 741   if (${_upspell}_FOUND)
 742     include_directories(${${_upspell}_INCLUDE_DIR})
 743     set(Spelling_FOUND ON)
 744     message(STATUS "Building with USE_${_upspell}")
 745     set(Include_used_spellchecker "${Include_used_spellchecker}#define USE_${_upspell} 1\n")
 746   else()
 747     if(LYX_${_upspell})
 748       message(FATAL_ERROR "Required ${_spell} devel package not found")
 749     else()
 750       message(STATUS "${_upspell} not found, building without ${_spell} support")
 751     endif()
 752   endif()
 753 endforeach()
 754
 755 if(GNUWIN32_DIR)
 756         list(APPEND CMAKE_PROGRAM_PATH "${GNUWIN32_DIR}/Python" )
 757 endif()
 758
 759 # Search for python default version first
 760 unset(PYTHON_EXECUTABLE CACHE)
 761 unset(LYX_PYTHON_EXECUTABLE CACHE)
 762 unset(PYTHON_VERSION_MAJOR)
 763 unset(PYTHON_VERSION_MINOR)
 764 unset(PYTHON_VERSION_STRING)
 765 find_package(PythonInterp 3.3 QUIET)
 766 if(NOT PYTHONINTERP_FOUND)
 767   unset(PYTHON_EXECUTABLE CACHE)
 768   find_package(PythonInterp 2.0 REQUIRED)
 769   if(NOT PYTHON_VERSION_STRING VERSION_LESS 2.8)
 770     message(FATAL_ERROR "Python interpreter found, but is not suitable")
 771   endif()
 772 endif()
 773
 774 set(LYX_PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 775
 776 if(LYX_NLS)
 777         find_package(LyXGettext)
 778         if(LYX_PYTHON_EXECUTABLE AND GETTEXT_FOUND)
 779                 add_subdirectory(po "${TOP_BINARY_DIR}/po")
 780         else()
 781                 # Install only supplied .gmo-files
 782                 file(GLOB _gmofiles RELATIVE "${TOP_SRC_DIR}/po" "${TOP_SRC_DIR}/po/*.gmo")
 783                 message(STATUS "Installing provided .gmo-files only")
 784                 foreach( _gmo ${_gmofiles})
 785                         string(REGEX REPLACE "\\.gmo$" "" _lang ${_gmo})
 786                         install(FILES "${TOP_SRC_DIR}/po/${_gmo}" DESTINATION ${LYX_LOCALEDIR}/${_lang}/LC_MESSAGES RENAME ${PACKAGE}.mo)
 787                 endforeach()
 788         endif()
 789 endif()
 790
 791 if(LYX_EXTERNAL_ICONV)
 792   find_package(ICONV REQUIRED)
 793 else()
 794   add_subdirectory(3rdparty/libiconv)
 795   set(HAVE_ICONV_CONST 1)
 796 endif()
 797
 798 if(LYX_EXTERNAL_Z)
 799   find_package(ZLIB REQUIRED)
 800 else()
 801   add_subdirectory(3rdparty/zlib)
 802 endif()
 803
 804 if(LYX_USE_STD_REGEX)
 805   # Set only include path.
 806   # Use internal boost, which is known to exist
 807   # we don't need any libraries
 808   set(Lyx_Boost_Libraries)
 809   add_definitions(-DBOOST_USER_CONFIG=<config.h>)
 810   include_directories(${TOP_SRC_DIR}/3rdparty/boost)
 811 else()
 812   # Using boost-regex
 813   if(LYX_EXTERNAL_BOOST)
 814     message(STATUS "Searching for external boost")
 815     find_package(Boost COMPONENTS regex)
 816     if(Boost_FOUND)
 817       message(STATUS "Boost found")
 818       message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 819       set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 820       if (LYX_STDLIB_DEBUG)
 821         # Comment from  Jean-Marc Lasgouttes:
 822         # In general, system boost libraries are incompatible with
 823         # the use of stdlib-debug in libstdc++. See ticket #9736 for
 824         # details.
 825         message(WARNING "Compiling LyX with stdlib-debug and system boost libraries may lead to crashes. Consider using '-DLYX_STDLIB_DEBUG=OFF' or using '-DLYX_EXTERNAL_BOOST=OFF'")
 826       endif()
 827     else()
 828       message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 829     endif()
 830   else()
 831     # Using included boost
 832     set(Lyx_Boost_Libraries boost_regex)
 833     add_definitions(-DBOOST_USER_CONFIG=<config.h>)
 834     include_directories(${TOP_SRC_DIR}/3rdparty/boost)
 835     add_subdirectory(3rdparty/boost "${TOP_BINARY_DIR}/3rdparty/boost")
 836   endif()
 837 endif()
 838
 839 if(WIN32)
 840         if(LYX_CONSOLE)
 841                 set(LYX_QTMAIN_LIBRARY)
 842         else()
 843                 set(WIN32_CONSOLE WIN32)
 844         endif()
 845         if(MSVC)
 846                 # -DPSAPI_VERSION=1 is needed to run on vista (bug 10186)
 847                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX -DPSAPI_VERSION=1)
 848                 # disable checked iterators for msvc release builds to get maximum speed
 849                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 850         else()
 851                 # -DPSAPI_VERSION=1 is not needed for mingw, since the mingw psapi.h
 852                 # does not use it and always declares the vista compatible API.
 853                 # If this ever changes then -DPSAPI_VERSION might be needed here as well.
 854                 add_definitions(-DWINVER=0x0500)
 855         endif()
 856 endif()
 857
 858 # Compute qt-version from ${QTVERSION}
 859
 860 message(STATUS "")
 861 foreach(_v PACKAGE PACKAGE_VERSION
 862         PROGRAM_SUFFIX LYX_DIR_VER LYX_USERDIR_VER
 863         LYX_ABS_TOP_SRCDIR
 864         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 865         if(NOT DEFINED ${_v})
 866                 message(FATAL_ERROR "${_v} not defined")
 867         endif()
 868         string(SUBSTRING "${_v}                            " 0 28 _v1)
 869         message(STATUS "----- ${_v1}: ${${_v}}")
 870 endforeach(_v)
 871 message(STATUS "")
 872
 873
 874 if(LYX_PCH)
 875         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 876         # Not sure if it works for all non-msvc compilers
 877         include(PCHSupport_26)
 878         configure_file(${TOP_CMAKE_PATH}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
 879         configure_file(${TOP_CMAKE_PATH}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 880         add_definitions(-DLYX_ENABLE_PCH)
 881
 882         if(MSVC)
 883                 macro(lyx_add_msvc_pch name_)
 884                         set_source_files_properties(${${name_}_sources} PROPERTIES
 885                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 886                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
 887                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 888                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
 889                                 ${TOP_BINARY_DIR}/pcheaders.h)
 890                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 891                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 892                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 893                 endmacro(lyx_add_msvc_pch)
 894                 macro(lyx_add_gcc_pch name_)
 895                 endmacro()
 896         else()
 897                 macro(lyx_add_msvc_pch name_)
 898                 endmacro()
 899                 macro(lyx_add_gcc_pch name_)
 900                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT)
 901                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
 902                 endmacro()
 903         endif()
 904 else()
 905         macro(lyx_add_msvc_pch)
 906         endmacro(lyx_add_msvc_pch)
 907         macro(lyx_add_gcc_pch name_)
 908         endmacro()
 909 endif()
 910
 911
 912 if(MSVC)
 913
 914         if(LYX_VLD)
 915                 set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/development/Win32/vld)
 916                 add_subdirectory(${vld_path}/cmake)
 917                 include(${vld_path}/cmake/vld.cmake) # forced include
 918                 set(vld_dll vld)
 919         endif()
 920
 921         if(LYX_WALL)
 922                 # Use the highest warning level
 923                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 924
 925                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 926                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 927                 else()
 928                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 929                 endif()
 930
 931                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 932                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 933                 else()
 934                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 935                 endif()
 936
 937                 # add here warnings which should produce an error /weXXXX
 938                 set(MSVC_W_ERROR   "/we4101 /we4189")
 939                 # add here warnings which should be disabled /wdXXXX
 940                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 941
 942                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 943                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 944                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 945
 946         else()
 947                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 948
 949                 # add here warnings which should produce an error /weXXXX
 950                 set(MSVC_W_ERROR   "/we4101 /we4189")
 951                 # add here warnings which should be disabled /wdXXXX
 952                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 953
 954                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 955                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 956                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 957
 958         endif()
 959
 960         if (NOT Qt5Core_FOUND)
 961                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 962                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 963                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 964         endif()
 965
 966         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 967         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 968         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 969         message(STATUS "")
 970 endif()
 971
 972
 973 if(LYX_DEBUG_GLIBC)
 974         set(_GLIBCXX_DEBUG ON)
 975 endif()
 976
 977 if(LYX_DEBUG_GLIBC_PEDANTIC)
 978         set(_GLIBCXX_DEBUG_PEDANTIC ON)
 979 endif()
 980
 981 # Xcode compiler
 982 if (CMAKE_GENERATOR MATCHES Xcode)
 983         if (XCODE_VERSION VERSION_LESS "5.0")
 984                 # Automatically select the Xcode compiler if not set
 985                 if (NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 986                         # XCode >= 3.1 has gcc 4.2 (up to actual Xcode)
 987                         if (XCODE_VERSION VERSION_GREATER "3.1")
 988                                 SET(CMAKE_XCODE_ATTRIBUTE_GCC_VERSION "com.apple.compilers.llvmgcc42")
 989                         ENDIF(XCODE_VERSION VERSION_GREATER "3.1")
 990                 ENDIF(NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 991                 # Print the selected compiler version
 992         MESSAGE(STATUS "---- Using XCode compiler CMAKE_XCODE_ATTRIBUTE_GCC_VERSION=${CMAKE_XCODE_ATTRIBUTE_GCC_VERSION}")
 993         ENDIF(XCODE_VERSION VERSION_LESS "5.0")
 994 ENDIF(CMAKE_GENERATOR MATCHES Xcode)
 995
 996 if (WIN32 AND Qt5Core_FOUND)
 997         set(Z_PREFIX 1)
 998 endif()
 999
1000 # compiler tests, config.h generation LYX_CONFIGURE_CHECKS
1001 include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
1002 configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
1003
1004 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
1005
1006 if(QTVERSION MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+).*")
1007         MATH(EXPR QT4_VERSION "(${CMAKE_MATCH_1}<<16)|(${CMAKE_MATCH_2}<<8)|${CMAKE_MATCH_3}")
1008 endif()
1009
1010 if (NOT HAVE_REGEX)
1011         set(LYX_USE_STD_REGEX 0)
1012 endif()
1013
1014
1015 set (cmd ${CMAKE_CTEST_COMMAND})
1016 if (MSVC)
1017         set (cmd ${cmd} -C ${CMAKE_CFG_INTDIR})
1018 else ()
1019         set (cmd ${cmd} -C ${CMAKE_BUILD_TYPE})
1020 endif ()
1021 add_custom_target (lyx_run_tests COMMAND ${cmd})
1022 set_target_properties(lyx_run_tests PROPERTIES FOLDER "tests")
1023
1024 if(LYX_ASAN)
1025     set(LYX_CXX_FLAGS "-fsanitize=address -fno-omit-frame-pointer -g")
1026     message(STATUS)
1027     message(STATUS "Address sanitizer enabled. Usage:")
1028     message(STATUS "    wget https://llvm.org/svn/llvm-project/compiler-rt/trunk/lib/asan/scripts/asan_symbolize.py")
1029     message(STATUS "    chmod  +x ./asan_symbolize.py")
1030     message(STATUS "    ./bin/lyx2.2 2>&1 | ./asan_symbolize.py  | c++filt ")
1031     message(STATUS)
1032 endif()
1033
1034 if(LYX_INSTALL)
1035         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
1036                 message(STATUS "Python required to create doc!")
1037         else()
1038                 if(UNIX)
1039                         add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
1040                 endif()
1041                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
1042         endif()
1043 endif()
1044 include(../Install)
1045
1046 # By running the URL tests first, time can be saved when running the ctests in
1047 # parallel since the URL tests take a long time to run (e.g. 10 minutes).
1048 if(LYX_ENABLE_URLTESTS)
1049         add_subdirectory(development/checkurls "${TOP_BINARY_DIR}/checkurls")
1050 endif()
1051 add_subdirectory(src "${TOP_BINARY_DIR}/src")
1052 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
1053 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
1054 add_subdirectory(lib/examples "${TOP_BINARY_DIR}/lib/examples")
1055 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
1056 add_subdirectory(development/autotests "${TOP_BINARY_DIR}/autotests")
1057 add_subdirectory(development/batchtests "${TOP_BINARY_DIR}/batchtests")
1058
1059 message(STATUS)
1060 message(STATUS "Build params, switch LYX_* options by -DLYX_*=ON or OFF, LYX_* combos by -DLYX_*=value:")
1061 message(STATUS)
1062
1063 LYX_OPTION_LIST_ALL(used)
1064
1065
1066 if(LYX_NLS)
1067         message(STATUS)
1068         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
1069         message(STATUS)
1070         message(STATUS "  * iconv")
1071         message(STATUS "     - include: ${ICONV_INCLUDE_DIR}")
1072         message(STATUS "     - library: ${ICONV_LIBRARY}")
1073         message(STATUS "  * zlib")
1074         message(STATUS "     - include: ${ZLIB_INCLUDE_DIR}")
1075         message(STATUS "     - library: ${ZLIB_LIBRARY}")
1076         message(STATUS)
1077 endif()
1078
1079 # Apple has builtin native spell checker,
1080 # no need to warn for missing Aspell, Hunspell or Enchant
1081 if(NOT Spelling_FOUND AND NOT APPLE)
1082   if(LYX_REQUIRE_SPELLCHECK)
1083     set(_mode "FATAL_ERROR")
1084   else()
1085     set(_mode "STATUS")
1086   endif()
1087   message(${_mode} "No spellcheck libraries found. LyX will be unable use spellchecking")
1088 endif()
1089
1090 include("${TOP_CMAKE_PATH}/LyxPackaging.cmake")
1091
1092 if(ENABLE_DIST)
1093   # Use git to create the source package
1094   # git archive --format=tgz --output=/home/kornel/x.tar.gz master
1095   if(UNIX)
1096     set(DIST_FORMAT tgz)
1097   else()
1098     set(DIST_FORMAT zip)
1099   endif()
1100   set(DIST_NAME ${CMAKE_PROJECT_NAME}-${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}-${CMAKE_SYSTEM_NAME}.${DIST_FORMAT})
1101
1102   add_custom_command(
1103     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME}
1104     COMMAND  ${LYX_GITVERSION} archive --format=${DIST_FORMAT} --output=${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME} master
1105     WORKING_DIRECTORY ${TOP_SRC_DIR})
1106   add_custom_target(git-archive DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME})
1107 endif()
1108
1109 # Last directory to be included so that the fixup code (OS X)
1110 # can be run last
1111 add_subdirectory(development/cmake/post_install)
1112
1113 message(STATUS)