CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 2.6.4)
   8
   9 set(LYX_PROJECT LyX)
  10
  11 enable_testing()
  12
  13 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README ABSOLUTE)
  14 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  15
  16 set(LYX_CMAKE_DIR "development/cmake")
  17 set(TOP_CMAKE_PATH "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}")
  18 set(TOP_MODULE_PATH "${TOP_CMAKE_PATH}/modules")
  19 set(TOP_SCRIPT_PATH "${TOP_CMAKE_PATH}/scripts")
  20
  21 set(CMAKE_MODULE_PATH "${TOP_MODULE_PATH}")
  22
  23 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  24
  25 message(STATUS)
  26 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  27         message(STATUS "Building in-source")
  28         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  29 else()
  30         message(STATUS "Building out-of-source")
  31         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  32 endif()
  33
  34 # This directory should be used if some test uses lyx-executable
  35 set(LYX_TESTS_USERDIR "${TOP_BINARY_DIR}/Testing/.lyx")
  36 file(MAKE_DIRECTORY "${LYX_TESTS_USERDIR}")
  37
  38 if(COMMAND cmake_policy)
  39         cmake_policy(SET CMP0003 OLD)
  40         cmake_policy(SET CMP0005 OLD)
  41         # Installing MACOSX_BUNDLE targets requires a BUNDLE DESTINATION
  42         cmake_policy(SET CMP0006 NEW)
  43         if(POLICY CMP0028)
  44                 cmake_policy(SET CMP0028 OLD)
  45         endif()
  46         if(POLICY CMP0043)
  47                 # COMPILE_DEFINITIONS are not used yet. Enable new behavior.
  48                 cmake_policy(SET CMP0043 NEW)
  49         endif()
  50 endif()
  51
  52 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  53
  54 # Supress regeneration
  55 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  56
  57 if(LYX_XMINGW)
  58     set(CMAKE_SYSTEM_NAME Windows)
  59     set(TOOLNAME ${LYX_XMINGW})
  60     set(TOOLCHAIN "${TOOLNAME}-")
  61     set(CMAKE_C_COMPILER   "${TOOLCHAIN}gcc"     CACHE PATH "Mingw C compiler" FORCE)
  62     set(CMAKE_CXX_COMPILER "${TOOLCHAIN}g++"     CACHE PATH "Mingw C++ compiler" FORCE)
  63     set(CMAKE_RC_COMPILER  "${TOOLCHAIN}windres" CACHE PATH "Mingw rc compiler" FORCE)
  64
  65     set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM BOTH)
  66     set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY)
  67     set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY)
  68 endif()
  69
  70 if(NOT help AND NOT HELP)
  71   # 'project' triggers the searching for a compiler
  72   project(${LYX_PROJECT})
  73   if (CMAKE_COMPILER_IS_GNUCXX)
  74     if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS "4.0")
  75       message(STATUS "Gnu CXX compiler version = ${CMAKE_CXX_COMPILER_VERSION}")
  76       message(STATUS "is too old, should be >= 4.0")
  77       message(FATAL_ERROR "Exiting")
  78     endif()
  79   endif()
  80 endif()
  81
  82 if(UNIX)
  83         set(ARCH_TRIPLET )
  84         FIND_PROGRAM(DPKG_ARCHITECTURE_EXECUTABLE dpkg-architecture)
  85         if(DPKG_ARCHITECTURE_EXECUTABLE)
  86                 EXECUTE_PROCESS(COMMAND ${DPKG_ARCHITECTURE_EXECUTABLE} -qDEB_HOST_MULTIARCH
  87                                 OUTPUT_VARIABLE ARCH_TRIPLET
  88                                 ERROR_VARIABLE ERROR_ARCH_TRIPLET
  89                                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  90         endif()
  91 endif()
  92 if(ARCH_TRIPLET)
  93         set(SYSTEM_LIB_DIRS /usr/lib /usr/lib/${ARCH_TRIPLET} /usr/local/lib)
  94 else()
  95         set(SYSTEM_LIB_DIRS /usr/lib /usr/local/lib)
  96 endif()
  97
  98 include(LyXMacros)
  99
 100 # Usage LYX_OPTION
 101 # 1. parameter: option name without prefix 'LYX_'
 102 # 2. parameter: description
 103 # 3. parameter: default value, ON or OFF
 104 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
 105
 106 # Usage LYX_COMBO
 107 # 1. parameter: name without prefix 'LYX_'
 108 # 2. parameter: description
 109 # 3. parameter: default value
 110 # 4-n parameter: possible other string values
 111
 112 LYX_OPTION_INIT()
 113
 114 # Options for all compilers/systems
 115 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
 116 LYX_OPTION(LOCALVERSIONING  "Add version info to created package name (only used if LYX_CPACK option set)" OFF ALL)
 117 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
 118 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
 119 LYX_OPTION(REQUIRE_SPELLCHECK "Abort if no spellchecker available" OFF ALL)
 120 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
 121 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
 122 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
 123 LYX_OPTION(DEVEL_VERSION    "Build developer version" OFF ALL)
 124 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" OFF ALL)
 125 LYX_OPTION(DEBUG            "Enforce debug build"  OFF ALL)
 126 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
 127 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
 128 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
 129 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
 130 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
 131 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
 132 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
 133 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
 134 LYX_OPTION(ENABLE_URLTESTS  "Enable for URL tests" OFF ALL)
 135 LYX_OPTION(ENABLE_EXPORT_TESTS "Enable for export tests" OFF ALL)
 136 LYX_OPTION(ASAN             "Use address sanitizer" OFF ALL)
 137
 138 # GCC specific
 139 LYX_OPTION(PROFILE              "Build profile version" OFF GCC)
 140 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" OFF GCC)
 141 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
 142 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
 143 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++ pedantic debug mode" OFF GCC)
 144 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" OFF GCC)
 145 LYX_OPTION(PROFILE              "Build with options for gprof" OFF GCC)
 146 LYX_OPTION(ENABLE_CXX11         "Build with options for c++11-mode" OFF GCC)
 147
 148 # MSVC specific
 149 LYX_OPTION(CONSOLE               "Show console on Windows, enforce with =FORCE" ON MSVC)
 150 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
 151 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
 152 LYX_OPTION(CONFIGURE_CHECKS      "Also run configure checks for MSVC" OFF MSVC)
 153 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
 154
 155 # APPLE specific
 156 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
 157 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
 158 if(LYX_XMINGW)
 159   LYX_COMBO(USE_QT               "Use Qt version as frontend for MINGW" QT4)
 160 else()
 161   LYX_COMBO(USE_QT               "Use Qt version as frontend" QT4 QT5)
 162 endif()
 163
 164
 165 if(help OR HELP)
 166         message(STATUS)
 167         message(STATUS "Available options: (dis/enable with -DLYX_*=OFF/ON)")
 168         message(STATUS)
 169         LYX_OPTION_LIST_ALL(help)
 170         message(STATUS)
 171         RETURN()
 172 endif()
 173
 174 # Check option dependencies
 175
 176 if(LYX_DMG)
 177         set(LYX_BUNDLE ON)
 178         set(LYX_CPACK ON)
 179 endif()
 180
 181 if(LYX_CPACK)
 182         set(LYX_INSTALL ON)
 183 endif()
 184
 185 if(LYX_INSTALL)
 186         set(LYX_NLS ON)
 187         if(WIN32 AND NOT MINGW)
 188                 set(LYX_HUNSPELL ON)
 189         endif()
 190         if(LYX_CONSOLE MATCHES "FORCE")
 191                 set(LYX_CONSOLE ON)
 192         else()
 193                 set(LYX_CONSOLE OFF)
 194         endif()
 195         set(LYX_PACKAGE_SUFFIX ON)
 196         if(NOT LYX_DEBUG)
 197                 set(LYX_RELEASE ON)
 198         endif()
 199         set(LYX_PROFILE OFF)
 200 endif()
 201
 202
 203 if(LYX_MERGE_FILES)
 204         set(LYX_PCH OFF)
 205 else()
 206         set(LYX_MERGE_REBUILD OFF)
 207 endif()
 208
 209
 210 if(LYX_DEPENDENCIES_DOWNLOAD)
 211         message(STATUS)
 212         set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 213         message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 214         set(deps_files lyx20-deps-msvc2010-x86.zip)
 215         set(deps_server http://downloads.sourceforge.net/project/lyx/Win_installers/Dependencies)
 216         foreach(it ${deps_files})
 217                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 218                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 219                 if(NOT already_downloaded)
 220                         message(STATUS "Downloading ${it} ...")
 221                         file(DOWNLOAD ${deps_server}/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS STATUS status LOG log)
 222                         list(GET status 0 status_code)
 223                         list(GET status 1 status_string)
 224                         if(NOT status_code EQUAL 0)
 225                                 file(REMOVE ${LYX_DEPENDENCIES_DIR}/${it})
 226                                 message(FATAL_ERROR "error: downloading '${it}' failed. status_code: ${status_code}, status_string: ${status_string}. \nLog: ${log} ")
 227                         endif()
 228                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 229                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 230                 endif()
 231         endforeach()
 232         set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/deps20)
 233     if(MSVC12)
 234         # handle error in msvc12 when linking against msvc10 libs
 235         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /vd2")
 236     endif()
 237 endif()
 238
 239
 240
 241 message(STATUS)
 242
 243 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 244 if(WIN32)
 245         set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 246 else()
 247         set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 248 endif()
 249
 250
 251 set(LYX_GCC11_MODE)
 252 if(UNIX OR MINGW)
 253         execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION)
 254         message(STATUS "Using GCC version ${GCC_VERSION}")
 255         if(GCC_VERSION VERSION_LESS 4.9)
 256                 # <regex> in gcc is unusable in versions less than 4.9.0
 257                 # see https://gcc.gnu.org/bugzilla/show_bug.cgi?id=53631
 258                 set(LYX_USE_STD_REGEX 0)
 259         endif()
 260         if (LYX_ENABLE_CXX11)
 261                 find_package(CXX11Compiler)
 262                 if(NOT CXX11COMPILER_FOUND)
 263                         message(FATAL_ERROR "A C++11 compatible compiler is required.")
 264                 endif()
 265                 set(LYX_GCC11_MODE "${CXX11_FLAG}")
 266         endif()
 267 else()
 268         set(LYX_USE_STD_REGEX 0)
 269 #       if(MSVC10)
 270 #               set(LYX_USE_STD_REGEX 1) #TODO should we use it in ECMAScript mode?
 271 #       endif()
 272 endif()
 273
 274
 275 set(VERSION_INFO "CMake Build")
 276
 277 # Try to get some informations from configure.ac
 278
 279 include(LyXPaths)
 280 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 281
 282 if(WIN32)
 283         set(USE_WINDOWS_PACKAGING ON)
 284 elseif(APPLE)
 285         set(USE_MACOSX_PACKAGING ON)
 286 else()
 287         set(USE_POSIX_PACKAGING ON)
 288 endif()
 289
 290 macro(setstripped _varname)
 291         if(${ARGC} GREATER 1)
 292                 string(STRIP "${ARGV1}" _v)
 293                 if(USE_POSIX_PACKAGING)
 294                         string(TOLOWER ${_v} ${_varname})
 295                 else()
 296                         set(${_varname} ${_v})
 297                 endif()
 298         else()
 299                 set(${_varname})
 300         endif()
 301 endmacro(setstripped)
 302
 303 foreach(_c_l ${_config_lines} )
 304         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 305                 setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 306                 setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 307                 setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 308                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\)\(\\.\([0-9]+\)\)?.*$")
 309                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 310                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 311                         set(LYX_PATCH_VERSION ${CMAKE_MATCH_4})
 312                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 313                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 314                         set(LYX_INSTALL_SUFFIX "${CMAKE_MATCH_1}.${CMAKE_MATCH_2}")
 315                 endif()
 316         endif()
 317         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 318                 set(LYX_DATE "${CMAKE_MATCH_1}")
 319         endif()
 320 endforeach(_c_l)
 321
 322 FIND_PROGRAM(LYX_GITVERSION git)
 323 #message(STATUS "gitversion = ${LYX_GITVERSION}")
 324 set(LYX_REVISION_VERSION ${LYX_PATCH_VERSION})
 325 if(LYX_GITVERSION)
 326   if (LYX_LOCALVERSIONING)
 327     # Find the revision number and for later use
 328     EXECUTE_PROCESS(COMMAND ${LYX_GITVERSION} describe --match 2.0.0 HEAD
 329       WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE LYX_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 330     if (LYX_PACKAGE_RELEASE MATCHES "^2\\.0\\.0\\-\([0-9]+\)\\-.*$")
 331       # We will add offset of 40000 to get appropriate value to
 332       # previous svn.
 333       # We use this value than also to set the package-patch-value
 334       MATH(EXPR tmp_REVISION_VERSION "(${CMAKE_MATCH_1}+40000)")
 335       set(LYX_REVISION_VERSION "${LYX_PATCH_VERSION}-${tmp_REVISION_VERSION}git")
 336       set(ENABLE_DIST ON)
 337     endif()
 338   endif()
 339 endif()
 340
 341 # Set the programs (lyx, tex2lyx, etc.) suffix
 342 # When building an OS X bundle, we will append
 343 # the suffix only to the bundle, not to the programs
 344 set(PROGRAM_SUFFIX "")
 345 if(LYX_PROGRAM_SUFFIX AND NOT (APPLE AND LYX_BUNDLE))
 346         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 347 endif()
 348 set(_lyx "${PACKAGE_BASE}${PROGRAM_SUFFIX}")
 349 set(_tex2lyx tex2lyx${PROGRAM_SUFFIX})
 350
 351 add_custom_target(lyx_version ALL
 352   COMMAND ${CMAKE_COMMAND} -DTOP_SRC_DIR=${TOP_SRC_DIR} -DTOP_CMAKE_PATH=${TOP_CMAKE_PATH} -DTOP_BINARY_DIR=${TOP_BINARY_DIR} -DLYX_DATE=${LYX_DATE} -P ${TOP_SCRIPT_PATH}/LyXGetVersion.cmake
 353   )
 354 set_target_properties(lyx_version PROPERTIES FOLDER "applications")
 355
 356 # Default paths for installed utilities (tex2lyx, lyxclient, etc.)
 357 set(LYX_UTILITIES_INSTALL_PATH bin)
 358
 359 if(LYX_BUNDLE)
 360         set(LYX_CPACK ON)
 361
 362         message(STATUS)
 363         message(STATUS "Bundle creation is enabled (experimental):")
 364         message(STATUS "    make")
 365         message(STATUS "    make install/strip")
 366         message(STATUS "    make package")
 367         if(APPLE)
 368                 set(MACOSX_BUNDLE TRUE)
 369                 # This sets the bundle + executable names
 370                 set(_lyx "${PACKAGE_BASE}${LYX_INSTALL_SUFFIX}")
 371                 # This sets the Info.plist executable name
 372                 set(osx_bundle_program_name ${_lyx})
 373                 # Bundle name
 374                 set(LYX_BUNDLE_NAME ${_lyx})
 375
 376                 # This will contain the list of files that need to be included
 377                 # in the bundle and their location within the bundle
 378                 set(OSX_BUNDLE_FILES "${TOP_SRC_DIR}/development/MacOSX/LyX.sdef;${TOP_SRC_DIR}/development/MacOSX/LyXapp.icns;${CMAKE_BINARY_DIR}/lyxrc.dist")
 379                 set(OSX_BUNDLE_DIRS "Resources;Resources;Resources")
 380
 381                 # Process Info.plist and lyxrc.dist
 382                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/Info.plist.in" "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 383                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/lyxrc.dist.in" "${CMAKE_CURRENT_BINARY_DIR}/lyxrc.dist")
 384
 385                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 386                 set(LYX_DATA_SUBDIR ${LYX_BUNDLE_NAME}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 387
 388                 # Variables used by CPack
 389                 set(CPACK_BUNDLE_NAME ${LYX_BUNDLE_NAME})
 390                 set(CPACK_BUNDLE_PLIST "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 391                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${LYX_BUNDLE_NAME}.app)
 392
 393                 # Set the install paths
 394                 set(LYX_UTILITIES_INSTALL_PATH ${LYX_BUNDLE_NAME}.app/Contents/MacOS)
 395                 if(NOT LYX_INSTALL_PREFIX)
 396                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 397                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 398                 endif()
 399                 # Change the owner so that the install can work
 400                 install(CODE "set(BU_CHMOD_BUNDLE_ITEMS 1)" COMPONENT Runtime)
 401         elseif(UNIX)
 402                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 403                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 404                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 405         elseif(WIN32)
 406                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 407         endif()
 408 endif()
 409
 410 if(LYX_INSTALL_PREFIX)
 411         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 412         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 413 endif()
 414 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 415
 416 string(REGEX REPLACE "/lyx${LYX_INSTALL_SUFFIX}$" "/share" SYSTEM_DATADIR ${CMAKE_INSTALL_PREFIX})
 417
 418 if(LYX_PACKAGE_SUFFIX)
 419         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 420 else()
 421         set(PACKAGE ${PACKAGE_BASE})
 422 endif()
 423
 424 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 425         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 426         if (UNIX)
 427                 # don't use the default "/usr/local"
 428                 # but respect the user-choice on the command-line
 429                 if(LYX_INSTALL_SUFFIX)
 430                         set(CMAKE_INSTALL_PREFIX "/usr/local/lyx${LYX_INSTALL_SUFFIX}" CACHE PATH "LyX default install prefix" FORCE)
 431                 else()
 432                         set(CMAKE_INSTALL_PREFIX "/usr/local/${LYX_PROJECT}" CACHE PATH "LyX default install prefix" FORCE)
 433                 endif()
 434         endif()
 435         if(WIN32)
 436                 set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 437         endif()
 438 endif()
 439 if(IS_ABSOLUTE)
 440         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 441 else()
 442         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 443 endif()
 444
 445
 446
 447 if(NOT LYX_DATA_SUBDIR)
 448         if (WIN32)
 449                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 450         else()
 451                 set(LYX_DATA_SUBDIR "" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 452         endif()
 453 endif()
 454
 455 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 456 set(LYX_LOCALEDIR "locale")
 457 set(LYX_ABS_INSTALLED_LOCALEDIR "${LYX_ABS_INSTALLED_DATADIR}/${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}")
 458 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 459
 460 if(LYX_BUNDLE AND APPLE)
 461         set(LYX_MAN_DIR "${LYX_DATA_SUBDIR}" CACHE STRING "Install location for man pages.")
 462 else()
 463         set(LYX_MAN_DIR "/usr/local/man/man1" CACHE STRING "Install location for man pages.")
 464 endif()
 465 mark_as_advanced(LYX_MAN_DIR)
 466
 467 if(LYX_INSTALL AND WIN32)
 468         message(STATUS "Configuring NSIS files")
 469         configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 470         configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 471         configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 472         message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 473 endif()
 474
 475 if(NOT GROUP_CODE)
 476         #set(GROUP_CODE "The Golden Code")
 477         set(GROUP_CODE flat)
 478 endif()
 479
 480 # lyx's source files
 481 set(LYX_CPP_FILES [a-zA-Z]*.cpp)
 482 set(LYX_HPP_FILES [a-zA-Z]*.h)
 483 set(LYX_MOC_FILES moc_*.cpp)
 484
 485 include(ProjectSourceGroup)
 486
 487
 488 if(LYX_PROFILE AND NOT MSVC)
 489         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 490         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg")
 491         set(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS}  -pg")
 492 else()
 493         set(LYX_PROFILE OFF)
 494 endif()
 495
 496
 497 if(LYX_NO_OPTIMIZE)
 498         set(CMAKE_BUILD_TYPE None)
 499         set(LYX_DEBUG OFF)
 500         set(LYX_RELEASE OFF)
 501         set(LYX_PROFILE OFF)
 502 elseif(LYX_RELEASE)
 503         set(CMAKE_BUILD_TYPE Release)
 504         set(LYX_DEBUG OFF)
 505         set(LYX_PROFILE OFF)
 506 elseif(LYX_PROFILE)
 507         set(CMAKE_BUILD_TYPE Profile)
 508         set(LYX_DEBUG OFF)
 509 else()
 510         set(CMAKE_BUILD_TYPE Debug)
 511         set(LYX_DEBUG ON)
 512 endif()
 513
 514
 515 # When shared libs are supported enable this option
 516 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 517 if(LYX_SHARED_LIBRARIES)
 518         set(library_type SHARED)
 519 else()
 520         set(library_type STATIC)
 521 endif()
 522
 523 if(NOT MSVC)
 524         if(NOT LYX_QUIET)
 525                 set(CMAKE_VERBOSE_MAKEFILE ON)
 526         endif()
 527     set(LYX_CXX_FLAGS "-Wall -Wunused-parameter ${LYX_GCC11_MODE}")
 528         if(LYX_STDLIB_DEBUG)
 529                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 530         endif()
 531         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 532         set(CMAKE_CXX_FLAGS_DEBUG "${LYX_CXX_FLAGS} -fno-strict-aliasing -O0 -g3 -D_DEBUG" CACHE TYPE STRING FORCE)
 533         if(MINGW)
 534                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 535         else()
 536                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 537         endif()
 538 endif()
 539
 540 set(LYX_CXX_FLAGS_EXTRA "" CACHE STRING "Desired semicolon separated list of extra cxx compile flags, like '-Werror'")
 541 mark_as_advanced(LYX_CXX_FLAGS_EXTRA)
 542 if(LYX_CXX_FLAGS_EXTRA)
 543         foreach(_flag ${LYX_CXX_FLAGS_EXTRA})
 544                 add_definitions(${_flag})
 545         endforeach()
 546 endif()
 547
 548 if(LYX_XMINGW)
 549     set(QT_MINGW_DIR ${LYX_QT4} CACHE PATH "Qt for Mingw" FORCE)
 550     list(APPEND CMAKE_FIND_ROOT_PATH ${QT_MINGW_DIR} ${GNUWIN32_DIR})
 551 endif()
 552 if(LYX_USE_QT MATCHES "QT5")
 553         find_package(Qt5Core REQUIRED)
 554         if (Qt5Core_FOUND)
 555                 find_package(Qt5Widgets REQUIRED)
 556                 if(APPLE)
 557                         find_package(Qt5MacExtras REQUIRED)
 558                 endif()
 559                 find_package(Qt5X11Extras QUIET)
 560                 find_package(Qt5WinExtras QUIET)
 561                 set(QTVERSION ${Qt5Core_VERSION})
 562                 macro (qt_use_modules)
 563                         qt5_use_modules(${ARGN})
 564                 endmacro()
 565                 macro (qt_add_resources)
 566                         qt5_add_resources(${ARGN})
 567                 endmacro()
 568                 macro (qt_wrap_uifiles)
 569                         qt5_wrap_ui(${ARGN})
 570                 endmacro()
 571                 message(STATUS "Found Qt-Version ${QTVERSION}")
 572         endif()
 573 elseif(LYX_USE_QT MATCHES "QT4")
 574         find_package(Qt4 "4.5.0" REQUIRED)
 575         macro (qt_use_modules)
 576         endmacro()
 577         macro (qt_add_resources)
 578                 qt4_add_resources(${ARGN})
 579         endmacro()
 580         macro (qt_wrap_uifiles)
 581                 qt4_wrap_ui(${ARGN})
 582         endmacro()
 583 else()
 584   message(FATAL_ERROR "Unhandled value for LYX_USE_QT (${LYX_USE_QT})")
 585 endif()
 586
 587 find_package(Magic)
 588 if(Magic_FOUND)
 589         set(HAVE_MAGIC_H 1)
 590 endif()
 591
 592 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 593
 594 set(Spelling_FOUND OFF)
 595 set(Include_used_spellchecker)   # String will be inserted into config.h
 596
 597 foreach(_spell "ASPELL" "Enchant" "Hunspell")
 598   string(TOUPPER ${_spell} _upspell)
 599   find_package(${_spell})
 600   if (${_upspell}_FOUND)
 601     include_directories(${${_upspell}_INCLUDE_DIR})
 602     set(Spelling_FOUND ON)
 603     message(STATUS "Building with USE_${_upspell}")
 604     set(Include_used_spellchecker "${Include_used_spellchecker}#define USE_${_upspell} 1\n")
 605   else()
 606     if(LYX_${_upspell})
 607       message(FATAL_ERROR "Required ${_spell} devel package not found")
 608     else()
 609       message(STATUS "${_upspell} not found, building without ${_spell} support")
 610     endif()
 611   endif()
 612 endforeach()
 613
 614 find_package(PythonInterp 2.7 QUIET)
 615 if(PYTHONINTERP_FOUND)
 616   if(PYTHON_VERSION_STRING VERSION_GREATER 2.8)
 617     unset(PYTHONINTERP_FOUND)
 618   endif()
 619 endif()
 620
 621 if (NOT PYTHONINTERP_FOUND)
 622   unset(PYTHON_EXECUTABLE CACHE)
 623   unset(PYTHON_VERSION_MAJOR)
 624   unset(PYTHON_VERSION_MINOR)
 625   unset(PYTHON_VERSION_STRING)
 626   find_package(PythonInterp 3.3 REQUIRED)
 627 endif()
 628
 629 set(LYX_PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 630
 631 if(LYX_NLS)
 632         find_package(LyXGettext)
 633         if(LYX_PYTHON_EXECUTABLE AND GETTEXT_FOUND)
 634                 add_subdirectory(po "${TOP_BINARY_DIR}/po")
 635         else()
 636                 # Install only supplied .gmo-files
 637                 file(GLOB _gmofiles RELATIVE "${TOP_SRC_DIR}/po" "${TOP_SRC_DIR}/po/*.gmo")
 638                 message(STATUS "Installing provided .gmo-files only")
 639                 foreach( _gmo ${_gmofiles})
 640                         string(REGEX REPLACE "\\.gmo$" "" _lang ${_gmo})
 641                         install(FILES "${TOP_SRC_DIR}/po/${_gmo}" DESTINATION ${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}/${_lang}/LC_MESSAGES RENAME ${PACKAGE}.mo)
 642                 endforeach()
 643         endif()
 644 endif()
 645
 646
 647 find_package(ICONV REQUIRED)
 648 find_package(ZLIB REQUIRED)
 649
 650 if(LYX_EXTERNAL_BOOST)
 651         message(STATUS "Searching for boost")
 652         if(LYX_USE_STD_REGEX)
 653                 find_package(Boost COMPONENTS signals)
 654         else()
 655                 find_package(Boost COMPONENTS signals regex)
 656         endif()
 657         if(Boost_FOUND)
 658                 message(STATUS "Boost found")
 659                 message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 660                 set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 661                 if (LYX_STDLIB_DEBUG)
 662                         # Comment from  Jean-Marc Lasgouttes:
 663                         # In general, system boost libraries are incompatible with
 664                         # the use of stdlib-debug in libstdc++. See ticket #9736 for
 665                         # details.
 666                         message(WARNING "Compiling LyX with stdlib-debug and system boost libraries may lead to crashes. Consider using '-DLYX_STDLIB_DEBUG=OFF' or using '-DLYX_EXTERNAL_BOOST=OFF'")
 667                 endif()
 668         else()
 669                 message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 670         endif()
 671 else()
 672         if(LYX_USE_STD_REGEX)
 673                 set(Lyx_Boost_Libraries boost_signals)
 674         else()
 675                 set(Lyx_Boost_Libraries boost_signals boost_regex)
 676         endif()
 677         add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 678         add_definitions(-DBOOST_SIGNALS_NO_DEPRECATION_WARNING=1)
 679         include_directories(${TOP_SRC_DIR}/boost)
 680         add_subdirectory(boost "${TOP_BINARY_DIR}/boost")
 681 endif()
 682
 683
 684
 685
 686 if(WIN32)
 687         if(NOT LYX_CONSOLE)
 688                 set(WIN32_CONSOLE WIN32)
 689                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARY})
 690         endif()
 691         if(MSVC)
 692                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 693                 # disable checked iterators for msvc release builds to get maximum speed
 694                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 695         else()
 696                 add_definitions(-DWINVER=0x0500)
 697         endif()
 698 endif()
 699
 700 # Compute qt4-version from ${QTVERSION}
 701
 702 message(STATUS "")
 703 foreach(_v PACKAGE PACKAGE_VERSION
 704         PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 705         LYX_ABS_TOP_SRCDIR
 706         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 707         if(NOT DEFINED ${_v})
 708                 message(FATAL_ERROR "${_v} not defined")
 709         endif()
 710         string(SUBSTRING "${_v}                            " 0 28 _v1)
 711         message(STATUS "----- ${_v1}: ${${_v}}")
 712 endforeach(_v)
 713 message(STATUS "")
 714
 715
 716 if(LYX_PCH)
 717         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 718         # Not sure if it works for all non-msvc compilers
 719         include(PCHSupport_26)
 720         configure_file(${TOP_CMAKE_PATH}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
 721         configure_file(${TOP_CMAKE_PATH}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 722         add_definitions(-DLYX_ENABLE_PCH)
 723
 724         if(MSVC)
 725                 macro(lyx_add_msvc_pch name_)
 726                         set_source_files_properties(${${name_}_sources} PROPERTIES
 727                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 728                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
 729                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 730                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
 731                                 ${TOP_BINARY_DIR}/pcheaders.h)
 732                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 733                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 734                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 735                 endmacro(lyx_add_msvc_pch)
 736                 macro(lyx_add_gcc_pch name_)
 737                 endmacro()
 738         else()
 739                 macro(lyx_add_msvc_pch name_)
 740                 endmacro()
 741                 macro(lyx_add_gcc_pch name_)
 742                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT)
 743                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
 744                 endmacro()
 745         endif()
 746 else()
 747         macro(lyx_add_msvc_pch)
 748         endmacro(lyx_add_msvc_pch)
 749         macro(lyx_add_gcc_pch name_)
 750         endmacro()
 751 endif()
 752
 753
 754 if(MSVC)
 755
 756         if(LYX_VLD)
 757                 set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/development/Win32/vld)
 758                 add_subdirectory(${vld_path}/cmake)
 759                 include(${vld_path}/cmake/vld.cmake) # forced include
 760                 set(vld_dll vld)
 761         endif()
 762
 763         if(LYX_WALL)
 764                 # Use the highest warning level
 765                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 766
 767                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 768                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 769                 else()
 770                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 771                 endif()
 772
 773                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 774                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 775                 else()
 776                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 777                 endif()
 778
 779                 # add here warnings which should produce an error /weXXXX
 780                 set(MSVC_W_ERROR   "/we4101 /we4189")
 781                 # add here warnings which should be disabled /wdXXXX
 782                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 783
 784                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 785                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 786                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 787
 788         else()
 789                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 790
 791                 # add here warnings which should produce an error /weXXXX
 792                 set(MSVC_W_ERROR   "/we4101 /we4189")
 793                 # add here warnings which should be disabled /wdXXXX
 794                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 795
 796                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 797                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 798                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 799
 800         endif()
 801
 802         if (NOT Qt5Core_FOUND)
 803                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 804                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 805                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 806         endif()
 807
 808         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 809         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 810         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 811         message(STATUS "")
 812 endif()
 813
 814
 815 if(LYX_DEBUG_GLIBC)
 816         set(_GLIBCXX_DEBUG ON)
 817 endif()
 818
 819 if(LYX_DEBUG_GLIBC_PEDANTIC)
 820         set(_GLIBCXX_DEBUG_PEDANTIC ON)
 821 endif()
 822
 823 # Xcode compiler
 824 if (CMAKE_GENERATOR MATCHES Xcode)
 825         if (XCODE_VERSION VERSION_LESS "5.0")
 826                 # Automatically select the Xcode compiler if not set
 827                 if (NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 828                         # XCode >= 3.1 has gcc 4.2 (up to actual Xcode)
 829                         if (XCODE_VERSION VERSION_GREATER "3.1")
 830                                 SET(CMAKE_XCODE_ATTRIBUTE_GCC_VERSION "com.apple.compilers.llvmgcc42")
 831                         ENDIF(XCODE_VERSION VERSION_GREATER "3.1")
 832                 ENDIF(NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 833                 # Print the selected compiler version
 834         MESSAGE(STATUS "---- Using XCode compiler CMAKE_XCODE_ATTRIBUTE_GCC_VERSION=${CMAKE_XCODE_ATTRIBUTE_GCC_VERSION}")
 835         ENDIF(XCODE_VERSION VERSION_LESS "5.0")
 836 ENDIF(CMAKE_GENERATOR MATCHES Xcode)
 837
 838 if (WIN32 AND Qt5Core_FOUND)
 839         set(Z_PREFIX 1)
 840 endif()
 841
 842 # compiler tests, config.h generation
 843 if(MSVC AND NOT LYX_CONFIGURE_CHECKS)
 844         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.msvc ${TOP_BINARY_DIR}/configCompiler.h)
 845 else()
 846         include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
 847         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
 848 endif()
 849
 850 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
 851
 852 if(QTVERSION MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+).*")
 853         MATH(EXPR QT4_VERSION "(${CMAKE_MATCH_1}<<16)|(${CMAKE_MATCH_2}<<8)|${CMAKE_MATCH_3}")
 854 endif()
 855
 856
 857 set (cmd ${CMAKE_CTEST_COMMAND})
 858 if (MSVC)
 859         set (cmd ${cmd} -C ${CMAKE_CFG_INTDIR})
 860 else ()
 861         set (cmd ${cmd} -C ${CMAKE_BUILD_TYPE})
 862 endif ()
 863 add_custom_target (lyx_run_tests COMMAND ${cmd})
 864 set_target_properties(lyx_run_tests PROPERTIES FOLDER "tests")
 865
 866 if(LYX_ASAN)
 867     set(LYX_CXX_FLAGS "-fsanitize=address -fno-omit-frame-pointer -g")
 868     message(STATUS)
 869     message(STATUS "Address sanitizer enabled. Usage:")
 870     message(STATUS "    wget https://llvm.org/svn/llvm-project/compiler-rt/trunk/lib/asan/scripts/asan_symbolize.py")
 871     message(STATUS "    chmod  +x ./asan_symbolize.py")
 872     message(STATUS "    ./bin/lyx2.2 2>&1 | ./asan_symbolize.py  | c++filt ")
 873     message(STATUS)
 874 endif()
 875
 876 if(LYX_INSTALL)
 877         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 878                 message(STATUS "Python required to create doc!")
 879         else()
 880                 if(UNIX)
 881                         add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
 882                 endif()
 883                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
 884         endif()
 885         include(../Install)
 886 endif()
 887
 888 add_subdirectory(src "${TOP_BINARY_DIR}/src")
 889 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
 890 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
 891 add_subdirectory(lib/examples "${TOP_BINARY_DIR}/lib/examples")
 892 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
 893 add_subdirectory(development/autotests "${TOP_BINARY_DIR}/autotests")
 894 if(LYX_ENABLE_URLTESTS)
 895         add_subdirectory(development/checkurls "${TOP_BINARY_DIR}/checkurls")
 896 endif()
 897
 898 message(STATUS)
 899 message(STATUS "Build params, switch LYX_* options by -DLYX_*=ON or OFF, LYX_* combos by -DLYX_*=value:")
 900 message(STATUS)
 901
 902 LYX_OPTION_LIST_ALL(used)
 903
 904
 905 if(LYX_NLS)
 906         message(STATUS)
 907         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
 908         message(STATUS)
 909         message(STATUS "  * iconv")
 910         message(STATUS "     - header : ${ICONV_HEADER}")
 911         message(STATUS "     - library: ${ICONV_LIBRARY}")
 912         message(STATUS "  * zlib")
 913         message(STATUS "     - header : ${ZLIB_HEADER}")
 914         message(STATUS "     - library: ${ZLIB_LIBRARY}")
 915         message(STATUS)
 916 endif()
 917
 918 # Apple has builtin native spell checker,
 919 # no need to warn for missing Aspell, Hunspell or Enchant
 920 if(NOT Spelling_FOUND AND NOT APPLE)
 921   if(LYX_REQUIRE_SPELLCHECK)
 922     set(_mode "FATAL_ERROR")
 923   else()
 924     set(_mode "STATUS")
 925   endif()
 926   message(${_mode} "No spellcheck libraries found. LyX will be unable use spellchecking")
 927 endif()
 928
 929 include("${TOP_CMAKE_PATH}/LyxPackaging.cmake")
 930
 931 if(ENABLE_DIST)
 932   # Use git to create the source package
 933   # git archive --format=tgz --output=/home/kornel/x.tar.gz master
 934   if(UNIX)
 935     set(DIST_FORMAT tgz)
 936   else()
 937     set(DIST_FORMAT zip)
 938   endif()
 939   set(DIST_NAME ${CMAKE_PROJECT_NAME}-${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}-${CMAKE_SYSTEM_NAME}.${DIST_FORMAT})
 940
 941   add_custom_command(
 942     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME}
 943     COMMAND  ${LYX_GITVERSION} archive --format=${DIST_FORMAT} --output=${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME} master
 944     WORKING_DIRECTORY ${TOP_SRC_DIR})
 945   add_custom_target(git-archive DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME})
 946 endif()
 947
 948 # Last directory to be included so that the fixup code (OS X)
 949 # can be run last
 950 add_subdirectory(development/cmake/post_install)
 951
 952 message(STATUS)