CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 2.6.4)
   8
   9 set(LYX_PROJECT LyX)
  10
  11 enable_testing()
  12
  13 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README ABSOLUTE)
  14 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  15
  16 set(LYX_CMAKE_DIR "development/cmake")
  17 set(TOP_CMAKE_PATH "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}")
  18 set(TOP_MODULE_PATH "${TOP_CMAKE_PATH}/modules")
  19 set(TOP_SCRIPT_PATH "${TOP_CMAKE_PATH}/scripts")
  20
  21 set(CMAKE_MODULE_PATH "${TOP_MODULE_PATH}")
  22
  23 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  24
  25 message(STATUS)
  26 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  27         message(STATUS "Building in-source")
  28         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  29 else()
  30         message(STATUS "Building out-of-source")
  31         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  32 endif()
  33
  34 # This directory should be used if some test uses lyx-executable
  35 set(LYX_TESTS_USERDIR "${TOP_BINARY_DIR}/Testing/.lyx")
  36 file(MAKE_DIRECTORY "${LYX_TESTS_USERDIR}")
  37
  38 if(COMMAND cmake_policy)
  39         cmake_policy(SET CMP0003 OLD)
  40         cmake_policy(SET CMP0005 OLD)
  41 endif()
  42
  43 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  44
  45 # Supress regeneration
  46 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  47
  48 if(NOT help AND NOT HELP)
  49         # 'project' triggers the searching for a compiler
  50         project(${LYX_PROJECT})
  51 endif()
  52
  53 if(UNIX)
  54         set(ARCH_TRIPLET )
  55         FIND_PROGRAM(DPKG_ARCHITECTURE_EXECUTABLE dpkg-architecture)
  56         if(DPKG_ARCHITECTURE_EXECUTABLE)
  57                 EXECUTE_PROCESS(COMMAND ${DPKG_ARCHITECTURE_EXECUTABLE} -qDEB_HOST_MULTIARCH
  58                                 OUTPUT_VARIABLE ARCH_TRIPLET
  59                                 ERROR_VARIABLE ERROR_ARCH_TRIPLET
  60                                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  61         endif()
  62 endif()
  63 if(ARCH_TRIPLET)
  64         set(SYSTEM_LIB_DIRS /usr/lib /usr/lib/${ARCH_TRIPLET} /usr/local/lib)
  65 else()
  66         set(SYSTEM_LIB_DIRS /usr/lib /usr/local/lib)
  67 endif()
  68
  69 include(LyXMacros)
  70
  71 # Usage LYX_OPTION
  72 # 1. parameter: option name without prefix 'LYX_'
  73 # 2. parameter: description
  74 # 3. parameter: default value, ON or OFF
  75 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
  76
  77
  78 LYX_OPTION_INIT()
  79
  80 # Options for all compilers/systems
  81 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
  82 LYX_OPTION(LOCALVERSIONING  "Add version info to created package name (only used if LYX_CPACK option set)" OFF ALL)
  83 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
  84 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
  85 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
  86 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
  87 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
  88 LYX_OPTION(DEVEL_VERSION    "Build developer version" OFF ALL)
  89 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" OFF ALL)
  90 LYX_OPTION(DEBUG            "Enforce debug build"  OFF ALL)
  91 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
  92 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
  93 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
  94 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
  95 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
  96 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
  97 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
  98 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
  99
 100 # GCC specific
 101 LYX_OPTION(PROFILE              "Build profile version" OFF GCC)
 102 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" OFF GCC)
 103 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
 104 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
 105 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++ pedantic debug mode" OFF GCC)
 106 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" OFF GCC)
 107 LYX_OPTION(CONCEPT_CHECKS       "Enable concept-checks" OFF GCC)
 108 LYX_OPTION(PROFILE              "Build with options for gprof" OFF GCC)
 109 LYX_OPTION(ENABLE_CXX11         "Build with options for c++11-mode" OFF GCC)
 110
 111 # MSVC specific
 112 LYX_OPTION(CONSOLE               "Show console on Windows, enforce with =FORCE" ON MSVC)
 113 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
 114 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
 115 LYX_OPTION(CONFIGURE_CHECKS      "Also run configure checks for MSVC" OFF MSVC)
 116 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
 117
 118 # APPLE specific
 119 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
 120 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
 121
 122
 123 if(help OR HELP)
 124         message(STATUS)
 125         message(STATUS "Available options: (dis/enable with -DLYX_*=OFF/ON)")
 126         message(STATUS)
 127         LYX_OPTION_LIST_ALL(help)
 128         message(STATUS)
 129         RETURN()
 130 endif()
 131
 132 # Check option dependencies
 133
 134 if(LYX_DMG)
 135         set(LYX_BUNDLE ON)
 136         set(LYX_CPACK ON)
 137 endif()
 138
 139 if(LYX_CPACK)
 140         set(LYX_INSTALL ON)
 141 endif()
 142
 143 if(LYX_INSTALL)
 144         set(LYX_NLS ON)
 145         if (WIN32)
 146                 set(LYX_HUNSPELL ON)
 147         endif()
 148         if(LYX_CONSOLE MATCHES "FORCE")
 149                 set(LYX_CONSOLE ON)
 150         else()
 151                 set(LYX_CONSOLE OFF)
 152         endif()
 153         set(LYX_PACKAGE_SUFFIX ON)
 154         if(NOT LYX_DEBUG)
 155                 set(LYX_RELEASE ON)
 156         endif()
 157         set(LYX_PROFILE OFF)
 158 endif()
 159
 160
 161 if(LYX_MERGE_FILES)
 162         set(LYX_PCH OFF)
 163 else()
 164         set(LYX_MERGE_REBUILD OFF)
 165 endif()
 166
 167 if(LYX_DEPENDENCIES_DOWNLOAD)
 168         message(STATUS)
 169         set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 170         message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 171         set(deps_files lyx20-deps-msvc2010-x86.zip)
 172         set(deps_server http://downloads.sourceforge.net/project/lyx/Win_installers/Dependencies)
 173         foreach(it ${deps_files})
 174                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 175                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 176                 if(NOT already_downloaded)
 177                         message(STATUS "Downloading ${it} ...")
 178                         file(DOWNLOAD ${deps_server}/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS STATUS status LOG log)
 179                         list(GET status 0 status_code)
 180                         list(GET status 1 status_string)
 181                         if(NOT status_code EQUAL 0)
 182                                 file(REMOVE ${LYX_DEPENDENCIES_DIR}/${it})
 183                                 message(FATAL_ERROR "error: downloading '${it}' failed. status_code: ${status_code}, status_string: ${status_string}. \nLog: ${log} ")
 184                         endif()
 185                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 186                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 187                 endif()
 188         endforeach()
 189         set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/deps20)
 190 endif()
 191
 192
 193
 194 message(STATUS)
 195
 196 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 197 if(WIN32)
 198         set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 199 else()
 200         set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 201 endif()
 202
 203
 204 set(LYX_GCC11_MODE)
 205 if(UNIX OR MINGW)
 206         execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION)
 207         message(STATUS "Using GCC version ${GCC_VERSION}")
 208         if(NOT GCC_VERSION VERSION_LESS 4.4)
 209                 set(LYX_USE_TR1 1)
 210                 # GCC <= 4.5 does not support regex: there are linker errors
 211                 # http://gcc.gnu.org/onlinedocs/libstdc++/manual/status.html#status.iso.tr1
 212                 set(LYX_USE_TR1_REGEX 0)
 213         endif()
 214         if (LYX_ENABLE_CXX11)
 215                 if(GCC_VERSION VERSION_GREATER 4.7)
 216                         set(LYX_GCC11_MODE "-std=gnu++11")
 217                 elseif(GCC_VERSION VERSION_GREATER 4.2)
 218                         set(LYX_GCC11_MODE "-std=gnu++0x")
 219                 endif()
 220         endif()
 221 else()
 222         if(MSVC10)
 223                 set(LYX_USE_TR1 1)
 224                 #set(LYX_USE_TR1_REGEX 1) #TODO should we use it in ECMAScript mode?
 225         endif()
 226 endif()
 227
 228
 229 set(VERSION_INFO "CMake Build")
 230
 231 # Try to get some informations from configure.ac
 232
 233 include(LyXPaths)
 234 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 235
 236 if(WIN32)
 237         set(USE_WINDOWS_PACKAGING ON)
 238 elseif(APPLE)
 239         set(USE_MACOSX_PACKAGING ON)
 240 else()
 241         set(USE_POSIX_PACKAGING ON)
 242 endif()
 243
 244 macro(setstripped _varname)
 245         if(${ARGC} GREATER 1)
 246                 string(STRIP "${ARGV1}" _v)
 247                 if(USE_POSIX_PACKAGING)
 248                         string(TOLOWER ${_v} ${_varname})
 249                 else()
 250                         set(${_varname} ${_v})
 251                 endif()
 252         else()
 253                 set(${_varname})
 254         endif()
 255 endmacro(setstripped)
 256
 257 foreach(_c_l ${_config_lines} )
 258         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 259                 setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 260                 setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 261                 setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 262                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\)\(\\.\([0-9]+\)\)?.*$")
 263                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 264                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 265                         set(LYX_PATCH_VERSION ${CMAKE_MATCH_4})
 266                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 267                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 268                         set(LYX_INSTALL_SUFFIX "${CMAKE_MATCH_1}.${CMAKE_MATCH_2}")
 269                 endif()
 270         endif()
 271         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 272                 set(LYX_DATE "${CMAKE_MATCH_1}")
 273         endif()
 274 endforeach(_c_l)
 275
 276 if (LYX_LOCALVERSIONING)
 277         # Find the revision number and for later use
 278         FIND_PROGRAM(LYX_GITVERSION git)
 279         #message(STATUS "gitversion = ${LYX_GITVERSION}")
 280         if(LYX_GITVERSION)
 281                 EXECUTE_PROCESS(COMMAND ${LYX_GITVERSION} "describe" WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE LYX_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 282                 if (LYX_PACKAGE_RELEASE MATCHES "^2\\.0\\.0\\-\([0-9]+\)\\-.*$")
 283                   # We will add offset of 40000 to get appropriate value to
 284                   # previous svn.
 285                   # We use this value than also to set the package-patch-value
 286                   MATH(EXPR tmp_REVISION_VERSION "(${CMAKE_MATCH_1}+40000)")
 287                   set(LYX_REVISION_VERSION "${LYX_PATCH_VERSION}-${tmp_REVISION_VERSION}git")
 288                   set(ENABLE_DIST ON)
 289                 endif()
 290         else()
 291                 set(LYX_REVISION_VERSION git) #TODO use date
 292         endif()
 293 else()
 294         set(LYX_REVISION_VERSION ${LYX_PATCH_VERSION})
 295 endif()
 296
 297 if(LYX_PROGRAM_SUFFIX)
 298         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 299 else()
 300         set(PROGRAM_SUFFIX "")
 301 endif()
 302
 303 add_custom_target(lyx_version ALL
 304   COMMAND ${CMAKE_COMMAND} -DTOP_SRC_DIR=${TOP_SRC_DIR} -DTOP_CMAKE_PATH=${TOP_CMAKE_PATH} -DTOP_BINARY_DIR=${TOP_BINARY_DIR} -DLYX_DATE=${LYX_DATE} -P ${TOP_SCRIPT_PATH}/LyXGetVersion.cmake
 305   )
 306 set_target_properties(lyx_version PROPERTIES FOLDER "applications")
 307
 308 if(APPLE)
 309         set(osx_bundle_program_name ${PACKAGE_BASE}${PROGRAM_SUFFIX})
 310         configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/Info.plist.in" "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 311 endif()
 312
 313 if(LYX_BUNDLE)
 314         set(LYX_CPACK ON)
 315         message(STATUS)
 316         message(STATUS "Bundle creation is enabled (experimental):")
 317         message(STATUS "    make")
 318         message(STATUS "    make install/strip")
 319         message(STATUS "    make package")
 320         if(APPLE)
 321                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 322                 set(CPACK_BUNDLE_NAME ${PACKAGE_BASE}${PROGRAM_SUFFIX})
 323                 set(CPACK_BUNDLE_PLIST "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 324                 set(LYX_DATA_SUBDIR ${PACKAGE_BASE}${PROGRAM_SUFFIX}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 325                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${PACKAGE_BASE}${PROGRAM_SUFFIX}.app)
 326                 if(NOT LYX_INSTALL_PREFIX)
 327                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 328                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 329                 endif()
 330                 # Change the owner so that the install can work
 331                 install(CODE "set(BU_CHMOD_BUNDLE_ITEMS 1)")
 332         elseif(UNIX)
 333                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 334                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 335                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 336         elseif(WIN32)
 337                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 338         endif()
 339 endif()
 340
 341 if(LYX_INSTALL_PREFIX)
 342         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 343         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 344 endif()
 345 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 346
 347 if(LYX_PACKAGE_SUFFIX)
 348         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 349 else()
 350         set(PACKAGE ${PACKAGE_BASE})
 351 endif()
 352
 353
 354 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 355         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 356         if (UNIX)
 357                 # don't use the default "/usr/local"
 358                 # but respect the user-choice on the command-line
 359                 if(LYX_INSTALL_SUFFIX)
 360                         set(CMAKE_INSTALL_PREFIX "/usr/local/lyx${LYX_INSTALL_SUFFIX}" CACHE PATH "LyX default install prefix" FORCE)
 361                 else()
 362                         set(CMAKE_INSTALL_PREFIX "/usr/local/${LYX_PROJECT}" CACHE PATH "LyX default install prefix" FORCE)
 363                 endif()
 364         endif()
 365         if(WIN32)
 366                 set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 367         endif()
 368 endif()
 369 if(IS_ABSOLUTE)
 370         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 371 else()
 372         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 373 endif()
 374
 375
 376
 377 if(NOT LYX_DATA_SUBDIR)
 378         if (WIN32)
 379                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 380         else()
 381                 set(LYX_DATA_SUBDIR "" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 382         endif()
 383 endif()
 384
 385 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 386 set(LYX_LOCALEDIR "locale")
 387 set(LYX_ABS_INSTALLED_LOCALEDIR "${LYX_ABS_INSTALLED_DATADIR}/${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}")
 388 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 389
 390
 391 if(LYX_INSTALL AND WIN32)
 392         message(STATUS "Configuring NSIS files")
 393         configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 394         configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 395         configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 396         message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 397 endif()
 398
 399 if(NOT GROUP_CODE)
 400         #set(GROUP_CODE "The Golden Code")
 401         set(GROUP_CODE flat)
 402 endif()
 403
 404 # lyx's source files
 405 set(LYX_CPP_FILES *.cpp)
 406 set(LYX_HPP_FILES *.h)
 407 set(LYX_MOC_FILES moc_*.cpp)
 408
 409 include(ProjectSourceGroup)
 410
 411
 412 if(LYX_PROFILE AND NOT MSVC)
 413         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 414         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg")
 415         set(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS}  -pg")
 416 else()
 417         set(LYX_PROFILE OFF)
 418 endif()
 419
 420
 421 if(LYX_NO_OPTIMIZE)
 422         set(CMAKE_BUILD_TYPE None)
 423         set(LYX_DEBUG OFF)
 424         set(LYX_RELEASE OFF)
 425         set(LYX_PROFILE OFF)
 426 elseif(LYX_RELEASE)
 427         set(CMAKE_BUILD_TYPE Release)
 428         set(LYX_DEBUG OFF)
 429         set(LYX_PROFILE OFF)
 430 elseif(LYX_PROFILE)
 431         set(CMAKE_BUILD_TYPE Profile)
 432         set(LYX_DEBUG OFF)
 433 else()
 434         set(CMAKE_BUILD_TYPE Debug)
 435         set(LYX_DEBUG ON)
 436 endif()
 437
 438
 439 # When shared libs are supported enable this option
 440 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 441 if(LYX_SHARED_LIBRARIES)
 442         set(library_type SHARED)
 443 else()
 444         set(library_type STATIC)
 445 endif()
 446
 447 if(NOT MSVC)
 448         if(NOT LYX_QUIET)
 449                 set(CMAKE_VERBOSE_MAKEFILE ON)
 450         endif()
 451         set(LYX_CXX_FLAGS "-Wall -Wunused-parameter ${LYX_GCC11_MODE}")
 452         if(LYX_STDLIB_DEBUG)
 453                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 454         endif()
 455         if(LYX_CONCEPT_CHECKS)
 456                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCPP_CONCEPT_CHECKS")
 457         endif()
 458         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 459         set(CMAKE_CXX_FLAGS_DEBUG "${LYX_CXX_FLAGS} -fno-strict-aliasing -O0 -g3 -D_DEBUG" CACHE TYPE STRING FORCE)
 460         if(MINGW)
 461                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 462         else()
 463                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 464         endif()
 465 endif()
 466
 467 find_package(Qt5Core QUIET)
 468 if (Qt5Core_FOUND)
 469         find_package(Qt5Widgets REQUIRED)
 470         set(QTVERSION ${Qt5Core_VERSION})
 471         macro (qt_use_modules)
 472                 qt5_use_modules(${ARGN})
 473         endmacro()
 474         macro (qt_add_resources)
 475                 qt5_add_resources(${ARGN})
 476         endmacro()
 477         macro (qt_wrap_uifiles)
 478                 qt5_wrap_ui(${ARGN})
 479         endmacro()
 480 else()
 481         find_package(Qt4 "4.5.0" REQUIRED)
 482         macro (qt_use_modules)
 483         endmacro()
 484         macro (qt_add_resources)
 485                 qt4_add_resources(${ARGN})
 486         endmacro()
 487         macro (qt_wrap_uifiles)
 488                 qt4_wrap_ui(${ARGN})
 489         endmacro()
 490 endif()
 491
 492 find_package(Magic)
 493 if(Magic_FOUND)
 494         set(HAVE_MAGIC_H 1)
 495 endif()
 496
 497 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 498
 499 if(LYX_ASPELL)
 500         find_package(ASPELL)
 501         include_directories(${ASPELL_INCLUDE_DIR})
 502 endif()
 503
 504 if(LYX_ENCHANT)
 505         find_package(Enchant REQUIRED)
 506         include_directories(${ENCHANT_INCLUDE_DIR})
 507 endif()
 508
 509 if(LYX_HUNSPELL)
 510         find_package(Hunspell REQUIRED)
 511         include_directories(${HUNSPELL_INCLUDE_DIR})
 512 endif()
 513
 514 if(LYX_NLS)
 515         FIND_PROGRAM(LYX_PYTHON_EXECUTABLE python2 python HINTS ${GNUWIN32_DIR}/python)
 516         find_package(LyXGettext)
 517         if(LYX_PYTHON_EXECUTABLE AND GETTEXT_FOUND)
 518                 add_subdirectory(po "${TOP_BINARY_DIR}/po")
 519         else()
 520                 # Install only supplied .gmo-files
 521                 file(GLOB _gmofiles RELATIVE "${TOP_SRC_DIR}/po" "${TOP_SRC_DIR}/po/*.gmo")
 522                 message(STATUS "Installing provided .gmo-files only")
 523                 foreach( _gmo ${_gmofiles})
 524                         string(REGEX REPLACE "\\.gmo$" "" _lang ${_gmo})
 525                         install(FILES "${TOP_SRC_DIR}/po/${_gmo}" DESTINATION ${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}/${_lang}/LC_MESSAGES RENAME ${PACKAGE}.mo)
 526                 endforeach()
 527         endif()
 528 endif()
 529
 530 find_package(ICONV REQUIRED)
 531 find_package(ZLIB REQUIRED)
 532
 533 if(LYX_EXTERNAL_BOOST)
 534         message(STATUS "Searching for boost")
 535         find_package(Boost COMPONENTS signals regex) #TODO could REQUIRED be used
 536         if(Boost_FOUND)
 537                 message(STATUS "Boost found")
 538                 message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 539                 set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 540         else()
 541                 message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 542         endif()
 543 else()
 544         if(LYX_USE_TR1_REGEX)
 545                 set(Lyx_Boost_Libraries boost_signals)
 546         else()
 547                 set(Lyx_Boost_Libraries boost_signals boost_regex)
 548         endif()
 549         add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 550         include_directories(${TOP_SRC_DIR}/boost)
 551         add_subdirectory(boost "${TOP_BINARY_DIR}/boost")
 552 endif()
 553
 554
 555
 556
 557 if(WIN32)
 558         if(NOT LYX_CONSOLE)
 559                 set(WIN32_CONSOLE WIN32)
 560                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARY})
 561         endif()
 562         if(MSVC)
 563                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 564                 # disable checked iterators for msvc release builds to get maximum speed
 565                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 566         else()
 567                 add_definitions(-DWINVER=0x0500)
 568         endif()
 569 endif()
 570
 571 # Compute qt4-version from ${QTVERSION}
 572
 573 message(STATUS "")
 574 foreach(_v PACKAGE PACKAGE_VERSION
 575         PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 576         LYX_ABS_TOP_SRCDIR
 577         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 578         if(NOT DEFINED ${_v})
 579                 message(FATAL_ERROR "${_v} not defined")
 580         endif()
 581         string(SUBSTRING "${_v}                            " 0 28 _v1)
 582         message(STATUS "----- ${_v1}: ${${_v}}")
 583 endforeach(_v)
 584 message(STATUS "")
 585
 586
 587 if(LYX_PCH)
 588         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 589         # Not sure if it works for all non-msvc compilers
 590         include(PCHSupport_26)
 591         configure_file(${TOP_CMAKE_PATH}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
 592         configure_file(${TOP_CMAKE_PATH}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 593         add_definitions(-DLYX_ENABLE_PCH)
 594
 595         if(MSVC)
 596                 macro(lyx_add_msvc_pch name_)
 597                         set_source_files_properties(${${name_}_sources} PROPERTIES
 598                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 599                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
 600                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 601                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
 602                                 ${TOP_BINARY_DIR}/pcheaders.h)
 603                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 604                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 605                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 606                 endmacro(lyx_add_msvc_pch)
 607                 macro(lyx_add_gcc_pch name_)
 608                 endmacro()
 609         else()
 610                 macro(lyx_add_msvc_pch name_)
 611                 endmacro()
 612                 macro(lyx_add_gcc_pch name_)
 613                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT4)
 614                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
 615                 endmacro()
 616         endif()
 617 else()
 618         macro(lyx_add_msvc_pch)
 619         endmacro(lyx_add_msvc_pch)
 620         macro(lyx_add_gcc_pch name_)
 621         endmacro()
 622 endif()
 623
 624
 625 if(MSVC)
 626
 627         if(LYX_VLD)
 628                 set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/development/Win32/vld)
 629                 add_subdirectory(${vld_path}/cmake)
 630                 include(${vld_path}/cmake/vld.cmake) # forced include
 631                 set(vld_dll vld)
 632         endif()
 633
 634         if(LYX_WALL)
 635                 # Use the highest warning level
 636                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 637
 638                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 639                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 640                 else()
 641                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 642                 endif()
 643
 644                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 645                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 646                 else()
 647                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 648                 endif()
 649
 650                 # add here warnings which should produce an error /weXXXX
 651                 set(MSVC_W_ERROR   "/we4101 /we4189")
 652                 # add here warnings which should be disabled /wdXXXX
 653                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 654
 655                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 656                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 657                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 658
 659         else()
 660                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 661
 662                 # add here warnings which should produce an error /weXXXX
 663                 set(MSVC_W_ERROR   "/we4101 /we4189")
 664                 # add here warnings which should be disabled /wdXXXX
 665                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 666
 667                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 668                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 669                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 670
 671         endif()
 672
 673         if (NOT Qt5Core_FOUND)
 674                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 675                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 676                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 677         endif()
 678
 679         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 680         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 681         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 682         message(STATUS "")
 683 endif()
 684
 685
 686 if(LYX_DEBUG_GLIBC)
 687         set(_GLIBCXX_DEBUG ON)
 688 endif()
 689
 690 if(LYX_DEBUG_GLIBC_PEDANTIC)
 691         set(_GLIBCXX_DEBUG_PEDANTIC ON)
 692 endif()
 693
 694 # Xcode compiler
 695 if (CMAKE_GENERATOR MATCHES Xcode)
 696         # Automatically select the Xcode compiler if not set
 697         if (NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 698                 # XCode >= 3.1 has gcc 4.2 (up to actual Xcode)
 699                 if (XCODE_VERSION VERSION_GREATER "3.1")
 700                         SET(CMAKE_XCODE_ATTRIBUTE_GCC_VERSION "com.apple.compilers.llvmgcc42")
 701                 ENDIF(XCODE_VERSION VERSION_GREATER "3.1")
 702         ENDIF(NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 703
 704         # Print the selected compiler version
 705     MESSAGE(STATUS "---- Using XCode compiler CMAKE_XCODE_ATTRIBUTE_GCC_VERSION=${CMAKE_XCODE_ATTRIBUTE_GCC_VERSION}")
 706 ENDIF(CMAKE_GENERATOR MATCHES Xcode)
 707
 708 if (WIN32 AND Qt5Core_FOUND)
 709         set(Z_PREFIX 1)
 710 endif()
 711
 712 # compiler tests, config.h generation
 713 if(MSVC AND NOT LYX_CONFIGURE_CHECKS)
 714         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.msvc ${TOP_BINARY_DIR}/configCompiler.h)
 715 else()
 716         include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
 717         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
 718 endif()
 719
 720 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
 721
 722 if(QTVERSION MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+).*")
 723         MATH(EXPR QT4_VERSION "(${CMAKE_MATCH_1}<<16)|(${CMAKE_MATCH_2}<<8)|${CMAKE_MATCH_3}")
 724 endif()
 725
 726 set(_lyx "${PACKAGE_BASE}${PROGRAM_SUFFIX}")
 727 set(_tex2lyx tex2lyx${PROGRAM_SUFFIX})
 728
 729 set (cmd ${CMAKE_CTEST_COMMAND})
 730 if (MSVC)
 731         set (cmd ${cmd} -C ${CMAKE_CFG_INTDIR})
 732 else ()
 733         set (cmd ${cmd} -C ${CMAKE_BUILD_TYPE})
 734 endif ()
 735 add_custom_target (lyx_run_tests COMMAND ${cmd})
 736 set_target_properties(lyx_run_tests PROPERTIES FOLDER "tests")
 737
 738
 739 add_subdirectory(src "${TOP_BINARY_DIR}/src")
 740 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
 741 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
 742 add_subdirectory(lib/examples "${TOP_BINARY_DIR}/lib/examples")
 743
 744
 745 if(LYX_INSTALL)
 746         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 747                 message(STATUS "Python required to create doc!")
 748         else()
 749                 add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
 750                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
 751         endif()
 752         if(NOT(LYX_BUNDLE AND APPLE))
 753                 include(../Install)
 754         endif()
 755 endif()
 756
 757 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
 758 add_subdirectory(development/autotests "${TOP_BINARY_DIR}/autotests")
 759
 760 message(STATUS)
 761 message(STATUS "Build options, switch LYX_* variables by -DLYX_*=ON or OFF:")
 762 message(STATUS)
 763 LYX_OPTION_LIST_ALL(used)
 764
 765
 766 if(LYX_NLS)
 767         message(STATUS)
 768         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
 769         message(STATUS)
 770         message(STATUS "  * iconv")
 771         message(STATUS "     - header : ${ICONV_HEADER}")
 772         message(STATUS "     - library: ${ICONV_LIBRARY}")
 773         message(STATUS "  * zlib")
 774         message(STATUS "     - header : ${ZLIB_HEADER}")
 775         message(STATUS "     - library: ${ZLIB_LIBRARY}")
 776         message(STATUS)
 777 endif()
 778
 779 include("${TOP_CMAKE_PATH}/LyxPackaging.cmake")
 780
 781 if(ENABLE_DIST)
 782   # Use git to create the source package
 783   # git archive --format=tgz --output=/home/kornel/x.tar.gz master
 784   if(UNIX)
 785     set(DIST_FORMAT tgz)
 786   else()
 787     set(DIST_FORMAT zip)
 788   endif()
 789   set(DIST_NAME ${CMAKE_PROJECT_NAME}-${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}-${CMAKE_SYSTEM_NAME}.${DIST_FORMAT})
 790
 791   add_custom_command(
 792     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME}
 793     COMMAND  ${LYX_GITVERSION} archive --format=${DIST_FORMAT} --output=${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME} master
 794     WORKING_DIRECTORY ${TOP_SRC_DIR})
 795   add_custom_target(git-archive DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME})
 796 endif()
 797
 798 message(STATUS)