CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 2.6.4)
   8
   9 set(LYX_PROJECT LyX)
  10
  11 enable_testing()
  12
  13 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README ABSOLUTE)
  14 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  15
  16 set(LYX_CMAKE_DIR "development/cmake")
  17 set(TOP_CMAKE_PATH "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}")
  18 set(TOP_MODULE_PATH "${TOP_CMAKE_PATH}/modules")
  19 set(TOP_SCRIPT_PATH "${TOP_CMAKE_PATH}/scripts")
  20
  21 set(CMAKE_MODULE_PATH "${TOP_MODULE_PATH}")
  22
  23 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  24
  25 message(STATUS)
  26 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  27         message(STATUS "Building in-source")
  28         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  29 else()
  30         message(STATUS "Building out-of-source")
  31         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  32 endif()
  33
  34 # This directory should be used if some test uses lyx-executable
  35 set(LYX_TESTS_USERDIR "${TOP_BINARY_DIR}/Testing/.lyx")
  36 file(MAKE_DIRECTORY "${LYX_TESTS_USERDIR}")
  37
  38 if(COMMAND cmake_policy)
  39         cmake_policy(SET CMP0003 OLD)
  40         cmake_policy(SET CMP0005 OLD)
  41         # Installing MACOSX_BUNDLE targets requires a BUNDLE DESTINATION
  42         cmake_policy(SET CMP0006 NEW)
  43 endif()
  44
  45 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  46
  47 # Supress regeneration
  48 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  49
  50 if(NOT help AND NOT HELP)
  51         # 'project' triggers the searching for a compiler
  52         project(${LYX_PROJECT})
  53 endif()
  54
  55 if(UNIX)
  56         set(ARCH_TRIPLET )
  57         FIND_PROGRAM(DPKG_ARCHITECTURE_EXECUTABLE dpkg-architecture)
  58         if(DPKG_ARCHITECTURE_EXECUTABLE)
  59                 EXECUTE_PROCESS(COMMAND ${DPKG_ARCHITECTURE_EXECUTABLE} -qDEB_HOST_MULTIARCH
  60                                 OUTPUT_VARIABLE ARCH_TRIPLET
  61                                 ERROR_VARIABLE ERROR_ARCH_TRIPLET
  62                                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  63         endif()
  64 endif()
  65 if(ARCH_TRIPLET)
  66         set(SYSTEM_LIB_DIRS /usr/lib /usr/lib/${ARCH_TRIPLET} /usr/local/lib)
  67 else()
  68         set(SYSTEM_LIB_DIRS /usr/lib /usr/local/lib)
  69 endif()
  70
  71 include(LyXMacros)
  72
  73 # Usage LYX_OPTION
  74 # 1. parameter: option name without prefix 'LYX_'
  75 # 2. parameter: description
  76 # 3. parameter: default value, ON or OFF
  77 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
  78
  79
  80 LYX_OPTION_INIT()
  81
  82 # Options for all compilers/systems
  83 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
  84 LYX_OPTION(LOCALVERSIONING  "Add version info to created package name (only used if LYX_CPACK option set)" OFF ALL)
  85 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
  86 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
  87 LYX_OPTION(REQUIRE_SPELLCHECK "Abort if no spellchecker available" OFF ALL)
  88 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
  89 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
  90 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
  91 LYX_OPTION(DEVEL_VERSION    "Build developer version" OFF ALL)
  92 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" OFF ALL)
  93 LYX_OPTION(DEBUG            "Enforce debug build"  OFF ALL)
  94 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
  95 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
  96 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
  97 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
  98 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
  99 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
 100 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
 101 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
 102 LYX_OPTION(ENABLE_URLTESTS  "Enable for URL tests" OFF ALL)
 103
 104 # GCC specific
 105 LYX_OPTION(PROFILE              "Build profile version" OFF GCC)
 106 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" OFF GCC)
 107 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
 108 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
 109 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++ pedantic debug mode" OFF GCC)
 110 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" OFF GCC)
 111 LYX_OPTION(CONCEPT_CHECKS       "Enable concept-checks" OFF GCC)
 112 LYX_OPTION(PROFILE              "Build with options for gprof" OFF GCC)
 113 LYX_OPTION(ENABLE_CXX11         "Build with options for c++11-mode" OFF GCC)
 114
 115 # MSVC specific
 116 LYX_OPTION(CONSOLE               "Show console on Windows, enforce with =FORCE" ON MSVC)
 117 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
 118 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
 119 LYX_OPTION(CONFIGURE_CHECKS      "Also run configure checks for MSVC" OFF MSVC)
 120 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
 121
 122 # APPLE specific
 123 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
 124 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
 125
 126
 127 if(help OR HELP)
 128         message(STATUS)
 129         message(STATUS "Available options: (dis/enable with -DLYX_*=OFF/ON)")
 130         message(STATUS)
 131         LYX_OPTION_LIST_ALL(help)
 132         message(STATUS)
 133         RETURN()
 134 endif()
 135
 136 # Check option dependencies
 137
 138 if(LYX_DMG)
 139         set(LYX_BUNDLE ON)
 140         set(LYX_CPACK ON)
 141 endif()
 142
 143 if(LYX_CPACK)
 144         set(LYX_INSTALL ON)
 145 endif()
 146
 147 if(LYX_INSTALL)
 148         set(LYX_NLS ON)
 149         if (WIN32)
 150                 set(LYX_HUNSPELL ON)
 151         endif()
 152         if(LYX_CONSOLE MATCHES "FORCE")
 153                 set(LYX_CONSOLE ON)
 154         else()
 155                 set(LYX_CONSOLE OFF)
 156         endif()
 157         set(LYX_PACKAGE_SUFFIX ON)
 158         if(NOT LYX_DEBUG)
 159                 set(LYX_RELEASE ON)
 160         endif()
 161         set(LYX_PROFILE OFF)
 162 endif()
 163
 164
 165 if(LYX_MERGE_FILES)
 166         set(LYX_PCH OFF)
 167 else()
 168         set(LYX_MERGE_REBUILD OFF)
 169 endif()
 170
 171 if(LYX_DEPENDENCIES_DOWNLOAD)
 172         message(STATUS)
 173         set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 174         message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 175         set(deps_files lyx20-deps-msvc2010-x86.zip)
 176         set(deps_server http://downloads.sourceforge.net/project/lyx/Win_installers/Dependencies)
 177         foreach(it ${deps_files})
 178                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 179                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 180                 if(NOT already_downloaded)
 181                         message(STATUS "Downloading ${it} ...")
 182                         file(DOWNLOAD ${deps_server}/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS STATUS status LOG log)
 183                         list(GET status 0 status_code)
 184                         list(GET status 1 status_string)
 185                         if(NOT status_code EQUAL 0)
 186                                 file(REMOVE ${LYX_DEPENDENCIES_DIR}/${it})
 187                                 message(FATAL_ERROR "error: downloading '${it}' failed. status_code: ${status_code}, status_string: ${status_string}. \nLog: ${log} ")
 188                         endif()
 189                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 190                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 191                 endif()
 192         endforeach()
 193         set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/deps20)
 194 endif()
 195
 196
 197
 198 message(STATUS)
 199
 200 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 201 if(WIN32)
 202         set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 203 else()
 204         set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 205 endif()
 206
 207
 208 set(LYX_GCC11_MODE)
 209 if(UNIX OR MINGW)
 210         execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION)
 211         message(STATUS "Using GCC version ${GCC_VERSION}")
 212         if(NOT GCC_VERSION VERSION_LESS 4.4)
 213                 set(LYX_USE_TR1 1)
 214                 # GCC <= 4.5 does not support regex: there are linker errors
 215                 # http://gcc.gnu.org/onlinedocs/libstdc++/manual/status.html#status.iso.tr1
 216                 set(LYX_USE_TR1_REGEX 0)
 217         endif()
 218         if (LYX_ENABLE_CXX11)
 219                 find_package(CXX11Compiler)
 220                 if(NOT CXX11COMPILER_FOUND)
 221                         message(FATAL_ERROR "A C++11 compatible compiler is required.")
 222                 endif()
 223                 set(LYX_GCC11_MODE "${CXX11_FLAG}")
 224         endif()
 225 else()
 226         if(MSVC10)
 227                 set(LYX_USE_TR1 1)
 228                 #set(LYX_USE_TR1_REGEX 1) #TODO should we use it in ECMAScript mode?
 229         endif()
 230 endif()
 231
 232
 233 set(VERSION_INFO "CMake Build")
 234
 235 # Try to get some informations from configure.ac
 236
 237 include(LyXPaths)
 238 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 239
 240 if(WIN32)
 241         set(USE_WINDOWS_PACKAGING ON)
 242 elseif(APPLE)
 243         set(USE_MACOSX_PACKAGING ON)
 244 else()
 245         set(USE_POSIX_PACKAGING ON)
 246 endif()
 247
 248 macro(setstripped _varname)
 249         if(${ARGC} GREATER 1)
 250                 string(STRIP "${ARGV1}" _v)
 251                 if(USE_POSIX_PACKAGING)
 252                         string(TOLOWER ${_v} ${_varname})
 253                 else()
 254                         set(${_varname} ${_v})
 255                 endif()
 256         else()
 257                 set(${_varname})
 258         endif()
 259 endmacro(setstripped)
 260
 261 foreach(_c_l ${_config_lines} )
 262         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 263                 setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 264                 setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 265                 setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 266                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\)\(\\.\([0-9]+\)\)?.*$")
 267                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 268                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 269                         set(LYX_PATCH_VERSION ${CMAKE_MATCH_4})
 270                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 271                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 272                         set(LYX_INSTALL_SUFFIX "${CMAKE_MATCH_1}.${CMAKE_MATCH_2}")
 273                 endif()
 274         endif()
 275         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 276                 set(LYX_DATE "${CMAKE_MATCH_1}")
 277         endif()
 278 endforeach(_c_l)
 279
 280 if (LYX_LOCALVERSIONING)
 281         # Find the revision number and for later use
 282         FIND_PROGRAM(LYX_GITVERSION git)
 283         #message(STATUS "gitversion = ${LYX_GITVERSION}")
 284         if(LYX_GITVERSION)
 285                 EXECUTE_PROCESS(COMMAND ${LYX_GITVERSION} describe --match 2.0.0 HEAD
 286                 WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE LYX_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 287                 if (LYX_PACKAGE_RELEASE MATCHES "^2\\.0\\.0\\-\([0-9]+\)\\-.*$")
 288                   # We will add offset of 40000 to get appropriate value to
 289                   # previous svn.
 290                   # We use this value than also to set the package-patch-value
 291                   MATH(EXPR tmp_REVISION_VERSION "(${CMAKE_MATCH_1}+40000)")
 292                   set(LYX_REVISION_VERSION "${LYX_PATCH_VERSION}-${tmp_REVISION_VERSION}git")
 293                   set(ENABLE_DIST ON)
 294                 endif()
 295         else()
 296                 set(LYX_REVISION_VERSION git) #TODO use date
 297         endif()
 298 else()
 299         set(LYX_REVISION_VERSION ${LYX_PATCH_VERSION})
 300 endif()
 301
 302 # Set the programs (lyx, tex2lyx, etc.) suffix
 303 # When building an OS X bundle, we will append
 304 # the suffix only to the bundle, not to the programs
 305 set(PROGRAM_SUFFIX "")
 306 if(LYX_PROGRAM_SUFFIX AND NOT (APPLE AND LYX_BUNDLE))
 307         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 308 endif()
 309 set(_lyx "${PACKAGE_BASE}${PROGRAM_SUFFIX}")
 310 set(_tex2lyx tex2lyx${PROGRAM_SUFFIX})
 311
 312 add_custom_target(lyx_version ALL
 313   COMMAND ${CMAKE_COMMAND} -DTOP_SRC_DIR=${TOP_SRC_DIR} -DTOP_CMAKE_PATH=${TOP_CMAKE_PATH} -DTOP_BINARY_DIR=${TOP_BINARY_DIR} -DLYX_DATE=${LYX_DATE} -P ${TOP_SCRIPT_PATH}/LyXGetVersion.cmake
 314   )
 315 set_target_properties(lyx_version PROPERTIES FOLDER "applications")
 316
 317 # Default paths for installed utilities (tex2lyx, lyxclient, etc.)
 318 set(LYX_UTILITIES_INSTALL_PATH bin)
 319
 320 if(LYX_BUNDLE)
 321         set(LYX_CPACK ON)
 322
 323         message(STATUS)
 324         message(STATUS "Bundle creation is enabled (experimental):")
 325         message(STATUS "    make")
 326         message(STATUS "    make install/strip")
 327         message(STATUS "    make package")
 328         if(APPLE)
 329                 set(MACOSX_BUNDLE TRUE)
 330                 # This sets the bundle + executable names
 331                 set(_lyx "${PACKAGE_BASE}${LYX_INSTALL_SUFFIX}")
 332                 # This sets the Info.plist executable name
 333                 set(osx_bundle_program_name ${_lyx})
 334                 # Bundle name
 335                 set(LYX_BUNDLE_NAME ${_lyx})
 336
 337                 # This will contain the list of files that need to be included
 338                 # in the bundle and their location within the bundle
 339                 set(OSX_BUNDLE_FILES "${TOP_SRC_DIR}/development/MacOSX/LyX.sdef;${TOP_SRC_DIR}/development/MacOSX/LyXapp.icns;${CMAKE_BINARY_DIR}/lyxrc.dist")
 340                 set(OSX_BUNDLE_DIRS "Resources;Resources;Resources")
 341
 342                 # Process Info.plist and lyxrc.dist
 343                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/Info.plist.in" "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 344                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/lyxrc.dist.in" "${CMAKE_CURRENT_BINARY_DIR}/lyxrc.dist")
 345
 346                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 347                 set(LYX_DATA_SUBDIR ${LYX_BUNDLE_NAME}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 348
 349                 # Variables used by CPack
 350                 set(CPACK_BUNDLE_NAME ${LYX_BUNDLE_NAME})
 351                 set(CPACK_BUNDLE_PLIST "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 352                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${LYX_BUNDLE_NAME}.app)
 353
 354                 # Set the install paths
 355                 set(LYX_UTILITIES_INSTALL_PATH ${LYX_BUNDLE_NAME}.app/Contents/MacOS)
 356                 if(NOT LYX_INSTALL_PREFIX)
 357                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 358                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 359                 endif()
 360                 # Change the owner so that the install can work
 361                 install(CODE "set(BU_CHMOD_BUNDLE_ITEMS 1)" COMPONENT Runtime)
 362         elseif(UNIX)
 363                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 364                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 365                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 366         elseif(WIN32)
 367                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 368         endif()
 369 endif()
 370
 371 if(LYX_INSTALL_PREFIX)
 372         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 373         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 374 endif()
 375 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 376
 377 string(REGEX REPLACE "/lyx${LYX_INSTALL_SUFFIX}$" "/share" SYSTEM_DATADIR ${CMAKE_INSTALL_PREFIX})
 378
 379 if(LYX_PACKAGE_SUFFIX)
 380         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 381 else()
 382         set(PACKAGE ${PACKAGE_BASE})
 383 endif()
 384
 385 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 386         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 387         if (UNIX)
 388                 # don't use the default "/usr/local"
 389                 # but respect the user-choice on the command-line
 390                 if(LYX_INSTALL_SUFFIX)
 391                         set(CMAKE_INSTALL_PREFIX "/usr/local/lyx${LYX_INSTALL_SUFFIX}" CACHE PATH "LyX default install prefix" FORCE)
 392                 else()
 393                         set(CMAKE_INSTALL_PREFIX "/usr/local/${LYX_PROJECT}" CACHE PATH "LyX default install prefix" FORCE)
 394                 endif()
 395         endif()
 396         if(WIN32)
 397                 set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 398         endif()
 399 endif()
 400 if(IS_ABSOLUTE)
 401         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 402 else()
 403         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 404 endif()
 405
 406
 407
 408 if(NOT LYX_DATA_SUBDIR)
 409         if (WIN32)
 410                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 411         else()
 412                 set(LYX_DATA_SUBDIR "" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 413         endif()
 414 endif()
 415
 416 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 417 set(LYX_LOCALEDIR "locale")
 418 set(LYX_ABS_INSTALLED_LOCALEDIR "${LYX_ABS_INSTALLED_DATADIR}/${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}")
 419 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 420
 421 if(LYX_BUNDLE AND APPLE)
 422         set(LYX_MAN_DIR "${LYX_DATA_SUBDIR}" CACHE STRING "Install location for man pages.")
 423 else()
 424         set(LYX_MAN_DIR "/usr/local/man/man1" CACHE STRING "Install location for man pages.")
 425 endif()
 426 mark_as_advanced(LYX_MAN_DIR)
 427
 428 if(LYX_INSTALL AND WIN32)
 429         message(STATUS "Configuring NSIS files")
 430         configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 431         configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 432         configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 433         message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 434 endif()
 435
 436 if(NOT GROUP_CODE)
 437         #set(GROUP_CODE "The Golden Code")
 438         set(GROUP_CODE flat)
 439 endif()
 440
 441 # lyx's source files
 442 set(LYX_CPP_FILES *.cpp)
 443 set(LYX_HPP_FILES *.h)
 444 set(LYX_MOC_FILES moc_*.cpp)
 445
 446 include(ProjectSourceGroup)
 447
 448
 449 if(LYX_PROFILE AND NOT MSVC)
 450         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 451         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg")
 452         set(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS}  -pg")
 453 else()
 454         set(LYX_PROFILE OFF)
 455 endif()
 456
 457
 458 if(LYX_NO_OPTIMIZE)
 459         set(CMAKE_BUILD_TYPE None)
 460         set(LYX_DEBUG OFF)
 461         set(LYX_RELEASE OFF)
 462         set(LYX_PROFILE OFF)
 463 elseif(LYX_RELEASE)
 464         set(CMAKE_BUILD_TYPE Release)
 465         set(LYX_DEBUG OFF)
 466         set(LYX_PROFILE OFF)
 467 elseif(LYX_PROFILE)
 468         set(CMAKE_BUILD_TYPE Profile)
 469         set(LYX_DEBUG OFF)
 470 else()
 471         set(CMAKE_BUILD_TYPE Debug)
 472         set(LYX_DEBUG ON)
 473 endif()
 474
 475
 476 # When shared libs are supported enable this option
 477 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 478 if(LYX_SHARED_LIBRARIES)
 479         set(library_type SHARED)
 480 else()
 481         set(library_type STATIC)
 482 endif()
 483
 484 if(NOT MSVC)
 485         if(NOT LYX_QUIET)
 486                 set(CMAKE_VERBOSE_MAKEFILE ON)
 487         endif()
 488         set(LYX_CXX_FLAGS "-Wall -Wunused-parameter ${LYX_GCC11_MODE}")
 489         if(LYX_STDLIB_DEBUG)
 490                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 491         endif()
 492         if(LYX_CONCEPT_CHECKS)
 493                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCPP_CONCEPT_CHECKS")
 494         endif()
 495         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 496         set(CMAKE_CXX_FLAGS_DEBUG "${LYX_CXX_FLAGS} -fno-strict-aliasing -O0 -g3 -D_DEBUG" CACHE TYPE STRING FORCE)
 497         if(MINGW)
 498                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 499         else()
 500                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 501         endif()
 502 endif()
 503
 504 set(LYX_CXX_FLAGS_EXTRA "" CACHE STRING "Desired semicolon separated list of extra cxx compile flags, like '-Werror'")
 505 mark_as_advanced(LYX_CXX_FLAGS_EXTRA)
 506 if(LYX_CXX_FLAGS_EXTRA)
 507         foreach(_flag ${LYX_CXX_FLAGS_EXTRA})
 508                 add_definitions(${_flag})
 509         endforeach()
 510 endif()
 511
 512 find_package(Qt5Core QUIET)
 513 if (Qt5Core_FOUND)
 514         find_package(Qt5Widgets REQUIRED)
 515         find_package(Qt5X11Extras)
 516         set(QTVERSION ${Qt5Core_VERSION})
 517         macro (qt_use_modules)
 518                 qt5_use_modules(${ARGN})
 519         endmacro()
 520         macro (qt_add_resources)
 521                 qt5_add_resources(${ARGN})
 522         endmacro()
 523         macro (qt_wrap_uifiles)
 524                 qt5_wrap_ui(${ARGN})
 525         endmacro()
 526 else()
 527         find_package(Qt4 "4.5.0" REQUIRED)
 528         macro (qt_use_modules)
 529         endmacro()
 530         macro (qt_add_resources)
 531                 qt4_add_resources(${ARGN})
 532         endmacro()
 533         macro (qt_wrap_uifiles)
 534                 qt4_wrap_ui(${ARGN})
 535         endmacro()
 536 endif()
 537
 538 find_package(Magic)
 539 if(Magic_FOUND)
 540         set(HAVE_MAGIC_H 1)
 541 endif()
 542
 543 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 544
 545 set(Spelling_FOUND OFF)
 546 set(Include_used_spellchecker)   # String will be inserted into config.h
 547
 548 foreach(_spell "ASPELL" "Enchant" "Hunspell")
 549   string(TOUPPER ${_spell} _upspell)
 550   find_package(${_spell})
 551   if (${_upspell}_FOUND)
 552     include_directories(${${_upspell}_INCLUDE_DIR})
 553     set(Spelling_FOUND ON)
 554     message(STATUS "Building with USE_${_upspell}")
 555     set(Include_used_spellchecker "${Include_used_spellchecker}#define USE_${_upspell} 1\n")
 556   else()
 557     if(LYX_${_upspell})
 558       message(FATAL_ERROR "Required ${_spell} devel package not found")
 559     else()
 560       message(STATUS "${_upspell} not found, building without ${_spell} support")
 561     endif()
 562   endif()
 563 endforeach()
 564
 565 if(LYX_NLS)
 566         FIND_PROGRAM(LYX_PYTHON_EXECUTABLE python2 python HINTS ${GNUWIN32_DIR}/python)
 567         find_package(LyXGettext)
 568         if(LYX_PYTHON_EXECUTABLE AND GETTEXT_FOUND)
 569                 add_subdirectory(po "${TOP_BINARY_DIR}/po")
 570         else()
 571                 # Install only supplied .gmo-files
 572                 file(GLOB _gmofiles RELATIVE "${TOP_SRC_DIR}/po" "${TOP_SRC_DIR}/po/*.gmo")
 573                 message(STATUS "Installing provided .gmo-files only")
 574                 foreach( _gmo ${_gmofiles})
 575                         string(REGEX REPLACE "\\.gmo$" "" _lang ${_gmo})
 576                         install(FILES "${TOP_SRC_DIR}/po/${_gmo}" DESTINATION ${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}/${_lang}/LC_MESSAGES RENAME ${PACKAGE}.mo)
 577                 endforeach()
 578         endif()
 579 endif()
 580
 581 find_package(ICONV REQUIRED)
 582 find_package(ZLIB REQUIRED)
 583
 584 if(LYX_EXTERNAL_BOOST)
 585         message(STATUS "Searching for boost")
 586         find_package(Boost COMPONENTS signals regex) #TODO could REQUIRED be used
 587         if(Boost_FOUND)
 588                 message(STATUS "Boost found")
 589                 message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 590                 set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 591         else()
 592                 message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 593         endif()
 594 else()
 595         if(LYX_USE_TR1_REGEX)
 596                 set(Lyx_Boost_Libraries boost_signals)
 597         else()
 598                 set(Lyx_Boost_Libraries boost_signals boost_regex)
 599         endif()
 600         add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 601         add_definitions(-DBOOST_SIGNALS_NO_DEPRECATION_WARNING=1)
 602         include_directories(${TOP_SRC_DIR}/boost)
 603         add_subdirectory(boost "${TOP_BINARY_DIR}/boost")
 604 endif()
 605
 606
 607
 608
 609 if(WIN32)
 610         if(NOT LYX_CONSOLE)
 611                 set(WIN32_CONSOLE WIN32)
 612                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARY})
 613         endif()
 614         if(MSVC)
 615                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 616                 # disable checked iterators for msvc release builds to get maximum speed
 617                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 618         else()
 619                 add_definitions(-DWINVER=0x0500)
 620         endif()
 621 endif()
 622
 623 # Compute qt4-version from ${QTVERSION}
 624
 625 message(STATUS "")
 626 foreach(_v PACKAGE PACKAGE_VERSION
 627         PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 628         LYX_ABS_TOP_SRCDIR
 629         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 630         if(NOT DEFINED ${_v})
 631                 message(FATAL_ERROR "${_v} not defined")
 632         endif()
 633         string(SUBSTRING "${_v}                            " 0 28 _v1)
 634         message(STATUS "----- ${_v1}: ${${_v}}")
 635 endforeach(_v)
 636 message(STATUS "")
 637
 638
 639 if(LYX_PCH)
 640         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 641         # Not sure if it works for all non-msvc compilers
 642         include(PCHSupport_26)
 643         configure_file(${TOP_CMAKE_PATH}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
 644         configure_file(${TOP_CMAKE_PATH}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 645         add_definitions(-DLYX_ENABLE_PCH)
 646
 647         if(MSVC)
 648                 macro(lyx_add_msvc_pch name_)
 649                         set_source_files_properties(${${name_}_sources} PROPERTIES
 650                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 651                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
 652                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 653                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
 654                                 ${TOP_BINARY_DIR}/pcheaders.h)
 655                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 656                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 657                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 658                 endmacro(lyx_add_msvc_pch)
 659                 macro(lyx_add_gcc_pch name_)
 660                 endmacro()
 661         else()
 662                 macro(lyx_add_msvc_pch name_)
 663                 endmacro()
 664                 macro(lyx_add_gcc_pch name_)
 665                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT4)
 666                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
 667                 endmacro()
 668         endif()
 669 else()
 670         macro(lyx_add_msvc_pch)
 671         endmacro(lyx_add_msvc_pch)
 672         macro(lyx_add_gcc_pch name_)
 673         endmacro()
 674 endif()
 675
 676
 677 if(MSVC)
 678
 679         if(LYX_VLD)
 680                 set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/development/Win32/vld)
 681                 add_subdirectory(${vld_path}/cmake)
 682                 include(${vld_path}/cmake/vld.cmake) # forced include
 683                 set(vld_dll vld)
 684         endif()
 685
 686         if(LYX_WALL)
 687                 # Use the highest warning level
 688                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 689
 690                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 691                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 692                 else()
 693                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 694                 endif()
 695
 696                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 697                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 698                 else()
 699                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 700                 endif()
 701
 702                 # add here warnings which should produce an error /weXXXX
 703                 set(MSVC_W_ERROR   "/we4101 /we4189")
 704                 # add here warnings which should be disabled /wdXXXX
 705                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 706
 707                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 708                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 709                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 710
 711         else()
 712                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 713
 714                 # add here warnings which should produce an error /weXXXX
 715                 set(MSVC_W_ERROR   "/we4101 /we4189")
 716                 # add here warnings which should be disabled /wdXXXX
 717                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 718
 719                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 720                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 721                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 722
 723         endif()
 724
 725         if (NOT Qt5Core_FOUND)
 726                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 727                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 728                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 729         endif()
 730
 731         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 732         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 733         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 734         message(STATUS "")
 735 endif()
 736
 737
 738 if(LYX_DEBUG_GLIBC)
 739         set(_GLIBCXX_DEBUG ON)
 740 endif()
 741
 742 if(LYX_DEBUG_GLIBC_PEDANTIC)
 743         set(_GLIBCXX_DEBUG_PEDANTIC ON)
 744 endif()
 745
 746 # Xcode compiler
 747 if (CMAKE_GENERATOR MATCHES Xcode)
 748         if (XCODE_VERSION VERSION_LESS "5.0")
 749                 # Automatically select the Xcode compiler if not set
 750                 if (NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 751                         # XCode >= 3.1 has gcc 4.2 (up to actual Xcode)
 752                         if (XCODE_VERSION VERSION_GREATER "3.1")
 753                                 SET(CMAKE_XCODE_ATTRIBUTE_GCC_VERSION "com.apple.compilers.llvmgcc42")
 754                         ENDIF(XCODE_VERSION VERSION_GREATER "3.1")
 755                 ENDIF(NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 756                 # Print the selected compiler version
 757         MESSAGE(STATUS "---- Using XCode compiler CMAKE_XCODE_ATTRIBUTE_GCC_VERSION=${CMAKE_XCODE_ATTRIBUTE_GCC_VERSION}")
 758         ENDIF(XCODE_VERSION VERSION_LESS "5.0")
 759 ENDIF(CMAKE_GENERATOR MATCHES Xcode)
 760
 761 if (WIN32 AND Qt5Core_FOUND)
 762         set(Z_PREFIX 1)
 763 endif()
 764
 765 # compiler tests, config.h generation
 766 if(MSVC AND NOT LYX_CONFIGURE_CHECKS)
 767         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.msvc ${TOP_BINARY_DIR}/configCompiler.h)
 768 else()
 769         include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
 770         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
 771 endif()
 772
 773 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
 774
 775 if(QTVERSION MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+).*")
 776         MATH(EXPR QT4_VERSION "(${CMAKE_MATCH_1}<<16)|(${CMAKE_MATCH_2}<<8)|${CMAKE_MATCH_3}")
 777 endif()
 778
 779
 780 set (cmd ${CMAKE_CTEST_COMMAND})
 781 if (MSVC)
 782         set (cmd ${cmd} -C ${CMAKE_CFG_INTDIR})
 783 else ()
 784         set (cmd ${cmd} -C ${CMAKE_BUILD_TYPE})
 785 endif ()
 786 add_custom_target (lyx_run_tests COMMAND ${cmd})
 787 set_target_properties(lyx_run_tests PROPERTIES FOLDER "tests")
 788
 789
 790 if(LYX_INSTALL)
 791         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 792                 message(STATUS "Python required to create doc!")
 793         else()
 794                 add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
 795                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
 796         endif()
 797         include(../Install)
 798 endif()
 799
 800 add_subdirectory(src "${TOP_BINARY_DIR}/src")
 801 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
 802 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
 803 add_subdirectory(lib/examples "${TOP_BINARY_DIR}/lib/examples")
 804 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
 805 add_subdirectory(development/autotests "${TOP_BINARY_DIR}/autotests")
 806 if(LYX_ENABLE_URLTESTS)
 807         add_subdirectory(development/checkurls "${TOP_BINARY_DIR}/checkurls")
 808 endif()
 809
 810 message(STATUS)
 811 message(STATUS "Build options, switch LYX_* variables by -DLYX_*=ON or OFF:")
 812 message(STATUS)
 813 LYX_OPTION_LIST_ALL(used)
 814
 815
 816 if(LYX_NLS)
 817         message(STATUS)
 818         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
 819         message(STATUS)
 820         message(STATUS "  * iconv")
 821         message(STATUS "     - header : ${ICONV_HEADER}")
 822         message(STATUS "     - library: ${ICONV_LIBRARY}")
 823         message(STATUS "  * zlib")
 824         message(STATUS "     - header : ${ZLIB_HEADER}")
 825         message(STATUS "     - library: ${ZLIB_LIBRARY}")
 826         message(STATUS)
 827 endif()
 828
 829 if(NOT Spelling_FOUND)
 830   if(LYX_REQUIRE_SPELLCHECK)
 831     set(_mode "FATAL_ERROR")
 832   else()
 833     set(_mode "STATUS")
 834   endif()
 835   message(${_mode} "No spellcheck libraries found. Lyx will be unable use spellchecking")
 836 endif()
 837
 838 include("${TOP_CMAKE_PATH}/LyxPackaging.cmake")
 839
 840 if(ENABLE_DIST)
 841   # Use git to create the source package
 842   # git archive --format=tgz --output=/home/kornel/x.tar.gz master
 843   if(UNIX)
 844     set(DIST_FORMAT tgz)
 845   else()
 846     set(DIST_FORMAT zip)
 847   endif()
 848   set(DIST_NAME ${CMAKE_PROJECT_NAME}-${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}-${CMAKE_SYSTEM_NAME}.${DIST_FORMAT})
 849
 850   add_custom_command(
 851     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME}
 852     COMMAND  ${LYX_GITVERSION} archive --format=${DIST_FORMAT} --output=${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME} master
 853     WORKING_DIRECTORY ${TOP_SRC_DIR})
 854   add_custom_target(git-archive DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME})
 855 endif()
 856
 857 # Last directory to be included so that the fixup code (OS X)
 858 # can be run last
 859 add_subdirectory(development/cmake/post_install)
 860
 861 message(STATUS)