CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2020 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 3.1.0)
   8
   9 set(LYX_PROJECT LyX)
  10 # Instruct cmake to not use gnu extensions,
  11 # this prevents the mix of '-std=c++*' and '-std=gnu++*' flags
  12 set(CMAKE_CXX_EXTENSIONS OFF)
  13
  14 enable_testing()
  15
  16 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README REALPATH) # Resolve symlinks
  17 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  18 message(STATUS "TOP_SRC_DIR = ${TOP_SRC_DIR}")
  19
  20 set(LYX_CMAKE_DIR "development/cmake")
  21 set(TOP_CMAKE_PATH "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}")
  22 set(TOP_MODULE_PATH "${TOP_CMAKE_PATH}/modules")
  23 set(TOP_SCRIPT_PATH "${TOP_CMAKE_PATH}/scripts")
  24
  25 set(CMAKE_MODULE_PATH "${TOP_MODULE_PATH}")
  26
  27 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  28
  29 message(STATUS)
  30 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  31         message(STATUS "Building in-source")
  32         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  33 else()
  34         message(STATUS "Building out-of-source")
  35         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  36 endif()
  37
  38 # This directory should be used if some test uses lyx-executable
  39 set(LYX_TESTS_USERDIR "${TOP_BINARY_DIR}/Testing/.lyx")
  40 file(MAKE_DIRECTORY "${LYX_TESTS_USERDIR}")
  41
  42 if(COMMAND cmake_policy)
  43         # Installing MACOSX_BUNDLE targets requires a BUNDLE DESTINATION
  44         cmake_policy(SET CMP0006 NEW)
  45         if(POLICY CMP0043)
  46                 # COMPILE_DEFINITIONS are not used yet. Enable new behavior.
  47                 cmake_policy(SET CMP0043 NEW)
  48         endif()
  49         cmake_policy(SET CMP0020 NEW)
  50         if(POLICY CMP0075)
  51                 cmake_policy(SET CMP0075 NEW)
  52         endif()
  53         if(POLICY CMP0077)
  54                 cmake_policy(SET CMP0077 NEW)
  55         endif()
  56 endif()
  57
  58 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  59
  60 # Supress regeneration
  61 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  62
  63 if(LYX_XMINGW)
  64     set(CMAKE_SYSTEM_NAME Windows)
  65     set(TOOLNAME ${LYX_XMINGW})
  66     set(TOOLCHAIN "${TOOLNAME}-")
  67     set(CMAKE_C_COMPILER   "${TOOLCHAIN}gcc"     CACHE PATH "Mingw C compiler" FORCE)
  68     set(CMAKE_CXX_COMPILER "${TOOLCHAIN}g++"     CACHE PATH "Mingw C++ compiler" FORCE)
  69     set(CMAKE_RC_COMPILER  "${TOOLCHAIN}windres" CACHE PATH "Mingw rc compiler" FORCE)
  70
  71     set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM BOTH)
  72     set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY)
  73     set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY)
  74 endif()
  75
  76 if(NOT help AND NOT HELP)
  77   # 'project' triggers the searching for a compiler
  78   project(${LYX_PROJECT})
  79   if (CMAKE_COMPILER_IS_GNUCXX)
  80     if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS "4.9")
  81       message(STATUS "Gnu CXX compiler version = ${CMAKE_CXX_COMPILER_VERSION}")
  82       message(STATUS "is too old, should be >= 4.9")
  83       message(FATAL_ERROR "Exiting")
  84     endif()
  85   endif()
  86 endif()
  87
  88 if(UNIX)
  89         set(ARCH_TRIPLET )
  90         FIND_PROGRAM(DPKG_ARCHITECTURE_EXECUTABLE dpkg-architecture)
  91         if(DPKG_ARCHITECTURE_EXECUTABLE)
  92                 EXECUTE_PROCESS(COMMAND ${DPKG_ARCHITECTURE_EXECUTABLE} -qDEB_HOST_MULTIARCH
  93                                 OUTPUT_VARIABLE ARCH_TRIPLET
  94                                 ERROR_VARIABLE ERROR_ARCH_TRIPLET
  95                                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  96         endif()
  97 endif()
  98 if(ARCH_TRIPLET)
  99         set(SYSTEM_LIB_DIRS /usr/lib /usr/lib/${ARCH_TRIPLET} /usr/local/lib)
 100 else()
 101         set(SYSTEM_LIB_DIRS /usr/lib /usr/local/lib)
 102 endif()
 103
 104 include(LyXMacros)
 105 include(LyXDestinations)
 106
 107 # Value of USE_POSIX_PACKAGING is needed in determineversionandbuildtype()
 108 if(WIN32)
 109         set(CMAKE_PREFIX_PATH Specify-path-to-Qt CACHE PATH "Used Qt version")
 110         if(MSVC)
 111                 set(LYX_3RDPARTY_BUILD ON CACHE BOOL "Build 3rdparty libraries" FORCE)
 112         endif()
 113         set(USE_WINDOWS_PACKAGING ON)
 114 elseif(APPLE)
 115         set(USE_MACOSX_PACKAGING ON)
 116 else()
 117         set(USE_POSIX_PACKAGING ON)
 118 endif()
 119
 120 determineversionandbuildtype("${TOP_SRC_DIR}/configure.ac" _package_list _version_list _envlist LYX_DATE LYX_BUILD_TYPE)
 121 list(GET _package_list 0 PACKAGE_BASE)
 122 list(GET _package_list 1 PACKAGE_VERSION)
 123 list(GET _package_list 2 PACKAGE_BUGREPORT)
 124 list(GET _envlist 0 LYX_DIR_VER)
 125 list(GET _envlist 1 LYX_USERDIR_VER)
 126 list(GET _version_list 0 LYX_VERSION)
 127 list(GET _version_list 1 LYX_MAJOR_VERSION)
 128 list(GET _version_list 2 LYX_MINOR_VERSION)
 129 list(GET _version_list 3 LYX_RELEASE_LEVEL)
 130 list(GET _version_list 4 LYX_RELEASE_PATCH)
 131
 132 # Usage LYX_OPTION
 133 # 1. parameter: option name without prefix 'LYX_'
 134 # 2. parameter: description
 135 # 3. parameter: default value, ON or OFF
 136 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
 137
 138 # Usage LYX_COMBO
 139 # 1. parameter: name without prefix 'LYX_'
 140 # 2. parameter: description
 141 # 3. parameter: default value
 142 # 4-n parameter: possible other string values
 143
 144 LYX_OPTION_INIT()
 145 LYX_COMBO(ENABLE_BUILD_TYPE  "Allows to tweak the compiled code" AUTO release prerelease development gprof)
 146
 147 if(LYX_ENABLE_BUILD_TYPE MATCHES "AUTO")
 148   message(STATUS "Selecting build type defaults from configure.ac")
 149 else()
 150   set(LYX_BUILD_TYPE "${LYX_ENABLE_BUILD_TYPE}")
 151   message(STATUS "Selecting build type defaults from LYX_ENABLE_BUILD_TYPE")
 152 endif()
 153
 154 # Select some defaults depending on LYX_BUILD_TYPE
 155 # they can always be overwritten by the respective command line settings
 156 # These settings are only effective on fresh(==empty) CMakeCache.txt
 157 if(LYX_BUILD_TYPE STREQUAL "development")
 158   set(DefaultLyxDebug ON)
 159   set(DefaultLyxRelease OFF)
 160   set(DefaultLyxStdlibDebug ON)
 161   set(DefaultLyxEnableAssertions ON)
 162   set(DefaultLyxProfile OFF)
 163   set(DefaultExternalLibs OFF)
 164 elseif(LYX_BUILD_TYPE STREQUAL "prerelease")
 165   set(DefaultLyxDebug OFF)
 166   set(DefaultLyxRelease OFF)
 167   set(DefaultLyxStdlibDebug OFF)
 168   set(DefaultLyxEnableAssertions OFF)
 169   set(DefaultLyxProfile OFF)
 170   set(DefaultExternalLibs ON)
 171 elseif(LYX_BUILD_TYPE STREQUAL "release")
 172   set(DefaultLyxDebug OFF)
 173   set(DefaultLyxRelease ON)
 174   set(DefaultLyxStdlibDebug OFF)
 175   set(DefaultLyxEnableAssertions OFF)
 176   set(DefaultLyxProfile OFF)
 177   set(DefaultExternalLibs ON)
 178 elseif(LYX_BUILD_TYPE STREQUAL "gprof")
 179   set(DefaultLyxDebug ON)
 180   set(DefaultLyxRelease OFF)
 181   set(DefaultLyxStdlibDebug OFF)
 182   set(DefaultLyxEnableAssertions OFF)
 183   set(DefaultLyxProfile ON)
 184   set(DefaultExternalLibs OFF)
 185 else()
 186   message(FATAL_ERROR "Invalid build type (${LYX_BUILD_TYPE}) encountered")
 187 endif()
 188
 189 # Options for all compilers/systems
 190 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
 191 LYX_OPTION(LOCALVERSIONING  "Add version info to created package name (only used if LYX_CPACK option set)" OFF ALL)
 192 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
 193 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
 194 LYX_OPTION(REQUIRE_SPELLCHECK "Abort if no spellchecker available" OFF ALL)
 195 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
 196 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
 197 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
 198 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" ${DefaultLyxRelease} ALL)
 199 LYX_OPTION(DEBUG            "Enforce debug build"  ${DefaultLyxDebug} ALL)
 200 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
 201 LYX_OPTION(ENABLE_ASSERTIONS "Run sanity checks in the program"  ${DefaultLyxEnableAssertions} ALL)
 202 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
 203 LYX_STRING(SUFFIX_VALUE     "Use this string as suffix" "")
 204 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
 205 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
 206 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
 207 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
 208 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
 209 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
 210 LYX_OPTION(ENABLE_URLTESTS  "Enable for URL tests" OFF ALL)
 211 LYX_OPTION(ENABLE_EXPORT_TESTS "Enable for export tests" OFF ALL)
 212 LYX_OPTION(ENABLE_KEYTESTS  "Enable for keytests" OFF ALL)
 213 if (NOT CMAKE_VERSION VERSION_LESS "3.17")
 214   LYX_OPTION(ENABLE_VALGRIND_TESTS  "Enable for tests involving valgrind" OFF ALL)
 215 else()
 216   if (LYX_ENABLE_VALGRIND_TESTS)
 217     unset(LYX_ENABLE_VALGRIND_TESTS CACHE)
 218   endif()
 219 endif()
 220 LYX_OPTION(ASAN             "Use address sanitizer" OFF ALL)
 221 #LYX_COMBO(USE_FILEDIALOG    "Use native or QT file dialog" QT NATIVE)
 222 LYX_COMBO(USE_QT            "Use Qt version as frontend" AUTO QT4 QT5)
 223 LYX_COMBO(USE_IPO           "Interprocedural optimization" OFF AUTO ON)
 224 #LYX_OPTION(3RDPARTY_BUILD   "Build 3rdparty libs" OFF ALL)
 225 LYX_OPTION(DISABLE_CALLSTACK_PRINTING "do not print a callstack when crashing" OFF ALL)
 226 LYX_OPTION(EXTERNAL_Z       "OFF := Build 3rdparty lib zlib" ${DefaultExternalLibs} ALL)
 227 LYX_OPTION(EXTERNAL_DTL     "OFF := Build 3rdparty commands dt2dv and dv2dt" ${DefaultExternalLibs} ALL)
 228 LYX_OPTION(EXTERNAL_ICONV   "OFF := Build 3rdparty lib iconvlib" ${DefaultExternalLibs} ALL)
 229 LYX_OPTION(EXTERNAL_HUNSPELL "OFF := Build 3rdparty lib hunspelllib" ${DefaultExternalLibs} ALL)
 230 LYX_COMBO(EXTERNAL_MYTHES   "OFF := Build 3rdparty lib mytheslib" AUTO OFF ON)
 231
 232 # GCC specific
 233 LYX_OPTION(PROFILE              "Build with options for gprof" ${DefaultLyxProfile} GCC)
 234 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" ${DefaultExternalLibs} GCC)
 235 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
 236 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
 237 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++ pedantic debug mode" OFF GCC)
 238 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" ${DefaultLyxStdlibDebug} GCC)
 239
 240 # MSVC specific
 241 LYX_OPTION(CONSOLE               "Show console on Windows" ON MSVC)
 242 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
 243 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
 244 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
 245
 246 # APPLE specific
 247 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
 248 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
 249
 250 # Try to get some informations from configure.ac
 251 include(LyXPaths)
 252
 253
 254 if(help OR HELP)
 255         message(STATUS)
 256         message(STATUS "Available options: (dis/enable with -DLYX_*=OFF/ON)")
 257         message(STATUS)
 258         LYX_OPTION_LIST_ALL(help)
 259         message(STATUS)
 260         unset(help CACHE)
 261         unset(HELP CACHE)
 262         RETURN()
 263 endif()
 264
 265 if ("${LYX_SUFFIX_VALUE}" MATCHES "")
 266   set(LYX_INSTALL_SUFFIX "${LYX_MAJOR_VERSION}.${LYX_MINOR_VERSION}")
 267 else()
 268   set(LYX_INSTALL_SUFFIX "${LYX_SUFFIX_VALUE}")
 269 endif()
 270
 271 # Check option dependencies
 272 if (LYX_ENABLE_VALGRIND_TESTS)
 273         find_program(VALGRIND_EXECUTABLE "valgrind")
 274         if (NOT VALGRIND_EXECUTABLE)
 275                 message(FATAL_ERROR "Cannot use valgrind tests, executable valgrind is missing. Please disable LYX_ENABLE_VALGRIND_TESTS")
 276         endif()
 277 endif()
 278 if (LYX_DEBUG_GLIBC OR LYX_DEBUG_GLIBC_PEDANTIC OR LYX_STDLIB_DEBUG)
 279   if (LYX_EXTERNAL_BOOST)
 280     message(FATAL_ERROR "Using external boost not compatible with debug mode for stdlib")
 281   endif()
 282 endif()
 283
 284 if(LYX_DMG)
 285         set(LYX_BUNDLE ON)
 286         set(LYX_CPACK ON)
 287 endif()
 288
 289 if(LYX_CPACK)
 290         set(LYX_INSTALL ON)
 291 endif()
 292
 293 if(LYX_INSTALL)
 294         set(LYX_NLS ON)
 295         if(WIN32 AND NOT MINGW)
 296                 set(LYX_HUNSPELL ON)
 297         endif()
 298         set(LYX_PACKAGE_SUFFIX ON)
 299         if(NOT LYX_DEBUG)
 300                 set(LYX_RELEASE ON)
 301         endif()
 302         set(LYX_PROFILE OFF)
 303 endif()
 304
 305
 306 if(LYX_MERGE_FILES)
 307         set(LYX_PCH OFF)
 308 else()
 309         set(LYX_MERGE_REBUILD OFF)
 310 endif()
 311
 312 if(LYX_DEPENDENCIES_DOWNLOAD)
 313         message(STATUS)
 314         if(MSVC14)
 315                 set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2015-deps)
 316                 set(deps_files lyx-windows-deps-msvc2015.zip)
 317                 set(deps_server http://ftp.lyx.de/LyX-Windows-Deps)
 318                 set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2015)
 319         elseif(MSVC10)
 320                 set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 321                 set(deps_files lyx-windows-deps-msvc2010.zip)
 322                 set(deps_server http://ftp.lyx.de/LyX-Windows-Deps)
 323                 set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2010)
 324         else()
 325                 message(FATAL_ERROR "error: no dependency package known for the selected MSVC version.")
 326         endif()
 327     message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 328         foreach(it ${deps_files})
 329                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 330                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 331                 if(NOT already_downloaded)
 332                         message(STATUS "Downloading ${it} ...")
 333                         file(DOWNLOAD ${deps_server}/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS STATUS status LOG log)
 334                         list(GET status 0 status_code)
 335                         list(GET status 1 status_string)
 336                         if(NOT status_code EQUAL 0)
 337                                 file(REMOVE ${LYX_DEPENDENCIES_DIR}/${it})
 338                                 message(FATAL_ERROR "error: downloading '${it}' failed. status_code: ${status_code}, status_string: ${status_string}. \nLog: ${log} ")
 339                         endif()
 340                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 341                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 342                 endif()
 343         endforeach()
 344 endif()
 345
 346 message(STATUS)
 347
 348 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 349 if(WIN32)
 350         set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 351 else()
 352         set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 353 endif()
 354
 355 set(LYX_IPO_SUPPORTED OFF)
 356 if (POLICY CMP0069)
 357   cmake_policy(SET CMP0069 NEW)
 358   if(LYX_USE_IPO MATCHES "AUTO")
 359     # Enable LTO if supported and not debugging
 360     if (NOT LYX_DEBUG)
 361       include(CheckIPOSupported)
 362       check_ipo_supported(RESULT LYX_IPO_SUPPORTED)
 363     endif()
 364   else()
 365     set(LYX_IPO_SUPPORTED ${LYX_USE_IPO})
 366   endif()
 367 endif()
 368 if (LYX_IPO_SUPPORTED)
 369   set(LYX_USE_IPO "ON" CACHE STRING "Use interprocedural optimization" FORCE)
 370 else()
 371   set(LYX_USE_IPO "OFF" CACHE STRING "Use interprocedural optimization" FORCE)
 372 endif()
 373
 374 # Set to some meaningful default
 375 find_package(CXX11Compiler)
 376 if(NOT CXX11COMPILER_FOUND)
 377         message(FATAL_ERROR "A C++11 compatible compiler is required.")
 378 endif()
 379 unset(LYX_GCC11_MODE)
 380 if(UNIX OR MINGW)
 381         if (CMAKE_CXX_COMPILER_ID MATCHES "^([cC]lang|AppleClang)$")
 382           # ignore the GCC_VERSION for clang
 383           message(STATUS "Using clang")
 384         else()
 385           execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpfullversion OUTPUT_VARIABLE GCC_VERSION ERROR_VARIABLE _error RESULT_VARIABLE _err OUTPUT_STRIP_TRAILING_WHITESPACE)
 386           #message(STATUS "dumpfullversion: error = ${_error}, result = ${_err}")
 387           if (_err)
 388             # previous check failed, try again with _old_ parameter
 389             execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION ERROR_VARIABLE _error RESULT_VARIABLE _err OUTPUT_STRIP_TRAILING_WHITESPACE)
 390             #message(STATUS "dumpversion: error = ${_error}, result = ${_err}")
 391           endif()
 392           message(STATUS "Using GCC version ${GCC_VERSION}")
 393           if(GCC_VERSION VERSION_LESS 4.9)
 394                 message(FATAL_ERROR "gcc >= 4.9 is required.")
 395           endif()
 396         endif()
 397         set(LYX_GCC11_MODE "${CXX11_FLAG}")
 398 else()
 399         if(MSVC_VERSION LESS 1900)
 400                 # Drop support for msvc versions prior to 1900 (Visual Studio 2015)
 401                 message(FATAL_ERROR "Visual Studio >= 2015 is required.")
 402         endif()
 403 endif()
 404
 405 if(LYX_3RDPARTY_BUILD)
 406   # LYX_3RDPARTY_BUILD is not cached anymore, but for compatibility reasons
 407   # this enables the build of all 3rd_party libs
 408   set(LYX_EXTERNAL_Z        OFF CACHE BOOL "Build 3rdparty lib zlib"    FORCE)
 409   set(LYX_EXTERNAL_ICONV    OFF CACHE BOOL "Build 3rdparty iconvlib"    FORCE)
 410   set(LYX_EXTERNAL_HUNSPELL OFF CACHE BOOL "Build 3rdparty hunspelllib" FORCE)
 411   set(LYX_EXTERNAL_MYTHES   OFF CACHE STRING "Build 3rdparty mytheslib" FORCE)
 412 endif()
 413
 414 FIND_PROGRAM(LYX_GITVERSION git)
 415 #message(STATUS "gitversion = ${LYX_GITVERSION}")
 416 set(LYX_REVISION_VERSION ${LYX_RELEASE_LEVEL})
 417 set(LYX_PACKAGE_RELEASE "UNDEFINED")
 418 if(LYX_GITVERSION)
 419   if (LYX_LOCALVERSIONING)
 420     # Find the revision number for later use
 421     EXECUTE_PROCESS(COMMAND ${LYX_GITVERSION} describe --match 2.0.0 HEAD
 422       WORKING_DIRECTORY "${TOP_SRC_DIR}"
 423       RESULT_VARIABLE tmp_GIT_RESULT
 424       OUTPUT_VARIABLE tmp_LYX_PACKAGE_RELEASE
 425       ERROR_VARIABLE tmp_GIT_ERROR
 426       OUTPUT_STRIP_TRAILING_WHITESPACE)
 427     if (tmp_GIT_RESULT EQUAL 0)
 428       if (tmp_LYX_PACKAGE_RELEASE MATCHES "^2\\.0\\.0\\-\([0-9]+\)\\-\(.*\)$")
 429         set(LYX_PACKAGE_RELEASE ${CMAKE_MATCH_2})
 430         # We will add offset of 40000 to get appropriate value to
 431         # previous svn.
 432         # We use this value than also to set the package-patch-value
 433         MATH(EXPR tmp_REVISION_VERSION "(${CMAKE_MATCH_1}+40000)")
 434         set(LYX_REVISION_VERSION "${LYX_RELEASE_LEVEL}-${tmp_REVISION_VERSION}git")
 435         set(ENABLE_DIST ON)
 436       endif()
 437     endif()
 438   endif()
 439 endif()
 440 if (LYX_PACKAGE_RELEASE MATCHES "UNDEFINED")
 441   set(LYX_PACKAGE_RELEASE  "1")
 442   if (LYX_RELEASE_PATCH GREATER 0)
 443     set(LYX_REVISION_VERSION "${LYX_RELEASE_LEVEL}.${LYX_RELEASE_PATCH}")
 444   endif()
 445 endif()
 446
 447 # Set the programs (lyx, tex2lyx, etc.) suffix
 448 # When building an OS X bundle, we will append
 449 # the suffix only to the bundle, not to the programs
 450 set(PROGRAM_SUFFIX "")
 451 if(LYX_PROGRAM_SUFFIX AND NOT (APPLE AND LYX_BUNDLE))
 452         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 453 endif()
 454 set(_lyx "${PACKAGE_BASE}${PROGRAM_SUFFIX}")
 455 set(_tex2lyx tex2lyx${PROGRAM_SUFFIX})
 456 set(_convert lyxconvert${PROGRAM_SUFFIX})
 457
 458 add_custom_target(lyx_version ALL
 459   COMMAND ${CMAKE_COMMAND} -DTOP_SRC_DIR=${TOP_SRC_DIR} -DTOP_CMAKE_PATH=${TOP_CMAKE_PATH} -DTOP_BINARY_DIR=${TOP_BINARY_DIR} -DLYX_DATE=${LYX_DATE} -P ${TOP_SCRIPT_PATH}/LyXGetVersion.cmake
 460   )
 461 set_target_properties(lyx_version PROPERTIES FOLDER "applications")
 462
 463 # Default paths for installed utilities (tex2lyx, lyxclient, etc.)
 464 set(LYX_UTILITIES_INSTALL_PATH bin)
 465
 466 if(LYX_BUNDLE)
 467         set(LYX_CPACK ON)
 468
 469         message(STATUS)
 470         message(STATUS "Bundle creation is enabled (experimental):")
 471         message(STATUS "    make")
 472         message(STATUS "    make install/strip")
 473         message(STATUS "    make package")
 474         if(APPLE)
 475                 set(MACOSX_BUNDLE TRUE)
 476                 # This sets the bundle + executable names
 477                 set(_lyx "${PACKAGE_BASE}${LYX_INSTALL_SUFFIX}")
 478                 # This sets the Info.plist executable name
 479                 set(osx_bundle_program_name ${_lyx})
 480                 # Bundle name
 481                 set(LYX_BUNDLE_NAME ${_lyx})
 482
 483                 # This will contain the list of files that need to be included
 484                 # in the bundle and their location within the bundle
 485                 set(OSX_BUNDLE_FILES "${TOP_SRC_DIR}/development/MacOSX/LyX.sdef;${TOP_SRC_DIR}/development/MacOSX/LyXapp.icns;${CMAKE_BINARY_DIR}/lyxrc.dist")
 486                 set(OSX_BUNDLE_DIRS "Resources;Resources;Resources")
 487
 488                 # Process Info.plist and lyxrc.dist
 489                 # See development/cmake/Install.cmake
 490                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/Info.plist.in" "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 491
 492                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 493                 set(LYX_DATA_SUBDIR ${LYX_BUNDLE_NAME}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 494
 495                 # Variables used by CPack
 496                 set(CPACK_BUNDLE_NAME ${LYX_BUNDLE_NAME})
 497                 set(CPACK_BUNDLE_PLIST "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 498                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${LYX_BUNDLE_NAME}.app)
 499
 500                 # Set the install paths
 501                 set(LYX_UTILITIES_INSTALL_PATH ${LYX_BUNDLE_NAME}.app/Contents/MacOS)
 502                 if(NOT LYX_INSTALL_PREFIX)
 503                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 504                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 505                 endif()
 506                 # Change the owner so that the install can work
 507                 install(CODE "set(BU_CHMOD_BUNDLE_ITEMS 1)" COMPONENT Runtime)
 508         elseif(UNIX)
 509                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 510                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 511                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 512         elseif(WIN32)
 513                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 514         endif()
 515 endif()
 516
 517 if(LYX_INSTALL_PREFIX)
 518         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 519         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 520 endif()
 521 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 522
 523 if(UNIX)
 524   set(SYSTEM_DATADIR "${CMAKE_INSTALL_PREFIX}/share")
 525 elseif(CMAKE_INSTALL_PREFIX MATCHES "/lyx${LYX_INSTALL_SUFFIX}$")
 526   string(REGEX REPLACE "/lyx${LYX_INSTALL_SUFFIX}$" "/share" SYSTEM_DATADIR ${CMAKE_INSTALL_PREFIX})
 527 else()
 528   set(SYSTEM_DATADIR "${CMAKE_INSTALL_PREFIX}")
 529 endif()
 530
 531 if(NOT CMAKE_COMPILER_IS_GNUCXX)
 532   # Not a GCC compiler, programs do not have a suffix
 533   set(suffixing ${LYX_PACKAGE_SUFFIX})
 534 elseif(WIN32 AND MINGW)
 535   # We want to use a suffix for the package in this case,
 536   # even if not for the program
 537   set(suffixing ${LYX_PACKAGE_SUFFIX})
 538 else()
 539   message(STATUS "CMAKE_COMPILER_IS_GNUCXX = ${CMAKE_COMPILER_IS_GNUCXX}")
 540   set(suffixing ${LYX_PROGRAM_SUFFIX})
 541 endif()
 542
 543 # The define PACKAGE below allows lyx-executable to find its default configuration files
 544 # see routines
 545 #    Package::messages_file()
 546 #    get_default_user_support_dir()
 547 #    relative_system_support_dir()
 548 # in src/support/Package.cpp
 549 if(suffixing)
 550         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 551 else()
 552         set(PACKAGE ${PACKAGE_BASE})
 553 endif()
 554
 555 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 556         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 557         if (UNIX)
 558                 # use the default "/usr/local"
 559                 # but respect the user-choice on the command-line
 560                 set(CMAKE_INSTALL_PREFIX "/usr/local" CACHE PATH "LyX default install prefix" FORCE)
 561         endif()
 562 endif()
 563 if(WIN32)
 564         set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 565 endif()
 566 if(IS_ABSOLUTE)
 567         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 568 else()
 569         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 570 endif()
 571
 572
 573
 574 if(NOT LYX_DATA_SUBDIR)
 575         if (WIN32)
 576                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 577         else()
 578                 set(LYX_DATA_SUBDIR "share/${_lyx}/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 579         endif()
 580 endif()
 581
 582 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}/${LYX_DATA_SUBDIR}")
 583 get_locale_destination(LYX_LOCALEDIR)
 584 set(LYX_ABS_INSTALLED_LOCALEDIR "${CMAKE_INSTALL_PREFIX}/${LYX_LOCALEDIR}")
 585 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 586
 587 if(LYX_BUNDLE AND APPLE)
 588         set(LYX_MAN_DIR_tmp "${LYX_DATA_SUBDIR}")
 589 else()
 590         if(WIN32)
 591                 set(LYX_MAN_DIR_tmp "${CMAKE_BINARY_DIR}/usr/local/man/")
 592         elseif(UNIX)
 593                 set(LYX_MAN_DIR_tmp "${CMAKE_INSTALL_PREFIX}/share/man/")
 594         else()
 595                 set(LYX_MAN_DIR_tmp "${CMAKE_INSTALL_PREFIX}/man/")
 596         endif()
 597 endif()
 598 if (NOT LYX_MAN_DIR_tmp EQUAL "${LYX_MAN_DIR}")
 599         unset(LYX_MAN_DIR CACHE)
 600         set(LYX_MAN_DIR "${LYX_MAN_DIR_tmp}" CACHE STRING "Install location for man pages.")
 601 endif()
 602 unset(LYX_MAN_DIR_tmp)
 603 mark_as_advanced(LYX_MAN_DIR)
 604
 605 # The Win installer cannot be built by CMake because one needs to install plugins for NSIS
 606 # see the Readme.txt of the installer
 607 #if(LYX_INSTALL AND WIN32)
 608 #       message(STATUS "Configuring NSIS files")
 609 #       configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 610 #       configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 611 #       configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 612 #       message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 613 #endif()
 614
 615 if(NOT GROUP_CODE)
 616         #set(GROUP_CODE "The Golden Code")
 617         set(GROUP_CODE flat)
 618 endif()
 619
 620 # lyx's source files
 621 set(LYX_CPP_FILES [a-zA-Z]*.cpp)
 622 set(LYX_HPP_FILES [a-zA-Z]*.h)
 623 set(LYX_MOC_FILES moc_*.cpp)
 624
 625 include(ProjectSourceGroup)
 626
 627
 628 if(LYX_PROFILE AND NOT MSVC)
 629         set(CMAKE_BUILD_TYPE Profile CACHE STRING "Profile build type" FORCE)
 630         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg")
 631         set(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS}  -pg")
 632 else()
 633         set(LYX_PROFILE OFF)
 634 endif()
 635
 636
 637 if(LYX_NO_OPTIMIZE)
 638         set(CMAKE_BUILD_TYPE None)
 639         set(LYX_DEBUG OFF)
 640         set(LYX_RELEASE OFF)
 641         set(LYX_PROFILE OFF)
 642 elseif(LYX_RELEASE)
 643         set(CMAKE_BUILD_TYPE Release)
 644         set(LYX_DEBUG OFF)
 645         set(LYX_PROFILE OFF)
 646 elseif(LYX_PROFILE)
 647         set(CMAKE_BUILD_TYPE Profile)
 648         set(LYX_DEBUG OFF)
 649 else()
 650         set(CMAKE_BUILD_TYPE Debug)
 651         set(LYX_DEBUG ON)
 652 endif()
 653
 654
 655 # When shared libs are supported enable this option
 656 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 657 if(LYX_SHARED_LIBRARIES)
 658         set(library_type SHARED)
 659 else()
 660         set(library_type STATIC)
 661 endif()
 662
 663 if(LYX_ENABLE_ASSERTIONS)
 664   set(LYX_CXX_FLAGS " -DENABLE_ASSERTIONS=1")
 665 else()
 666   set(LYX_CXX_FLAGS "")
 667 endif()
 668
 669 if(MSVC)
 670   if (CXX11_FLAG MATCHES "\\+\\+([0-9]+)")
 671     set(CMAKE_CXX_STANDARD ${CMAKE_MATCH_1})
 672     message(STATUS "CMAKE_CXX_STANDARD set to ${CMAKE_CXX_STANDARD}")
 673   endif()
 674   set(CMAKE_CXX_FLAGS       "${CMAKE_CXX_FLAGS}${LYX_CXX_FLAGS}")
 675 else()
 676         if(NOT LYX_QUIET)
 677                 set(CMAKE_VERBOSE_MAKEFILE ON)
 678         endif()
 679         if(LYX_GCC11_MODE MATCHES "\\+\\+([0-9][0-9])")
 680           # Thanks to Brad King <brad.king@kitware.com>
 681           # for the pointer to https://cmake.org/cmake/help/v3.6/variable/CMAKE_CXX_STANDARD.html
 682           # This allows us to use QT5.7 with recent g++ (version >= 4.9) compilers
 683           # and still use our own c++ extension tests
 684           set(std_num ${CMAKE_MATCH_1})
 685           set(CMAKE_CXX_STANDARD ${std_num})
 686         else()
 687           message(STATUS "Setting CMAKE_CXX_STANDARD 11 as fallback")
 688           set(CMAKE_CXX_STANDARD 11)
 689           set(LYX_GCC11_MODE "--std=c++11")
 690         endif()
 691         # The following setting with LYX_GCC11_MODE is needed because cmake does not honor
 692         # CMAKE_CXX_STANDARD while performing tests like
 693         # check_cxx_source_compiles("..." HAVE_DEF_MAKE_UNIQUE)
 694         set(LYX_CXX_FLAGS "-Wall -Wextra -Wno-deprecated-copy ${LYX_GCC11_MODE}${LYX_CXX_FLAGS}")
 695         if(LYX_STDLIB_DEBUG)
 696           set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 697         else()
 698           if(LYX_DEBUG_GLIBC)
 699             set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG")
 700           endif()
 701           if(LYX_DEBUG_GLIBC_PEDANTIC)
 702             set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG_PEDANTIC")
 703           endif()
 704         endif()
 705         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE STRING "Set CXX flags" FORCE)
 706         set(CMAKE_CXX_FLAGS_DEBUG "-O0 -g3 -D_DEBUG" CACHE STRING "Set debug flags" FORCE)
 707         if(MINGW)
 708                 set(CMAKE_CXX_FLAGS_RELEASE "-O2 -DNDEBUG" CACHE STRING "Set release flags for Mingw" FORCE)
 709         else()
 710                 set(CMAKE_CXX_FLAGS_RELEASE "-O3 -DNDEBUG" CACHE STRING "Set release flags" FORCE)
 711         endif()
 712 endif()
 713
 714 if(LYX_ASAN)
 715     set(CMAKE_CXX_FLAGS "-fsanitize=address -fno-omit-frame-pointer -g ${CMAKE_CXX_FLAGS}")
 716     message(STATUS)
 717     message(STATUS "Address sanitizer enabled. Usage:")
 718     message(STATUS "    wget https://llvm.org/svn/llvm-project/compiler-rt/trunk/lib/asan/scripts/asan_symbolize.py")
 719     message(STATUS "    chmod  +x ./asan_symbolize.py")
 720     message(STATUS "    ./bin/${_lyx} 2>&1 | ./asan_symbolize.py  | c++filt ")
 721     message(STATUS)
 722 endif()
 723
 724 set(LYX_CXX_FLAGS_EXTRA "" CACHE STRING "Desired semicolon separated list of extra cxx compile flags, like '-Werror'")
 725 mark_as_advanced(LYX_CXX_FLAGS_EXTRA)
 726 if(LYX_CXX_FLAGS_EXTRA)
 727         foreach(_flag ${LYX_CXX_FLAGS_EXTRA})
 728                 add_definitions(${_flag})
 729         endforeach()
 730 endif()
 731
 732 if(LYX_XMINGW)
 733         list(APPEND CMAKE_FIND_ROOT_PATH ${GNUWIN32_DIR})
 734 endif()
 735
 736 set(min_qt5_version "5.6")
 737 if(LYX_USE_QT MATCHES "AUTO")
 738         # try qt5 first
 739         find_package(Qt5Core CONFIG QUIET)
 740         if(Qt5Core_FOUND)
 741                 set(LYX_USE_QT "QT5" CACHE STRING "Valid qt version" FORCE)
 742                 message(STATUS "Qt5Core_VERSION = ${Qt5Core_VERSION}")
 743                 if(Qt5Core_VERSION VERSION_LESS ${min_qt5_version})
 744                         find_package(Qt4 "4.5.0" QUIET)
 745                         if(QT4_FOUND)
 746                                 set(LYX_USE_QT "QT4" CACHE STRING "Valid qt version" FORCE)
 747                         endif()
 748                 endif()
 749         else()
 750                 set(LYX_USE_QT "QT4" CACHE STRING "Valid qt version" FORCE)
 751         endif()
 752 endif()
 753 if(LYX_USE_QT MATCHES "QT5")
 754         # set QPA_XCB if QT uses X11
 755         find_package(Qt5Core CONFIG REQUIRED)
 756         if (Qt5Core_FOUND)
 757                 find_package(Qt5Widgets CONFIG REQUIRED)
 758                 if(APPLE)
 759                         find_package(Qt5MacExtras CONFIG REQUIRED)
 760                 endif()
 761                 find_package(Qt5X11Extras CONFIG QUIET)
 762                 find_package(Qt5WinExtras CONFIG QUIET)
 763                 set(QTVERSION ${Qt5Core_VERSION})
 764                 if (QTVERSION VERSION_LESS ${min_qt5_version})
 765                         message(STATUS "QTVERSION = \"${QTVERSION}\"")
 766                         message(STATUS "This version is not recommended, try either option -DLYX_USE_QT=QT4 or")
 767                         message(STATUS "install QT-Version >= \"${min_qt5_version}\"")
 768                         # see thread in lyx-devel list
 769                         # From: Jean-Pierre Chrétien <jeanpierre.chretien@free.fr>
 770                         # Date 11.03.2017
 771                         # Subject: cmake compilation error
 772                         #message(FATAL_ERROR "Wrong Qt-Version")
 773                 endif()
 774                 macro (qt_use_modules lyxtarget)
 775                         foreach (_tg ${ARGN})
 776                                 find_package(Qt5${_tg} CONFIG REQUIRED)
 777                                 target_link_libraries(${lyxtarget} Qt5::${_tg})
 778                         endforeach()
 779                 endmacro()
 780                 macro (qt_add_resources)
 781                         qt5_add_resources(${ARGN})
 782                 endmacro()
 783                 macro (qt_wrap_uifiles)
 784                         qt5_wrap_ui(${ARGN})
 785                 endmacro()
 786                 message(STATUS "Found Qt-Version ${QTVERSION}")
 787                 if(WIN32)
 788                         set(LYX_QTMAIN_LIBRARY ${Qt5Core_QTMAIN_LIBRARIES})
 789                 endif()
 790         endif()
 791 elseif(LYX_USE_QT MATCHES "QT4")
 792         if(LYX_XMINGW)
 793                 set(QT_MINGW_DIR ${LYX_QT4} CACHE PATH "Qt for Mingw" FORCE)
 794                 list(APPEND CMAKE_FIND_ROOT_PATH ${QT_MINGW_DIR} ${GNUWIN32_DIR})
 795         endif()
 796         find_package(Qt4 "4.5.0" REQUIRED)
 797         macro (qt_use_modules)
 798         endmacro()
 799         macro (qt_add_resources)
 800                 qt4_add_resources(${ARGN})
 801         endmacro()
 802         macro (qt_wrap_uifiles)
 803                 qt4_wrap_ui(${ARGN})
 804         endmacro()
 805         set(LYX_QTMAIN_LIBRARY ${QT_QTSVG_LIBRARY})
 806         if(WIN32)
 807                 list(APPEND LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARIES})
 808         endif()
 809 else()
 810   message(FATAL_ERROR "Unhandled value for LYX_USE_QT (${LYX_USE_QT})")
 811 endif()
 812
 813 find_package(Magic)
 814 if(Magic_FOUND)
 815   set(HAVE_MAGIC_H 1)
 816   include_directories(${Magic_INCLUDE_DIR})
 817 endif()
 818
 819 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 820
 821 set(Spelling_FOUND OFF)
 822 set(Include_used_spellchecker)   # String will be inserted into config.h
 823
 824 if (LYX_EXTERNAL_MYTHES MATCHES "AUTO")
 825   # try system library first
 826   find_package(MYTHESLIB)
 827   if (MYTHESLIB_FOUND)
 828     set(LYX_EXTERNAL_MYTHES ON CACHE STRING "OFF:= Build 3rdparty mytheslib" FORCE)
 829   else()
 830     set(LYX_EXTERNAL_MYTHES OFF CACHE STRING "OFF:= Build 3rdparty mytheslib" FORCE)
 831   endif()
 832 endif()
 833 if (LYX_EXTERNAL_MYTHES MATCHES "ON")
 834   find_package(MYTHESLIB REQUIRED)
 835 else()
 836   add_subdirectory(3rdparty/mythes)
 837 endif()
 838 set(MYTHES_DIR ${MYTHESLIB_INCLUDE_DIR})
 839
 840 if(NOT LYX_EXTERNAL_HUNSPELL)
 841     add_subdirectory(3rdparty/hunspell)
 842     add_definitions(-DHUNSPELL_STATIC)
 843     set(HUNSPELL_FOUND ON)
 844     message(STATUS "  * Hunspell:")
 845     message(STATUS "     - include: ${HUNSPELL_INCLUDE_DIR}")
 846     message(STATUS "     - library: ${HUNSPELL_LIBRARY}")
 847 endif()
 848
 849 foreach(_spell "ASPELL" "ENCHANT" "HUNSPELL")
 850   string(TOUPPER ${_spell} _upspell)
 851   if (NOT ${_upspell}_FOUND)
 852     find_package(${_spell})
 853   endif()
 854   if (${_upspell}_FOUND)
 855     include_directories(${${_upspell}_INCLUDE_DIR})
 856     set(Spelling_FOUND ON)
 857     message(STATUS "Building with USE_${_upspell}")
 858     set(Include_used_spellchecker "${Include_used_spellchecker}#define USE_${_upspell} 1\n")
 859   else()
 860     if(LYX_${_upspell})
 861       message(FATAL_ERROR "Required ${_spell} devel package not found")
 862     else()
 863       message(STATUS "${_upspell} not found, building without ${_spell} support")
 864     endif()
 865   endif()
 866 endforeach()
 867
 868 if(GNUWIN32_DIR)
 869         list(APPEND CMAKE_PROGRAM_PATH "${GNUWIN32_DIR}/Python" )
 870         list(APPEND CMAKE_PROGRAM_PATH "${GNUWIN32_DIR}/Perl/bin" )
 871 endif()
 872
 873 # Search for python default version first
 874 unset(PYTHON_EXECUTABLE CACHE)
 875 unset(LYX_PYTHON_EXECUTABLE CACHE)
 876 unset(PYTHON_VERSION_MAJOR)
 877 unset(PYTHON_VERSION_MINOR)
 878 unset(PYTHON_VERSION_STRING)
 879 if (CMAKE_VERSION VERSION_LESS "3.13")
 880   find_package(PythonInterp 3.5 QUIET)
 881   if(NOT PYTHONINTERP_FOUND)
 882     find_package(PythonInterp 2.0 REQUIRED)
 883     if(NOT PYTHON_VERSION_STRING VERSION_LESS 2.8)
 884       message(FATAL_ERROR "Python interpreter found, but is not suitable")
 885     endif()
 886   endif()
 887   set(LYX_PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 888 else()
 889   find_package(Python3 3.5 QUIET)
 890   if(NOT Python3_Interpreter_FOUND)
 891     unset(PYTHON_EXECUTABLE CACHE)
 892     find_package(Python2 2.0 REQUIRED)
 893     if(NOT Python2_VERSION VERSION_LESS 2.8)
 894       message(FATAL_ERROR "Python interpreter found, but is not suitable")
 895     endif()
 896     set(LYX_PYTHON_EXECUTABLE ${Python2_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 897   else()
 898     set(LYX_PYTHON_EXECUTABLE ${Python3_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 899   endif()
 900 endif()
 901
 902 if(LYX_NLS)
 903         find_package(LyXGettext)
 904         if(LYX_PYTHON_EXECUTABLE AND GETTEXT_FOUND)
 905                 add_subdirectory(po "${TOP_BINARY_DIR}/po")
 906         else()
 907                 # Install only supplied .gmo-files
 908                 file(GLOB _gmofiles RELATIVE "${TOP_SRC_DIR}/po" "${TOP_SRC_DIR}/po/*.gmo")
 909                 message(STATUS "Installing provided .gmo-files only")
 910                 foreach( _gmo ${_gmofiles})
 911                         string(REGEX REPLACE "\\.gmo$" "" _lang ${_gmo})
 912                         install(FILES "${TOP_SRC_DIR}/po/${_gmo}" DESTINATION ${LYX_LOCALEDIR}/${_lang}/LC_MESSAGES RENAME ${PACKAGE}.mo)
 913                 endforeach()
 914         endif()
 915 endif()
 916
 917 if(LYX_EXTERNAL_ICONV)
 918   # Possible remnants of previous run without external iconv
 919   file(REMOVE_RECURSE "${CMAKE_BINARY_DIR}/libiconv" "${CMAKE_BINARY_DIR}/3rdparty/libiconv")
 920   find_package(ICONV REQUIRED)
 921 else()
 922   add_subdirectory(3rdparty/libiconv)
 923   set(HAVE_ICONV_CONST 1)
 924 endif()
 925
 926 if(LYX_EXTERNAL_Z)
 927   find_package(ZLIB REQUIRED)
 928 else()
 929   add_subdirectory(3rdparty/zlib)
 930 endif()
 931
 932 if(NOT LYX_EXTERNAL_DTL)
 933   add_subdirectory(3rdparty/dtl)
 934 endif()
 935
 936 # Set only include path.
 937 # Use internal boost, which is known to exist
 938 # we don't need any libraries
 939 set(Lyx_Boost_Libraries)
 940 add_definitions(-DBOOST_USER_CONFIG=<config.h>)
 941 include_directories(${TOP_SRC_DIR}/3rdparty/boost)
 942
 943 if(WIN32)
 944         if(LYX_CONSOLE)
 945                 set(LYX_QTMAIN_LIBRARY)
 946         else()
 947                 set(WIN32_CONSOLE WIN32)
 948         endif()
 949         if(MSVC)
 950                 # -DPSAPI_VERSION=1 is needed to run on vista (bug 10186)
 951                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX -DPSAPI_VERSION=1)
 952                 # disable checked iterators for msvc release builds to get maximum speed
 953                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 954         else()
 955                 # -DPSAPI_VERSION=1 is not needed for mingw, since the mingw psapi.h
 956                 # does not use it and always declares the vista compatible API.
 957                 # If this ever changes then -DPSAPI_VERSION might be needed here as well.
 958                 add_definitions(-DWINVER=0x0500)
 959         endif()
 960 endif()
 961
 962 # Compute qt-version from ${QTVERSION}
 963
 964 message(STATUS "")
 965 foreach(_v PACKAGE PACKAGE_VERSION
 966         PROGRAM_SUFFIX LYX_VERSION LYX_DIR_VER LYX_USERDIR_VER
 967         LYX_ABS_TOP_SRCDIR
 968         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 969         if(NOT DEFINED ${_v})
 970                 message(FATAL_ERROR "${_v} not defined")
 971         endif()
 972         string(SUBSTRING "${_v}                            " 0 28 _v1)
 973         message(STATUS "----- ${_v1}: ${${_v}}")
 974 endforeach(_v)
 975 message(STATUS "")
 976
 977
 978 if(LYX_PCH)
 979         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 980         # Not sure if it works for all non-msvc compilers
 981         include(PCHSupport_26)
 982         configure_file(${TOP_CMAKE_PATH}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
 983         configure_file(${TOP_CMAKE_PATH}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 984         add_definitions(-DLYX_ENABLE_PCH)
 985
 986         if(MSVC)
 987                 macro(lyx_add_msvc_pch name_)
 988                         set_source_files_properties(${${name_}_sources} PROPERTIES
 989                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 990                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
 991                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 992                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
 993                                 ${TOP_BINARY_DIR}/pcheaders.h)
 994                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 995                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 996                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 997                 endmacro(lyx_add_msvc_pch)
 998                 macro(lyx_add_gcc_pch name_)
 999                 endmacro()
1000         else()
1001                 macro(lyx_add_msvc_pch name_)
1002                 endmacro()
1003                 macro(lyx_add_gcc_pch name_)
1004                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT)
1005                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
1006                 endmacro()
1007         endif()
1008 else()
1009         macro(lyx_add_msvc_pch)
1010         endmacro(lyx_add_msvc_pch)
1011         macro(lyx_add_gcc_pch name_)
1012         endmacro()
1013 endif()
1014
1015
1016 if(MSVC)
1017
1018         if(LYX_VLD)
1019                 set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/development/Win32/vld)
1020                 add_subdirectory(${vld_path}/cmake)
1021                 include(${vld_path}/cmake/vld.cmake) # forced include
1022                 set(vld_dll vld)
1023         endif()
1024
1025         if(LYX_WALL)
1026                 # Use the highest warning level
1027                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE STRING "Warning level" FORCE)
1028
1029                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
1030                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
1031                 else()
1032                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
1033                 endif()
1034
1035                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
1036                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
1037                 else()
1038                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
1039                 endif()
1040
1041                 # add here warnings which should produce an error /weXXXX
1042                 set(MSVC_W_ERROR   "/we4101 /we4189")
1043                 # add here warnings which should be disabled /wdXXXX
1044                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
1045
1046                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /W4 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1047                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /W4 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1048                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /W4 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1049
1050         else()
1051                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE STRING "Warning level" FORCE)
1052
1053                 # add here warnings which should produce an error /weXXXX
1054                 set(MSVC_W_ERROR   "/we4101 /we4189")
1055                 # add here warnings which should be disabled /wdXXXX
1056                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
1057
1058                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1059                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1060                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1061
1062         endif()
1063
1064         if (NOT Qt5Core_FOUND)
1065                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
1066                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
1067                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
1068         endif()
1069
1070         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
1071         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
1072         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
1073         message(STATUS "")
1074 endif()
1075
1076
1077 # Xcode compiler
1078 if (CMAKE_GENERATOR MATCHES Xcode)
1079         if (XCODE_VERSION VERSION_LESS "5.0")
1080                 # Automatically select the Xcode compiler if not set
1081                 if (NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
1082                         # XCode >= 3.1 has gcc 4.2 (up to actual Xcode)
1083                         if (XCODE_VERSION VERSION_GREATER "3.1")
1084                                 SET(CMAKE_XCODE_ATTRIBUTE_GCC_VERSION "com.apple.compilers.llvmgcc42")
1085                         ENDIF(XCODE_VERSION VERSION_GREATER "3.1")
1086                 ENDIF(NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
1087                 # Print the selected compiler version
1088         MESSAGE(STATUS "---- Using XCode compiler CMAKE_XCODE_ATTRIBUTE_GCC_VERSION=${CMAKE_XCODE_ATTRIBUTE_GCC_VERSION}")
1089         ENDIF(XCODE_VERSION VERSION_LESS "5.0")
1090 ENDIF(CMAKE_GENERATOR MATCHES Xcode)
1091
1092 if (WIN32 AND Qt5Core_FOUND)
1093         set(Z_PREFIX 1)
1094 endif()
1095
1096 # compiler tests, config.h generation LYX_CONFIGURE_CHECKS
1097 include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
1098 configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
1099
1100 unset(opts)
1101 foreach(_option ${LYX_OPTIONS})
1102   if(${_option}_show_message)
1103     string(SUBSTRING "${_option}                            " 0 31 _var)
1104     get_property(_prop CACHE ${_option} PROPERTY STRINGS)
1105     list(FIND LYX_OPTION_STRINGS ${_option} _index)
1106     if (${_index} GREATER -1)
1107       set(_isset ${${_option}})
1108     elseif(${_option})
1109       set(_isset ON)
1110     else()
1111       set(_isset OFF)
1112     endif()
1113     string(SUBSTRING "${_isset}           " 0 10 _val)
1114     set(opts "${opts} ${_option}(${${_option}})")
1115   endif()
1116 endforeach()
1117 set(tmp_vi "CMake Build")
1118 list(APPEND tmp_vi "  Host name:               ${CMAKE_HOST_SYSTEM_NAME}")
1119 list(APPEND tmp_vi "  Host processor:          ${CMAKE_HOST_SYSTEM_PROCESSOR}")
1120 list(APPEND tmp_vi "  Build flags:             ${opts}")
1121 list(APPEND tmp_vi "  C++ Compiler:            ${CMAKE_CXX_COMPILER_ID} (${CMAKE_CXX_COMPILER_VERSION})")
1122 list(APPEND tmp_vi "  C++ Compiler flags:      ${CMAKE_CXX_FLAGS}")
1123 if (LYX_DEBUG)
1124 list(APPEND tmp_vi "  C++ Compiler user flags: ${CMAKE_CXX_FLAGS_DEBUG}")
1125 else()
1126 list(APPEND tmp_vi "  C++ Compiler user flags: ${CMAKE_CXX_FLAGS_RELEASE}")
1127 endif()
1128 list(APPEND tmp_vi "  Qt version:              ${QTVERSION}")
1129 list(APPEND tmp_vi "  LyX binary dir:          ${CMAKE_INSTALL_PREFIX}/${LYX_UTILITIES_INSTALL_PATH}")
1130 get_data_destination(dest_data)
1131 list(APPEND tmp_vi "  LyX files dir:           ${CMAKE_INSTALL_PREFIX}/${dest_data}")
1132 string(REPLACE ";" "\\n" VERSION_INFO "${tmp_vi}")
1133
1134 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
1135 unset(opts)
1136 unset(tmp_vi)
1137
1138 if(QTVERSION MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+).*")
1139         MATH(EXPR QT4_VERSION "(${CMAKE_MATCH_1}<<16)|(${CMAKE_MATCH_2}<<8)|${CMAKE_MATCH_3}")
1140 endif()
1141
1142
1143 set (cmd ${CMAKE_CTEST_COMMAND})
1144 if (MSVC)
1145         set (cmd ${cmd} -C ${CMAKE_CFG_INTDIR})
1146 else ()
1147         set (cmd ${cmd} -C ${CMAKE_BUILD_TYPE})
1148 endif ()
1149 add_custom_target (lyx_run_tests COMMAND ${cmd})
1150 set_target_properties(lyx_run_tests PROPERTIES FOLDER "tests")
1151
1152 if(LYX_INSTALL)
1153         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
1154                 message(STATUS "Python required to create doc!")
1155         else()
1156                 if(UNIX)
1157                         add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
1158                 endif()
1159                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
1160         endif()
1161 endif()
1162 include(../Install)
1163
1164 # By running the URL tests first, time can be saved when running the ctests in
1165 # parallel since the URL tests take a long time to run (e.g. 10 minutes).
1166
1167 # Needed, because of perl scripts in checkurls autotests and batchtests
1168 find_package(Perl REQUIRED)
1169
1170 if(LYX_ENABLE_URLTESTS)
1171         add_subdirectory(development/checkurls "${TOP_BINARY_DIR}/checkurls")
1172 endif()
1173 add_subdirectory(src "${TOP_BINARY_DIR}/src")
1174 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
1175 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
1176 add_subdirectory(lib/examples "${TOP_BINARY_DIR}/lib/examples")
1177 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
1178 add_subdirectory(development/autotests "${TOP_BINARY_DIR}/autotests")
1179 add_subdirectory(development/batchtests "${TOP_BINARY_DIR}/batchtests")
1180
1181 message(STATUS)
1182 message(STATUS "Build params, switch LYX_* options by -DLYX_*=ON or OFF, LYX_* combos by -DLYX_*=value:")
1183 message(STATUS)
1184
1185 LYX_OPTION_LIST_ALL(used)
1186
1187
1188 if(LYX_NLS)
1189         message(STATUS)
1190         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
1191         message(STATUS)
1192         message(STATUS "  * iconv")
1193         message(STATUS "     - include: ${ICONV_INCLUDE_DIR}")
1194         message(STATUS "     - library: ${ICONV_LIBRARY}")
1195         message(STATUS "  * zlib")
1196         message(STATUS "     - include: ${ZLIB_INCLUDE_DIR}")
1197         message(STATUS "     - library: ${ZLIB_LIBRARY}")
1198         message(STATUS)
1199 endif()
1200
1201 # Apple has builtin native spell checker,
1202 # no need to warn for missing Aspell, Hunspell or Enchant
1203 if(NOT Spelling_FOUND AND NOT APPLE)
1204   if(LYX_REQUIRE_SPELLCHECK)
1205     set(_mode "FATAL_ERROR")
1206   else()
1207     set(_mode "STATUS")
1208   endif()
1209   message(${_mode} "No spellcheck libraries found. LyX will be unable use spellchecking")
1210 endif()
1211
1212 include("${TOP_CMAKE_PATH}/LyxPackaging.cmake")
1213
1214 if(ENABLE_DIST)
1215   # Use git to create the source package
1216   # git archive --format=tgz --output=/home/kornel/x.tar.gz master
1217   if(UNIX)
1218     set(DIST_FORMAT tgz)
1219   else()
1220     set(DIST_FORMAT zip)
1221   endif()
1222   set(DIST_NAME ${CMAKE_PROJECT_NAME}-${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}-${CMAKE_SYSTEM_NAME}.${DIST_FORMAT})
1223
1224   add_custom_command(
1225     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME}
1226     COMMAND  ${LYX_GITVERSION} archive --format=${DIST_FORMAT} --output=${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME} master
1227     WORKING_DIRECTORY ${TOP_SRC_DIR})
1228   add_custom_target(git-archive DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME})
1229 endif()
1230
1231 # Last directory to be included so that the fixup code (OS X)
1232 # can be run last
1233 add_subdirectory(development/cmake/post_install)
1234
1235 string(TIMESTAMP current_date "%Y-%m-%d %H:%M")
1236 execute_process(COMMAND ${LYX_GITVERSION} describe --tags
1237         WORKING_DIRECTORY "${TOP_SRC_DIR}"
1238         OUTPUT_VARIABLE current_version
1239         OUTPUT_STRIP_TRAILING_WHITESPACE)
1240 file(APPEND "${TOP_BINARY_DIR}/Testing/IgnoredCount" "${current_date} ${current_version} Ignored tests = ${LYX_ignored_count}\n")
1241 message(STATUS)