CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 2.6.4)
   8
   9 set(LYX_PROJECT LyX)
  10
  11 enable_testing()
  12
  13 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README REALPATH) # Resolve symlinks
  14 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  15 message(STATUS "TOP_SRC_DIR = ${TOP_SRC_DIR}")
  16
  17 set(LYX_CMAKE_DIR "development/cmake")
  18 set(TOP_CMAKE_PATH "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}")
  19 set(TOP_MODULE_PATH "${TOP_CMAKE_PATH}/modules")
  20 set(TOP_SCRIPT_PATH "${TOP_CMAKE_PATH}/scripts")
  21
  22 set(CMAKE_MODULE_PATH "${TOP_MODULE_PATH}")
  23
  24 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  25
  26 message(STATUS)
  27 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  28         message(STATUS "Building in-source")
  29         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  30 else()
  31         message(STATUS "Building out-of-source")
  32         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  33 endif()
  34
  35 # This directory should be used if some test uses lyx-executable
  36 set(LYX_TESTS_USERDIR "${TOP_BINARY_DIR}/Testing/.lyx")
  37 file(MAKE_DIRECTORY "${LYX_TESTS_USERDIR}")
  38
  39 if(COMMAND cmake_policy)
  40         cmake_policy(SET CMP0003 OLD)
  41         cmake_policy(SET CMP0005 OLD)
  42         # Installing MACOSX_BUNDLE targets requires a BUNDLE DESTINATION
  43         cmake_policy(SET CMP0006 NEW)
  44         if(POLICY CMP0020)
  45                 cmake_policy(SET CMP0020 OLD)
  46         endif()
  47         if(POLICY CMP0028)
  48                 cmake_policy(SET CMP0028 OLD)
  49         endif()
  50         if(POLICY CMP0043)
  51                 # COMPILE_DEFINITIONS are not used yet. Enable new behavior.
  52                 cmake_policy(SET CMP0043 NEW)
  53         endif()
  54 endif()
  55
  56 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  57
  58 # Supress regeneration
  59 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  60
  61 if(LYX_XMINGW)
  62     set(CMAKE_SYSTEM_NAME Windows)
  63     set(TOOLNAME ${LYX_XMINGW})
  64     set(TOOLCHAIN "${TOOLNAME}-")
  65     set(CMAKE_C_COMPILER   "${TOOLCHAIN}gcc"     CACHE PATH "Mingw C compiler" FORCE)
  66     set(CMAKE_CXX_COMPILER "${TOOLCHAIN}g++"     CACHE PATH "Mingw C++ compiler" FORCE)
  67     set(CMAKE_RC_COMPILER  "${TOOLCHAIN}windres" CACHE PATH "Mingw rc compiler" FORCE)
  68
  69     set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM BOTH)
  70     set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY)
  71     set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY)
  72 endif()
  73
  74 if(NOT help AND NOT HELP)
  75   # 'project' triggers the searching for a compiler
  76   project(${LYX_PROJECT})
  77   if (CMAKE_COMPILER_IS_GNUCXX)
  78     if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS "4.0")
  79       message(STATUS "Gnu CXX compiler version = ${CMAKE_CXX_COMPILER_VERSION}")
  80       message(STATUS "is too old, should be >= 4.0")
  81       message(FATAL_ERROR "Exiting")
  82     endif()
  83   endif()
  84 endif()
  85
  86 if(UNIX)
  87         set(ARCH_TRIPLET )
  88         FIND_PROGRAM(DPKG_ARCHITECTURE_EXECUTABLE dpkg-architecture)
  89         if(DPKG_ARCHITECTURE_EXECUTABLE)
  90                 EXECUTE_PROCESS(COMMAND ${DPKG_ARCHITECTURE_EXECUTABLE} -qDEB_HOST_MULTIARCH
  91                                 OUTPUT_VARIABLE ARCH_TRIPLET
  92                                 ERROR_VARIABLE ERROR_ARCH_TRIPLET
  93                                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  94         endif()
  95 endif()
  96 if(ARCH_TRIPLET)
  97         set(SYSTEM_LIB_DIRS /usr/lib /usr/lib/${ARCH_TRIPLET} /usr/local/lib)
  98 else()
  99         set(SYSTEM_LIB_DIRS /usr/lib /usr/local/lib)
 100 endif()
 101
 102 include(LyXMacros)
 103
 104 # Usage LYX_OPTION
 105 # 1. parameter: option name without prefix 'LYX_'
 106 # 2. parameter: description
 107 # 3. parameter: default value, ON or OFF
 108 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
 109
 110 # Usage LYX_COMBO
 111 # 1. parameter: name without prefix 'LYX_'
 112 # 2. parameter: description
 113 # 3. parameter: default value
 114 # 4-n parameter: possible other string values
 115
 116 LYX_OPTION_INIT()
 117
 118 # Options for all compilers/systems
 119 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
 120 LYX_OPTION(LOCALVERSIONING  "Add version info to created package name (only used if LYX_CPACK option set)" OFF ALL)
 121 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
 122 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
 123 LYX_OPTION(REQUIRE_SPELLCHECK "Abort if no spellchecker available" OFF ALL)
 124 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
 125 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
 126 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
 127 LYX_OPTION(DEVEL_VERSION    "Build developer version" OFF ALL)
 128 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" OFF ALL)
 129 LYX_OPTION(DEBUG            "Enforce debug build"  OFF ALL)
 130 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
 131 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
 132 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
 133 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
 134 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
 135 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
 136 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
 137 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
 138 LYX_OPTION(ENABLE_URLTESTS  "Enable for URL tests" OFF ALL)
 139 LYX_OPTION(ENABLE_EXPORT_TESTS "Enable for export tests" OFF ALL)
 140 LYX_OPTION(ASAN             "Use address sanitizer" OFF ALL)
 141 LYX_COMBO(USE_QT            "Use Qt version as frontend" QT4 QT5)
 142 LYX_OPTION(3RDPARTY_BUILD   "Build 3rdparty libs" OFF ALL)
 143
 144 # GCC specific
 145 LYX_OPTION(PROFILE              "Build profile version" OFF GCC)
 146 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" OFF GCC)
 147 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
 148 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
 149 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++ pedantic debug mode" OFF GCC)
 150 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" OFF GCC)
 151 LYX_OPTION(PROFILE              "Build with options for gprof" OFF GCC)
 152 LYX_OPTION(ENABLE_CXX11         "Build with options for c++11-mode" OFF GCC)
 153
 154 # MSVC specific
 155 LYX_OPTION(CONSOLE               "Show console on Windows, enforce with =FORCE" ON MSVC)
 156 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
 157 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
 158 LYX_OPTION(CONFIGURE_CHECKS      "Also run configure checks for MSVC" OFF MSVC)
 159 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
 160 LYX_OPTION(3RDPARTY_BUILD        "Build 3rdparty libraries " OFF MSVC)
 161
 162 # APPLE specific
 163 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
 164 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
 165
 166
 167 if(help OR HELP)
 168         message(STATUS)
 169         message(STATUS "Available options: (dis/enable with -DLYX_*=OFF/ON)")
 170         message(STATUS)
 171         LYX_OPTION_LIST_ALL(help)
 172         message(STATUS)
 173         RETURN()
 174 endif()
 175
 176 # Check option dependencies
 177
 178 if(LYX_DMG)
 179         set(LYX_BUNDLE ON)
 180         set(LYX_CPACK ON)
 181 endif()
 182
 183 if(LYX_CPACK)
 184         set(LYX_INSTALL ON)
 185 endif()
 186
 187 if(LYX_INSTALL)
 188         set(LYX_NLS ON)
 189         if(WIN32 AND NOT MINGW)
 190                 set(LYX_HUNSPELL ON)
 191         endif()
 192         if(LYX_CONSOLE MATCHES "FORCE")
 193                 set(LYX_CONSOLE ON)
 194         else()
 195                 set(LYX_CONSOLE OFF)
 196         endif()
 197         set(LYX_PACKAGE_SUFFIX ON)
 198         if(NOT LYX_DEBUG)
 199                 set(LYX_RELEASE ON)
 200         endif()
 201         set(LYX_PROFILE OFF)
 202 endif()
 203
 204
 205 if(LYX_MERGE_FILES)
 206         set(LYX_PCH OFF)
 207 else()
 208         set(LYX_MERGE_REBUILD OFF)
 209 endif()
 210
 211
 212 if(LYX_DEPENDENCIES_DOWNLOAD)
 213         message(STATUS)
 214     if(MSVC12)
 215         set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2013-deps)
 216         set(deps_files lyx-windows-deps-msvc2013.zip)
 217         set(deps_server http://ftp.lyx.de/LyX-Windows-Deps)
 218         set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2013)
 219     else()
 220         set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 221             set(deps_files lyx20-deps-msvc2010-x86.zip)
 222             set(deps_server http://downloads.sourceforge.net/project/lyx/Win_installers/Dependencies)
 223         set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/deps20)
 224     endif()
 225     message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 226         foreach(it ${deps_files})
 227                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 228                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 229                 if(NOT already_downloaded)
 230                         message(STATUS "Downloading ${it} ...")
 231                         file(DOWNLOAD ${deps_server}/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS STATUS status LOG log)
 232                         list(GET status 0 status_code)
 233                         list(GET status 1 status_string)
 234                         if(NOT status_code EQUAL 0)
 235                                 file(REMOVE ${LYX_DEPENDENCIES_DIR}/${it})
 236                                 message(FATAL_ERROR "error: downloading '${it}' failed. status_code: ${status_code}, status_string: ${status_string}. \nLog: ${log} ")
 237                         endif()
 238                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 239                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 240                 endif()
 241         endforeach()
 242 endif()
 243
 244
 245
 246 message(STATUS)
 247
 248 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 249 if(WIN32)
 250         set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 251 else()
 252         set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 253 endif()
 254
 255
 256 set(LYX_GCC11_MODE)
 257 if(UNIX OR MINGW)
 258         execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION OUTPUT_STRIP_TRAILING_WHITESPACE)
 259         message(STATUS "Using GCC version ${GCC_VERSION}")
 260         if(GCC_VERSION VERSION_LESS 4.9)
 261                 # <regex> in gcc is unusable in versions less than 4.9.0
 262                 # see https://gcc.gnu.org/bugzilla/show_bug.cgi?id=53631
 263                 set(LYX_USE_STD_REGEX 0)
 264         else()
 265                 if (LYX_ENABLE_CXX11)
 266                         set(LYX_USE_STD_REGEX 1)
 267                 endif()
 268         endif()
 269         if (LYX_ENABLE_CXX11)
 270                 find_package(CXX11Compiler)
 271                 if(NOT CXX11COMPILER_FOUND)
 272                         message(FATAL_ERROR "A C++11 compatible compiler is required.")
 273                 endif()
 274                 set(LYX_GCC11_MODE "${CXX11_FLAG}")
 275         endif()
 276 else()
 277         set(LYX_USE_STD_REGEX 0)
 278 #       if(MSVC10)
 279 #               set(LYX_USE_STD_REGEX 1) #TODO should we use it in ECMAScript mode?
 280 #       endif()
 281 endif()
 282
 283
 284 set(VERSION_INFO "CMake Build")
 285
 286 # Try to get some informations from configure.ac
 287
 288 include(LyXPaths)
 289 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 290
 291 if(WIN32)
 292         if(MSVC)
 293                 set(LYX_3RDPARTY_BUILD ON)
 294         endif()
 295         set(USE_WINDOWS_PACKAGING ON)
 296 elseif(APPLE)
 297         set(USE_MACOSX_PACKAGING ON)
 298 else()
 299         set(USE_POSIX_PACKAGING ON)
 300 endif()
 301
 302 macro(setstripped _varname)
 303         if(${ARGC} GREATER 1)
 304                 string(STRIP "${ARGV1}" _v)
 305                 if(USE_POSIX_PACKAGING)
 306                         string(TOLOWER ${_v} ${_varname})
 307                 else()
 308                         set(${_varname} ${_v})
 309                 endif()
 310         else()
 311                 set(${_varname})
 312         endif()
 313 endmacro(setstripped)
 314
 315 foreach(_c_l ${_config_lines} )
 316         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 317                 setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 318                 setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 319                 setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 320                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\)\(\\.\([0-9]+\)\)?.*$")
 321                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 322                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 323                         set(LYX_PATCH_VERSION ${CMAKE_MATCH_4})
 324                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 325                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 326                         set(LYX_INSTALL_SUFFIX "${CMAKE_MATCH_1}.${CMAKE_MATCH_2}")
 327                 endif()
 328         endif()
 329         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 330                 set(LYX_DATE "${CMAKE_MATCH_1}")
 331         endif()
 332 endforeach(_c_l)
 333
 334 FIND_PROGRAM(LYX_GITVERSION git)
 335 #message(STATUS "gitversion = ${LYX_GITVERSION}")
 336 set(LYX_REVISION_VERSION ${LYX_PATCH_VERSION})
 337 if(LYX_GITVERSION)
 338   if (LYX_LOCALVERSIONING)
 339     # Find the revision number and for later use
 340     EXECUTE_PROCESS(COMMAND ${LYX_GITVERSION} describe --match 2.0.0 HEAD
 341       WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE LYX_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 342     if (LYX_PACKAGE_RELEASE MATCHES "^2\\.0\\.0\\-\([0-9]+\)\\-.*$")
 343       # We will add offset of 40000 to get appropriate value to
 344       # previous svn.
 345       # We use this value than also to set the package-patch-value
 346       MATH(EXPR tmp_REVISION_VERSION "(${CMAKE_MATCH_1}+40000)")
 347       set(LYX_REVISION_VERSION "${LYX_PATCH_VERSION}-${tmp_REVISION_VERSION}git")
 348       set(ENABLE_DIST ON)
 349     endif()
 350   endif()
 351 endif()
 352
 353 # Set the programs (lyx, tex2lyx, etc.) suffix
 354 # When building an OS X bundle, we will append
 355 # the suffix only to the bundle, not to the programs
 356 set(PROGRAM_SUFFIX "")
 357 if(LYX_PROGRAM_SUFFIX AND NOT (APPLE AND LYX_BUNDLE))
 358         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 359 endif()
 360 set(_lyx "${PACKAGE_BASE}${PROGRAM_SUFFIX}")
 361 set(_tex2lyx tex2lyx${PROGRAM_SUFFIX})
 362
 363 add_custom_target(lyx_version ALL
 364   COMMAND ${CMAKE_COMMAND} -DTOP_SRC_DIR=${TOP_SRC_DIR} -DTOP_CMAKE_PATH=${TOP_CMAKE_PATH} -DTOP_BINARY_DIR=${TOP_BINARY_DIR} -DLYX_DATE=${LYX_DATE} -P ${TOP_SCRIPT_PATH}/LyXGetVersion.cmake
 365   )
 366 set_target_properties(lyx_version PROPERTIES FOLDER "applications")
 367
 368 # Default paths for installed utilities (tex2lyx, lyxclient, etc.)
 369 set(LYX_UTILITIES_INSTALL_PATH bin)
 370
 371 if(LYX_BUNDLE)
 372         set(LYX_CPACK ON)
 373
 374         message(STATUS)
 375         message(STATUS "Bundle creation is enabled (experimental):")
 376         message(STATUS "    make")
 377         message(STATUS "    make install/strip")
 378         message(STATUS "    make package")
 379         if(APPLE)
 380                 set(MACOSX_BUNDLE TRUE)
 381                 # This sets the bundle + executable names
 382                 set(_lyx "${PACKAGE_BASE}${LYX_INSTALL_SUFFIX}")
 383                 # This sets the Info.plist executable name
 384                 set(osx_bundle_program_name ${_lyx})
 385                 # Bundle name
 386                 set(LYX_BUNDLE_NAME ${_lyx})
 387
 388                 # This will contain the list of files that need to be included
 389                 # in the bundle and their location within the bundle
 390                 set(OSX_BUNDLE_FILES "${TOP_SRC_DIR}/development/MacOSX/LyX.sdef;${TOP_SRC_DIR}/development/MacOSX/LyXapp.icns;${CMAKE_BINARY_DIR}/lyxrc.dist")
 391                 set(OSX_BUNDLE_DIRS "Resources;Resources;Resources")
 392
 393                 # Process Info.plist and lyxrc.dist
 394                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/Info.plist.in" "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 395                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/lyxrc.dist.in" "${CMAKE_CURRENT_BINARY_DIR}/lyxrc.dist")
 396
 397                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 398                 set(LYX_DATA_SUBDIR ${LYX_BUNDLE_NAME}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 399
 400                 # Variables used by CPack
 401                 set(CPACK_BUNDLE_NAME ${LYX_BUNDLE_NAME})
 402                 set(CPACK_BUNDLE_PLIST "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 403                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${LYX_BUNDLE_NAME}.app)
 404
 405                 # Set the install paths
 406                 set(LYX_UTILITIES_INSTALL_PATH ${LYX_BUNDLE_NAME}.app/Contents/MacOS)
 407                 if(NOT LYX_INSTALL_PREFIX)
 408                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 409                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 410                 endif()
 411                 # Change the owner so that the install can work
 412                 install(CODE "set(BU_CHMOD_BUNDLE_ITEMS 1)" COMPONENT Runtime)
 413         elseif(UNIX)
 414                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 415                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 416                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 417         elseif(WIN32)
 418                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 419         endif()
 420 endif()
 421
 422 if(LYX_INSTALL_PREFIX)
 423         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 424         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 425 endif()
 426 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 427
 428 string(REGEX REPLACE "/lyx${LYX_INSTALL_SUFFIX}$" "/share" SYSTEM_DATADIR ${CMAKE_INSTALL_PREFIX})
 429
 430 if(LYX_PACKAGE_SUFFIX)
 431         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 432 else()
 433         set(PACKAGE ${PACKAGE_BASE})
 434 endif()
 435
 436 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 437         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 438         if (UNIX)
 439                 # don't use the default "/usr/local"
 440                 # but respect the user-choice on the command-line
 441                 if(LYX_INSTALL_SUFFIX)
 442                         set(CMAKE_INSTALL_PREFIX "/usr/local/lyx${LYX_INSTALL_SUFFIX}" CACHE PATH "LyX default install prefix" FORCE)
 443                 else()
 444                         set(CMAKE_INSTALL_PREFIX "/usr/local/${LYX_PROJECT}" CACHE PATH "LyX default install prefix" FORCE)
 445                 endif()
 446         endif()
 447         if(WIN32)
 448                 set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 449         endif()
 450 endif()
 451 if(IS_ABSOLUTE)
 452         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 453 else()
 454         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 455 endif()
 456
 457
 458
 459 if(NOT LYX_DATA_SUBDIR)
 460         if (WIN32)
 461                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 462         else()
 463                 set(LYX_DATA_SUBDIR "" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 464         endif()
 465 endif()
 466
 467 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 468 set(LYX_LOCALEDIR "locale")
 469 set(LYX_ABS_INSTALLED_LOCALEDIR "${LYX_ABS_INSTALLED_DATADIR}/${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}")
 470 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 471
 472 if(LYX_BUNDLE AND APPLE)
 473         set(LYX_MAN_DIR "${LYX_DATA_SUBDIR}" CACHE STRING "Install location for man pages.")
 474 else()
 475         set(LYX_MAN_DIR "/usr/local/man/man1" CACHE STRING "Install location for man pages.")
 476 endif()
 477 mark_as_advanced(LYX_MAN_DIR)
 478
 479 if(LYX_INSTALL AND WIN32)
 480         message(STATUS "Configuring NSIS files")
 481         configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 482         configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 483         configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 484         message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 485 endif()
 486
 487 if(NOT GROUP_CODE)
 488         #set(GROUP_CODE "The Golden Code")
 489         set(GROUP_CODE flat)
 490 endif()
 491
 492 # lyx's source files
 493 set(LYX_CPP_FILES [a-zA-Z]*.cpp)
 494 set(LYX_HPP_FILES [a-zA-Z]*.h)
 495 set(LYX_MOC_FILES moc_*.cpp)
 496
 497 include(ProjectSourceGroup)
 498
 499
 500 if(LYX_PROFILE AND NOT MSVC)
 501         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 502         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg")
 503         set(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS}  -pg")
 504 else()
 505         set(LYX_PROFILE OFF)
 506 endif()
 507
 508
 509 if(LYX_NO_OPTIMIZE)
 510         set(CMAKE_BUILD_TYPE None)
 511         set(LYX_DEBUG OFF)
 512         set(LYX_RELEASE OFF)
 513         set(LYX_PROFILE OFF)
 514 elseif(LYX_RELEASE)
 515         set(CMAKE_BUILD_TYPE Release)
 516         set(LYX_DEBUG OFF)
 517         set(LYX_PROFILE OFF)
 518 elseif(LYX_PROFILE)
 519         set(CMAKE_BUILD_TYPE Profile)
 520         set(LYX_DEBUG OFF)
 521 else()
 522         set(CMAKE_BUILD_TYPE Debug)
 523         set(LYX_DEBUG ON)
 524 endif()
 525
 526
 527 # When shared libs are supported enable this option
 528 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 529 if(LYX_SHARED_LIBRARIES)
 530         set(library_type SHARED)
 531 else()
 532         set(library_type STATIC)
 533 endif()
 534
 535 if(NOT MSVC)
 536         if(NOT LYX_QUIET)
 537                 set(CMAKE_VERBOSE_MAKEFILE ON)
 538         endif()
 539     set(LYX_CXX_FLAGS "-Wall -Wunused-parameter ${LYX_GCC11_MODE}")
 540         if(LYX_STDLIB_DEBUG)
 541                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 542         endif()
 543         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 544         set(CMAKE_CXX_FLAGS_DEBUG "${LYX_CXX_FLAGS} -fno-strict-aliasing -O0 -g3 -D_DEBUG" CACHE TYPE STRING FORCE)
 545         if(MINGW)
 546                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 547         else()
 548                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 549         endif()
 550 endif()
 551
 552 set(LYX_CXX_FLAGS_EXTRA "" CACHE STRING "Desired semicolon separated list of extra cxx compile flags, like '-Werror'")
 553 mark_as_advanced(LYX_CXX_FLAGS_EXTRA)
 554 if(LYX_CXX_FLAGS_EXTRA)
 555         foreach(_flag ${LYX_CXX_FLAGS_EXTRA})
 556                 add_definitions(${_flag})
 557         endforeach()
 558 endif()
 559
 560 if(LYX_XMINGW)
 561         list(APPEND CMAKE_FIND_ROOT_PATH ${GNUWIN32_DIR})
 562 endif()
 563
 564 if(LYX_USE_QT MATCHES "QT5")
 565         find_package(Qt5Core REQUIRED)
 566         if (Qt5Core_FOUND)
 567                 find_package(Qt5Widgets REQUIRED)
 568                 if(APPLE)
 569                         find_package(Qt5MacExtras REQUIRED)
 570                 endif()
 571                 find_package(Qt5X11Extras QUIET)
 572                 find_package(Qt5WinExtras QUIET)
 573                 set(QTVERSION ${Qt5Core_VERSION})
 574                 macro (qt_use_modules)
 575                         qt5_use_modules(${ARGN})
 576                 endmacro()
 577                 macro (qt_add_resources)
 578                         qt5_add_resources(${ARGN})
 579                 endmacro()
 580                 macro (qt_wrap_uifiles)
 581                         qt5_wrap_ui(${ARGN})
 582                 endmacro()
 583                 message(STATUS "Found Qt-Version ${QTVERSION}")
 584                 if(WIN32)
 585                         set(LYX_QTMAIN_LIBRARY ${Qt5Core_QTMAIN_LIBRARIES})
 586                 endif()
 587         endif()
 588 elseif(LYX_USE_QT MATCHES "QT4")
 589         if(LYX_XMINGW)
 590                 set(QT_MINGW_DIR ${LYX_QT4} CACHE PATH "Qt for Mingw" FORCE)
 591                 list(APPEND CMAKE_FIND_ROOT_PATH ${QT_MINGW_DIR} ${GNUWIN32_DIR})
 592         endif()
 593         find_package(Qt4 "4.5.0" REQUIRED)
 594         macro (qt_use_modules)
 595         endmacro()
 596         macro (qt_add_resources)
 597                 qt4_add_resources(${ARGN})
 598         endmacro()
 599         macro (qt_wrap_uifiles)
 600                 qt4_wrap_ui(${ARGN})
 601         endmacro()
 602         if(WIN32)
 603                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARIES})
 604         endif()
 605 else()
 606   message(FATAL_ERROR "Unhandled value for LYX_USE_QT (${LYX_USE_QT})")
 607 endif()
 608
 609 find_package(Magic)
 610 if(Magic_FOUND)
 611         set(HAVE_MAGIC_H 1)
 612 endif()
 613
 614 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 615
 616 set(Spelling_FOUND OFF)
 617 set(Include_used_spellchecker)   # String will be inserted into config.h
 618
 619 if(LYX_3RDPARTY_BUILD)
 620     add_subdirectory(3rdparty/hunspell)
 621     add_definitions(-DHUNSPELL_STATIC)
 622     set(HUNSPELL_FOUND ON)
 623     message(STATUS "  * Hunspell:")
 624     message(STATUS "     - include: ${HUNSPELL_INCLUDE_DIR}")
 625     message(STATUS "     - library: ${HUNSPELL_LIBRARY}")
 626 endif()
 627
 628 foreach(_spell "ASPELL" "Enchant" "Hunspell")
 629   string(TOUPPER ${_spell} _upspell)
 630   if (NOT ${_upspell}_FOUND)
 631     find_package(${_spell})
 632   endif()
 633   if (${_upspell}_FOUND)
 634     include_directories(${${_upspell}_INCLUDE_DIR})
 635     set(Spelling_FOUND ON)
 636     message(STATUS "Building with USE_${_upspell}")
 637     set(Include_used_spellchecker "${Include_used_spellchecker}#define USE_${_upspell} 1\n")
 638   else()
 639     if(LYX_${_upspell})
 640       message(FATAL_ERROR "Required ${_spell} devel package not found")
 641     else()
 642       message(STATUS "${_upspell} not found, building without ${_spell} support")
 643     endif()
 644   endif()
 645 endforeach()
 646
 647 if(NOT LYX_PYTHON_EXECUTABLE)
 648         find_package(PythonInterp 2.7 QUIET)
 649         if(PYTHONINTERP_FOUND)
 650           if(PYTHON_VERSION_STRING VERSION_GREATER 2.8)
 651                 unset(PYTHONINTERP_FOUND)
 652           endif()
 653         endif()
 654
 655         if(NOT PYTHONINTERP_FOUND AND NOT GNUWIN32_DIR)
 656           unset(PYTHON_EXECUTABLE CACHE)
 657           unset(PYTHON_VERSION_MAJOR)
 658           unset(PYTHON_VERSION_MINOR)
 659           unset(PYTHON_VERSION_STRING)
 660           find_package(PythonInterp 3.3 REQUIRED)
 661         endif()
 662
 663         set(LYX_PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 664 endif()
 665
 666 if(LYX_NLS)
 667         find_package(LyXGettext)
 668         if(LYX_PYTHON_EXECUTABLE AND GETTEXT_FOUND)
 669                 add_subdirectory(po "${TOP_BINARY_DIR}/po")
 670         else()
 671                 # Install only supplied .gmo-files
 672                 file(GLOB _gmofiles RELATIVE "${TOP_SRC_DIR}/po" "${TOP_SRC_DIR}/po/*.gmo")
 673                 message(STATUS "Installing provided .gmo-files only")
 674                 foreach( _gmo ${_gmofiles})
 675                         string(REGEX REPLACE "\\.gmo$" "" _lang ${_gmo})
 676                         install(FILES "${TOP_SRC_DIR}/po/${_gmo}" DESTINATION ${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}/${_lang}/LC_MESSAGES RENAME ${PACKAGE}.mo)
 677                 endforeach()
 678         endif()
 679 endif()
 680
 681 if(UNIX)
 682     find_package(ICONV REQUIRED)
 683     find_package(ZLIB REQUIRED)
 684 else()
 685     if(LYX_3RDPARTY_BUILD)
 686         add_subdirectory(3rdparty/libiconv)
 687         set(HAVE_ICONV_CONST 1)
 688         add_subdirectory(3rdparty/zlib)
 689     endif()
 690 endif()
 691
 692 if(LYX_EXTERNAL_BOOST)
 693         message(STATUS "Searching for boost")
 694         if(LYX_USE_STD_REGEX)
 695                 find_package(Boost COMPONENTS signals)
 696         else()
 697                 find_package(Boost COMPONENTS signals regex)
 698         endif()
 699         if(Boost_FOUND)
 700                 message(STATUS "Boost found")
 701                 message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 702                 set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 703                 if (LYX_STDLIB_DEBUG)
 704                         # Comment from  Jean-Marc Lasgouttes:
 705                         # In general, system boost libraries are incompatible with
 706                         # the use of stdlib-debug in libstdc++. See ticket #9736 for
 707                         # details.
 708                         message(WARNING "Compiling LyX with stdlib-debug and system boost libraries may lead to crashes. Consider using '-DLYX_STDLIB_DEBUG=OFF' or using '-DLYX_EXTERNAL_BOOST=OFF'")
 709                 endif()
 710         else()
 711                 message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 712         endif()
 713 else()
 714         if(LYX_USE_STD_REGEX)
 715                 set(Lyx_Boost_Libraries boost_signals)
 716         else()
 717                 set(Lyx_Boost_Libraries boost_signals boost_regex)
 718         endif()
 719         add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 720         add_definitions(-DBOOST_SIGNALS_NO_DEPRECATION_WARNING=1)
 721         include_directories(${TOP_SRC_DIR}/3rdparty/boost)
 722         add_subdirectory(3rdparty/boost "${TOP_BINARY_DIR}/3rdparty/boost")
 723 endif()
 724
 725
 726
 727
 728 if(WIN32)
 729         if(LYX_CONSOLE)
 730                 set(LYX_QTMAIN_LIBRARY)
 731         else()
 732                 set(WIN32_CONSOLE WIN32)
 733         endif()
 734         if(MSVC)
 735                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 736                 # disable checked iterators for msvc release builds to get maximum speed
 737                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 738         else()
 739                 add_definitions(-DWINVER=0x0500)
 740         endif()
 741 endif()
 742
 743 # Compute qt4-version from ${QTVERSION}
 744
 745 message(STATUS "")
 746 foreach(_v PACKAGE PACKAGE_VERSION
 747         PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 748         LYX_ABS_TOP_SRCDIR
 749         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 750         if(NOT DEFINED ${_v})
 751                 message(FATAL_ERROR "${_v} not defined")
 752         endif()
 753         string(SUBSTRING "${_v}                            " 0 28 _v1)
 754         message(STATUS "----- ${_v1}: ${${_v}}")
 755 endforeach(_v)
 756 message(STATUS "")
 757
 758
 759 if(LYX_PCH)
 760         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 761         # Not sure if it works for all non-msvc compilers
 762         include(PCHSupport_26)
 763         configure_file(${TOP_CMAKE_PATH}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
 764         configure_file(${TOP_CMAKE_PATH}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 765         add_definitions(-DLYX_ENABLE_PCH)
 766
 767         if(MSVC)
 768                 macro(lyx_add_msvc_pch name_)
 769                         set_source_files_properties(${${name_}_sources} PROPERTIES
 770                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 771                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
 772                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 773                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
 774                                 ${TOP_BINARY_DIR}/pcheaders.h)
 775                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 776                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 777                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 778                 endmacro(lyx_add_msvc_pch)
 779                 macro(lyx_add_gcc_pch name_)
 780                 endmacro()
 781         else()
 782                 macro(lyx_add_msvc_pch name_)
 783                 endmacro()
 784                 macro(lyx_add_gcc_pch name_)
 785                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT)
 786                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
 787                 endmacro()
 788         endif()
 789 else()
 790         macro(lyx_add_msvc_pch)
 791         endmacro(lyx_add_msvc_pch)
 792         macro(lyx_add_gcc_pch name_)
 793         endmacro()
 794 endif()
 795
 796
 797 if(MSVC)
 798
 799         if(LYX_VLD)
 800                 set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/development/Win32/vld)
 801                 add_subdirectory(${vld_path}/cmake)
 802                 include(${vld_path}/cmake/vld.cmake) # forced include
 803                 set(vld_dll vld)
 804         endif()
 805
 806         if(LYX_WALL)
 807                 # Use the highest warning level
 808                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 809
 810                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 811                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 812                 else()
 813                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 814                 endif()
 815
 816                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 817                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 818                 else()
 819                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 820                 endif()
 821
 822                 # add here warnings which should produce an error /weXXXX
 823                 set(MSVC_W_ERROR   "/we4101 /we4189")
 824                 # add here warnings which should be disabled /wdXXXX
 825                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 826
 827                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 828                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 829                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 830
 831         else()
 832                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 833
 834                 # add here warnings which should produce an error /weXXXX
 835                 set(MSVC_W_ERROR   "/we4101 /we4189")
 836                 # add here warnings which should be disabled /wdXXXX
 837                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 838
 839                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 840                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 841                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 842
 843         endif()
 844
 845         if (NOT Qt5Core_FOUND)
 846                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 847                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 848                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 849         endif()
 850
 851         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 852         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 853         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 854         message(STATUS "")
 855 endif()
 856
 857
 858 if(LYX_DEBUG_GLIBC)
 859         set(_GLIBCXX_DEBUG ON)
 860 endif()
 861
 862 if(LYX_DEBUG_GLIBC_PEDANTIC)
 863         set(_GLIBCXX_DEBUG_PEDANTIC ON)
 864 endif()
 865
 866 # Xcode compiler
 867 if (CMAKE_GENERATOR MATCHES Xcode)
 868         if (XCODE_VERSION VERSION_LESS "5.0")
 869                 # Automatically select the Xcode compiler if not set
 870                 if (NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 871                         # XCode >= 3.1 has gcc 4.2 (up to actual Xcode)
 872                         if (XCODE_VERSION VERSION_GREATER "3.1")
 873                                 SET(CMAKE_XCODE_ATTRIBUTE_GCC_VERSION "com.apple.compilers.llvmgcc42")
 874                         ENDIF(XCODE_VERSION VERSION_GREATER "3.1")
 875                 ENDIF(NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 876                 # Print the selected compiler version
 877         MESSAGE(STATUS "---- Using XCode compiler CMAKE_XCODE_ATTRIBUTE_GCC_VERSION=${CMAKE_XCODE_ATTRIBUTE_GCC_VERSION}")
 878         ENDIF(XCODE_VERSION VERSION_LESS "5.0")
 879 ENDIF(CMAKE_GENERATOR MATCHES Xcode)
 880
 881 if (WIN32 AND Qt5Core_FOUND)
 882         set(Z_PREFIX 1)
 883 endif()
 884
 885 # compiler tests, config.h generation
 886 if(MSVC AND NOT LYX_CONFIGURE_CHECKS)
 887         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.msvc ${TOP_BINARY_DIR}/configCompiler.h)
 888 else()
 889         include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
 890         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
 891 endif()
 892
 893 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
 894
 895 if(QTVERSION MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+).*")
 896         MATH(EXPR QT4_VERSION "(${CMAKE_MATCH_1}<<16)|(${CMAKE_MATCH_2}<<8)|${CMAKE_MATCH_3}")
 897 endif()
 898
 899 if (NOT HAVE_REGEX)
 900         set(LYX_USE_STD_REGEX 0)
 901 endif()
 902
 903
 904 set (cmd ${CMAKE_CTEST_COMMAND})
 905 if (MSVC)
 906         set (cmd ${cmd} -C ${CMAKE_CFG_INTDIR})
 907 else ()
 908         set (cmd ${cmd} -C ${CMAKE_BUILD_TYPE})
 909 endif ()
 910 add_custom_target (lyx_run_tests COMMAND ${cmd})
 911 set_target_properties(lyx_run_tests PROPERTIES FOLDER "tests")
 912
 913 if(LYX_ASAN)
 914     set(LYX_CXX_FLAGS "-fsanitize=address -fno-omit-frame-pointer -g")
 915     message(STATUS)
 916     message(STATUS "Address sanitizer enabled. Usage:")
 917     message(STATUS "    wget https://llvm.org/svn/llvm-project/compiler-rt/trunk/lib/asan/scripts/asan_symbolize.py")
 918     message(STATUS "    chmod  +x ./asan_symbolize.py")
 919     message(STATUS "    ./bin/lyx2.2 2>&1 | ./asan_symbolize.py  | c++filt ")
 920     message(STATUS)
 921 endif()
 922
 923 if(LYX_INSTALL)
 924         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 925                 message(STATUS "Python required to create doc!")
 926         else()
 927                 if(UNIX)
 928                         add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
 929                 endif()
 930                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
 931         endif()
 932         include(../Install)
 933 endif()
 934
 935 add_subdirectory(src "${TOP_BINARY_DIR}/src")
 936 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
 937 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
 938 add_subdirectory(lib/examples "${TOP_BINARY_DIR}/lib/examples")
 939 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
 940 add_subdirectory(development/autotests "${TOP_BINARY_DIR}/autotests")
 941 if(LYX_ENABLE_URLTESTS)
 942         add_subdirectory(development/checkurls "${TOP_BINARY_DIR}/checkurls")
 943 endif()
 944
 945 message(STATUS)
 946 message(STATUS "Build params, switch LYX_* options by -DLYX_*=ON or OFF, LYX_* combos by -DLYX_*=value:")
 947 message(STATUS)
 948
 949 LYX_OPTION_LIST_ALL(used)
 950
 951
 952 if(LYX_NLS)
 953         message(STATUS)
 954         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
 955         message(STATUS)
 956         message(STATUS "  * iconv")
 957         message(STATUS "     - include: ${ICONV_INCLUDE_DIR}")
 958         message(STATUS "     - library: ${ICONV_LIBRARY}")
 959         message(STATUS "  * zlib")
 960         message(STATUS "     - include: ${ZLIB_INCLUDE_DIR}")
 961         message(STATUS "     - library: ${ZLIB_LIBRARY}")
 962         message(STATUS)
 963 endif()
 964
 965 # Apple has builtin native spell checker,
 966 # no need to warn for missing Aspell, Hunspell or Enchant
 967 if(NOT Spelling_FOUND AND NOT APPLE)
 968   if(LYX_REQUIRE_SPELLCHECK)
 969     set(_mode "FATAL_ERROR")
 970   else()
 971     set(_mode "STATUS")
 972   endif()
 973   message(${_mode} "No spellcheck libraries found. LyX will be unable use spellchecking")
 974 endif()
 975
 976 include("${TOP_CMAKE_PATH}/LyxPackaging.cmake")
 977
 978 if(ENABLE_DIST)
 979   # Use git to create the source package
 980   # git archive --format=tgz --output=/home/kornel/x.tar.gz master
 981   if(UNIX)
 982     set(DIST_FORMAT tgz)
 983   else()
 984     set(DIST_FORMAT zip)
 985   endif()
 986   set(DIST_NAME ${CMAKE_PROJECT_NAME}-${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}-${CMAKE_SYSTEM_NAME}.${DIST_FORMAT})
 987
 988   add_custom_command(
 989     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME}
 990     COMMAND  ${LYX_GITVERSION} archive --format=${DIST_FORMAT} --output=${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME} master
 991     WORKING_DIRECTORY ${TOP_SRC_DIR})
 992   add_custom_target(git-archive DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME})
 993 endif()
 994
 995 # Last directory to be included so that the fixup code (OS X)
 996 # can be run last
 997 add_subdirectory(development/cmake/post_install)
 998
 999 message(STATUS)