CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 3.1.0)
   8
   9 set(LYX_PROJECT LyX)
  10
  11 # Instruct cmake to not use gnu extensions,
  12 # this prevents the mix of '-std=c++*' and '-std=gnu++*' flags
  13 set(CMAKE_CXX_EXTENSIONS OFF)
  14
  15 enable_testing()
  16
  17 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README REALPATH) # Resolve symlinks
  18 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  19 message(STATUS "TOP_SRC_DIR = ${TOP_SRC_DIR}")
  20
  21 set(LYX_CMAKE_DIR "development/cmake")
  22 set(TOP_CMAKE_PATH "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}")
  23 set(TOP_MODULE_PATH "${TOP_CMAKE_PATH}/modules")
  24 set(TOP_SCRIPT_PATH "${TOP_CMAKE_PATH}/scripts")
  25
  26 set(CMAKE_MODULE_PATH "${TOP_MODULE_PATH}")
  27
  28 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  29
  30 message(STATUS)
  31 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  32         message(STATUS "Building in-source")
  33         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  34 else()
  35         message(STATUS "Building out-of-source")
  36         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  37 endif()
  38
  39 # This directory should be used if some test uses lyx-executable
  40 set(LYX_TESTS_USERDIR "${TOP_BINARY_DIR}/Testing/.lyx")
  41 file(MAKE_DIRECTORY "${LYX_TESTS_USERDIR}")
  42
  43 if(COMMAND cmake_policy)
  44         # Installing MACOSX_BUNDLE targets requires a BUNDLE DESTINATION
  45         cmake_policy(SET CMP0006 NEW)
  46         if(POLICY CMP0043)
  47                 # COMPILE_DEFINITIONS are not used yet. Enable new behavior.
  48                 cmake_policy(SET CMP0043 NEW)
  49         endif()
  50         cmake_policy(SET CMP0020 NEW)
  51         if(POLICY CMP0075)
  52                 cmake_policy(SET CMP0075 NEW)
  53         endif()
  54 endif()
  55
  56 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  57
  58 # Supress regeneration
  59 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  60
  61 if(LYX_XMINGW)
  62     set(CMAKE_SYSTEM_NAME Windows)
  63     set(TOOLNAME ${LYX_XMINGW})
  64     set(TOOLCHAIN "${TOOLNAME}-")
  65     set(CMAKE_C_COMPILER   "${TOOLCHAIN}gcc"     CACHE PATH "Mingw C compiler" FORCE)
  66     set(CMAKE_CXX_COMPILER "${TOOLCHAIN}g++"     CACHE PATH "Mingw C++ compiler" FORCE)
  67     set(CMAKE_RC_COMPILER  "${TOOLCHAIN}windres" CACHE PATH "Mingw rc compiler" FORCE)
  68
  69     set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM BOTH)
  70     set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY)
  71     set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY)
  72 endif()
  73
  74 if(NOT help AND NOT HELP)
  75   # 'project' triggers the searching for a compiler
  76   project(${LYX_PROJECT})
  77   if (CMAKE_COMPILER_IS_GNUCXX)
  78     if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS "4.0")
  79       message(STATUS "Gnu CXX compiler version = ${CMAKE_CXX_COMPILER_VERSION}")
  80       message(STATUS "is too old, should be >= 4.0")
  81       message(FATAL_ERROR "Exiting")
  82     endif()
  83   endif()
  84 endif()
  85
  86 if(UNIX)
  87         set(ARCH_TRIPLET )
  88         FIND_PROGRAM(DPKG_ARCHITECTURE_EXECUTABLE dpkg-architecture)
  89         if(DPKG_ARCHITECTURE_EXECUTABLE)
  90                 EXECUTE_PROCESS(COMMAND ${DPKG_ARCHITECTURE_EXECUTABLE} -qDEB_HOST_MULTIARCH
  91                                 OUTPUT_VARIABLE ARCH_TRIPLET
  92                                 ERROR_VARIABLE ERROR_ARCH_TRIPLET
  93                                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  94         endif()
  95 endif()
  96 if(ARCH_TRIPLET)
  97         set(SYSTEM_LIB_DIRS /usr/lib /usr/lib/${ARCH_TRIPLET} /usr/local/lib)
  98 else()
  99         set(SYSTEM_LIB_DIRS /usr/lib /usr/local/lib)
 100 endif()
 101
 102 include(LyXMacros)
 103 include(LyXDestinations)
 104
 105 # Try to get some informations from configure.ac
 106 include(LyXPaths)
 107
 108 # Value of USE_POSIX_PACKAGING is needed in determineversionandbuildtype()
 109 if(WIN32)
 110         set(CMAKE_PREFIX_PATH Specify-path-to-Qt CACHE PATH "Used Qt version")
 111         if(MSVC)
 112                 set(LYX_3RDPARTY_BUILD ON CACHE BOOL "Build 3rdparty libraries" FORCE)
 113         endif()
 114         set(USE_WINDOWS_PACKAGING ON)
 115 elseif(APPLE)
 116         set(USE_MACOSX_PACKAGING ON)
 117 else()
 118         set(USE_POSIX_PACKAGING ON)
 119 endif()
 120
 121 determineversionandbuildtype("${TOP_SRC_DIR}/configure.ac" _package_list _version_list _envlist LYX_DATE LYX_BUILD_TYPE)
 122 list(GET _package_list 0 PACKAGE_BASE)
 123 list(GET _package_list 1 PACKAGE_VERSION)
 124 list(GET _package_list 2 PACKAGE_BUGREPORT)
 125 list(GET _envlist 0 LYX_DIR_VER)
 126 list(GET _envlist 1 LYX_USERDIR_VER)
 127 list(GET _version_list 0 LYX_VERSION)
 128 list(GET _version_list 1 LYX_MAJOR_VERSION)
 129 list(GET _version_list 2 LYX_MINOR_VERSION)
 130 list(GET _version_list 3 LYX_RELEASE_LEVEL)
 131 list(GET _version_list 4 LYX_RELEASE_PATCH)
 132
 133 # Usage LYX_OPTION
 134 # 1. parameter: option name without prefix 'LYX_'
 135 # 2. parameter: description
 136 # 3. parameter: default value, ON or OFF
 137 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
 138
 139
 140 # Select some defaults depending on LYX_BUILD_TYPE
 141 if(LYX_BUILD_TYPE STREQUAL "development")
 142   set(DefaultLyxDebug ON)
 143   set(DefaultLyxRelease OFF)
 144   set(DefaultLyxStdlibDebug ON)
 145   set(DefaultLyxEnableAssertions ON)
 146 elseif(LYX_BUILD_TYPE STREQUAL "prerelease")
 147   set(DefaultLyxDebug OFF)
 148   set(DefaultLyxRelease OFF)
 149   set(DefaultLyxStdlibDebug OFF)
 150   set(DefaultLyxEnableAssertions OFF)
 151 elseif(LYX_BUILD_TYPE STREQUAL "release")
 152   set(DefaultLyxDebug OFF)
 153   set(DefaultLyxRelease ON)
 154   set(DefaultLyxStdlibDebug OFF)
 155   set(DefaultLyxEnableAssertions OFF)
 156 else()
 157   message(FATAL_ERROR "Unknown build type (${LYX_BUILD_TYPE}) encountered")
 158 endif()
 159 # Usage LYX_COMBO
 160 # 1. parameter: name without prefix 'LYX_'
 161 # 2. parameter: description
 162 # 3. parameter: default value
 163 # 4-n parameter: possible other string values
 164
 165 LYX_OPTION_INIT()
 166
 167 # Options for all compilers/systems
 168 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
 169 LYX_OPTION(LOCALVERSIONING  "Add version info to created package name (only used if LYX_CPACK option set)" OFF ALL)
 170 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
 171 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
 172 LYX_OPTION(REQUIRE_SPELLCHECK "Abort if no spellchecker available" OFF ALL)
 173 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
 174 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
 175 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
 176 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" ${DefaultLyxRelease} ALL)
 177 LYX_OPTION(DEBUG            "Enforce debug build"  ${DefaultLyxDebug} ALL)
 178 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
 179 LYX_OPTION(ENABLE_ASSERTIONS "Run sanity checks in the program"  ${DefaultLyxEnableAssertions} ALL)
 180 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
 181 LYX_STRING(SUFFIX_VALUE     "Use this string as suffix" "")
 182 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
 183 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
 184 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
 185 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
 186 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
 187 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
 188 LYX_OPTION(ENABLE_URLTESTS  "Enable for URL tests" OFF ALL)
 189 LYX_OPTION(ENABLE_EXPORT_TESTS "Enable for export tests" OFF ALL)
 190 LYX_OPTION(ENABLE_KEYTESTS  "Enable for keytests" OFF ALL)
 191 if (NOT CMAKE_VERSION VERSION_LESS "3.17")
 192   LYX_OPTION(ENABLE_VALGRIND_TESTS  "Enable for tests involving valgrind" OFF ALL)
 193 else()
 194   if (LYX_ENABLE_VALGRIND_TESTS)
 195     unset(LYX_ENABLE_VALGRIND_TESTS CACHE)
 196   endif()
 197 endif()
 198 LYX_OPTION(ASAN             "Use address sanitizer" OFF ALL)
 199 #LYX_COMBO(USE_FILEDIALOG    "Use native or QT file dialog" QT NATIVE)
 200 LYX_COMBO(USE_QT            "Use Qt version as frontend" AUTO QT4 QT5)
 201 LYX_COMBO(USE_IPO           "Interprocedural optimization" OFF AUTO ON)
 202 #LYX_OPTION(3RDPARTY_BUILD   "Build 3rdparty libs" OFF ALL)
 203 LYX_OPTION(DISABLE_CALLSTACK_PRINTING "do not print a callstack when crashing" OFF ALL)
 204 LYX_OPTION(EXTERNAL_Z       "OFF := Build 3rdparty lib zlib" ON ALL)
 205 LYX_OPTION(EXTERNAL_DTL     "OFF := Build 3rdparty commands dt2dv and dv2dt" ON ALL)
 206 LYX_OPTION(EXTERNAL_ICONV   "OFF := Build 3rdparty lib iconvlib" ON ALL)
 207 LYX_OPTION(EXTERNAL_HUNSPELL "OFF := Build 3rdparty lib hunspelllib" ON ALL)
 208 LYX_COMBO(EXTERNAL_MYTHES   "OFF := Build 3rdparty lib mytheslib" AUTO OFF ON)
 209
 210 # GCC specific
 211 LYX_OPTION(PROFILE              "Build with options for gprof" OFF GCC)
 212 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" OFF GCC)
 213 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
 214 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
 215 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++ pedantic debug mode" OFF GCC)
 216 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" ${DefaultLyxStdlibDebug} GCC)
 217
 218 # MSVC specific
 219 LYX_OPTION(CONSOLE               "Show console on Windows" ON MSVC)
 220 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
 221 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
 222 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
 223
 224 # APPLE specific
 225 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
 226 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
 227
 228
 229 if(help OR HELP)
 230         message(STATUS)
 231         message(STATUS "Available options: (dis/enable with -DLYX_*=OFF/ON)")
 232         message(STATUS)
 233         LYX_OPTION_LIST_ALL(help)
 234         message(STATUS)
 235         RETURN()
 236 endif()
 237
 238 if ("${LYX_SUFFIX_VALUE}" MATCHES "")
 239   set(LYX_INSTALL_SUFFIX "${LYX_MAJOR_VERSION}.${LYX_MINOR_VERSION}")
 240 else()
 241   set(LYX_INSTALL_SUFFIX "${LYX_SUFFIX_VALUE}")
 242 endif()
 243
 244 # Check option dependencies
 245 if (LYX_ENABLE_VALGRIND_TESTS)
 246         find_program(VALGRIND_EXECUTABLE "valgrind")
 247         if (NOT VALGRIND_EXECUTABLE)
 248                 message(FATAL_ERROR "Cannot use valgrind tests, executable valgrind is missing. Please disable LYX_ENABLE_VALGRIND_TESTS")
 249         endif()
 250 endif()
 251 if (LYX_DEBUG_GLIBC OR LYX_DEBUG_GLIBC_PEDANTIC OR LYX_STDLIB_DEBUG)
 252   if (LYX_EXTERNAL_BOOST)
 253     message(FATAL_ERROR "Using external boost not compatible with debug mode for stdlib")
 254   endif()
 255 endif()
 256
 257 if(LYX_DMG)
 258         set(LYX_BUNDLE ON)
 259         set(LYX_CPACK ON)
 260 endif()
 261
 262 if(LYX_CPACK)
 263         set(LYX_INSTALL ON)
 264 endif()
 265
 266 if(LYX_INSTALL)
 267         set(LYX_NLS ON)
 268         if(WIN32 AND NOT MINGW)
 269                 set(LYX_HUNSPELL ON)
 270         endif()
 271         set(LYX_PACKAGE_SUFFIX ON)
 272         if(NOT LYX_DEBUG)
 273                 set(LYX_RELEASE ON)
 274         endif()
 275         set(LYX_PROFILE OFF)
 276 endif()
 277
 278
 279 if(LYX_MERGE_FILES)
 280         set(LYX_PCH OFF)
 281 else()
 282         set(LYX_MERGE_REBUILD OFF)
 283 endif()
 284
 285 if(LYX_DEPENDENCIES_DOWNLOAD)
 286         message(STATUS)
 287         if(MSVC14)
 288                 set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2015-deps)
 289                 set(deps_files lyx-windows-deps-msvc2015.zip)
 290                 set(deps_server http://ftp.lyx.de/LyX-Windows-Deps)
 291                 set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2015)
 292         elseif(MSVC10)
 293                 set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 294                 set(deps_files lyx-windows-deps-msvc2010.zip)
 295                 set(deps_server http://ftp.lyx.de/LyX-Windows-Deps)
 296                 set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2010)
 297         else()
 298                 message(FATAL_ERROR "error: no dependency package known for the selected MSVC version.")
 299         endif()
 300     message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 301         foreach(it ${deps_files})
 302                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 303                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 304                 if(NOT already_downloaded)
 305                         message(STATUS "Downloading ${it} ...")
 306                         file(DOWNLOAD ${deps_server}/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS STATUS status LOG log)
 307                         list(GET status 0 status_code)
 308                         list(GET status 1 status_string)
 309                         if(NOT status_code EQUAL 0)
 310                                 file(REMOVE ${LYX_DEPENDENCIES_DIR}/${it})
 311                                 message(FATAL_ERROR "error: downloading '${it}' failed. status_code: ${status_code}, status_string: ${status_string}. \nLog: ${log} ")
 312                         endif()
 313                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 314                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 315                 endif()
 316         endforeach()
 317 endif()
 318
 319 message(STATUS)
 320
 321 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 322 if(WIN32)
 323         set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 324 else()
 325         set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 326 endif()
 327
 328 set(LYX_IPO_SUPPORTED OFF)
 329 if (POLICY CMP0069)
 330   cmake_policy(SET CMP0069 NEW)
 331   if(LYX_USE_IPO MATCHES "AUTO")
 332     # Enable LTO if supported and not debugging
 333     if (NOT LYX_DEBUG)
 334       include(CheckIPOSupported)
 335       check_ipo_supported(RESULT LYX_IPO_SUPPORTED)
 336     endif()
 337   else()
 338     set(LYX_IPO_SUPPORTED ${LYX_USE_IPO})
 339   endif()
 340 endif()
 341 if (LYX_IPO_SUPPORTED)
 342   set(LYX_USE_IPO "ON" CACHE STRING "Use interprocedural optimization" FORCE)
 343 else()
 344   set(LYX_USE_IPO "OFF" CACHE STRING "Use interprocedural optimization" FORCE)
 345 endif()
 346
 347 # Set to some meaningful default
 348 find_package(CXX11Compiler)
 349 if(NOT CXX11COMPILER_FOUND)
 350         message(FATAL_ERROR "A C++11 compatible compiler is required.")
 351 endif()
 352 unset(LYX_GCC11_MODE)
 353 if(UNIX OR MINGW)
 354         if (CMAKE_CXX_COMPILER_ID MATCHES "^([cC]lang|AppleClang)$")
 355           # ignore the GCC_VERSION for clang
 356           # and use the resulting CXX11_STD_REGEX found in FindCXX11Compiler.cmake
 357           message(STATUS "Using clang")
 358           if(CXX11_STD_REGEX)
 359             set(LYX_USE_STD_REGEX 1)
 360           else()
 361             set(LYX_USE_STD_REGEX 0)
 362           endif()
 363         else()
 364           execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpfullversion OUTPUT_VARIABLE GCC_VERSION ERROR_VARIABLE _error RESULT_VARIABLE _err OUTPUT_STRIP_TRAILING_WHITESPACE)
 365           #message(STATUS "dumpfullversion: error = ${_error}, result = ${_err}")
 366           if (_err)
 367             # previous check failed, try again with _old_ parameter
 368             execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION ERROR_VARIABLE _error RESULT_VARIABLE _err OUTPUT_STRIP_TRAILING_WHITESPACE)
 369             #message(STATUS "dumpversion: error = ${_error}, result = ${_err}")
 370           endif()
 371           message(STATUS "Using GCC version ${GCC_VERSION}")
 372           if(GCC_VERSION VERSION_LESS 4.6)
 373                 message(FATAL_ERROR "gcc >= 4.6 is required.")
 374           elseif(GCC_VERSION VERSION_LESS 4.9)
 375                 # <regex> in gcc is unusable in versions less than 4.9.0
 376                 # see https://gcc.gnu.org/bugzilla/show_bug.cgi?id=53631
 377                 set(LYX_USE_STD_REGEX 0)
 378           else()
 379                 set(LYX_USE_STD_REGEX 1)
 380           endif()
 381         endif()
 382         set(LYX_GCC11_MODE "${CXX11_FLAG}")
 383 else()
 384         if(MSVC_VERSION LESS 1900)
 385                 # Drop support for msvc versions prior to 1900 (Visual Studio 2015)
 386                 message(FATAL_ERROR "Visual Studio >= 2015 is required.")
 387                 set(LYX_USE_STD_REGEX 0)
 388         else()
 389                 set(LYX_USE_STD_REGEX 1)
 390         endif()
 391 endif()
 392
 393 if(LYX_3RDPARTY_BUILD)
 394   # LYX_3RDPARTY_BUILD is not cached anymore, but for compatibility reasons
 395   # this enables the build of all 3rd_party libs
 396   set(LYX_EXTERNAL_Z        OFF CACHE BOOL "Build 3rdparty lib zlib"    FORCE)
 397   set(LYX_EXTERNAL_ICONV    OFF CACHE BOOL "Build 3rdparty iconvlib"    FORCE)
 398   set(LYX_EXTERNAL_HUNSPELL OFF CACHE BOOL "Build 3rdparty hunspelllib" FORCE)
 399   set(LYX_EXTERNAL_MYTHES   OFF CACHE STRING "Build 3rdparty mytheslib" FORCE)
 400 endif()
 401
 402 FIND_PROGRAM(LYX_GITVERSION git)
 403 #message(STATUS "gitversion = ${LYX_GITVERSION}")
 404 set(LYX_REVISION_VERSION ${LYX_RELEASE_LEVEL})
 405 set(LYX_PACKAGE_RELEASE "UNDEFINED")
 406 if(LYX_GITVERSION)
 407   if (LYX_LOCALVERSIONING)
 408     # Find the revision number for later use
 409     EXECUTE_PROCESS(COMMAND ${LYX_GITVERSION} describe --match 2.0.0 HEAD
 410       WORKING_DIRECTORY "${TOP_SRC_DIR}"
 411       RESULT_VARIABLE tmp_GIT_RESULT
 412       OUTPUT_VARIABLE tmp_LYX_PACKAGE_RELEASE
 413       ERROR_VARIABLE tmp_GIT_ERROR
 414       OUTPUT_STRIP_TRAILING_WHITESPACE)
 415     if (tmp_GIT_RESULT EQUAL 0)
 416       if (tmp_LYX_PACKAGE_RELEASE MATCHES "^2\\.0\\.0\\-\([0-9]+\)\\-\(.*\)$")
 417         set(LYX_PACKAGE_RELEASE ${CMAKE_MATCH_2})
 418         # We will add offset of 40000 to get appropriate value to
 419         # previous svn.
 420         # We use this value than also to set the package-patch-value
 421         MATH(EXPR tmp_REVISION_VERSION "(${CMAKE_MATCH_1}+40000)")
 422         set(LYX_REVISION_VERSION "${LYX_RELEASE_LEVEL}-${tmp_REVISION_VERSION}git")
 423         set(ENABLE_DIST ON)
 424       endif()
 425     endif()
 426   endif()
 427 endif()
 428 if (LYX_PACKAGE_RELEASE MATCHES "UNDEFINED")
 429   set(LYX_PACKAGE_RELEASE  "1")
 430   if (LYX_RELEASE_PATCH GREATER 0)
 431     set(LYX_REVISION_VERSION "${LYX_RELEASE_LEVEL}.${LYX_RELEASE_PATCH}")
 432   endif()
 433 endif()
 434
 435 # Set the programs (lyx, tex2lyx, etc.) suffix
 436 # When building an OS X bundle, we will append
 437 # the suffix only to the bundle, not to the programs
 438 set(PROGRAM_SUFFIX "")
 439 if(LYX_PROGRAM_SUFFIX AND NOT (APPLE AND LYX_BUNDLE))
 440         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 441 endif()
 442 set(_lyx "${PACKAGE_BASE}${PROGRAM_SUFFIX}")
 443 set(_tex2lyx tex2lyx${PROGRAM_SUFFIX})
 444 set(_convert lyxconvert${PROGRAM_SUFFIX})
 445
 446 add_custom_target(lyx_version ALL
 447   COMMAND ${CMAKE_COMMAND} -DTOP_SRC_DIR=${TOP_SRC_DIR} -DTOP_CMAKE_PATH=${TOP_CMAKE_PATH} -DTOP_BINARY_DIR=${TOP_BINARY_DIR} -DLYX_DATE=${LYX_DATE} -P ${TOP_SCRIPT_PATH}/LyXGetVersion.cmake
 448   )
 449 set_target_properties(lyx_version PROPERTIES FOLDER "applications")
 450
 451 # Default paths for installed utilities (tex2lyx, lyxclient, etc.)
 452 set(LYX_UTILITIES_INSTALL_PATH bin)
 453
 454 if(LYX_BUNDLE)
 455         set(LYX_CPACK ON)
 456
 457         message(STATUS)
 458         message(STATUS "Bundle creation is enabled (experimental):")
 459         message(STATUS "    make")
 460         message(STATUS "    make install/strip")
 461         message(STATUS "    make package")
 462         if(APPLE)
 463                 set(MACOSX_BUNDLE TRUE)
 464                 # This sets the bundle + executable names
 465                 set(_lyx "${PACKAGE_BASE}${LYX_INSTALL_SUFFIX}")
 466                 # This sets the Info.plist executable name
 467                 set(osx_bundle_program_name ${_lyx})
 468                 # Bundle name
 469                 set(LYX_BUNDLE_NAME ${_lyx})
 470
 471                 # This will contain the list of files that need to be included
 472                 # in the bundle and their location within the bundle
 473                 set(OSX_BUNDLE_FILES "${TOP_SRC_DIR}/development/MacOSX/LyX.sdef;${TOP_SRC_DIR}/development/MacOSX/LyXapp.icns;${CMAKE_BINARY_DIR}/lyxrc.dist")
 474                 set(OSX_BUNDLE_DIRS "Resources;Resources;Resources")
 475
 476                 # Process Info.plist and lyxrc.dist
 477                 # See development/cmake/Install.cmake
 478                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/Info.plist.in" "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 479
 480                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 481                 set(LYX_DATA_SUBDIR ${LYX_BUNDLE_NAME}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 482
 483                 # Variables used by CPack
 484                 set(CPACK_BUNDLE_NAME ${LYX_BUNDLE_NAME})
 485                 set(CPACK_BUNDLE_PLIST "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 486                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${LYX_BUNDLE_NAME}.app)
 487
 488                 # Set the install paths
 489                 set(LYX_UTILITIES_INSTALL_PATH ${LYX_BUNDLE_NAME}.app/Contents/MacOS)
 490                 if(NOT LYX_INSTALL_PREFIX)
 491                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 492                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 493                 endif()
 494                 # Change the owner so that the install can work
 495                 install(CODE "set(BU_CHMOD_BUNDLE_ITEMS 1)" COMPONENT Runtime)
 496         elseif(UNIX)
 497                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 498                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 499                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 500         elseif(WIN32)
 501                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 502         endif()
 503 endif()
 504
 505 if(LYX_INSTALL_PREFIX)
 506         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 507         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 508 endif()
 509 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 510
 511 if(UNIX)
 512   set(SYSTEM_DATADIR "${CMAKE_INSTALL_PREFIX}/share")
 513 elseif(CMAKE_INSTALL_PREFIX MATCHES "/lyx${LYX_INSTALL_SUFFIX}$")
 514   string(REGEX REPLACE "/lyx${LYX_INSTALL_SUFFIX}$" "/share" SYSTEM_DATADIR ${CMAKE_INSTALL_PREFIX})
 515 else()
 516   set(SYSTEM_DATADIR "${CMAKE_INSTALL_PREFIX}")
 517 endif()
 518
 519 if(NOT CMAKE_COMPILER_IS_GNUCXX)
 520   # Not a GCC compiler, programs do not have a suffix
 521   set(suffixing ${LYX_PACKAGE_SUFFIX})
 522 elseif(WIN32 AND MINGW)
 523   # We want to use a suffix for the package in this case,
 524   # even if not for the program
 525   set(suffixing ${LYX_PACKAGE_SUFFIX})
 526 else()
 527   message(STATUS "CMAKE_COMPILER_IS_GNUCXX = ${CMAKE_COMPILER_IS_GNUCXX}")
 528   set(suffixing ${LYX_PROGRAM_SUFFIX})
 529 endif()
 530
 531 # The define PACKAGE below allows lyx-executable to find its default configuration files
 532 # see routines
 533 #    Package::messages_file()
 534 #    get_default_user_support_dir()
 535 #    relative_system_support_dir()
 536 # in src/support/Package.cpp
 537 if(suffixing)
 538         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 539 else()
 540         set(PACKAGE ${PACKAGE_BASE})
 541 endif()
 542
 543 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 544         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 545         if (UNIX)
 546                 # use the default "/usr/local"
 547                 # but respect the user-choice on the command-line
 548                 set(CMAKE_INSTALL_PREFIX "/usr/local" CACHE PATH "LyX default install prefix" FORCE)
 549         endif()
 550 endif()
 551 if(WIN32)
 552         set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 553 endif()
 554 if(IS_ABSOLUTE)
 555         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 556 else()
 557         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 558 endif()
 559
 560
 561
 562 if(NOT LYX_DATA_SUBDIR)
 563         if (WIN32)
 564                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 565         else()
 566                 set(LYX_DATA_SUBDIR "share/${_lyx}/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 567         endif()
 568 endif()
 569
 570 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}/${LYX_DATA_SUBDIR}")
 571 get_locale_destination(LYX_LOCALEDIR)
 572 set(LYX_ABS_INSTALLED_LOCALEDIR "${CMAKE_INSTALL_PREFIX}/${LYX_LOCALEDIR}")
 573 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 574
 575 if(LYX_BUNDLE AND APPLE)
 576         set(LYX_MAN_DIR_tmp "${LYX_DATA_SUBDIR}")
 577 else()
 578         if(WIN32)
 579                 set(LYX_MAN_DIR_tmp "${CMAKE_BINARY_DIR}/usr/local/man/")
 580         elseif(UNIX)
 581                 set(LYX_MAN_DIR_tmp "${CMAKE_INSTALL_PREFIX}/share/man/")
 582         else()
 583                 set(LYX_MAN_DIR_tmp "${CMAKE_INSTALL_PREFIX}/man/")
 584         endif()
 585 endif()
 586 if (NOT LYX_MAN_DIR_tmp EQUAL "${LYX_MAN_DIR}")
 587         unset(LYX_MAN_DIR CACHE)
 588         set(LYX_MAN_DIR "${LYX_MAN_DIR_tmp}" CACHE STRING "Install location for man pages.")
 589 endif()
 590 unset(LYX_MAN_DIR_tmp)
 591 mark_as_advanced(LYX_MAN_DIR)
 592
 593 # The Win installer cannot be built by CMake because one needs to install plugins for NSIS
 594 # see the Readme.txt of the installer
 595 #if(LYX_INSTALL AND WIN32)
 596 #       message(STATUS "Configuring NSIS files")
 597 #       configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 598 #       configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 599 #       configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 600 #       message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 601 #endif()
 602
 603 if(NOT GROUP_CODE)
 604         #set(GROUP_CODE "The Golden Code")
 605         set(GROUP_CODE flat)
 606 endif()
 607
 608 # lyx's source files
 609 set(LYX_CPP_FILES [a-zA-Z]*.cpp)
 610 set(LYX_HPP_FILES [a-zA-Z]*.h)
 611 set(LYX_MOC_FILES moc_*.cpp)
 612
 613 include(ProjectSourceGroup)
 614
 615
 616 if(LYX_PROFILE AND NOT MSVC)
 617         set(CMAKE_BUILD_TYPE Profile CACHE STRING "Profile build type" FORCE)
 618         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg")
 619         set(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS}  -pg")
 620 else()
 621         set(LYX_PROFILE OFF)
 622 endif()
 623
 624
 625 if(LYX_NO_OPTIMIZE)
 626         set(CMAKE_BUILD_TYPE None)
 627         set(LYX_DEBUG OFF)
 628         set(LYX_RELEASE OFF)
 629         set(LYX_PROFILE OFF)
 630 elseif(LYX_RELEASE)
 631         set(CMAKE_BUILD_TYPE Release)
 632         set(LYX_DEBUG OFF)
 633         set(LYX_PROFILE OFF)
 634 elseif(LYX_PROFILE)
 635         set(CMAKE_BUILD_TYPE Profile)
 636         set(LYX_DEBUG OFF)
 637 else()
 638         set(CMAKE_BUILD_TYPE Debug)
 639         set(LYX_DEBUG ON)
 640 endif()
 641
 642
 643 # When shared libs are supported enable this option
 644 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 645 if(LYX_SHARED_LIBRARIES)
 646         set(library_type SHARED)
 647 else()
 648         set(library_type STATIC)
 649 endif()
 650
 651 if(LYX_ENABLE_ASSERTIONS)
 652   set(LYX_CXX_FLAGS " -DENABLE_ASSERTIONS=1")
 653 else()
 654   set(LYX_CXX_FLAGS "")
 655 endif()
 656
 657 if(MSVC)
 658   if (CXX11_FLAG MATCHES "\\+\\+([0-9]+)")
 659     set(CMAKE_CXX_STANDARD ${CMAKE_MATCH_1})
 660     message(STATUS "CMAKE_CXX_STANDARD set to ${CMAKE_CXX_STANDARD}")
 661   endif()
 662   set(CMAKE_CXX_FLAGS       "${CMAKE_CXX_FLAGS}${LYX_CXX_FLAGS}")
 663 else()
 664         if(NOT LYX_QUIET)
 665                 set(CMAKE_VERBOSE_MAKEFILE ON)
 666         endif()
 667         set(LYX_CXX_FLAGS "-Wall -Wunused-parameter ${LYX_GCC11_MODE}${LYX_CXX_FLAGS}")
 668         if(LYX_GCC11_MODE MATCHES "\\+\\+(14|11|98)")
 669           # Thanks to Brad King <brad.king@kitware.com>
 670           # for the pointer to https://cmake.org/cmake/help/v3.6/variable/CMAKE_CXX_STANDARD.html
 671           # This allows us to use QT5.7 with recent g++ (version >= 4.9) compilers
 672           # and still use our own c++ extension tests
 673           set(CMAKE_CXX_STANDARD ${CMAKE_MATCH_1})
 674           message(STATUS "CMAKE_CXX_STANDARD set to ${CMAKE_CXX_STANDARD}")
 675         endif()
 676         if(LYX_STDLIB_DEBUG)
 677           set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 678         else()
 679           if(LYX_DEBUG_GLIBC)
 680             set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG")
 681           endif()
 682           if(LYX_DEBUG_GLIBC_PEDANTIC)
 683             set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG_PEDANTIC")
 684           endif()
 685         endif()
 686         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE STRING "Set CXX flags" FORCE)
 687         set(CMAKE_CXX_FLAGS_DEBUG "-O0 -g3 -D_DEBUG" CACHE STRING "Set debug flags" FORCE)
 688         if(MINGW)
 689                 set(CMAKE_CXX_FLAGS_RELEASE "-O2 -DNDEBUG" CACHE STRING "Set release flags for Mingw" FORCE)
 690         else()
 691                 set(CMAKE_CXX_FLAGS_RELEASE "-O3 -DNDEBUG" CACHE STRING "Set release flags" FORCE)
 692         endif()
 693 endif()
 694
 695 set(LYX_CXX_FLAGS_EXTRA "" CACHE STRING "Desired semicolon separated list of extra cxx compile flags, like '-Werror'")
 696 mark_as_advanced(LYX_CXX_FLAGS_EXTRA)
 697 if(LYX_CXX_FLAGS_EXTRA)
 698         foreach(_flag ${LYX_CXX_FLAGS_EXTRA})
 699                 add_definitions(${_flag})
 700         endforeach()
 701 endif()
 702
 703 if(LYX_XMINGW)
 704         list(APPEND CMAKE_FIND_ROOT_PATH ${GNUWIN32_DIR})
 705 endif()
 706
 707 set(min_qt5_version "5.6")
 708 if(LYX_USE_QT MATCHES "AUTO")
 709         # try qt5 first
 710         find_package(Qt5Core CONFIG QUIET)
 711         if(Qt5Core_FOUND)
 712                 set(LYX_USE_QT "QT5" CACHE STRING "Valid qt version" FORCE)
 713                 message(STATUS "Qt5Core_VERSION = ${Qt5Core_VERSION}")
 714                 if(Qt5Core_VERSION VERSION_LESS ${min_qt5_version})
 715                         find_package(Qt4 "4.5.0" QUIET)
 716                         if(QT4_FOUND)
 717                                 set(LYX_USE_QT "QT4" CACHE STRING "Valid qt version" FORCE)
 718                         endif()
 719                 endif()
 720         else()
 721                 set(LYX_USE_QT "QT4" CACHE STRING "Valid qt version" FORCE)
 722         endif()
 723 endif()
 724 if(LYX_USE_QT MATCHES "QT5")
 725         # set QPA_XCB if QT uses X11
 726         find_package(Qt5Core CONFIG REQUIRED)
 727         if (Qt5Core_FOUND)
 728                 find_package(Qt5Widgets CONFIG REQUIRED)
 729                 if(APPLE)
 730                         find_package(Qt5MacExtras CONFIG REQUIRED)
 731                 endif()
 732                 find_package(Qt5X11Extras CONFIG QUIET)
 733                 find_package(Qt5WinExtras CONFIG QUIET)
 734                 set(QTVERSION ${Qt5Core_VERSION})
 735                 if (QTVERSION VERSION_LESS ${min_qt5_version})
 736                         message(STATUS "QTVERSION = \"${QTVERSION}\"")
 737                         message(STATUS "This version is not recommended, try either option -DLYX_USE_QT=QT4 or")
 738                         message(STATUS "install QT-Version >= \"${min_qt5_version}\"")
 739                         # see thread in lyx-devel list
 740                         # From: Jean-Pierre Chrétien <jeanpierre.chretien@free.fr>
 741                         # Date 11.03.2017
 742                         # Subject: cmake compilation error
 743                         #message(FATAL_ERROR "Wrong Qt-Version")
 744                 endif()
 745                 macro (qt_use_modules lyxtarget)
 746                         foreach (_tg ${ARGN})
 747                                 find_package(Qt5${_tg} CONFIG REQUIRED)
 748                                 target_link_libraries(${lyxtarget} Qt5::${_tg})
 749                         endforeach()
 750                 endmacro()
 751                 macro (qt_add_resources)
 752                         qt5_add_resources(${ARGN})
 753                 endmacro()
 754                 macro (qt_wrap_uifiles)
 755                         qt5_wrap_ui(${ARGN})
 756                 endmacro()
 757                 message(STATUS "Found Qt-Version ${QTVERSION}")
 758                 if(WIN32)
 759                         set(LYX_QTMAIN_LIBRARY ${Qt5Core_QTMAIN_LIBRARIES})
 760                 endif()
 761         endif()
 762 elseif(LYX_USE_QT MATCHES "QT4")
 763         if(LYX_XMINGW)
 764                 set(QT_MINGW_DIR ${LYX_QT4} CACHE PATH "Qt for Mingw" FORCE)
 765                 list(APPEND CMAKE_FIND_ROOT_PATH ${QT_MINGW_DIR} ${GNUWIN32_DIR})
 766         endif()
 767         find_package(Qt4 "4.5.0" REQUIRED)
 768         macro (qt_use_modules)
 769         endmacro()
 770         macro (qt_add_resources)
 771                 qt4_add_resources(${ARGN})
 772         endmacro()
 773         macro (qt_wrap_uifiles)
 774                 qt4_wrap_ui(${ARGN})
 775         endmacro()
 776         set(LYX_QTMAIN_LIBRARY ${QT_QTSVG_LIBRARY})
 777         if(WIN32)
 778                 list(APPEND LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARIES})
 779         endif()
 780 else()
 781   message(FATAL_ERROR "Unhandled value for LYX_USE_QT (${LYX_USE_QT})")
 782 endif()
 783
 784 find_package(Magic)
 785 if(Magic_FOUND)
 786   set(HAVE_MAGIC_H 1)
 787   include_directories(${Magic_INCLUDE_DIR})
 788 endif()
 789
 790 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 791
 792 set(Spelling_FOUND OFF)
 793 set(Include_used_spellchecker)   # String will be inserted into config.h
 794
 795 if (LYX_EXTERNAL_MYTHES MATCHES "AUTO")
 796   # try system library first
 797   find_package(MyThesLIB)
 798   if (MYTHESLIB_FOUND)
 799     set(LYX_EXTERNAL_MYTHES ON CACHE STRING "OFF:= Build 3rdparty mytheslib" FORCE)
 800   else()
 801     set(LYX_EXTERNAL_MYTHES OFF CACHE STRING "OFF:= Build 3rdparty mytheslib" FORCE)
 802   endif()
 803 endif()
 804 if (LYX_EXTERNAL_MYTHES MATCHES "ON")
 805   find_package(MyThesLIB REQUIRED)
 806 else()
 807   add_subdirectory(3rdparty/mythes)
 808 endif()
 809 set(MYTHES_DIR ${MYTHESLIB_INCLUDE_DIR})
 810
 811 if(NOT LYX_EXTERNAL_HUNSPELL)
 812     add_subdirectory(3rdparty/hunspell)
 813     add_definitions(-DHUNSPELL_STATIC)
 814     set(HUNSPELL_FOUND ON)
 815     message(STATUS "  * Hunspell:")
 816     message(STATUS "     - include: ${HUNSPELL_INCLUDE_DIR}")
 817     message(STATUS "     - library: ${HUNSPELL_LIBRARY}")
 818 endif()
 819
 820 foreach(_spell "ASPELL" "ENCHANT" "HUNSPELL")
 821   string(TOUPPER ${_spell} _upspell)
 822   if (NOT ${_upspell}_FOUND)
 823     find_package(${_spell})
 824   endif()
 825   if (${_upspell}_FOUND)
 826     include_directories(${${_upspell}_INCLUDE_DIR})
 827     set(Spelling_FOUND ON)
 828     message(STATUS "Building with USE_${_upspell}")
 829     set(Include_used_spellchecker "${Include_used_spellchecker}#define USE_${_upspell} 1\n")
 830   else()
 831     if(LYX_${_upspell})
 832       message(FATAL_ERROR "Required ${_spell} devel package not found")
 833     else()
 834       message(STATUS "${_upspell} not found, building without ${_spell} support")
 835     endif()
 836   endif()
 837 endforeach()
 838
 839 if(GNUWIN32_DIR)
 840         list(APPEND CMAKE_PROGRAM_PATH "${GNUWIN32_DIR}/Python" )
 841 endif()
 842
 843 # Search for python default version first
 844 unset(PYTHON_EXECUTABLE CACHE)
 845 unset(LYX_PYTHON_EXECUTABLE CACHE)
 846 unset(PYTHON_VERSION_MAJOR)
 847 unset(PYTHON_VERSION_MINOR)
 848 unset(PYTHON_VERSION_STRING)
 849 if (CMAKE_VERSION VERSION_LESS "3.13")
 850   find_package(PythonInterp 3.5 QUIET)
 851   if(NOT PYTHONINTERP_FOUND)
 852     find_package(PythonInterp 2.0 REQUIRED)
 853     if(NOT PYTHON_VERSION_STRING VERSION_LESS 2.8)
 854       message(FATAL_ERROR "Python interpreter found, but is not suitable")
 855     endif()
 856   endif()
 857   set(LYX_PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 858 else()
 859   find_package(Python3 3.5 QUIET)
 860   if(NOT Python3_Interpreter_FOUND)
 861     unset(PYTHON_EXECUTABLE CACHE)
 862     find_package(Python2 2.0 REQUIRED)
 863     if(NOT Python2_VERSION VERSION_LESS 2.8)
 864       message(FATAL_ERROR "Python interpreter found, but is not suitable")
 865     endif()
 866     set(LYX_PYTHON_EXECUTABLE ${Python2_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 867   else()
 868     set(LYX_PYTHON_EXECUTABLE ${Python3_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 869   endif()
 870 endif()
 871
 872 if(LYX_NLS)
 873         find_package(LyXGettext)
 874         if(LYX_PYTHON_EXECUTABLE AND GETTEXT_FOUND)
 875                 add_subdirectory(po "${TOP_BINARY_DIR}/po")
 876         else()
 877                 # Install only supplied .gmo-files
 878                 file(GLOB _gmofiles RELATIVE "${TOP_SRC_DIR}/po" "${TOP_SRC_DIR}/po/*.gmo")
 879                 message(STATUS "Installing provided .gmo-files only")
 880                 foreach( _gmo ${_gmofiles})
 881                         string(REGEX REPLACE "\\.gmo$" "" _lang ${_gmo})
 882                         install(FILES "${TOP_SRC_DIR}/po/${_gmo}" DESTINATION ${LYX_LOCALEDIR}/${_lang}/LC_MESSAGES RENAME ${PACKAGE}.mo)
 883                 endforeach()
 884         endif()
 885 endif()
 886
 887 if(LYX_EXTERNAL_ICONV)
 888   find_package(ICONV REQUIRED)
 889 else()
 890   add_subdirectory(3rdparty/libiconv)
 891   set(HAVE_ICONV_CONST 1)
 892 endif()
 893
 894 if(LYX_EXTERNAL_Z)
 895   find_package(ZLIB REQUIRED)
 896 else()
 897   add_subdirectory(3rdparty/zlib)
 898 endif()
 899
 900 if(NOT LYX_EXTERNAL_DTL)
 901   add_subdirectory(3rdparty/dtl)
 902 endif()
 903
 904 if(LYX_USE_STD_REGEX)
 905   # Set only include path.
 906   # Use internal boost, which is known to exist
 907   # we don't need any libraries
 908   set(Lyx_Boost_Libraries)
 909   add_definitions(-DBOOST_USER_CONFIG=<config.h>)
 910   include_directories(${TOP_SRC_DIR}/3rdparty/boost)
 911 else()
 912   # Using boost-regex
 913   if(LYX_EXTERNAL_BOOST)
 914     message(STATUS "Searching for external boost")
 915     find_package(Boost COMPONENTS regex)
 916     if(Boost_FOUND)
 917       message(STATUS "Boost found")
 918       message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 919       set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 920       if (LYX_STDLIB_DEBUG OR LYX_DEBUG_GLIBC OR LYX_DEBUG_GLIBC_PEDANTIC)
 921         # Comment from  Jean-Marc Lasgouttes:
 922         # In general, system boost libraries are incompatible with
 923         # the use of stdlib-debug in libstdc++. See ticket #9736 for
 924         # details.
 925         message(FATAL_ERROR "Compiling LyX with stdlib-debug and system boost libraries may lead to crashes. Consider using '-DLYX_STDLIB_DEBUG=OFF -DLYX_DEBUG_GLIBC=OFF -DLYX_DEBUG_GLIBC_PEDANTIC=OFF' or using '-DLYX_EXTERNAL_BOOST=OFF'")
 926       endif()
 927     else()
 928       message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 929     endif()
 930   else()
 931     # Using included boost
 932     set(Lyx_Boost_Libraries boost_regex)
 933     add_definitions(-DBOOST_USER_CONFIG=<config.h>)
 934     include_directories(${TOP_SRC_DIR}/3rdparty/boost)
 935     add_subdirectory(3rdparty/boost "${TOP_BINARY_DIR}/3rdparty/boost")
 936   endif()
 937 endif()
 938
 939 if(WIN32)
 940         if(LYX_CONSOLE)
 941                 set(LYX_QTMAIN_LIBRARY)
 942         else()
 943                 set(WIN32_CONSOLE WIN32)
 944         endif()
 945         if(MSVC)
 946                 # -DPSAPI_VERSION=1 is needed to run on vista (bug 10186)
 947                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX -DPSAPI_VERSION=1)
 948                 # disable checked iterators for msvc release builds to get maximum speed
 949                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 950         else()
 951                 # -DPSAPI_VERSION=1 is not needed for mingw, since the mingw psapi.h
 952                 # does not use it and always declares the vista compatible API.
 953                 # If this ever changes then -DPSAPI_VERSION might be needed here as well.
 954                 add_definitions(-DWINVER=0x0500)
 955         endif()
 956 endif()
 957
 958 # Compute qt-version from ${QTVERSION}
 959
 960 message(STATUS "")
 961 foreach(_v PACKAGE PACKAGE_VERSION
 962         PROGRAM_SUFFIX LYX_VERSION LYX_DIR_VER LYX_USERDIR_VER
 963         LYX_ABS_TOP_SRCDIR
 964         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 965         if(NOT DEFINED ${_v})
 966                 message(FATAL_ERROR "${_v} not defined")
 967         endif()
 968         string(SUBSTRING "${_v}                            " 0 28 _v1)
 969         message(STATUS "----- ${_v1}: ${${_v}}")
 970 endforeach(_v)
 971 message(STATUS "")
 972
 973
 974 if(LYX_PCH)
 975         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 976         # Not sure if it works for all non-msvc compilers
 977         include(PCHSupport_26)
 978         configure_file(${TOP_CMAKE_PATH}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
 979         configure_file(${TOP_CMAKE_PATH}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 980         add_definitions(-DLYX_ENABLE_PCH)
 981
 982         if(MSVC)
 983                 macro(lyx_add_msvc_pch name_)
 984                         set_source_files_properties(${${name_}_sources} PROPERTIES
 985                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 986                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
 987                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 988                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
 989                                 ${TOP_BINARY_DIR}/pcheaders.h)
 990                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 991                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 992                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 993                 endmacro(lyx_add_msvc_pch)
 994                 macro(lyx_add_gcc_pch name_)
 995                 endmacro()
 996         else()
 997                 macro(lyx_add_msvc_pch name_)
 998                 endmacro()
 999                 macro(lyx_add_gcc_pch name_)
1000                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT)
1001                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
1002                 endmacro()
1003         endif()
1004 else()
1005         macro(lyx_add_msvc_pch)
1006         endmacro(lyx_add_msvc_pch)
1007         macro(lyx_add_gcc_pch name_)
1008         endmacro()
1009 endif()
1010
1011
1012 if(MSVC)
1013
1014         if(LYX_VLD)
1015                 set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/development/Win32/vld)
1016                 add_subdirectory(${vld_path}/cmake)
1017                 include(${vld_path}/cmake/vld.cmake) # forced include
1018                 set(vld_dll vld)
1019         endif()
1020
1021         if(LYX_WALL)
1022                 # Use the highest warning level
1023                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE STRING "Warning level" FORCE)
1024
1025                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
1026                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
1027                 else()
1028                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
1029                 endif()
1030
1031                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
1032                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
1033                 else()
1034                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
1035                 endif()
1036
1037                 # add here warnings which should produce an error /weXXXX
1038                 set(MSVC_W_ERROR   "/we4101 /we4189")
1039                 # add here warnings which should be disabled /wdXXXX
1040                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
1041
1042                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1043                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1044                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1045
1046         else()
1047                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE STRING "Warning level" FORCE)
1048
1049                 # add here warnings which should produce an error /weXXXX
1050                 set(MSVC_W_ERROR   "/we4101 /we4189")
1051                 # add here warnings which should be disabled /wdXXXX
1052                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
1053
1054                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1055                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1056                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1057
1058         endif()
1059
1060         if (NOT Qt5Core_FOUND)
1061                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
1062                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
1063                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
1064         endif()
1065
1066         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
1067         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
1068         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
1069         message(STATUS "")
1070 endif()
1071
1072
1073 # Xcode compiler
1074 if (CMAKE_GENERATOR MATCHES Xcode)
1075         if (XCODE_VERSION VERSION_LESS "5.0")
1076                 # Automatically select the Xcode compiler if not set
1077                 if (NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
1078                         # XCode >= 3.1 has gcc 4.2 (up to actual Xcode)
1079                         if (XCODE_VERSION VERSION_GREATER "3.1")
1080                                 SET(CMAKE_XCODE_ATTRIBUTE_GCC_VERSION "com.apple.compilers.llvmgcc42")
1081                         ENDIF(XCODE_VERSION VERSION_GREATER "3.1")
1082                 ENDIF(NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
1083                 # Print the selected compiler version
1084         MESSAGE(STATUS "---- Using XCode compiler CMAKE_XCODE_ATTRIBUTE_GCC_VERSION=${CMAKE_XCODE_ATTRIBUTE_GCC_VERSION}")
1085         ENDIF(XCODE_VERSION VERSION_LESS "5.0")
1086 ENDIF(CMAKE_GENERATOR MATCHES Xcode)
1087
1088 if (WIN32 AND Qt5Core_FOUND)
1089         set(Z_PREFIX 1)
1090 endif()
1091
1092 # compiler tests, config.h generation LYX_CONFIGURE_CHECKS
1093 include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
1094 configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
1095
1096 unset(opts)
1097 foreach(_option ${LYX_OPTIONS})
1098   if(${_option}_show_message)
1099     string(SUBSTRING "${_option}                            " 0 31 _var)
1100     get_property(_prop CACHE ${_option} PROPERTY STRINGS)
1101     list(FIND LYX_OPTION_STRINGS ${_option} _index)
1102     if (${_index} GREATER -1)
1103       set(_isset ${${_option}})
1104     elseif(${_option})
1105       set(_isset ON)
1106     else()
1107       set(_isset OFF)
1108     endif()
1109     string(SUBSTRING "${_isset}           " 0 10 _val)
1110     set(opts "${opts} ${_option}(${${_option}})")
1111   endif()
1112 endforeach()
1113 set(tmp_vi "CMake Build")
1114 list(APPEND tmp_vi "  Host name:               ${CMAKE_HOST_SYSTEM_NAME}")
1115 list(APPEND tmp_vi "  Host processor:          ${CMAKE_HOST_SYSTEM_PROCESSOR}")
1116 list(APPEND tmp_vi "  Build flags:             ${opts}")
1117 list(APPEND tmp_vi "  C++ Compiler:            ${CMAKE_CXX_COMPILER_ID} (${CMAKE_CXX_COMPILER_VERSION})")
1118 list(APPEND tmp_vi "  C++ Compiler flags:      ${CMAKE_CXX_FLAGS}")
1119 if (LYX_DEBUG)
1120 list(APPEND tmp_vi "  C++ Compiler user flags: ${CMAKE_CXX_FLAGS_DEBUG}")
1121 else()
1122 list(APPEND tmp_vi "  C++ Compiler user flags: ${CMAKE_CXX_FLAGS_RELEASE}")
1123 endif()
1124 list(APPEND tmp_vi "  Qt version:              ${QTVERSION}")
1125 list(APPEND tmp_vi "  LyX binary dir:          ${CMAKE_INSTALL_PREFIX}/${LYX_UTILITIES_INSTALL_PATH}")
1126 get_data_destination(dest_data)
1127 list(APPEND tmp_vi "  LyX files dir:           ${CMAKE_INSTALL_PREFIX}/${dest_data}")
1128 string(REPLACE ";" "\\n" VERSION_INFO "${tmp_vi}")
1129
1130 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
1131 unset(opts)
1132 unset(tmp_vi)
1133
1134 if(QTVERSION MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+).*")
1135         MATH(EXPR QT4_VERSION "(${CMAKE_MATCH_1}<<16)|(${CMAKE_MATCH_2}<<8)|${CMAKE_MATCH_3}")
1136 endif()
1137
1138 if (NOT HAVE_REGEX)
1139         set(LYX_USE_STD_REGEX 0)
1140 endif()
1141
1142
1143 set (cmd ${CMAKE_CTEST_COMMAND})
1144 if (MSVC)
1145         set (cmd ${cmd} -C ${CMAKE_CFG_INTDIR})
1146 else ()
1147         set (cmd ${cmd} -C ${CMAKE_BUILD_TYPE})
1148 endif ()
1149 add_custom_target (lyx_run_tests COMMAND ${cmd})
1150 set_target_properties(lyx_run_tests PROPERTIES FOLDER "tests")
1151
1152 if(LYX_ASAN)
1153     set(LYX_CXX_FLAGS "-fsanitize=address -fno-omit-frame-pointer -g")
1154     message(STATUS)
1155     message(STATUS "Address sanitizer enabled. Usage:")
1156     message(STATUS "    wget https://llvm.org/svn/llvm-project/compiler-rt/trunk/lib/asan/scripts/asan_symbolize.py")
1157     message(STATUS "    chmod  +x ./asan_symbolize.py")
1158     message(STATUS "    ./bin/lyx2.2 2>&1 | ./asan_symbolize.py  | c++filt ")
1159     message(STATUS)
1160 endif()
1161
1162 if(LYX_INSTALL)
1163         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
1164                 message(STATUS "Python required to create doc!")
1165         else()
1166                 if(UNIX)
1167                         add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
1168                 endif()
1169                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
1170         endif()
1171 endif()
1172 include(../Install)
1173
1174 # By running the URL tests first, time can be saved when running the ctests in
1175 # parallel since the URL tests take a long time to run (e.g. 10 minutes).
1176 if(LYX_ENABLE_URLTESTS)
1177         add_subdirectory(development/checkurls "${TOP_BINARY_DIR}/checkurls")
1178 endif()
1179 add_subdirectory(src "${TOP_BINARY_DIR}/src")
1180 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
1181 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
1182 add_subdirectory(lib/examples "${TOP_BINARY_DIR}/lib/examples")
1183 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
1184 add_subdirectory(development/autotests "${TOP_BINARY_DIR}/autotests")
1185 add_subdirectory(development/batchtests "${TOP_BINARY_DIR}/batchtests")
1186
1187 message(STATUS)
1188 message(STATUS "Build params, switch LYX_* options by -DLYX_*=ON or OFF, LYX_* combos by -DLYX_*=value:")
1189 message(STATUS)
1190
1191 LYX_OPTION_LIST_ALL(used)
1192
1193
1194 if(LYX_NLS)
1195         message(STATUS)
1196         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
1197         message(STATUS)
1198         message(STATUS "  * iconv")
1199         message(STATUS "     - include: ${ICONV_INCLUDE_DIR}")
1200         message(STATUS "     - library: ${ICONV_LIBRARY}")
1201         message(STATUS "  * zlib")
1202         message(STATUS "     - include: ${ZLIB_INCLUDE_DIR}")
1203         message(STATUS "     - library: ${ZLIB_LIBRARY}")
1204         message(STATUS)
1205 endif()
1206
1207 # Apple has builtin native spell checker,
1208 # no need to warn for missing Aspell, Hunspell or Enchant
1209 if(NOT Spelling_FOUND AND NOT APPLE)
1210   if(LYX_REQUIRE_SPELLCHECK)
1211     set(_mode "FATAL_ERROR")
1212   else()
1213     set(_mode "STATUS")
1214   endif()
1215   message(${_mode} "No spellcheck libraries found. LyX will be unable use spellchecking")
1216 endif()
1217
1218 include("${TOP_CMAKE_PATH}/LyxPackaging.cmake")
1219
1220 if(ENABLE_DIST)
1221   # Use git to create the source package
1222   # git archive --format=tgz --output=/home/kornel/x.tar.gz master
1223   if(UNIX)
1224     set(DIST_FORMAT tgz)
1225   else()
1226     set(DIST_FORMAT zip)
1227   endif()
1228   set(DIST_NAME ${CMAKE_PROJECT_NAME}-${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}-${CMAKE_SYSTEM_NAME}.${DIST_FORMAT})
1229
1230   add_custom_command(
1231     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME}
1232     COMMAND  ${LYX_GITVERSION} archive --format=${DIST_FORMAT} --output=${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME} master
1233     WORKING_DIRECTORY ${TOP_SRC_DIR})
1234   add_custom_target(git-archive DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME})
1235 endif()
1236
1237 # Last directory to be included so that the fixup code (OS X)
1238 # can be run last
1239 add_subdirectory(development/cmake/post_install)
1240
1241 message(STATUS)