CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 2.6.4)
   8
   9 set(LYX_PROJECT LyX)
  10
  11 # Instruct cmake to not use gnu extensions,
  12 # this prevents the mix of '-std=c++*' and '-std=gnu++*' flags
  13 set(CMAKE_CXX_EXTENSIONS OFF)
  14
  15 enable_testing()
  16
  17 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README REALPATH) # Resolve symlinks
  18 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  19 message(STATUS "TOP_SRC_DIR = ${TOP_SRC_DIR}")
  20
  21 set(LYX_CMAKE_DIR "development/cmake")
  22 set(TOP_CMAKE_PATH "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}")
  23 set(TOP_MODULE_PATH "${TOP_CMAKE_PATH}/modules")
  24 set(TOP_SCRIPT_PATH "${TOP_CMAKE_PATH}/scripts")
  25
  26 set(CMAKE_MODULE_PATH "${TOP_MODULE_PATH}")
  27
  28 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  29
  30 message(STATUS)
  31 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  32         message(STATUS "Building in-source")
  33         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  34 else()
  35         message(STATUS "Building out-of-source")
  36         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  37 endif()
  38
  39 # This directory should be used if some test uses lyx-executable
  40 set(LYX_TESTS_USERDIR "${TOP_BINARY_DIR}/Testing/.lyx")
  41 file(MAKE_DIRECTORY "${LYX_TESTS_USERDIR}")
  42
  43 if(COMMAND cmake_policy)
  44         # Installing MACOSX_BUNDLE targets requires a BUNDLE DESTINATION
  45         cmake_policy(SET CMP0006 NEW)
  46         if(POLICY CMP0043)
  47                 # COMPILE_DEFINITIONS are not used yet. Enable new behavior.
  48                 cmake_policy(SET CMP0043 NEW)
  49         endif()
  50 endif()
  51
  52 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  53
  54 # Supress regeneration
  55 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  56
  57 if(LYX_XMINGW)
  58     set(CMAKE_SYSTEM_NAME Windows)
  59     set(TOOLNAME ${LYX_XMINGW})
  60     set(TOOLCHAIN "${TOOLNAME}-")
  61     set(CMAKE_C_COMPILER   "${TOOLCHAIN}gcc"     CACHE PATH "Mingw C compiler" FORCE)
  62     set(CMAKE_CXX_COMPILER "${TOOLCHAIN}g++"     CACHE PATH "Mingw C++ compiler" FORCE)
  63     set(CMAKE_RC_COMPILER  "${TOOLCHAIN}windres" CACHE PATH "Mingw rc compiler" FORCE)
  64
  65     set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM BOTH)
  66     set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY)
  67     set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY)
  68 endif()
  69
  70 if(NOT help AND NOT HELP)
  71   # 'project' triggers the searching for a compiler
  72   project(${LYX_PROJECT})
  73   if (CMAKE_COMPILER_IS_GNUCXX)
  74     if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS "4.0")
  75       message(STATUS "Gnu CXX compiler version = ${CMAKE_CXX_COMPILER_VERSION}")
  76       message(STATUS "is too old, should be >= 4.0")
  77       message(FATAL_ERROR "Exiting")
  78     endif()
  79   endif()
  80 endif()
  81
  82 if(UNIX)
  83         set(ARCH_TRIPLET )
  84         FIND_PROGRAM(DPKG_ARCHITECTURE_EXECUTABLE dpkg-architecture)
  85         if(DPKG_ARCHITECTURE_EXECUTABLE)
  86                 EXECUTE_PROCESS(COMMAND ${DPKG_ARCHITECTURE_EXECUTABLE} -qDEB_HOST_MULTIARCH
  87                                 OUTPUT_VARIABLE ARCH_TRIPLET
  88                                 ERROR_VARIABLE ERROR_ARCH_TRIPLET
  89                                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  90         endif()
  91 endif()
  92 if(ARCH_TRIPLET)
  93         set(SYSTEM_LIB_DIRS /usr/lib /usr/lib/${ARCH_TRIPLET} /usr/local/lib)
  94 else()
  95         set(SYSTEM_LIB_DIRS /usr/lib /usr/local/lib)
  96 endif()
  97
  98 include(LyXMacros)
  99 include(LyXDestinations)
 100
 101 # Usage LYX_OPTION
 102 # 1. parameter: option name without prefix 'LYX_'
 103 # 2. parameter: description
 104 # 3. parameter: default value, ON or OFF
 105 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
 106
 107 # Usage LYX_COMBO
 108 # 1. parameter: name without prefix 'LYX_'
 109 # 2. parameter: description
 110 # 3. parameter: default value
 111 # 4-n parameter: possible other string values
 112
 113 LYX_OPTION_INIT()
 114
 115 # Options for all compilers/systems
 116 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
 117 LYX_OPTION(LOCALVERSIONING  "Add version info to created package name (only used if LYX_CPACK option set)" OFF ALL)
 118 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
 119 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
 120 LYX_OPTION(REQUIRE_SPELLCHECK "Abort if no spellchecker available" OFF ALL)
 121 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
 122 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
 123 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
 124 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" OFF ALL)
 125 LYX_OPTION(DEBUG            "Enforce debug build"  OFF ALL)
 126 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
 127 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
 128 LYX_STRING(SUFFIX_VALUE     "Use this string as suffix" "")
 129 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
 130 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
 131 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
 132 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
 133 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
 134 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
 135 LYX_OPTION(ENABLE_URLTESTS  "Enable for URL tests" OFF ALL)
 136 LYX_OPTION(ENABLE_EXPORT_TESTS "Enable for export tests" OFF ALL)
 137 LYX_OPTION(ENABLE_KEYTESTS  "Enable for keytests" OFF ALL)
 138 LYX_OPTION(ASAN             "Use address sanitizer" OFF ALL)
 139 LYX_COMBO(USE_QT            "Use Qt version as frontend" AUTO QT4 QT5)
 140 #LYX_OPTION(3RDPARTY_BUILD   "Build 3rdparty libs" OFF ALL)
 141 LYX_OPTION(EXTERNAL_Z       "OFF := Build 3rdparty lib zlib" ON ALL)
 142 LYX_OPTION(EXTERNAL_ICONV   "OFF := Build 3rdparty lib iconvlib" ON ALL)
 143 LYX_OPTION(EXTERNAL_HUNSPELL "OFF := Build 3rdparty lib hunspelllib" ON ALL)
 144 LYX_COMBO(EXTERNAL_MYTHES   "OFF := Build 3rdparty lib mytheslib" AUTO OFF ON)
 145
 146 # GCC specific
 147 LYX_OPTION(PROFILE              "Build profile version" OFF GCC)
 148 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" OFF GCC)
 149 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
 150 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
 151 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++ pedantic debug mode" OFF GCC)
 152 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" OFF GCC)
 153 LYX_OPTION(PROFILE              "Build with options for gprof" OFF GCC)
 154
 155 # MSVC specific
 156 LYX_OPTION(CONSOLE               "Show console on Windows, enforce with =FORCE" ON MSVC)
 157 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
 158 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
 159 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
 160
 161 # APPLE specific
 162 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
 163 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
 164
 165
 166 if(help OR HELP)
 167         message(STATUS)
 168         message(STATUS "Available options: (dis/enable with -DLYX_*=OFF/ON)")
 169         message(STATUS)
 170         LYX_OPTION_LIST_ALL(help)
 171         message(STATUS)
 172         RETURN()
 173 endif()
 174
 175 # Check option dependencies
 176
 177 if(LYX_DMG)
 178         set(LYX_BUNDLE ON)
 179         set(LYX_CPACK ON)
 180 endif()
 181
 182 if(LYX_CPACK)
 183         set(LYX_INSTALL ON)
 184 endif()
 185
 186 if(LYX_INSTALL)
 187         set(LYX_NLS ON)
 188         if(WIN32 AND NOT MINGW)
 189                 set(LYX_HUNSPELL ON)
 190         endif()
 191         if(LYX_CONSOLE MATCHES "FORCE")
 192                 set(LYX_CONSOLE ON)
 193         else()
 194                 set(LYX_CONSOLE OFF)
 195         endif()
 196         set(LYX_PACKAGE_SUFFIX ON)
 197         if(NOT LYX_DEBUG)
 198                 set(LYX_RELEASE ON)
 199         endif()
 200         set(LYX_PROFILE OFF)
 201 endif()
 202
 203
 204 if(LYX_MERGE_FILES)
 205         set(LYX_PCH OFF)
 206 else()
 207         set(LYX_MERGE_REBUILD OFF)
 208 endif()
 209
 210 if(LYX_DEPENDENCIES_DOWNLOAD)
 211         message(STATUS)
 212         if(MSVC14)
 213                 set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2015-deps)
 214                 set(deps_files lyx-windows-deps-msvc2015.zip)
 215                 set(deps_server http://ftp.lyx.de/LyX-Windows-Deps)
 216                 set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2015)
 217         elseif(MSVC10)
 218                 set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 219                 set(deps_files lyx-windows-deps-msvc2010.zip)
 220                 set(deps_server http://ftp.lyx.de/LyX-Windows-Deps)
 221                 set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2010)
 222         else()
 223                 message(FATAL_ERROR "error: no dependency package known for the selected MSVC version.")
 224         endif()
 225     message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 226         foreach(it ${deps_files})
 227                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 228                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 229                 if(NOT already_downloaded)
 230                         message(STATUS "Downloading ${it} ...")
 231                         file(DOWNLOAD ${deps_server}/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS STATUS status LOG log)
 232                         list(GET status 0 status_code)
 233                         list(GET status 1 status_string)
 234                         if(NOT status_code EQUAL 0)
 235                                 file(REMOVE ${LYX_DEPENDENCIES_DIR}/${it})
 236                                 message(FATAL_ERROR "error: downloading '${it}' failed. status_code: ${status_code}, status_string: ${status_string}. \nLog: ${log} ")
 237                         endif()
 238                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 239                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 240                 endif()
 241         endforeach()
 242 endif()
 243
 244
 245
 246 message(STATUS)
 247
 248 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 249 if(WIN32)
 250         set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 251 else()
 252         set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 253 endif()
 254
 255
 256 # Set to some meaningful default
 257 find_package(CXX11Compiler)
 258 if(NOT CXX11COMPILER_FOUND)
 259         message(FATAL_ERROR "A C++11 compatible compiler is required.")
 260 endif()
 261 set(LYX_GCC11_MODE)
 262 if(UNIX OR MINGW)
 263         if (CMAKE_CXX_COMPILER_ID MATCHES "^[cC]lang$")
 264           # ignore the GCC_VERSION for clang
 265           # and use the resulting CXX11_STD_REGEX found in FindCXX11Compiler.cmake
 266           message(STATUS "Using clang")
 267           if(CXX11_STD_REGEX)
 268             set(LYX_USE_STD_REGEX 1)
 269           else()
 270             set(LYX_USE_STD_REGEX 0)
 271           endif()
 272         else()
 273           execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION OUTPUT_STRIP_TRAILING_WHITESPACE)
 274           message(STATUS "Using GCC version ${GCC_VERSION}")
 275           if(GCC_VERSION VERSION_LESS 4.9)
 276                   if(GCC_VERSION VERSION_LESS 4.6)
 277                           message(FATAL_ERROR "gcc >= 4.6 is required.")
 278                   endif()
 279                   # <regex> in gcc is unusable in versions less than 4.9.0
 280                   # see https://gcc.gnu.org/bugzilla/show_bug.cgi?id=53631
 281                   set(LYX_USE_STD_REGEX 0)
 282           else()
 283                   set(LYX_USE_STD_REGEX 1)
 284           endif()
 285         endif()
 286         set(LYX_GCC11_MODE "${CXX11_FLAG}")
 287 else()
 288         set(LYX_USE_STD_REGEX 0)
 289 #       if(MSVC10)
 290 #               set(LYX_USE_STD_REGEX 1) #TODO should we use it in ECMAScript mode?
 291 #       endif()
 292 endif()
 293
 294
 295 set(VERSION_INFO "CMake Build")
 296
 297 # Try to get some informations from configure.ac
 298
 299 include(LyXPaths)
 300 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 301
 302 if(WIN32)
 303         set(CMAKE_PREFIX_PATH Specify-path-to-Qt CACHE PATH "Used Qt version")
 304         if(MSVC)
 305                 set(LYX_3RDPARTY_BUILD ON CACHE BOOL "Build 3rdparty libraries" FORCE)
 306         endif()
 307         set(USE_WINDOWS_PACKAGING ON)
 308 elseif(APPLE)
 309         set(USE_MACOSX_PACKAGING ON)
 310 else()
 311         set(USE_POSIX_PACKAGING ON)
 312 endif()
 313
 314 if(LYX_3RDPARTY_BUILD)
 315   # LYX_3RDPARTY_BUILD is not cached anymore, but for compatibility reasons
 316   # this enables the build of all 3rd_party libs
 317   set(LYX_EXTERNAL_Z        OFF CACHE BOOL "Build 3rdparty lib zlib"    FORCE)
 318   set(LYX_EXTERNAL_ICONV    OFF CACHE BOOL "Build 3rdparty iconvlib"    FORCE)
 319   set(LYX_EXTERNAL_HUNSPELL OFF CACHE BOOL "Build 3rdparty hunspelllib" FORCE)
 320   set(LYX_EXTERNAL_MYTHES   OFF CACHE STRING "Build 3rdparty mytheslib" FORCE)
 321 endif()
 322
 323 macro(setstripped _varname)
 324         if(${ARGC} GREATER 1)
 325                 string(STRIP "${ARGV1}" _v)
 326                 if(USE_POSIX_PACKAGING)
 327                         string(TOLOWER ${_v} ${_varname})
 328                 else()
 329                         set(${_varname} ${_v})
 330                 endif()
 331         else()
 332                 set(${_varname})
 333         endif()
 334 endmacro(setstripped)
 335
 336 foreach(_c_l ${_config_lines} )
 337         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 338                 setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 339                 setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 340                 setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 341                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\)\(\\.\([0-9]+\)\)?.*$")
 342                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 343                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 344                         set(LYX_PATCH_VERSION ${CMAKE_MATCH_4})
 345                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 346                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 347                         if ("${LYX_SUFFIX_VALUE}" MATCHES "")
 348                           set(LYX_INSTALL_SUFFIX "${LYX_MAJOR_VERSION}.${LYX_MINOR_VERSION}")
 349                         else()
 350                           set(LYX_INSTALL_SUFFIX "${LYX_SUFFIX_VALUE}")
 351                         endif()
 352                 endif()
 353         endif()
 354         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 355                 set(LYX_DATE "${CMAKE_MATCH_1}")
 356         endif()
 357 endforeach(_c_l)
 358
 359 FIND_PROGRAM(LYX_GITVERSION git)
 360 #message(STATUS "gitversion = ${LYX_GITVERSION}")
 361 set(LYX_REVISION_VERSION ${LYX_PATCH_VERSION})
 362 if(LYX_GITVERSION)
 363   if (LYX_LOCALVERSIONING)
 364     # Find the revision number and for later use
 365     EXECUTE_PROCESS(COMMAND ${LYX_GITVERSION} describe --match 2.0.0 HEAD
 366       WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE LYX_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 367     if (LYX_PACKAGE_RELEASE MATCHES "^2\\.0\\.0\\-\([0-9]+\)\\-.*$")
 368       # We will add offset of 40000 to get appropriate value to
 369       # previous svn.
 370       # We use this value than also to set the package-patch-value
 371       MATH(EXPR tmp_REVISION_VERSION "(${CMAKE_MATCH_1}+40000)")
 372       set(LYX_REVISION_VERSION "${LYX_PATCH_VERSION}-${tmp_REVISION_VERSION}git")
 373       set(ENABLE_DIST ON)
 374     endif()
 375   endif()
 376 endif()
 377
 378 # Set the programs (lyx, tex2lyx, etc.) suffix
 379 # When building an OS X bundle, we will append
 380 # the suffix only to the bundle, not to the programs
 381 set(PROGRAM_SUFFIX "")
 382 if(LYX_PROGRAM_SUFFIX AND NOT (APPLE AND LYX_BUNDLE))
 383         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 384 endif()
 385 set(_lyx "${PACKAGE_BASE}${PROGRAM_SUFFIX}")
 386 set(_tex2lyx tex2lyx${PROGRAM_SUFFIX})
 387
 388 add_custom_target(lyx_version ALL
 389   COMMAND ${CMAKE_COMMAND} -DTOP_SRC_DIR=${TOP_SRC_DIR} -DTOP_CMAKE_PATH=${TOP_CMAKE_PATH} -DTOP_BINARY_DIR=${TOP_BINARY_DIR} -DLYX_DATE=${LYX_DATE} -P ${TOP_SCRIPT_PATH}/LyXGetVersion.cmake
 390   )
 391 set_target_properties(lyx_version PROPERTIES FOLDER "applications")
 392
 393 # Default paths for installed utilities (tex2lyx, lyxclient, etc.)
 394 set(LYX_UTILITIES_INSTALL_PATH bin)
 395
 396 if(LYX_BUNDLE)
 397         set(LYX_CPACK ON)
 398
 399         message(STATUS)
 400         message(STATUS "Bundle creation is enabled (experimental):")
 401         message(STATUS "    make")
 402         message(STATUS "    make install/strip")
 403         message(STATUS "    make package")
 404         if(APPLE)
 405                 set(MACOSX_BUNDLE TRUE)
 406                 # This sets the bundle + executable names
 407                 set(_lyx "${PACKAGE_BASE}${LYX_INSTALL_SUFFIX}")
 408                 # This sets the Info.plist executable name
 409                 set(osx_bundle_program_name ${_lyx})
 410                 # Bundle name
 411                 set(LYX_BUNDLE_NAME ${_lyx})
 412
 413                 # This will contain the list of files that need to be included
 414                 # in the bundle and their location within the bundle
 415                 set(OSX_BUNDLE_FILES "${TOP_SRC_DIR}/development/MacOSX/LyX.sdef;${TOP_SRC_DIR}/development/MacOSX/LyXapp.icns;${CMAKE_BINARY_DIR}/lyxrc.dist")
 416                 set(OSX_BUNDLE_DIRS "Resources;Resources;Resources")
 417
 418                 # Process Info.plist and lyxrc.dist
 419                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/Info.plist.in" "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 420                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/lyxrc.dist.in" "${CMAKE_CURRENT_BINARY_DIR}/lyxrc.dist")
 421
 422                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 423                 set(LYX_DATA_SUBDIR ${LYX_BUNDLE_NAME}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 424
 425                 # Variables used by CPack
 426                 set(CPACK_BUNDLE_NAME ${LYX_BUNDLE_NAME})
 427                 set(CPACK_BUNDLE_PLIST "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 428                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${LYX_BUNDLE_NAME}.app)
 429
 430                 # Set the install paths
 431                 set(LYX_UTILITIES_INSTALL_PATH ${LYX_BUNDLE_NAME}.app/Contents/MacOS)
 432                 if(NOT LYX_INSTALL_PREFIX)
 433                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 434                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 435                 endif()
 436                 # Change the owner so that the install can work
 437                 install(CODE "set(BU_CHMOD_BUNDLE_ITEMS 1)" COMPONENT Runtime)
 438         elseif(UNIX)
 439                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 440                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 441                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 442         elseif(WIN32)
 443                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 444         endif()
 445 endif()
 446
 447 if(LYX_INSTALL_PREFIX)
 448         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 449         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 450 endif()
 451 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 452
 453 if(UNIX)
 454   set(SYSTEM_DATADIR "${CMAKE_INSTALL_PREFIX}/share")
 455 elseif(CMAKE_INSTALL_PREFIX MATCHES "/lyx${LYX_INSTALL_SUFFIX}$")
 456   string(REGEX REPLACE "/lyx${LYX_INSTALL_SUFFIX}$" "/share" SYSTEM_DATADIR ${CMAKE_INSTALL_PREFIX})
 457 else()
 458   set(SYSTEM_DATADIR "${CMAKE_INSTALL_PREFIX}")
 459 endif()
 460
 461 if(CMAKE_COMPILER_IS_GNUCXX)
 462   message(STATUS "CMAKE_COMPILER_IS_GNUCXX = ${CMAKE_COMPILER_IS_GNUCXX}")
 463   set(suffixing ${LYX_PROGRAM_SUFFIX})
 464 else()
 465   # Not a GCC compiler, programs do not have a suffix
 466   set(suffixing ${LYX_PACKAGE_SUFFIX})
 467 endif()
 468
 469 # The define PACKAGE below allows lyx-executable to find its default configuration files
 470 # see routines
 471 #    Package::messages_file()
 472 #    get_default_user_support_dir()
 473 #    relative_system_support_dir()
 474 # in src/support/Package.cpp
 475 #
 476 if(suffixing)
 477         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 478 else()
 479         set(PACKAGE ${PACKAGE_BASE})
 480 endif()
 481
 482 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 483         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 484         if (UNIX)
 485                 # use the default "/usr/local"
 486                 # but respect the user-choice on the command-line
 487                 set(CMAKE_INSTALL_PREFIX "/usr/local" CACHE PATH "LyX default install prefix" FORCE)
 488         endif()
 489 endif()
 490 if(WIN32)
 491         set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 492 endif()
 493 if(IS_ABSOLUTE)
 494         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 495 else()
 496         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 497 endif()
 498
 499
 500
 501 if(NOT LYX_DATA_SUBDIR)
 502         if (WIN32)
 503                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 504         else()
 505                 set(LYX_DATA_SUBDIR "share/${_lyx}/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 506         endif()
 507 endif()
 508
 509 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 510 get_locale_destination(LYX_LOCALEDIR)
 511 set(LYX_ABS_INSTALLED_LOCALEDIR "${CMAKE_INSTALL_PREFIX}/${LYX_LOCALEDIR}")
 512 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 513
 514 if(LYX_BUNDLE AND APPLE)
 515         set(LYX_MAN_DIR "${LYX_DATA_SUBDIR}" CACHE STRING "Install location for man pages.")
 516 else()
 517         if(WIN32)
 518                 set(LYX_MAN_DIR "${CMAKE_BINARY_DIR}/usr/local/man" CACHE STRING "Install location for man pages.")
 519         elseif(UNIX)
 520                 set(LYX_MAN_DIR "${CMAKE_INSTALL_PREFIX}/share/man" CACHE STRING "Install location for man pages.")
 521         else()
 522                 set(LYX_MAN_DIR "${CMAKE_INSTALL_PREFIX}/man" CACHE STRING "Install location for man pages.")
 523         endif()
 524 endif()
 525 mark_as_advanced(LYX_MAN_DIR)
 526
 527 if(LYX_INSTALL AND WIN32)
 528         message(STATUS "Configuring NSIS files")
 529         configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 530         configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 531         configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 532         message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 533 endif()
 534
 535 if(NOT GROUP_CODE)
 536         #set(GROUP_CODE "The Golden Code")
 537         set(GROUP_CODE flat)
 538 endif()
 539
 540 # lyx's source files
 541 set(LYX_CPP_FILES [a-zA-Z]*.cpp)
 542 set(LYX_HPP_FILES [a-zA-Z]*.h)
 543 set(LYX_MOC_FILES moc_*.cpp)
 544
 545 include(ProjectSourceGroup)
 546
 547
 548 if(LYX_PROFILE AND NOT MSVC)
 549         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 550         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg")
 551         set(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS}  -pg")
 552 else()
 553         set(LYX_PROFILE OFF)
 554 endif()
 555
 556
 557 if(LYX_NO_OPTIMIZE)
 558         set(CMAKE_BUILD_TYPE None)
 559         set(LYX_DEBUG OFF)
 560         set(LYX_RELEASE OFF)
 561         set(LYX_PROFILE OFF)
 562 elseif(LYX_RELEASE)
 563         set(CMAKE_BUILD_TYPE Release)
 564         set(LYX_DEBUG OFF)
 565         set(LYX_PROFILE OFF)
 566 elseif(LYX_PROFILE)
 567         set(CMAKE_BUILD_TYPE Profile)
 568         set(LYX_DEBUG OFF)
 569 else()
 570         set(CMAKE_BUILD_TYPE Debug)
 571         set(LYX_DEBUG ON)
 572 endif()
 573
 574
 575 # When shared libs are supported enable this option
 576 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 577 if(LYX_SHARED_LIBRARIES)
 578         set(library_type SHARED)
 579 else()
 580         set(library_type STATIC)
 581 endif()
 582
 583 if(NOT MSVC)
 584         if(NOT LYX_QUIET)
 585                 set(CMAKE_VERBOSE_MAKEFILE ON)
 586         endif()
 587         set(LYX_CXX_FLAGS "-Wall -Wunused-parameter ${LYX_GCC11_MODE}")
 588         if(LYX_CXX_FLAGS MATCHES "\\+\\+(14|11|98)")
 589           # Thanks to Brad King <brad.king@kitware.com>
 590           # for the pointer to https://cmake.org/cmake/help/v3.6/variable/CMAKE_CXX_STANDARD.html
 591           # This allows us to use QT5.7 with recent g++ (version >= 4.9) compilers
 592           # and still use our own c++ extension tests
 593           set(CMAKE_CXX_STANDARD ${CMAKE_MATCH_1})
 594           message(STATUS "CMAKE_CXX_STANDARD set to ${CMAKE_CXX_STANDARD}")
 595         endif()
 596         if(LYX_STDLIB_DEBUG)
 597                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 598         endif()
 599         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 600         set(CMAKE_CXX_FLAGS_DEBUG "-O0 -g3 -D_DEBUG" CACHE TYPE STRING FORCE)
 601         if(MINGW)
 602                 set(CMAKE_CXX_FLAGS_RELEASE "-O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 603         else()
 604                 set(CMAKE_CXX_FLAGS_RELEASE "-O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 605         endif()
 606 endif()
 607
 608 set(LYX_CXX_FLAGS_EXTRA "" CACHE STRING "Desired semicolon separated list of extra cxx compile flags, like '-Werror'")
 609 mark_as_advanced(LYX_CXX_FLAGS_EXTRA)
 610 if(LYX_CXX_FLAGS_EXTRA)
 611         foreach(_flag ${LYX_CXX_FLAGS_EXTRA})
 612                 add_definitions(${_flag})
 613         endforeach()
 614 endif()
 615
 616 if(LYX_XMINGW)
 617         list(APPEND CMAKE_FIND_ROOT_PATH ${GNUWIN32_DIR})
 618 endif()
 619
 620 set(min_qt5_version "5.6")
 621 if(LYX_USE_QT MATCHES "AUTO")
 622         # try qt5 first
 623         find_package(Qt5Core QUIET)
 624         if(Qt5Core_FOUND)
 625                 set(LYX_USE_QT "QT5" CACHE STRING "Valid qt version" FORCE)
 626                 message(STATUS "Qt5Core_VERSION = ${Qt5Core_VERSION}")
 627                 if(Qt5Core_VERSION VERSION_LESS ${min_qt5_version})
 628                         find_package(Qt4 "4.5.0" QUIET)
 629                         if(QT4_FOUND)
 630                                 set(LYX_USE_QT "QT4" CACHE STRING "Valid qt version" FORCE)
 631                         endif()
 632                 endif()
 633         else()
 634                 set(LYX_USE_QT "QT4" CACHE STRING "Valid qt version" FORCE)
 635         endif()
 636 endif()
 637 if(LYX_USE_QT MATCHES "QT5")
 638         # set QPA_XCB if QT uses X11
 639         find_package(Qt5Core REQUIRED)
 640         if (Qt5Core_FOUND)
 641                 find_package(Qt5Widgets REQUIRED)
 642                 if(APPLE)
 643                         find_package(Qt5MacExtras REQUIRED)
 644                 endif()
 645                 find_package(Qt5X11Extras QUIET)
 646                 find_package(Qt5WinExtras QUIET)
 647                 set(QTVERSION ${Qt5Core_VERSION})
 648                 if (QTVERSION VERSION_LESS ${min_qt5_version})
 649                         message(STATUS "QTVERSION = \"${QTVERSION}\"")
 650                         message(STATUS "This version is not recommended, try either option -DLYX_USE_QT=QT4 or")
 651                         message(STATUS "install QT-Version >= \"${min_qt5_version}\"")
 652                         # see thread in lyx-devel list
 653                         # From: Jean-Pierre Chrétien <jeanpierre.chretien@free.fr>
 654                         # Date 11.03.2017
 655                         # Subject: cmake compilation error
 656                         #message(FATAL_ERROR "Wrong Qt-Version")
 657                 endif()
 658                 macro (qt_use_modules)
 659                         qt5_use_modules(${ARGN})
 660                 endmacro()
 661                 macro (qt_add_resources)
 662                         qt5_add_resources(${ARGN})
 663                 endmacro()
 664                 macro (qt_wrap_uifiles)
 665                         qt5_wrap_ui(${ARGN})
 666                 endmacro()
 667                 message(STATUS "Found Qt-Version ${QTVERSION}")
 668                 if(WIN32)
 669                         set(LYX_QTMAIN_LIBRARY ${Qt5Core_QTMAIN_LIBRARIES})
 670                 endif()
 671         endif()
 672 elseif(LYX_USE_QT MATCHES "QT4")
 673         if(LYX_XMINGW)
 674                 set(QT_MINGW_DIR ${LYX_QT4} CACHE PATH "Qt for Mingw" FORCE)
 675                 list(APPEND CMAKE_FIND_ROOT_PATH ${QT_MINGW_DIR} ${GNUWIN32_DIR})
 676         endif()
 677         find_package(Qt4 "4.5.0" REQUIRED)
 678         macro (qt_use_modules)
 679         endmacro()
 680         macro (qt_add_resources)
 681                 qt4_add_resources(${ARGN})
 682         endmacro()
 683         macro (qt_wrap_uifiles)
 684                 qt4_wrap_ui(${ARGN})
 685         endmacro()
 686         set(LYX_QTMAIN_LIBRARY ${QT_QTSVG_LIBRARY})
 687         if(WIN32)
 688                 list(APPEND LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARIES})
 689         endif()
 690 else()
 691   message(FATAL_ERROR "Unhandled value for LYX_USE_QT (${LYX_USE_QT})")
 692 endif()
 693
 694 find_package(Magic)
 695 if(Magic_FOUND)
 696         set(HAVE_MAGIC_H 1)
 697 endif()
 698
 699 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 700
 701 set(Spelling_FOUND OFF)
 702 set(Include_used_spellchecker)   # String will be inserted into config.h
 703
 704 if (LYX_EXTERNAL_MYTHES MATCHES "AUTO")
 705   # try system library first
 706   find_package(MyThesLIB)
 707   if (MYTHESLIB_FOUND)
 708     set(LYX_EXTERNAL_MYTHES ON CACHE STRING "OFF:= Build 3rdparty mytheslib" FORCE)
 709   else()
 710     set(LYX_EXTERNAL_MYTHES OFF CACHE STRING "OFF:= Build 3rdparty mytheslib" FORCE)
 711   endif()
 712 endif()
 713 if (LYX_EXTERNAL_MYTHES MATCHES "ON")
 714   find_package(MyThesLIB REQUIRED)
 715 else()
 716   add_subdirectory(3rdparty/mythes)
 717 endif()
 718 set(MYTHES_DIR ${MYTHESLIB_INCLUDE_DIR})
 719
 720 if(NOT LYX_EXTERNAL_HUNSPELL)
 721     add_subdirectory(3rdparty/hunspell)
 722     add_definitions(-DHUNSPELL_STATIC)
 723     set(HUNSPELL_FOUND ON)
 724     message(STATUS "  * Hunspell:")
 725     message(STATUS "     - include: ${HUNSPELL_INCLUDE_DIR}")
 726     message(STATUS "     - library: ${HUNSPELL_LIBRARY}")
 727 endif()
 728
 729 foreach(_spell "ASPELL" "Enchant" "Hunspell")
 730   string(TOUPPER ${_spell} _upspell)
 731   if (NOT ${_upspell}_FOUND)
 732     find_package(${_spell})
 733   endif()
 734   if (${_upspell}_FOUND)
 735     include_directories(${${_upspell}_INCLUDE_DIR})
 736     set(Spelling_FOUND ON)
 737     message(STATUS "Building with USE_${_upspell}")
 738     set(Include_used_spellchecker "${Include_used_spellchecker}#define USE_${_upspell} 1\n")
 739   else()
 740     if(LYX_${_upspell})
 741       message(FATAL_ERROR "Required ${_spell} devel package not found")
 742     else()
 743       message(STATUS "${_upspell} not found, building without ${_spell} support")
 744     endif()
 745   endif()
 746 endforeach()
 747
 748 if(GNUWIN32_DIR)
 749         list(APPEND CMAKE_PROGRAM_PATH "${GNUWIN32_DIR}/Python" )
 750 endif()
 751
 752 # Search for python default version first
 753 unset(PYTHON_EXECUTABLE CACHE)
 754 unset(LYX_PYTHON_EXECUTABLE CACHE)
 755 unset(PYTHON_VERSION_MAJOR)
 756 unset(PYTHON_VERSION_MINOR)
 757 unset(PYTHON_VERSION_STRING)
 758 find_package(PythonInterp 3.3 QUIET)
 759 if(NOT PYTHONINTERP_FOUND)
 760   unset(PYTHON_EXECUTABLE CACHE)
 761   find_package(PythonInterp 2.0 REQUIRED)
 762   if(NOT PYTHON_VERSION_STRING VERSION_LESS 2.8)
 763     message(FATAL_ERROR "Python interpreter found, but is not suitable")
 764   endif()
 765 endif()
 766
 767 set(LYX_PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 768
 769 if(LYX_NLS)
 770         find_package(LyXGettext)
 771         if(LYX_PYTHON_EXECUTABLE AND GETTEXT_FOUND)
 772                 add_subdirectory(po "${TOP_BINARY_DIR}/po")
 773         else()
 774                 # Install only supplied .gmo-files
 775                 file(GLOB _gmofiles RELATIVE "${TOP_SRC_DIR}/po" "${TOP_SRC_DIR}/po/*.gmo")
 776                 message(STATUS "Installing provided .gmo-files only")
 777                 foreach( _gmo ${_gmofiles})
 778                         string(REGEX REPLACE "\\.gmo$" "" _lang ${_gmo})
 779                         install(FILES "${TOP_SRC_DIR}/po/${_gmo}" DESTINATION ${LYX_LOCALEDIR}/${_lang}/LC_MESSAGES RENAME ${PACKAGE}.mo)
 780                 endforeach()
 781         endif()
 782 endif()
 783
 784 if(LYX_EXTERNAL_ICONV)
 785   find_package(ICONV REQUIRED)
 786 else()
 787   add_subdirectory(3rdparty/libiconv)
 788   set(HAVE_ICONV_CONST 1)
 789 endif()
 790
 791 if(LYX_EXTERNAL_Z)
 792   find_package(ZLIB REQUIRED)
 793 else()
 794   add_subdirectory(3rdparty/zlib)
 795 endif()
 796
 797 if(LYX_USE_STD_REGEX)
 798   # Set only include path.
 799   # Use internal boost, which is known to exist
 800   # we don't need any libraries
 801   set(Lyx_Boost_Libraries)
 802   add_definitions(-DBOOST_USER_CONFIG=<config.h>)
 803   include_directories(${TOP_SRC_DIR}/3rdparty/boost)
 804 else()
 805   # Using boost-regex
 806   if(LYX_EXTERNAL_BOOST)
 807     message(STATUS "Searching for external boost")
 808     find_package(Boost COMPONENTS regex)
 809     if(Boost_FOUND)
 810       message(STATUS "Boost found")
 811       message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 812       set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 813       if (LYX_STDLIB_DEBUG)
 814         # Comment from  Jean-Marc Lasgouttes:
 815         # In general, system boost libraries are incompatible with
 816         # the use of stdlib-debug in libstdc++. See ticket #9736 for
 817         # details.
 818         message(WARNING "Compiling LyX with stdlib-debug and system boost libraries may lead to crashes. Consider using '-DLYX_STDLIB_DEBUG=OFF' or using '-DLYX_EXTERNAL_BOOST=OFF'")
 819       endif()
 820     else()
 821       message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 822     endif()
 823   else()
 824     # Using included boost
 825     set(Lyx_Boost_Libraries boost_regex)
 826     add_definitions(-DBOOST_USER_CONFIG=<config.h>)
 827     include_directories(${TOP_SRC_DIR}/3rdparty/boost)
 828     add_subdirectory(3rdparty/boost "${TOP_BINARY_DIR}/3rdparty/boost")
 829   endif()
 830 endif()
 831
 832 if(WIN32)
 833         if(LYX_CONSOLE)
 834                 set(LYX_QTMAIN_LIBRARY)
 835         else()
 836                 set(WIN32_CONSOLE WIN32)
 837         endif()
 838         if(MSVC)
 839                 # -DPSAPI_VERSION=1 is needed to run on vista (bug 10186)
 840                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX -DPSAPI_VERSION=1)
 841                 # disable checked iterators for msvc release builds to get maximum speed
 842                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 843         else()
 844                 # -DPSAPI_VERSION=1 is not needed for mingw, since the mingw psapi.h
 845                 # does not use it and always declares the vista compatible API.
 846                 # If this ever changes then -DPSAPI_VERSION might be needed here as well.
 847                 add_definitions(-DWINVER=0x0500)
 848         endif()
 849 endif()
 850
 851 # Compute qt-version from ${QTVERSION}
 852
 853 message(STATUS "")
 854 foreach(_v PACKAGE PACKAGE_VERSION
 855         PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 856         LYX_ABS_TOP_SRCDIR
 857         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 858         if(NOT DEFINED ${_v})
 859                 message(FATAL_ERROR "${_v} not defined")
 860         endif()
 861         string(SUBSTRING "${_v}                            " 0 28 _v1)
 862         message(STATUS "----- ${_v1}: ${${_v}}")
 863 endforeach(_v)
 864 message(STATUS "")
 865
 866
 867 if(LYX_PCH)
 868         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 869         # Not sure if it works for all non-msvc compilers
 870         include(PCHSupport_26)
 871         configure_file(${TOP_CMAKE_PATH}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
 872         configure_file(${TOP_CMAKE_PATH}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 873         add_definitions(-DLYX_ENABLE_PCH)
 874
 875         if(MSVC)
 876                 macro(lyx_add_msvc_pch name_)
 877                         set_source_files_properties(${${name_}_sources} PROPERTIES
 878                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 879                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
 880                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 881                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
 882                                 ${TOP_BINARY_DIR}/pcheaders.h)
 883                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 884                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 885                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 886                 endmacro(lyx_add_msvc_pch)
 887                 macro(lyx_add_gcc_pch name_)
 888                 endmacro()
 889         else()
 890                 macro(lyx_add_msvc_pch name_)
 891                 endmacro()
 892                 macro(lyx_add_gcc_pch name_)
 893                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT)
 894                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
 895                 endmacro()
 896         endif()
 897 else()
 898         macro(lyx_add_msvc_pch)
 899         endmacro(lyx_add_msvc_pch)
 900         macro(lyx_add_gcc_pch name_)
 901         endmacro()
 902 endif()
 903
 904
 905 if(MSVC)
 906
 907         if(LYX_VLD)
 908                 set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/development/Win32/vld)
 909                 add_subdirectory(${vld_path}/cmake)
 910                 include(${vld_path}/cmake/vld.cmake) # forced include
 911                 set(vld_dll vld)
 912         endif()
 913
 914         if(LYX_WALL)
 915                 # Use the highest warning level
 916                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 917
 918                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 919                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 920                 else()
 921                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 922                 endif()
 923
 924                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 925                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 926                 else()
 927                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 928                 endif()
 929
 930                 # add here warnings which should produce an error /weXXXX
 931                 set(MSVC_W_ERROR   "/we4101 /we4189")
 932                 # add here warnings which should be disabled /wdXXXX
 933                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 934
 935                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 936                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 937                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 938
 939         else()
 940                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 941
 942                 # add here warnings which should produce an error /weXXXX
 943                 set(MSVC_W_ERROR   "/we4101 /we4189")
 944                 # add here warnings which should be disabled /wdXXXX
 945                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 946
 947                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 948                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 949                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 950
 951         endif()
 952
 953         if (NOT Qt5Core_FOUND)
 954                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 955                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 956                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 957         endif()
 958
 959         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 960         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 961         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 962         message(STATUS "")
 963 endif()
 964
 965
 966 if(LYX_DEBUG_GLIBC)
 967         set(_GLIBCXX_DEBUG ON)
 968 endif()
 969
 970 if(LYX_DEBUG_GLIBC_PEDANTIC)
 971         set(_GLIBCXX_DEBUG_PEDANTIC ON)
 972 endif()
 973
 974 # Xcode compiler
 975 if (CMAKE_GENERATOR MATCHES Xcode)
 976         if (XCODE_VERSION VERSION_LESS "5.0")
 977                 # Automatically select the Xcode compiler if not set
 978                 if (NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 979                         # XCode >= 3.1 has gcc 4.2 (up to actual Xcode)
 980                         if (XCODE_VERSION VERSION_GREATER "3.1")
 981                                 SET(CMAKE_XCODE_ATTRIBUTE_GCC_VERSION "com.apple.compilers.llvmgcc42")
 982                         ENDIF(XCODE_VERSION VERSION_GREATER "3.1")
 983                 ENDIF(NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 984                 # Print the selected compiler version
 985         MESSAGE(STATUS "---- Using XCode compiler CMAKE_XCODE_ATTRIBUTE_GCC_VERSION=${CMAKE_XCODE_ATTRIBUTE_GCC_VERSION}")
 986         ENDIF(XCODE_VERSION VERSION_LESS "5.0")
 987 ENDIF(CMAKE_GENERATOR MATCHES Xcode)
 988
 989 if (WIN32 AND Qt5Core_FOUND)
 990         set(Z_PREFIX 1)
 991 endif()
 992
 993 # compiler tests, config.h generation LYX_CONFIGURE_CHECKS
 994 include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
 995 configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
 996
 997 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
 998
 999 if(QTVERSION MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+).*")
1000         MATH(EXPR QT4_VERSION "(${CMAKE_MATCH_1}<<16)|(${CMAKE_MATCH_2}<<8)|${CMAKE_MATCH_3}")
1001 endif()
1002
1003 if (NOT HAVE_REGEX)
1004         set(LYX_USE_STD_REGEX 0)
1005 endif()
1006
1007
1008 set (cmd ${CMAKE_CTEST_COMMAND})
1009 if (MSVC)
1010         set (cmd ${cmd} -C ${CMAKE_CFG_INTDIR})
1011 else ()
1012         set (cmd ${cmd} -C ${CMAKE_BUILD_TYPE})
1013 endif ()
1014 add_custom_target (lyx_run_tests COMMAND ${cmd})
1015 set_target_properties(lyx_run_tests PROPERTIES FOLDER "tests")
1016
1017 if(LYX_ASAN)
1018     set(LYX_CXX_FLAGS "-fsanitize=address -fno-omit-frame-pointer -g")
1019     message(STATUS)
1020     message(STATUS "Address sanitizer enabled. Usage:")
1021     message(STATUS "    wget https://llvm.org/svn/llvm-project/compiler-rt/trunk/lib/asan/scripts/asan_symbolize.py")
1022     message(STATUS "    chmod  +x ./asan_symbolize.py")
1023     message(STATUS "    ./bin/lyx2.2 2>&1 | ./asan_symbolize.py  | c++filt ")
1024     message(STATUS)
1025 endif()
1026
1027 if(LYX_INSTALL)
1028         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
1029                 message(STATUS "Python required to create doc!")
1030         else()
1031                 if(UNIX)
1032                         add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
1033                 endif()
1034                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
1035         endif()
1036         include(../Install)
1037 endif()
1038
1039 add_subdirectory(src "${TOP_BINARY_DIR}/src")
1040 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
1041 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
1042 add_subdirectory(lib/examples "${TOP_BINARY_DIR}/lib/examples")
1043 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
1044 add_subdirectory(development/autotests "${TOP_BINARY_DIR}/autotests")
1045 if(LYX_ENABLE_URLTESTS)
1046         add_subdirectory(development/checkurls "${TOP_BINARY_DIR}/checkurls")
1047 endif()
1048
1049 message(STATUS)
1050 message(STATUS "Build params, switch LYX_* options by -DLYX_*=ON or OFF, LYX_* combos by -DLYX_*=value:")
1051 message(STATUS)
1052
1053 LYX_OPTION_LIST_ALL(used)
1054
1055
1056 if(LYX_NLS)
1057         message(STATUS)
1058         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
1059         message(STATUS)
1060         message(STATUS "  * iconv")
1061         message(STATUS "     - include: ${ICONV_INCLUDE_DIR}")
1062         message(STATUS "     - library: ${ICONV_LIBRARY}")
1063         message(STATUS "  * zlib")
1064         message(STATUS "     - include: ${ZLIB_INCLUDE_DIR}")
1065         message(STATUS "     - library: ${ZLIB_LIBRARY}")
1066         message(STATUS)
1067 endif()
1068
1069 # Apple has builtin native spell checker,
1070 # no need to warn for missing Aspell, Hunspell or Enchant
1071 if(NOT Spelling_FOUND AND NOT APPLE)
1072   if(LYX_REQUIRE_SPELLCHECK)
1073     set(_mode "FATAL_ERROR")
1074   else()
1075     set(_mode "STATUS")
1076   endif()
1077   message(${_mode} "No spellcheck libraries found. LyX will be unable use spellchecking")
1078 endif()
1079
1080 include("${TOP_CMAKE_PATH}/LyxPackaging.cmake")
1081
1082 if(ENABLE_DIST)
1083   # Use git to create the source package
1084   # git archive --format=tgz --output=/home/kornel/x.tar.gz master
1085   if(UNIX)
1086     set(DIST_FORMAT tgz)
1087   else()
1088     set(DIST_FORMAT zip)
1089   endif()
1090   set(DIST_NAME ${CMAKE_PROJECT_NAME}-${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}-${CMAKE_SYSTEM_NAME}.${DIST_FORMAT})
1091
1092   add_custom_command(
1093     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME}
1094     COMMAND  ${LYX_GITVERSION} archive --format=${DIST_FORMAT} --output=${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME} master
1095     WORKING_DIRECTORY ${TOP_SRC_DIR})
1096   add_custom_target(git-archive DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME})
1097 endif()
1098
1099 # Last directory to be included so that the fixup code (OS X)
1100 # can be run last
1101 add_subdirectory(development/cmake/post_install)
1102
1103 message(STATUS)