CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 2.6.4)
   8
   9 set(LYX_PROJECT LyX)
  10
  11 # Instruct cmake to not use gnu extensions,
  12 # this prevents the mix of '-std=c++*' and '-std=gnu++*' flags
  13 set(CMAKE_CXX_EXTENSIONS OFF)
  14
  15 enable_testing()
  16
  17 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README REALPATH) # Resolve symlinks
  18 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  19 message(STATUS "TOP_SRC_DIR = ${TOP_SRC_DIR}")
  20
  21 set(LYX_CMAKE_DIR "development/cmake")
  22 set(TOP_CMAKE_PATH "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}")
  23 set(TOP_MODULE_PATH "${TOP_CMAKE_PATH}/modules")
  24 set(TOP_SCRIPT_PATH "${TOP_CMAKE_PATH}/scripts")
  25
  26 set(CMAKE_MODULE_PATH "${TOP_MODULE_PATH}")
  27
  28 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  29
  30 message(STATUS)
  31 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  32         message(STATUS "Building in-source")
  33         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  34 else()
  35         message(STATUS "Building out-of-source")
  36         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  37 endif()
  38
  39 # This directory should be used if some test uses lyx-executable
  40 set(LYX_TESTS_USERDIR "${TOP_BINARY_DIR}/Testing/.lyx")
  41 file(MAKE_DIRECTORY "${LYX_TESTS_USERDIR}")
  42
  43 if(COMMAND cmake_policy)
  44         # Installing MACOSX_BUNDLE targets requires a BUNDLE DESTINATION
  45         cmake_policy(SET CMP0006 NEW)
  46         if(POLICY CMP0043)
  47                 # COMPILE_DEFINITIONS are not used yet. Enable new behavior.
  48                 cmake_policy(SET CMP0043 NEW)
  49         endif()
  50 endif()
  51
  52 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  53
  54 # Supress regeneration
  55 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  56
  57 if(LYX_XMINGW)
  58     set(CMAKE_SYSTEM_NAME Windows)
  59     set(TOOLNAME ${LYX_XMINGW})
  60     set(TOOLCHAIN "${TOOLNAME}-")
  61     set(CMAKE_C_COMPILER   "${TOOLCHAIN}gcc"     CACHE PATH "Mingw C compiler" FORCE)
  62     set(CMAKE_CXX_COMPILER "${TOOLCHAIN}g++"     CACHE PATH "Mingw C++ compiler" FORCE)
  63     set(CMAKE_RC_COMPILER  "${TOOLCHAIN}windres" CACHE PATH "Mingw rc compiler" FORCE)
  64
  65     set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM BOTH)
  66     set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY)
  67     set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY)
  68 endif()
  69
  70 if(NOT help AND NOT HELP)
  71   # 'project' triggers the searching for a compiler
  72   project(${LYX_PROJECT})
  73   if (CMAKE_COMPILER_IS_GNUCXX)
  74     if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS "4.0")
  75       message(STATUS "Gnu CXX compiler version = ${CMAKE_CXX_COMPILER_VERSION}")
  76       message(STATUS "is too old, should be >= 4.0")
  77       message(FATAL_ERROR "Exiting")
  78     endif()
  79   endif()
  80 endif()
  81
  82 if(UNIX)
  83         set(ARCH_TRIPLET )
  84         FIND_PROGRAM(DPKG_ARCHITECTURE_EXECUTABLE dpkg-architecture)
  85         if(DPKG_ARCHITECTURE_EXECUTABLE)
  86                 EXECUTE_PROCESS(COMMAND ${DPKG_ARCHITECTURE_EXECUTABLE} -qDEB_HOST_MULTIARCH
  87                                 OUTPUT_VARIABLE ARCH_TRIPLET
  88                                 ERROR_VARIABLE ERROR_ARCH_TRIPLET
  89                                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  90         endif()
  91 endif()
  92 if(ARCH_TRIPLET)
  93         set(SYSTEM_LIB_DIRS /usr/lib /usr/lib/${ARCH_TRIPLET} /usr/local/lib)
  94 else()
  95         set(SYSTEM_LIB_DIRS /usr/lib /usr/local/lib)
  96 endif()
  97
  98 include(LyXMacros)
  99 include(LyXDestinations)
 100
 101 # Usage LYX_OPTION
 102 # 1. parameter: option name without prefix 'LYX_'
 103 # 2. parameter: description
 104 # 3. parameter: default value, ON or OFF
 105 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
 106
 107 # Usage LYX_COMBO
 108 # 1. parameter: name without prefix 'LYX_'
 109 # 2. parameter: description
 110 # 3. parameter: default value
 111 # 4-n parameter: possible other string values
 112
 113 LYX_OPTION_INIT()
 114
 115 # Options for all compilers/systems
 116 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
 117 LYX_OPTION(LOCALVERSIONING  "Add version info to created package name (only used if LYX_CPACK option set)" OFF ALL)
 118 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
 119 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
 120 LYX_OPTION(REQUIRE_SPELLCHECK "Abort if no spellchecker available" OFF ALL)
 121 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
 122 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
 123 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
 124 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" OFF ALL)
 125 LYX_OPTION(DEBUG            "Enforce debug build"  OFF ALL)
 126 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
 127 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
 128 LYX_STRING(SUFFIX_VALUE     "Use this string as suffix" "")
 129 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
 130 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
 131 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
 132 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
 133 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
 134 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
 135 LYX_OPTION(ENABLE_URLTESTS  "Enable for URL tests" OFF ALL)
 136 LYX_OPTION(ENABLE_EXPORT_TESTS "Enable for export tests" OFF ALL)
 137 LYX_OPTION(ENABLE_KEYTESTS  "Enable for keytests" OFF ALL)
 138 LYX_OPTION(ASAN             "Use address sanitizer" OFF ALL)
 139 LYX_COMBO(USE_QT            "Use Qt version as frontend" AUTO QT4 QT5)
 140 #LYX_OPTION(3RDPARTY_BUILD   "Build 3rdparty libs" OFF ALL)
 141 LYX_OPTION(EXTERNAL_Z       "OFF := Build 3rdparty lib zlib" ON ALL)
 142 LYX_OPTION(EXTERNAL_ICONV   "OFF := Build 3rdparty lib iconvlib" ON ALL)
 143 LYX_OPTION(EXTERNAL_HUNSPELL "OFF := Build 3rdparty lib hunspelllib" ON ALL)
 144 LYX_COMBO(EXTERNAL_MYTHES   "OFF := Build 3rdparty lib mytheslib" AUTO OFF ON)
 145
 146 # GCC specific
 147 LYX_OPTION(PROFILE              "Build profile version" OFF GCC)
 148 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" OFF GCC)
 149 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
 150 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
 151 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++ pedantic debug mode" OFF GCC)
 152 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" OFF GCC)
 153 LYX_OPTION(PROFILE              "Build with options for gprof" OFF GCC)
 154
 155 # MSVC specific
 156 LYX_OPTION(CONSOLE               "Show console on Windows" ON MSVC)
 157 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
 158 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
 159 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
 160
 161 # APPLE specific
 162 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
 163 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
 164
 165
 166 if(help OR HELP)
 167         message(STATUS)
 168         message(STATUS "Available options: (dis/enable with -DLYX_*=OFF/ON)")
 169         message(STATUS)
 170         LYX_OPTION_LIST_ALL(help)
 171         message(STATUS)
 172         RETURN()
 173 endif()
 174
 175 # Check option dependencies
 176
 177 if(LYX_DMG)
 178         set(LYX_BUNDLE ON)
 179         set(LYX_CPACK ON)
 180 endif()
 181
 182 if(LYX_CPACK)
 183         set(LYX_INSTALL ON)
 184 endif()
 185
 186 if(LYX_INSTALL)
 187         set(LYX_NLS ON)
 188         if(WIN32 AND NOT MINGW)
 189                 set(LYX_HUNSPELL ON)
 190         endif()
 191         set(LYX_PACKAGE_SUFFIX ON)
 192         if(NOT LYX_DEBUG)
 193                 set(LYX_RELEASE ON)
 194         endif()
 195         set(LYX_PROFILE OFF)
 196 endif()
 197
 198
 199 if(LYX_MERGE_FILES)
 200         set(LYX_PCH OFF)
 201 else()
 202         set(LYX_MERGE_REBUILD OFF)
 203 endif()
 204
 205 if(LYX_DEPENDENCIES_DOWNLOAD)
 206         message(STATUS)
 207         if(MSVC14)
 208                 set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2015-deps)
 209                 set(deps_files lyx-windows-deps-msvc2015.zip)
 210                 set(deps_server http://ftp.lyx.de/LyX-Windows-Deps)
 211                 set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2015)
 212         elseif(MSVC10)
 213                 set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 214                 set(deps_files lyx-windows-deps-msvc2010.zip)
 215                 set(deps_server http://ftp.lyx.de/LyX-Windows-Deps)
 216                 set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2010)
 217         else()
 218                 message(FATAL_ERROR "error: no dependency package known for the selected MSVC version.")
 219         endif()
 220     message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 221         foreach(it ${deps_files})
 222                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 223                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 224                 if(NOT already_downloaded)
 225                         message(STATUS "Downloading ${it} ...")
 226                         file(DOWNLOAD ${deps_server}/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS STATUS status LOG log)
 227                         list(GET status 0 status_code)
 228                         list(GET status 1 status_string)
 229                         if(NOT status_code EQUAL 0)
 230                                 file(REMOVE ${LYX_DEPENDENCIES_DIR}/${it})
 231                                 message(FATAL_ERROR "error: downloading '${it}' failed. status_code: ${status_code}, status_string: ${status_string}. \nLog: ${log} ")
 232                         endif()
 233                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 234                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 235                 endif()
 236         endforeach()
 237 endif()
 238
 239
 240
 241 message(STATUS)
 242
 243 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 244 if(WIN32)
 245         set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 246 else()
 247         set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 248 endif()
 249
 250
 251 # Set to some meaningful default
 252 find_package(CXX11Compiler)
 253 if(NOT CXX11COMPILER_FOUND)
 254         message(FATAL_ERROR "A C++11 compatible compiler is required.")
 255 endif()
 256 set(LYX_GCC11_MODE)
 257 if(UNIX OR MINGW)
 258         if (CMAKE_CXX_COMPILER_ID MATCHES "^[cC]lang$")
 259           # ignore the GCC_VERSION for clang
 260           # and use the resulting CXX11_STD_REGEX found in FindCXX11Compiler.cmake
 261           message(STATUS "Using clang")
 262           if(CXX11_STD_REGEX)
 263             set(LYX_USE_STD_REGEX 1)
 264           else()
 265             set(LYX_USE_STD_REGEX 0)
 266           endif()
 267         else()
 268           execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION OUTPUT_STRIP_TRAILING_WHITESPACE)
 269           message(STATUS "Using GCC version ${GCC_VERSION}")
 270           if(GCC_VERSION VERSION_LESS 4.9)
 271                   if(GCC_VERSION VERSION_LESS 4.6)
 272                           message(FATAL_ERROR "gcc >= 4.6 is required.")
 273                   endif()
 274                   # <regex> in gcc is unusable in versions less than 4.9.0
 275                   # see https://gcc.gnu.org/bugzilla/show_bug.cgi?id=53631
 276                   set(LYX_USE_STD_REGEX 0)
 277           else()
 278                   set(LYX_USE_STD_REGEX 1)
 279           endif()
 280         endif()
 281         set(LYX_GCC11_MODE "${CXX11_FLAG}")
 282 else()
 283         set(LYX_USE_STD_REGEX 0)
 284 #       if(MSVC10)
 285 #               set(LYX_USE_STD_REGEX 1) #TODO should we use it in ECMAScript mode?
 286 #       endif()
 287 endif()
 288
 289
 290 set(VERSION_INFO "CMake Build")
 291
 292 # Try to get some informations from configure.ac
 293
 294 include(LyXPaths)
 295 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 296
 297 if(WIN32)
 298         set(CMAKE_PREFIX_PATH Specify-path-to-Qt CACHE PATH "Used Qt version")
 299         if(MSVC)
 300                 set(LYX_3RDPARTY_BUILD ON CACHE BOOL "Build 3rdparty libraries" FORCE)
 301         endif()
 302         set(USE_WINDOWS_PACKAGING ON)
 303 elseif(APPLE)
 304         set(USE_MACOSX_PACKAGING ON)
 305 else()
 306         set(USE_POSIX_PACKAGING ON)
 307 endif()
 308
 309 if(LYX_3RDPARTY_BUILD)
 310   # LYX_3RDPARTY_BUILD is not cached anymore, but for compatibility reasons
 311   # this enables the build of all 3rd_party libs
 312   set(LYX_EXTERNAL_Z        OFF CACHE BOOL "Build 3rdparty lib zlib"    FORCE)
 313   set(LYX_EXTERNAL_ICONV    OFF CACHE BOOL "Build 3rdparty iconvlib"    FORCE)
 314   set(LYX_EXTERNAL_HUNSPELL OFF CACHE BOOL "Build 3rdparty hunspelllib" FORCE)
 315   set(LYX_EXTERNAL_MYTHES   OFF CACHE STRING "Build 3rdparty mytheslib" FORCE)
 316 endif()
 317
 318 macro(setstripped _varname)
 319         if(${ARGC} GREATER 1)
 320                 string(STRIP "${ARGV1}" _v)
 321                 if(USE_POSIX_PACKAGING)
 322                         string(TOLOWER ${_v} ${_varname})
 323                 else()
 324                         set(${_varname} ${_v})
 325                 endif()
 326         else()
 327                 set(${_varname})
 328         endif()
 329 endmacro(setstripped)
 330
 331 foreach(_c_l ${_config_lines} )
 332         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 333                 setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 334                 setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 335                 setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 336                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\)\(\\.\([0-9]+\)\)?.*$")
 337                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 338                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 339                         set(LYX_PATCH_VERSION ${CMAKE_MATCH_4})
 340                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 341                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 342                         if ("${LYX_SUFFIX_VALUE}" MATCHES "")
 343                           set(LYX_INSTALL_SUFFIX "${LYX_MAJOR_VERSION}.${LYX_MINOR_VERSION}")
 344                         else()
 345                           set(LYX_INSTALL_SUFFIX "${LYX_SUFFIX_VALUE}")
 346                         endif()
 347                 endif()
 348         endif()
 349         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 350                 set(LYX_DATE "${CMAKE_MATCH_1}")
 351         endif()
 352 endforeach(_c_l)
 353
 354 FIND_PROGRAM(LYX_GITVERSION git)
 355 #message(STATUS "gitversion = ${LYX_GITVERSION}")
 356 set(LYX_REVISION_VERSION ${LYX_PATCH_VERSION})
 357 set(LYX_PACKAGE_RELEASE "1")
 358 if(LYX_GITVERSION)
 359   if (LYX_LOCALVERSIONING)
 360     # Find the revision number and for later use
 361     EXECUTE_PROCESS(COMMAND ${LYX_GITVERSION} describe --match 2.0.0 HEAD
 362       WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE tmp_LYX_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 363     if (tmp_LYX_PACKAGE_RELEASE MATCHES "^2\\.0\\.0\\-\([0-9]+\)\\-\(.*\)$")
 364       set(LYX_PACKAGE_RELEASE ${CMAKE_MATCH_2})
 365       # We will add offset of 40000 to get appropriate value to
 366       # previous svn.
 367       # We use this value than also to set the package-patch-value
 368       MATH(EXPR tmp_REVISION_VERSION "(${CMAKE_MATCH_1}+40000)")
 369       set(LYX_REVISION_VERSION "${LYX_PATCH_VERSION}-${tmp_REVISION_VERSION}git")
 370       set(ENABLE_DIST ON)
 371     endif()
 372   endif()
 373 endif()
 374
 375 # Set the programs (lyx, tex2lyx, etc.) suffix
 376 # When building an OS X bundle, we will append
 377 # the suffix only to the bundle, not to the programs
 378 set(PROGRAM_SUFFIX "")
 379 if(LYX_PROGRAM_SUFFIX AND NOT (APPLE AND LYX_BUNDLE))
 380         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 381 endif()
 382 set(_lyx "${PACKAGE_BASE}${PROGRAM_SUFFIX}")
 383 set(_tex2lyx tex2lyx${PROGRAM_SUFFIX})
 384 set(_convert lyxconvert${PROGRAM_SUFFIX})
 385
 386 add_custom_target(lyx_version ALL
 387   COMMAND ${CMAKE_COMMAND} -DTOP_SRC_DIR=${TOP_SRC_DIR} -DTOP_CMAKE_PATH=${TOP_CMAKE_PATH} -DTOP_BINARY_DIR=${TOP_BINARY_DIR} -DLYX_DATE=${LYX_DATE} -P ${TOP_SCRIPT_PATH}/LyXGetVersion.cmake
 388   )
 389 set_target_properties(lyx_version PROPERTIES FOLDER "applications")
 390
 391 # Default paths for installed utilities (tex2lyx, lyxclient, etc.)
 392 set(LYX_UTILITIES_INSTALL_PATH bin)
 393
 394 if(LYX_BUNDLE)
 395         set(LYX_CPACK ON)
 396
 397         message(STATUS)
 398         message(STATUS "Bundle creation is enabled (experimental):")
 399         message(STATUS "    make")
 400         message(STATUS "    make install/strip")
 401         message(STATUS "    make package")
 402         if(APPLE)
 403                 set(MACOSX_BUNDLE TRUE)
 404                 # This sets the bundle + executable names
 405                 set(_lyx "${PACKAGE_BASE}${LYX_INSTALL_SUFFIX}")
 406                 # This sets the Info.plist executable name
 407                 set(osx_bundle_program_name ${_lyx})
 408                 # Bundle name
 409                 set(LYX_BUNDLE_NAME ${_lyx})
 410
 411                 # This will contain the list of files that need to be included
 412                 # in the bundle and their location within the bundle
 413                 set(OSX_BUNDLE_FILES "${TOP_SRC_DIR}/development/MacOSX/LyX.sdef;${TOP_SRC_DIR}/development/MacOSX/LyXapp.icns;${CMAKE_BINARY_DIR}/lyxrc.dist")
 414                 set(OSX_BUNDLE_DIRS "Resources;Resources;Resources")
 415
 416                 # Process Info.plist and lyxrc.dist
 417                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/Info.plist.in" "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 418                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/lyxrc.dist.in" "${CMAKE_CURRENT_BINARY_DIR}/lyxrc.dist")
 419
 420                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 421                 set(LYX_DATA_SUBDIR ${LYX_BUNDLE_NAME}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 422
 423                 # Variables used by CPack
 424                 set(CPACK_BUNDLE_NAME ${LYX_BUNDLE_NAME})
 425                 set(CPACK_BUNDLE_PLIST "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 426                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${LYX_BUNDLE_NAME}.app)
 427
 428                 # Set the install paths
 429                 set(LYX_UTILITIES_INSTALL_PATH ${LYX_BUNDLE_NAME}.app/Contents/MacOS)
 430                 if(NOT LYX_INSTALL_PREFIX)
 431                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 432                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 433                 endif()
 434                 # Change the owner so that the install can work
 435                 install(CODE "set(BU_CHMOD_BUNDLE_ITEMS 1)" COMPONENT Runtime)
 436         elseif(UNIX)
 437                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 438                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 439                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 440         elseif(WIN32)
 441                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 442         endif()
 443 endif()
 444
 445 if(LYX_INSTALL_PREFIX)
 446         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 447         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 448 endif()
 449 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 450
 451 if(UNIX)
 452   set(SYSTEM_DATADIR "${CMAKE_INSTALL_PREFIX}/share")
 453 elseif(CMAKE_INSTALL_PREFIX MATCHES "/lyx${LYX_INSTALL_SUFFIX}$")
 454   string(REGEX REPLACE "/lyx${LYX_INSTALL_SUFFIX}$" "/share" SYSTEM_DATADIR ${CMAKE_INSTALL_PREFIX})
 455 else()
 456   set(SYSTEM_DATADIR "${CMAKE_INSTALL_PREFIX}")
 457 endif()
 458
 459 if(CMAKE_COMPILER_IS_GNUCXX)
 460   message(STATUS "CMAKE_COMPILER_IS_GNUCXX = ${CMAKE_COMPILER_IS_GNUCXX}")
 461   set(suffixing ${LYX_PROGRAM_SUFFIX})
 462 else()
 463   # Not a GCC compiler, programs do not have a suffix
 464   set(suffixing ${LYX_PACKAGE_SUFFIX})
 465 endif()
 466
 467 # The define PACKAGE below allows lyx-executable to find its default configuration files
 468 # see routines
 469 #    Package::messages_file()
 470 #    get_default_user_support_dir()
 471 #    relative_system_support_dir()
 472 # in src/support/Package.cpp
 473 #
 474 if(suffixing)
 475         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 476 else()
 477         set(PACKAGE ${PACKAGE_BASE})
 478 endif()
 479
 480 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 481         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 482         if (UNIX)
 483                 # use the default "/usr/local"
 484                 # but respect the user-choice on the command-line
 485                 set(CMAKE_INSTALL_PREFIX "/usr/local" CACHE PATH "LyX default install prefix" FORCE)
 486         endif()
 487 endif()
 488 if(WIN32)
 489         set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 490 endif()
 491 if(IS_ABSOLUTE)
 492         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 493 else()
 494         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 495 endif()
 496
 497
 498
 499 if(NOT LYX_DATA_SUBDIR)
 500         if (WIN32)
 501                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 502         else()
 503                 set(LYX_DATA_SUBDIR "share/${_lyx}/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 504         endif()
 505 endif()
 506
 507 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 508 get_locale_destination(LYX_LOCALEDIR)
 509 set(LYX_ABS_INSTALLED_LOCALEDIR "${CMAKE_INSTALL_PREFIX}/${LYX_LOCALEDIR}")
 510 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 511
 512 if(LYX_BUNDLE AND APPLE)
 513         set(LYX_MAN_DIR "${LYX_DATA_SUBDIR}" CACHE STRING "Install location for man pages.")
 514 else()
 515         if(WIN32)
 516                 set(LYX_MAN_DIR "${CMAKE_BINARY_DIR}/usr/local/man" CACHE STRING "Install location for man pages.")
 517         elseif(UNIX)
 518                 set(LYX_MAN_DIR "${CMAKE_INSTALL_PREFIX}/share/man" CACHE STRING "Install location for man pages.")
 519         else()
 520                 set(LYX_MAN_DIR "${CMAKE_INSTALL_PREFIX}/man" CACHE STRING "Install location for man pages.")
 521         endif()
 522 endif()
 523 mark_as_advanced(LYX_MAN_DIR)
 524
 525 if(LYX_INSTALL AND WIN32)
 526         message(STATUS "Configuring NSIS files")
 527         configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 528         configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 529         configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 530         message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 531 endif()
 532
 533 if(NOT GROUP_CODE)
 534         #set(GROUP_CODE "The Golden Code")
 535         set(GROUP_CODE flat)
 536 endif()
 537
 538 # lyx's source files
 539 set(LYX_CPP_FILES [a-zA-Z]*.cpp)
 540 set(LYX_HPP_FILES [a-zA-Z]*.h)
 541 set(LYX_MOC_FILES moc_*.cpp)
 542
 543 include(ProjectSourceGroup)
 544
 545
 546 if(LYX_PROFILE AND NOT MSVC)
 547         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 548         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg")
 549         set(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS}  -pg")
 550 else()
 551         set(LYX_PROFILE OFF)
 552 endif()
 553
 554
 555 if(LYX_NO_OPTIMIZE)
 556         set(CMAKE_BUILD_TYPE None)
 557         set(LYX_DEBUG OFF)
 558         set(LYX_RELEASE OFF)
 559         set(LYX_PROFILE OFF)
 560 elseif(LYX_RELEASE)
 561         set(CMAKE_BUILD_TYPE Release)
 562         set(LYX_DEBUG OFF)
 563         set(LYX_PROFILE OFF)
 564 elseif(LYX_PROFILE)
 565         set(CMAKE_BUILD_TYPE Profile)
 566         set(LYX_DEBUG OFF)
 567 else()
 568         set(CMAKE_BUILD_TYPE Debug)
 569         set(LYX_DEBUG ON)
 570 endif()
 571
 572
 573 # When shared libs are supported enable this option
 574 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 575 if(LYX_SHARED_LIBRARIES)
 576         set(library_type SHARED)
 577 else()
 578         set(library_type STATIC)
 579 endif()
 580
 581 if(NOT MSVC)
 582         if(NOT LYX_QUIET)
 583                 set(CMAKE_VERBOSE_MAKEFILE ON)
 584         endif()
 585         set(LYX_CXX_FLAGS "-Wall -Wunused-parameter ${LYX_GCC11_MODE}")
 586         if(LYX_CXX_FLAGS MATCHES "\\+\\+(14|11|98)")
 587           # Thanks to Brad King <brad.king@kitware.com>
 588           # for the pointer to https://cmake.org/cmake/help/v3.6/variable/CMAKE_CXX_STANDARD.html
 589           # This allows us to use QT5.7 with recent g++ (version >= 4.9) compilers
 590           # and still use our own c++ extension tests
 591           set(CMAKE_CXX_STANDARD ${CMAKE_MATCH_1})
 592           message(STATUS "CMAKE_CXX_STANDARD set to ${CMAKE_CXX_STANDARD}")
 593         endif()
 594         if(LYX_STDLIB_DEBUG)
 595                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 596         endif()
 597         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 598         set(CMAKE_CXX_FLAGS_DEBUG "-O0 -g3 -D_DEBUG" CACHE TYPE STRING FORCE)
 599         if(MINGW)
 600                 set(CMAKE_CXX_FLAGS_RELEASE "-O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 601         else()
 602                 set(CMAKE_CXX_FLAGS_RELEASE "-O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 603         endif()
 604 endif()
 605
 606 set(LYX_CXX_FLAGS_EXTRA "" CACHE STRING "Desired semicolon separated list of extra cxx compile flags, like '-Werror'")
 607 mark_as_advanced(LYX_CXX_FLAGS_EXTRA)
 608 if(LYX_CXX_FLAGS_EXTRA)
 609         foreach(_flag ${LYX_CXX_FLAGS_EXTRA})
 610                 add_definitions(${_flag})
 611         endforeach()
 612 endif()
 613
 614 if(LYX_XMINGW)
 615         list(APPEND CMAKE_FIND_ROOT_PATH ${GNUWIN32_DIR})
 616 endif()
 617
 618 set(min_qt5_version "5.6")
 619 if(LYX_USE_QT MATCHES "AUTO")
 620         # try qt5 first
 621         find_package(Qt5Core QUIET)
 622         if(Qt5Core_FOUND)
 623                 set(LYX_USE_QT "QT5" CACHE STRING "Valid qt version" FORCE)
 624                 message(STATUS "Qt5Core_VERSION = ${Qt5Core_VERSION}")
 625                 if(Qt5Core_VERSION VERSION_LESS ${min_qt5_version})
 626                         find_package(Qt4 "4.5.0" QUIET)
 627                         if(QT4_FOUND)
 628                                 set(LYX_USE_QT "QT4" CACHE STRING "Valid qt version" FORCE)
 629                         endif()
 630                 endif()
 631         else()
 632                 set(LYX_USE_QT "QT4" CACHE STRING "Valid qt version" FORCE)
 633         endif()
 634 endif()
 635 if(LYX_USE_QT MATCHES "QT5")
 636         # set QPA_XCB if QT uses X11
 637         find_package(Qt5Core REQUIRED)
 638         if (Qt5Core_FOUND)
 639                 find_package(Qt5Widgets REQUIRED)
 640                 if(APPLE)
 641                         find_package(Qt5MacExtras REQUIRED)
 642                 endif()
 643                 find_package(Qt5X11Extras QUIET)
 644                 find_package(Qt5WinExtras QUIET)
 645                 set(QTVERSION ${Qt5Core_VERSION})
 646                 if (QTVERSION VERSION_LESS ${min_qt5_version})
 647                         message(STATUS "QTVERSION = \"${QTVERSION}\"")
 648                         message(STATUS "This version is not recommended, try either option -DLYX_USE_QT=QT4 or")
 649                         message(STATUS "install QT-Version >= \"${min_qt5_version}\"")
 650                         # see thread in lyx-devel list
 651                         # From: Jean-Pierre Chrétien <jeanpierre.chretien@free.fr>
 652                         # Date 11.03.2017
 653                         # Subject: cmake compilation error
 654                         #message(FATAL_ERROR "Wrong Qt-Version")
 655                 endif()
 656                 macro (qt_use_modules)
 657                         qt5_use_modules(${ARGN})
 658                 endmacro()
 659                 macro (qt_add_resources)
 660                         qt5_add_resources(${ARGN})
 661                 endmacro()
 662                 macro (qt_wrap_uifiles)
 663                         qt5_wrap_ui(${ARGN})
 664                 endmacro()
 665                 message(STATUS "Found Qt-Version ${QTVERSION}")
 666                 if(WIN32)
 667                         set(LYX_QTMAIN_LIBRARY ${Qt5Core_QTMAIN_LIBRARIES})
 668                 endif()
 669         endif()
 670 elseif(LYX_USE_QT MATCHES "QT4")
 671         if(LYX_XMINGW)
 672                 set(QT_MINGW_DIR ${LYX_QT4} CACHE PATH "Qt for Mingw" FORCE)
 673                 list(APPEND CMAKE_FIND_ROOT_PATH ${QT_MINGW_DIR} ${GNUWIN32_DIR})
 674         endif()
 675         find_package(Qt4 "4.5.0" REQUIRED)
 676         macro (qt_use_modules)
 677         endmacro()
 678         macro (qt_add_resources)
 679                 qt4_add_resources(${ARGN})
 680         endmacro()
 681         macro (qt_wrap_uifiles)
 682                 qt4_wrap_ui(${ARGN})
 683         endmacro()
 684         set(LYX_QTMAIN_LIBRARY ${QT_QTSVG_LIBRARY})
 685         if(WIN32)
 686                 list(APPEND LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARIES})
 687         endif()
 688 else()
 689   message(FATAL_ERROR "Unhandled value for LYX_USE_QT (${LYX_USE_QT})")
 690 endif()
 691
 692 find_package(Magic)
 693 if(Magic_FOUND)
 694         set(HAVE_MAGIC_H 1)
 695 endif()
 696
 697 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 698
 699 set(Spelling_FOUND OFF)
 700 set(Include_used_spellchecker)   # String will be inserted into config.h
 701
 702 if (LYX_EXTERNAL_MYTHES MATCHES "AUTO")
 703   # try system library first
 704   find_package(MyThesLIB)
 705   if (MYTHESLIB_FOUND)
 706     set(LYX_EXTERNAL_MYTHES ON CACHE STRING "OFF:= Build 3rdparty mytheslib" FORCE)
 707   else()
 708     set(LYX_EXTERNAL_MYTHES OFF CACHE STRING "OFF:= Build 3rdparty mytheslib" FORCE)
 709   endif()
 710 endif()
 711 if (LYX_EXTERNAL_MYTHES MATCHES "ON")
 712   find_package(MyThesLIB REQUIRED)
 713 else()
 714   add_subdirectory(3rdparty/mythes)
 715 endif()
 716 set(MYTHES_DIR ${MYTHESLIB_INCLUDE_DIR})
 717
 718 if(NOT LYX_EXTERNAL_HUNSPELL)
 719     add_subdirectory(3rdparty/hunspell)
 720     add_definitions(-DHUNSPELL_STATIC)
 721     set(HUNSPELL_FOUND ON)
 722     message(STATUS "  * Hunspell:")
 723     message(STATUS "     - include: ${HUNSPELL_INCLUDE_DIR}")
 724     message(STATUS "     - library: ${HUNSPELL_LIBRARY}")
 725 endif()
 726
 727 foreach(_spell "ASPELL" "Enchant" "Hunspell")
 728   string(TOUPPER ${_spell} _upspell)
 729   if (NOT ${_upspell}_FOUND)
 730     find_package(${_spell})
 731   endif()
 732   if (${_upspell}_FOUND)
 733     include_directories(${${_upspell}_INCLUDE_DIR})
 734     set(Spelling_FOUND ON)
 735     message(STATUS "Building with USE_${_upspell}")
 736     set(Include_used_spellchecker "${Include_used_spellchecker}#define USE_${_upspell} 1\n")
 737   else()
 738     if(LYX_${_upspell})
 739       message(FATAL_ERROR "Required ${_spell} devel package not found")
 740     else()
 741       message(STATUS "${_upspell} not found, building without ${_spell} support")
 742     endif()
 743   endif()
 744 endforeach()
 745
 746 if(GNUWIN32_DIR)
 747         list(APPEND CMAKE_PROGRAM_PATH "${GNUWIN32_DIR}/Python" )
 748 endif()
 749
 750 # Search for python default version first
 751 unset(PYTHON_EXECUTABLE CACHE)
 752 unset(LYX_PYTHON_EXECUTABLE CACHE)
 753 unset(PYTHON_VERSION_MAJOR)
 754 unset(PYTHON_VERSION_MINOR)
 755 unset(PYTHON_VERSION_STRING)
 756 find_package(PythonInterp 3.3 QUIET)
 757 if(NOT PYTHONINTERP_FOUND)
 758   unset(PYTHON_EXECUTABLE CACHE)
 759   find_package(PythonInterp 2.0 REQUIRED)
 760   if(NOT PYTHON_VERSION_STRING VERSION_LESS 2.8)
 761     message(FATAL_ERROR "Python interpreter found, but is not suitable")
 762   endif()
 763 endif()
 764
 765 set(LYX_PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 766
 767 if(LYX_NLS)
 768         find_package(LyXGettext)
 769         if(LYX_PYTHON_EXECUTABLE AND GETTEXT_FOUND)
 770                 add_subdirectory(po "${TOP_BINARY_DIR}/po")
 771         else()
 772                 # Install only supplied .gmo-files
 773                 file(GLOB _gmofiles RELATIVE "${TOP_SRC_DIR}/po" "${TOP_SRC_DIR}/po/*.gmo")
 774                 message(STATUS "Installing provided .gmo-files only")
 775                 foreach( _gmo ${_gmofiles})
 776                         string(REGEX REPLACE "\\.gmo$" "" _lang ${_gmo})
 777                         install(FILES "${TOP_SRC_DIR}/po/${_gmo}" DESTINATION ${LYX_LOCALEDIR}/${_lang}/LC_MESSAGES RENAME ${PACKAGE}.mo)
 778                 endforeach()
 779         endif()
 780 endif()
 781
 782 if(LYX_EXTERNAL_ICONV)
 783   find_package(ICONV REQUIRED)
 784 else()
 785   add_subdirectory(3rdparty/libiconv)
 786   set(HAVE_ICONV_CONST 1)
 787 endif()
 788
 789 if(LYX_EXTERNAL_Z)
 790   find_package(ZLIB REQUIRED)
 791 else()
 792   add_subdirectory(3rdparty/zlib)
 793 endif()
 794
 795 if(LYX_USE_STD_REGEX)
 796   # Set only include path.
 797   # Use internal boost, which is known to exist
 798   # we don't need any libraries
 799   set(Lyx_Boost_Libraries)
 800   add_definitions(-DBOOST_USER_CONFIG=<config.h>)
 801   include_directories(${TOP_SRC_DIR}/3rdparty/boost)
 802 else()
 803   # Using boost-regex
 804   if(LYX_EXTERNAL_BOOST)
 805     message(STATUS "Searching for external boost")
 806     find_package(Boost COMPONENTS regex)
 807     if(Boost_FOUND)
 808       message(STATUS "Boost found")
 809       message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 810       set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 811       if (LYX_STDLIB_DEBUG)
 812         # Comment from  Jean-Marc Lasgouttes:
 813         # In general, system boost libraries are incompatible with
 814         # the use of stdlib-debug in libstdc++. See ticket #9736 for
 815         # details.
 816         message(WARNING "Compiling LyX with stdlib-debug and system boost libraries may lead to crashes. Consider using '-DLYX_STDLIB_DEBUG=OFF' or using '-DLYX_EXTERNAL_BOOST=OFF'")
 817       endif()
 818     else()
 819       message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 820     endif()
 821   else()
 822     # Using included boost
 823     set(Lyx_Boost_Libraries boost_regex)
 824     add_definitions(-DBOOST_USER_CONFIG=<config.h>)
 825     include_directories(${TOP_SRC_DIR}/3rdparty/boost)
 826     add_subdirectory(3rdparty/boost "${TOP_BINARY_DIR}/3rdparty/boost")
 827   endif()
 828 endif()
 829
 830 if(WIN32)
 831         if(LYX_CONSOLE)
 832                 set(LYX_QTMAIN_LIBRARY)
 833         else()
 834                 set(WIN32_CONSOLE WIN32)
 835         endif()
 836         if(MSVC)
 837                 # -DPSAPI_VERSION=1 is needed to run on vista (bug 10186)
 838                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX -DPSAPI_VERSION=1)
 839                 # disable checked iterators for msvc release builds to get maximum speed
 840                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 841         else()
 842                 # -DPSAPI_VERSION=1 is not needed for mingw, since the mingw psapi.h
 843                 # does not use it and always declares the vista compatible API.
 844                 # If this ever changes then -DPSAPI_VERSION might be needed here as well.
 845                 add_definitions(-DWINVER=0x0500)
 846         endif()
 847 endif()
 848
 849 # Compute qt-version from ${QTVERSION}
 850
 851 message(STATUS "")
 852 foreach(_v PACKAGE PACKAGE_VERSION
 853         PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 854         LYX_ABS_TOP_SRCDIR
 855         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 856         if(NOT DEFINED ${_v})
 857                 message(FATAL_ERROR "${_v} not defined")
 858         endif()
 859         string(SUBSTRING "${_v}                            " 0 28 _v1)
 860         message(STATUS "----- ${_v1}: ${${_v}}")
 861 endforeach(_v)
 862 message(STATUS "")
 863
 864
 865 if(LYX_PCH)
 866         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 867         # Not sure if it works for all non-msvc compilers
 868         include(PCHSupport_26)
 869         configure_file(${TOP_CMAKE_PATH}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
 870         configure_file(${TOP_CMAKE_PATH}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 871         add_definitions(-DLYX_ENABLE_PCH)
 872
 873         if(MSVC)
 874                 macro(lyx_add_msvc_pch name_)
 875                         set_source_files_properties(${${name_}_sources} PROPERTIES
 876                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 877                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
 878                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 879                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
 880                                 ${TOP_BINARY_DIR}/pcheaders.h)
 881                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 882                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 883                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 884                 endmacro(lyx_add_msvc_pch)
 885                 macro(lyx_add_gcc_pch name_)
 886                 endmacro()
 887         else()
 888                 macro(lyx_add_msvc_pch name_)
 889                 endmacro()
 890                 macro(lyx_add_gcc_pch name_)
 891                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT)
 892                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
 893                 endmacro()
 894         endif()
 895 else()
 896         macro(lyx_add_msvc_pch)
 897         endmacro(lyx_add_msvc_pch)
 898         macro(lyx_add_gcc_pch name_)
 899         endmacro()
 900 endif()
 901
 902
 903 if(MSVC)
 904
 905         if(LYX_VLD)
 906                 set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/development/Win32/vld)
 907                 add_subdirectory(${vld_path}/cmake)
 908                 include(${vld_path}/cmake/vld.cmake) # forced include
 909                 set(vld_dll vld)
 910         endif()
 911
 912         if(LYX_WALL)
 913                 # Use the highest warning level
 914                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 915
 916                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 917                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 918                 else()
 919                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 920                 endif()
 921
 922                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 923                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 924                 else()
 925                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 926                 endif()
 927
 928                 # add here warnings which should produce an error /weXXXX
 929                 set(MSVC_W_ERROR   "/we4101 /we4189")
 930                 # add here warnings which should be disabled /wdXXXX
 931                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 932
 933                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 934                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 935                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 936
 937         else()
 938                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 939
 940                 # add here warnings which should produce an error /weXXXX
 941                 set(MSVC_W_ERROR   "/we4101 /we4189")
 942                 # add here warnings which should be disabled /wdXXXX
 943                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 944
 945                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 946                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 947                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 948
 949         endif()
 950
 951         if (NOT Qt5Core_FOUND)
 952                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 953                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 954                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 955         endif()
 956
 957         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 958         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 959         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 960         message(STATUS "")
 961 endif()
 962
 963
 964 if(LYX_DEBUG_GLIBC)
 965         set(_GLIBCXX_DEBUG ON)
 966 endif()
 967
 968 if(LYX_DEBUG_GLIBC_PEDANTIC)
 969         set(_GLIBCXX_DEBUG_PEDANTIC ON)
 970 endif()
 971
 972 # Xcode compiler
 973 if (CMAKE_GENERATOR MATCHES Xcode)
 974         if (XCODE_VERSION VERSION_LESS "5.0")
 975                 # Automatically select the Xcode compiler if not set
 976                 if (NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 977                         # XCode >= 3.1 has gcc 4.2 (up to actual Xcode)
 978                         if (XCODE_VERSION VERSION_GREATER "3.1")
 979                                 SET(CMAKE_XCODE_ATTRIBUTE_GCC_VERSION "com.apple.compilers.llvmgcc42")
 980                         ENDIF(XCODE_VERSION VERSION_GREATER "3.1")
 981                 ENDIF(NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 982                 # Print the selected compiler version
 983         MESSAGE(STATUS "---- Using XCode compiler CMAKE_XCODE_ATTRIBUTE_GCC_VERSION=${CMAKE_XCODE_ATTRIBUTE_GCC_VERSION}")
 984         ENDIF(XCODE_VERSION VERSION_LESS "5.0")
 985 ENDIF(CMAKE_GENERATOR MATCHES Xcode)
 986
 987 if (WIN32 AND Qt5Core_FOUND)
 988         set(Z_PREFIX 1)
 989 endif()
 990
 991 # compiler tests, config.h generation LYX_CONFIGURE_CHECKS
 992 include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
 993 configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
 994
 995 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
 996
 997 if(QTVERSION MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+).*")
 998         MATH(EXPR QT4_VERSION "(${CMAKE_MATCH_1}<<16)|(${CMAKE_MATCH_2}<<8)|${CMAKE_MATCH_3}")
 999 endif()
1000
1001 if (NOT HAVE_REGEX)
1002         set(LYX_USE_STD_REGEX 0)
1003 endif()
1004
1005
1006 set (cmd ${CMAKE_CTEST_COMMAND})
1007 if (MSVC)
1008         set (cmd ${cmd} -C ${CMAKE_CFG_INTDIR})
1009 else ()
1010         set (cmd ${cmd} -C ${CMAKE_BUILD_TYPE})
1011 endif ()
1012 add_custom_target (lyx_run_tests COMMAND ${cmd})
1013 set_target_properties(lyx_run_tests PROPERTIES FOLDER "tests")
1014
1015 if(LYX_ASAN)
1016     set(LYX_CXX_FLAGS "-fsanitize=address -fno-omit-frame-pointer -g")
1017     message(STATUS)
1018     message(STATUS "Address sanitizer enabled. Usage:")
1019     message(STATUS "    wget https://llvm.org/svn/llvm-project/compiler-rt/trunk/lib/asan/scripts/asan_symbolize.py")
1020     message(STATUS "    chmod  +x ./asan_symbolize.py")
1021     message(STATUS "    ./bin/lyx2.2 2>&1 | ./asan_symbolize.py  | c++filt ")
1022     message(STATUS)
1023 endif()
1024
1025 if(LYX_INSTALL)
1026         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
1027                 message(STATUS "Python required to create doc!")
1028         else()
1029                 if(UNIX)
1030                         add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
1031                 endif()
1032                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
1033         endif()
1034 endif()
1035 include(../Install)
1036
1037 add_subdirectory(src "${TOP_BINARY_DIR}/src")
1038 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
1039 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
1040 add_subdirectory(lib/examples "${TOP_BINARY_DIR}/lib/examples")
1041 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
1042 add_subdirectory(development/autotests "${TOP_BINARY_DIR}/autotests")
1043 if(LYX_ENABLE_URLTESTS)
1044         add_subdirectory(development/checkurls "${TOP_BINARY_DIR}/checkurls")
1045 endif()
1046
1047 message(STATUS)
1048 message(STATUS "Build params, switch LYX_* options by -DLYX_*=ON or OFF, LYX_* combos by -DLYX_*=value:")
1049 message(STATUS)
1050
1051 LYX_OPTION_LIST_ALL(used)
1052
1053
1054 if(LYX_NLS)
1055         message(STATUS)
1056         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
1057         message(STATUS)
1058         message(STATUS "  * iconv")
1059         message(STATUS "     - include: ${ICONV_INCLUDE_DIR}")
1060         message(STATUS "     - library: ${ICONV_LIBRARY}")
1061         message(STATUS "  * zlib")
1062         message(STATUS "     - include: ${ZLIB_INCLUDE_DIR}")
1063         message(STATUS "     - library: ${ZLIB_LIBRARY}")
1064         message(STATUS)
1065 endif()
1066
1067 # Apple has builtin native spell checker,
1068 # no need to warn for missing Aspell, Hunspell or Enchant
1069 if(NOT Spelling_FOUND AND NOT APPLE)
1070   if(LYX_REQUIRE_SPELLCHECK)
1071     set(_mode "FATAL_ERROR")
1072   else()
1073     set(_mode "STATUS")
1074   endif()
1075   message(${_mode} "No spellcheck libraries found. LyX will be unable use spellchecking")
1076 endif()
1077
1078 include("${TOP_CMAKE_PATH}/LyxPackaging.cmake")
1079
1080 if(ENABLE_DIST)
1081   # Use git to create the source package
1082   # git archive --format=tgz --output=/home/kornel/x.tar.gz master
1083   if(UNIX)
1084     set(DIST_FORMAT tgz)
1085   else()
1086     set(DIST_FORMAT zip)
1087   endif()
1088   set(DIST_NAME ${CMAKE_PROJECT_NAME}-${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}-${CMAKE_SYSTEM_NAME}.${DIST_FORMAT})
1089
1090   add_custom_command(
1091     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME}
1092     COMMAND  ${LYX_GITVERSION} archive --format=${DIST_FORMAT} --output=${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME} master
1093     WORKING_DIRECTORY ${TOP_SRC_DIR})
1094   add_custom_target(git-archive DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME})
1095 endif()
1096
1097 # Last directory to be included so that the fixup code (OS X)
1098 # can be run last
1099 add_subdirectory(development/cmake/post_install)
1100
1101 message(STATUS)