CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2020 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 3.1.0)
   8
   9 set(LYX_PROJECT LyX)
  10 # Instruct cmake to not use gnu extensions,
  11 # this prevents the mix of '-std=c++*' and '-std=gnu++*' flags
  12 set(CMAKE_CXX_EXTENSIONS OFF)
  13
  14 enable_testing()
  15
  16 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README REALPATH) # Resolve symlinks
  17 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  18 message(STATUS "TOP_SRC_DIR = ${TOP_SRC_DIR}")
  19
  20 set(LYX_CMAKE_DIR "development/cmake")
  21 set(TOP_CMAKE_PATH "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}")
  22 set(TOP_MODULE_PATH "${TOP_CMAKE_PATH}/modules")
  23 set(TOP_SCRIPT_PATH "${TOP_CMAKE_PATH}/scripts")
  24
  25 set(CMAKE_MODULE_PATH "${TOP_MODULE_PATH}")
  26
  27 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  28
  29 message(STATUS)
  30 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  31         message(STATUS "Building in-source")
  32         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  33 else()
  34         message(STATUS "Building out-of-source")
  35         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  36 endif()
  37
  38 # This directory should be used if some test uses lyx-executable
  39 set(LYX_TESTS_USERDIR "${TOP_BINARY_DIR}/Testing/.lyx")
  40 file(MAKE_DIRECTORY "${LYX_TESTS_USERDIR}")
  41
  42 if(COMMAND cmake_policy)
  43         # Installing MACOSX_BUNDLE targets requires a BUNDLE DESTINATION
  44         cmake_policy(SET CMP0006 NEW)
  45         if(POLICY CMP0043)
  46                 # COMPILE_DEFINITIONS are not used yet. Enable new behavior.
  47                 cmake_policy(SET CMP0043 NEW)
  48         endif()
  49         cmake_policy(SET CMP0020 NEW)
  50         if(POLICY CMP0075)
  51                 cmake_policy(SET CMP0075 NEW)
  52         endif()
  53         if(POLICY CMP0077)
  54                 cmake_policy(SET CMP0077 NEW)
  55         endif()
  56 endif()
  57
  58 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  59
  60 # Supress regeneration
  61 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  62
  63 if(LYX_XMINGW)
  64     set(CMAKE_SYSTEM_NAME Windows)
  65     set(TOOLNAME ${LYX_XMINGW})
  66     set(TOOLCHAIN "${TOOLNAME}-")
  67     set(CMAKE_C_COMPILER   "${TOOLCHAIN}gcc"     CACHE PATH "Mingw C compiler" FORCE)
  68     set(CMAKE_CXX_COMPILER "${TOOLCHAIN}g++"     CACHE PATH "Mingw C++ compiler" FORCE)
  69     set(CMAKE_RC_COMPILER  "${TOOLCHAIN}windres" CACHE PATH "Mingw rc compiler" FORCE)
  70
  71     set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM BOTH)
  72     set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY)
  73     set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY)
  74 endif()
  75
  76 if(NOT help AND NOT HELP)
  77   # 'project' triggers the searching for a compiler
  78   project(${LYX_PROJECT})
  79   if (CMAKE_COMPILER_IS_GNUCXX)
  80     if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS "4.9")
  81       message(STATUS "Gnu CXX compiler version = ${CMAKE_CXX_COMPILER_VERSION}")
  82       message(STATUS "is too old, should be >= 4.9")
  83       message(FATAL_ERROR "Exiting")
  84     endif()
  85   endif()
  86 endif()
  87
  88 if(UNIX)
  89         set(ARCH_TRIPLET )
  90         FIND_PROGRAM(DPKG_ARCHITECTURE_EXECUTABLE dpkg-architecture)
  91         if(DPKG_ARCHITECTURE_EXECUTABLE)
  92                 EXECUTE_PROCESS(COMMAND ${DPKG_ARCHITECTURE_EXECUTABLE} -qDEB_HOST_MULTIARCH
  93                                 OUTPUT_VARIABLE ARCH_TRIPLET
  94                                 ERROR_VARIABLE ERROR_ARCH_TRIPLET
  95                                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  96         endif()
  97 endif()
  98 if(ARCH_TRIPLET)
  99         set(SYSTEM_LIB_DIRS /usr/lib /usr/lib/${ARCH_TRIPLET} /usr/local/lib)
 100 else()
 101         set(SYSTEM_LIB_DIRS /usr/lib /usr/local/lib)
 102 endif()
 103
 104 include(LyXMacros)
 105 include(LyXDestinations)
 106
 107 # Value of USE_POSIX_PACKAGING is needed in determineversionandbuildtype()
 108 if(WIN32)
 109         set(CMAKE_PREFIX_PATH Specify-path-to-Qt CACHE PATH "Used Qt version")
 110         if(MSVC)
 111                 set(LYX_3RDPARTY_BUILD ON CACHE BOOL "Build 3rdparty libraries" FORCE)
 112         endif()
 113         set(USE_WINDOWS_PACKAGING ON)
 114 elseif(APPLE)
 115         set(USE_MACOSX_PACKAGING ON)
 116 else()
 117         set(USE_POSIX_PACKAGING ON)
 118 endif()
 119
 120 determineversionandbuildtype("${TOP_SRC_DIR}/configure.ac" _package_list _version_list _envlist LYX_DATE LYX_BUILD_TYPE)
 121 list(GET _package_list 0 PACKAGE_BASE)
 122 list(GET _package_list 1 PACKAGE_VERSION)
 123 list(GET _package_list 2 PACKAGE_BUGREPORT)
 124 list(GET _envlist 0 LYX_DIR_VER)
 125 list(GET _envlist 1 LYX_USERDIR_VER)
 126 list(GET _version_list 0 LYX_VERSION)
 127 list(GET _version_list 1 LYX_MAJOR_VERSION)
 128 list(GET _version_list 2 LYX_MINOR_VERSION)
 129 list(GET _version_list 3 LYX_RELEASE_LEVEL)
 130 list(GET _version_list 4 LYX_RELEASE_PATCH)
 131
 132 # Usage LYX_OPTION
 133 # 1. parameter: option name without prefix 'LYX_'
 134 # 2. parameter: description
 135 # 3. parameter: default value, ON or OFF
 136 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
 137
 138 # Usage LYX_COMBO
 139 # 1. parameter: name without prefix 'LYX_'
 140 # 2. parameter: description
 141 # 3. parameter: default value
 142 # 4-n parameter: possible other string values
 143
 144 LYX_OPTION_INIT()
 145 LYX_COMBO(ENABLE_BUILD_TYPE  "Allows to tweak the compiled code" AUTO release prerelease development gprof)
 146
 147 if(LYX_ENABLE_BUILD_TYPE MATCHES "AUTO")
 148   message(STATUS "Selecting build type defaults from configure.ac")
 149 else()
 150   set(LYX_BUILD_TYPE "${LYX_ENABLE_BUILD_TYPE}")
 151   message(STATUS "Selecting build type defaults from LYX_ENABLE_BUILD_TYPE")
 152 endif()
 153
 154 # Select some defaults depending on LYX_BUILD_TYPE
 155 # they can always be overwritten by the respective command line settings
 156 # These settings are only effective on fresh(==empty) CMakeCache.txt
 157 if(LYX_BUILD_TYPE STREQUAL "development")
 158   set(DefaultLyxDebug ON)
 159   set(DefaultLyxRelease OFF)
 160   set(DefaultLyxStdlibDebug ON)
 161   set(DefaultLyxEnableAssertions ON)
 162   set(DefaultLyxProfile OFF)
 163   set(DefaultExternalLibs OFF)
 164 elseif(LYX_BUILD_TYPE STREQUAL "prerelease")
 165   set(DefaultLyxDebug OFF)
 166   set(DefaultLyxRelease OFF)
 167   set(DefaultLyxStdlibDebug OFF)
 168   set(DefaultLyxEnableAssertions OFF)
 169   set(DefaultLyxProfile OFF)
 170   set(DefaultExternalLibs ON)
 171 elseif(LYX_BUILD_TYPE STREQUAL "release")
 172   set(DefaultLyxDebug OFF)
 173   set(DefaultLyxRelease ON)
 174   set(DefaultLyxStdlibDebug OFF)
 175   set(DefaultLyxEnableAssertions OFF)
 176   set(DefaultLyxProfile OFF)
 177   set(DefaultExternalLibs ON)
 178 elseif(LYX_BUILD_TYPE STREQUAL "gprof")
 179   set(DefaultLyxDebug ON)
 180   set(DefaultLyxRelease OFF)
 181   set(DefaultLyxStdlibDebug OFF)
 182   set(DefaultLyxEnableAssertions OFF)
 183   set(DefaultLyxProfile ON)
 184   set(DefaultExternalLibs OFF)
 185 else()
 186   message(FATAL_ERROR "Invalid build type (${LYX_BUILD_TYPE}) encountered")
 187 endif()
 188
 189 # Options for all compilers/systems
 190 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
 191 LYX_OPTION(LOCALVERSIONING  "Add version info to created package name (only used if LYX_CPACK option set)" OFF ALL)
 192 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
 193 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
 194 LYX_OPTION(REQUIRE_SPELLCHECK "Abort if no spellchecker available" OFF ALL)
 195 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
 196 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
 197 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
 198 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" ${DefaultLyxRelease} ALL)
 199 LYX_OPTION(DEBUG            "Enforce debug build"  ${DefaultLyxDebug} ALL)
 200 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
 201 LYX_OPTION(ENABLE_ASSERTIONS "Run sanity checks in the program"  ${DefaultLyxEnableAssertions} ALL)
 202 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
 203 LYX_STRING(SUFFIX_VALUE     "Use this string as suffix" "")
 204 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
 205 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
 206 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
 207 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
 208 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
 209 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
 210 LYX_OPTION(ENABLE_URLTESTS  "Enable for URL tests" OFF ALL)
 211 LYX_OPTION(ENABLE_EXPORT_TESTS "Enable for export tests" OFF ALL)
 212 LYX_OPTION(ENABLE_KEYTESTS  "Enable for keytests" OFF ALL)
 213 if (NOT CMAKE_VERSION VERSION_LESS "3.17")
 214   LYX_OPTION(ENABLE_VALGRIND_TESTS  "Enable for tests involving valgrind" OFF ALL)
 215 else()
 216   if (LYX_ENABLE_VALGRIND_TESTS)
 217     unset(LYX_ENABLE_VALGRIND_TESTS CACHE)
 218   endif()
 219 endif()
 220 LYX_COMBO(DEBUG_SANITIZE    "Use sanitize check" NONE ADDRESS UNSPECIFIED)
 221 #LYX_COMBO(USE_FILEDIALOG    "Use native or QT file dialog" QT NATIVE)
 222 LYX_COMBO(USE_QT            "Use Qt version as frontend" AUTO QT5 QT6)
 223 LYX_COMBO(USE_IPO           "Interprocedural optimization" OFF AUTO ON)
 224 #LYX_OPTION(3RDPARTY_BUILD   "Build 3rdparty libs" OFF ALL)
 225 LYX_OPTION(DISABLE_CALLSTACK_PRINTING "do not print a callstack when crashing" OFF ALL)
 226 LYX_OPTION(EXTERNAL_Z       "OFF := Build 3rdparty lib zlib" ${DefaultExternalLibs} ALL)
 227 LYX_OPTION(EXTERNAL_DTL     "OFF := Build 3rdparty commands dt2dv and dv2dt" ${DefaultExternalLibs} ALL)
 228 LYX_OPTION(EXTERNAL_ICONV   "OFF := Build 3rdparty lib iconvlib" ${DefaultExternalLibs} ALL)
 229 LYX_OPTION(EXTERNAL_HUNSPELL "OFF := Build 3rdparty lib hunspelllib" ${DefaultExternalLibs} ALL)
 230 LYX_COMBO(EXTERNAL_MYTHES   "OFF := Build 3rdparty lib mytheslib" AUTO OFF ON)
 231
 232 # GCC specific
 233 LYX_OPTION(PROFILE              "Build with options for gprof" ${DefaultLyxProfile} GCC)
 234 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" ${DefaultExternalLibs} GCC)
 235 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
 236 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
 237 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++ pedantic debug mode" OFF GCC)
 238 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" ${DefaultLyxStdlibDebug} GCC)
 239
 240 # MSVC specific
 241 LYX_OPTION(CONSOLE               "Show console on Windows" ON MSVC)
 242 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
 243 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
 244 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
 245
 246 # APPLE specific
 247 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
 248 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
 249
 250 # On Windows, download the dependencies if need be.
 251 if(LYX_DEPENDENCIES_DOWNLOAD)
 252         message(STATUS)
 253         # Do not check for bitness against CMAKE_SIZEOF_VOID_P, as it relates to the bitness of the CMake executable,
 254         # not that of the compiler.
 255         if(MSVC_VERSION GREATER_EQUAL 1920 AND "${CMAKE_CXX_COMPILER_ARCHITECTURE_ID}" MATCHES "x64")
 256                 set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2019-deps-64)
 257                 set(deps_files lyx-windows-deps-msvc2019_64.zip)
 258                 set(deps_server http://ftp.lyx.org/pub/lyx/devel/win_deps)
 259                 set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2019-64)
 260         elseif(MSVC_VERSION GREATER_EQUAL 1920)
 261                 set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2019-deps)
 262                 set(deps_files lyx-windows-deps-msvc2019_32.zip)
 263                 set(deps_server http://ftp.lyx.org/pub/lyx/devel/win_deps)
 264                 set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2019)
 265         elseif(MSVC_VERSION GREATER_EQUAL 1900 AND NOT "${CMAKE_CXX_COMPILER_ARCHITECTURE_ID}" MATCHES "x64")
 266                 set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2015-deps)
 267                 set(deps_files lyx-windows-deps-msvc2015.zip)
 268                 set(deps_server http://ftp.lyx.org/pub/lyx/devel/win_deps)
 269                 set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2015)
 270         else()
 271                 message(FATAL_ERROR "error: no dependency package known for the selected MSVC version.")
 272         endif()
 273         message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 274         foreach(it ${deps_files})
 275                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 276                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 277                 if(NOT already_downloaded)
 278                         message(STATUS "Downloading ${it} ...")
 279                         file(DOWNLOAD ${deps_server}/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS STATUS status LOG log)
 280                         list(GET status 0 status_code)
 281                         list(GET status 1 status_string)
 282                         if(NOT status_code EQUAL 0)
 283                                 file(REMOVE ${LYX_DEPENDENCIES_DIR}/${it})
 284                                 message(FATAL_ERROR "error: downloading '${it}' failed. status_code: ${status_code}, status_string: ${status_string}. \nLog: ${log} ")
 285                         endif()
 286                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 287                                         WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 288                 endif()
 289         endforeach()
 290 endif()
 291
 292 # Try to get some information from configure.ac
 293 include(LyXPaths)
 294
 295
 296 if(help OR HELP)
 297         message(STATUS)
 298         message(STATUS "Available options: (dis/enable with -DLYX_*=OFF/ON)")
 299         message(STATUS)
 300         LYX_OPTION_LIST_ALL(help)
 301         message(STATUS)
 302         unset(help CACHE)
 303         unset(HELP CACHE)
 304         RETURN()
 305 endif()
 306
 307 if ("${LYX_SUFFIX_VALUE}" MATCHES "")
 308   set(LYX_INSTALL_SUFFIX "${LYX_MAJOR_VERSION}.${LYX_MINOR_VERSION}")
 309 else()
 310   set(LYX_INSTALL_SUFFIX "${LYX_SUFFIX_VALUE}")
 311 endif()
 312
 313 # Check option dependencies
 314 if (LYX_ENABLE_VALGRIND_TESTS)
 315         find_program(VALGRIND_EXECUTABLE "valgrind")
 316         if (NOT VALGRIND_EXECUTABLE)
 317                 message(FATAL_ERROR "Cannot use valgrind tests, executable valgrind is missing. Please disable LYX_ENABLE_VALGRIND_TESTS")
 318         endif()
 319 endif()
 320 if (LYX_DEBUG_GLIBC OR LYX_DEBUG_GLIBC_PEDANTIC OR LYX_STDLIB_DEBUG)
 321   if (LYX_EXTERNAL_BOOST)
 322     message(FATAL_ERROR "Using external boost not compatible with debug mode for stdlib")
 323   endif()
 324 endif()
 325
 326 if(LYX_DMG)
 327         set(LYX_BUNDLE ON)
 328         set(LYX_CPACK ON)
 329 endif()
 330
 331 if(LYX_CPACK)
 332         set(LYX_INSTALL ON)
 333 endif()
 334
 335 if(LYX_INSTALL)
 336         set(LYX_NLS ON)
 337         if(WIN32 AND NOT MINGW)
 338                 set(LYX_HUNSPELL ON)
 339         endif()
 340         set(LYX_PACKAGE_SUFFIX ON)
 341         if(NOT LYX_DEBUG)
 342                 set(LYX_RELEASE ON)
 343         endif()
 344         set(LYX_PROFILE OFF)
 345 endif()
 346
 347
 348 if(LYX_MERGE_FILES)
 349         set(LYX_PCH OFF)
 350 else()
 351         set(LYX_MERGE_REBUILD OFF)
 352 endif()
 353
 354 message(STATUS)
 355
 356 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 357 if(WIN32)
 358         set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 359 else()
 360         set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 361 endif()
 362
 363 set(LYX_IPO_SUPPORTED OFF)
 364 if (POLICY CMP0069)
 365   cmake_policy(SET CMP0069 NEW)
 366   if(LYX_USE_IPO MATCHES "AUTO")
 367     # Enable LTO if supported and not debugging
 368     if (NOT LYX_DEBUG)
 369       include(CheckIPOSupported)
 370       check_ipo_supported(RESULT LYX_IPO_SUPPORTED)
 371     endif()
 372   else()
 373     set(LYX_IPO_SUPPORTED ${LYX_USE_IPO})
 374   endif()
 375 endif()
 376 if (LYX_IPO_SUPPORTED)
 377   set(LYX_USE_IPO "ON" CACHE STRING "Use interprocedural optimization" FORCE)
 378 else()
 379   set(LYX_USE_IPO "OFF" CACHE STRING "Use interprocedural optimization" FORCE)
 380 endif()
 381
 382 # Set to some meaningful default
 383 find_package(CXX11Compiler)
 384 if(NOT CXX11COMPILER_FOUND)
 385         message(FATAL_ERROR "A C++11 compatible compiler is required.")
 386 endif()
 387 unset(LYX_GCC11_MODE)
 388 if(UNIX OR MINGW)
 389         if (CMAKE_CXX_COMPILER_ID MATCHES "^([cC]lang|AppleClang)$")
 390           # ignore the GCC_VERSION for clang
 391           message(STATUS "Using clang")
 392         else()
 393           execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpfullversion OUTPUT_VARIABLE GCC_VERSION ERROR_VARIABLE _error RESULT_VARIABLE _err OUTPUT_STRIP_TRAILING_WHITESPACE)
 394           #message(STATUS "dumpfullversion: error = ${_error}, result = ${_err}")
 395           if (_err)
 396             # previous check failed, try again with _old_ parameter
 397             execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION ERROR_VARIABLE _error RESULT_VARIABLE _err OUTPUT_STRIP_TRAILING_WHITESPACE)
 398             #message(STATUS "dumpversion: error = ${_error}, result = ${_err}")
 399           endif()
 400           message(STATUS "Using GCC version ${GCC_VERSION}")
 401           if(GCC_VERSION VERSION_LESS 4.9)
 402                 message(FATAL_ERROR "gcc >= 4.9 is required.")
 403           endif()
 404         endif()
 405         set(LYX_GCC11_MODE "${CXX11_FLAG}")
 406 else()
 407         if(MSVC_VERSION LESS 1900)
 408                 # Drop support for msvc versions prior to 1900 (Visual Studio 2015)
 409                 message(FATAL_ERROR "Visual Studio >= 2015 is required.")
 410         endif()
 411 endif()
 412
 413 if(LYX_3RDPARTY_BUILD)
 414   # LYX_3RDPARTY_BUILD is not cached anymore, but for compatibility reasons
 415   # this enables the build of all 3rd_party libs
 416   set(LYX_EXTERNAL_Z        OFF CACHE BOOL "Build 3rdparty lib zlib"    FORCE)
 417   set(LYX_EXTERNAL_ICONV    OFF CACHE BOOL "Build 3rdparty iconvlib"    FORCE)
 418   set(LYX_EXTERNAL_HUNSPELL OFF CACHE BOOL "Build 3rdparty hunspelllib" FORCE)
 419   set(LYX_EXTERNAL_MYTHES   OFF CACHE STRING "Build 3rdparty mytheslib" FORCE)
 420 endif()
 421
 422 FIND_PROGRAM(LYX_GITVERSION git)
 423 #message(STATUS "gitversion = ${LYX_GITVERSION}")
 424 set(LYX_REVISION_VERSION ${LYX_RELEASE_LEVEL})
 425 set(LYX_PACKAGE_RELEASE "UNDEFINED")
 426 if(LYX_GITVERSION)
 427   if (LYX_LOCALVERSIONING)
 428     # Find the revision number for later use
 429     EXECUTE_PROCESS(COMMAND ${LYX_GITVERSION} describe --match 2.0.0 HEAD
 430       WORKING_DIRECTORY "${TOP_SRC_DIR}"
 431       RESULT_VARIABLE tmp_GIT_RESULT
 432       OUTPUT_VARIABLE tmp_LYX_PACKAGE_RELEASE
 433       ERROR_VARIABLE tmp_GIT_ERROR
 434       OUTPUT_STRIP_TRAILING_WHITESPACE)
 435     if (tmp_GIT_RESULT EQUAL 0)
 436       if (tmp_LYX_PACKAGE_RELEASE MATCHES "^2\\.0\\.0\\-\([0-9]+\)\\-\(.*\)$")
 437         set(LYX_PACKAGE_RELEASE ${CMAKE_MATCH_2})
 438         # We will add offset of 40000 to get appropriate value to
 439         # previous svn.
 440         # We use this value than also to set the package-patch-value
 441         MATH(EXPR tmp_REVISION_VERSION "(${CMAKE_MATCH_1}+40000)")
 442         set(LYX_REVISION_VERSION "${LYX_RELEASE_LEVEL}-${tmp_REVISION_VERSION}git")
 443         set(ENABLE_DIST ON)
 444       endif()
 445     endif()
 446   endif()
 447 endif()
 448 if (LYX_PACKAGE_RELEASE MATCHES "UNDEFINED")
 449   set(LYX_PACKAGE_RELEASE  "1")
 450   if (LYX_RELEASE_PATCH GREATER 0)
 451     set(LYX_REVISION_VERSION "${LYX_RELEASE_LEVEL}.${LYX_RELEASE_PATCH}")
 452   endif()
 453 endif()
 454
 455 # Set the programs (lyx, tex2lyx, etc.) suffix
 456 # When building an OS X bundle, we will append
 457 # the suffix only to the bundle, not to the programs
 458 set(PROGRAM_SUFFIX "")
 459 if(LYX_PROGRAM_SUFFIX AND NOT (APPLE AND LYX_BUNDLE))
 460         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 461 endif()
 462 set(_lyx "${PACKAGE_BASE}${PROGRAM_SUFFIX}")
 463 set(_tex2lyx tex2lyx${PROGRAM_SUFFIX})
 464 set(_convert lyxconvert${PROGRAM_SUFFIX})
 465
 466 add_custom_target(lyx_version ALL
 467   COMMAND ${CMAKE_COMMAND} -DTOP_SRC_DIR=${TOP_SRC_DIR} -DTOP_CMAKE_PATH=${TOP_CMAKE_PATH} -DTOP_BINARY_DIR=${TOP_BINARY_DIR} -DLYX_DATE=${LYX_DATE} -P ${TOP_SCRIPT_PATH}/LyXGetVersion.cmake
 468   )
 469 set_target_properties(lyx_version PROPERTIES FOLDER "applications")
 470
 471 # Default paths for installed utilities (tex2lyx, lyxclient, etc.)
 472 set(LYX_UTILITIES_INSTALL_PATH bin)
 473
 474 if(LYX_BUNDLE)
 475         set(LYX_CPACK ON)
 476
 477         message(STATUS)
 478         message(STATUS "Bundle creation is enabled (experimental):")
 479         message(STATUS "    make")
 480         message(STATUS "    make install/strip")
 481         message(STATUS "    make package")
 482         if(APPLE)
 483                 set(MACOSX_BUNDLE TRUE)
 484                 # This sets the bundle + executable names
 485                 set(_lyx "${PACKAGE_BASE}${LYX_INSTALL_SUFFIX}")
 486                 # This sets the Info.plist executable name
 487                 set(osx_bundle_program_name ${_lyx})
 488                 # Bundle name
 489                 set(LYX_BUNDLE_NAME ${_lyx})
 490
 491                 # This will contain the list of files that need to be included
 492                 # in the bundle and their location within the bundle
 493                 set(OSX_BUNDLE_FILES "${TOP_SRC_DIR}/development/MacOSX/LyX.sdef;${TOP_SRC_DIR}/development/MacOSX/LyXapp.icns;${CMAKE_BINARY_DIR}/lyxrc.dist")
 494                 set(OSX_BUNDLE_DIRS "Resources;Resources;Resources")
 495
 496                 # Process Info.plist and lyxrc.dist
 497                 # See development/cmake/Install.cmake
 498                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/Info.plist.in" "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 499
 500                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 501                 set(LYX_DATA_SUBDIR ${LYX_BUNDLE_NAME}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 502
 503                 # Variables used by CPack
 504                 set(CPACK_BUNDLE_NAME ${LYX_BUNDLE_NAME})
 505                 set(CPACK_BUNDLE_PLIST "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 506                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${LYX_BUNDLE_NAME}.app)
 507
 508                 # Set the install paths
 509                 set(LYX_UTILITIES_INSTALL_PATH ${LYX_BUNDLE_NAME}.app/Contents/MacOS)
 510                 if(NOT LYX_INSTALL_PREFIX)
 511                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 512                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 513                 endif()
 514                 # Change the owner so that the install can work
 515                 install(CODE "set(BU_CHMOD_BUNDLE_ITEMS 1)" COMPONENT Runtime)
 516         elseif(UNIX)
 517                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 518                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 519                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 520         elseif(WIN32)
 521                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 522         endif()
 523 endif()
 524
 525 if(LYX_INSTALL_PREFIX)
 526         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 527         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 528 endif()
 529 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 530
 531 if(UNIX)
 532   set(SYSTEM_DATADIR "${CMAKE_INSTALL_PREFIX}/share")
 533 elseif(CMAKE_INSTALL_PREFIX MATCHES "/lyx${LYX_INSTALL_SUFFIX}$")
 534   string(REGEX REPLACE "/lyx${LYX_INSTALL_SUFFIX}$" "/share" SYSTEM_DATADIR ${CMAKE_INSTALL_PREFIX})
 535 else()
 536   set(SYSTEM_DATADIR "${CMAKE_INSTALL_PREFIX}")
 537 endif()
 538
 539 if(NOT CMAKE_COMPILER_IS_GNUCXX)
 540   # Not a GCC compiler, programs do not have a suffix
 541   set(suffixing ${LYX_PACKAGE_SUFFIX})
 542 elseif(WIN32 AND MINGW)
 543   # We want to use a suffix for the package in this case,
 544   # even if not for the program
 545   set(suffixing ${LYX_PACKAGE_SUFFIX})
 546 else()
 547   message(STATUS "CMAKE_COMPILER_IS_GNUCXX = ${CMAKE_COMPILER_IS_GNUCXX}")
 548   set(suffixing ${LYX_PROGRAM_SUFFIX})
 549 endif()
 550
 551 # The define PACKAGE below allows lyx-executable to find its default configuration files
 552 # see routines
 553 #    Package::messages_file()
 554 #    get_default_user_support_dir()
 555 #    relative_system_support_dir()
 556 # in src/support/Package.cpp
 557 if(suffixing)
 558         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 559 else()
 560         set(PACKAGE ${PACKAGE_BASE})
 561 endif()
 562
 563 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 564         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 565         if (UNIX)
 566                 # use the default "/usr/local"
 567                 # but respect the user-choice on the command-line
 568                 set(CMAKE_INSTALL_PREFIX "/usr/local" CACHE PATH "LyX default install prefix" FORCE)
 569         endif()
 570 endif()
 571 if(WIN32)
 572         set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 573 endif()
 574 if(IS_ABSOLUTE)
 575         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 576 else()
 577         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 578 endif()
 579
 580
 581
 582 if(NOT LYX_DATA_SUBDIR)
 583         if (WIN32)
 584                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 585         else()
 586                 set(LYX_DATA_SUBDIR "share/${_lyx}/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 587         endif()
 588 endif()
 589
 590 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}/${LYX_DATA_SUBDIR}")
 591 get_locale_destination(LYX_LOCALEDIR)
 592 set(LYX_ABS_INSTALLED_LOCALEDIR "${CMAKE_INSTALL_PREFIX}/${LYX_LOCALEDIR}")
 593 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 594
 595 if(LYX_BUNDLE AND APPLE)
 596         set(LYX_MAN_DIR_tmp "${LYX_DATA_SUBDIR}")
 597 else()
 598         if(WIN32)
 599                 set(LYX_MAN_DIR_tmp "${CMAKE_BINARY_DIR}/usr/local/man/")
 600         elseif(UNIX)
 601                 set(LYX_MAN_DIR_tmp "${CMAKE_INSTALL_PREFIX}/share/man/")
 602         else()
 603                 set(LYX_MAN_DIR_tmp "${CMAKE_INSTALL_PREFIX}/man/")
 604         endif()
 605 endif()
 606 if (NOT LYX_MAN_DIR_tmp EQUAL "${LYX_MAN_DIR}")
 607         unset(LYX_MAN_DIR CACHE)
 608         set(LYX_MAN_DIR "${LYX_MAN_DIR_tmp}" CACHE STRING "Install location for man pages.")
 609 endif()
 610 unset(LYX_MAN_DIR_tmp)
 611 mark_as_advanced(LYX_MAN_DIR)
 612
 613 # The Win installer cannot be built by CMake because one needs to install plugins for NSIS
 614 # see the Readme.txt of the installer
 615 #if(LYX_INSTALL AND WIN32)
 616 #       message(STATUS "Configuring NSIS files")
 617 #       configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 618 #       configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 619 #       configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 620 #       message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 621 #endif()
 622
 623 if(NOT GROUP_CODE)
 624         #set(GROUP_CODE "The Golden Code")
 625         set(GROUP_CODE flat)
 626 endif()
 627
 628 # lyx's source files
 629 set(LYX_CPP_FILES [a-zA-Z]*.cpp)
 630 set(LYX_HPP_FILES [a-zA-Z]*.h)
 631 set(LYX_MOC_FILES moc_*.cpp)
 632
 633 include(ProjectSourceGroup)
 634
 635
 636 if(LYX_PROFILE AND NOT MSVC)
 637         set(CMAKE_BUILD_TYPE Profile CACHE STRING "Profile build type" FORCE)
 638         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg")
 639         set(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS}  -pg")
 640 else()
 641         set(LYX_PROFILE OFF)
 642 endif()
 643
 644
 645 if(LYX_NO_OPTIMIZE)
 646         set(CMAKE_BUILD_TYPE None)
 647         set(LYX_DEBUG OFF)
 648         set(LYX_RELEASE OFF)
 649         set(LYX_PROFILE OFF)
 650 elseif(LYX_RELEASE)
 651         set(CMAKE_BUILD_TYPE Release)
 652         set(LYX_DEBUG OFF)
 653         set(LYX_PROFILE OFF)
 654 elseif(LYX_PROFILE)
 655         set(CMAKE_BUILD_TYPE Profile)
 656         set(LYX_DEBUG OFF)
 657 else()
 658         set(CMAKE_BUILD_TYPE Debug)
 659         set(LYX_DEBUG ON)
 660 endif()
 661
 662
 663 # When shared libs are supported enable this option
 664 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 665 if(LYX_SHARED_LIBRARIES)
 666         set(library_type SHARED)
 667 else()
 668         set(library_type STATIC)
 669 endif()
 670
 671 if(LYX_ENABLE_ASSERTIONS)
 672   set(LYX_CXX_FLAGS " -DENABLE_ASSERTIONS=1")
 673 else()
 674   set(LYX_CXX_FLAGS "")
 675 endif()
 676
 677 if (LYX_DEBUG_SANITIZE MATCHES "ADDRESS")
 678     set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -fsanitize=address -fno-omit-frame-pointer")
 679     message(STATUS)
 680     message(STATUS "Address sanitizer enabled. Usage:")
 681     message(STATUS "    wget https://llvm.org/svn/llvm-project/compiler-rt/trunk/lib/asan/scripts/asan_symbolize.py")
 682     message(STATUS "    chmod  +x ./asan_symbolize.py")
 683     message(STATUS "    ./bin/${_lyx} 2>&1 | ./asan_symbolize.py  | c++filt ")
 684     message(STATUS)
 685 elseif (LYX_DEBUG_SANITIZE MATCHES "UNSPECIFIED")
 686     set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -fsanitize=undefined -fno-omit-frame-pointer")
 687     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -fsanitize=undefined -fno-omit-frame-pointer")
 688 endif()
 689
 690 if(MSVC)
 691   if (CXX11_FLAG MATCHES "\\+\\+([0-9]+)")
 692     set(CMAKE_CXX_STANDARD ${CMAKE_MATCH_1})
 693     message(STATUS "CMAKE_CXX_STANDARD set to ${CMAKE_CXX_STANDARD}")
 694   endif()
 695   set(CMAKE_CXX_FLAGS       "${CMAKE_CXX_FLAGS}${LYX_CXX_FLAGS}")
 696 else()
 697         if(NOT LYX_QUIET)
 698                 set(CMAKE_VERBOSE_MAKEFILE ON)
 699         endif()
 700         if(LYX_GCC11_MODE MATCHES "\\+\\+([0-9][0-9])")
 701           # Thanks to Brad King <brad.king@kitware.com>
 702           # for the pointer to https://cmake.org/cmake/help/v3.6/variable/CMAKE_CXX_STANDARD.html
 703           # This allows us to use QT5.7 with recent g++ (version >= 4.9) compilers
 704           # and still use our own c++ extension tests
 705           set(std_num ${CMAKE_MATCH_1})
 706           set(CMAKE_CXX_STANDARD ${std_num})
 707         else()
 708           message(STATUS "Setting CMAKE_CXX_STANDARD 11 as fallback")
 709           set(CMAKE_CXX_STANDARD 11)
 710           set(LYX_GCC11_MODE "--std=c++11")
 711         endif()
 712         # The following setting with LYX_GCC11_MODE is needed because cmake does not honor
 713         # CMAKE_CXX_STANDARD while performing tests like
 714         # check_cxx_source_compiles("..." HAVE_DEF_MAKE_UNIQUE)
 715         include(CheckCXXCompilerFlag)
 716         unset(CHECK_WNODEPRECATEDCOPY_FLAG CACHE)
 717         CHECK_CXX_COMPILER_FLAG("-Wdeprecated-copy" CHECK_WNODEPRECATEDCOPY_FLAG)
 718         if(${CHECK_WNODEPRECATEDCOPY_FLAG})
 719                 set(LYX_CXX_FLAGS "-Wall -Wextra -Wno-deprecated-copy ${LYX_GCC11_MODE}${LYX_CXX_FLAGS}")
 720         else()
 721                 set(LYX_CXX_FLAGS "-Wall -Wextra ${LYX_GCC11_MODE}${LYX_CXX_FLAGS}")
 722         endif()
 723         if(LYX_STDLIB_DEBUG)
 724           set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 725         else()
 726           if(LYX_DEBUG_GLIBC)
 727             set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG")
 728           endif()
 729           if(LYX_DEBUG_GLIBC_PEDANTIC)
 730             set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG_PEDANTIC")
 731           endif()
 732         endif()
 733         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE STRING "Set CXX flags" FORCE)
 734         set(CMAKE_CXX_FLAGS_DEBUG "-O0 -g3 -D_DEBUG" CACHE STRING "Set debug flags" FORCE)
 735         if(MINGW)
 736                 set(CMAKE_CXX_FLAGS_RELEASE "-O2 -DNDEBUG" CACHE STRING "Set release flags for Mingw" FORCE)
 737         else()
 738                 set(CMAKE_CXX_FLAGS_RELEASE "-O3 -DNDEBUG" CACHE STRING "Set release flags" FORCE)
 739         endif()
 740 endif()
 741
 742 set(LYX_CXX_FLAGS_EXTRA "" CACHE STRING "Desired semicolon separated list of extra cxx compile flags, like '-Werror'")
 743 mark_as_advanced(LYX_CXX_FLAGS_EXTRA)
 744 if(LYX_CXX_FLAGS_EXTRA)
 745         foreach(_flag ${LYX_CXX_FLAGS_EXTRA})
 746                 add_definitions(${_flag})
 747         endforeach()
 748 endif()
 749
 750 if(LYX_XMINGW)
 751         list(APPEND CMAKE_FIND_ROOT_PATH ${GNUWIN32_DIR})
 752 endif()
 753
 754 set(min_qt5_version "5.6")
 755 if(LYX_USE_QT MATCHES "AUTO")
 756         # try qt6 first
 757         find_package(Qt6Core CONFIG QUIET)
 758         if (Qt6Core_Found)
 759                 set(LYX_USE_QT "QT6" CACHE STRING "Valid qt version" FORCE)
 760                 message(STATUS "Qt5Core_VERSION = ${Qt5Core_VERSION}")
 761         else()
 762                 find_package(Qt5Core CONFIG QUIET)
 763                 if(Qt5Core_FOUND)
 764                         set(LYX_USE_QT "QT5" CACHE STRING "Valid qt version" FORCE)
 765                         message(STATUS "Qt5Core_VERSION = ${Qt5Core_VERSION}")
 766                         if(Qt5Core_VERSION VERSION_LESS ${min_qt5_version})
 767                                 message(FATAL_ERROR "No appropriate QT-version found")
 768                         endif()
 769                 else()
 770                         message(FATAL_ERROR "No appropriate QT-version found")
 771                 endif()
 772         endif()
 773 endif()
 774
 775 set(QtCore5CompatLibrary)
 776 set(QtCore5CompatModule)
 777 if(LYX_USE_QT MATCHES "QT6|QT5")
 778         if (LYX_USE_QT MATCHES "QT6")
 779                 set(QtVal "Qt6")
 780                 macro (qt_add_resources)
 781                         Qt6_add_resources(${ARGN})
 782                 endmacro()
 783                 macro (qt_wrap_uifiles)
 784                         Qt6_wrap_ui(${ARGN})
 785                 endmacro()
 786         else()
 787                 set(QtVal "Qt5")
 788                 macro (qt_add_resources)
 789                         Qt5_add_resources(${ARGN})
 790                 endmacro()
 791                 macro (qt_wrap_uifiles)
 792                         Qt5_wrap_ui(${ARGN})
 793                 endmacro()
 794         endif()
 795         # set QPA_XCB if QT uses X11
 796         find_package(${QtVal}Core CONFIG REQUIRED)
 797         if (${QtVal}Core_FOUND)
 798                 find_package(${QtVal}Widgets CONFIG REQUIRED)
 799                 if(APPLE)
 800                         if (LYX_USE_QT MATCHES "QT6")
 801                                 find_package(${QtVal}MacExtras CONFIG QUIET)
 802                         else()
 803                                 find_package(${QtVal}MacExtras CONFIG REQUIRED)
 804                         endif()
 805                 endif()
 806                 find_package(${QtVal}X11Extras CONFIG QUIET)
 807                 find_package(${QtVal}WinExtras CONFIG QUIET)
 808                 set(QTVERSION ${${QtVal}Core_VERSION})
 809                 if (QTVERSION VERSION_LESS ${min_qt5_version})
 810                         message(STATUS "QTVERSION = \"${QTVERSION}\"")
 811                         message(STATUS "This version is not recommended,")
 812                         message(STATUS "please install QT-Version >= \"${min_qt5_version}\"")
 813                         # see thread in lyx-devel list
 814                         # From: Jean-Pierre Chrétien <jeanpierre.chretien@free.fr>
 815                         # Date 11.03.2017
 816                         # Subject: cmake compilation error
 817                         #message(FATAL_ERROR "Wrong Qt-Version")
 818                 endif()
 819                 macro (qt_use_modules lyxtarget)
 820                         foreach (_tg ${ARGN})
 821                                 find_package(${QtVal}${_tg} CONFIG REQUIRED)
 822                                 target_link_libraries(${lyxtarget} ${QtVal}::${_tg})
 823                         endforeach()
 824                 endmacro()
 825                 message(STATUS "Found Qt-Version ${QTVERSION}")
 826                 if(WIN32)
 827                         set(LYX_QTMAIN_LIBRARY ${${QtVal}Core_QTMAIN_LIBRARIES})
 828                 endif()
 829                 if (LYX_USE_QT MATCHES "QT6")
 830                         get_target_property(QT_MOC_EXECUTABLE Qt6::moc LOCATION)
 831                         find_package(Qt6 COMPONENTS Core5Compat REQUIRED)
 832                         include_directories(${Qt6Core5Compat_INCLUDE_DIRS})
 833                         set(QtCore5CompatLibrary Qt6::Core5Compat)
 834                         set(QtCore5CompatModule Core5Compat)
 835                 endif()
 836         endif()
 837 else()
 838   message(FATAL_ERROR "Unhandled value for LYX_USE_QT (${LYX_USE_QT})")
 839 endif()
 840
 841 find_package(Magic)
 842 if(Magic_FOUND)
 843   set(HAVE_MAGIC_H 1)
 844   include_directories(${Magic_INCLUDE_DIR})
 845 endif()
 846
 847 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 848
 849 set(Spelling_FOUND OFF)
 850 set(Include_used_spellchecker)   # String will be inserted into config.h
 851
 852 if (LYX_EXTERNAL_MYTHES MATCHES "AUTO")
 853   # try system library first
 854   find_package(MYTHESLIB)
 855   if (MYTHESLIB_FOUND)
 856     set(LYX_EXTERNAL_MYTHES ON CACHE STRING "OFF:= Build 3rdparty mytheslib" FORCE)
 857   else()
 858     set(LYX_EXTERNAL_MYTHES OFF CACHE STRING "OFF:= Build 3rdparty mytheslib" FORCE)
 859   endif()
 860 endif()
 861 if (LYX_EXTERNAL_MYTHES MATCHES "ON")
 862   find_package(MYTHESLIB REQUIRED)
 863 else()
 864   add_subdirectory(3rdparty/mythes)
 865 endif()
 866 set(MYTHES_DIR ${MYTHESLIB_INCLUDE_DIR})
 867
 868 if(NOT LYX_EXTERNAL_HUNSPELL)
 869     add_subdirectory(3rdparty/hunspell)
 870     add_definitions(-DHUNSPELL_STATIC)
 871     set(HUNSPELL_FOUND ON)
 872     message(STATUS "  * Hunspell:")
 873     message(STATUS "     - include: ${HUNSPELL_INCLUDE_DIR}")
 874     message(STATUS "     - library: ${HUNSPELL_LIBRARY}")
 875 endif()
 876
 877 foreach(_spell "ASPELL" "ENCHANT" "HUNSPELL")
 878   string(TOUPPER ${_spell} _upspell)
 879   if (NOT ${_upspell}_FOUND)
 880     find_package(${_spell})
 881   endif()
 882   if (${_upspell}_FOUND)
 883     include_directories(${${_upspell}_INCLUDE_DIR})
 884     set(Spelling_FOUND ON)
 885     message(STATUS "Building with USE_${_upspell}")
 886     set(Include_used_spellchecker "${Include_used_spellchecker}#define USE_${_upspell} 1\n")
 887   else()
 888     if(LYX_${_upspell})
 889       message(FATAL_ERROR "Required ${_spell} devel package not found")
 890     else()
 891       message(STATUS "${_upspell} not found, building without ${_spell} support")
 892     endif()
 893   endif()
 894 endforeach()
 895
 896 if(GNUWIN32_DIR)
 897         list(APPEND CMAKE_PROGRAM_PATH "${GNUWIN32_DIR}/Python" )
 898         list(APPEND CMAKE_PROGRAM_PATH "${GNUWIN32_DIR}/Perl/bin" )
 899 endif()
 900
 901 # Search for python default version first
 902 unset(PYTHON_EXECUTABLE CACHE)
 903 unset(LYX_PYTHON_EXECUTABLE CACHE)
 904 unset(PYTHON_VERSION_MAJOR)
 905 unset(PYTHON_VERSION_MINOR)
 906 unset(PYTHON_VERSION_STRING)
 907 if (CMAKE_VERSION VERSION_LESS "3.13")
 908   find_package(PythonInterp 3.5 QUIET)
 909   if(NOT PYTHONINTERP_FOUND)
 910     find_package(PythonInterp 2.0 REQUIRED)
 911     if(NOT PYTHON_VERSION_STRING VERSION_LESS 2.8)
 912       message(FATAL_ERROR "Python interpreter found, but is not suitable")
 913     endif()
 914   endif()
 915   set(LYX_PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 916 else()
 917   find_package(Python3 3.5 QUIET)
 918   if(NOT Python3_Interpreter_FOUND)
 919     unset(PYTHON_EXECUTABLE CACHE)
 920     find_package(Python2 2.0 REQUIRED)
 921     if(NOT Python2_VERSION VERSION_LESS 2.8)
 922       message(FATAL_ERROR "Python interpreter found, but is not suitable")
 923     endif()
 924     set(LYX_PYTHON_EXECUTABLE ${Python2_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 925   else()
 926     set(LYX_PYTHON_EXECUTABLE ${Python3_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 927   endif()
 928 endif()
 929
 930 if(LYX_NLS)
 931         find_package(LyXGettext)
 932         if(LYX_PYTHON_EXECUTABLE AND GETTEXT_FOUND)
 933                 add_subdirectory(po "${TOP_BINARY_DIR}/po")
 934         else()
 935                 # Install only supplied .gmo-files
 936                 file(GLOB _gmofiles RELATIVE "${TOP_SRC_DIR}/po" "${TOP_SRC_DIR}/po/*.gmo")
 937                 message(STATUS "Installing provided .gmo-files only")
 938                 foreach( _gmo ${_gmofiles})
 939                         string(REGEX REPLACE "\\.gmo$" "" _lang ${_gmo})
 940                         install(FILES "${TOP_SRC_DIR}/po/${_gmo}" DESTINATION ${LYX_LOCALEDIR}/${_lang}/LC_MESSAGES RENAME ${PACKAGE}.mo)
 941                 endforeach()
 942         endif()
 943 endif()
 944
 945 if(LYX_EXTERNAL_ICONV)
 946   # Possible remnants of previous run without external iconv
 947   file(REMOVE_RECURSE "${CMAKE_BINARY_DIR}/libiconv" "${CMAKE_BINARY_DIR}/3rdparty/libiconv")
 948   find_package(ICONV REQUIRED)
 949 else()
 950   add_subdirectory(3rdparty/libiconv)
 951   set(HAVE_ICONV_CONST 1)
 952 endif()
 953
 954 if(LYX_EXTERNAL_Z)
 955   find_package(ZLIB REQUIRED)
 956 else()
 957   add_subdirectory(3rdparty/zlib)
 958 endif()
 959
 960 if(NOT LYX_EXTERNAL_DTL)
 961   add_subdirectory(3rdparty/dtl)
 962 endif()
 963
 964 # Set only include path.
 965 # Use internal boost, which is known to exist
 966 # we don't need any libraries
 967 set(Lyx_Boost_Libraries)
 968 add_definitions(-DBOOST_USER_CONFIG=<config.h>)
 969 include_directories(${TOP_SRC_DIR}/3rdparty/boost)
 970
 971 include_directories(${TOP_SRC_DIR}/3rdparty/nod)
 972
 973 if(WIN32)
 974         if(LYX_CONSOLE)
 975                 set(LYX_QTMAIN_LIBRARY)
 976         else()
 977                 set(WIN32_CONSOLE WIN32)
 978         endif()
 979         if(MSVC)
 980                 # -DPSAPI_VERSION=1 is needed to run on vista (bug 10186)
 981                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX -DPSAPI_VERSION=1)
 982                 # disable checked iterators for msvc release builds to get maximum speed
 983                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 984         else()
 985                 # -DPSAPI_VERSION=1 is not needed for mingw, since the mingw psapi.h
 986                 # does not use it and always declares the vista compatible API.
 987                 # If this ever changes then -DPSAPI_VERSION might be needed here as well.
 988                 add_definitions(-DWINVER=0x0500)
 989         endif()
 990 endif()
 991
 992 # Compute qt-version from ${QTVERSION}
 993
 994 message(STATUS "")
 995 foreach(_v PACKAGE PACKAGE_VERSION
 996         PROGRAM_SUFFIX LYX_VERSION LYX_DIR_VER LYX_USERDIR_VER
 997         LYX_ABS_TOP_SRCDIR
 998         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 999         if(NOT DEFINED ${_v})
1000                 message(FATAL_ERROR "${_v} not defined")
1001         endif()
1002         string(SUBSTRING "${_v}                            " 0 28 _v1)
1003         message(STATUS "----- ${_v1}: ${${_v}}")
1004 endforeach(_v)
1005 message(STATUS "")
1006
1007
1008 if(LYX_PCH)
1009         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
1010         # Not sure if it works for all non-msvc compilers
1011         include(PCHSupport_26)
1012         configure_file(${TOP_CMAKE_PATH}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
1013         configure_file(${TOP_CMAKE_PATH}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
1014         add_definitions(-DLYX_ENABLE_PCH)
1015
1016         if(MSVC)
1017                 macro(lyx_add_msvc_pch name_)
1018                         set_source_files_properties(${${name_}_sources} PROPERTIES
1019                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
1020                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
1021                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
1022                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
1023                                 ${TOP_BINARY_DIR}/pcheaders.h)
1024                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
1025                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
1026                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
1027                 endmacro(lyx_add_msvc_pch)
1028                 macro(lyx_add_gcc_pch name_)
1029                 endmacro()
1030         else()
1031                 macro(lyx_add_msvc_pch name_)
1032                 endmacro()
1033                 macro(lyx_add_gcc_pch name_)
1034                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT)
1035                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
1036                 endmacro()
1037         endif()
1038 else()
1039         macro(lyx_add_msvc_pch)
1040         endmacro(lyx_add_msvc_pch)
1041         macro(lyx_add_gcc_pch name_)
1042         endmacro()
1043 endif()
1044
1045
1046 if(MSVC)
1047
1048         if(LYX_VLD)
1049                 set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/development/Win32/vld)
1050                 add_subdirectory(${vld_path}/cmake)
1051                 include(${vld_path}/cmake/vld.cmake) # forced include
1052                 set(vld_dll vld)
1053         endif()
1054
1055         if(LYX_WALL)
1056                 # Use the highest warning level
1057                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE STRING "Warning level" FORCE)
1058
1059                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
1060                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
1061                 else()
1062                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
1063                 endif()
1064
1065                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
1066                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
1067                 else()
1068                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
1069                 endif()
1070
1071                 # add here warnings which should produce an error /weXXXX
1072                 set(MSVC_W_ERROR   "/we4101 /we4189")
1073                 # add here warnings which should be disabled /wdXXXX
1074                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
1075
1076                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /W4 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1077                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /W4 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1078                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /W4 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1079
1080         else()
1081                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE STRING "Warning level" FORCE)
1082
1083                 # add here warnings which should produce an error /weXXXX
1084                 set(MSVC_W_ERROR   "/we4101 /we4189")
1085                 # add here warnings which should be disabled /wdXXXX
1086                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
1087
1088                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1089                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1090                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1091
1092         endif()
1093
1094         if (NOT (Qt5Core_FOUND OR Qt6Core_FOUND))
1095                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
1096                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
1097                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
1098         endif()
1099
1100         if (MSVC_VERSION GREATER_EQUAL 1914)
1101                 # Ensure the __cplusplus macro is set to a sensible value.
1102                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:__cplusplus")
1103                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:__cplusplus")
1104                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:__cplusplus")
1105         endif()
1106
1107         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
1108         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
1109         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
1110         message(STATUS "")
1111 endif()
1112
1113
1114 # Xcode compiler
1115 if (CMAKE_GENERATOR MATCHES Xcode)
1116         if (XCODE_VERSION VERSION_LESS "5.0")
1117                 # Automatically select the Xcode compiler if not set
1118                 if (NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
1119                         # XCode >= 3.1 has gcc 4.2 (up to actual Xcode)
1120                         if (XCODE_VERSION VERSION_GREATER "3.1")
1121                                 SET(CMAKE_XCODE_ATTRIBUTE_GCC_VERSION "com.apple.compilers.llvmgcc42")
1122                         ENDIF(XCODE_VERSION VERSION_GREATER "3.1")
1123                 ENDIF(NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
1124                 # Print the selected compiler version
1125         MESSAGE(STATUS "---- Using XCode compiler CMAKE_XCODE_ATTRIBUTE_GCC_VERSION=${CMAKE_XCODE_ATTRIBUTE_GCC_VERSION}")
1126         ENDIF(XCODE_VERSION VERSION_LESS "5.0")
1127 ENDIF(CMAKE_GENERATOR MATCHES Xcode)
1128
1129 if (WIN32 AND Qt5Core_FOUND)
1130         set(Z_PREFIX 1)
1131 endif()
1132
1133 # compiler tests, config.h generation LYX_CONFIGURE_CHECKS
1134 include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
1135 configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
1136
1137 unset(opts)
1138 foreach(_option ${LYX_OPTIONS})
1139   if(${_option}_show_message)
1140     string(SUBSTRING "${_option}                            " 0 31 _var)
1141     get_property(_prop CACHE ${_option} PROPERTY STRINGS)
1142     list(FIND LYX_OPTION_STRINGS ${_option} _index)
1143     if (${_index} GREATER -1)
1144       set(_isset ${${_option}})
1145     elseif(${_option})
1146       set(_isset ON)
1147     else()
1148       set(_isset OFF)
1149     endif()
1150     string(SUBSTRING "${_isset}           " 0 10 _val)
1151     set(opts "${opts} ${_option}(${${_option}})")
1152   endif()
1153 endforeach()
1154 set(tmp_vi "CMake Build")
1155 list(APPEND tmp_vi "  Host name:               ${CMAKE_HOST_SYSTEM_NAME}")
1156 list(APPEND tmp_vi "  Host processor:          ${CMAKE_HOST_SYSTEM_PROCESSOR}")
1157 list(APPEND tmp_vi "  Build flags:             ${opts}")
1158 list(APPEND tmp_vi "  C++ Compiler:            ${CMAKE_CXX_COMPILER_ID} (${CMAKE_CXX_COMPILER_VERSION})")
1159 list(APPEND tmp_vi "  C++ Compiler flags:      ${CMAKE_CXX_FLAGS}")
1160 if (LYX_DEBUG)
1161 list(APPEND tmp_vi "  C++ Compiler user flags: ${CMAKE_CXX_FLAGS_DEBUG}")
1162 else()
1163 list(APPEND tmp_vi "  C++ Compiler user flags: ${CMAKE_CXX_FLAGS_RELEASE}")
1164 endif()
1165 list(APPEND tmp_vi "  Qt version:              ${QTVERSION}")
1166 list(APPEND tmp_vi "  LyX binary dir:          ${CMAKE_INSTALL_PREFIX}/${LYX_UTILITIES_INSTALL_PATH}")
1167 get_data_destination(dest_data)
1168 list(APPEND tmp_vi "  LyX files dir:           ${CMAKE_INSTALL_PREFIX}/${dest_data}")
1169 string(REPLACE ";" "\\n" VERSION_INFO "${tmp_vi}")
1170
1171 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
1172 unset(opts)
1173 unset(tmp_vi)
1174
1175 if(QTVERSION MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+).*")
1176         MATH(EXPR QTx_VERSION "(${CMAKE_MATCH_1}<<16)|(${CMAKE_MATCH_2}<<8)|${CMAKE_MATCH_3}")
1177 endif()
1178
1179
1180 set (cmd ${CMAKE_CTEST_COMMAND})
1181 if (MSVC)
1182         set (cmd ${cmd} -C ${CMAKE_CFG_INTDIR})
1183 else ()
1184         set (cmd ${cmd} -C ${CMAKE_BUILD_TYPE})
1185 endif ()
1186 add_custom_target (lyx_run_tests COMMAND ${cmd})
1187 set_target_properties(lyx_run_tests PROPERTIES FOLDER "tests")
1188
1189 if(LYX_INSTALL)
1190         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
1191                 message(STATUS "Python required to create doc!")
1192         else()
1193                 if(UNIX)
1194                         add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
1195                 endif()
1196                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
1197         endif()
1198 endif()
1199 include(../Install)
1200
1201 # By running the URL tests first, time can be saved when running the ctests in
1202 # parallel since the URL tests take a long time to run (e.g. 10 minutes).
1203
1204 # Needed, because of perl scripts in checkurls autotests and batchtests
1205 find_package(Perl REQUIRED)
1206
1207 if(LYX_ENABLE_URLTESTS)
1208         add_subdirectory(development/checkurls "${TOP_BINARY_DIR}/checkurls")
1209 endif()
1210 add_subdirectory(src "${TOP_BINARY_DIR}/src")
1211 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
1212 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
1213 add_subdirectory(lib/examples "${TOP_BINARY_DIR}/lib/examples")
1214 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
1215 add_subdirectory(development/autotests "${TOP_BINARY_DIR}/autotests")
1216 add_subdirectory(development/batchtests "${TOP_BINARY_DIR}/batchtests")
1217
1218 message(STATUS)
1219 message(STATUS "Build params, switch LYX_* options by -DLYX_*=ON or OFF, LYX_* combos by -DLYX_*=value:")
1220 message(STATUS)
1221
1222 LYX_OPTION_LIST_ALL(used)
1223
1224
1225 if(LYX_NLS)
1226         message(STATUS)
1227         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
1228         message(STATUS)
1229         message(STATUS "  * iconv")
1230         message(STATUS "     - include: ${ICONV_INCLUDE_DIR}")
1231         message(STATUS "     - library: ${ICONV_LIBRARY}")
1232         message(STATUS "  * zlib")
1233         message(STATUS "     - include: ${ZLIB_INCLUDE_DIR}")
1234         message(STATUS "     - library: ${ZLIB_LIBRARY}")
1235         message(STATUS)
1236 endif()
1237
1238 # Apple has builtin native spell checker,
1239 # no need to warn for missing Aspell, Hunspell or Enchant
1240 if(NOT Spelling_FOUND AND NOT APPLE)
1241   if(LYX_REQUIRE_SPELLCHECK)
1242     set(_mode "FATAL_ERROR")
1243   else()
1244     set(_mode "STATUS")
1245   endif()
1246   message(${_mode} "No spellcheck libraries found. LyX will be unable use spellchecking")
1247 endif()
1248
1249 include("${TOP_CMAKE_PATH}/LyxPackaging.cmake")
1250
1251 if(ENABLE_DIST)
1252   # Use git to create the source package
1253   # git archive --format=tgz --output=/home/kornel/x.tar.gz master
1254   if(UNIX)
1255     set(DIST_FORMAT tgz)
1256   else()
1257     set(DIST_FORMAT zip)
1258   endif()
1259   set(DIST_NAME ${CMAKE_PROJECT_NAME}-${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}-${CMAKE_SYSTEM_NAME}.${DIST_FORMAT})
1260
1261   add_custom_command(
1262     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME}
1263     COMMAND  ${LYX_GITVERSION} archive --format=${DIST_FORMAT} --output=${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME} master
1264     WORKING_DIRECTORY ${TOP_SRC_DIR})
1265   add_custom_target(git-archive DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME})
1266 endif()
1267
1268 # Last directory to be included so that the fixup code (OS X)
1269 # can be run last
1270 add_subdirectory(development/cmake/post_install)
1271
1272 string(TIMESTAMP current_date "%Y-%m-%d %H:%M")
1273 execute_process(COMMAND ${LYX_GITVERSION} describe --tags
1274         WORKING_DIRECTORY "${TOP_SRC_DIR}"
1275         OUTPUT_VARIABLE current_version
1276         OUTPUT_STRIP_TRAILING_WHITESPACE)
1277 file(APPEND "${TOP_BINARY_DIR}/Testing/IgnoredCount" "${current_date} ${current_version} Ignored tests = ${LYX_ignored_count}\n")
1278 message(STATUS)