CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 2.6.4)
   8
   9
  10 set(LYX_PROJECT LyX)
  11
  12 set(LYX_CMAKE_DIR "development/cmake")
  13 set(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/${LYX_CMAKE_DIR}/modules")
  14
  15 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README ABSOLUTE)
  16 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  17
  18 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  19
  20 message(STATUS)
  21 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  22         message(STATUS "Building in-source")
  23         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  24 else()
  25         message(STATUS "Building out-of-source")
  26         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  27 endif()
  28
  29
  30 if(COMMAND cmake_policy)
  31         cmake_policy(SET CMP0003 OLD)
  32         cmake_policy(SET CMP0005 OLD)
  33 endif()
  34
  35 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  36
  37 # Supress regeneration
  38 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  39
  40 if(NOT help AND NOT HELP)
  41         # 'project' triggers the searching for a compiler
  42         project(${LYX_PROJECT})
  43 endif()
  44
  45 if(UNIX)
  46         set(ARCH_TRIPLET )
  47         FIND_PROGRAM(DPKG_ARCHITECTURE_EXECUTABLE dpkg-architecture)
  48         if(DPKG_ARCHITECTURE_EXECUTABLE)
  49                 EXECUTE_PROCESS(COMMAND ${DPKG_ARCHITECTURE_EXECUTABLE} -qDEB_HOST_MULTIARCH
  50                                 OUTPUT_VARIABLE ARCH_TRIPLET
  51                                 ERROR_VARIABLE ERROR_ARCH_TRIPLET
  52                                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  53         endif()
  54 endif()
  55 if(ARCH_TRIPLET)
  56         set(SYSTEM_LIB_DIRS /usr/lib /usr/lib/${ARCH_TRIPLET} /usr/local/lib)
  57 else()
  58         set(SYSTEM_LIB_DIRS /usr/lib /usr/local/lib)
  59 endif()
  60
  61 include(LyXMacros)
  62
  63 # Usage LYX_OPTION
  64 # 1. parameter: option name without prefix 'LYX_'
  65 # 2. parameter: description
  66 # 3. parameter: default value, ON or OFF
  67 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
  68
  69
  70 LYX_OPTION_INIT()
  71
  72 # Options for all compilers/systems
  73 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
  74 LYX_OPTION(LOCALVERSIONING  "Add version info to created package name (only used if LYX_CPACK option set)" OFF ALL)
  75 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
  76 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
  77 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
  78 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
  79 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
  80 LYX_OPTION(DEVEL_VERSION    "Build developer version" OFF ALL)
  81 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" OFF ALL)
  82 LYX_OPTION(DEBUG            "Enforce debug build"  OFF ALL)
  83 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
  84 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
  85 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
  86 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
  87 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
  88 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
  89 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
  90 LYX_OPTION(EXTERNAL_LIBINTL "Use external libintl" ON ALL)
  91 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
  92
  93 # GCC specific
  94 LYX_OPTION(PROFILE              "Build profile version" OFF GCC)
  95 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" OFF GCC)
  96 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
  97 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
  98 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++pedantic debug mode" OFF GCC)
  99 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" OFF GCC)
 100 LYX_OPTION(CONCEPT_CHECKS       "Enable concept-checks" OFF GCC)
 101 LYX_OPTION(PROFILE              "Build with options for gprof" OFF GCC)
 102
 103 # MSVC specific
 104 LYX_OPTION(CONSOLE               "Show console on Windows, enforce with =FORCE" ON MSVC)
 105 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
 106 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
 107 LYX_OPTION(CONFIGURE_CHECKS      "Also run configure checks for MSVC" OFF MSVC)
 108 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
 109
 110 # APPLE specific
 111 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
 112 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
 113
 114
 115 if(help OR HELP)
 116         message(STATUS)
 117         message(STATUS "Available options: (dis/enable with -DLYX_*=OFF/ON)")
 118         message(STATUS)
 119         LYX_OPTION_LIST_ALL(help)
 120         message(STATUS)
 121         RETURN()
 122 endif()
 123
 124 # Check option dependencies
 125
 126 if(LYX_CPACK)
 127         set(LYX_INSTALL ON)
 128 endif()
 129
 130 if(LYX_DMG)
 131         set(LYX_BUNDLE ON)
 132         set(LYX_CPACK ON)
 133 endif()
 134
 135 if(LYX_INSTALL)
 136         set(LYX_NLS ON)
 137         if (WIN32)
 138                 set(LYX_HUNSPELL ON)
 139         endif()
 140         if(LYX_CONSOLE MATCHES "FORCE")
 141                 set(LYX_CONSOLE ON)
 142         else()
 143                 set(LYX_CONSOLE OFF)
 144         endif()
 145         set(LYX_PACKAGE_SUFFIX ON)
 146         set(LYX_RELEASE ON)
 147         set(LYX_PROFILE OFF)
 148 endif()
 149
 150
 151 if(LYX_MERGE_FILES)
 152         set(LYX_PCH OFF)
 153 else()
 154         set(LYX_MERGE_REBUILD OFF)
 155 endif()
 156
 157 if(LYX_DEPENDENCIES_DOWNLOAD)
 158         message(STATUS)
 159         set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 160         message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 161         set(deps_files lyx20-deps-msvc2010-x86.zip)
 162         set(deps_server http://downloads.sourceforge.net/project/lyx/Win_installers/Dependencies)
 163         foreach(it ${deps_files})
 164                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 165                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 166                 if(NOT already_downloaded)
 167                         message(STATUS "Downloading ${it} ...")
 168                         file(DOWNLOAD ${deps_server}/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS STATUS status LOG log)
 169                         list(GET status 0 status_code)
 170                         list(GET status 1 status_string)
 171                         if(NOT status_code EQUAL 0)
 172                                 file(REMOVE ${LYX_DEPENDENCIES_DIR}/${it})
 173                                 message(FATAL_ERROR "error: downloading '${it}' failed. status_code: ${status_code}, status_string: ${status_string}. \nLog: ${log} ")
 174                         endif()
 175                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 176                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 177                 endif()
 178         endforeach()
 179         set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/deps20)
 180 endif()
 181
 182
 183
 184 message(STATUS)
 185
 186 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 187 if(WIN32)
 188         set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 189 else()
 190         set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 191 endif()
 192
 193
 194 if(UNIX OR MINGW)
 195         execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION)
 196         message(STATUS "Using GCC version ${GCC_VERSION}")
 197         if(NOT GCC_VERSION VERSION_LESS 4.4)
 198                 set(LYX_USE_TR1 1)
 199                 # GCC <= 4.5 does not support regex: there are linker errors
 200                 # http://gcc.gnu.org/onlinedocs/libstdc++/manual/status.html#status.iso.tr1
 201                 set(LYX_USE_TR1_REGEX 0)
 202         endif()
 203 else()
 204         if(MSVC10)
 205                 set(LYX_USE_TR1 1)
 206                 #set(LYX_USE_TR1_REGEX 1) #TODO should we use it in ECMAScript mode?
 207         endif()
 208 endif()
 209
 210
 211 set(VERSION_INFO "CMake Build")
 212
 213 # Try to get some informations from configure.ac
 214
 215 include(LyXPaths)
 216 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 217
 218 if(WIN32)
 219         set(USE_WINDOWS_PACKAGING ON)
 220 elseif(APPLE)
 221         set(USE_MACOSX_PACKAGING ON)
 222 else()
 223         set(USE_POSIX_PACKAGING ON)
 224 endif()
 225
 226 macro(setstripped _varname _value)
 227         string(STRIP ${_value} _v)
 228         if(USE_POSIX_PACKAGING)
 229                 string(TOLOWER ${_v} ${_varname})
 230         else()
 231                 set(${_varname} ${_v})
 232         endif()
 233 endmacro(setstripped)
 234
 235 foreach(_c_l ${_config_lines} )
 236         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 237                 setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 238                 setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 239                 setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 240                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\)\(\\.\([0-9]+\)\)?.*$")
 241                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 242                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 243                         set(LYX_PATCH_VERSION ${CMAKE_MATCH_4})
 244                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 245                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 246                         set(LYX_INSTALL_SUFFIX "${CMAKE_MATCH_1}.${CMAKE_MATCH_2}")
 247                 endif()
 248         endif()
 249         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 250                 set(LYX_DATE "${CMAKE_MATCH_1}")
 251         endif()
 252 endforeach(_c_l)
 253
 254 if (LYX_LOCALVERSIONING)
 255         # Find the revision number and for later use
 256         FIND_PROGRAM(LYX_GITVERSION git)
 257         #message(STATUS "gitversion = ${LYX_GITVERSION}")
 258         if(LYX_GITVERSION)
 259                 EXECUTE_PROCESS(COMMAND ${LYX_GITVERSION} "describe" WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE LYX_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 260                 if (LYX_PACKAGE_RELEASE MATCHES "^2\\.0\\.0\\-\([0-9]+\)\\-.*$")
 261                   # We will add offset of 40000 to get appropriate value to
 262                   # previous svn.
 263                   # We use this value than also to set the package-patch-value
 264                   MATH(EXPR tmp_REVISION_VERSION "(${CMAKE_MATCH_1}+40000)")
 265                   set(LYX_REVISION_VERSION "${LYX_PATCH_VERSION}-${tmp_REVISION_VERSION}git")
 266                 endif()
 267                 # Override the value from configure.ac, if possible
 268                 EXECUTE_PROCESS(COMMAND ${LYX_GITVERSION} "log" "-1" "--format=%ci"
 269                         WORKING_DIRECTORY "${TOP_SRC_DIR}"
 270                         OUTPUT_VARIABLE LYX_DATEtmp OUTPUT_STRIP_TRAILING_WHITESPACE)
 271
 272                 string(REGEX MATCH "([0-9]+-[0-9]+-[0-9]+)" LYX_DATE ${LYX_DATEtmp})
 273         else()
 274                 set(LYX_REVISION_VERSION git) #TODO use date
 275         endif()
 276 else()
 277         set(LYX_REVISION_VERSION ${LYX_PATCH_VERSION})
 278 endif()
 279
 280 if(LYX_PROGRAM_SUFFIX)
 281         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 282 else()
 283         set(PROGRAM_SUFFIX "")
 284 endif()
 285
 286
 287 if(APPLE)
 288         set(osx_bundle_program_name ${PACKAGE_BASE}${PROGRAM_SUFFIX})
 289         configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/Info.plist.in" "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 290 endif()
 291
 292 if(LYX_BUNDLE)
 293         set(LYX_CPACK ON)
 294         message(STATUS)
 295         message(STATUS "Bundle creation is enabled (experimental):")
 296         message(STATUS "    make")
 297         message(STATUS "    make install/strip")
 298         message(STATUS "    make package")
 299         if(APPLE)
 300                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 301                 set(CPACK_BUNDLE_NAME ${PACKAGE_BASE}${PROGRAM_SUFFIX})
 302                 set(CPACK_BUNDLE_PLIST "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 303                 set(LYX_DATA_SUBDIR ${PACKAGE_BASE}${PROGRAM_SUFFIX}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 304                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${PACKAGE_BASE}${PROGRAM_SUFFIX}.app)
 305                 if(NOT LYX_INSTALL_PREFIX)
 306                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 307                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 308                 endif()
 309                 # Change the owner so that the install can work
 310                 install(CODE "set(BU_CHMOD_BUNDLE_ITEMS 1)")
 311         elseif(UNIX)
 312                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 313                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 314                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 315         elseif(WIN32)
 316                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 317         endif()
 318 endif()
 319
 320 if(LYX_INSTALL_PREFIX)
 321         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 322         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 323 endif()
 324 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 325
 326 if(LYX_PACKAGE_SUFFIX)
 327         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 328 else()
 329         set(PACKAGE ${PACKAGE_BASE})
 330 endif()
 331
 332
 333 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 334         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 335         if (UNIX)
 336                 # don't use the default "/usr/local"
 337                 # but respect the user-choice on the command-line
 338                 if(LYX_INSTALL_SUFFIX)
 339                         set(CMAKE_INSTALL_PREFIX "/usr/local/lyx${LYX_INSTALL_SUFFIX}" CACHE PATH "LyX default install prefix" FORCE)
 340                 else()
 341                         set(CMAKE_INSTALL_PREFIX "/usr/local/${LYX_PROJECT}" CACHE PATH "LyX default install prefix" FORCE)
 342                 endif()
 343         endif()
 344         if(WIN32)
 345                 set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 346         endif()
 347 endif()
 348 if(IS_ABSOLUTE)
 349         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 350 else()
 351         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 352 endif()
 353
 354
 355
 356 if(NOT LYX_DATA_SUBDIR)
 357         if (WIN32)
 358                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 359         else()
 360                 set(LYX_DATA_SUBDIR "" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 361         endif()
 362 endif()
 363
 364 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 365 set(LYX_LOCALEDIR "locale")
 366 set(LYX_ABS_INSTALLED_LOCALEDIR "${LYX_ABS_INSTALLED_DATADIR}/${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}")
 367 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 368
 369
 370 if(LYX_INSTALL AND WIN32)
 371         message(STATUS "Configuring NSIS files")
 372         configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 373         configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 374         configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 375         message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 376 endif()
 377
 378 if(NOT GROUP_CODE)
 379         #set(GROUP_CODE "The Golden Code")
 380         set(GROUP_CODE flat)
 381 endif()
 382
 383 # lyx's source files
 384 set(LYX_CPP_FILES *.cpp)
 385 set(LYX_HPP_FILES *.h)
 386 set(LYX_MOC_FILES moc_*.cpp)
 387
 388 include(ProjectSourceGroup)
 389
 390
 391 if(LYX_PROFILE AND NOT MSVC)
 392         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 393         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg")
 394         set(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS}  -pg")
 395 else()
 396         set(LYX_PROFILE OFF)
 397 endif()
 398
 399
 400 if(LYX_NO_OPTIMIZE)
 401         set(CMAKE_BUILD_TYPE None)
 402         set(LYX_DEBUG OFF)
 403         set(LYX_RELEASE OFF)
 404         set(LYX_PROFILE OFF)
 405 elseif(LYX_RELEASE)
 406         set(CMAKE_BUILD_TYPE Release)
 407         set(LYX_DEBUG OFF)
 408         set(LYX_PROFILE OFF)
 409 elseif(LYX_PROFILE)
 410         set(CMAKE_BUILD_TYPE Profile)
 411         set(LYX_DEBUG OFF)
 412 else()
 413         set(CMAKE_BUILD_TYPE Debug)
 414         set(LYX_DEBUG ON)
 415 endif()
 416
 417
 418 # When shared libs are supported enable this option
 419 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 420 if(LYX_SHARED_LIBRARIES)
 421         set(library_type SHARED)
 422 else()
 423         set(library_type STATIC)
 424 endif()
 425
 426 if(NOT MSVC)
 427         if(NOT LYX_QUIET)
 428                 set(CMAKE_VERBOSE_MAKEFILE ON)
 429         endif()
 430         set(LYX_CXX_FLAGS "-Wall -Wunused-parameter")
 431         if(LYX_STDLIB_DEBUG)
 432                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 433         endif()
 434         if(LYX_CONCEPT_CHECKS)
 435                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCPP_CONCEPT_CHECKS")
 436         endif()
 437         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 438         set(CMAKE_CXX_FLAGS_DEBUG "${LYX_CXX_FLAGS} -fno-strict-aliasing -O0 -g -D_DEBUG" CACHE TYPE STRING FORCE)
 439         if(MINGW)
 440                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 441         else()
 442                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 443         endif()
 444 endif()
 445
 446
 447 find_package(Qt4 REQUIRED)
 448 find_package(Magic)
 449 if(Magic_FOUND)
 450         set(HAVE_MAGIC_H 1)
 451 endif()
 452
 453 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 454
 455 if(LYX_ASPELL)
 456         find_package(ASPELL)
 457         include_directories(${ASPELL_INCLUDE_DIR})
 458 endif()
 459
 460 if(LYX_ENCHANT)
 461         find_package(Enchant REQUIRED)
 462         include_directories(${ENCHANT_INCLUDE_DIR})
 463 endif()
 464
 465 if(LYX_HUNSPELL)
 466         find_package(Hunspell REQUIRED)
 467         include_directories(${HUNSPELL_INCLUDE_DIR})
 468 endif()
 469
 470 if(LYX_NLS)
 471         FIND_PROGRAM(LYX_PYTHON_EXECUTABLE python2 python HINTS ${GNUWIN32_DIR}/python)
 472         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 473                 message(FATAL_ERROR "Python 2.6 needed!")
 474         endif()
 475         find_package(LyXGettext REQUIRED)
 476         add_subdirectory(po "${TOP_BINARY_DIR}/po")
 477 endif()
 478
 479 if(LYX_NLS)
 480         if(LYX_EXTERNAL_LIBINTL)
 481                 find_package(Libintl REQUIRED)
 482                 if(DEFINED LIBINTL_LIBRARIES)
 483                         # find getext when configuring
 484                         list(APPEND CMAKE_REQUIRED_LIBRARIES ${LIBINTL_LIBRARIES})
 485                         # on mac use iconv also form ports
 486                         get_filename_component(ICONV_RELATIVE_TO_LIBINTL ${LIBINTL_LIBRARIES} PATH)
 487                 endif()
 488         else()
 489                 add_subdirectory(intl "${TOP_BINARY_DIR}/intl")
 490         endif()
 491 endif()
 492
 493 find_package(ICONV REQUIRED)
 494 find_package(ZLIB REQUIRED)
 495
 496 if(LYX_EXTERNAL_BOOST)
 497         message(STATUS "Searching for boost")
 498         find_package(Boost COMPONENTS signals regex) #TODO could REQUIRED be used
 499         if(Boost_FOUND)
 500                 message(STATUS "Boost found")
 501                 message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 502                 set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 503         else()
 504                 message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 505         endif()
 506 else()
 507         if(LYX_USE_TR1_REGEX)
 508                 set(Lyx_Boost_Libraries boost_signals)
 509         else()
 510                 set(Lyx_Boost_Libraries boost_signals boost_regex)
 511         endif()
 512         add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 513         include_directories(${TOP_SRC_DIR}/boost)
 514         add_subdirectory(boost "${TOP_BINARY_DIR}/boost")
 515 endif()
 516
 517
 518
 519
 520 if(WIN32)
 521         if(NOT LYX_CONSOLE)
 522                 set(WIN32_CONSOLE WIN32)
 523                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARY})
 524         endif()
 525         if(MSVC)
 526                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 527                 # disable checked iterators for msvc release builds to get maximum speed
 528                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 529         else()
 530                 add_definitions(-DWINVER=0x0500)
 531         endif()
 532 endif()
 533
 534 message(STATUS "")
 535 foreach(_v PACKAGE PACKAGE_VERSION
 536         PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 537         LYX_ABS_TOP_SRCDIR
 538         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 539         if(NOT DEFINED ${_v})
 540                 message(FATAL_ERROR "${_v} not defined")
 541         endif()
 542         string(SUBSTRING "${_v}                            " 0 28 _v1)
 543         message(STATUS "----- ${_v1}: ${${_v}}")
 544 endforeach(_v)
 545 message(STATUS "")
 546
 547
 548 if(LYX_PCH)
 549         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 550         # Not sure if it works for all non-msvc compilers
 551         include(PCHSupport_26)
 552         configure_file(${TOP_SRC_DIR}/${LYX_CMAKE_DIR}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
 553         configure_file(${TOP_SRC_DIR}/${LYX_CMAKE_DIR}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 554         add_definitions(-DLYX_ENABLE_PCH)
 555
 556         if(MSVC)
 557                 macro(lyx_add_msvc_pch name_)
 558                         set_source_files_properties(${${name_}_sources} PROPERTIES
 559                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 560                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
 561                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 562                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
 563                                 ${TOP_BINARY_DIR}/pcheaders.h)
 564                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 565                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 566                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 567                 endmacro(lyx_add_msvc_pch)
 568                 macro(lyx_add_gcc_pch name_)
 569                 endmacro()
 570         else()
 571                 macro(lyx_add_msvc_pch name_)
 572                 endmacro()
 573                 macro(lyx_add_gcc_pch name_)
 574                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT4)
 575                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
 576                 endmacro()
 577         endif()
 578 else()
 579         macro(lyx_add_msvc_pch)
 580         endmacro(lyx_add_msvc_pch)
 581         macro(lyx_add_gcc_pch name_)
 582         endmacro()
 583 endif()
 584
 585
 586 if(MSVC)
 587
 588         if(LYX_VLD)
 589                 set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/development/Win32/vld)
 590                 add_subdirectory(${vld_path}/cmake)
 591                 include(${vld_path}/cmake/vld.cmake) # forced include
 592                 set(vld_dll vld)
 593         endif()
 594
 595         if(LYX_WALL)
 596                 # Use the highest warning level
 597                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 598
 599                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 600                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 601                 else()
 602                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 603                 endif()
 604
 605                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 606                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 607                 else()
 608                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 609                 endif()
 610
 611                 # add here warnings which should produce an error /weXXXX
 612                 set(MSVC_W_ERROR   "/we4101 /we4189")
 613                 # add here warnings which should be disabled /wdXXXX
 614                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 615
 616                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 617                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 618                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 619
 620         else()
 621                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 622
 623                 # add here warnings which should produce an error /weXXXX
 624                 set(MSVC_W_ERROR   "/we4101 /we4189")
 625                 # add here warnings which should be disabled /wdXXXX
 626                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 627
 628                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 629                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 630                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 631
 632         endif()
 633         set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 634         set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 635         set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 636
 637         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 638         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 639         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 640         message(STATUS "")
 641 endif()
 642
 643
 644 if(LYX_DEBUG_GLIBC)
 645         set(_GLIBCXX_DEBUG ON)
 646 endif()
 647
 648 if(LYX_DEBUG_GLIBC_PEDANTIC)
 649         set(_GLIBCXX_DEBUG_PEDANTIC ON)
 650 endif()
 651
 652 # Xcode compiler
 653 if (CMAKE_GENERATOR MATCHES Xcode)
 654         # Automatically select the Xcode compiler if not set
 655         if (NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 656                 # XCode >= 3.1 has gcc 4.2 (up to actual Xcode)
 657                 if (XCODE_VERSION VERSION_GREATER "3.1")
 658                         SET(CMAKE_XCODE_ATTRIBUTE_GCC_VERSION "com.apple.compilers.llvmgcc42")
 659                 ENDIF(XCODE_VERSION VERSION_GREATER "3.1")
 660         ENDIF(NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 661
 662         # Print the selected compiler version
 663     MESSAGE(STATUS "---- Using XCode compiler CMAKE_XCODE_ATTRIBUTE_GCC_VERSION=${CMAKE_XCODE_ATTRIBUTE_GCC_VERSION}")
 664 ENDIF(CMAKE_GENERATOR MATCHES Xcode)
 665
 666
 667 # compiler tests, config.h generation
 668 if(MSVC AND NOT LYX_CONFIGURE_CHECKS)
 669         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.msvc ${TOP_BINARY_DIR}/configCompiler.h)
 670 else()
 671         include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
 672         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
 673 endif()
 674
 675 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
 676
 677 # Compute qt4-version from ${QTVERSION}
 678 if(QTVERSION MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+).*")
 679         MATH(EXPR QT4_VERSION "(${CMAKE_MATCH_1}<<16)|(${CMAKE_MATCH_2}<<8)|${CMAKE_MATCH_3}")
 680 endif()
 681
 682 add_subdirectory(src "${TOP_BINARY_DIR}/src")
 683 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
 684 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
 685 add_subdirectory(lib/examples "${TOP_BINARY_DIR}/lib/examples")
 686
 687
 688 if(LYX_INSTALL)
 689         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 690                 message(STATUS "Python required to create doc!")
 691         else()
 692                 add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
 693                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
 694         endif()
 695         if(NOT(LYX_BUNDLE AND APPLE))
 696                 include(../Install)
 697         endif()
 698 endif()
 699
 700 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
 701
 702 message(STATUS)
 703 message(STATUS "Build options, switch LYX_* variables by -DLYX_*=ON or OFF:")
 704 message(STATUS)
 705 LYX_OPTION_LIST_ALL(used)
 706
 707
 708 if(LYX_NLS)
 709         message(STATUS)
 710         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
 711         message(STATUS)
 712         message(STATUS "  * intl")
 713         message(STATUS "     - header : ${LIBINTL_HEADER}")
 714         message(STATUS "     - library: ${LIBINTL_LIBRARIES}")
 715         message(STATUS "  * iconv")
 716         message(STATUS "     - header : ${ICONV_HEADER}")
 717         message(STATUS "     - library: ${ICONV_LIBRARY}")
 718         message(STATUS "  * zlib")
 719         message(STATUS "     - header : ${ZLIB_HEADER}")
 720         message(STATUS "     - library: ${ZLIB_LIBRARY}")
 721         message(STATUS)
 722 endif()
 723
 724 include("${TOP_SRC_DIR}/${LYX_CMAKE_DIR}/LyxPackaging.cmake")
 725
 726 message(STATUS)