CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 2.6.4)
   8
   9
  10 set(LYX_PROJECT lyx)
  11
  12 set(LYX_CMAKE_DIR "development/cmake")
  13 set(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/${LYX_CMAKE_DIR}/modules")
  14
  15 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README ABSOLUTE)
  16 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  17
  18 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  19
  20 message(STATUS)
  21 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  22         message(STATUS "Building in-source")
  23         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  24 else()
  25         message(STATUS "Building out-of-source")
  26         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  27 endif()
  28
  29
  30 if(COMMAND cmake_policy)
  31         cmake_policy(SET CMP0003 OLD)
  32         cmake_policy(SET CMP0005 OLD)
  33 endif()
  34
  35 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  36
  37 # Supress regeneration
  38 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  39
  40 if(NOT help AND NOT HELP)
  41         # 'project' triggers the searching for a compiler
  42         project(${LYX_PROJECT})
  43 endif()
  44
  45 if(UNIX)
  46         set(ARCH_TRIPLET )
  47         FIND_PROGRAM(DPKG_ARCHITECTURE_EXECUTABLE dpkg-architecture)
  48         if(DPKG_ARCHITECTURE_EXECUTABLE)
  49                 EXECUTE_PROCESS(COMMAND ${DPKG_ARCHITECTURE_EXECUTABLE} -qDEB_HOST_MULTIARCH
  50                                 OUTPUT_VARIABLE ARCH_TRIPLET
  51                                 ERROR_VARIABLE ERROR_ARCH_TRIPLET
  52                                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  53         endif()
  54 endif()
  55 if(ARCH_TRIPLET)
  56         set(SYSTEM_LIB_DIRS /usr/lib /usr/lib/${ARCH_TRIPLET} /usr/local/lib)
  57 else()
  58         set(SYSTEM_LIB_DIRS /usr/lib /usr/local/lib)
  59 endif()
  60
  61 include(LyXMacros)
  62
  63 # Usage LYX_OPTION
  64 # 1. parameter: option name without prefix 'LYX_'
  65 # 2. parameter: description
  66 # 3. parameter: default value, ON or OFF
  67 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
  68
  69
  70 LYX_OPTION_INIT()
  71
  72 # Options for all compilers/systems
  73 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
  74 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
  75 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
  76 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
  77 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
  78 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
  79 LYX_OPTION(DEVEL_VERSION    "Build developer version" OFF ALL)
  80 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" OFF ALL)
  81 LYX_OPTION(DEBUG            "Enforce debug build"  OFF ALL)
  82 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
  83 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
  84 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
  85 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
  86 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
  87 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
  88 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
  89 LYX_OPTION(EXTERNAL_LIBINTL "Use external libintl" ON ALL)
  90 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
  91
  92 # GCC specific
  93 LYX_OPTION(PROFILE              "Build profile version" OFF GCC)
  94 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" OFF GCC)
  95 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
  96 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
  97 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++pedantic debug mode" OFF GCC)
  98 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" OFF GCC)
  99 LYX_OPTION(CONCEPT_CHECKS       "Enable concept-checks" OFF GCC)
 100 LYX_OPTION(PROFILE              "Build with options for gprof" OFF GCC)
 101
 102 # MSVC specific
 103 LYX_OPTION(CONSOLE               "Show console on Windows, enforce with =FORCE" ON MSVC)
 104 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
 105 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
 106 LYX_OPTION(CONFIGURE_CHECKS      "Also run configure checks for MSVC" OFF MSVC)
 107 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
 108
 109 # APPLE specific
 110 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
 111 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
 112
 113
 114 if(help OR HELP)
 115         message(STATUS)
 116         message(STATUS "Available options: (dis/enable with -DLYX_*=OFF/ON)")
 117         message(STATUS)
 118         LYX_OPTION_LIST_ALL(help)
 119         message(STATUS)
 120         RETURN()
 121 endif()
 122
 123 # Check option dependencies
 124
 125 if(LYX_CPACK)
 126         set(LYX_INSTALL ON)
 127 endif()
 128
 129 if(LYX_DMG)
 130         set(LYX_BUNDLE ON)
 131         set(LYX_CPACK ON)
 132 endif()
 133
 134 if(LYX_INSTALL)
 135         set(LYX_NLS ON)
 136         if (WIN32)
 137                 set(LYX_HUNSPELL ON)
 138         endif()
 139         if(LYX_CONSOLE MATCHES "FORCE")
 140                 set(LYX_CONSOLE ON)
 141         else()
 142                 set(LYX_CONSOLE OFF)
 143         endif()
 144         set(LYX_PACKAGE_SUFFIX ON)
 145         set(LYX_RELEASE ON)
 146         set(LYX_PROFILE OFF)
 147 endif()
 148
 149
 150 if(LYX_MERGE_FILES)
 151         set(LYX_PCH OFF)
 152 else()
 153         set(LYX_MERGE_REBUILD OFF)
 154 endif()
 155
 156 if(LYX_DEPENDENCIES_DOWNLOAD)
 157         message(STATUS)
 158         set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 159         message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 160         set(deps_files lyx20-deps-msvc2010-x86.zip)
 161         set(deps_server http://downloads.sourceforge.net/project/lyx/Win_installers/Dependencies)
 162         foreach(it ${deps_files})
 163                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 164                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 165                 if(NOT already_downloaded)
 166                         message(STATUS "Downloading ${it} ...")
 167                         file(DOWNLOAD ${deps_server}/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS STATUS status LOG log)
 168                         list(GET status 0 status_code)
 169                         list(GET status 1 status_string)
 170                         if(NOT status_code EQUAL 0)
 171                                 file(REMOVE ${LYX_DEPENDENCIES_DIR}/${it})
 172                                 message(FATAL_ERROR "error: downloading '${it}' failed. status_code: ${status_code}, status_string: ${status_string}. \nLog: ${log} ")
 173                         endif()
 174                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 175                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 176                 endif()
 177         endforeach()
 178         set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/deps20)
 179 endif()
 180
 181
 182
 183 message(STATUS)
 184
 185 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 186 if(WIN32)
 187         set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 188 else()
 189         set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 190 endif()
 191
 192
 193 if(UNIX OR MINGW)
 194         execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION)
 195         message(STATUS "Using GCC version ${GCC_VERSION}")
 196         if(NOT GCC_VERSION VERSION_LESS 4.4)
 197                 set(LYX_USE_TR1 1)
 198                 # GCC <= 4.5 does not support regex: there are linker errors
 199                 # http://gcc.gnu.org/onlinedocs/libstdc++/manual/status.html#status.iso.tr1
 200                 set(LYX_USE_TR1_REGEX 0)
 201         endif()
 202 else()
 203         if(MSVC10)
 204                 set(LYX_USE_TR1 1)
 205                 #set(LYX_USE_TR1_REGEX 1) #TODO should we use it in ECMAScript mode?
 206         endif()
 207 endif()
 208
 209
 210 set(VERSION_INFO "CMake Build")
 211
 212 # Try to get some informations from configure.ac
 213
 214 include(LyXPaths)
 215 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 216
 217 if(WIN32)
 218         set(USE_WINDOWS_PACKAGING ON)
 219 elseif(APPLE)
 220         set(USE_MACOSX_PACKAGING ON)
 221 else()
 222         set(USE_POSIX_PACKAGING ON)
 223 endif()
 224
 225 macro(setstripped _varname _value)
 226         string(STRIP ${_value} _v)
 227         if(USE_POSIX_PACKAGING)
 228                 string(TOLOWER ${_v} ${_varname})
 229         else()
 230                 set(${_varname} ${_v})
 231         endif()
 232 endmacro(setstripped)
 233
 234 foreach(_c_l ${_config_lines} )
 235         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 236                 setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 237                 setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 238                 setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 239                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\)\(\\.\([0-9]+\)\)?.*$")
 240                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 241                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 242                         set(LYX_PATCH_VERSION ${CMAKE_MATCH_4})
 243                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 244                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 245                         set(LYX_INSTALL_SUFFIX "${CMAKE_MATCH_1}.${CMAKE_MATCH_2}")
 246                 endif()
 247         endif()
 248         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 249                 set(LYX_DATE "${CMAKE_MATCH_1}")
 250         endif()
 251 endforeach(_c_l)
 252
 253 # Find the revision number and for later use
 254 FIND_PROGRAM(LYX_SVNVERSION svnversion)
 255 #message(STATUS "svnversion = ${LYX_SVNVERSION}")
 256 if(LYX_SVNVERSION)
 257         EXECUTE_PROCESS(COMMAND ${LYX_SVNVERSION} WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE LYX_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 258         # We use this value also to set the package-patch-value
 259         if(LYX_PACKAGE_RELEASE MATCHES "^\([0-9]+\)")
 260                 set(LYX_REVISION_VERSION ${CMAKE_MATCH_1})
 261         endif()
 262 else()
 263         set(LYX_REVISION_VERSION svn) #TODO use date
 264 endif()
 265
 266
 267 if(LYX_PROGRAM_SUFFIX)
 268         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 269 else()
 270         set(PROGRAM_SUFFIX "")
 271 endif()
 272
 273
 274 if(LYX_BUNDLE)
 275         set(LYX_CPACK ON)
 276         message(STATUS)
 277         message(STATUS "Bundle creation is enabled (experimental):")
 278         message(STATUS "    make")
 279         message(STATUS "    make install/strip")
 280         message(STATUS "    make package")
 281         if(APPLE)
 282                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 283                 set(LYX_DATA_SUBDIR ${PACKAGE_BASE}${PROGRAM_SUFFIX}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 284                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${PACKAGE_BASE}${PROGRAM_SUFFIX}.app)
 285                 if(NOT LYX_INSTALL_PREFIX)
 286                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 287                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 288                 endif()
 289         elseif(UNIX)
 290                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 291                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 292                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 293         elseif(WIN32)
 294                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 295         endif()
 296 endif()
 297
 298 if(LYX_INSTALL_PREFIX)
 299         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 300         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 301 endif()
 302 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 303
 304 if(LYX_PACKAGE_SUFFIX)
 305         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 306 else()
 307         set(PACKAGE ${PACKAGE_BASE})
 308 endif()
 309
 310
 311 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 312         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 313         if (UNIX)
 314                 # don't use the default "/usr/local"
 315                 # but respect the user-choice on the command-line
 316                 if(LYX_INSTALL_SUFFIX)
 317                         set(CMAKE_INSTALL_PREFIX "/usr/local/lyx${LYX_INSTALL_SUFFIX}" CACHE PATH "LyX default install prefix" FORCE)
 318                 else()
 319                         set(CMAKE_INSTALL_PREFIX "/usr/local/${LYX_PROJECT}" CACHE PATH "LyX default install prefix" FORCE)
 320                 endif()
 321         endif()
 322         if(WIN32)
 323                 set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 324         endif()
 325 endif()
 326 if(IS_ABSOLUTE)
 327         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 328 else()
 329         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 330 endif()
 331
 332
 333
 334 if(NOT LYX_DATA_SUBDIR)
 335         if (WIN32)
 336                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 337         else()
 338                 set(LYX_DATA_SUBDIR "" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 339         endif()
 340 endif()
 341
 342 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 343 set(LYX_LOCALEDIR "locale")
 344 set(LYX_ABS_INSTALLED_LOCALEDIR "${LYX_ABS_INSTALLED_DATADIR}/${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}")
 345 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 346
 347
 348 if(LYX_INSTALL AND WIN32)
 349         message(STATUS "Configuring NSIS files")
 350         configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 351         configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 352         configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 353         message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 354 endif()
 355
 356 if(NOT GROUP_CODE)
 357         #set(GROUP_CODE "The Golden Code")
 358         set(GROUP_CODE flat)
 359 endif()
 360
 361 # lyx's source files
 362 set(LYX_CPP_FILES *.cpp)
 363 set(LYX_HPP_FILES *.h)
 364 set(LYX_MOC_FILES moc_*.cpp)
 365
 366 include(ProjectSourceGroup)
 367
 368
 369 if(LYX_PROFILE AND NOT MSVC)
 370         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 371         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg")
 372         set(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS}  -pg")
 373 else()
 374         set(LYX_PROFILE OFF)
 375 endif()
 376
 377
 378 if(LYX_NO_OPTIMIZE)
 379         set(CMAKE_BUILD_TYPE None)
 380         set(LYX_DEBUG OFF)
 381         set(LYX_RELEASE OFF)
 382         set(LYX_PROFILE OFF)
 383 elseif(LYX_RELEASE)
 384         set(CMAKE_BUILD_TYPE Release)
 385         set(LYX_DEBUG OFF)
 386         set(LYX_PROFILE OFF)
 387 elseif(LYX_PROFILE)
 388         set(CMAKE_BUILD_TYPE Profile)
 389         set(LYX_DEBUG OFF)
 390 else()
 391         set(CMAKE_BUILD_TYPE Debug)
 392         set(LYX_DEBUG ON)
 393 endif()
 394
 395
 396 # When shared libs are supported enable this option
 397 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 398 if(LYX_SHARED_LIBRARIES)
 399         set(library_type SHARED)
 400 else()
 401         set(library_type STATIC)
 402 endif()
 403
 404 if(NOT MSVC)
 405         if(NOT LYX_QUIET)
 406                 set(CMAKE_VERBOSE_MAKEFILE ON)
 407         endif()
 408         set(LYX_CXX_FLAGS "-Wall -Wunused-parameter")
 409         if(LYX_STDLIB_DEBUG)
 410                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 411         endif()
 412         if(LYX_CONCEPT_CHECKS)
 413                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCPP_CONCEPT_CHECKS")
 414         endif()
 415         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 416         set(CMAKE_CXX_FLAGS_DEBUG "${LYX_CXX_FLAGS} -fno-strict-aliasing -O0 -g -D_DEBUG" CACHE TYPE STRING FORCE)
 417         if(MINGW)
 418                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 419         else()
 420                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 421         endif()
 422 endif()
 423
 424
 425 find_package(Qt4 REQUIRED)
 426 find_package(Magic)
 427 if(Magic_FOUND)
 428         set(HAVE_MAGIC_H 1)
 429 endif()
 430
 431 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 432
 433 if(LYX_ASPELL)
 434         find_package(ASPELL)
 435         include_directories(${ASPELL_INCLUDE_DIR})
 436 endif()
 437
 438 if(LYX_ENCHANT)
 439         find_package(Enchant REQUIRED)
 440         include_directories(${ENCHANT_INCLUDE_DIR})
 441 endif()
 442
 443 if(LYX_HUNSPELL)
 444         find_package(Hunspell REQUIRED)
 445         include_directories(${HUNSPELL_INCLUDE_DIR})
 446 endif()
 447
 448 if(LYX_NLS)
 449         FIND_PROGRAM(LYX_PYTHON_EXECUTABLE python2 python HINTS ${GNUWIN32_DIR}/python)
 450         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 451                 message(FATAL_ERROR "Python 2.6 needed!")
 452         endif()
 453         find_package(LyXGettext REQUIRED)
 454         include_directories(${TOP_SRC_DIR}/po)
 455         add_subdirectory(po "${TOP_BINARY_DIR}/po")
 456 endif()
 457
 458 if(LYX_NLS)
 459         if(LYX_EXTERNAL_LIBINTL)
 460                 find_package(Libintl REQUIRED)
 461                 if(DEFINED LIBINTL_LIBRARIES)
 462                         # find getext when configuring
 463                         list(APPEND CMAKE_REQUIRED_LIBRARIES ${LIBINTL_LIBRARIES})
 464                         # on mac use iconv also form ports
 465                         get_filename_component(ICONV_RELATIVE_TO_LIBINTL ${LIBINTL_LIBRARIES} PATH)
 466                 endif()
 467         else()
 468                 add_subdirectory(intl "${TOP_BINARY_DIR}/intl")
 469         endif()
 470 endif()
 471
 472 find_package(ICONV REQUIRED)
 473 find_package(ZLIB REQUIRED)
 474
 475 if(LYX_EXTERNAL_BOOST)
 476         message(STATUS "Searching for boost")
 477         find_package(Boost COMPONENTS signals regex) #TODO could REQUIRED be used
 478         if(Boost_FOUND)
 479                 message(STATUS "Boost found")
 480                 message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 481                 set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 482         else()
 483                 message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 484         endif()
 485 else()
 486         if(LYX_USE_TR1_REGEX)
 487                 set(Lyx_Boost_Libraries boost_signals)
 488         else()
 489                 set(Lyx_Boost_Libraries boost_signals boost_regex)
 490         endif()
 491         add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 492         include_directories(${TOP_SRC_DIR}/boost)
 493         add_subdirectory(boost "${TOP_BINARY_DIR}/boost")
 494 endif()
 495
 496
 497
 498
 499 if(WIN32)
 500         if(NOT LYX_CONSOLE)
 501                 set(WIN32_CONSOLE WIN32)
 502                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARY})
 503         endif()
 504         if(MSVC)
 505                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 506                 # disable checked iterators for msvc release builds to get maximum speed
 507                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 508         else()
 509                 add_definitions(-DWINVER=0x0500)
 510         endif()
 511 endif()
 512
 513 message(STATUS "")
 514 foreach(_v PACKAGE PACKAGE_VERSION
 515         PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 516         LYX_ABS_TOP_SRCDIR
 517         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 518         if(NOT DEFINED ${_v})
 519                 message(FATAL_ERROR "${_v} not defined")
 520         endif()
 521         string(SUBSTRING "${_v}                            " 0 28 _v1)
 522         message(STATUS "----- ${_v1}: ${${_v}}")
 523 endforeach(_v)
 524 message(STATUS "")
 525
 526
 527 if(LYX_PCH)
 528         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 529         # Not sure if it works for all non-msvc compilers
 530         include(PCHSupport_26)
 531         configure_file(${TOP_SRC_DIR}/${LYX_CMAKE_DIR}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
 532         configure_file(${TOP_SRC_DIR}/${LYX_CMAKE_DIR}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 533         add_definitions(-DLYX_ENABLE_PCH)
 534
 535         if(MSVC)
 536                 macro(lyx_add_msvc_pch name_)
 537                         set_source_files_properties(${${name_}_sources} PROPERTIES
 538                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 539                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
 540                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 541                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
 542                                 ${TOP_BINARY_DIR}/pcheaders.h)
 543                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 544                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 545                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 546                 endmacro(lyx_add_msvc_pch)
 547                 macro(lyx_add_gcc_pch name_)
 548                 endmacro()
 549         else()
 550                 macro(lyx_add_msvc_pch name_)
 551                 endmacro()
 552                 macro(lyx_add_gcc_pch name_)
 553                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT4)
 554                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
 555                 endmacro()
 556         endif()
 557 else()
 558         macro(lyx_add_msvc_pch)
 559         endmacro(lyx_add_msvc_pch)
 560         macro(lyx_add_gcc_pch name_)
 561         endmacro()
 562 endif()
 563
 564
 565 if(MSVC)
 566
 567         if(LYX_VLD)
 568                 set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/development/Win32/vld)
 569                 add_subdirectory(${vld_path}/cmake)
 570                 include(${vld_path}/cmake/vld.cmake) # forced include
 571                 set(vld_dll vld)
 572         endif()
 573
 574         if(LYX_WALL)
 575                 # Use the highest warning level
 576                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 577
 578                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 579                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 580                 else()
 581                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 582                 endif()
 583
 584                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 585                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 586                 else()
 587                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 588                 endif()
 589
 590                 # add here warnings which should produce an error /weXXXX
 591                 set(MSVC_W_ERROR   "/we4101 /we4189")
 592                 # add here warnings which should be disabled /wdXXXX
 593                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 594
 595                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 596                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 597                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 598
 599         else()
 600                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 601
 602                 # add here warnings which should produce an error /weXXXX
 603                 set(MSVC_W_ERROR   "/we4101 /we4189")
 604                 # add here warnings which should be disabled /wdXXXX
 605                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 606
 607                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 608                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 609                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 610
 611         endif()
 612         set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 613         set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 614         set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 615
 616         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 617         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 618         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 619         message(STATUS "")
 620 endif()
 621
 622
 623 if(LYX_DEBUG_GLIBC)
 624         set(_GLIBCXX_DEBUG ON)
 625 endif()
 626
 627 if(LYX_DEBUG_GLIBC_PEDANTIC)
 628         set(_GLIBCXX_DEBUG_PEDANTIC ON)
 629 endif()
 630
 631 # Xcode compiler
 632 if (CMAKE_GENERATOR MATCHES Xcode)
 633         # Automatically select the Xcode compiler if not set
 634         if (NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 635                 # XCode >= 3.1 has gcc 4.2 (up to actual Xcode)
 636                 if (XCODE_VERSION VERSION_GREATER "3.1")
 637                         SET(CMAKE_XCODE_ATTRIBUTE_GCC_VERSION "com.apple.compilers.llvmgcc42")
 638                 ENDIF(XCODE_VERSION VERSION_GREATER "3.1")
 639         ENDIF(NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 640
 641         # Print the selected compiler version
 642     MESSAGE(STATUS "---- Using XCode compiler CMAKE_XCODE_ATTRIBUTE_GCC_VERSION=${CMAKE_XCODE_ATTRIBUTE_GCC_VERSION}")
 643 ENDIF(CMAKE_GENERATOR MATCHES Xcode)
 644
 645
 646 # compiler tests, config.h generation
 647 if(MSVC AND NOT LYX_CONFIGURE_CHECKS)
 648         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.msvc ${TOP_BINARY_DIR}/configCompiler.h)
 649 else()
 650         include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
 651         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
 652 endif()
 653
 654 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
 655
 656 # Compute qt4-version from ${QTVERSION}
 657 if(QTVERSION MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+).*")
 658         MATH(EXPR QT4_VERSION "(${CMAKE_MATCH_1}<<16)|(${CMAKE_MATCH_2}<<8)|${CMAKE_MATCH_3}")
 659 endif()
 660
 661 add_subdirectory(src "${TOP_BINARY_DIR}/src")
 662 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
 663 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
 664
 665
 666 if(LYX_INSTALL)
 667         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 668                 message(STATUS "Python required to create doc!")
 669         else()
 670                 add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
 671                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
 672         endif()
 673         include(../Install)
 674 endif()
 675
 676 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
 677
 678 message(STATUS)
 679 message(STATUS "Build options, switch LYX_* variables by -DLYX_*=ON or OFF:")
 680 message(STATUS)
 681 LYX_OPTION_LIST_ALL(used)
 682
 683
 684 if(LYX_NLS)
 685         message(STATUS)
 686         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
 687         message(STATUS)
 688         message(STATUS "  * intl")
 689         message(STATUS "     - header : ${LIBINTL_HEADER}")
 690         message(STATUS "     - library: ${LIBINTL_LIBRARIES}")
 691         message(STATUS "  * iconv")
 692         message(STATUS "     - header : ${ICONV_HEADER}")
 693         message(STATUS "     - library: ${ICONV_LIBRARY}")
 694         message(STATUS "  * zlib")
 695         message(STATUS "     - header : ${ZLIB_HEADER}")
 696         message(STATUS "     - library: ${ZLIB_LIBRARY}")
 697         message(STATUS)
 698 endif()
 699
 700 include("${TOP_SRC_DIR}/${LYX_CMAKE_DIR}/LyxPackaging.cmake")
 701
 702 message(STATUS)