CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 2.6.4)
   8
   9 set(LYX_PROJECT LyX)
  10
  11 enable_testing()
  12
  13 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README ABSOLUTE)
  14 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  15
  16 set(LYX_CMAKE_DIR "development/cmake")
  17 set(TOP_CMAKE_PATH "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}")
  18 set(TOP_MODULE_PATH "${TOP_CMAKE_PATH}/modules")
  19 set(TOP_SCRIPT_PATH "${TOP_CMAKE_PATH}/scripts")
  20
  21 set(CMAKE_MODULE_PATH "${TOP_MODULE_PATH}")
  22
  23 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  24
  25 message(STATUS)
  26 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  27         message(STATUS "Building in-source")
  28         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  29 else()
  30         message(STATUS "Building out-of-source")
  31         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  32 endif()
  33
  34 # This directory should be used if some test uses lyx-executable
  35 set(LYX_TESTS_USERDIR "${TOP_BINARY_DIR}/Testing/.lyx")
  36 file(MAKE_DIRECTORY "${LYX_TESTS_USERDIR}")
  37
  38 if(COMMAND cmake_policy)
  39         cmake_policy(SET CMP0003 OLD)
  40         cmake_policy(SET CMP0005 OLD)
  41         # Installing MACOSX_BUNDLE targets requires a BUNDLE DESTINATION
  42         cmake_policy(SET CMP0006 NEW)
  43         if(POLICY CMP0028)
  44                 cmake_policy(SET CMP0028 OLD)
  45         endif()
  46         if(POLICY CMP0043)
  47                 # COMPILE_DEFINITIONS are not used yet. Enable new behavior.
  48                 cmake_policy(SET CMP0043 NEW)
  49         endif()
  50 endif()
  51
  52 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  53
  54 # Supress regeneration
  55 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  56
  57 if(LYX_XMINGW)
  58     set(CMAKE_SYSTEM_NAME Windows)
  59     set(TOOLNAME ${LYX_XMINGW})
  60     set(TOOLCHAIN "${TOOLNAME}-")
  61     set(CMAKE_C_COMPILER   "${TOOLCHAIN}gcc"     CACHE PATH "Mingw C compiler" FORCE)
  62     set(CMAKE_CXX_COMPILER "${TOOLCHAIN}g++"     CACHE PATH "Mingw C++ compiler" FORCE)
  63     set(CMAKE_RC_COMPILER  "${TOOLCHAIN}windres" CACHE PATH "Mingw rc compiler" FORCE)
  64
  65     set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM BOTH)
  66     set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY)
  67     set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY)
  68 endif()
  69
  70 if(NOT help AND NOT HELP)
  71         # 'project' triggers the searching for a compiler
  72         project(${LYX_PROJECT})
  73 endif()
  74
  75 if(UNIX)
  76         set(ARCH_TRIPLET )
  77         FIND_PROGRAM(DPKG_ARCHITECTURE_EXECUTABLE dpkg-architecture)
  78         if(DPKG_ARCHITECTURE_EXECUTABLE)
  79                 EXECUTE_PROCESS(COMMAND ${DPKG_ARCHITECTURE_EXECUTABLE} -qDEB_HOST_MULTIARCH
  80                                 OUTPUT_VARIABLE ARCH_TRIPLET
  81                                 ERROR_VARIABLE ERROR_ARCH_TRIPLET
  82                                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  83         endif()
  84 endif()
  85 if(ARCH_TRIPLET)
  86         set(SYSTEM_LIB_DIRS /usr/lib /usr/lib/${ARCH_TRIPLET} /usr/local/lib)
  87 else()
  88         set(SYSTEM_LIB_DIRS /usr/lib /usr/local/lib)
  89 endif()
  90
  91 include(LyXMacros)
  92
  93 # Usage LYX_OPTION
  94 # 1. parameter: option name without prefix 'LYX_'
  95 # 2. parameter: description
  96 # 3. parameter: default value, ON or OFF
  97 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
  98
  99 # Usage LYX_COMBO
 100 # 1. parameter: name without prefix 'LYX_'
 101 # 2. parameter: description
 102 # 3. parameter: default value
 103 # 4-n parameter: possible other string values
 104
 105 LYX_OPTION_INIT()
 106
 107 # Options for all compilers/systems
 108 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
 109 LYX_OPTION(LOCALVERSIONING  "Add version info to created package name (only used if LYX_CPACK option set)" OFF ALL)
 110 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
 111 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
 112 LYX_OPTION(REQUIRE_SPELLCHECK "Abort if no spellchecker available" OFF ALL)
 113 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
 114 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
 115 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
 116 LYX_OPTION(DEVEL_VERSION    "Build developer version" OFF ALL)
 117 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" OFF ALL)
 118 LYX_OPTION(DEBUG            "Enforce debug build"  OFF ALL)
 119 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
 120 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
 121 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
 122 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
 123 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
 124 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
 125 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
 126 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
 127 LYX_OPTION(ENABLE_URLTESTS  "Enable for URL tests" OFF ALL)
 128 LYX_OPTION(ENABLE_EXPORT_TESTS "Enable for export tests" OFF ALL)
 129 LYX_OPTION(ASAN             "Use address sanitizer" OFF ALL)
 130
 131 # GCC specific
 132 LYX_OPTION(PROFILE              "Build profile version" OFF GCC)
 133 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" OFF GCC)
 134 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
 135 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
 136 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++ pedantic debug mode" OFF GCC)
 137 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" OFF GCC)
 138 LYX_OPTION(CONCEPT_CHECKS       "Enable concept-checks" OFF GCC)
 139 LYX_OPTION(PROFILE              "Build with options for gprof" OFF GCC)
 140 LYX_OPTION(ENABLE_CXX11         "Build with options for c++11-mode" OFF GCC)
 141
 142 # MSVC specific
 143 LYX_OPTION(CONSOLE               "Show console on Windows, enforce with =FORCE" ON MSVC)
 144 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
 145 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
 146 LYX_OPTION(CONFIGURE_CHECKS      "Also run configure checks for MSVC" OFF MSVC)
 147 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
 148
 149 # APPLE specific
 150 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
 151 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
 152 if(LYX_XMINGW)
 153   LYX_COMBO(USE_QT               "Use Qt version as frontend for MINGW" QT4)
 154 else()
 155   LYX_COMBO(USE_QT               "Use Qt version as frontend" QT4 QT5)
 156 endif()
 157
 158
 159 if(help OR HELP)
 160         message(STATUS)
 161         message(STATUS "Available options: (dis/enable with -DLYX_*=OFF/ON)")
 162         message(STATUS)
 163         LYX_OPTION_LIST_ALL(help)
 164         message(STATUS)
 165         RETURN()
 166 endif()
 167
 168 # Check option dependencies
 169
 170 if(LYX_DMG)
 171         set(LYX_BUNDLE ON)
 172         set(LYX_CPACK ON)
 173 endif()
 174
 175 if(LYX_CPACK)
 176         set(LYX_INSTALL ON)
 177 endif()
 178
 179 if(LYX_INSTALL)
 180         set(LYX_NLS ON)
 181         if(WIN32 AND NOT MINGW)
 182                 set(LYX_HUNSPELL ON)
 183         endif()
 184         if(LYX_CONSOLE MATCHES "FORCE")
 185                 set(LYX_CONSOLE ON)
 186         else()
 187                 set(LYX_CONSOLE OFF)
 188         endif()
 189         set(LYX_PACKAGE_SUFFIX ON)
 190         if(NOT LYX_DEBUG)
 191                 set(LYX_RELEASE ON)
 192         endif()
 193         set(LYX_PROFILE OFF)
 194 endif()
 195
 196
 197 if(LYX_MERGE_FILES)
 198         set(LYX_PCH OFF)
 199 else()
 200         set(LYX_MERGE_REBUILD OFF)
 201 endif()
 202
 203
 204 if(LYX_DEPENDENCIES_DOWNLOAD)
 205         message(STATUS)
 206         set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 207         message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 208         set(deps_files lyx20-deps-msvc2010-x86.zip)
 209         set(deps_server http://downloads.sourceforge.net/project/lyx/Win_installers/Dependencies)
 210         foreach(it ${deps_files})
 211                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 212                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 213                 if(NOT already_downloaded)
 214                         message(STATUS "Downloading ${it} ...")
 215                         file(DOWNLOAD ${deps_server}/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS STATUS status LOG log)
 216                         list(GET status 0 status_code)
 217                         list(GET status 1 status_string)
 218                         if(NOT status_code EQUAL 0)
 219                                 file(REMOVE ${LYX_DEPENDENCIES_DIR}/${it})
 220                                 message(FATAL_ERROR "error: downloading '${it}' failed. status_code: ${status_code}, status_string: ${status_string}. \nLog: ${log} ")
 221                         endif()
 222                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 223                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 224                 endif()
 225         endforeach()
 226         set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/deps20)
 227     if(MSVC12)
 228         # handle error in msvc12 when linking against msvc10 libs
 229         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /vd2")
 230     endif()
 231 endif()
 232
 233
 234
 235 message(STATUS)
 236
 237 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 238 if(WIN32)
 239         set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 240 else()
 241         set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 242 endif()
 243
 244
 245 set(LYX_GCC11_MODE)
 246 if(UNIX OR MINGW)
 247         execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION)
 248         message(STATUS "Using GCC version ${GCC_VERSION}")
 249         if(NOT GCC_VERSION VERSION_LESS 4.4)
 250                 set(LYX_USE_TR1 1)
 251                 # GCC <= 4.5 does not support regex: there are linker errors
 252                 # http://gcc.gnu.org/onlinedocs/libstdc++/manual/status.html#status.iso.tr1
 253                 set(LYX_USE_TR1_REGEX 0)
 254         endif()
 255         if (LYX_ENABLE_CXX11)
 256                 find_package(CXX11Compiler)
 257                 if(NOT CXX11COMPILER_FOUND)
 258                         message(FATAL_ERROR "A C++11 compatible compiler is required.")
 259                 endif()
 260                 set(LYX_GCC11_MODE "${CXX11_FLAG}")
 261         endif()
 262 else()
 263         if(MSVC10)
 264                 set(LYX_USE_TR1 1)
 265                 #set(LYX_USE_TR1_REGEX 1) #TODO should we use it in ECMAScript mode?
 266         endif()
 267 endif()
 268
 269
 270 set(VERSION_INFO "CMake Build")
 271
 272 # Try to get some informations from configure.ac
 273
 274 include(LyXPaths)
 275 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 276
 277 if(WIN32)
 278         set(USE_WINDOWS_PACKAGING ON)
 279 elseif(APPLE)
 280         set(USE_MACOSX_PACKAGING ON)
 281 else()
 282         set(USE_POSIX_PACKAGING ON)
 283 endif()
 284
 285 macro(setstripped _varname)
 286         if(${ARGC} GREATER 1)
 287                 string(STRIP "${ARGV1}" _v)
 288                 if(USE_POSIX_PACKAGING)
 289                         string(TOLOWER ${_v} ${_varname})
 290                 else()
 291                         set(${_varname} ${_v})
 292                 endif()
 293         else()
 294                 set(${_varname})
 295         endif()
 296 endmacro(setstripped)
 297
 298 foreach(_c_l ${_config_lines} )
 299         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 300                 setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 301                 setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 302                 setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 303                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\)\(\\.\([0-9]+\)\)?.*$")
 304                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 305                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 306                         set(LYX_PATCH_VERSION ${CMAKE_MATCH_4})
 307                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 308                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 309                         set(LYX_INSTALL_SUFFIX "${CMAKE_MATCH_1}.${CMAKE_MATCH_2}")
 310                 endif()
 311         endif()
 312         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 313                 set(LYX_DATE "${CMAKE_MATCH_1}")
 314         endif()
 315 endforeach(_c_l)
 316
 317 FIND_PROGRAM(LYX_GITVERSION git)
 318 #message(STATUS "gitversion = ${LYX_GITVERSION}")
 319 set(LYX_REVISION_VERSION ${LYX_PATCH_VERSION})
 320 if(LYX_GITVERSION)
 321   if (LYX_LOCALVERSIONING)
 322     # Find the revision number and for later use
 323     EXECUTE_PROCESS(COMMAND ${LYX_GITVERSION} describe --match 2.0.0 HEAD
 324       WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE LYX_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 325     if (LYX_PACKAGE_RELEASE MATCHES "^2\\.0\\.0\\-\([0-9]+\)\\-.*$")
 326       # We will add offset of 40000 to get appropriate value to
 327       # previous svn.
 328       # We use this value than also to set the package-patch-value
 329       MATH(EXPR tmp_REVISION_VERSION "(${CMAKE_MATCH_1}+40000)")
 330       set(LYX_REVISION_VERSION "${LYX_PATCH_VERSION}-${tmp_REVISION_VERSION}git")
 331       set(ENABLE_DIST ON)
 332     endif()
 333   endif()
 334 endif()
 335
 336 # Set the programs (lyx, tex2lyx, etc.) suffix
 337 # When building an OS X bundle, we will append
 338 # the suffix only to the bundle, not to the programs
 339 set(PROGRAM_SUFFIX "")
 340 if(LYX_PROGRAM_SUFFIX AND NOT (APPLE AND LYX_BUNDLE))
 341         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 342 endif()
 343 set(_lyx "${PACKAGE_BASE}${PROGRAM_SUFFIX}")
 344 set(_tex2lyx tex2lyx${PROGRAM_SUFFIX})
 345
 346 add_custom_target(lyx_version ALL
 347   COMMAND ${CMAKE_COMMAND} -DTOP_SRC_DIR=${TOP_SRC_DIR} -DTOP_CMAKE_PATH=${TOP_CMAKE_PATH} -DTOP_BINARY_DIR=${TOP_BINARY_DIR} -DLYX_DATE=${LYX_DATE} -P ${TOP_SCRIPT_PATH}/LyXGetVersion.cmake
 348   )
 349 set_target_properties(lyx_version PROPERTIES FOLDER "applications")
 350
 351 # Default paths for installed utilities (tex2lyx, lyxclient, etc.)
 352 set(LYX_UTILITIES_INSTALL_PATH bin)
 353
 354 if(LYX_BUNDLE)
 355         set(LYX_CPACK ON)
 356
 357         message(STATUS)
 358         message(STATUS "Bundle creation is enabled (experimental):")
 359         message(STATUS "    make")
 360         message(STATUS "    make install/strip")
 361         message(STATUS "    make package")
 362         if(APPLE)
 363                 set(MACOSX_BUNDLE TRUE)
 364                 # This sets the bundle + executable names
 365                 set(_lyx "${PACKAGE_BASE}${LYX_INSTALL_SUFFIX}")
 366                 # This sets the Info.plist executable name
 367                 set(osx_bundle_program_name ${_lyx})
 368                 # Bundle name
 369                 set(LYX_BUNDLE_NAME ${_lyx})
 370
 371                 # This will contain the list of files that need to be included
 372                 # in the bundle and their location within the bundle
 373                 set(OSX_BUNDLE_FILES "${TOP_SRC_DIR}/development/MacOSX/LyX.sdef;${TOP_SRC_DIR}/development/MacOSX/LyXapp.icns;${CMAKE_BINARY_DIR}/lyxrc.dist")
 374                 set(OSX_BUNDLE_DIRS "Resources;Resources;Resources")
 375
 376                 # Process Info.plist and lyxrc.dist
 377                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/Info.plist.in" "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 378                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/lyxrc.dist.in" "${CMAKE_CURRENT_BINARY_DIR}/lyxrc.dist")
 379
 380                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 381                 set(LYX_DATA_SUBDIR ${LYX_BUNDLE_NAME}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 382
 383                 # Variables used by CPack
 384                 set(CPACK_BUNDLE_NAME ${LYX_BUNDLE_NAME})
 385                 set(CPACK_BUNDLE_PLIST "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 386                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${LYX_BUNDLE_NAME}.app)
 387
 388                 # Set the install paths
 389                 set(LYX_UTILITIES_INSTALL_PATH ${LYX_BUNDLE_NAME}.app/Contents/MacOS)
 390                 if(NOT LYX_INSTALL_PREFIX)
 391                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 392                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 393                 endif()
 394                 # Change the owner so that the install can work
 395                 install(CODE "set(BU_CHMOD_BUNDLE_ITEMS 1)" COMPONENT Runtime)
 396         elseif(UNIX)
 397                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 398                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 399                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 400         elseif(WIN32)
 401                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 402         endif()
 403 endif()
 404
 405 if(LYX_INSTALL_PREFIX)
 406         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 407         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 408 endif()
 409 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 410
 411 string(REGEX REPLACE "/lyx${LYX_INSTALL_SUFFIX}$" "/share" SYSTEM_DATADIR ${CMAKE_INSTALL_PREFIX})
 412
 413 if(LYX_PACKAGE_SUFFIX)
 414         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 415 else()
 416         set(PACKAGE ${PACKAGE_BASE})
 417 endif()
 418
 419 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 420         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 421         if (UNIX)
 422                 # don't use the default "/usr/local"
 423                 # but respect the user-choice on the command-line
 424                 if(LYX_INSTALL_SUFFIX)
 425                         set(CMAKE_INSTALL_PREFIX "/usr/local/lyx${LYX_INSTALL_SUFFIX}" CACHE PATH "LyX default install prefix" FORCE)
 426                 else()
 427                         set(CMAKE_INSTALL_PREFIX "/usr/local/${LYX_PROJECT}" CACHE PATH "LyX default install prefix" FORCE)
 428                 endif()
 429         endif()
 430         if(WIN32)
 431                 set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 432         endif()
 433 endif()
 434 if(IS_ABSOLUTE)
 435         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 436 else()
 437         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 438 endif()
 439
 440
 441
 442 if(NOT LYX_DATA_SUBDIR)
 443         if (WIN32)
 444                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 445         else()
 446                 set(LYX_DATA_SUBDIR "" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 447         endif()
 448 endif()
 449
 450 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 451 set(LYX_LOCALEDIR "locale")
 452 set(LYX_ABS_INSTALLED_LOCALEDIR "${LYX_ABS_INSTALLED_DATADIR}/${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}")
 453 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 454
 455 if(LYX_BUNDLE AND APPLE)
 456         set(LYX_MAN_DIR "${LYX_DATA_SUBDIR}" CACHE STRING "Install location for man pages.")
 457 else()
 458         set(LYX_MAN_DIR "/usr/local/man/man1" CACHE STRING "Install location for man pages.")
 459 endif()
 460 mark_as_advanced(LYX_MAN_DIR)
 461
 462 if(LYX_INSTALL AND WIN32)
 463         message(STATUS "Configuring NSIS files")
 464         configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 465         configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 466         configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 467         message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 468 endif()
 469
 470 if(NOT GROUP_CODE)
 471         #set(GROUP_CODE "The Golden Code")
 472         set(GROUP_CODE flat)
 473 endif()
 474
 475 # lyx's source files
 476 set(LYX_CPP_FILES [a-zA-Z]*.cpp)
 477 set(LYX_HPP_FILES [a-zA-Z]*.h)
 478 set(LYX_MOC_FILES moc_*.cpp)
 479
 480 include(ProjectSourceGroup)
 481
 482
 483 if(LYX_PROFILE AND NOT MSVC)
 484         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 485         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg")
 486         set(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS}  -pg")
 487 else()
 488         set(LYX_PROFILE OFF)
 489 endif()
 490
 491
 492 if(LYX_NO_OPTIMIZE)
 493         set(CMAKE_BUILD_TYPE None)
 494         set(LYX_DEBUG OFF)
 495         set(LYX_RELEASE OFF)
 496         set(LYX_PROFILE OFF)
 497 elseif(LYX_RELEASE)
 498         set(CMAKE_BUILD_TYPE Release)
 499         set(LYX_DEBUG OFF)
 500         set(LYX_PROFILE OFF)
 501 elseif(LYX_PROFILE)
 502         set(CMAKE_BUILD_TYPE Profile)
 503         set(LYX_DEBUG OFF)
 504 else()
 505         set(CMAKE_BUILD_TYPE Debug)
 506         set(LYX_DEBUG ON)
 507 endif()
 508
 509
 510 # When shared libs are supported enable this option
 511 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 512 if(LYX_SHARED_LIBRARIES)
 513         set(library_type SHARED)
 514 else()
 515         set(library_type STATIC)
 516 endif()
 517
 518 if(NOT MSVC)
 519         if(NOT LYX_QUIET)
 520                 set(CMAKE_VERBOSE_MAKEFILE ON)
 521         endif()
 522     set(LYX_CXX_FLAGS "-Wall -Wunused-parameter ${LYX_GCC11_MODE}")
 523         if(LYX_STDLIB_DEBUG)
 524                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 525         endif()
 526         if(LYX_CONCEPT_CHECKS)
 527                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCPP_CONCEPT_CHECKS")
 528         endif()
 529         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 530         set(CMAKE_CXX_FLAGS_DEBUG "${LYX_CXX_FLAGS} -fno-strict-aliasing -O0 -g3 -D_DEBUG" CACHE TYPE STRING FORCE)
 531         if(MINGW)
 532                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 533         else()
 534                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 535         endif()
 536 endif()
 537
 538 set(LYX_CXX_FLAGS_EXTRA "" CACHE STRING "Desired semicolon separated list of extra cxx compile flags, like '-Werror'")
 539 mark_as_advanced(LYX_CXX_FLAGS_EXTRA)
 540 if(LYX_CXX_FLAGS_EXTRA)
 541         foreach(_flag ${LYX_CXX_FLAGS_EXTRA})
 542                 add_definitions(${_flag})
 543         endforeach()
 544 endif()
 545
 546 if(LYX_XMINGW)
 547     set(QT_MINGW_DIR ${LYX_QT4} CACHE PATH "Qt for Mingw" FORCE)
 548     list(APPEND CMAKE_FIND_ROOT_PATH ${QT_MINGW_DIR} ${GNUWIN32_DIR})
 549 endif()
 550 if(LYX_USE_QT MATCHES "QT5")
 551         find_package(Qt5Core REQUIRED)
 552         if (Qt5Core_FOUND)
 553                 find_package(Qt5Widgets REQUIRED)
 554                 if(APPLE)
 555                         find_package(Qt5MacExtras REQUIRED)
 556                 endif()
 557                 find_package(Qt5X11Extras QUIET)
 558                 set(QTVERSION ${Qt5Core_VERSION})
 559                 macro (qt_use_modules)
 560                         qt5_use_modules(${ARGN})
 561                 endmacro()
 562                 macro (qt_add_resources)
 563                         qt5_add_resources(${ARGN})
 564                 endmacro()
 565                 macro (qt_wrap_uifiles)
 566                         qt5_wrap_ui(${ARGN})
 567                 endmacro()
 568                 message(STATUS "Found Qt-Version ${QTVERSION}")
 569         endif()
 570 elseif(LYX_USE_QT MATCHES "QT4")
 571         find_package(Qt4 "4.5.0" REQUIRED)
 572         macro (qt_use_modules)
 573         endmacro()
 574         macro (qt_add_resources)
 575                 qt4_add_resources(${ARGN})
 576         endmacro()
 577         macro (qt_wrap_uifiles)
 578                 qt4_wrap_ui(${ARGN})
 579         endmacro()
 580 else()
 581   message(FATAL_ERROR "Unhandled value for LYX_USE_QT (${LYX_USE_QT})")
 582 endif()
 583
 584 find_package(Magic)
 585 if(Magic_FOUND)
 586         set(HAVE_MAGIC_H 1)
 587 endif()
 588
 589 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 590
 591 set(Spelling_FOUND OFF)
 592 set(Include_used_spellchecker)   # String will be inserted into config.h
 593
 594 foreach(_spell "ASPELL" "Enchant" "Hunspell")
 595   string(TOUPPER ${_spell} _upspell)
 596   find_package(${_spell})
 597   if (${_upspell}_FOUND)
 598     include_directories(${${_upspell}_INCLUDE_DIR})
 599     set(Spelling_FOUND ON)
 600     message(STATUS "Building with USE_${_upspell}")
 601     set(Include_used_spellchecker "${Include_used_spellchecker}#define USE_${_upspell} 1\n")
 602   else()
 603     if(LYX_${_upspell})
 604       message(FATAL_ERROR "Required ${_spell} devel package not found")
 605     else()
 606       message(STATUS "${_upspell} not found, building without ${_spell} support")
 607     endif()
 608   endif()
 609 endforeach()
 610
 611 if(LYX_NLS)
 612         FIND_PROGRAM(LYX_PYTHON_EXECUTABLE python2 python HINTS ${GNUWIN32_DIR}/python)
 613         find_package(LyXGettext)
 614         if(LYX_PYTHON_EXECUTABLE AND GETTEXT_FOUND)
 615                 add_subdirectory(po "${TOP_BINARY_DIR}/po")
 616         else()
 617                 # Install only supplied .gmo-files
 618                 file(GLOB _gmofiles RELATIVE "${TOP_SRC_DIR}/po" "${TOP_SRC_DIR}/po/*.gmo")
 619                 message(STATUS "Installing provided .gmo-files only")
 620                 foreach( _gmo ${_gmofiles})
 621                         string(REGEX REPLACE "\\.gmo$" "" _lang ${_gmo})
 622                         install(FILES "${TOP_SRC_DIR}/po/${_gmo}" DESTINATION ${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}/${_lang}/LC_MESSAGES RENAME ${PACKAGE}.mo)
 623                 endforeach()
 624         endif()
 625 endif()
 626
 627
 628 find_package(ICONV REQUIRED)
 629 find_package(ZLIB REQUIRED)
 630
 631 if(LYX_EXTERNAL_BOOST)
 632         message(STATUS "Searching for boost")
 633         find_package(Boost COMPONENTS signals regex) #TODO could REQUIRED be used
 634         if(Boost_FOUND)
 635                 message(STATUS "Boost found")
 636                 message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 637                 set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 638         else()
 639                 message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 640         endif()
 641 else()
 642         if(LYX_USE_TR1_REGEX)
 643                 set(Lyx_Boost_Libraries boost_signals)
 644         else()
 645                 set(Lyx_Boost_Libraries boost_signals boost_regex)
 646         endif()
 647         add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 648         add_definitions(-DBOOST_SIGNALS_NO_DEPRECATION_WARNING=1)
 649         include_directories(${TOP_SRC_DIR}/boost)
 650         add_subdirectory(boost "${TOP_BINARY_DIR}/boost")
 651 endif()
 652
 653
 654
 655
 656 if(WIN32)
 657         if(NOT LYX_CONSOLE)
 658                 set(WIN32_CONSOLE WIN32)
 659                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARY})
 660         endif()
 661         if(MSVC)
 662                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 663                 # disable checked iterators for msvc release builds to get maximum speed
 664                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 665         else()
 666                 add_definitions(-DWINVER=0x0500)
 667         endif()
 668 endif()
 669
 670 # Compute qt4-version from ${QTVERSION}
 671
 672 message(STATUS "")
 673 foreach(_v PACKAGE PACKAGE_VERSION
 674         PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 675         LYX_ABS_TOP_SRCDIR
 676         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 677         if(NOT DEFINED ${_v})
 678                 message(FATAL_ERROR "${_v} not defined")
 679         endif()
 680         string(SUBSTRING "${_v}                            " 0 28 _v1)
 681         message(STATUS "----- ${_v1}: ${${_v}}")
 682 endforeach(_v)
 683 message(STATUS "")
 684
 685
 686 if(LYX_PCH)
 687         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 688         # Not sure if it works for all non-msvc compilers
 689         include(PCHSupport_26)
 690         configure_file(${TOP_CMAKE_PATH}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
 691         configure_file(${TOP_CMAKE_PATH}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 692         add_definitions(-DLYX_ENABLE_PCH)
 693
 694         if(MSVC)
 695                 macro(lyx_add_msvc_pch name_)
 696                         set_source_files_properties(${${name_}_sources} PROPERTIES
 697                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 698                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
 699                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 700                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
 701                                 ${TOP_BINARY_DIR}/pcheaders.h)
 702                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 703                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 704                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 705                 endmacro(lyx_add_msvc_pch)
 706                 macro(lyx_add_gcc_pch name_)
 707                 endmacro()
 708         else()
 709                 macro(lyx_add_msvc_pch name_)
 710                 endmacro()
 711                 macro(lyx_add_gcc_pch name_)
 712                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT)
 713                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
 714                 endmacro()
 715         endif()
 716 else()
 717         macro(lyx_add_msvc_pch)
 718         endmacro(lyx_add_msvc_pch)
 719         macro(lyx_add_gcc_pch name_)
 720         endmacro()
 721 endif()
 722
 723
 724 if(MSVC)
 725
 726         if(LYX_VLD)
 727                 set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/development/Win32/vld)
 728                 add_subdirectory(${vld_path}/cmake)
 729                 include(${vld_path}/cmake/vld.cmake) # forced include
 730                 set(vld_dll vld)
 731         endif()
 732
 733         if(LYX_WALL)
 734                 # Use the highest warning level
 735                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 736
 737                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 738                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 739                 else()
 740                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 741                 endif()
 742
 743                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 744                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 745                 else()
 746                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 747                 endif()
 748
 749                 # add here warnings which should produce an error /weXXXX
 750                 set(MSVC_W_ERROR   "/we4101 /we4189")
 751                 # add here warnings which should be disabled /wdXXXX
 752                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 753
 754                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 755                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 756                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 757
 758         else()
 759                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 760
 761                 # add here warnings which should produce an error /weXXXX
 762                 set(MSVC_W_ERROR   "/we4101 /we4189")
 763                 # add here warnings which should be disabled /wdXXXX
 764                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 765
 766                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 767                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 768                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 769
 770         endif()
 771
 772         if (NOT Qt5Core_FOUND)
 773                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 774                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 775                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 776         endif()
 777
 778         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 779         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 780         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 781         message(STATUS "")
 782 endif()
 783
 784
 785 if(LYX_DEBUG_GLIBC)
 786         set(_GLIBCXX_DEBUG ON)
 787 endif()
 788
 789 if(LYX_DEBUG_GLIBC_PEDANTIC)
 790         set(_GLIBCXX_DEBUG_PEDANTIC ON)
 791 endif()
 792
 793 # Xcode compiler
 794 if (CMAKE_GENERATOR MATCHES Xcode)
 795         if (XCODE_VERSION VERSION_LESS "5.0")
 796                 # Automatically select the Xcode compiler if not set
 797                 if (NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 798                         # XCode >= 3.1 has gcc 4.2 (up to actual Xcode)
 799                         if (XCODE_VERSION VERSION_GREATER "3.1")
 800                                 SET(CMAKE_XCODE_ATTRIBUTE_GCC_VERSION "com.apple.compilers.llvmgcc42")
 801                         ENDIF(XCODE_VERSION VERSION_GREATER "3.1")
 802                 ENDIF(NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 803                 # Print the selected compiler version
 804         MESSAGE(STATUS "---- Using XCode compiler CMAKE_XCODE_ATTRIBUTE_GCC_VERSION=${CMAKE_XCODE_ATTRIBUTE_GCC_VERSION}")
 805         ENDIF(XCODE_VERSION VERSION_LESS "5.0")
 806 ENDIF(CMAKE_GENERATOR MATCHES Xcode)
 807
 808 if (WIN32 AND Qt5Core_FOUND)
 809         set(Z_PREFIX 1)
 810 endif()
 811
 812 # compiler tests, config.h generation
 813 if(MSVC AND NOT LYX_CONFIGURE_CHECKS)
 814         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.msvc ${TOP_BINARY_DIR}/configCompiler.h)
 815 else()
 816         include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
 817         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
 818 endif()
 819
 820 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
 821
 822 if(QTVERSION MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+).*")
 823         MATH(EXPR QT4_VERSION "(${CMAKE_MATCH_1}<<16)|(${CMAKE_MATCH_2}<<8)|${CMAKE_MATCH_3}")
 824 endif()
 825
 826
 827 set (cmd ${CMAKE_CTEST_COMMAND})
 828 if (MSVC)
 829         set (cmd ${cmd} -C ${CMAKE_CFG_INTDIR})
 830 else ()
 831         set (cmd ${cmd} -C ${CMAKE_BUILD_TYPE})
 832 endif ()
 833 add_custom_target (lyx_run_tests COMMAND ${cmd})
 834 set_target_properties(lyx_run_tests PROPERTIES FOLDER "tests")
 835
 836 if(LYX_ASAN)
 837     set(LYX_CXX_FLAGS "-fsanitize=address -fno-omit-frame-pointer -g")
 838     message(STATUS)
 839     message(STATUS "Address sanitizer enabled. Usage:")
 840     message(STATUS "    wget https://llvm.org/svn/llvm-project/compiler-rt/trunk/lib/asan/scripts/asan_symbolize.py")
 841     message(STATUS "    chmod  +x ./asan_symbolize.py")
 842     message(STATUS "    ./bin/lyx2.2 2>&1 | ./asan_symbolize.py  | c++filt ")
 843     message(STATUS)
 844 endif()
 845
 846 if(LYX_INSTALL)
 847         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 848                 message(STATUS "Python required to create doc!")
 849         else()
 850                 if(UNIX)
 851                         add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
 852                 endif()
 853                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
 854         endif()
 855         include(../Install)
 856 endif()
 857
 858 add_subdirectory(src "${TOP_BINARY_DIR}/src")
 859 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
 860 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
 861 add_subdirectory(lib/examples "${TOP_BINARY_DIR}/lib/examples")
 862 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
 863 add_subdirectory(development/autotests "${TOP_BINARY_DIR}/autotests")
 864 if(LYX_ENABLE_URLTESTS)
 865         add_subdirectory(development/checkurls "${TOP_BINARY_DIR}/checkurls")
 866 endif()
 867
 868 message(STATUS)
 869 message(STATUS "Build params, switch LYX_* options by -DLYX_*=ON or OFF, LYX_* combos by -DLYX_*=value:")
 870 message(STATUS)
 871
 872 LYX_OPTION_LIST_ALL(used)
 873
 874
 875 if(LYX_NLS)
 876         message(STATUS)
 877         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
 878         message(STATUS)
 879         message(STATUS "  * iconv")
 880         message(STATUS "     - header : ${ICONV_HEADER}")
 881         message(STATUS "     - library: ${ICONV_LIBRARY}")
 882         message(STATUS "  * zlib")
 883         message(STATUS "     - header : ${ZLIB_HEADER}")
 884         message(STATUS "     - library: ${ZLIB_LIBRARY}")
 885         message(STATUS)
 886 endif()
 887
 888 # Apple has builtin native spell checker,
 889 # no need to warn for missing Aspell, Hunspell or Enchant
 890 if(NOT Spelling_FOUND AND NOT APPLE)
 891   if(LYX_REQUIRE_SPELLCHECK)
 892     set(_mode "FATAL_ERROR")
 893   else()
 894     set(_mode "STATUS")
 895   endif()
 896   message(${_mode} "No spellcheck libraries found. LyX will be unable use spellchecking")
 897 endif()
 898
 899 include("${TOP_CMAKE_PATH}/LyxPackaging.cmake")
 900
 901 if(ENABLE_DIST)
 902   # Use git to create the source package
 903   # git archive --format=tgz --output=/home/kornel/x.tar.gz master
 904   if(UNIX)
 905     set(DIST_FORMAT tgz)
 906   else()
 907     set(DIST_FORMAT zip)
 908   endif()
 909   set(DIST_NAME ${CMAKE_PROJECT_NAME}-${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}-${CMAKE_SYSTEM_NAME}.${DIST_FORMAT})
 910
 911   add_custom_command(
 912     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME}
 913     COMMAND  ${LYX_GITVERSION} archive --format=${DIST_FORMAT} --output=${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME} master
 914     WORKING_DIRECTORY ${TOP_SRC_DIR})
 915   add_custom_target(git-archive DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME})
 916 endif()
 917
 918 # Last directory to be included so that the fixup code (OS X)
 919 # can be run last
 920 add_subdirectory(development/cmake/post_install)
 921
 922 message(STATUS)