CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 2.6.4)
   8
   9 set(LYX_PROJECT LyX)
  10
  11 # Instruct cmake to not use gnu extensions,
  12 # this prevents the mix of '-std=c++*' and '-std=gnu++*' flags
  13 set(CMAKE_CXX_EXTENSIONS OFF)
  14
  15 enable_testing()
  16
  17 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README REALPATH) # Resolve symlinks
  18 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  19 message(STATUS "TOP_SRC_DIR = ${TOP_SRC_DIR}")
  20
  21 set(LYX_CMAKE_DIR "development/cmake")
  22 set(TOP_CMAKE_PATH "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}")
  23 set(TOP_MODULE_PATH "${TOP_CMAKE_PATH}/modules")
  24 set(TOP_SCRIPT_PATH "${TOP_CMAKE_PATH}/scripts")
  25
  26 set(CMAKE_MODULE_PATH "${TOP_MODULE_PATH}")
  27
  28 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  29
  30 message(STATUS)
  31 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  32         message(STATUS "Building in-source")
  33         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  34 else()
  35         message(STATUS "Building out-of-source")
  36         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  37 endif()
  38
  39 # This directory should be used if some test uses lyx-executable
  40 set(LYX_TESTS_USERDIR "${TOP_BINARY_DIR}/Testing/.lyx")
  41 file(MAKE_DIRECTORY "${LYX_TESTS_USERDIR}")
  42
  43 if(COMMAND cmake_policy)
  44         # Installing MACOSX_BUNDLE targets requires a BUNDLE DESTINATION
  45         cmake_policy(SET CMP0006 NEW)
  46         if(POLICY CMP0043)
  47                 # COMPILE_DEFINITIONS are not used yet. Enable new behavior.
  48                 cmake_policy(SET CMP0043 NEW)
  49         endif()
  50 endif()
  51
  52 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  53
  54 # Supress regeneration
  55 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  56
  57 if(LYX_XMINGW)
  58     set(CMAKE_SYSTEM_NAME Windows)
  59     set(TOOLNAME ${LYX_XMINGW})
  60     set(TOOLCHAIN "${TOOLNAME}-")
  61     set(CMAKE_C_COMPILER   "${TOOLCHAIN}gcc"     CACHE PATH "Mingw C compiler" FORCE)
  62     set(CMAKE_CXX_COMPILER "${TOOLCHAIN}g++"     CACHE PATH "Mingw C++ compiler" FORCE)
  63     set(CMAKE_RC_COMPILER  "${TOOLCHAIN}windres" CACHE PATH "Mingw rc compiler" FORCE)
  64
  65     set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM BOTH)
  66     set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY)
  67     set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY)
  68 endif()
  69
  70 if(NOT help AND NOT HELP)
  71   # 'project' triggers the searching for a compiler
  72   project(${LYX_PROJECT})
  73   if (CMAKE_COMPILER_IS_GNUCXX)
  74     if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS "4.0")
  75       message(STATUS "Gnu CXX compiler version = ${CMAKE_CXX_COMPILER_VERSION}")
  76       message(STATUS "is too old, should be >= 4.0")
  77       message(FATAL_ERROR "Exiting")
  78     endif()
  79   endif()
  80 endif()
  81
  82 if(UNIX)
  83         set(ARCH_TRIPLET )
  84         FIND_PROGRAM(DPKG_ARCHITECTURE_EXECUTABLE dpkg-architecture)
  85         if(DPKG_ARCHITECTURE_EXECUTABLE)
  86                 EXECUTE_PROCESS(COMMAND ${DPKG_ARCHITECTURE_EXECUTABLE} -qDEB_HOST_MULTIARCH
  87                                 OUTPUT_VARIABLE ARCH_TRIPLET
  88                                 ERROR_VARIABLE ERROR_ARCH_TRIPLET
  89                                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  90         endif()
  91 endif()
  92 if(ARCH_TRIPLET)
  93         set(SYSTEM_LIB_DIRS /usr/lib /usr/lib/${ARCH_TRIPLET} /usr/local/lib)
  94 else()
  95         set(SYSTEM_LIB_DIRS /usr/lib /usr/local/lib)
  96 endif()
  97
  98 include(LyXMacros)
  99 include(LyXDestinations)
 100
 101 # Usage LYX_OPTION
 102 # 1. parameter: option name without prefix 'LYX_'
 103 # 2. parameter: description
 104 # 3. parameter: default value, ON or OFF
 105 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
 106
 107 # Usage LYX_COMBO
 108 # 1. parameter: name without prefix 'LYX_'
 109 # 2. parameter: description
 110 # 3. parameter: default value
 111 # 4-n parameter: possible other string values
 112
 113 LYX_OPTION_INIT()
 114
 115 # Options for all compilers/systems
 116 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
 117 LYX_OPTION(LOCALVERSIONING  "Add version info to created package name (only used if LYX_CPACK option set)" OFF ALL)
 118 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
 119 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
 120 LYX_OPTION(REQUIRE_SPELLCHECK "Abort if no spellchecker available" OFF ALL)
 121 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
 122 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
 123 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
 124 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" OFF ALL)
 125 LYX_OPTION(DEBUG            "Enforce debug build"  OFF ALL)
 126 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
 127 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
 128 LYX_STRING(SUFFIX_VALUE     "Use this string as suffix" "")
 129 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
 130 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
 131 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
 132 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
 133 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
 134 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
 135 LYX_OPTION(ENABLE_URLTESTS  "Enable for URL tests" OFF ALL)
 136 LYX_OPTION(ENABLE_EXPORT_TESTS "Enable for export tests" OFF ALL)
 137 LYX_OPTION(ENABLE_KEYTESTS  "Enable for keytests" OFF ALL)
 138 LYX_OPTION(ASAN             "Use address sanitizer" OFF ALL)
 139 LYX_COMBO(USE_FILEDIALOG    "Use native or QT file dialog" QT NATIVE)
 140 LYX_COMBO(USE_QT            "Use Qt version as frontend" AUTO QT4 QT5)
 141 #LYX_OPTION(3RDPARTY_BUILD   "Build 3rdparty libs" OFF ALL)
 142 LYX_OPTION(EXTERNAL_Z       "OFF := Build 3rdparty lib zlib" ON ALL)
 143 LYX_OPTION(EXTERNAL_ICONV   "OFF := Build 3rdparty lib iconvlib" ON ALL)
 144 LYX_OPTION(EXTERNAL_HUNSPELL "OFF := Build 3rdparty lib hunspelllib" ON ALL)
 145 LYX_COMBO(EXTERNAL_MYTHES   "OFF := Build 3rdparty lib mytheslib" AUTO OFF ON)
 146
 147 # GCC specific
 148 LYX_OPTION(PROFILE              "Build profile version" OFF GCC)
 149 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" OFF GCC)
 150 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
 151 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
 152 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++ pedantic debug mode" OFF GCC)
 153 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" OFF GCC)
 154 LYX_OPTION(PROFILE              "Build with options for gprof" OFF GCC)
 155
 156 # MSVC specific
 157 LYX_OPTION(CONSOLE               "Show console on Windows" ON MSVC)
 158 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
 159 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
 160 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
 161
 162 # APPLE specific
 163 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
 164 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
 165
 166
 167 if(help OR HELP)
 168         message(STATUS)
 169         message(STATUS "Available options: (dis/enable with -DLYX_*=OFF/ON)")
 170         message(STATUS)
 171         LYX_OPTION_LIST_ALL(help)
 172         message(STATUS)
 173         RETURN()
 174 endif()
 175
 176 # Check option dependencies
 177
 178 if(LYX_DMG)
 179         set(LYX_BUNDLE ON)
 180         set(LYX_CPACK ON)
 181 endif()
 182
 183 if(LYX_CPACK)
 184         set(LYX_INSTALL ON)
 185 endif()
 186
 187 if(LYX_INSTALL)
 188         set(LYX_NLS ON)
 189         if(WIN32 AND NOT MINGW)
 190                 set(LYX_HUNSPELL ON)
 191         endif()
 192         set(LYX_PACKAGE_SUFFIX ON)
 193         if(NOT LYX_DEBUG)
 194                 set(LYX_RELEASE ON)
 195         endif()
 196         set(LYX_PROFILE OFF)
 197 endif()
 198
 199
 200 if(LYX_MERGE_FILES)
 201         set(LYX_PCH OFF)
 202 else()
 203         set(LYX_MERGE_REBUILD OFF)
 204 endif()
 205
 206 if(LYX_DEPENDENCIES_DOWNLOAD)
 207         message(STATUS)
 208         if(MSVC14)
 209                 set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2015-deps)
 210                 set(deps_files lyx-windows-deps-msvc2015.zip)
 211                 set(deps_server http://ftp.lyx.de/LyX-Windows-Deps)
 212                 set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2015)
 213         elseif(MSVC10)
 214                 set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 215                 set(deps_files lyx-windows-deps-msvc2010.zip)
 216                 set(deps_server http://ftp.lyx.de/LyX-Windows-Deps)
 217                 set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2010)
 218         else()
 219                 message(FATAL_ERROR "error: no dependency package known for the selected MSVC version.")
 220         endif()
 221     message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 222         foreach(it ${deps_files})
 223                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 224                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 225                 if(NOT already_downloaded)
 226                         message(STATUS "Downloading ${it} ...")
 227                         file(DOWNLOAD ${deps_server}/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS STATUS status LOG log)
 228                         list(GET status 0 status_code)
 229                         list(GET status 1 status_string)
 230                         if(NOT status_code EQUAL 0)
 231                                 file(REMOVE ${LYX_DEPENDENCIES_DIR}/${it})
 232                                 message(FATAL_ERROR "error: downloading '${it}' failed. status_code: ${status_code}, status_string: ${status_string}. \nLog: ${log} ")
 233                         endif()
 234                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 235                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 236                 endif()
 237         endforeach()
 238 endif()
 239
 240
 241
 242 message(STATUS)
 243
 244 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 245 if(WIN32)
 246         set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 247 else()
 248         set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 249 endif()
 250
 251
 252 # Set to some meaningful default
 253 find_package(CXX11Compiler)
 254 if(NOT CXX11COMPILER_FOUND)
 255         message(FATAL_ERROR "A C++11 compatible compiler is required.")
 256 endif()
 257 set(LYX_GCC11_MODE)
 258 if(UNIX OR MINGW)
 259         if (CMAKE_CXX_COMPILER_ID MATCHES "^[cC]lang$")
 260           # ignore the GCC_VERSION for clang
 261           # and use the resulting CXX11_STD_REGEX found in FindCXX11Compiler.cmake
 262           message(STATUS "Using clang")
 263           if(CXX11_STD_REGEX)
 264             set(LYX_USE_STD_REGEX 1)
 265           else()
 266             set(LYX_USE_STD_REGEX 0)
 267           endif()
 268         else()
 269           execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION OUTPUT_STRIP_TRAILING_WHITESPACE)
 270           message(STATUS "Using GCC version ${GCC_VERSION}")
 271           if(GCC_VERSION VERSION_LESS 4.9)
 272                   if(GCC_VERSION VERSION_LESS 4.6)
 273                           message(FATAL_ERROR "gcc >= 4.6 is required.")
 274                   endif()
 275                   # <regex> in gcc is unusable in versions less than 4.9.0
 276                   # see https://gcc.gnu.org/bugzilla/show_bug.cgi?id=53631
 277                   set(LYX_USE_STD_REGEX 0)
 278           else()
 279                   set(LYX_USE_STD_REGEX 1)
 280           endif()
 281         endif()
 282         set(LYX_GCC11_MODE "${CXX11_FLAG}")
 283 else()
 284         set(LYX_USE_STD_REGEX 0)
 285 #       if(MSVC10)
 286 #               set(LYX_USE_STD_REGEX 1) #TODO should we use it in ECMAScript mode?
 287 #       endif()
 288 endif()
 289
 290
 291 set(VERSION_INFO "CMake Build")
 292
 293 # Try to get some informations from configure.ac
 294
 295 include(LyXPaths)
 296 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 297
 298 if(WIN32)
 299         set(CMAKE_PREFIX_PATH Specify-path-to-Qt CACHE PATH "Used Qt version")
 300         if(MSVC)
 301                 set(LYX_3RDPARTY_BUILD ON CACHE BOOL "Build 3rdparty libraries" FORCE)
 302         endif()
 303         set(USE_WINDOWS_PACKAGING ON)
 304 elseif(APPLE)
 305         set(USE_MACOSX_PACKAGING ON)
 306 else()
 307         set(USE_POSIX_PACKAGING ON)
 308 endif()
 309
 310 if(LYX_3RDPARTY_BUILD)
 311   # LYX_3RDPARTY_BUILD is not cached anymore, but for compatibility reasons
 312   # this enables the build of all 3rd_party libs
 313   set(LYX_EXTERNAL_Z        OFF CACHE BOOL "Build 3rdparty lib zlib"    FORCE)
 314   set(LYX_EXTERNAL_ICONV    OFF CACHE BOOL "Build 3rdparty iconvlib"    FORCE)
 315   set(LYX_EXTERNAL_HUNSPELL OFF CACHE BOOL "Build 3rdparty hunspelllib" FORCE)
 316   set(LYX_EXTERNAL_MYTHES   OFF CACHE STRING "Build 3rdparty mytheslib" FORCE)
 317 endif()
 318
 319 macro(setstripped _varname)
 320         if(${ARGC} GREATER 1)
 321                 string(STRIP "${ARGV1}" _v)
 322                 if(USE_POSIX_PACKAGING)
 323                         string(TOLOWER ${_v} ${_varname})
 324                 else()
 325                         set(${_varname} ${_v})
 326                 endif()
 327         else()
 328                 set(${_varname})
 329         endif()
 330 endmacro(setstripped)
 331
 332 foreach(_c_l ${_config_lines} )
 333         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 334                 setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 335                 setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 336                 setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 337                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\)\(\\.\([0-9]+\)\)?.*$")
 338                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 339                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 340                         set(LYX_PATCH_VERSION ${CMAKE_MATCH_4})
 341                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 342                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 343                         if ("${LYX_SUFFIX_VALUE}" MATCHES "")
 344                           set(LYX_INSTALL_SUFFIX "${LYX_MAJOR_VERSION}.${LYX_MINOR_VERSION}")
 345                         else()
 346                           set(LYX_INSTALL_SUFFIX "${LYX_SUFFIX_VALUE}")
 347                         endif()
 348                 endif()
 349         endif()
 350         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 351                 set(LYX_DATE "${CMAKE_MATCH_1}")
 352         endif()
 353 endforeach(_c_l)
 354
 355 FIND_PROGRAM(LYX_GITVERSION git)
 356 #message(STATUS "gitversion = ${LYX_GITVERSION}")
 357 set(LYX_REVISION_VERSION ${LYX_PATCH_VERSION})
 358 set(LYX_PACKAGE_RELEASE "1")
 359 if(LYX_GITVERSION)
 360   if (LYX_LOCALVERSIONING)
 361     # Find the revision number and for later use
 362     EXECUTE_PROCESS(COMMAND ${LYX_GITVERSION} describe --match 2.0.0 HEAD
 363       WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE tmp_LYX_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 364     if (tmp_LYX_PACKAGE_RELEASE MATCHES "^2\\.0\\.0\\-\([0-9]+\)\\-\(.*\)$")
 365       set(LYX_PACKAGE_RELEASE ${CMAKE_MATCH_2})
 366       # We will add offset of 40000 to get appropriate value to
 367       # previous svn.
 368       # We use this value than also to set the package-patch-value
 369       MATH(EXPR tmp_REVISION_VERSION "(${CMAKE_MATCH_1}+40000)")
 370       set(LYX_REVISION_VERSION "${LYX_PATCH_VERSION}-${tmp_REVISION_VERSION}git")
 371       set(ENABLE_DIST ON)
 372     endif()
 373   endif()
 374 endif()
 375
 376 # Set the programs (lyx, tex2lyx, etc.) suffix
 377 # When building an OS X bundle, we will append
 378 # the suffix only to the bundle, not to the programs
 379 set(PROGRAM_SUFFIX "")
 380 if(LYX_PROGRAM_SUFFIX AND NOT (APPLE AND LYX_BUNDLE))
 381         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 382 endif()
 383 set(_lyx "${PACKAGE_BASE}${PROGRAM_SUFFIX}")
 384 set(_tex2lyx tex2lyx${PROGRAM_SUFFIX})
 385 set(_convert lyxconvert${PROGRAM_SUFFIX})
 386
 387 add_custom_target(lyx_version ALL
 388   COMMAND ${CMAKE_COMMAND} -DTOP_SRC_DIR=${TOP_SRC_DIR} -DTOP_CMAKE_PATH=${TOP_CMAKE_PATH} -DTOP_BINARY_DIR=${TOP_BINARY_DIR} -DLYX_DATE=${LYX_DATE} -P ${TOP_SCRIPT_PATH}/LyXGetVersion.cmake
 389   )
 390 set_target_properties(lyx_version PROPERTIES FOLDER "applications")
 391
 392 # Default paths for installed utilities (tex2lyx, lyxclient, etc.)
 393 set(LYX_UTILITIES_INSTALL_PATH bin)
 394
 395 if(LYX_BUNDLE)
 396         set(LYX_CPACK ON)
 397
 398         message(STATUS)
 399         message(STATUS "Bundle creation is enabled (experimental):")
 400         message(STATUS "    make")
 401         message(STATUS "    make install/strip")
 402         message(STATUS "    make package")
 403         if(APPLE)
 404                 set(MACOSX_BUNDLE TRUE)
 405                 # This sets the bundle + executable names
 406                 set(_lyx "${PACKAGE_BASE}${LYX_INSTALL_SUFFIX}")
 407                 # This sets the Info.plist executable name
 408                 set(osx_bundle_program_name ${_lyx})
 409                 # Bundle name
 410                 set(LYX_BUNDLE_NAME ${_lyx})
 411
 412                 # This will contain the list of files that need to be included
 413                 # in the bundle and their location within the bundle
 414                 set(OSX_BUNDLE_FILES "${TOP_SRC_DIR}/development/MacOSX/LyX.sdef;${TOP_SRC_DIR}/development/MacOSX/LyXapp.icns;${CMAKE_BINARY_DIR}/lyxrc.dist")
 415                 set(OSX_BUNDLE_DIRS "Resources;Resources;Resources")
 416
 417                 # Process Info.plist and lyxrc.dist
 418                 # See development/cmake/Install.cmake
 419                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/Info.plist.in" "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 420
 421                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 422                 set(LYX_DATA_SUBDIR ${LYX_BUNDLE_NAME}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 423
 424                 # Variables used by CPack
 425                 set(CPACK_BUNDLE_NAME ${LYX_BUNDLE_NAME})
 426                 set(CPACK_BUNDLE_PLIST "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 427                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${LYX_BUNDLE_NAME}.app)
 428
 429                 # Set the install paths
 430                 set(LYX_UTILITIES_INSTALL_PATH ${LYX_BUNDLE_NAME}.app/Contents/MacOS)
 431                 if(NOT LYX_INSTALL_PREFIX)
 432                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 433                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 434                 endif()
 435                 # Change the owner so that the install can work
 436                 install(CODE "set(BU_CHMOD_BUNDLE_ITEMS 1)" COMPONENT Runtime)
 437         elseif(UNIX)
 438                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 439                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 440                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 441         elseif(WIN32)
 442                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 443         endif()
 444 endif()
 445
 446 if(LYX_INSTALL_PREFIX)
 447         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 448         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 449 endif()
 450 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 451
 452 if(UNIX)
 453   set(SYSTEM_DATADIR "${CMAKE_INSTALL_PREFIX}/share")
 454 elseif(CMAKE_INSTALL_PREFIX MATCHES "/lyx${LYX_INSTALL_SUFFIX}$")
 455   string(REGEX REPLACE "/lyx${LYX_INSTALL_SUFFIX}$" "/share" SYSTEM_DATADIR ${CMAKE_INSTALL_PREFIX})
 456 else()
 457   set(SYSTEM_DATADIR "${CMAKE_INSTALL_PREFIX}")
 458 endif()
 459
 460 if(CMAKE_COMPILER_IS_GNUCXX)
 461   message(STATUS "CMAKE_COMPILER_IS_GNUCXX = ${CMAKE_COMPILER_IS_GNUCXX}")
 462   set(suffixing ${LYX_PROGRAM_SUFFIX})
 463 else()
 464   # Not a GCC compiler, programs do not have a suffix
 465   set(suffixing ${LYX_PACKAGE_SUFFIX})
 466 endif()
 467
 468 # The define PACKAGE below allows lyx-executable to find its default configuration files
 469 # see routines
 470 #    Package::messages_file()
 471 #    get_default_user_support_dir()
 472 #    relative_system_support_dir()
 473 # in src/support/Package.cpp
 474 #
 475 if(suffixing)
 476         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 477 else()
 478         set(PACKAGE ${PACKAGE_BASE})
 479 endif()
 480
 481 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 482         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 483         if (UNIX)
 484                 # use the default "/usr/local"
 485                 # but respect the user-choice on the command-line
 486                 set(CMAKE_INSTALL_PREFIX "/usr/local" CACHE PATH "LyX default install prefix" FORCE)
 487         endif()
 488 endif()
 489 if(WIN32)
 490         set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 491 endif()
 492 if(IS_ABSOLUTE)
 493         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 494 else()
 495         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 496 endif()
 497
 498
 499
 500 if(NOT LYX_DATA_SUBDIR)
 501         if (WIN32)
 502                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 503         else()
 504                 set(LYX_DATA_SUBDIR "share/${_lyx}/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 505         endif()
 506 endif()
 507
 508 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 509 get_locale_destination(LYX_LOCALEDIR)
 510 set(LYX_ABS_INSTALLED_LOCALEDIR "${CMAKE_INSTALL_PREFIX}/${LYX_LOCALEDIR}")
 511 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 512
 513 if(LYX_BUNDLE AND APPLE)
 514         set(LYX_MAN_DIR "${LYX_DATA_SUBDIR}" CACHE STRING "Install location for man pages.")
 515 else()
 516         if(WIN32)
 517                 set(LYX_MAN_DIR "${CMAKE_BINARY_DIR}/usr/local/man" CACHE STRING "Install location for man pages.")
 518         elseif(UNIX)
 519                 set(LYX_MAN_DIR "${CMAKE_INSTALL_PREFIX}/share/man" CACHE STRING "Install location for man pages.")
 520         else()
 521                 set(LYX_MAN_DIR "${CMAKE_INSTALL_PREFIX}/man" CACHE STRING "Install location for man pages.")
 522         endif()
 523 endif()
 524 mark_as_advanced(LYX_MAN_DIR)
 525
 526 # The Win installer cannot be built by CMake because one needs to install plugins for NSIS
 527 # see the Readme.txt of the installer
 528 #if(LYX_INSTALL AND WIN32)
 529 #       message(STATUS "Configuring NSIS files")
 530 #       configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 531 #       configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 532 #       configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 533 #       message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 534 #endif()
 535
 536 if(NOT GROUP_CODE)
 537         #set(GROUP_CODE "The Golden Code")
 538         set(GROUP_CODE flat)
 539 endif()
 540
 541 # lyx's source files
 542 set(LYX_CPP_FILES [a-zA-Z]*.cpp)
 543 set(LYX_HPP_FILES [a-zA-Z]*.h)
 544 set(LYX_MOC_FILES moc_*.cpp)
 545
 546 include(ProjectSourceGroup)
 547
 548
 549 if(LYX_PROFILE AND NOT MSVC)
 550         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 551         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg")
 552         set(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS}  -pg")
 553 else()
 554         set(LYX_PROFILE OFF)
 555 endif()
 556
 557
 558 if(LYX_NO_OPTIMIZE)
 559         set(CMAKE_BUILD_TYPE None)
 560         set(LYX_DEBUG OFF)
 561         set(LYX_RELEASE OFF)
 562         set(LYX_PROFILE OFF)
 563 elseif(LYX_RELEASE)
 564         set(CMAKE_BUILD_TYPE Release)
 565         set(LYX_DEBUG OFF)
 566         set(LYX_PROFILE OFF)
 567 elseif(LYX_PROFILE)
 568         set(CMAKE_BUILD_TYPE Profile)
 569         set(LYX_DEBUG OFF)
 570 else()
 571         set(CMAKE_BUILD_TYPE Debug)
 572         set(LYX_DEBUG ON)
 573 endif()
 574
 575
 576 # When shared libs are supported enable this option
 577 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 578 if(LYX_SHARED_LIBRARIES)
 579         set(library_type SHARED)
 580 else()
 581         set(library_type STATIC)
 582 endif()
 583
 584 if(NOT MSVC)
 585         if(NOT LYX_QUIET)
 586                 set(CMAKE_VERBOSE_MAKEFILE ON)
 587         endif()
 588         set(LYX_CXX_FLAGS "-Wall -Wunused-parameter ${LYX_GCC11_MODE}")
 589         if(LYX_CXX_FLAGS MATCHES "\\+\\+(14|11|98)")
 590           # Thanks to Brad King <brad.king@kitware.com>
 591           # for the pointer to https://cmake.org/cmake/help/v3.6/variable/CMAKE_CXX_STANDARD.html
 592           # This allows us to use QT5.7 with recent g++ (version >= 4.9) compilers
 593           # and still use our own c++ extension tests
 594           set(CMAKE_CXX_STANDARD ${CMAKE_MATCH_1})
 595           message(STATUS "CMAKE_CXX_STANDARD set to ${CMAKE_CXX_STANDARD}")
 596         endif()
 597         if(LYX_STDLIB_DEBUG)
 598                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 599         endif()
 600         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 601         set(CMAKE_CXX_FLAGS_DEBUG "-O0 -g3 -D_DEBUG" CACHE TYPE STRING FORCE)
 602         if(MINGW)
 603                 set(CMAKE_CXX_FLAGS_RELEASE "-O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 604         else()
 605                 set(CMAKE_CXX_FLAGS_RELEASE "-O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 606         endif()
 607 endif()
 608
 609 set(LYX_CXX_FLAGS_EXTRA "" CACHE STRING "Desired semicolon separated list of extra cxx compile flags, like '-Werror'")
 610 mark_as_advanced(LYX_CXX_FLAGS_EXTRA)
 611 if(LYX_CXX_FLAGS_EXTRA)
 612         foreach(_flag ${LYX_CXX_FLAGS_EXTRA})
 613                 add_definitions(${_flag})
 614         endforeach()
 615 endif()
 616
 617 if(LYX_XMINGW)
 618         list(APPEND CMAKE_FIND_ROOT_PATH ${GNUWIN32_DIR})
 619 endif()
 620
 621 set(min_qt5_version "5.6")
 622 if(LYX_USE_QT MATCHES "AUTO")
 623         # try qt5 first
 624         find_package(Qt5Core QUIET)
 625         if(Qt5Core_FOUND)
 626                 set(LYX_USE_QT "QT5" CACHE STRING "Valid qt version" FORCE)
 627                 message(STATUS "Qt5Core_VERSION = ${Qt5Core_VERSION}")
 628                 if(Qt5Core_VERSION VERSION_LESS ${min_qt5_version})
 629                         find_package(Qt4 "4.5.0" QUIET)
 630                         if(QT4_FOUND)
 631                                 set(LYX_USE_QT "QT4" CACHE STRING "Valid qt version" FORCE)
 632                         endif()
 633                 endif()
 634         else()
 635                 set(LYX_USE_QT "QT4" CACHE STRING "Valid qt version" FORCE)
 636         endif()
 637 endif()
 638 if(LYX_USE_QT MATCHES "QT5")
 639         # set QPA_XCB if QT uses X11
 640         find_package(Qt5Core REQUIRED)
 641         if (Qt5Core_FOUND)
 642                 find_package(Qt5Widgets REQUIRED)
 643                 if(APPLE)
 644                         find_package(Qt5MacExtras REQUIRED)
 645                 endif()
 646                 find_package(Qt5X11Extras QUIET)
 647                 find_package(Qt5WinExtras QUIET)
 648                 set(QTVERSION ${Qt5Core_VERSION})
 649                 if (QTVERSION VERSION_LESS ${min_qt5_version})
 650                         message(STATUS "QTVERSION = \"${QTVERSION}\"")
 651                         message(STATUS "This version is not recommended, try either option -DLYX_USE_QT=QT4 or")
 652                         message(STATUS "install QT-Version >= \"${min_qt5_version}\"")
 653                         # see thread in lyx-devel list
 654                         # From: Jean-Pierre Chrétien <jeanpierre.chretien@free.fr>
 655                         # Date 11.03.2017
 656                         # Subject: cmake compilation error
 657                         #message(FATAL_ERROR "Wrong Qt-Version")
 658                 endif()
 659                 macro (qt_use_modules)
 660                         qt5_use_modules(${ARGN})
 661                 endmacro()
 662                 macro (qt_add_resources)
 663                         qt5_add_resources(${ARGN})
 664                 endmacro()
 665                 macro (qt_wrap_uifiles)
 666                         qt5_wrap_ui(${ARGN})
 667                 endmacro()
 668                 message(STATUS "Found Qt-Version ${QTVERSION}")
 669                 if(WIN32)
 670                         set(LYX_QTMAIN_LIBRARY ${Qt5Core_QTMAIN_LIBRARIES})
 671                 endif()
 672         endif()
 673 elseif(LYX_USE_QT MATCHES "QT4")
 674         if(LYX_XMINGW)
 675                 set(QT_MINGW_DIR ${LYX_QT4} CACHE PATH "Qt for Mingw" FORCE)
 676                 list(APPEND CMAKE_FIND_ROOT_PATH ${QT_MINGW_DIR} ${GNUWIN32_DIR})
 677         endif()
 678         find_package(Qt4 "4.5.0" REQUIRED)
 679         macro (qt_use_modules)
 680         endmacro()
 681         macro (qt_add_resources)
 682                 qt4_add_resources(${ARGN})
 683         endmacro()
 684         macro (qt_wrap_uifiles)
 685                 qt4_wrap_ui(${ARGN})
 686         endmacro()
 687         set(LYX_QTMAIN_LIBRARY ${QT_QTSVG_LIBRARY})
 688         if(WIN32)
 689                 list(APPEND LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARIES})
 690         endif()
 691 else()
 692   message(FATAL_ERROR "Unhandled value for LYX_USE_QT (${LYX_USE_QT})")
 693 endif()
 694
 695 find_package(Magic)
 696 if(Magic_FOUND)
 697   set(HAVE_MAGIC_H 1)
 698   include_directories(${Magic_INCLUDE_DIR})
 699 endif()
 700
 701 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 702
 703 set(Spelling_FOUND OFF)
 704 set(Include_used_spellchecker)   # String will be inserted into config.h
 705
 706 if (LYX_EXTERNAL_MYTHES MATCHES "AUTO")
 707   # try system library first
 708   find_package(MyThesLIB)
 709   if (MYTHESLIB_FOUND)
 710     set(LYX_EXTERNAL_MYTHES ON CACHE STRING "OFF:= Build 3rdparty mytheslib" FORCE)
 711   else()
 712     set(LYX_EXTERNAL_MYTHES OFF CACHE STRING "OFF:= Build 3rdparty mytheslib" FORCE)
 713   endif()
 714 endif()
 715 if (LYX_EXTERNAL_MYTHES MATCHES "ON")
 716   find_package(MyThesLIB REQUIRED)
 717 else()
 718   add_subdirectory(3rdparty/mythes)
 719 endif()
 720 set(MYTHES_DIR ${MYTHESLIB_INCLUDE_DIR})
 721
 722 if(NOT LYX_EXTERNAL_HUNSPELL)
 723     add_subdirectory(3rdparty/hunspell)
 724     add_definitions(-DHUNSPELL_STATIC)
 725     set(HUNSPELL_FOUND ON)
 726     message(STATUS "  * Hunspell:")
 727     message(STATUS "     - include: ${HUNSPELL_INCLUDE_DIR}")
 728     message(STATUS "     - library: ${HUNSPELL_LIBRARY}")
 729 endif()
 730
 731 foreach(_spell "ASPELL" "Enchant" "Hunspell")
 732   string(TOUPPER ${_spell} _upspell)
 733   if (NOT ${_upspell}_FOUND)
 734     find_package(${_spell})
 735   endif()
 736   if (${_upspell}_FOUND)
 737     include_directories(${${_upspell}_INCLUDE_DIR})
 738     set(Spelling_FOUND ON)
 739     message(STATUS "Building with USE_${_upspell}")
 740     set(Include_used_spellchecker "${Include_used_spellchecker}#define USE_${_upspell} 1\n")
 741   else()
 742     if(LYX_${_upspell})
 743       message(FATAL_ERROR "Required ${_spell} devel package not found")
 744     else()
 745       message(STATUS "${_upspell} not found, building without ${_spell} support")
 746     endif()
 747   endif()
 748 endforeach()
 749
 750 if(GNUWIN32_DIR)
 751         list(APPEND CMAKE_PROGRAM_PATH "${GNUWIN32_DIR}/Python" )
 752 endif()
 753
 754 # Search for python default version first
 755 unset(PYTHON_EXECUTABLE CACHE)
 756 unset(LYX_PYTHON_EXECUTABLE CACHE)
 757 unset(PYTHON_VERSION_MAJOR)
 758 unset(PYTHON_VERSION_MINOR)
 759 unset(PYTHON_VERSION_STRING)
 760 find_package(PythonInterp 3.3 QUIET)
 761 if(NOT PYTHONINTERP_FOUND)
 762   unset(PYTHON_EXECUTABLE CACHE)
 763   find_package(PythonInterp 2.0 REQUIRED)
 764   if(NOT PYTHON_VERSION_STRING VERSION_LESS 2.8)
 765     message(FATAL_ERROR "Python interpreter found, but is not suitable")
 766   endif()
 767 endif()
 768
 769 set(LYX_PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 770
 771 if(LYX_NLS)
 772         find_package(LyXGettext)
 773         if(LYX_PYTHON_EXECUTABLE AND GETTEXT_FOUND)
 774                 add_subdirectory(po "${TOP_BINARY_DIR}/po")
 775         else()
 776                 # Install only supplied .gmo-files
 777                 file(GLOB _gmofiles RELATIVE "${TOP_SRC_DIR}/po" "${TOP_SRC_DIR}/po/*.gmo")
 778                 message(STATUS "Installing provided .gmo-files only")
 779                 foreach( _gmo ${_gmofiles})
 780                         string(REGEX REPLACE "\\.gmo$" "" _lang ${_gmo})
 781                         install(FILES "${TOP_SRC_DIR}/po/${_gmo}" DESTINATION ${LYX_LOCALEDIR}/${_lang}/LC_MESSAGES RENAME ${PACKAGE}.mo)
 782                 endforeach()
 783         endif()
 784 endif()
 785
 786 if(LYX_EXTERNAL_ICONV)
 787   find_package(ICONV REQUIRED)
 788 else()
 789   add_subdirectory(3rdparty/libiconv)
 790   set(HAVE_ICONV_CONST 1)
 791 endif()
 792
 793 if(LYX_EXTERNAL_Z)
 794   find_package(ZLIB REQUIRED)
 795 else()
 796   add_subdirectory(3rdparty/zlib)
 797 endif()
 798
 799 if(LYX_USE_STD_REGEX)
 800   # Set only include path.
 801   # Use internal boost, which is known to exist
 802   # we don't need any libraries
 803   set(Lyx_Boost_Libraries)
 804   add_definitions(-DBOOST_USER_CONFIG=<config.h>)
 805   include_directories(${TOP_SRC_DIR}/3rdparty/boost)
 806 else()
 807   # Using boost-regex
 808   if(LYX_EXTERNAL_BOOST)
 809     message(STATUS "Searching for external boost")
 810     find_package(Boost COMPONENTS regex)
 811     if(Boost_FOUND)
 812       message(STATUS "Boost found")
 813       message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 814       set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 815       if (LYX_STDLIB_DEBUG)
 816         # Comment from  Jean-Marc Lasgouttes:
 817         # In general, system boost libraries are incompatible with
 818         # the use of stdlib-debug in libstdc++. See ticket #9736 for
 819         # details.
 820         message(WARNING "Compiling LyX with stdlib-debug and system boost libraries may lead to crashes. Consider using '-DLYX_STDLIB_DEBUG=OFF' or using '-DLYX_EXTERNAL_BOOST=OFF'")
 821       endif()
 822     else()
 823       message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 824     endif()
 825   else()
 826     # Using included boost
 827     set(Lyx_Boost_Libraries boost_regex)
 828     add_definitions(-DBOOST_USER_CONFIG=<config.h>)
 829     include_directories(${TOP_SRC_DIR}/3rdparty/boost)
 830     add_subdirectory(3rdparty/boost "${TOP_BINARY_DIR}/3rdparty/boost")
 831   endif()
 832 endif()
 833
 834 if(WIN32)
 835         if(LYX_CONSOLE)
 836                 set(LYX_QTMAIN_LIBRARY)
 837         else()
 838                 set(WIN32_CONSOLE WIN32)
 839         endif()
 840         if(MSVC)
 841                 # -DPSAPI_VERSION=1 is needed to run on vista (bug 10186)
 842                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX -DPSAPI_VERSION=1)
 843                 # disable checked iterators for msvc release builds to get maximum speed
 844                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 845         else()
 846                 # -DPSAPI_VERSION=1 is not needed for mingw, since the mingw psapi.h
 847                 # does not use it and always declares the vista compatible API.
 848                 # If this ever changes then -DPSAPI_VERSION might be needed here as well.
 849                 add_definitions(-DWINVER=0x0500)
 850         endif()
 851 endif()
 852
 853 # Compute qt-version from ${QTVERSION}
 854
 855 message(STATUS "")
 856 foreach(_v PACKAGE PACKAGE_VERSION
 857         PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 858         LYX_ABS_TOP_SRCDIR
 859         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 860         if(NOT DEFINED ${_v})
 861                 message(FATAL_ERROR "${_v} not defined")
 862         endif()
 863         string(SUBSTRING "${_v}                            " 0 28 _v1)
 864         message(STATUS "----- ${_v1}: ${${_v}}")
 865 endforeach(_v)
 866 message(STATUS "")
 867
 868
 869 if(LYX_PCH)
 870         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 871         # Not sure if it works for all non-msvc compilers
 872         include(PCHSupport_26)
 873         configure_file(${TOP_CMAKE_PATH}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
 874         configure_file(${TOP_CMAKE_PATH}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 875         add_definitions(-DLYX_ENABLE_PCH)
 876
 877         if(MSVC)
 878                 macro(lyx_add_msvc_pch name_)
 879                         set_source_files_properties(${${name_}_sources} PROPERTIES
 880                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 881                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
 882                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 883                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
 884                                 ${TOP_BINARY_DIR}/pcheaders.h)
 885                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 886                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 887                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 888                 endmacro(lyx_add_msvc_pch)
 889                 macro(lyx_add_gcc_pch name_)
 890                 endmacro()
 891         else()
 892                 macro(lyx_add_msvc_pch name_)
 893                 endmacro()
 894                 macro(lyx_add_gcc_pch name_)
 895                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT)
 896                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
 897                 endmacro()
 898         endif()
 899 else()
 900         macro(lyx_add_msvc_pch)
 901         endmacro(lyx_add_msvc_pch)
 902         macro(lyx_add_gcc_pch name_)
 903         endmacro()
 904 endif()
 905
 906
 907 if(MSVC)
 908
 909         if(LYX_VLD)
 910                 set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/development/Win32/vld)
 911                 add_subdirectory(${vld_path}/cmake)
 912                 include(${vld_path}/cmake/vld.cmake) # forced include
 913                 set(vld_dll vld)
 914         endif()
 915
 916         if(LYX_WALL)
 917                 # Use the highest warning level
 918                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 919
 920                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 921                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 922                 else()
 923                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 924                 endif()
 925
 926                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 927                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 928                 else()
 929                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 930                 endif()
 931
 932                 # add here warnings which should produce an error /weXXXX
 933                 set(MSVC_W_ERROR   "/we4101 /we4189")
 934                 # add here warnings which should be disabled /wdXXXX
 935                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 936
 937                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 938                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 939                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 940
 941         else()
 942                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 943
 944                 # add here warnings which should produce an error /weXXXX
 945                 set(MSVC_W_ERROR   "/we4101 /we4189")
 946                 # add here warnings which should be disabled /wdXXXX
 947                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 948
 949                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 950                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 951                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 952
 953         endif()
 954
 955         if (NOT Qt5Core_FOUND)
 956                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 957                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 958                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 959         endif()
 960
 961         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 962         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 963         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 964         message(STATUS "")
 965 endif()
 966
 967
 968 if(LYX_DEBUG_GLIBC)
 969         set(_GLIBCXX_DEBUG ON)
 970 endif()
 971
 972 if(LYX_DEBUG_GLIBC_PEDANTIC)
 973         set(_GLIBCXX_DEBUG_PEDANTIC ON)
 974 endif()
 975
 976 # Xcode compiler
 977 if (CMAKE_GENERATOR MATCHES Xcode)
 978         if (XCODE_VERSION VERSION_LESS "5.0")
 979                 # Automatically select the Xcode compiler if not set
 980                 if (NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 981                         # XCode >= 3.1 has gcc 4.2 (up to actual Xcode)
 982                         if (XCODE_VERSION VERSION_GREATER "3.1")
 983                                 SET(CMAKE_XCODE_ATTRIBUTE_GCC_VERSION "com.apple.compilers.llvmgcc42")
 984                         ENDIF(XCODE_VERSION VERSION_GREATER "3.1")
 985                 ENDIF(NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 986                 # Print the selected compiler version
 987         MESSAGE(STATUS "---- Using XCode compiler CMAKE_XCODE_ATTRIBUTE_GCC_VERSION=${CMAKE_XCODE_ATTRIBUTE_GCC_VERSION}")
 988         ENDIF(XCODE_VERSION VERSION_LESS "5.0")
 989 ENDIF(CMAKE_GENERATOR MATCHES Xcode)
 990
 991 if (WIN32 AND Qt5Core_FOUND)
 992         set(Z_PREFIX 1)
 993 endif()
 994
 995 # compiler tests, config.h generation LYX_CONFIGURE_CHECKS
 996 include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
 997 configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
 998
 999 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
1000
1001 if(QTVERSION MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+).*")
1002         MATH(EXPR QT4_VERSION "(${CMAKE_MATCH_1}<<16)|(${CMAKE_MATCH_2}<<8)|${CMAKE_MATCH_3}")
1003 endif()
1004
1005 if (NOT HAVE_REGEX)
1006         set(LYX_USE_STD_REGEX 0)
1007 endif()
1008
1009
1010 set (cmd ${CMAKE_CTEST_COMMAND})
1011 if (MSVC)
1012         set (cmd ${cmd} -C ${CMAKE_CFG_INTDIR})
1013 else ()
1014         set (cmd ${cmd} -C ${CMAKE_BUILD_TYPE})
1015 endif ()
1016 add_custom_target (lyx_run_tests COMMAND ${cmd})
1017 set_target_properties(lyx_run_tests PROPERTIES FOLDER "tests")
1018
1019 if(LYX_ASAN)
1020     set(LYX_CXX_FLAGS "-fsanitize=address -fno-omit-frame-pointer -g")
1021     message(STATUS)
1022     message(STATUS "Address sanitizer enabled. Usage:")
1023     message(STATUS "    wget https://llvm.org/svn/llvm-project/compiler-rt/trunk/lib/asan/scripts/asan_symbolize.py")
1024     message(STATUS "    chmod  +x ./asan_symbolize.py")
1025     message(STATUS "    ./bin/lyx2.2 2>&1 | ./asan_symbolize.py  | c++filt ")
1026     message(STATUS)
1027 endif()
1028
1029 if(LYX_INSTALL)
1030         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
1031                 message(STATUS "Python required to create doc!")
1032         else()
1033                 if(UNIX)
1034                         add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
1035                 endif()
1036                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
1037         endif()
1038 endif()
1039 include(../Install)
1040
1041 # By running the URL tests first, time can be saved when running the ctests in
1042 # parallel since the URL tests take a long time to run (e.g. 10 minutes).
1043 if(LYX_ENABLE_URLTESTS)
1044         add_subdirectory(development/checkurls "${TOP_BINARY_DIR}/checkurls")
1045 endif()
1046 add_subdirectory(src "${TOP_BINARY_DIR}/src")
1047 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
1048 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
1049 add_subdirectory(lib/examples "${TOP_BINARY_DIR}/lib/examples")
1050 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
1051 add_subdirectory(development/autotests "${TOP_BINARY_DIR}/autotests")
1052 add_subdirectory(development/batchtests "${TOP_BINARY_DIR}/batchtests")
1053
1054 message(STATUS)
1055 message(STATUS "Build params, switch LYX_* options by -DLYX_*=ON or OFF, LYX_* combos by -DLYX_*=value:")
1056 message(STATUS)
1057
1058 LYX_OPTION_LIST_ALL(used)
1059
1060
1061 if(LYX_NLS)
1062         message(STATUS)
1063         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
1064         message(STATUS)
1065         message(STATUS "  * iconv")
1066         message(STATUS "     - include: ${ICONV_INCLUDE_DIR}")
1067         message(STATUS "     - library: ${ICONV_LIBRARY}")
1068         message(STATUS "  * zlib")
1069         message(STATUS "     - include: ${ZLIB_INCLUDE_DIR}")
1070         message(STATUS "     - library: ${ZLIB_LIBRARY}")
1071         message(STATUS)
1072 endif()
1073
1074 # Apple has builtin native spell checker,
1075 # no need to warn for missing Aspell, Hunspell or Enchant
1076 if(NOT Spelling_FOUND AND NOT APPLE)
1077   if(LYX_REQUIRE_SPELLCHECK)
1078     set(_mode "FATAL_ERROR")
1079   else()
1080     set(_mode "STATUS")
1081   endif()
1082   message(${_mode} "No spellcheck libraries found. LyX will be unable use spellchecking")
1083 endif()
1084
1085 include("${TOP_CMAKE_PATH}/LyxPackaging.cmake")
1086
1087 if(ENABLE_DIST)
1088   # Use git to create the source package
1089   # git archive --format=tgz --output=/home/kornel/x.tar.gz master
1090   if(UNIX)
1091     set(DIST_FORMAT tgz)
1092   else()
1093     set(DIST_FORMAT zip)
1094   endif()
1095   set(DIST_NAME ${CMAKE_PROJECT_NAME}-${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}-${CMAKE_SYSTEM_NAME}.${DIST_FORMAT})
1096
1097   add_custom_command(
1098     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME}
1099     COMMAND  ${LYX_GITVERSION} archive --format=${DIST_FORMAT} --output=${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME} master
1100     WORKING_DIRECTORY ${TOP_SRC_DIR})
1101   add_custom_target(git-archive DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME})
1102 endif()
1103
1104 # Last directory to be included so that the fixup code (OS X)
1105 # can be run last
1106 add_subdirectory(development/cmake/post_install)
1107
1108 message(STATUS)