CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 3.1.0)
   8
   9 set(LYX_PROJECT LyX)
  10
  11 # Instruct cmake to not use gnu extensions,
  12 # this prevents the mix of '-std=c++*' and '-std=gnu++*' flags
  13 set(CMAKE_CXX_EXTENSIONS OFF)
  14
  15 enable_testing()
  16
  17 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README REALPATH) # Resolve symlinks
  18 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  19 message(STATUS "TOP_SRC_DIR = ${TOP_SRC_DIR}")
  20
  21 set(LYX_CMAKE_DIR "development/cmake")
  22 set(TOP_CMAKE_PATH "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}")
  23 set(TOP_MODULE_PATH "${TOP_CMAKE_PATH}/modules")
  24 set(TOP_SCRIPT_PATH "${TOP_CMAKE_PATH}/scripts")
  25
  26 set(CMAKE_MODULE_PATH "${TOP_MODULE_PATH}")
  27
  28 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  29
  30 message(STATUS)
  31 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  32         message(STATUS "Building in-source")
  33         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  34 else()
  35         message(STATUS "Building out-of-source")
  36         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  37 endif()
  38
  39 # This directory should be used if some test uses lyx-executable
  40 set(LYX_TESTS_USERDIR "${TOP_BINARY_DIR}/Testing/.lyx")
  41 file(MAKE_DIRECTORY "${LYX_TESTS_USERDIR}")
  42
  43 if(COMMAND cmake_policy)
  44         # Installing MACOSX_BUNDLE targets requires a BUNDLE DESTINATION
  45         cmake_policy(SET CMP0006 NEW)
  46         if(POLICY CMP0043)
  47                 # COMPILE_DEFINITIONS are not used yet. Enable new behavior.
  48                 cmake_policy(SET CMP0043 NEW)
  49         endif()
  50         cmake_policy(SET CMP0020 NEW)
  51         if(POLICY CMP0075)
  52                 cmake_policy(SET CMP0075 OLD)
  53         endif()
  54 endif()
  55
  56 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  57
  58 # Supress regeneration
  59 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  60
  61 if(LYX_XMINGW)
  62     set(CMAKE_SYSTEM_NAME Windows)
  63     set(TOOLNAME ${LYX_XMINGW})
  64     set(TOOLCHAIN "${TOOLNAME}-")
  65     set(CMAKE_C_COMPILER   "${TOOLCHAIN}gcc"     CACHE PATH "Mingw C compiler" FORCE)
  66     set(CMAKE_CXX_COMPILER "${TOOLCHAIN}g++"     CACHE PATH "Mingw C++ compiler" FORCE)
  67     set(CMAKE_RC_COMPILER  "${TOOLCHAIN}windres" CACHE PATH "Mingw rc compiler" FORCE)
  68
  69     set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM BOTH)
  70     set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY)
  71     set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY)
  72 endif()
  73
  74 if(NOT help AND NOT HELP)
  75   # 'project' triggers the searching for a compiler
  76   project(${LYX_PROJECT})
  77   if (CMAKE_COMPILER_IS_GNUCXX)
  78     if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS "4.0")
  79       message(STATUS "Gnu CXX compiler version = ${CMAKE_CXX_COMPILER_VERSION}")
  80       message(STATUS "is too old, should be >= 4.0")
  81       message(FATAL_ERROR "Exiting")
  82     endif()
  83   endif()
  84 endif()
  85
  86 if(UNIX)
  87         set(ARCH_TRIPLET )
  88         FIND_PROGRAM(DPKG_ARCHITECTURE_EXECUTABLE dpkg-architecture)
  89         if(DPKG_ARCHITECTURE_EXECUTABLE)
  90                 EXECUTE_PROCESS(COMMAND ${DPKG_ARCHITECTURE_EXECUTABLE} -qDEB_HOST_MULTIARCH
  91                                 OUTPUT_VARIABLE ARCH_TRIPLET
  92                                 ERROR_VARIABLE ERROR_ARCH_TRIPLET
  93                                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  94         endif()
  95 endif()
  96 if(ARCH_TRIPLET)
  97         set(SYSTEM_LIB_DIRS /usr/lib /usr/lib/${ARCH_TRIPLET} /usr/local/lib)
  98 else()
  99         set(SYSTEM_LIB_DIRS /usr/lib /usr/local/lib)
 100 endif()
 101
 102 include(LyXMacros)
 103 include(LyXDestinations)
 104
 105 # Usage LYX_OPTION
 106 # 1. parameter: option name without prefix 'LYX_'
 107 # 2. parameter: description
 108 # 3. parameter: default value, ON or OFF
 109 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
 110
 111 # Usage LYX_COMBO
 112 # 1. parameter: name without prefix 'LYX_'
 113 # 2. parameter: description
 114 # 3. parameter: default value
 115 # 4-n parameter: possible other string values
 116
 117 LYX_OPTION_INIT()
 118
 119 # Options for all compilers/systems
 120 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
 121 LYX_OPTION(LOCALVERSIONING  "Add version info to created package name (only used if LYX_CPACK option set)" OFF ALL)
 122 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
 123 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
 124 LYX_OPTION(REQUIRE_SPELLCHECK "Abort if no spellchecker available" OFF ALL)
 125 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
 126 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
 127 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
 128 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" OFF ALL)
 129 LYX_OPTION(DEBUG            "Enforce debug build"  OFF ALL)
 130 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
 131 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
 132 LYX_STRING(SUFFIX_VALUE     "Use this string as suffix" "")
 133 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
 134 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
 135 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
 136 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
 137 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
 138 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
 139 LYX_OPTION(ENABLE_URLTESTS  "Enable for URL tests" OFF ALL)
 140 LYX_OPTION(ENABLE_EXPORT_TESTS "Enable for export tests" OFF ALL)
 141 LYX_OPTION(ENABLE_KEYTESTS  "Enable for keytests" OFF ALL)
 142 LYX_OPTION(ASAN             "Use address sanitizer" OFF ALL)
 143 LYX_COMBO(USE_FILEDIALOG    "Use native or QT file dialog" QT NATIVE)
 144 LYX_COMBO(USE_QT            "Use Qt version as frontend" AUTO QT4 QT5)
 145 LYX_COMBO(USE_IPO           "Interprocedural optimization" OFF AUTO ON)
 146 #LYX_OPTION(3RDPARTY_BUILD   "Build 3rdparty libs" OFF ALL)
 147 LYX_OPTION(DISABLE_CALLSTACK_PRINTING "do not print a callstack when crashing" OFF ALL)
 148 LYX_OPTION(EXTERNAL_Z       "OFF := Build 3rdparty lib zlib" ON ALL)
 149 LYX_OPTION(EXTERNAL_ICONV   "OFF := Build 3rdparty lib iconvlib" ON ALL)
 150 LYX_OPTION(EXTERNAL_HUNSPELL "OFF := Build 3rdparty lib hunspelllib" ON ALL)
 151 LYX_COMBO(EXTERNAL_MYTHES   "OFF := Build 3rdparty lib mytheslib" AUTO OFF ON)
 152
 153 # GCC specific
 154 LYX_OPTION(PROFILE              "Build with options for gprof" OFF GCC)
 155 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" OFF GCC)
 156 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
 157 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
 158 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++ pedantic debug mode" OFF GCC)
 159 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" OFF GCC)
 160
 161 # MSVC specific
 162 LYX_OPTION(CONSOLE               "Show console on Windows" ON MSVC)
 163 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
 164 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
 165 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
 166
 167 # APPLE specific
 168 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
 169 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
 170
 171
 172 if(help OR HELP)
 173         message(STATUS)
 174         message(STATUS "Available options: (dis/enable with -DLYX_*=OFF/ON)")
 175         message(STATUS)
 176         LYX_OPTION_LIST_ALL(help)
 177         message(STATUS)
 178         RETURN()
 179 endif()
 180
 181 # Check option dependencies
 182
 183 if(LYX_DMG)
 184         set(LYX_BUNDLE ON)
 185         set(LYX_CPACK ON)
 186 endif()
 187
 188 if(LYX_CPACK)
 189         set(LYX_INSTALL ON)
 190 endif()
 191
 192 if(LYX_INSTALL)
 193         set(LYX_NLS ON)
 194         if(WIN32 AND NOT MINGW)
 195                 set(LYX_HUNSPELL ON)
 196         endif()
 197         set(LYX_PACKAGE_SUFFIX ON)
 198         if(NOT LYX_DEBUG)
 199                 set(LYX_RELEASE ON)
 200         endif()
 201         set(LYX_PROFILE OFF)
 202 endif()
 203
 204
 205 if(LYX_MERGE_FILES)
 206         set(LYX_PCH OFF)
 207 else()
 208         set(LYX_MERGE_REBUILD OFF)
 209 endif()
 210
 211 if(LYX_DEPENDENCIES_DOWNLOAD)
 212         message(STATUS)
 213         if(MSVC14)
 214                 set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2015-deps)
 215                 set(deps_files lyx-windows-deps-msvc2015.zip)
 216                 set(deps_server http://ftp.lyx.de/LyX-Windows-Deps)
 217                 set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2015)
 218         elseif(MSVC10)
 219                 set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 220                 set(deps_files lyx-windows-deps-msvc2010.zip)
 221                 set(deps_server http://ftp.lyx.de/LyX-Windows-Deps)
 222                 set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2010)
 223         else()
 224                 message(FATAL_ERROR "error: no dependency package known for the selected MSVC version.")
 225         endif()
 226     message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 227         foreach(it ${deps_files})
 228                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 229                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 230                 if(NOT already_downloaded)
 231                         message(STATUS "Downloading ${it} ...")
 232                         file(DOWNLOAD ${deps_server}/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS STATUS status LOG log)
 233                         list(GET status 0 status_code)
 234                         list(GET status 1 status_string)
 235                         if(NOT status_code EQUAL 0)
 236                                 file(REMOVE ${LYX_DEPENDENCIES_DIR}/${it})
 237                                 message(FATAL_ERROR "error: downloading '${it}' failed. status_code: ${status_code}, status_string: ${status_string}. \nLog: ${log} ")
 238                         endif()
 239                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 240                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 241                 endif()
 242         endforeach()
 243 endif()
 244
 245 message(STATUS)
 246
 247 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 248 if(WIN32)
 249         set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 250 else()
 251         set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 252 endif()
 253
 254 set(LYX_IPO_SUPPORTED OFF)
 255 if (POLICY CMP0069)
 256   cmake_policy(SET CMP0069 NEW)
 257   if(LYX_USE_IPO MATCHES "AUTO")
 258     # Enable LTO if supported and not debugging
 259     if (NOT LYX_DEBUG)
 260       include(CheckIPOSupported)
 261       check_ipo_supported(RESULT LYX_IPO_SUPPORTED)
 262     endif()
 263   else()
 264     set(LYX_IPO_SUPPORTED ${LYX_USE_IPO})
 265   endif()
 266 endif()
 267 if (LYX_IPO_SUPPORTED)
 268   set(LYX_USE_IPO "ON" CACHE STRING "Use interprocedural optimization" FORCE)
 269 else()
 270   set(LYX_USE_IPO "OFF" CACHE STRING "Use interprocedural optimization" FORCE)
 271 endif()
 272
 273 # Set to some meaningful default
 274 find_package(CXX11Compiler)
 275 if(NOT CXX11COMPILER_FOUND)
 276         message(FATAL_ERROR "A C++11 compatible compiler is required.")
 277 endif()
 278 set(LYX_GCC11_MODE)
 279 if(UNIX OR MINGW)
 280         if (CMAKE_CXX_COMPILER_ID MATCHES "^([cC]lang|AppleClang)$")
 281           # ignore the GCC_VERSION for clang
 282           # and use the resulting CXX11_STD_REGEX found in FindCXX11Compiler.cmake
 283           message(STATUS "Using clang")
 284           if(CXX11_STD_REGEX)
 285             set(LYX_USE_STD_REGEX 1)
 286           else()
 287             set(LYX_USE_STD_REGEX 0)
 288           endif()
 289         else()
 290           execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpfullversion OUTPUT_VARIABLE GCC_VERSION ERROR_VARIABLE _error RESULT_VARIABLE _err OUTPUT_STRIP_TRAILING_WHITESPACE)
 291           #message(STATUS "dumpfullversion: error = ${_error}, result = ${_err}")
 292           if (_err)
 293             # previous check failed, try again with _old_ parameter
 294             execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION ERROR_VARIABLE _error RESULT_VARIABLE _err OUTPUT_STRIP_TRAILING_WHITESPACE)
 295             #message(STATUS "dumpversion: error = ${_error}, result = ${_err}")
 296           endif()
 297           message(STATUS "Using GCC version ${GCC_VERSION}")
 298           if(GCC_VERSION VERSION_LESS 4.6)
 299                 message(FATAL_ERROR "gcc >= 4.6 is required.")
 300           elseif(GCC_VERSION VERSION_LESS 4.9)
 301                 # <regex> in gcc is unusable in versions less than 4.9.0
 302                 # see https://gcc.gnu.org/bugzilla/show_bug.cgi?id=53631
 303                 set(LYX_USE_STD_REGEX 0)
 304           else()
 305                 set(LYX_USE_STD_REGEX 1)
 306           endif()
 307         endif()
 308         set(LYX_GCC11_MODE "${CXX11_FLAG}")
 309 else()
 310         if(MSVC_VERSION LESS 1900)
 311                 # Drop support for msvc versions prior to 1900 (Visual Studio 2015)
 312                 message(FATAL_ERROR "Visual Studio >= 2015 is required.")
 313                 set(LYX_USE_STD_REGEX 0)
 314         else()
 315                 set(LYX_USE_STD_REGEX 1)
 316         endif()
 317 endif()
 318
 319
 320 set(VERSION_INFO "CMake Build")
 321
 322 # Try to get some informations from configure.ac
 323
 324 include(LyXPaths)
 325 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 326
 327 if(WIN32)
 328         set(CMAKE_PREFIX_PATH Specify-path-to-Qt CACHE PATH "Used Qt version")
 329         if(MSVC)
 330                 set(LYX_3RDPARTY_BUILD ON CACHE BOOL "Build 3rdparty libraries" FORCE)
 331         endif()
 332         set(USE_WINDOWS_PACKAGING ON)
 333 elseif(APPLE)
 334         set(USE_MACOSX_PACKAGING ON)
 335 else()
 336         set(USE_POSIX_PACKAGING ON)
 337 endif()
 338
 339 if(LYX_3RDPARTY_BUILD)
 340   # LYX_3RDPARTY_BUILD is not cached anymore, but for compatibility reasons
 341   # this enables the build of all 3rd_party libs
 342   set(LYX_EXTERNAL_Z        OFF CACHE BOOL "Build 3rdparty lib zlib"    FORCE)
 343   set(LYX_EXTERNAL_ICONV    OFF CACHE BOOL "Build 3rdparty iconvlib"    FORCE)
 344   set(LYX_EXTERNAL_HUNSPELL OFF CACHE BOOL "Build 3rdparty hunspelllib" FORCE)
 345   set(LYX_EXTERNAL_MYTHES   OFF CACHE STRING "Build 3rdparty mytheslib" FORCE)
 346 endif()
 347
 348 macro(setstripped _varname)
 349         if(${ARGC} GREATER 1)
 350                 string(STRIP "${ARGV1}" _v)
 351                 if (_v MATCHES "^\\[\(.+\)\\]$")
 352                   set(_v ${CMAKE_MATCH_1})
 353                 endif()
 354                 if(USE_POSIX_PACKAGING)
 355                         string(TOLOWER ${_v} ${_varname})
 356                 else()
 357                         set(${_varname} ${_v})
 358                 endif()
 359         else()
 360                 set(${_varname})
 361         endif()
 362 endmacro(setstripped)
 363
 364 foreach(_c_l ${_config_lines} )
 365         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 366                 # Not using CMAKE_MATCH_ directly is needed, because
 367                 # its value is now changed inside macro setstripped
 368                 set(_PB ${CMAKE_MATCH_1})
 369                 set(_PV ${CMAKE_MATCH_2})
 370                 set(_PBU ${CMAKE_MATCH_3})
 371                 setstripped(PACKAGE_BASE ${_PB})
 372                 setstripped(PACKAGE_VERSION ${_PV})
 373                 setstripped(PACKAGE_BUGREPORT ${_PBU})
 374                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\)\(\\.\([0-9]+\)\(\\.\([0-9]+\)\)?\)?.*$")
 375                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 376                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 377                         set(LYX_RELEASE_LEVEL ${CMAKE_MATCH_4})
 378                         set(LYX_RELEASE_PATCH ${CMAKE_MATCH_6})
 379                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 380                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 381                         if (NOT LYX_RELEASE_LEVEL)
 382                                 set(LYX_RELEASE_LEVEL '0')
 383                         endif()
 384                         if (NOT LYX_RELEASE_PATCH)
 385                                 set(LYX_RELEASE_PATCH '0')
 386                         endif()
 387                         if ("${LYX_SUFFIX_VALUE}" MATCHES "")
 388                           set(LYX_INSTALL_SUFFIX "${LYX_MAJOR_VERSION}.${LYX_MINOR_VERSION}")
 389                         else()
 390                           set(LYX_INSTALL_SUFFIX "${LYX_SUFFIX_VALUE}")
 391                         endif()
 392                 endif()
 393         endif()
 394         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 395                 set(LYX_DATE "${CMAKE_MATCH_1}")
 396         endif()
 397 endforeach(_c_l)
 398
 399 FIND_PROGRAM(LYX_GITVERSION git)
 400 #message(STATUS "gitversion = ${LYX_GITVERSION}")
 401 set(LYX_REVISION_VERSION ${LYX_RELEASE_LEVEL})
 402 set(LYX_PACKAGE_RELEASE "1")
 403 if(LYX_GITVERSION)
 404   if (LYX_LOCALVERSIONING)
 405     # Find the revision number and for later use
 406     EXECUTE_PROCESS(COMMAND ${LYX_GITVERSION} describe --match 2.0.0 HEAD
 407       WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE tmp_LYX_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 408     if (tmp_LYX_PACKAGE_RELEASE MATCHES "^2\\.0\\.0\\-\([0-9]+\)\\-\(.*\)$")
 409       set(LYX_PACKAGE_RELEASE ${CMAKE_MATCH_2})
 410       # We will add offset of 40000 to get appropriate value to
 411       # previous svn.
 412       # We use this value than also to set the package-patch-value
 413       MATH(EXPR tmp_REVISION_VERSION "(${CMAKE_MATCH_1}+40000)")
 414       set(LYX_REVISION_VERSION "${LYX_RELEASE_LEVEL}-${tmp_REVISION_VERSION}git")
 415       set(ENABLE_DIST ON)
 416     endif()
 417   endif()
 418 endif()
 419
 420 # Set the programs (lyx, tex2lyx, etc.) suffix
 421 # When building an OS X bundle, we will append
 422 # the suffix only to the bundle, not to the programs
 423 set(PROGRAM_SUFFIX "")
 424 if(LYX_PROGRAM_SUFFIX AND NOT (APPLE AND LYX_BUNDLE))
 425         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 426 endif()
 427 set(_lyx "${PACKAGE_BASE}${PROGRAM_SUFFIX}")
 428 set(_tex2lyx tex2lyx${PROGRAM_SUFFIX})
 429 set(_convert lyxconvert${PROGRAM_SUFFIX})
 430
 431 add_custom_target(lyx_version ALL
 432   COMMAND ${CMAKE_COMMAND} -DTOP_SRC_DIR=${TOP_SRC_DIR} -DTOP_CMAKE_PATH=${TOP_CMAKE_PATH} -DTOP_BINARY_DIR=${TOP_BINARY_DIR} -DLYX_DATE=${LYX_DATE} -P ${TOP_SCRIPT_PATH}/LyXGetVersion.cmake
 433   )
 434 set_target_properties(lyx_version PROPERTIES FOLDER "applications")
 435
 436 # Default paths for installed utilities (tex2lyx, lyxclient, etc.)
 437 set(LYX_UTILITIES_INSTALL_PATH bin)
 438
 439 if(LYX_BUNDLE)
 440         set(LYX_CPACK ON)
 441
 442         message(STATUS)
 443         message(STATUS "Bundle creation is enabled (experimental):")
 444         message(STATUS "    make")
 445         message(STATUS "    make install/strip")
 446         message(STATUS "    make package")
 447         if(APPLE)
 448                 set(MACOSX_BUNDLE TRUE)
 449                 # This sets the bundle + executable names
 450                 set(_lyx "${PACKAGE_BASE}${LYX_INSTALL_SUFFIX}")
 451                 # This sets the Info.plist executable name
 452                 set(osx_bundle_program_name ${_lyx})
 453                 # Bundle name
 454                 set(LYX_BUNDLE_NAME ${_lyx})
 455
 456                 # This will contain the list of files that need to be included
 457                 # in the bundle and their location within the bundle
 458                 set(OSX_BUNDLE_FILES "${TOP_SRC_DIR}/development/MacOSX/LyX.sdef;${TOP_SRC_DIR}/development/MacOSX/LyXapp.icns;${CMAKE_BINARY_DIR}/lyxrc.dist")
 459                 set(OSX_BUNDLE_DIRS "Resources;Resources;Resources")
 460
 461                 # Process Info.plist and lyxrc.dist
 462                 # See development/cmake/Install.cmake
 463                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/Info.plist.in" "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 464
 465                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 466                 set(LYX_DATA_SUBDIR ${LYX_BUNDLE_NAME}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 467
 468                 # Variables used by CPack
 469                 set(CPACK_BUNDLE_NAME ${LYX_BUNDLE_NAME})
 470                 set(CPACK_BUNDLE_PLIST "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 471                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${LYX_BUNDLE_NAME}.app)
 472
 473                 # Set the install paths
 474                 set(LYX_UTILITIES_INSTALL_PATH ${LYX_BUNDLE_NAME}.app/Contents/MacOS)
 475                 if(NOT LYX_INSTALL_PREFIX)
 476                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 477                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 478                 endif()
 479                 # Change the owner so that the install can work
 480                 install(CODE "set(BU_CHMOD_BUNDLE_ITEMS 1)" COMPONENT Runtime)
 481         elseif(UNIX)
 482                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 483                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 484                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 485         elseif(WIN32)
 486                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 487         endif()
 488 endif()
 489
 490 if(LYX_INSTALL_PREFIX)
 491         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 492         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 493 endif()
 494 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 495
 496 if(UNIX)
 497   set(SYSTEM_DATADIR "${CMAKE_INSTALL_PREFIX}/share")
 498 elseif(CMAKE_INSTALL_PREFIX MATCHES "/lyx${LYX_INSTALL_SUFFIX}$")
 499   string(REGEX REPLACE "/lyx${LYX_INSTALL_SUFFIX}$" "/share" SYSTEM_DATADIR ${CMAKE_INSTALL_PREFIX})
 500 else()
 501   set(SYSTEM_DATADIR "${CMAKE_INSTALL_PREFIX}")
 502 endif()
 503
 504 if(NOT CMAKE_COMPILER_IS_GNUCXX)
 505   # Not a GCC compiler, programs do not have a suffix
 506   set(suffixing ${LYX_PACKAGE_SUFFIX})
 507 elseif(WIN32 AND MINGW)
 508   # We want to use a suffix for the package in this case,
 509   # even if not for the program
 510   set(suffixing ${LYX_PACKAGE_SUFFIX})
 511 else()
 512   message(STATUS "CMAKE_COMPILER_IS_GNUCXX = ${CMAKE_COMPILER_IS_GNUCXX}")
 513   set(suffixing ${LYX_PROGRAM_SUFFIX})
 514 endif()
 515
 516 # The define PACKAGE below allows lyx-executable to find its default configuration files
 517 # see routines
 518 #    Package::messages_file()
 519 #    get_default_user_support_dir()
 520 #    relative_system_support_dir()
 521 # in src/support/Package.cpp
 522 if(suffixing)
 523         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 524 else()
 525         set(PACKAGE ${PACKAGE_BASE})
 526 endif()
 527
 528 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 529         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 530         if (UNIX)
 531                 # use the default "/usr/local"
 532                 # but respect the user-choice on the command-line
 533                 set(CMAKE_INSTALL_PREFIX "/usr/local" CACHE PATH "LyX default install prefix" FORCE)
 534         endif()
 535 endif()
 536 if(WIN32)
 537         set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 538 endif()
 539 if(IS_ABSOLUTE)
 540         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 541 else()
 542         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 543 endif()
 544
 545
 546
 547 if(NOT LYX_DATA_SUBDIR)
 548         if (WIN32)
 549                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 550         else()
 551                 set(LYX_DATA_SUBDIR "share/${_lyx}/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 552         endif()
 553 endif()
 554
 555 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 556 get_locale_destination(LYX_LOCALEDIR)
 557 set(LYX_ABS_INSTALLED_LOCALEDIR "${CMAKE_INSTALL_PREFIX}/${LYX_LOCALEDIR}")
 558 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 559
 560 if(LYX_BUNDLE AND APPLE)
 561         set(LYX_MAN_DIR "${LYX_DATA_SUBDIR}" CACHE STRING "Install location for man pages.")
 562 else()
 563         if(WIN32)
 564                 set(LYX_MAN_DIR "${CMAKE_BINARY_DIR}/usr/local/man" CACHE STRING "Install location for man pages.")
 565         elseif(UNIX)
 566                 set(LYX_MAN_DIR "${CMAKE_INSTALL_PREFIX}/share/man" CACHE STRING "Install location for man pages.")
 567         else()
 568                 set(LYX_MAN_DIR "${CMAKE_INSTALL_PREFIX}/man" CACHE STRING "Install location for man pages.")
 569         endif()
 570 endif()
 571 mark_as_advanced(LYX_MAN_DIR)
 572
 573 # The Win installer cannot be built by CMake because one needs to install plugins for NSIS
 574 # see the Readme.txt of the installer
 575 #if(LYX_INSTALL AND WIN32)
 576 #       message(STATUS "Configuring NSIS files")
 577 #       configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 578 #       configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 579 #       configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 580 #       message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 581 #endif()
 582
 583 if(NOT GROUP_CODE)
 584         #set(GROUP_CODE "The Golden Code")
 585         set(GROUP_CODE flat)
 586 endif()
 587
 588 # lyx's source files
 589 set(LYX_CPP_FILES [a-zA-Z]*.cpp)
 590 set(LYX_HPP_FILES [a-zA-Z]*.h)
 591 set(LYX_MOC_FILES moc_*.cpp)
 592
 593 include(ProjectSourceGroup)
 594
 595
 596 if(LYX_PROFILE AND NOT MSVC)
 597         set(CMAKE_BUILD_TYPE Profile CACHE STRING "Profile build type" FORCE)
 598         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg")
 599         set(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS}  -pg")
 600 else()
 601         set(LYX_PROFILE OFF)
 602 endif()
 603
 604
 605 if(LYX_NO_OPTIMIZE)
 606         set(CMAKE_BUILD_TYPE None)
 607         set(LYX_DEBUG OFF)
 608         set(LYX_RELEASE OFF)
 609         set(LYX_PROFILE OFF)
 610 elseif(LYX_RELEASE)
 611         set(CMAKE_BUILD_TYPE Release)
 612         set(LYX_DEBUG OFF)
 613         set(LYX_PROFILE OFF)
 614 elseif(LYX_PROFILE)
 615         set(CMAKE_BUILD_TYPE Profile)
 616         set(LYX_DEBUG OFF)
 617 else()
 618         set(CMAKE_BUILD_TYPE Debug)
 619         set(LYX_DEBUG ON)
 620 endif()
 621
 622
 623 # When shared libs are supported enable this option
 624 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 625 if(LYX_SHARED_LIBRARIES)
 626         set(library_type SHARED)
 627 else()
 628         set(library_type STATIC)
 629 endif()
 630
 631 if(NOT MSVC)
 632         if(NOT LYX_QUIET)
 633                 set(CMAKE_VERBOSE_MAKEFILE ON)
 634         endif()
 635         set(LYX_CXX_FLAGS "-Wall -Wunused-parameter ${LYX_GCC11_MODE}")
 636         if(LYX_CXX_FLAGS MATCHES "\\+\\+(14|11|98)")
 637           # Thanks to Brad King <brad.king@kitware.com>
 638           # for the pointer to https://cmake.org/cmake/help/v3.6/variable/CMAKE_CXX_STANDARD.html
 639           # This allows us to use QT5.7 with recent g++ (version >= 4.9) compilers
 640           # and still use our own c++ extension tests
 641           set(CMAKE_CXX_STANDARD ${CMAKE_MATCH_1})
 642           message(STATUS "CMAKE_CXX_STANDARD set to ${CMAKE_CXX_STANDARD}")
 643         endif()
 644         if(LYX_STDLIB_DEBUG)
 645                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 646         endif()
 647         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE STRING "Set CXX flags" FORCE)
 648         set(CMAKE_CXX_FLAGS_DEBUG "-O0 -g3 -D_DEBUG" CACHE STRING "Set debug flags" FORCE)
 649         if(MINGW)
 650                 set(CMAKE_CXX_FLAGS_RELEASE "-O2 -DNDEBUG" CACHE STRING "Set release flags for Mingw" FORCE)
 651         else()
 652                 set(CMAKE_CXX_FLAGS_RELEASE "-O3 -DNDEBUG" CACHE STRING "Set release flags" FORCE)
 653         endif()
 654 endif()
 655
 656 set(LYX_CXX_FLAGS_EXTRA "" CACHE STRING "Desired semicolon separated list of extra cxx compile flags, like '-Werror'")
 657 mark_as_advanced(LYX_CXX_FLAGS_EXTRA)
 658 if(LYX_CXX_FLAGS_EXTRA)
 659         foreach(_flag ${LYX_CXX_FLAGS_EXTRA})
 660                 add_definitions(${_flag})
 661         endforeach()
 662 endif()
 663
 664 if(LYX_XMINGW)
 665         list(APPEND CMAKE_FIND_ROOT_PATH ${GNUWIN32_DIR})
 666 endif()
 667
 668 set(min_qt5_version "5.6")
 669 if(LYX_USE_QT MATCHES "AUTO")
 670         # try qt5 first
 671         find_package(Qt5Core CONFIG QUIET)
 672         if(Qt5Core_FOUND)
 673                 set(LYX_USE_QT "QT5" CACHE STRING "Valid qt version" FORCE)
 674                 message(STATUS "Qt5Core_VERSION = ${Qt5Core_VERSION}")
 675                 if(Qt5Core_VERSION VERSION_LESS ${min_qt5_version})
 676                         find_package(Qt4 "4.5.0" QUIET)
 677                         if(QT4_FOUND)
 678                                 set(LYX_USE_QT "QT4" CACHE STRING "Valid qt version" FORCE)
 679                         endif()
 680                 endif()
 681         else()
 682                 set(LYX_USE_QT "QT4" CACHE STRING "Valid qt version" FORCE)
 683         endif()
 684 endif()
 685 if(LYX_USE_QT MATCHES "QT5")
 686         # set QPA_XCB if QT uses X11
 687         find_package(Qt5Core CONFIG REQUIRED)
 688         if (Qt5Core_FOUND)
 689                 find_package(Qt5Widgets CONFIG REQUIRED)
 690                 if(APPLE)
 691                         find_package(Qt5MacExtras CONFIG REQUIRED)
 692                 endif()
 693                 find_package(Qt5X11Extras CONFIG QUIET)
 694                 find_package(Qt5WinExtras CONFIG QUIET)
 695                 set(QTVERSION ${Qt5Core_VERSION})
 696                 if (QTVERSION VERSION_LESS ${min_qt5_version})
 697                         message(STATUS "QTVERSION = \"${QTVERSION}\"")
 698                         message(STATUS "This version is not recommended, try either option -DLYX_USE_QT=QT4 or")
 699                         message(STATUS "install QT-Version >= \"${min_qt5_version}\"")
 700                         # see thread in lyx-devel list
 701                         # From: Jean-Pierre Chrétien <jeanpierre.chretien@free.fr>
 702                         # Date 11.03.2017
 703                         # Subject: cmake compilation error
 704                         #message(FATAL_ERROR "Wrong Qt-Version")
 705                 endif()
 706                 macro (qt_use_modules lyxtarget)
 707                         foreach (_tg ${ARGN})
 708                                 find_package(Qt5${_tg} CONFIG REQUIRED)
 709                                 target_link_libraries(${lyxtarget} Qt5::${_tg})
 710                         endforeach()
 711                 endmacro()
 712                 macro (qt_add_resources)
 713                         qt5_add_resources(${ARGN})
 714                 endmacro()
 715                 macro (qt_wrap_uifiles)
 716                         qt5_wrap_ui(${ARGN})
 717                 endmacro()
 718                 message(STATUS "Found Qt-Version ${QTVERSION}")
 719                 if(WIN32)
 720                         set(LYX_QTMAIN_LIBRARY ${Qt5Core_QTMAIN_LIBRARIES})
 721                 endif()
 722         endif()
 723 elseif(LYX_USE_QT MATCHES "QT4")
 724         if(LYX_XMINGW)
 725                 set(QT_MINGW_DIR ${LYX_QT4} CACHE PATH "Qt for Mingw" FORCE)
 726                 list(APPEND CMAKE_FIND_ROOT_PATH ${QT_MINGW_DIR} ${GNUWIN32_DIR})
 727         endif()
 728         find_package(Qt4 "4.5.0" REQUIRED)
 729         macro (qt_use_modules)
 730         endmacro()
 731         macro (qt_add_resources)
 732                 qt4_add_resources(${ARGN})
 733         endmacro()
 734         macro (qt_wrap_uifiles)
 735                 qt4_wrap_ui(${ARGN})
 736         endmacro()
 737         set(LYX_QTMAIN_LIBRARY ${QT_QTSVG_LIBRARY})
 738         if(WIN32)
 739                 list(APPEND LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARIES})
 740         endif()
 741 else()
 742   message(FATAL_ERROR "Unhandled value for LYX_USE_QT (${LYX_USE_QT})")
 743 endif()
 744
 745 find_package(Magic)
 746 if(Magic_FOUND)
 747   set(HAVE_MAGIC_H 1)
 748   include_directories(${Magic_INCLUDE_DIR})
 749 endif()
 750
 751 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 752
 753 set(Spelling_FOUND OFF)
 754 set(Include_used_spellchecker)   # String will be inserted into config.h
 755
 756 if (LYX_EXTERNAL_MYTHES MATCHES "AUTO")
 757   # try system library first
 758   find_package(MyThesLIB)
 759   if (MYTHESLIB_FOUND)
 760     set(LYX_EXTERNAL_MYTHES ON CACHE STRING "OFF:= Build 3rdparty mytheslib" FORCE)
 761   else()
 762     set(LYX_EXTERNAL_MYTHES OFF CACHE STRING "OFF:= Build 3rdparty mytheslib" FORCE)
 763   endif()
 764 endif()
 765 if (LYX_EXTERNAL_MYTHES MATCHES "ON")
 766   find_package(MyThesLIB REQUIRED)
 767 else()
 768   add_subdirectory(3rdparty/mythes)
 769 endif()
 770 set(MYTHES_DIR ${MYTHESLIB_INCLUDE_DIR})
 771
 772 if(NOT LYX_EXTERNAL_HUNSPELL)
 773     add_subdirectory(3rdparty/hunspell)
 774     add_definitions(-DHUNSPELL_STATIC)
 775     set(HUNSPELL_FOUND ON)
 776     message(STATUS "  * Hunspell:")
 777     message(STATUS "     - include: ${HUNSPELL_INCLUDE_DIR}")
 778     message(STATUS "     - library: ${HUNSPELL_LIBRARY}")
 779 endif()
 780
 781 foreach(_spell "ASPELL" "Enchant" "Hunspell")
 782   string(TOUPPER ${_spell} _upspell)
 783   if (NOT ${_upspell}_FOUND)
 784     find_package(${_spell})
 785   endif()
 786   if (${_upspell}_FOUND)
 787     include_directories(${${_upspell}_INCLUDE_DIR})
 788     set(Spelling_FOUND ON)
 789     message(STATUS "Building with USE_${_upspell}")
 790     set(Include_used_spellchecker "${Include_used_spellchecker}#define USE_${_upspell} 1\n")
 791   else()
 792     if(LYX_${_upspell})
 793       message(FATAL_ERROR "Required ${_spell} devel package not found")
 794     else()
 795       message(STATUS "${_upspell} not found, building without ${_spell} support")
 796     endif()
 797   endif()
 798 endforeach()
 799
 800 if(GNUWIN32_DIR)
 801         list(APPEND CMAKE_PROGRAM_PATH "${GNUWIN32_DIR}/Python" )
 802 endif()
 803
 804 # Search for python default version first
 805 unset(PYTHON_EXECUTABLE CACHE)
 806 unset(LYX_PYTHON_EXECUTABLE CACHE)
 807 unset(PYTHON_VERSION_MAJOR)
 808 unset(PYTHON_VERSION_MINOR)
 809 unset(PYTHON_VERSION_STRING)
 810 if (CMAKE_VERSION VERSION_LESS "3.13")
 811   find_package(PythonInterp 3.5 QUIET)
 812   if(NOT PYTHONINTERP_FOUND)
 813     find_package(PythonInterp 2.0 REQUIRED)
 814     if(NOT PYTHON_VERSION_STRING VERSION_LESS 2.8)
 815       message(FATAL_ERROR "Python interpreter found, but is not suitable")
 816     endif()
 817   endif()
 818   set(LYX_PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 819 else()
 820   find_package(Python3 3.5 QUIET)
 821   if(NOT Python3_Interpreter_FOUND)
 822     unset(PYTHON_EXECUTABLE CACHE)
 823     find_package(Python2 2.0 REQUIRED)
 824     if(NOT Python2_VERSION VERSION_LESS 2.8)
 825       message(FATAL_ERROR "Python interpreter found, but is not suitable")
 826     endif()
 827     set(LYX_PYTHON_EXECUTABLE ${Python2_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 828   else()
 829     set(LYX_PYTHON_EXECUTABLE ${Python3_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 830   endif()
 831 endif()
 832
 833 if(LYX_NLS)
 834         find_package(LyXGettext)
 835         if(LYX_PYTHON_EXECUTABLE AND GETTEXT_FOUND)
 836                 add_subdirectory(po "${TOP_BINARY_DIR}/po")
 837         else()
 838                 # Install only supplied .gmo-files
 839                 file(GLOB _gmofiles RELATIVE "${TOP_SRC_DIR}/po" "${TOP_SRC_DIR}/po/*.gmo")
 840                 message(STATUS "Installing provided .gmo-files only")
 841                 foreach( _gmo ${_gmofiles})
 842                         string(REGEX REPLACE "\\.gmo$" "" _lang ${_gmo})
 843                         install(FILES "${TOP_SRC_DIR}/po/${_gmo}" DESTINATION ${LYX_LOCALEDIR}/${_lang}/LC_MESSAGES RENAME ${PACKAGE}.mo)
 844                 endforeach()
 845         endif()
 846 endif()
 847
 848 if(LYX_EXTERNAL_ICONV)
 849   find_package(ICONV REQUIRED)
 850 else()
 851   add_subdirectory(3rdparty/libiconv)
 852   set(HAVE_ICONV_CONST 1)
 853 endif()
 854
 855 if(LYX_EXTERNAL_Z)
 856   find_package(ZLIB REQUIRED)
 857 else()
 858   add_subdirectory(3rdparty/zlib)
 859 endif()
 860
 861 if(LYX_USE_STD_REGEX)
 862   # Set only include path.
 863   # Use internal boost, which is known to exist
 864   # we don't need any libraries
 865   set(Lyx_Boost_Libraries)
 866   add_definitions(-DBOOST_USER_CONFIG=<config.h>)
 867   include_directories(${TOP_SRC_DIR}/3rdparty/boost)
 868 else()
 869   # Using boost-regex
 870   if(LYX_EXTERNAL_BOOST)
 871     message(STATUS "Searching for external boost")
 872     find_package(Boost COMPONENTS regex)
 873     if(Boost_FOUND)
 874       message(STATUS "Boost found")
 875       message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 876       set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 877       if (LYX_STDLIB_DEBUG)
 878         # Comment from  Jean-Marc Lasgouttes:
 879         # In general, system boost libraries are incompatible with
 880         # the use of stdlib-debug in libstdc++. See ticket #9736 for
 881         # details.
 882         message(WARNING "Compiling LyX with stdlib-debug and system boost libraries may lead to crashes. Consider using '-DLYX_STDLIB_DEBUG=OFF' or using '-DLYX_EXTERNAL_BOOST=OFF'")
 883       endif()
 884     else()
 885       message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 886     endif()
 887   else()
 888     # Using included boost
 889     set(Lyx_Boost_Libraries boost_regex)
 890     add_definitions(-DBOOST_USER_CONFIG=<config.h>)
 891     include_directories(${TOP_SRC_DIR}/3rdparty/boost)
 892     add_subdirectory(3rdparty/boost "${TOP_BINARY_DIR}/3rdparty/boost")
 893   endif()
 894 endif()
 895
 896 if(WIN32)
 897         if(LYX_CONSOLE)
 898                 set(LYX_QTMAIN_LIBRARY)
 899         else()
 900                 set(WIN32_CONSOLE WIN32)
 901         endif()
 902         if(MSVC)
 903                 # -DPSAPI_VERSION=1 is needed to run on vista (bug 10186)
 904                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX -DPSAPI_VERSION=1)
 905                 # disable checked iterators for msvc release builds to get maximum speed
 906                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 907         else()
 908                 # -DPSAPI_VERSION=1 is not needed for mingw, since the mingw psapi.h
 909                 # does not use it and always declares the vista compatible API.
 910                 # If this ever changes then -DPSAPI_VERSION might be needed here as well.
 911                 add_definitions(-DWINVER=0x0500)
 912         endif()
 913 endif()
 914
 915 # Compute qt-version from ${QTVERSION}
 916
 917 message(STATUS "")
 918 foreach(_v PACKAGE PACKAGE_VERSION
 919         PROGRAM_SUFFIX LYX_DIR_VER LYX_USERDIR_VER
 920         LYX_ABS_TOP_SRCDIR
 921         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 922         if(NOT DEFINED ${_v})
 923                 message(FATAL_ERROR "${_v} not defined")
 924         endif()
 925         string(SUBSTRING "${_v}                            " 0 28 _v1)
 926         message(STATUS "----- ${_v1}: ${${_v}}")
 927 endforeach(_v)
 928 message(STATUS "")
 929
 930
 931 if(LYX_PCH)
 932         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 933         # Not sure if it works for all non-msvc compilers
 934         include(PCHSupport_26)
 935         configure_file(${TOP_CMAKE_PATH}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
 936         configure_file(${TOP_CMAKE_PATH}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 937         add_definitions(-DLYX_ENABLE_PCH)
 938
 939         if(MSVC)
 940                 macro(lyx_add_msvc_pch name_)
 941                         set_source_files_properties(${${name_}_sources} PROPERTIES
 942                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 943                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
 944                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 945                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
 946                                 ${TOP_BINARY_DIR}/pcheaders.h)
 947                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 948                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 949                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 950                 endmacro(lyx_add_msvc_pch)
 951                 macro(lyx_add_gcc_pch name_)
 952                 endmacro()
 953         else()
 954                 macro(lyx_add_msvc_pch name_)
 955                 endmacro()
 956                 macro(lyx_add_gcc_pch name_)
 957                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT)
 958                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
 959                 endmacro()
 960         endif()
 961 else()
 962         macro(lyx_add_msvc_pch)
 963         endmacro(lyx_add_msvc_pch)
 964         macro(lyx_add_gcc_pch name_)
 965         endmacro()
 966 endif()
 967
 968
 969 if(MSVC)
 970
 971         if(LYX_VLD)
 972                 set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/development/Win32/vld)
 973                 add_subdirectory(${vld_path}/cmake)
 974                 include(${vld_path}/cmake/vld.cmake) # forced include
 975                 set(vld_dll vld)
 976         endif()
 977
 978         if(LYX_WALL)
 979                 # Use the highest warning level
 980                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE STRING "Warning level" FORCE)
 981
 982                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 983                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 984                 else()
 985                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 986                 endif()
 987
 988                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 989                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 990                 else()
 991                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 992                 endif()
 993
 994                 # add here warnings which should produce an error /weXXXX
 995                 set(MSVC_W_ERROR   "/we4101 /we4189")
 996                 # add here warnings which should be disabled /wdXXXX
 997                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 998
 999                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1000                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1001                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1002
1003         else()
1004                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE STRING "Warning level" FORCE)
1005
1006                 # add here warnings which should produce an error /weXXXX
1007                 set(MSVC_W_ERROR   "/we4101 /we4189")
1008                 # add here warnings which should be disabled /wdXXXX
1009                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
1010
1011                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1012                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1013                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1014
1015         endif()
1016
1017         if (NOT Qt5Core_FOUND)
1018                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
1019                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
1020                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
1021         endif()
1022
1023         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
1024         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
1025         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
1026         message(STATUS "")
1027 endif()
1028
1029
1030 if(LYX_DEBUG_GLIBC)
1031         set(_GLIBCXX_DEBUG ON)
1032 endif()
1033
1034 if(LYX_DEBUG_GLIBC_PEDANTIC)
1035         set(_GLIBCXX_DEBUG_PEDANTIC ON)
1036 endif()
1037
1038 # Xcode compiler
1039 if (CMAKE_GENERATOR MATCHES Xcode)
1040         if (XCODE_VERSION VERSION_LESS "5.0")
1041                 # Automatically select the Xcode compiler if not set
1042                 if (NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
1043                         # XCode >= 3.1 has gcc 4.2 (up to actual Xcode)
1044                         if (XCODE_VERSION VERSION_GREATER "3.1")
1045                                 SET(CMAKE_XCODE_ATTRIBUTE_GCC_VERSION "com.apple.compilers.llvmgcc42")
1046                         ENDIF(XCODE_VERSION VERSION_GREATER "3.1")
1047                 ENDIF(NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
1048                 # Print the selected compiler version
1049         MESSAGE(STATUS "---- Using XCode compiler CMAKE_XCODE_ATTRIBUTE_GCC_VERSION=${CMAKE_XCODE_ATTRIBUTE_GCC_VERSION}")
1050         ENDIF(XCODE_VERSION VERSION_LESS "5.0")
1051 ENDIF(CMAKE_GENERATOR MATCHES Xcode)
1052
1053 if (WIN32 AND Qt5Core_FOUND)
1054         set(Z_PREFIX 1)
1055 endif()
1056
1057 # compiler tests, config.h generation LYX_CONFIGURE_CHECKS
1058 include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
1059 configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
1060
1061 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
1062
1063 if(QTVERSION MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+).*")
1064         MATH(EXPR QT4_VERSION "(${CMAKE_MATCH_1}<<16)|(${CMAKE_MATCH_2}<<8)|${CMAKE_MATCH_3}")
1065 endif()
1066
1067 if (NOT HAVE_REGEX)
1068         set(LYX_USE_STD_REGEX 0)
1069 endif()
1070
1071
1072 set (cmd ${CMAKE_CTEST_COMMAND})
1073 if (MSVC)
1074         set (cmd ${cmd} -C ${CMAKE_CFG_INTDIR})
1075 else ()
1076         set (cmd ${cmd} -C ${CMAKE_BUILD_TYPE})
1077 endif ()
1078 add_custom_target (lyx_run_tests COMMAND ${cmd})
1079 set_target_properties(lyx_run_tests PROPERTIES FOLDER "tests")
1080
1081 if(LYX_ASAN)
1082     set(LYX_CXX_FLAGS "-fsanitize=address -fno-omit-frame-pointer -g")
1083     message(STATUS)
1084     message(STATUS "Address sanitizer enabled. Usage:")
1085     message(STATUS "    wget https://llvm.org/svn/llvm-project/compiler-rt/trunk/lib/asan/scripts/asan_symbolize.py")
1086     message(STATUS "    chmod  +x ./asan_symbolize.py")
1087     message(STATUS "    ./bin/lyx2.2 2>&1 | ./asan_symbolize.py  | c++filt ")
1088     message(STATUS)
1089 endif()
1090
1091 if(LYX_INSTALL)
1092         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
1093                 message(STATUS "Python required to create doc!")
1094         else()
1095                 if(UNIX)
1096                         add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
1097                 endif()
1098                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
1099         endif()
1100 endif()
1101 include(../Install)
1102
1103 # By running the URL tests first, time can be saved when running the ctests in
1104 # parallel since the URL tests take a long time to run (e.g. 10 minutes).
1105 if(LYX_ENABLE_URLTESTS)
1106         add_subdirectory(development/checkurls "${TOP_BINARY_DIR}/checkurls")
1107 endif()
1108 add_subdirectory(src "${TOP_BINARY_DIR}/src")
1109 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
1110 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
1111 add_subdirectory(lib/examples "${TOP_BINARY_DIR}/lib/examples")
1112 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
1113 add_subdirectory(development/autotests "${TOP_BINARY_DIR}/autotests")
1114 add_subdirectory(development/batchtests "${TOP_BINARY_DIR}/batchtests")
1115
1116 message(STATUS)
1117 message(STATUS "Build params, switch LYX_* options by -DLYX_*=ON or OFF, LYX_* combos by -DLYX_*=value:")
1118 message(STATUS)
1119
1120 LYX_OPTION_LIST_ALL(used)
1121
1122
1123 if(LYX_NLS)
1124         message(STATUS)
1125         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
1126         message(STATUS)
1127         message(STATUS "  * iconv")
1128         message(STATUS "     - include: ${ICONV_INCLUDE_DIR}")
1129         message(STATUS "     - library: ${ICONV_LIBRARY}")
1130         message(STATUS "  * zlib")
1131         message(STATUS "     - include: ${ZLIB_INCLUDE_DIR}")
1132         message(STATUS "     - library: ${ZLIB_LIBRARY}")
1133         message(STATUS)
1134 endif()
1135
1136 # Apple has builtin native spell checker,
1137 # no need to warn for missing Aspell, Hunspell or Enchant
1138 if(NOT Spelling_FOUND AND NOT APPLE)
1139   if(LYX_REQUIRE_SPELLCHECK)
1140     set(_mode "FATAL_ERROR")
1141   else()
1142     set(_mode "STATUS")
1143   endif()
1144   message(${_mode} "No spellcheck libraries found. LyX will be unable use spellchecking")
1145 endif()
1146
1147 include("${TOP_CMAKE_PATH}/LyxPackaging.cmake")
1148
1149 if(ENABLE_DIST)
1150   # Use git to create the source package
1151   # git archive --format=tgz --output=/home/kornel/x.tar.gz master
1152   if(UNIX)
1153     set(DIST_FORMAT tgz)
1154   else()
1155     set(DIST_FORMAT zip)
1156   endif()
1157   set(DIST_NAME ${CMAKE_PROJECT_NAME}-${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}-${CMAKE_SYSTEM_NAME}.${DIST_FORMAT})
1158
1159   add_custom_command(
1160     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME}
1161     COMMAND  ${LYX_GITVERSION} archive --format=${DIST_FORMAT} --output=${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME} master
1162     WORKING_DIRECTORY ${TOP_SRC_DIR})
1163   add_custom_target(git-archive DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME})
1164 endif()
1165
1166 # Last directory to be included so that the fixup code (OS X)
1167 # can be run last
1168 add_subdirectory(development/cmake/post_install)
1169
1170 message(STATUS)