CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 2.6.4)
   8
   9 set(LYX_PROJECT LyX)
  10
  11 enable_testing()
  12
  13 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README ABSOLUTE)
  14 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  15
  16 set(LYX_CMAKE_DIR "development/cmake")
  17 set(TOP_CMAKE_PATH "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}")
  18 set(TOP_MODULE_PATH "${TOP_CMAKE_PATH}/modules")
  19 set(TOP_SCRIPT_PATH "${TOP_CMAKE_PATH}/scripts")
  20
  21 set(CMAKE_MODULE_PATH "${TOP_MODULE_PATH}")
  22
  23 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  24
  25 message(STATUS)
  26 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  27         message(STATUS "Building in-source")
  28         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  29 else()
  30         message(STATUS "Building out-of-source")
  31         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  32 endif()
  33
  34 # This directory should be used if some test uses lyx-executable
  35 set(LYX_TESTS_USERDIR "${TOP_BINARY_DIR}/Testing/.lyx")
  36 file(MAKE_DIRECTORY "${LYX_TESTS_USERDIR}")
  37
  38 if(COMMAND cmake_policy)
  39         cmake_policy(SET CMP0003 OLD)
  40         cmake_policy(SET CMP0005 OLD)
  41         # Installing MACOSX_BUNDLE targets requires a BUNDLE DESTINATION
  42         cmake_policy(SET CMP0006 NEW)
  43 endif()
  44
  45 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  46
  47 # Supress regeneration
  48 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  49
  50 if(NOT help AND NOT HELP)
  51         # 'project' triggers the searching for a compiler
  52         project(${LYX_PROJECT})
  53 endif()
  54
  55 if(UNIX)
  56         set(ARCH_TRIPLET )
  57         FIND_PROGRAM(DPKG_ARCHITECTURE_EXECUTABLE dpkg-architecture)
  58         if(DPKG_ARCHITECTURE_EXECUTABLE)
  59                 EXECUTE_PROCESS(COMMAND ${DPKG_ARCHITECTURE_EXECUTABLE} -qDEB_HOST_MULTIARCH
  60                                 OUTPUT_VARIABLE ARCH_TRIPLET
  61                                 ERROR_VARIABLE ERROR_ARCH_TRIPLET
  62                                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  63         endif()
  64 endif()
  65 if(ARCH_TRIPLET)
  66         set(SYSTEM_LIB_DIRS /usr/lib /usr/lib/${ARCH_TRIPLET} /usr/local/lib)
  67 else()
  68         set(SYSTEM_LIB_DIRS /usr/lib /usr/local/lib)
  69 endif()
  70
  71 include(LyXMacros)
  72
  73 # Usage LYX_OPTION
  74 # 1. parameter: option name without prefix 'LYX_'
  75 # 2. parameter: description
  76 # 3. parameter: default value, ON or OFF
  77 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
  78
  79
  80 LYX_OPTION_INIT()
  81
  82 # Options for all compilers/systems
  83 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
  84 LYX_OPTION(LOCALVERSIONING  "Add version info to created package name (only used if LYX_CPACK option set)" OFF ALL)
  85 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
  86 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
  87 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
  88 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
  89 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
  90 LYX_OPTION(DEVEL_VERSION    "Build developer version" OFF ALL)
  91 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" OFF ALL)
  92 LYX_OPTION(DEBUG            "Enforce debug build"  OFF ALL)
  93 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
  94 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
  95 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
  96 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
  97 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
  98 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
  99 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
 100 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
 101 LYX_OPTION(ENABLE_URLTESTS  "Enable for URL tests" OFF ALL)
 102
 103 # GCC specific
 104 LYX_OPTION(PROFILE              "Build profile version" OFF GCC)
 105 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" OFF GCC)
 106 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
 107 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
 108 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++ pedantic debug mode" OFF GCC)
 109 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" OFF GCC)
 110 LYX_OPTION(CONCEPT_CHECKS       "Enable concept-checks" OFF GCC)
 111 LYX_OPTION(PROFILE              "Build with options for gprof" OFF GCC)
 112 LYX_OPTION(ENABLE_CXX11         "Build with options for c++11-mode" OFF GCC)
 113
 114 # MSVC specific
 115 LYX_OPTION(CONSOLE               "Show console on Windows, enforce with =FORCE" ON MSVC)
 116 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
 117 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
 118 LYX_OPTION(CONFIGURE_CHECKS      "Also run configure checks for MSVC" OFF MSVC)
 119 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
 120
 121 # APPLE specific
 122 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
 123 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
 124
 125
 126 if(help OR HELP)
 127         message(STATUS)
 128         message(STATUS "Available options: (dis/enable with -DLYX_*=OFF/ON)")
 129         message(STATUS)
 130         LYX_OPTION_LIST_ALL(help)
 131         message(STATUS)
 132         RETURN()
 133 endif()
 134
 135 # Check option dependencies
 136
 137 if(LYX_DMG)
 138         set(LYX_BUNDLE ON)
 139         set(LYX_CPACK ON)
 140 endif()
 141
 142 if(LYX_CPACK)
 143         set(LYX_INSTALL ON)
 144 endif()
 145
 146 if(LYX_INSTALL)
 147         set(LYX_NLS ON)
 148         if (WIN32)
 149                 set(LYX_HUNSPELL ON)
 150         endif()
 151         if(LYX_CONSOLE MATCHES "FORCE")
 152                 set(LYX_CONSOLE ON)
 153         else()
 154                 set(LYX_CONSOLE OFF)
 155         endif()
 156         set(LYX_PACKAGE_SUFFIX ON)
 157         if(NOT LYX_DEBUG)
 158                 set(LYX_RELEASE ON)
 159         endif()
 160         set(LYX_PROFILE OFF)
 161 endif()
 162
 163
 164 if(LYX_MERGE_FILES)
 165         set(LYX_PCH OFF)
 166 else()
 167         set(LYX_MERGE_REBUILD OFF)
 168 endif()
 169
 170 if(LYX_DEPENDENCIES_DOWNLOAD)
 171         message(STATUS)
 172         set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 173         message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 174         set(deps_files lyx20-deps-msvc2010-x86.zip)
 175         set(deps_server http://downloads.sourceforge.net/project/lyx/Win_installers/Dependencies)
 176         foreach(it ${deps_files})
 177                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 178                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 179                 if(NOT already_downloaded)
 180                         message(STATUS "Downloading ${it} ...")
 181                         file(DOWNLOAD ${deps_server}/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS STATUS status LOG log)
 182                         list(GET status 0 status_code)
 183                         list(GET status 1 status_string)
 184                         if(NOT status_code EQUAL 0)
 185                                 file(REMOVE ${LYX_DEPENDENCIES_DIR}/${it})
 186                                 message(FATAL_ERROR "error: downloading '${it}' failed. status_code: ${status_code}, status_string: ${status_string}. \nLog: ${log} ")
 187                         endif()
 188                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 189                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 190                 endif()
 191         endforeach()
 192         set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/deps20)
 193 endif()
 194
 195
 196
 197 message(STATUS)
 198
 199 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 200 if(WIN32)
 201         set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 202 else()
 203         set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 204 endif()
 205
 206
 207 # Variable that hold the flags that should only be used with C++ files
 208 set(LYX_CXX_SPECIFIC_FLAGS)
 209 if(UNIX OR MINGW)
 210         execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION)
 211         message(STATUS "Using GCC version ${GCC_VERSION}")
 212         if(NOT GCC_VERSION VERSION_LESS 4.4)
 213                 set(LYX_USE_TR1 1)
 214                 # GCC <= 4.5 does not support regex: there are linker errors
 215                 # http://gcc.gnu.org/onlinedocs/libstdc++/manual/status.html#status.iso.tr1
 216                 set(LYX_USE_TR1_REGEX 0)
 217         endif()
 218         if (LYX_ENABLE_CXX11)
 219                 find_package(CXX11Compiler)
 220                 if(NOT CXX11COMPILER_FOUND)
 221                         message(FATAL_ERROR "A C++11 compatible compiler is required.")
 222                 endif()
 223                 set(LYX_CXX_SPECIFIC_FLAGS "${LYX_CXX_SPECIFIC_FLAGS} ${CXX11_FLAG}")
 224         endif()
 225 else()
 226         if(MSVC10)
 227                 set(LYX_USE_TR1 1)
 228                 #set(LYX_USE_TR1_REGEX 1) #TODO should we use it in ECMAScript mode?
 229         endif()
 230 endif()
 231
 232
 233 set(VERSION_INFO "CMake Build")
 234
 235 # Try to get some informations from configure.ac
 236
 237 include(LyXPaths)
 238 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 239
 240 if(WIN32)
 241         set(USE_WINDOWS_PACKAGING ON)
 242 elseif(APPLE)
 243         set(USE_MACOSX_PACKAGING ON)
 244 else()
 245         set(USE_POSIX_PACKAGING ON)
 246 endif()
 247
 248 macro(setstripped _varname)
 249         if(${ARGC} GREATER 1)
 250                 string(STRIP "${ARGV1}" _v)
 251                 if(USE_POSIX_PACKAGING)
 252                         string(TOLOWER ${_v} ${_varname})
 253                 else()
 254                         set(${_varname} ${_v})
 255                 endif()
 256         else()
 257                 set(${_varname})
 258         endif()
 259 endmacro(setstripped)
 260
 261 foreach(_c_l ${_config_lines} )
 262         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 263                 setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 264                 setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 265                 setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 266                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\)\(\\.\([0-9]+\)\)?.*$")
 267                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 268                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 269                         set(LYX_PATCH_VERSION ${CMAKE_MATCH_4})
 270                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 271                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 272                         set(LYX_INSTALL_SUFFIX "${CMAKE_MATCH_1}.${CMAKE_MATCH_2}")
 273                 endif()
 274         endif()
 275         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 276                 set(LYX_DATE "${CMAKE_MATCH_1}")
 277         endif()
 278 endforeach(_c_l)
 279
 280 if (LYX_LOCALVERSIONING)
 281         # Find the revision number and for later use
 282         FIND_PROGRAM(LYX_GITVERSION git)
 283         #message(STATUS "gitversion = ${LYX_GITVERSION}")
 284         if(LYX_GITVERSION)
 285                 EXECUTE_PROCESS(COMMAND ${LYX_GITVERSION} describe --match 2.0.0 HEAD
 286                 WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE LYX_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 287                 if (LYX_PACKAGE_RELEASE MATCHES "^2\\.0\\.0\\-\([0-9]+\)\\-.*$")
 288                   # We will add offset of 40000 to get appropriate value to
 289                   # previous svn.
 290                   # We use this value than also to set the package-patch-value
 291                   MATH(EXPR tmp_REVISION_VERSION "(${CMAKE_MATCH_1}+40000)")
 292                   set(LYX_REVISION_VERSION "${LYX_PATCH_VERSION}-${tmp_REVISION_VERSION}git")
 293                   set(ENABLE_DIST ON)
 294                 endif()
 295         else()
 296                 set(LYX_REVISION_VERSION git) #TODO use date
 297         endif()
 298 else()
 299         set(LYX_REVISION_VERSION ${LYX_PATCH_VERSION})
 300 endif()
 301
 302 # Set the programs (lyx, tex2lyx, etc.) suffix
 303 # When building an OS X bundle, we will append
 304 # the suffix only to the bundle, not to the programs
 305 set(PROGRAM_SUFFIX "")
 306 if(LYX_PROGRAM_SUFFIX AND NOT (APPLE AND LYX_BUNDLE))
 307         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 308 endif()
 309 set(_lyx "${PACKAGE_BASE}${PROGRAM_SUFFIX}")
 310 set(_tex2lyx tex2lyx${PROGRAM_SUFFIX})
 311
 312 add_custom_target(lyx_version ALL
 313   COMMAND ${CMAKE_COMMAND} -DTOP_SRC_DIR=${TOP_SRC_DIR} -DTOP_CMAKE_PATH=${TOP_CMAKE_PATH} -DTOP_BINARY_DIR=${TOP_BINARY_DIR} -DLYX_DATE=${LYX_DATE} -P ${TOP_SCRIPT_PATH}/LyXGetVersion.cmake
 314   )
 315 set_target_properties(lyx_version PROPERTIES FOLDER "applications")
 316
 317 # Default paths for installed utilities (tex2lyx, lyxclient, etc.)
 318 set(LYX_UTILITIES_INSTALL_PATH bin)
 319
 320 if(LYX_BUNDLE)
 321         set(LYX_CPACK ON)
 322
 323         message(STATUS)
 324         message(STATUS "Bundle creation is enabled (experimental):")
 325         message(STATUS "    make")
 326         message(STATUS "    make install/strip")
 327         message(STATUS "    make package")
 328         if(APPLE)
 329                 set(MACOSX_BUNDLE TRUE)
 330                 # This sets the bundle + executable names
 331                 set(_lyx "${PACKAGE_BASE}${LYX_INSTALL_SUFFIX}")
 332                 # This sets the Info.plist executable name
 333                 set(osx_bundle_program_name ${_lyx})
 334                 # Bundle name
 335                 set(LYX_BUNDLE_NAME ${_lyx})
 336
 337                 # This will contain the list of files that need to be included
 338                 # in the bundle and their location within the bundle
 339                 set(OSX_BUNDLE_FILES "${TOP_SRC_DIR}/development/MacOSX/LyX.sdef;${TOP_SRC_DIR}/development/MacOSX/LyXapp.icns;${CMAKE_BINARY_DIR}/lyxrc.dist")
 340                 set(OSX_BUNDLE_DIRS "Resources;Resources;Resources")
 341
 342                 # Process Info.plist and lyxrc.dist
 343                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/Info.plist.in" "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 344                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/lyxrc.dist.in" "${CMAKE_CURRENT_BINARY_DIR}/lyxrc.dist")
 345
 346                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 347                 set(LYX_DATA_SUBDIR ${LYX_BUNDLE_NAME}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 348
 349                 # Variables used by CPack
 350                 set(CPACK_BUNDLE_NAME ${LYX_BUNDLE_NAME})
 351                 set(CPACK_BUNDLE_PLIST "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 352                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${LYX_BUNDLE_NAME}.app)
 353
 354                 # Set the install paths
 355                 set(LYX_UTILITIES_INSTALL_PATH ${LYX_BUNDLE_NAME}.app/Contents/MacOS)
 356                 if(NOT LYX_INSTALL_PREFIX)
 357                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 358                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 359                 endif()
 360                 # Change the owner so that the install can work
 361                 install(CODE "set(BU_CHMOD_BUNDLE_ITEMS 1)" COMPONENT Runtime)
 362         elseif(UNIX)
 363                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 364                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 365                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 366         elseif(WIN32)
 367                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 368         endif()
 369 endif()
 370
 371 if(LYX_INSTALL_PREFIX)
 372         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 373         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 374 endif()
 375 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 376
 377 if(LYX_PACKAGE_SUFFIX)
 378         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 379 else()
 380         set(PACKAGE ${PACKAGE_BASE})
 381 endif()
 382
 383
 384 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 385         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 386         if (UNIX)
 387                 # don't use the default "/usr/local"
 388                 # but respect the user-choice on the command-line
 389                 if(LYX_INSTALL_SUFFIX)
 390                         set(CMAKE_INSTALL_PREFIX "/usr/local/lyx${LYX_INSTALL_SUFFIX}" CACHE PATH "LyX default install prefix" FORCE)
 391                 else()
 392                         set(CMAKE_INSTALL_PREFIX "/usr/local/${LYX_PROJECT}" CACHE PATH "LyX default install prefix" FORCE)
 393                 endif()
 394         endif()
 395         if(WIN32)
 396                 set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 397         endif()
 398 endif()
 399 if(IS_ABSOLUTE)
 400         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 401 else()
 402         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 403 endif()
 404
 405
 406
 407 if(NOT LYX_DATA_SUBDIR)
 408         if (WIN32)
 409                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 410         else()
 411                 set(LYX_DATA_SUBDIR "" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 412         endif()
 413 endif()
 414
 415 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 416 set(LYX_LOCALEDIR "locale")
 417 set(LYX_ABS_INSTALLED_LOCALEDIR "${LYX_ABS_INSTALLED_DATADIR}/${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}")
 418 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 419
 420 if(LYX_BUNDLE AND APPLE)
 421         set(LYX_MAN_DIR "${LYX_DATA_SUBDIR}" CACHE STRING "Install location for man pages.")
 422 else()
 423         set(LYX_MAN_DIR "/usr/local/man/man1" CACHE STRING "Install location for man pages.")
 424 endif()
 425 mark_as_advanced(LYX_MAN_DIR)
 426
 427 if(LYX_INSTALL AND WIN32)
 428         message(STATUS "Configuring NSIS files")
 429         configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 430         configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 431         configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 432         message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 433 endif()
 434
 435 if(NOT GROUP_CODE)
 436         #set(GROUP_CODE "The Golden Code")
 437         set(GROUP_CODE flat)
 438 endif()
 439
 440 # lyx's source files
 441 set(LYX_CPP_FILES *.cpp)
 442 set(LYX_HPP_FILES *.h)
 443 set(LYX_MOC_FILES moc_*.cpp)
 444
 445 include(ProjectSourceGroup)
 446
 447
 448 if(LYX_PROFILE AND NOT MSVC)
 449         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 450         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg")
 451         set(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS}  -pg")
 452 else()
 453         set(LYX_PROFILE OFF)
 454 endif()
 455
 456
 457 if(LYX_NO_OPTIMIZE)
 458         set(CMAKE_BUILD_TYPE None)
 459         set(LYX_DEBUG OFF)
 460         set(LYX_RELEASE OFF)
 461         set(LYX_PROFILE OFF)
 462 elseif(LYX_RELEASE)
 463         set(CMAKE_BUILD_TYPE Release)
 464         set(LYX_DEBUG OFF)
 465         set(LYX_PROFILE OFF)
 466 elseif(LYX_PROFILE)
 467         set(CMAKE_BUILD_TYPE Profile)
 468         set(LYX_DEBUG OFF)
 469 else()
 470         set(CMAKE_BUILD_TYPE Debug)
 471         set(LYX_DEBUG ON)
 472 endif()
 473
 474
 475 # When shared libs are supported enable this option
 476 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 477 if(LYX_SHARED_LIBRARIES)
 478         set(library_type SHARED)
 479 else()
 480         set(library_type STATIC)
 481 endif()
 482
 483 if(NOT MSVC)
 484         if(NOT LYX_QUIET)
 485                 set(CMAKE_VERBOSE_MAKEFILE ON)
 486         endif()
 487         set(LYX_CXX_FLAGS "-Wall -Wunused-parameter")
 488         if(LYX_STDLIB_DEBUG)
 489                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 490         endif()
 491         if(LYX_CONCEPT_CHECKS)
 492                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCPP_CONCEPT_CHECKS")
 493         endif()
 494         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 495         set(CMAKE_CXX_FLAGS_DEBUG "${LYX_CXX_FLAGS} -fno-strict-aliasing -O0 -g3 -D_DEBUG" CACHE TYPE STRING FORCE)
 496         if(MINGW)
 497                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 498         else()
 499                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 500         endif()
 501 endif()
 502
 503 set(LYX_CXX_FLAGS_EXTRA "" CACHE STRING "Desired semicolon separated list of extra cxx compile flags, like '-Werror'")
 504 mark_as_advanced(LYX_CXX_FLAGS_EXTRA)
 505 if(LYX_CXX_FLAGS_EXTRA)
 506         foreach(_flag ${LYX_CXX_FLAGS_EXTRA})
 507                 add_definitions(${_flag})
 508         endforeach()
 509 endif()
 510
 511 find_package(Qt5Core QUIET)
 512 if (Qt5Core_FOUND)
 513         find_package(Qt5Widgets REQUIRED)
 514         set(QTVERSION ${Qt5Core_VERSION})
 515         macro (qt_use_modules)
 516                 qt5_use_modules(${ARGN})
 517         endmacro()
 518         macro (qt_add_resources)
 519                 qt5_add_resources(${ARGN})
 520         endmacro()
 521         macro (qt_wrap_uifiles)
 522                 qt5_wrap_ui(${ARGN})
 523         endmacro()
 524 else()
 525         find_package(Qt4 "4.5.0" REQUIRED)
 526         macro (qt_use_modules)
 527         endmacro()
 528         macro (qt_add_resources)
 529                 qt4_add_resources(${ARGN})
 530         endmacro()
 531         macro (qt_wrap_uifiles)
 532                 qt4_wrap_ui(${ARGN})
 533         endmacro()
 534 endif()
 535
 536 find_package(Magic)
 537 if(Magic_FOUND)
 538         set(HAVE_MAGIC_H 1)
 539 endif()
 540
 541 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 542
 543 if(LYX_ASPELL)
 544         find_package(ASPELL REQUIRED)
 545         include_directories(${ASPELL_INCLUDE_DIR})
 546 endif()
 547
 548 if(LYX_ENCHANT)
 549         find_package(Enchant REQUIRED)
 550         include_directories(${ENCHANT_INCLUDE_DIR})
 551 endif()
 552
 553 if(LYX_HUNSPELL)
 554         find_package(Hunspell REQUIRED)
 555         include_directories(${HUNSPELL_INCLUDE_DIR})
 556 endif()
 557
 558 if(LYX_NLS)
 559         FIND_PROGRAM(LYX_PYTHON_EXECUTABLE python2 python HINTS ${GNUWIN32_DIR}/python)
 560         find_package(LyXGettext)
 561         if(LYX_PYTHON_EXECUTABLE AND GETTEXT_FOUND)
 562                 add_subdirectory(po "${TOP_BINARY_DIR}/po")
 563         else()
 564                 # Install only supplied .gmo-files
 565                 file(GLOB _gmofiles RELATIVE "${TOP_SRC_DIR}/po" "${TOP_SRC_DIR}/po/*.gmo")
 566                 message(STATUS "Installing provided .gmo-files only")
 567                 foreach( _gmo ${_gmofiles})
 568                         string(REGEX REPLACE "\\.gmo$" "" _lang ${_gmo})
 569                         install(FILES "${TOP_SRC_DIR}/po/${_gmo}" DESTINATION ${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}/${_lang}/LC_MESSAGES RENAME ${PACKAGE}.mo)
 570                 endforeach()
 571         endif()
 572 endif()
 573
 574 find_package(ICONV REQUIRED)
 575 find_package(ZLIB REQUIRED)
 576
 577 if(LYX_EXTERNAL_BOOST)
 578         message(STATUS "Searching for boost")
 579         find_package(Boost COMPONENTS signals regex) #TODO could REQUIRED be used
 580         if(Boost_FOUND)
 581                 message(STATUS "Boost found")
 582                 message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 583                 set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 584         else()
 585                 message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 586         endif()
 587 else()
 588         if(LYX_USE_TR1_REGEX)
 589                 set(Lyx_Boost_Libraries boost_signals)
 590         else()
 591                 set(Lyx_Boost_Libraries boost_signals boost_regex)
 592         endif()
 593         add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 594         include_directories(${TOP_SRC_DIR}/boost)
 595         add_subdirectory(boost "${TOP_BINARY_DIR}/boost")
 596 endif()
 597
 598
 599
 600
 601 if(WIN32)
 602         if(NOT LYX_CONSOLE)
 603                 set(WIN32_CONSOLE WIN32)
 604                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARY})
 605         endif()
 606         if(MSVC)
 607                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 608                 # disable checked iterators for msvc release builds to get maximum speed
 609                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 610         else()
 611                 add_definitions(-DWINVER=0x0500)
 612         endif()
 613 endif()
 614
 615 # Compute qt4-version from ${QTVERSION}
 616
 617 message(STATUS "")
 618 foreach(_v PACKAGE PACKAGE_VERSION
 619         PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 620         LYX_ABS_TOP_SRCDIR
 621         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 622         if(NOT DEFINED ${_v})
 623                 message(FATAL_ERROR "${_v} not defined")
 624         endif()
 625         string(SUBSTRING "${_v}                            " 0 28 _v1)
 626         message(STATUS "----- ${_v1}: ${${_v}}")
 627 endforeach(_v)
 628 message(STATUS "")
 629
 630
 631 if(LYX_PCH)
 632         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 633         # Not sure if it works for all non-msvc compilers
 634         include(PCHSupport_26)
 635         configure_file(${TOP_CMAKE_PATH}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
 636         configure_file(${TOP_CMAKE_PATH}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 637         add_definitions(-DLYX_ENABLE_PCH)
 638
 639         if(MSVC)
 640                 macro(lyx_add_msvc_pch name_)
 641                         set_source_files_properties(${${name_}_sources} PROPERTIES
 642                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 643                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
 644                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 645                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
 646                                 ${TOP_BINARY_DIR}/pcheaders.h)
 647                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 648                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 649                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 650                 endmacro(lyx_add_msvc_pch)
 651                 macro(lyx_add_gcc_pch name_)
 652                 endmacro()
 653         else()
 654                 macro(lyx_add_msvc_pch name_)
 655                 endmacro()
 656                 macro(lyx_add_gcc_pch name_)
 657                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT4)
 658                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
 659                 endmacro()
 660         endif()
 661 else()
 662         macro(lyx_add_msvc_pch)
 663         endmacro(lyx_add_msvc_pch)
 664         macro(lyx_add_gcc_pch name_)
 665         endmacro()
 666 endif()
 667
 668
 669 if(MSVC)
 670
 671         if(LYX_VLD)
 672                 set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/development/Win32/vld)
 673                 add_subdirectory(${vld_path}/cmake)
 674                 include(${vld_path}/cmake/vld.cmake) # forced include
 675                 set(vld_dll vld)
 676         endif()
 677
 678         if(LYX_WALL)
 679                 # Use the highest warning level
 680                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 681
 682                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 683                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 684                 else()
 685                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 686                 endif()
 687
 688                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 689                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 690                 else()
 691                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 692                 endif()
 693
 694                 # add here warnings which should produce an error /weXXXX
 695                 set(MSVC_W_ERROR   "/we4101 /we4189")
 696                 # add here warnings which should be disabled /wdXXXX
 697                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 698
 699                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 700                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 701                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 702
 703         else()
 704                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 705
 706                 # add here warnings which should produce an error /weXXXX
 707                 set(MSVC_W_ERROR   "/we4101 /we4189")
 708                 # add here warnings which should be disabled /wdXXXX
 709                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 710
 711                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 712                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 713                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 714
 715         endif()
 716
 717         if (NOT Qt5Core_FOUND)
 718                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 719                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 720                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 721         endif()
 722
 723         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 724         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 725         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 726         message(STATUS "")
 727 endif()
 728
 729
 730 if(LYX_DEBUG_GLIBC)
 731         set(_GLIBCXX_DEBUG ON)
 732 endif()
 733
 734 if(LYX_DEBUG_GLIBC_PEDANTIC)
 735         set(_GLIBCXX_DEBUG_PEDANTIC ON)
 736 endif()
 737
 738 # Xcode compiler
 739 if (CMAKE_GENERATOR MATCHES Xcode)
 740         if (XCODE_VERSION VERSION_LESS "5.0")
 741                 # Automatically select the Xcode compiler if not set
 742                 if (NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 743                         # XCode >= 3.1 has gcc 4.2 (up to actual Xcode)
 744                         if (XCODE_VERSION VERSION_GREATER "3.1")
 745                                 SET(CMAKE_XCODE_ATTRIBUTE_GCC_VERSION "com.apple.compilers.llvmgcc42")
 746                         ENDIF(XCODE_VERSION VERSION_GREATER "3.1")
 747                 ENDIF(NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 748                 # Print the selected compiler version
 749         MESSAGE(STATUS "---- Using XCode compiler CMAKE_XCODE_ATTRIBUTE_GCC_VERSION=${CMAKE_XCODE_ATTRIBUTE_GCC_VERSION}")
 750         ENDIF(XCODE_VERSION VERSION_LESS "5.0")
 751 ENDIF(CMAKE_GENERATOR MATCHES Xcode)
 752
 753 if (WIN32 AND Qt5Core_FOUND)
 754         set(Z_PREFIX 1)
 755 endif()
 756
 757 # compiler tests, config.h generation
 758 if(MSVC AND NOT LYX_CONFIGURE_CHECKS)
 759         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.msvc ${TOP_BINARY_DIR}/configCompiler.h)
 760 else()
 761         include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
 762         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
 763 endif()
 764
 765 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
 766
 767 if(QTVERSION MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+).*")
 768         MATH(EXPR QT4_VERSION "(${CMAKE_MATCH_1}<<16)|(${CMAKE_MATCH_2}<<8)|${CMAKE_MATCH_3}")
 769 endif()
 770
 771
 772 set (cmd ${CMAKE_CTEST_COMMAND})
 773 if (MSVC)
 774         set (cmd ${cmd} -C ${CMAKE_CFG_INTDIR})
 775 else ()
 776         set (cmd ${cmd} -C ${CMAKE_BUILD_TYPE})
 777 endif ()
 778 add_custom_target (lyx_run_tests COMMAND ${cmd})
 779 set_target_properties(lyx_run_tests PROPERTIES FOLDER "tests")
 780
 781
 782 if(LYX_INSTALL)
 783         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 784                 message(STATUS "Python required to create doc!")
 785         else()
 786                 add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
 787                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
 788         endif()
 789         include(../Install)
 790 endif()
 791
 792 add_subdirectory(src "${TOP_BINARY_DIR}/src")
 793 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
 794 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
 795 add_subdirectory(lib/examples "${TOP_BINARY_DIR}/lib/examples")
 796 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
 797 add_subdirectory(development/autotests "${TOP_BINARY_DIR}/autotests")
 798 if(LYX_ENABLE_URLTESTS)
 799         add_subdirectory(development/checkurls "${TOP_BINARY_DIR}/checkurls")
 800 endif()
 801
 802 message(STATUS)
 803 message(STATUS "Build options, switch LYX_* variables by -DLYX_*=ON or OFF:")
 804 message(STATUS)
 805 LYX_OPTION_LIST_ALL(used)
 806
 807
 808 if(LYX_NLS)
 809         message(STATUS)
 810         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
 811         message(STATUS)
 812         message(STATUS "  * iconv")
 813         message(STATUS "     - header : ${ICONV_HEADER}")
 814         message(STATUS "     - library: ${ICONV_LIBRARY}")
 815         message(STATUS "  * zlib")
 816         message(STATUS "     - header : ${ZLIB_HEADER}")
 817         message(STATUS "     - library: ${ZLIB_LIBRARY}")
 818         message(STATUS)
 819 endif()
 820
 821 include("${TOP_CMAKE_PATH}/LyxPackaging.cmake")
 822
 823 if(ENABLE_DIST)
 824   # Use git to create the source package
 825   # git archive --format=tgz --output=/home/kornel/x.tar.gz master
 826   if(UNIX)
 827     set(DIST_FORMAT tgz)
 828   else()
 829     set(DIST_FORMAT zip)
 830   endif()
 831   set(DIST_NAME ${CMAKE_PROJECT_NAME}-${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}-${CMAKE_SYSTEM_NAME}.${DIST_FORMAT})
 832
 833   add_custom_command(
 834     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME}
 835     COMMAND  ${LYX_GITVERSION} archive --format=${DIST_FORMAT} --output=${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME} master
 836     WORKING_DIRECTORY ${TOP_SRC_DIR})
 837   add_custom_target(git-archive DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME})
 838 endif()
 839
 840 # Last directory to be included so that the fixup code (OS X)
 841 # can be run last
 842 add_subdirectory(development/cmake/post_install)
 843
 844 message(STATUS)