CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 2.6.4)
   8
   9 set(LYX_PROJECT LyX)
  10
  11 enable_testing()
  12
  13 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README REALPATH) # Resolve symlinks
  14 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  15 message(STATUS "TOP_SRC_DIR = ${TOP_SRC_DIR}")
  16
  17 set(LYX_CMAKE_DIR "development/cmake")
  18 set(TOP_CMAKE_PATH "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}")
  19 set(TOP_MODULE_PATH "${TOP_CMAKE_PATH}/modules")
  20 set(TOP_SCRIPT_PATH "${TOP_CMAKE_PATH}/scripts")
  21
  22 set(CMAKE_MODULE_PATH "${TOP_MODULE_PATH}")
  23
  24 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  25
  26 message(STATUS)
  27 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  28         message(STATUS "Building in-source")
  29         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  30 else()
  31         message(STATUS "Building out-of-source")
  32         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  33 endif()
  34
  35 # This directory should be used if some test uses lyx-executable
  36 set(LYX_TESTS_USERDIR "${TOP_BINARY_DIR}/Testing/.lyx")
  37 file(MAKE_DIRECTORY "${LYX_TESTS_USERDIR}")
  38
  39 if(COMMAND cmake_policy)
  40         # Installing MACOSX_BUNDLE targets requires a BUNDLE DESTINATION
  41         cmake_policy(SET CMP0006 NEW)
  42         if(POLICY CMP0043)
  43                 # COMPILE_DEFINITIONS are not used yet. Enable new behavior.
  44                 cmake_policy(SET CMP0043 NEW)
  45         endif()
  46 endif()
  47
  48 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  49
  50 # Supress regeneration
  51 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  52
  53 if(LYX_XMINGW)
  54     set(CMAKE_SYSTEM_NAME Windows)
  55     set(TOOLNAME ${LYX_XMINGW})
  56     set(TOOLCHAIN "${TOOLNAME}-")
  57     set(CMAKE_C_COMPILER   "${TOOLCHAIN}gcc"     CACHE PATH "Mingw C compiler" FORCE)
  58     set(CMAKE_CXX_COMPILER "${TOOLCHAIN}g++"     CACHE PATH "Mingw C++ compiler" FORCE)
  59     set(CMAKE_RC_COMPILER  "${TOOLCHAIN}windres" CACHE PATH "Mingw rc compiler" FORCE)
  60
  61     set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM BOTH)
  62     set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY)
  63     set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY)
  64 endif()
  65
  66 if(NOT help AND NOT HELP)
  67   # 'project' triggers the searching for a compiler
  68   project(${LYX_PROJECT})
  69   if (CMAKE_COMPILER_IS_GNUCXX)
  70     if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS "4.0")
  71       message(STATUS "Gnu CXX compiler version = ${CMAKE_CXX_COMPILER_VERSION}")
  72       message(STATUS "is too old, should be >= 4.0")
  73       message(FATAL_ERROR "Exiting")
  74     endif()
  75   endif()
  76 endif()
  77
  78 if(UNIX)
  79         set(ARCH_TRIPLET )
  80         FIND_PROGRAM(DPKG_ARCHITECTURE_EXECUTABLE dpkg-architecture)
  81         if(DPKG_ARCHITECTURE_EXECUTABLE)
  82                 EXECUTE_PROCESS(COMMAND ${DPKG_ARCHITECTURE_EXECUTABLE} -qDEB_HOST_MULTIARCH
  83                                 OUTPUT_VARIABLE ARCH_TRIPLET
  84                                 ERROR_VARIABLE ERROR_ARCH_TRIPLET
  85                                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  86         endif()
  87 endif()
  88 if(ARCH_TRIPLET)
  89         set(SYSTEM_LIB_DIRS /usr/lib /usr/lib/${ARCH_TRIPLET} /usr/local/lib)
  90 else()
  91         set(SYSTEM_LIB_DIRS /usr/lib /usr/local/lib)
  92 endif()
  93
  94 include(LyXMacros)
  95 include(LyXDestinations)
  96
  97 # Usage LYX_OPTION
  98 # 1. parameter: option name without prefix 'LYX_'
  99 # 2. parameter: description
 100 # 3. parameter: default value, ON or OFF
 101 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
 102
 103 # Usage LYX_COMBO
 104 # 1. parameter: name without prefix 'LYX_'
 105 # 2. parameter: description
 106 # 3. parameter: default value
 107 # 4-n parameter: possible other string values
 108
 109 LYX_OPTION_INIT()
 110
 111 # Options for all compilers/systems
 112 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
 113 LYX_OPTION(LOCALVERSIONING  "Add version info to created package name (only used if LYX_CPACK option set)" OFF ALL)
 114 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
 115 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
 116 LYX_OPTION(REQUIRE_SPELLCHECK "Abort if no spellchecker available" OFF ALL)
 117 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
 118 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
 119 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
 120 LYX_OPTION(DEVEL_VERSION    "Build developer version" OFF ALL)
 121 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" OFF ALL)
 122 LYX_OPTION(DEBUG            "Enforce debug build"  OFF ALL)
 123 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
 124 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
 125 LYX_STRING(SUFFIX_VALUE     "Use this string as suffix" "")
 126 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
 127 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
 128 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
 129 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
 130 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
 131 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
 132 LYX_OPTION(ENABLE_URLTESTS  "Enable for URL tests" OFF ALL)
 133 LYX_OPTION(ENABLE_EXPORT_TESTS "Enable for export tests" OFF ALL)
 134 LYX_OPTION(ENABLE_KEYTESTS  "Enable for keytests" OFF ALL)
 135 LYX_OPTION(ASAN             "Use address sanitizer" OFF ALL)
 136 LYX_COMBO(USE_QT            "Use Qt version as frontend" AUTO QT4 QT5)
 137 #LYX_OPTION(3RDPARTY_BUILD   "Build 3rdparty libs" OFF ALL)
 138 LYX_OPTION(EXTERNAL_Z       "OFF := Build 3rdparty lib zlib" ON ALL)
 139 LYX_OPTION(EXTERNAL_ICONV   "OFF := Build 3rdparty lib iconvlib" ON ALL)
 140 LYX_OPTION(EXTERNAL_HUNSPELL "OFF := Build 3rdparty lib hunspelllib" ON ALL)
 141 LYX_COMBO(EXTERNAL_MYTHES   "OFF := Build 3rdparty lib mytheslib" AUTO OFF ON)
 142
 143 # GCC specific
 144 LYX_OPTION(PROFILE              "Build profile version" OFF GCC)
 145 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" OFF GCC)
 146 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
 147 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
 148 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++ pedantic debug mode" OFF GCC)
 149 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" OFF GCC)
 150 LYX_OPTION(PROFILE              "Build with options for gprof" OFF GCC)
 151
 152 # MSVC specific
 153 LYX_OPTION(CONSOLE               "Show console on Windows, enforce with =FORCE" ON MSVC)
 154 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
 155 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
 156 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
 157
 158 # APPLE specific
 159 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
 160 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
 161
 162
 163 if(help OR HELP)
 164         message(STATUS)
 165         message(STATUS "Available options: (dis/enable with -DLYX_*=OFF/ON)")
 166         message(STATUS)
 167         LYX_OPTION_LIST_ALL(help)
 168         message(STATUS)
 169         RETURN()
 170 endif()
 171
 172 # Check option dependencies
 173
 174 if(LYX_DMG)
 175         set(LYX_BUNDLE ON)
 176         set(LYX_CPACK ON)
 177 endif()
 178
 179 if(LYX_CPACK)
 180         set(LYX_INSTALL ON)
 181 endif()
 182
 183 if(LYX_INSTALL)
 184         set(LYX_NLS ON)
 185         if(WIN32 AND NOT MINGW)
 186                 set(LYX_HUNSPELL ON)
 187         endif()
 188         if(LYX_CONSOLE MATCHES "FORCE")
 189                 set(LYX_CONSOLE ON)
 190         else()
 191                 set(LYX_CONSOLE OFF)
 192         endif()
 193         set(LYX_PACKAGE_SUFFIX ON)
 194         if(NOT LYX_DEBUG)
 195                 set(LYX_RELEASE ON)
 196         endif()
 197         set(LYX_PROFILE OFF)
 198 endif()
 199
 200
 201 if(LYX_MERGE_FILES)
 202         set(LYX_PCH OFF)
 203 else()
 204         set(LYX_MERGE_REBUILD OFF)
 205 endif()
 206
 207 if(LYX_DEPENDENCIES_DOWNLOAD)
 208         message(STATUS)
 209         if(MSVC14)
 210                 set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2015-deps)
 211                 set(deps_files lyx-windows-deps-msvc2015.zip)
 212                 set(deps_server http://ftp.lyx.de/LyX-Windows-Deps)
 213                 set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2015)
 214         elseif(MSVC10)
 215                 set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 216                 set(deps_files lyx-windows-deps-msvc2010.zip)
 217                 set(deps_server http://ftp.lyx.de/LyX-Windows-Deps)
 218                 set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2010)
 219         else()
 220                 message(FATAL_ERROR "error: no dependency package known for the selected MSVC version.")
 221         endif()
 222     message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 223         foreach(it ${deps_files})
 224                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 225                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 226                 if(NOT already_downloaded)
 227                         message(STATUS "Downloading ${it} ...")
 228                         file(DOWNLOAD ${deps_server}/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS STATUS status LOG log)
 229                         list(GET status 0 status_code)
 230                         list(GET status 1 status_string)
 231                         if(NOT status_code EQUAL 0)
 232                                 file(REMOVE ${LYX_DEPENDENCIES_DIR}/${it})
 233                                 message(FATAL_ERROR "error: downloading '${it}' failed. status_code: ${status_code}, status_string: ${status_string}. \nLog: ${log} ")
 234                         endif()
 235                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 236                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 237                 endif()
 238         endforeach()
 239 endif()
 240
 241
 242
 243 message(STATUS)
 244
 245 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 246 if(WIN32)
 247         set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 248 else()
 249         set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 250 endif()
 251
 252
 253 # Set to some meaningful default
 254 find_package(CXX11Compiler)
 255 if(NOT CXX11COMPILER_FOUND)
 256         message(FATAL_ERROR "A C++11 compatible compiler is required.")
 257 endif()
 258 set(LYX_GCC11_MODE)
 259 if(UNIX OR MINGW)
 260         if (CMAKE_CXX_COMPILER_ID MATCHES "^[cC]lang$")
 261           # ignore the GCC_VERSION for clang
 262           # and use the resulting CXX11_STD_REGEX found in FindCXX11Compiler.cmake
 263           message(STATUS "Using clang")
 264           if(CXX11_STD_REGEX)
 265             set(LYX_USE_STD_REGEX 1)
 266           else()
 267             set(LYX_USE_STD_REGEX 0)
 268           endif()
 269         else()
 270           execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION OUTPUT_STRIP_TRAILING_WHITESPACE)
 271           message(STATUS "Using GCC version ${GCC_VERSION}")
 272           if(GCC_VERSION VERSION_LESS 4.9)
 273                   if(GCC_VERSION VERSION_LESS 4.6)
 274                           message(FATAL_ERROR "gcc >= 4.6 is required.")
 275                   endif()
 276                   # <regex> in gcc is unusable in versions less than 4.9.0
 277                   # see https://gcc.gnu.org/bugzilla/show_bug.cgi?id=53631
 278                   set(LYX_USE_STD_REGEX 0)
 279           else()
 280                   set(LYX_USE_STD_REGEX 1)
 281           endif()
 282         endif()
 283         set(LYX_GCC11_MODE "${CXX11_FLAG}")
 284 else()
 285         set(LYX_USE_STD_REGEX 0)
 286 #       if(MSVC10)
 287 #               set(LYX_USE_STD_REGEX 1) #TODO should we use it in ECMAScript mode?
 288 #       endif()
 289 endif()
 290
 291
 292 set(VERSION_INFO "CMake Build")
 293
 294 # Try to get some informations from configure.ac
 295
 296 include(LyXPaths)
 297 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 298
 299 if(WIN32)
 300         set(CMAKE_PREFIX_PATH Specify-path-to-Qt CACHE PATH "Used Qt version")
 301         if(MSVC)
 302                 set(LYX_3RDPARTY_BUILD ON CACHE BOOL "Build 3rdparty libraries" FORCE)
 303         endif()
 304         set(USE_WINDOWS_PACKAGING ON)
 305 elseif(APPLE)
 306         set(USE_MACOSX_PACKAGING ON)
 307 else()
 308         set(USE_POSIX_PACKAGING ON)
 309 endif()
 310
 311 if(LYX_3RDPARTY_BUILD)
 312   # LYX_3RDPARTY_BUILD is not cached anymore, but for compatibility reasons
 313   # this enables the build of all 3rd_party libs
 314   set(LYX_EXTERNAL_Z        OFF CACHE BOOL "Build 3rdparty lib zlib"    FORCE)
 315   set(LYX_EXTERNAL_ICONV    OFF CACHE BOOL "Build 3rdparty iconvlib"    FORCE)
 316   set(LYX_EXTERNAL_HUNSPELL OFF CACHE BOOL "Build 3rdparty hunspelllib" FORCE)
 317   set(LYX_EXTERNAL_MYTHES   OFF CACHE STRING "Build 3rdparty mytheslib" FORCE)
 318 endif()
 319
 320 macro(setstripped _varname)
 321         if(${ARGC} GREATER 1)
 322                 string(STRIP "${ARGV1}" _v)
 323                 if(USE_POSIX_PACKAGING)
 324                         string(TOLOWER ${_v} ${_varname})
 325                 else()
 326                         set(${_varname} ${_v})
 327                 endif()
 328         else()
 329                 set(${_varname})
 330         endif()
 331 endmacro(setstripped)
 332
 333 foreach(_c_l ${_config_lines} )
 334         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 335                 setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 336                 setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 337                 setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 338                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\)\(\\.\([0-9]+\)\)?.*$")
 339                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 340                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 341                         set(LYX_PATCH_VERSION ${CMAKE_MATCH_4})
 342                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 343                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 344                         if ("${LYX_SUFFIX_VALUE}" MATCHES "")
 345                           set(LYX_INSTALL_SUFFIX "${LYX_MAJOR_VERSION}.${LYX_MINOR_VERSION}")
 346                         else()
 347                           set(LYX_INSTALL_SUFFIX "${LYX_SUFFIX_VALUE}")
 348                         endif()
 349                 endif()
 350         endif()
 351         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 352                 set(LYX_DATE "${CMAKE_MATCH_1}")
 353         endif()
 354 endforeach(_c_l)
 355
 356 FIND_PROGRAM(LYX_GITVERSION git)
 357 #message(STATUS "gitversion = ${LYX_GITVERSION}")
 358 set(LYX_REVISION_VERSION ${LYX_PATCH_VERSION})
 359 if(LYX_GITVERSION)
 360   if (LYX_LOCALVERSIONING)
 361     # Find the revision number and for later use
 362     EXECUTE_PROCESS(COMMAND ${LYX_GITVERSION} describe --match 2.0.0 HEAD
 363       WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE LYX_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 364     if (LYX_PACKAGE_RELEASE MATCHES "^2\\.0\\.0\\-\([0-9]+\)\\-.*$")
 365       # We will add offset of 40000 to get appropriate value to
 366       # previous svn.
 367       # We use this value than also to set the package-patch-value
 368       MATH(EXPR tmp_REVISION_VERSION "(${CMAKE_MATCH_1}+40000)")
 369       set(LYX_REVISION_VERSION "${LYX_PATCH_VERSION}-${tmp_REVISION_VERSION}git")
 370       set(ENABLE_DIST ON)
 371     endif()
 372   endif()
 373 endif()
 374
 375 # Set the programs (lyx, tex2lyx, etc.) suffix
 376 # When building an OS X bundle, we will append
 377 # the suffix only to the bundle, not to the programs
 378 set(PROGRAM_SUFFIX "")
 379 if(LYX_PROGRAM_SUFFIX AND NOT (APPLE AND LYX_BUNDLE))
 380         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 381 endif()
 382 set(_lyx "${PACKAGE_BASE}${PROGRAM_SUFFIX}")
 383 set(_tex2lyx tex2lyx${PROGRAM_SUFFIX})
 384
 385 add_custom_target(lyx_version ALL
 386   COMMAND ${CMAKE_COMMAND} -DTOP_SRC_DIR=${TOP_SRC_DIR} -DTOP_CMAKE_PATH=${TOP_CMAKE_PATH} -DTOP_BINARY_DIR=${TOP_BINARY_DIR} -DLYX_DATE=${LYX_DATE} -P ${TOP_SCRIPT_PATH}/LyXGetVersion.cmake
 387   )
 388 set_target_properties(lyx_version PROPERTIES FOLDER "applications")
 389
 390 # Default paths for installed utilities (tex2lyx, lyxclient, etc.)
 391 set(LYX_UTILITIES_INSTALL_PATH bin)
 392
 393 if(LYX_BUNDLE)
 394         set(LYX_CPACK ON)
 395
 396         message(STATUS)
 397         message(STATUS "Bundle creation is enabled (experimental):")
 398         message(STATUS "    make")
 399         message(STATUS "    make install/strip")
 400         message(STATUS "    make package")
 401         if(APPLE)
 402                 set(MACOSX_BUNDLE TRUE)
 403                 # This sets the bundle + executable names
 404                 set(_lyx "${PACKAGE_BASE}${LYX_INSTALL_SUFFIX}")
 405                 # This sets the Info.plist executable name
 406                 set(osx_bundle_program_name ${_lyx})
 407                 # Bundle name
 408                 set(LYX_BUNDLE_NAME ${_lyx})
 409
 410                 # This will contain the list of files that need to be included
 411                 # in the bundle and their location within the bundle
 412                 set(OSX_BUNDLE_FILES "${TOP_SRC_DIR}/development/MacOSX/LyX.sdef;${TOP_SRC_DIR}/development/MacOSX/LyXapp.icns;${CMAKE_BINARY_DIR}/lyxrc.dist")
 413                 set(OSX_BUNDLE_DIRS "Resources;Resources;Resources")
 414
 415                 # Process Info.plist and lyxrc.dist
 416                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/Info.plist.in" "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 417                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/lyxrc.dist.in" "${CMAKE_CURRENT_BINARY_DIR}/lyxrc.dist")
 418
 419                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 420                 set(LYX_DATA_SUBDIR ${LYX_BUNDLE_NAME}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 421
 422                 # Variables used by CPack
 423                 set(CPACK_BUNDLE_NAME ${LYX_BUNDLE_NAME})
 424                 set(CPACK_BUNDLE_PLIST "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 425                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${LYX_BUNDLE_NAME}.app)
 426
 427                 # Set the install paths
 428                 set(LYX_UTILITIES_INSTALL_PATH ${LYX_BUNDLE_NAME}.app/Contents/MacOS)
 429                 if(NOT LYX_INSTALL_PREFIX)
 430                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 431                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 432                 endif()
 433                 # Change the owner so that the install can work
 434                 install(CODE "set(BU_CHMOD_BUNDLE_ITEMS 1)" COMPONENT Runtime)
 435         elseif(UNIX)
 436                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 437                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 438                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 439         elseif(WIN32)
 440                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 441         endif()
 442 endif()
 443
 444 if(LYX_INSTALL_PREFIX)
 445         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 446         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 447 endif()
 448 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 449
 450 if(UNIX)
 451   set(SYSTEM_DATADIR "${CMAKE_INSTALL_PREFIX}/share")
 452 elseif(CMAKE_INSTALL_PREFIX MATCHES "/lyx${LYX_INSTALL_SUFFIX}$")
 453   string(REGEX REPLACE "/lyx${LYX_INSTALL_SUFFIX}$" "/share" SYSTEM_DATADIR ${CMAKE_INSTALL_PREFIX})
 454 else()
 455   set(SYSTEM_DATADIR "${CMAKE_INSTALL_PREFIX}")
 456 endif()
 457
 458 if(CMAKE_COMPILER_IS_GNUCXX)
 459   message(STATUS "CMAKE_COMPILER_IS_GNUCXX = ${CMAKE_COMPILER_IS_GNUCXX}")
 460   set(suffixing ${LYX_PROGRAM_SUFFIX})
 461 else()
 462   # Not a GCC compiler, programs do not have a suffix
 463   set(suffixing ${LYX_PACKAGE_SUFFIX})
 464 endif()
 465
 466 # The define PACKAGE below allows lyx-executable to find its default configuration files
 467 # see routines
 468 #    Package::messages_file()
 469 #    get_default_user_support_dir()
 470 #    relative_system_support_dir()
 471 # in src/support/Package.cpp
 472 #
 473 if(suffixing)
 474         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 475 else()
 476         set(PACKAGE ${PACKAGE_BASE})
 477 endif()
 478
 479 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 480         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 481         if (UNIX)
 482                 # use the default "/usr/local"
 483                 # but respect the user-choice on the command-line
 484                 set(CMAKE_INSTALL_PREFIX "/usr/local" CACHE PATH "LyX default install prefix" FORCE)
 485         endif()
 486 endif()
 487 if(WIN32)
 488         set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 489 endif()
 490 if(IS_ABSOLUTE)
 491         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 492 else()
 493         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 494 endif()
 495
 496
 497
 498 if(NOT LYX_DATA_SUBDIR)
 499         if (WIN32)
 500                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 501         else()
 502                 set(LYX_DATA_SUBDIR "share/${_lyx}/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 503         endif()
 504 endif()
 505
 506 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 507 get_locale_destination(LYX_LOCALEDIR)
 508 set(LYX_ABS_INSTALLED_LOCALEDIR "${CMAKE_INSTALL_PREFIX}/${LYX_LOCALEDIR}")
 509 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 510
 511 if(LYX_BUNDLE AND APPLE)
 512         set(LYX_MAN_DIR "${LYX_DATA_SUBDIR}" CACHE STRING "Install location for man pages.")
 513 else()
 514         if(WIN32)
 515                 set(LYX_MAN_DIR "${CMAKE_BINARY_DIR}/usr/local/man" CACHE STRING "Install location for man pages.")
 516         elseif(UNIX)
 517                 set(LYX_MAN_DIR "${CMAKE_INSTALL_PREFIX}/share/man" CACHE STRING "Install location for man pages.")
 518         else()
 519                 set(LYX_MAN_DIR "${CMAKE_INSTALL_PREFIX}/man" CACHE STRING "Install location for man pages.")
 520         endif()
 521 endif()
 522 mark_as_advanced(LYX_MAN_DIR)
 523
 524 if(LYX_INSTALL AND WIN32)
 525         message(STATUS "Configuring NSIS files")
 526         configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 527         configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 528         configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 529         message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 530 endif()
 531
 532 if(NOT GROUP_CODE)
 533         #set(GROUP_CODE "The Golden Code")
 534         set(GROUP_CODE flat)
 535 endif()
 536
 537 # lyx's source files
 538 set(LYX_CPP_FILES [a-zA-Z]*.cpp)
 539 set(LYX_HPP_FILES [a-zA-Z]*.h)
 540 set(LYX_MOC_FILES moc_*.cpp)
 541
 542 include(ProjectSourceGroup)
 543
 544
 545 if(LYX_PROFILE AND NOT MSVC)
 546         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 547         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg")
 548         set(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS}  -pg")
 549 else()
 550         set(LYX_PROFILE OFF)
 551 endif()
 552
 553
 554 if(LYX_NO_OPTIMIZE)
 555         set(CMAKE_BUILD_TYPE None)
 556         set(LYX_DEBUG OFF)
 557         set(LYX_RELEASE OFF)
 558         set(LYX_PROFILE OFF)
 559 elseif(LYX_RELEASE)
 560         set(CMAKE_BUILD_TYPE Release)
 561         set(LYX_DEBUG OFF)
 562         set(LYX_PROFILE OFF)
 563 elseif(LYX_PROFILE)
 564         set(CMAKE_BUILD_TYPE Profile)
 565         set(LYX_DEBUG OFF)
 566 else()
 567         set(CMAKE_BUILD_TYPE Debug)
 568         set(LYX_DEBUG ON)
 569 endif()
 570
 571
 572 # When shared libs are supported enable this option
 573 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 574 if(LYX_SHARED_LIBRARIES)
 575         set(library_type SHARED)
 576 else()
 577         set(library_type STATIC)
 578 endif()
 579
 580 if(NOT MSVC)
 581         if(NOT LYX_QUIET)
 582                 set(CMAKE_VERBOSE_MAKEFILE ON)
 583         endif()
 584         set(LYX_CXX_FLAGS "-Wall -Wunused-parameter ${LYX_GCC11_MODE}")
 585         if(LYX_CXX_FLAGS MATCHES "\\+\\+(14|11|98)")
 586           # Thanks to Brad King <brad.king@kitware.com>
 587           # for the pointer to https://cmake.org/cmake/help/v3.6/variable/CMAKE_CXX_STANDARD.html
 588           # This allows us to use QT5.7 with recent g++ (version >= 4.9) compilers
 589           # and still use our own c++ extension tests
 590           set(CMAKE_CXX_STANDARD ${CMAKE_MATCH_1})
 591           message(STATUS "CMAKE_CXX_STANDARD set to ${CMAKE_CXX_STANDARD}")
 592         endif()
 593         if(LYX_STDLIB_DEBUG)
 594                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 595         endif()
 596         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 597         set(CMAKE_CXX_FLAGS_DEBUG "${LYX_CXX_FLAGS} -fno-strict-aliasing -O0 -g3 -D_DEBUG" CACHE TYPE STRING FORCE)
 598         if(MINGW)
 599                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 600         else()
 601                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 602         endif()
 603 endif()
 604
 605 set(LYX_CXX_FLAGS_EXTRA "" CACHE STRING "Desired semicolon separated list of extra cxx compile flags, like '-Werror'")
 606 mark_as_advanced(LYX_CXX_FLAGS_EXTRA)
 607 if(LYX_CXX_FLAGS_EXTRA)
 608         foreach(_flag ${LYX_CXX_FLAGS_EXTRA})
 609                 add_definitions(${_flag})
 610         endforeach()
 611 endif()
 612
 613 if(LYX_XMINGW)
 614         list(APPEND CMAKE_FIND_ROOT_PATH ${GNUWIN32_DIR})
 615 endif()
 616
 617 set(min_qt5_version "5.6")
 618 if(LYX_USE_QT MATCHES "AUTO")
 619         # try qt5 first
 620         find_package(Qt5Core QUIET)
 621         if(Qt5Core_FOUND)
 622                 set(LYX_USE_QT "QT5" CACHE STRING "Valid qt version" FORCE)
 623                 message(STATUS "Qt5Core_VERSION = ${Qt5Core_VERSION}")
 624                 if(Qt5Core_VERSION VERSION_LESS ${min_qt5_version})
 625                         find_package(Qt4 "4.5.0" QUIET)
 626                         if(QT4_FOUND)
 627                                 set(LYX_USE_QT "QT4" CACHE STRING "Valid qt version" FORCE)
 628                         endif()
 629                 endif()
 630         else()
 631                 set(LYX_USE_QT "QT4" CACHE STRING "Valid qt version" FORCE)
 632         endif()
 633 endif()
 634 if(LYX_USE_QT MATCHES "QT5")
 635         # set QPA_XCB if QT uses X11
 636         find_package(Qt5Core REQUIRED)
 637         if (Qt5Core_FOUND)
 638                 find_package(Qt5Widgets REQUIRED)
 639                 if(APPLE)
 640                         find_package(Qt5MacExtras REQUIRED)
 641                 endif()
 642                 find_package(Qt5X11Extras QUIET)
 643                 find_package(Qt5WinExtras QUIET)
 644                 set(QTVERSION ${Qt5Core_VERSION})
 645                 if (QTVERSION VERSION_LESS ${min_qt5_version})
 646                         message(STATUS "QTVERSION = \"${QTVERSION}\"")
 647                         message(STATUS "This version is not recommended, try either option -DLYX_USE_QT=QT4 or")
 648                         message(STATUS "install QT-Version >= \"${min_qt5_version}\"")
 649                         # see thread in lyx-devel list
 650                         # From: Jean-Pierre Chrétien <jeanpierre.chretien@free.fr>
 651                         # Date 11.03.2017
 652                         # Subject: cmake compilation error
 653                         #message(FATAL_ERROR "Wrong Qt-Version")
 654                 endif()
 655                 macro (qt_use_modules)
 656                         qt5_use_modules(${ARGN})
 657                 endmacro()
 658                 macro (qt_add_resources)
 659                         qt5_add_resources(${ARGN})
 660                 endmacro()
 661                 macro (qt_wrap_uifiles)
 662                         qt5_wrap_ui(${ARGN})
 663                 endmacro()
 664                 message(STATUS "Found Qt-Version ${QTVERSION}")
 665                 if(WIN32)
 666                         set(LYX_QTMAIN_LIBRARY ${Qt5Core_QTMAIN_LIBRARIES})
 667                 endif()
 668         endif()
 669 elseif(LYX_USE_QT MATCHES "QT4")
 670         if(LYX_XMINGW)
 671                 set(QT_MINGW_DIR ${LYX_QT4} CACHE PATH "Qt for Mingw" FORCE)
 672                 list(APPEND CMAKE_FIND_ROOT_PATH ${QT_MINGW_DIR} ${GNUWIN32_DIR})
 673         endif()
 674         find_package(Qt4 "4.5.0" REQUIRED)
 675         macro (qt_use_modules)
 676         endmacro()
 677         macro (qt_add_resources)
 678                 qt4_add_resources(${ARGN})
 679         endmacro()
 680         macro (qt_wrap_uifiles)
 681                 qt4_wrap_ui(${ARGN})
 682         endmacro()
 683         set(LYX_QTMAIN_LIBRARY ${QT_QTSVG_LIBRARY})
 684         if(WIN32)
 685                 list(APPEND LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARIES})
 686         endif()
 687 else()
 688   message(FATAL_ERROR "Unhandled value for LYX_USE_QT (${LYX_USE_QT})")
 689 endif()
 690
 691 find_package(Magic)
 692 if(Magic_FOUND)
 693         set(HAVE_MAGIC_H 1)
 694 endif()
 695
 696 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 697
 698 set(Spelling_FOUND OFF)
 699 set(Include_used_spellchecker)   # String will be inserted into config.h
 700
 701 if (LYX_EXTERNAL_MYTHES MATCHES "AUTO")
 702   # try system library first
 703   find_package(MyThesLIB)
 704   if (MYTHESLIB_FOUND)
 705     set(LYX_EXTERNAL_MYTHES ON CACHE STRING "OFF:= Build 3rdparty mytheslib" FORCE)
 706   else()
 707     set(LYX_EXTERNAL_MYTHES OFF CACHE STRING "OFF:= Build 3rdparty mytheslib" FORCE)
 708   endif()
 709 endif()
 710 if (LYX_EXTERNAL_MYTHES MATCHES "ON")
 711   find_package(MyThesLIB REQUIRED)
 712 else()
 713   add_subdirectory(3rdparty/mythes)
 714 endif()
 715 set(MYTHES_DIR ${MYTHESLIB_INCLUDE_DIR})
 716
 717 if(NOT LYX_EXTERNAL_HUNSPELL)
 718     add_subdirectory(3rdparty/hunspell)
 719     add_definitions(-DHUNSPELL_STATIC)
 720     set(HUNSPELL_FOUND ON)
 721     message(STATUS "  * Hunspell:")
 722     message(STATUS "     - include: ${HUNSPELL_INCLUDE_DIR}")
 723     message(STATUS "     - library: ${HUNSPELL_LIBRARY}")
 724 endif()
 725
 726 foreach(_spell "ASPELL" "Enchant" "Hunspell")
 727   string(TOUPPER ${_spell} _upspell)
 728   if (NOT ${_upspell}_FOUND)
 729     find_package(${_spell})
 730   endif()
 731   if (${_upspell}_FOUND)
 732     include_directories(${${_upspell}_INCLUDE_DIR})
 733     set(Spelling_FOUND ON)
 734     message(STATUS "Building with USE_${_upspell}")
 735     set(Include_used_spellchecker "${Include_used_spellchecker}#define USE_${_upspell} 1\n")
 736   else()
 737     if(LYX_${_upspell})
 738       message(FATAL_ERROR "Required ${_spell} devel package not found")
 739     else()
 740       message(STATUS "${_upspell} not found, building without ${_spell} support")
 741     endif()
 742   endif()
 743 endforeach()
 744
 745 if(GNUWIN32_DIR)
 746         list(APPEND CMAKE_PROGRAM_PATH "${GNUWIN32_DIR}/Python" )
 747 endif()
 748
 749 # Search for python default version first
 750 unset(PYTHON_EXECUTABLE CACHE)
 751 unset(LYX_PYTHON_EXECUTABLE CACHE)
 752 unset(PYTHON_VERSION_MAJOR)
 753 unset(PYTHON_VERSION_MINOR)
 754 unset(PYTHON_VERSION_STRING)
 755 find_package(PythonInterp 3.3 QUIET)
 756 if(NOT PYTHONINTERP_FOUND)
 757   unset(PYTHON_EXECUTABLE CACHE)
 758   find_package(PythonInterp 2.0 REQUIRED)
 759   if(NOT PYTHON_VERSION_STRING VERSION_LESS 2.8)
 760     message(FATAL_ERROR "Python interpreter found, but is not suitable")
 761   endif()
 762 endif()
 763
 764 set(LYX_PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 765
 766 if(LYX_NLS)
 767         find_package(LyXGettext)
 768         if(LYX_PYTHON_EXECUTABLE AND GETTEXT_FOUND)
 769                 add_subdirectory(po "${TOP_BINARY_DIR}/po")
 770         else()
 771                 # Install only supplied .gmo-files
 772                 file(GLOB _gmofiles RELATIVE "${TOP_SRC_DIR}/po" "${TOP_SRC_DIR}/po/*.gmo")
 773                 message(STATUS "Installing provided .gmo-files only")
 774                 foreach( _gmo ${_gmofiles})
 775                         string(REGEX REPLACE "\\.gmo$" "" _lang ${_gmo})
 776                         install(FILES "${TOP_SRC_DIR}/po/${_gmo}" DESTINATION ${LYX_LOCALEDIR}/${_lang}/LC_MESSAGES RENAME ${PACKAGE}.mo)
 777                 endforeach()
 778         endif()
 779 endif()
 780
 781 if(LYX_EXTERNAL_ICONV)
 782   find_package(ICONV REQUIRED)
 783 else()
 784   add_subdirectory(3rdparty/libiconv)
 785   set(HAVE_ICONV_CONST 1)
 786 endif()
 787
 788 if(LYX_EXTERNAL_Z)
 789   find_package(ZLIB REQUIRED)
 790 else()
 791   add_subdirectory(3rdparty/zlib)
 792 endif()
 793
 794 if(LYX_EXTERNAL_BOOST)
 795         message(STATUS "Searching for boost")
 796         if(NOT LYX_USE_STD_REGEX)
 797                 find_package(Boost COMPONENTS regex)
 798         endif()
 799         if(Boost_FOUND)
 800                 message(STATUS "Boost found")
 801                 message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 802                 set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 803                 if (LYX_STDLIB_DEBUG)
 804                         # Comment from  Jean-Marc Lasgouttes:
 805                         # In general, system boost libraries are incompatible with
 806                         # the use of stdlib-debug in libstdc++. See ticket #9736 for
 807                         # details.
 808                         message(WARNING "Compiling LyX with stdlib-debug and system boost libraries may lead to crashes. Consider using '-DLYX_STDLIB_DEBUG=OFF' or using '-DLYX_EXTERNAL_BOOST=OFF'")
 809                 endif()
 810         else()
 811                 message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 812         endif()
 813 else()
 814         if(NOT LYX_USE_STD_REGEX)
 815                 set(Lyx_Boost_Libraries boost_regex)
 816         endif()
 817         add_definitions(-DBOOST_USER_CONFIG=<config.h>)
 818         include_directories(${TOP_SRC_DIR}/3rdparty/boost)
 819         add_subdirectory(3rdparty/boost "${TOP_BINARY_DIR}/3rdparty/boost")
 820 endif()
 821
 822
 823
 824
 825 if(WIN32)
 826         if(LYX_CONSOLE)
 827                 set(LYX_QTMAIN_LIBRARY)
 828         else()
 829                 set(WIN32_CONSOLE WIN32)
 830         endif()
 831         if(MSVC)
 832                 # -DPSAPI_VERSION=1 is needed to run on vista (bug 10186)
 833                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX -DPSAPI_VERSION=1)
 834                 # disable checked iterators for msvc release builds to get maximum speed
 835                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 836         else()
 837                 # -DPSAPI_VERSION=1 is not needed for mingw, since the mingw psapi.h
 838                 # does not use it and always declares the vista compatible API.
 839                 # If this ever changes then -DPSAPI_VERSION might be needed here as well.
 840                 add_definitions(-DWINVER=0x0500)
 841         endif()
 842 endif()
 843
 844 # Compute qt-version from ${QTVERSION}
 845
 846 message(STATUS "")
 847 foreach(_v PACKAGE PACKAGE_VERSION
 848         PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 849         LYX_ABS_TOP_SRCDIR
 850         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 851         if(NOT DEFINED ${_v})
 852                 message(FATAL_ERROR "${_v} not defined")
 853         endif()
 854         string(SUBSTRING "${_v}                            " 0 28 _v1)
 855         message(STATUS "----- ${_v1}: ${${_v}}")
 856 endforeach(_v)
 857 message(STATUS "")
 858
 859
 860 if(LYX_PCH)
 861         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 862         # Not sure if it works for all non-msvc compilers
 863         include(PCHSupport_26)
 864         configure_file(${TOP_CMAKE_PATH}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
 865         configure_file(${TOP_CMAKE_PATH}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 866         add_definitions(-DLYX_ENABLE_PCH)
 867
 868         if(MSVC)
 869                 macro(lyx_add_msvc_pch name_)
 870                         set_source_files_properties(${${name_}_sources} PROPERTIES
 871                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 872                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
 873                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 874                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
 875                                 ${TOP_BINARY_DIR}/pcheaders.h)
 876                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 877                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 878                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 879                 endmacro(lyx_add_msvc_pch)
 880                 macro(lyx_add_gcc_pch name_)
 881                 endmacro()
 882         else()
 883                 macro(lyx_add_msvc_pch name_)
 884                 endmacro()
 885                 macro(lyx_add_gcc_pch name_)
 886                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT)
 887                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
 888                 endmacro()
 889         endif()
 890 else()
 891         macro(lyx_add_msvc_pch)
 892         endmacro(lyx_add_msvc_pch)
 893         macro(lyx_add_gcc_pch name_)
 894         endmacro()
 895 endif()
 896
 897
 898 if(MSVC)
 899
 900         if(LYX_VLD)
 901                 set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/development/Win32/vld)
 902                 add_subdirectory(${vld_path}/cmake)
 903                 include(${vld_path}/cmake/vld.cmake) # forced include
 904                 set(vld_dll vld)
 905         endif()
 906
 907         if(LYX_WALL)
 908                 # Use the highest warning level
 909                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 910
 911                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 912                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 913                 else()
 914                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 915                 endif()
 916
 917                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 918                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 919                 else()
 920                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 921                 endif()
 922
 923                 # add here warnings which should produce an error /weXXXX
 924                 set(MSVC_W_ERROR   "/we4101 /we4189")
 925                 # add here warnings which should be disabled /wdXXXX
 926                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 927
 928                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 929                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 930                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 931
 932         else()
 933                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 934
 935                 # add here warnings which should produce an error /weXXXX
 936                 set(MSVC_W_ERROR   "/we4101 /we4189")
 937                 # add here warnings which should be disabled /wdXXXX
 938                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 939
 940                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 941                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 942                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 943
 944         endif()
 945
 946         if (NOT Qt5Core_FOUND)
 947                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 948                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 949                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 950         endif()
 951
 952         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 953         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 954         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 955         message(STATUS "")
 956 endif()
 957
 958
 959 if(LYX_DEBUG_GLIBC)
 960         set(_GLIBCXX_DEBUG ON)
 961 endif()
 962
 963 if(LYX_DEBUG_GLIBC_PEDANTIC)
 964         set(_GLIBCXX_DEBUG_PEDANTIC ON)
 965 endif()
 966
 967 # Xcode compiler
 968 if (CMAKE_GENERATOR MATCHES Xcode)
 969         if (XCODE_VERSION VERSION_LESS "5.0")
 970                 # Automatically select the Xcode compiler if not set
 971                 if (NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 972                         # XCode >= 3.1 has gcc 4.2 (up to actual Xcode)
 973                         if (XCODE_VERSION VERSION_GREATER "3.1")
 974                                 SET(CMAKE_XCODE_ATTRIBUTE_GCC_VERSION "com.apple.compilers.llvmgcc42")
 975                         ENDIF(XCODE_VERSION VERSION_GREATER "3.1")
 976                 ENDIF(NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 977                 # Print the selected compiler version
 978         MESSAGE(STATUS "---- Using XCode compiler CMAKE_XCODE_ATTRIBUTE_GCC_VERSION=${CMAKE_XCODE_ATTRIBUTE_GCC_VERSION}")
 979         ENDIF(XCODE_VERSION VERSION_LESS "5.0")
 980 ENDIF(CMAKE_GENERATOR MATCHES Xcode)
 981
 982 if (WIN32 AND Qt5Core_FOUND)
 983         set(Z_PREFIX 1)
 984 endif()
 985
 986 # compiler tests, config.h generation LYX_CONFIGURE_CHECKS
 987 include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
 988 configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
 989
 990 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
 991
 992 if(QTVERSION MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+).*")
 993         MATH(EXPR QT4_VERSION "(${CMAKE_MATCH_1}<<16)|(${CMAKE_MATCH_2}<<8)|${CMAKE_MATCH_3}")
 994 endif()
 995
 996 if (NOT HAVE_REGEX)
 997         set(LYX_USE_STD_REGEX 0)
 998 endif()
 999
1000
1001 set (cmd ${CMAKE_CTEST_COMMAND})
1002 if (MSVC)
1003         set (cmd ${cmd} -C ${CMAKE_CFG_INTDIR})
1004 else ()
1005         set (cmd ${cmd} -C ${CMAKE_BUILD_TYPE})
1006 endif ()
1007 add_custom_target (lyx_run_tests COMMAND ${cmd})
1008 set_target_properties(lyx_run_tests PROPERTIES FOLDER "tests")
1009
1010 if(LYX_ASAN)
1011     set(LYX_CXX_FLAGS "-fsanitize=address -fno-omit-frame-pointer -g")
1012     message(STATUS)
1013     message(STATUS "Address sanitizer enabled. Usage:")
1014     message(STATUS "    wget https://llvm.org/svn/llvm-project/compiler-rt/trunk/lib/asan/scripts/asan_symbolize.py")
1015     message(STATUS "    chmod  +x ./asan_symbolize.py")
1016     message(STATUS "    ./bin/lyx2.2 2>&1 | ./asan_symbolize.py  | c++filt ")
1017     message(STATUS)
1018 endif()
1019
1020 if(LYX_INSTALL)
1021         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
1022                 message(STATUS "Python required to create doc!")
1023         else()
1024                 if(UNIX)
1025                         add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
1026                 endif()
1027                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
1028         endif()
1029         include(../Install)
1030 endif()
1031
1032 add_subdirectory(src "${TOP_BINARY_DIR}/src")
1033 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
1034 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
1035 add_subdirectory(lib/examples "${TOP_BINARY_DIR}/lib/examples")
1036 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
1037 add_subdirectory(development/autotests "${TOP_BINARY_DIR}/autotests")
1038 if(LYX_ENABLE_URLTESTS)
1039         add_subdirectory(development/checkurls "${TOP_BINARY_DIR}/checkurls")
1040 endif()
1041
1042 message(STATUS)
1043 message(STATUS "Build params, switch LYX_* options by -DLYX_*=ON or OFF, LYX_* combos by -DLYX_*=value:")
1044 message(STATUS)
1045
1046 LYX_OPTION_LIST_ALL(used)
1047
1048
1049 if(LYX_NLS)
1050         message(STATUS)
1051         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
1052         message(STATUS)
1053         message(STATUS "  * iconv")
1054         message(STATUS "     - include: ${ICONV_INCLUDE_DIR}")
1055         message(STATUS "     - library: ${ICONV_LIBRARY}")
1056         message(STATUS "  * zlib")
1057         message(STATUS "     - include: ${ZLIB_INCLUDE_DIR}")
1058         message(STATUS "     - library: ${ZLIB_LIBRARY}")
1059         message(STATUS)
1060 endif()
1061
1062 # Apple has builtin native spell checker,
1063 # no need to warn for missing Aspell, Hunspell or Enchant
1064 if(NOT Spelling_FOUND AND NOT APPLE)
1065   if(LYX_REQUIRE_SPELLCHECK)
1066     set(_mode "FATAL_ERROR")
1067   else()
1068     set(_mode "STATUS")
1069   endif()
1070   message(${_mode} "No spellcheck libraries found. LyX will be unable use spellchecking")
1071 endif()
1072
1073 include("${TOP_CMAKE_PATH}/LyxPackaging.cmake")
1074
1075 if(ENABLE_DIST)
1076   # Use git to create the source package
1077   # git archive --format=tgz --output=/home/kornel/x.tar.gz master
1078   if(UNIX)
1079     set(DIST_FORMAT tgz)
1080   else()
1081     set(DIST_FORMAT zip)
1082   endif()
1083   set(DIST_NAME ${CMAKE_PROJECT_NAME}-${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}-${CMAKE_SYSTEM_NAME}.${DIST_FORMAT})
1084
1085   add_custom_command(
1086     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME}
1087     COMMAND  ${LYX_GITVERSION} archive --format=${DIST_FORMAT} --output=${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME} master
1088     WORKING_DIRECTORY ${TOP_SRC_DIR})
1089   add_custom_target(git-archive DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME})
1090 endif()
1091
1092 # Last directory to be included so that the fixup code (OS X)
1093 # can be run last
1094 add_subdirectory(development/cmake/post_install)
1095
1096 message(STATUS)